src/compiler/typetran.lisp

   1 ;;;; This file contains stuff that implements the portable IR1
   2 ;;;; semantics of type tests and coercion. The main thing we do is
   3 ;;;; convert complex type operations into simpler code that can be
   4 ;;;; compiled inline.
   5
   6 ;;;; This software is part of the SBCL system. See the README file for
   7 ;;;; more information.
   8 ;;;;
   9 ;;;; This software is derived from the CMU CL system, which was
  10 ;;;; written at Carnegie Mellon University and released into the
  11 ;;;; public domain. The software is in the public domain and is
  12 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  13 ;;;; files for more information.
  14
  15 (in-package "SB!C")
  16 \f
  17 ;;;; type predicate translation
  18 ;;;;
  19 ;;;; We maintain a bidirectional association between type predicates
  20 ;;;; and the tested type. The presence of a predicate in this
  21 ;;;; association implies that it is desirable to implement tests of
  22 ;;;; this type using the predicate. These are either predicates that
  23 ;;;; the back end is likely to have special knowledge about, or
  24 ;;;; predicates so complex that the only reasonable implentation is
  25 ;;;; via function call.
  26 ;;;;
  27 ;;;; Some standard types (such as SEQUENCE) are best tested by letting
  28 ;;;; the TYPEP source transform do its thing with the expansion. These
  29 ;;;; types (and corresponding predicates) are not maintained in this
  30 ;;;; association. In this case, there need not be any predicate
  31 ;;;; function unless it is required by the Common Lisp specification.
  32 ;;;;
  33 ;;;; The mapping between predicates and type structures is considered
  34 ;;;; part of the backend; different backends can support different
  35 ;;;; sets of predicates.
  36
  37 ;;; Establish an association between the type predicate NAME and the
  38 ;;; corresponding TYPE. This causes the type predicate to be
  39 ;;; recognized for purposes of optimization.
  40 (defmacro define-type-predicate (name type)
  41   `(%define-type-predicate ',name ',type))
  42 (defun %define-type-predicate (name specifier)
  43   (let ((type (specifier-type specifier)))
  44     (setf (gethash name *backend-predicate-types*) type)
  45     (setf *backend-type-predicates*
  46           (cons (cons type name)
  47                 (remove name *backend-type-predicates*
  48                         :key #'cdr)))
  49     (%deftransform name '(function (t) *) #'fold-type-predicate)
  50     name))
  51 \f
  52 ;;;; IR1 transforms
  53
  54 ;;; If we discover the type argument is constant during IR1
  55 ;;; optimization, then give the source transform another chance. The
  56 ;;; source transform can't pass, since we give it an explicit
  57 ;;; constant. At worst, it will convert to %TYPEP, which will prevent
  58 ;;; spurious attempts at transformation (and possible repeated
  59 ;;; warnings.)
  60 (deftransform typep ((object type))
  61   (unless (constant-lvar-p type)
  62     (give-up-ir1-transform "can't open-code test of non-constant type"))
  63   `(typep object ',(lvar-value type)))
  64
  65 ;;; If the lvar OBJECT definitely is or isn't of the specified
  66 ;;; type, then return T or NIL as appropriate. Otherwise quietly
  67 ;;; GIVE-UP-IR1-TRANSFORM.
  68 (defun ir1-transform-type-predicate (object type)
  69   (declare (type lvar object) (type ctype type))
  70   (let ((otype (lvar-type object)))
  71     (cond ((not (types-equal-or-intersect otype type))
  72            nil)
  73           ((csubtypep otype type)
  74            t)
  75           ((eq type *empty-type*)
  76            nil)
  77           (t
  78            (give-up-ir1-transform)))))
  79
  80 ;;; Flush %TYPEP tests whose result is known at compile time.
  81 (deftransform %typep ((object type))
  82   (unless (constant-lvar-p type)
  83     (give-up-ir1-transform))
  84   (ir1-transform-type-predicate
  85    object
  86    (ir1-transform-specifier-type (lvar-value type))))
  87
  88 ;;; This is the IR1 transform for simple type predicates. It checks
  89 ;;; whether the single argument is known to (not) be of the
  90 ;;; appropriate type, expanding to T or NIL as appropriate.
  91 (deftransform fold-type-predicate ((object) * * :node node :defun-only t)
  92   (let ((ctype (gethash (leaf-source-name
  93                          (ref-leaf
  94                           (lvar-uses
  95                            (basic-combination-fun node))))
  96                         *backend-predicate-types*)))
  97     (aver ctype)
  98     (ir1-transform-type-predicate object ctype)))
  99
 100 ;;; If FIND-CLASS is called on a constant class, locate the CLASS-CELL
 101 ;;; at load time.
 102 (deftransform find-classoid ((name) ((constant-arg symbol)) *)
 103   (let* ((name (lvar-value name))
 104          (cell (find-classoid-cell name)))
 105     `(or (classoid-cell-classoid ',cell)
 106          (error "class not yet defined: ~S" name))))
 107 \f
 108 ;;;; standard type predicates, i.e. those defined in package COMMON-LISP,
 109 ;;;; plus at least one oddball (%INSTANCEP)
 110 ;;;;
 111 ;;;; Various other type predicates (e.g. low-level representation
 112 ;;;; stuff like SIMPLE-ARRAY-SINGLE-FLOAT-P) are defined elsewhere.
 113
 114 ;;; FIXME: This function is only called once, at top level. Why not
 115 ;;; just expand all its operations into toplevel code?
 116 (defun !define-standard-type-predicates ()
 117   (define-type-predicate arrayp array)
 118   ; (The ATOM predicate is handled separately as (NOT CONS).)
 119   (define-type-predicate bit-vector-p bit-vector)
 120   (define-type-predicate characterp character)
 121   (define-type-predicate compiled-function-p compiled-function)
 122   (define-type-predicate complexp complex)
 123   (define-type-predicate complex-rational-p (complex rational))
 124   (define-type-predicate complex-float-p (complex float))
 125   (define-type-predicate consp cons)
 126   (define-type-predicate floatp float)
 127   (define-type-predicate functionp function)
 128   (define-type-predicate integerp integer)
 129   (define-type-predicate keywordp keyword)
 130   (define-type-predicate listp list)
 131   (define-type-predicate null null)
 132   (define-type-predicate numberp number)
 133   (define-type-predicate rationalp rational)
 134   (define-type-predicate realp real)
 135   (define-type-predicate simple-bit-vector-p simple-bit-vector)
 136   (define-type-predicate simple-string-p simple-string)
 137   (define-type-predicate simple-vector-p simple-vector)
 138   (define-type-predicate stringp string)
 139   (define-type-predicate %instancep instance)
 140   (define-type-predicate funcallable-instance-p funcallable-instance)
 141   (define-type-predicate symbolp symbol)
 142   (define-type-predicate vectorp vector))
 143 (!define-standard-type-predicates)
 144 \f
 145 ;;;; transforms for type predicates not implemented primitively
 146 ;;;;
 147 ;;;; See also VM dependent transforms.
 148
 149 (define-source-transform atom (x)
 150   `(not (consp ,x)))
 151 \f
 152 ;;;; TYPEP source transform
 153
 154 ;;; Return a form that tests the variable N-OBJECT for being in the
 155 ;;; binds specified by TYPE. BASE is the name of the base type, for
 156 ;;; declaration. We make SAFETY locally 0 to inhibit any checking of
 157 ;;; this assertion.
 158 (defun transform-numeric-bound-test (n-object type base)
 159   (declare (type numeric-type type))
 160   (let ((low (numeric-type-low type))
 161         (high (numeric-type-high type)))
 162     `(locally
 163        (declare (optimize (safety 0)))
 164        (and ,@(when low
 165                 (if (consp low)
 166                     `((> (truly-the ,base ,n-object) ,(car low)))
 167                     `((>= (truly-the ,base ,n-object) ,low))))
 168             ,@(when high
 169                 (if (consp high)
 170                     `((< (truly-the ,base ,n-object) ,(car high)))
 171                     `((<= (truly-the ,base ,n-object) ,high))))))))
 172
 173 ;;; Do source transformation of a test of a known numeric type. We can
 174 ;;; assume that the type doesn't have a corresponding predicate, since
 175 ;;; those types have already been picked off. In particular, CLASS
 176 ;;; must be specified, since it is unspecified only in NUMBER and
 177 ;;; COMPLEX. Similarly, we assume that COMPLEXP is always specified.
 178 ;;;
 179 ;;; For non-complex types, we just test that the number belongs to the
 180 ;;; base type, and then test that it is in bounds. When CLASS is
 181 ;;; INTEGER, we check to see whether the range is no bigger than
 182 ;;; FIXNUM. If so, we check for FIXNUM instead of INTEGER. This allows
 183 ;;; us to use fixnum comparison to test the bounds.
 184 ;;;
 185 ;;; For complex types, we must test for complex, then do the above on
 186 ;;; both the real and imaginary parts. When CLASS is float, we need
 187 ;;; only check the type of the realpart, since the format of the
 188 ;;; realpart and the imagpart must be the same.
 189 (defun source-transform-numeric-typep (object type)
 190   (let* ((class (numeric-type-class type))
 191          (base (ecase class
 192                  (integer (containing-integer-type
 193                            (if (numeric-type-complexp type)
 194                                (modified-numeric-type type
 195                                                       :complexp :real)
 196                                type)))
 197                  (rational 'rational)
 198                  (float (or (numeric-type-format type) 'float))
 199                  ((nil) 'real))))
 200     (once-only ((n-object object))
 201       (ecase (numeric-type-complexp type)
 202         (:real
 203          `(and (typep ,n-object ',base)
 204                ,(transform-numeric-bound-test n-object type base)))
 205         (:complex
 206          `(and (complexp ,n-object)
 207                ,(once-only ((n-real `(realpart (truly-the complex ,n-object)))
 208                             (n-imag `(imagpart (truly-the complex ,n-object))))
 209                   `(progn
 210                      ,n-imag ; ignorable
 211                      (and (typep ,n-real ',base)
 212                           ,@(when (eq class 'integer)
 213                               `((typep ,n-imag ',base)))
 214                           ,(transform-numeric-bound-test n-real type base)
 215                           ,(transform-numeric-bound-test n-imag type
 216                                                          base))))))))))
 217
 218 ;;; Do the source transformation for a test of a hairy type. AND,
 219 ;;; SATISFIES and NOT are converted into the obvious code. We convert
 220 ;;; unknown types to %TYPEP, emitting an efficiency note if
 221 ;;; appropriate.
 222 (defun source-transform-hairy-typep (object type)
 223   (declare (type hairy-type type))
 224   (let ((spec (hairy-type-specifier type)))
 225     (cond ((unknown-type-p type)
 226            (when (policy *lexenv* (> speed inhibit-warnings))
 227              (compiler-notify "can't open-code test of unknown type ~S"
 228                               (type-specifier type)))
 229            `(%typep ,object ',spec))
 230           (t
 231            (ecase (first spec)
 232              (satisfies `(if (funcall #',(second spec) ,object) t nil))
 233              ((not and)
 234               (once-only ((n-obj object))
 235                 `(,(first spec) ,@(mapcar (lambda (x)
 236                                             `(typep ,n-obj ',x))
 237                                           (rest spec))))))))))
 238
 239 (defun source-transform-negation-typep (object type)
 240   (declare (type negation-type type))
 241   (let ((spec (type-specifier (negation-type-type type))))
 242     `(not (typep ,object ',spec))))
 243
 244 ;;; Do source transformation for TYPEP of a known union type. If a
 245 ;;; union type contains LIST, then we pull that out and make it into a
 246 ;;; single LISTP call.  Note that if SYMBOL is in the union, then LIST
 247 ;;; will be a subtype even without there being any (member NIL).  We
 248 ;;; currently just drop through to the general code in this case,
 249 ;;; rather than trying to optimize it (but FIXME CSR 2004-04-05: it
 250 ;;; wouldn't be hard to optimize it after all).
 251 (defun source-transform-union-typep (object type)
 252   (let* ((types (union-type-types type))
 253          (type-cons (specifier-type 'cons))
 254          (mtype (find-if #'member-type-p types))
 255          (members (when mtype (member-type-members mtype))))
 256     (if (and mtype
 257              (memq nil members)
 258              (memq type-cons types))
 259         (once-only ((n-obj object))
 260           `(or (listp ,n-obj)
 261                (typep ,n-obj
 262                       '(or ,@(mapcar #'type-specifier
 263                                      (remove type-cons
 264                                              (remove mtype types)))
 265                         (member ,@(remove nil members))))))
 266         (once-only ((n-obj object))
 267           `(or ,@(mapcar (lambda (x)
 268                            `(typep ,n-obj ',(type-specifier x)))
 269                          types))))))
 270
 271 ;;; Do source transformation for TYPEP of a known intersection type.
 272 (defun source-transform-intersection-typep (object type)
 273   (once-only ((n-obj object))
 274     `(and ,@(mapcar (lambda (x)
 275                       `(typep ,n-obj ',(type-specifier x)))
 276                     (intersection-type-types type)))))
 277
 278 ;;; If necessary recurse to check the cons type.
 279 (defun source-transform-cons-typep (object type)
 280   (let* ((car-type (cons-type-car-type type))
 281          (cdr-type (cons-type-cdr-type type)))
 282     (let ((car-test-p (not (type= car-type *universal-type*)))
 283           (cdr-test-p (not (type= cdr-type *universal-type*))))
 284       (if (and (not car-test-p) (not cdr-test-p))
 285           `(consp ,object)
 286           (once-only ((n-obj object))
 287             `(and (consp ,n-obj)
 288                   ,@(if car-test-p
 289                         `((typep (car ,n-obj)
 290                                  ',(type-specifier car-type))))
 291                   ,@(if cdr-test-p
 292                         `((typep (cdr ,n-obj)
 293                                  ',(type-specifier cdr-type))))))))))
 294
 295 ;;; Return the predicate and type from the most specific entry in
 296 ;;; *TYPE-PREDICATES* that is a supertype of TYPE.
 297 (defun find-supertype-predicate (type)
 298   (declare (type ctype type))
 299   (let ((res nil)
 300         (res-type nil))
 301     (dolist (x *backend-type-predicates*)
 302       (let ((stype (car x)))
 303         (when (and (csubtypep type stype)
 304                    (or (not res-type)
 305                        (csubtypep stype res-type)))
 306           (setq res-type stype)
 307           (setq res (cdr x)))))
 308     (values res res-type)))
 309
 310 ;;; Return forms to test that OBJ has the rank and dimensions
 311 ;;; specified by TYPE, where STYPE is the type we have checked against
 312 ;;; (which is the same but for dimensions.)
 313 (defun test-array-dimensions (obj type stype)
 314   (declare (type array-type type stype))
 315   (let ((obj `(truly-the ,(type-specifier stype) ,obj))
 316         (dims (array-type-dimensions type)))
 317     (unless (eq dims '*)
 318       (collect ((res))
 319         (when (eq (array-type-dimensions stype) '*)
 320           (res `(= (array-rank ,obj) ,(length dims))))
 321         (do ((i 0 (1+ i))
 322              (dim dims (cdr dim)))
 323             ((null dim))
 324           (let ((dim (car dim)))
 325             (unless (eq dim '*)
 326               (res `(= (array-dimension ,obj ,i) ,dim)))))
 327         (res)))))
 328
 329 ;;; If we can find a type predicate that tests for the type without
 330 ;;; dimensions, then use that predicate and test for dimensions.
 331 ;;; Otherwise, just do %TYPEP.
 332 (defun source-transform-array-typep (obj type)
 333   (multiple-value-bind (pred stype) (find-supertype-predicate type)
 334     (if (and (array-type-p stype)
 335              ;; (If the element type hasn't been defined yet, it's
 336              ;; not safe to assume here that it will eventually
 337              ;; have (UPGRADED-ARRAY-ELEMENT-TYPE type)=T, so punt.)
 338              (not (unknown-type-p (array-type-element-type type)))
 339              (type= (array-type-specialized-element-type stype)
 340                     (array-type-specialized-element-type type))
 341              (eq (array-type-complexp stype) (array-type-complexp type)))
 342         (once-only ((n-obj obj))
 343           `(and (,pred ,n-obj)
 344                 ,@(test-array-dimensions n-obj type stype)))
 345         `(%typep ,obj ',(type-specifier type)))))
 346
 347 ;;; Transform a type test against some instance type. The type test is
 348 ;;; flushed if the result is known at compile time. If not properly
 349 ;;; named, error. If sealed and has no subclasses, just test for
 350 ;;; layout-EQ. If a structure then test for layout-EQ and then a
 351 ;;; general test based on layout-inherits. If safety is important,
 352 ;;; then we also check whether the layout for the object is invalid
 353 ;;; and signal an error if so. Otherwise, look up the indirect
 354 ;;; class-cell and call CLASS-CELL-TYPEP at runtime.
 355 (deftransform %instance-typep ((object spec) (* *) * :node node)
 356   (aver (constant-lvar-p spec))
 357   (let* ((spec (lvar-value spec))
 358          (class (specifier-type spec))
 359          (name (classoid-name class))
 360          (otype (lvar-type object))
 361          (layout (let ((res (info :type :compiler-layout name)))
 362                    (if (and res (not (layout-invalid res)))
 363                        res
 364                        nil))))
 365     (cond
 366       ;; Flush tests whose result is known at compile time.
 367       ((not (types-equal-or-intersect otype class))
 368        nil)
 369       ((csubtypep otype class)
 370        t)
 371       ;; If not properly named, error.
 372       ((not (and name (eq (find-classoid name) class)))
 373        (compiler-error "can't compile TYPEP of anonymous or undefined ~
 374                         class:~%  ~S"
 375                        class))
 376       (t
 377         ;; Delay the type transform to give type propagation a chance.
 378         (delay-ir1-transform node :constraint)
 379
 380        ;; Otherwise transform the type test.
 381        (multiple-value-bind (pred get-layout)
 382            (cond
 383              ((csubtypep class (specifier-type 'funcallable-instance))
 384               (values 'funcallable-instance-p '%funcallable-instance-layout))
 385              ((csubtypep class (specifier-type 'instance))
 386               (values '%instancep '%instance-layout))
 387              (t
 388               (values '(lambda (x) (declare (ignore x)) t) 'layout-of)))
 389          (cond
 390            ((and (eq (classoid-state class) :sealed) layout
 391                  (not (classoid-subclasses class)))
 392             ;; Sealed and has no subclasses.
 393             (let ((n-layout (gensym)))
 394               `(and (,pred object)
 395                     (let ((,n-layout (,get-layout object)))
 396                       ,@(when (policy *lexenv* (>= safety speed))
 397                               `((when (layout-invalid ,n-layout)
 398                                   (%layout-invalid-error object ',layout))))
 399                       (eq ,n-layout ',layout)))))
 400            ((and (typep class 'basic-structure-classoid) layout)
 401             ;; structure type tests; hierarchical layout depths
 402             (let ((depthoid (layout-depthoid layout))
 403                   (n-layout (gensym)))
 404               `(and (,pred object)
 405                     (let ((,n-layout (,get-layout object)))
 406                       ,@(when (policy *lexenv* (>= safety speed))
 407                               `((when (layout-invalid ,n-layout)
 408                                   (%layout-invalid-error object ',layout))))
 409                       (if (eq ,n-layout ',layout)
 410                           t
 411                           (and (> (layout-depthoid ,n-layout)
 412                                   ,depthoid)
 413                                (locally (declare (optimize (safety 0)))
 414                                  (eq (svref (layout-inherits ,n-layout)
 415                                             ,depthoid)
 416                                      ',layout))))))))
 417            ((and layout (>= (layout-depthoid layout) 0))
 418             ;; hierarchical layout depths for other things (e.g.
 419             ;; CONDITIONs)
 420             (let ((depthoid (layout-depthoid layout))
 421                   (n-layout (gensym))
 422                   (n-inherits (gensym)))
 423               `(and (,pred object)
 424                     (let ((,n-layout (,get-layout object)))
 425                       ,@(when (policy *lexenv* (>= safety speed))
 426                           `((when (layout-invalid ,n-layout)
 427                               (%layout-invalid-error object ',layout))))
 428                       (if (eq ,n-layout ',layout)
 429                           t
 430                           (let ((,n-inherits (layout-inherits ,n-layout)))
 431                             (declare (optimize (safety 0)))
 432                             (and (> (length ,n-inherits) ,depthoid)
 433                                  (eq (svref ,n-inherits ,depthoid)
 434                                      ',layout))))))))
 435            (t
 436             (/noshow "default case -- ,PRED and CLASS-CELL-TYPEP")
 437             `(and (,pred object)
 438                   (classoid-cell-typep (,get-layout object)
 439                                        ',(find-classoid-cell name)
 440                                        object)))))))))
 441
 442 ;;; If the specifier argument is a quoted constant, then we consider
 443 ;;; converting into a simple predicate or other stuff. If the type is
 444 ;;; constant, but we can't transform the call, then we convert to
 445 ;;; %TYPEP. We only pass when the type is non-constant. This allows us
 446 ;;; to recognize between calls that might later be transformed
 447 ;;; successfully when a constant type is discovered. We don't give an
 448 ;;; efficiency note when we pass, since the IR1 transform will give
 449 ;;; one if necessary and appropriate.
 450 ;;;
 451 ;;; If the type is TYPE= to a type that has a predicate, then expand
 452 ;;; to that predicate. Otherwise, we dispatch off of the type's type.
 453 ;;; These transformations can increase space, but it is hard to tell
 454 ;;; when, so we ignore policy and always do them.
 455 (define-source-transform typep (object spec)
 456   ;; KLUDGE: It looks bad to only do this on explicitly quoted forms,
 457   ;; since that would overlook other kinds of constants. But it turns
 458   ;; out that the DEFTRANSFORM for TYPEP detects any constant
 459   ;; lvar, transforms it into a quoted form, and gives this
 460   ;; source transform another chance, so it all works out OK, in a
 461   ;; weird roundabout way. -- WHN 2001-03-18
 462   (if (and (consp spec) (eq (car spec) 'quote))
 463       (let ((type (careful-specifier-type (cadr spec))))
 464         (or (when (not type)
 465               (compiler-warn "illegal type specifier for TYPEP: ~S"
 466                              (cadr spec))
 467               `(%typep ,object ,spec))
 468             (let ((pred (cdr (assoc type *backend-type-predicates*
 469                                     :test #'type=))))
 470               (when pred `(,pred ,object)))
 471             (typecase type
 472               (hairy-type
 473                (source-transform-hairy-typep object type))
 474               (negation-type
 475                (source-transform-negation-typep object type))
 476               (union-type
 477                (source-transform-union-typep object type))
 478               (intersection-type
 479                (source-transform-intersection-typep object type))
 480               (member-type
 481                `(member ,object ',(member-type-members type)))
 482               (args-type
 483                (compiler-warn "illegal type specifier for TYPEP: ~S"
 484                               (cadr spec))
 485                `(%typep ,object ,spec))
 486               (t nil))
 487             (typecase type
 488               (numeric-type
 489                (source-transform-numeric-typep object type))
 490               (classoid
 491                `(%instance-typep ,object ,spec))
 492               (array-type
 493                (source-transform-array-typep object type))
 494               (cons-type
 495                (source-transform-cons-typep object type))
 496               (t nil))
 497             `(%typep ,object ,spec)))
 498       (values nil t)))
 499 \f
 500 ;;;; coercion
 501
 502 (deftransform coerce ((x type) (* *) * :node node)
 503   (unless (constant-lvar-p type)
 504     (give-up-ir1-transform))
 505   (let ((tspec (ir1-transform-specifier-type (lvar-value type))))
 506     (if (csubtypep (lvar-type x) tspec)
 507         'x
 508         ;; Note: The THE here makes sure that specifiers like
 509         ;; (SINGLE-FLOAT 0.0 1.0) can raise a TYPE-ERROR.
 510         `(the ,(lvar-value type)
 511            ,(cond
 512              ((csubtypep tspec (specifier-type 'double-float))
 513               '(%double-float x))
 514              ;; FIXME: #!+long-float (t ,(error "LONG-FLOAT case needed"))
 515              ((csubtypep tspec (specifier-type 'float))
 516               '(%single-float x))
 517              ((and (csubtypep tspec (specifier-type 'simple-vector))
 518                    ;; Can we avoid checking for dimension issues like
 519                    ;; (COERCE FOO '(SIMPLE-VECTOR 5)) returning a
 520                    ;; vector of length 6?
 521                    (or (policy node (< safety 3)) ; no need in unsafe code
 522                        (and (array-type-p tspec) ; no need when no dimensions
 523                             (equal (array-type-dimensions tspec) '(*)))))
 524               `(if (simple-vector-p x)
 525                    x
 526                    (replace (make-array (length x)) x)))
 527              ;; FIXME: other VECTOR types?
 528              (t
 529               (give-up-ir1-transform)))))))
 530
 531