src/compiler/typetran.lisp

   1 ;;;; This file contains stuff that implements the portable IR1
   2 ;;;; semantics of type tests and coercion. The main thing we do is
   3 ;;;; convert complex type operations into simpler code that can be
   4 ;;;; compiled inline.
   5
   6 ;;;; This software is part of the SBCL system. See the README file for
   7 ;;;; more information.
   8 ;;;;
   9 ;;;; This software is derived from the CMU CL system, which was
  10 ;;;; written at Carnegie Mellon University and released into the
  11 ;;;; public domain. The software is in the public domain and is
  12 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  13 ;;;; files for more information.
  14
  15 (in-package "SB!C")
  16 \f
  17 ;;;; type predicate translation
  18 ;;;;
  19 ;;;; We maintain a bidirectional association between type predicates
  20 ;;;; and the tested type. The presence of a predicate in this
  21 ;;;; association implies that it is desirable to implement tests of
  22 ;;;; this type using the predicate. These are either predicates that
  23 ;;;; the back end is likely to have special knowledge about, or
  24 ;;;; predicates so complex that the only reasonable implentation is
  25 ;;;; via function call.
  26 ;;;;
  27 ;;;; Some standard types (such as SEQUENCE) are best tested by letting
  28 ;;;; the TYPEP source transform do its thing with the expansion. These
  29 ;;;; types (and corresponding predicates) are not maintained in this
  30 ;;;; association. In this case, there need not be any predicate
  31 ;;;; function unless it is required by the Common Lisp specification.
  32 ;;;;
  33 ;;;; The mapping between predicates and type structures is considered
  34 ;;;; part of the backend; different backends can support different
  35 ;;;; sets of predicates.
  36
  37 ;;; Establish an association between the type predicate NAME and the
  38 ;;; corresponding TYPE. This causes the type predicate to be
  39 ;;; recognized for purposes of optimization.
  40 (defmacro define-type-predicate (name type)
  41   `(%define-type-predicate ',name ',type))
  42 (defun %define-type-predicate (name specifier)
  43   (let ((type (specifier-type specifier)))
  44     (setf (gethash name *backend-predicate-types*) type)
  45     (setf *backend-type-predicates*
  46           (cons (cons type name)
  47                 (remove name *backend-type-predicates*
  48                         :key #'cdr)))
  49     (%deftransform name '(function (t) *) #'fold-type-predicate)
  50     name))
  51 \f
  52 ;;;; IR1 transforms
  53
  54 ;;; If we discover the type argument is constant during IR1
  55 ;;; optimization, then give the source transform another chance. The
  56 ;;; source transform can't pass, since we give it an explicit
  57 ;;; constant. At worst, it will convert to %TYPEP, which will prevent
  58 ;;; spurious attempts at transformation (and possible repeated
  59 ;;; warnings.)
  60 (deftransform typep ((object type))
  61   (unless (constant-continuation-p type)
  62     (give-up-ir1-transform "can't open-code test of non-constant type"))
  63   `(typep object ',(continuation-value type)))
  64
  65 ;;; If the continuation OBJECT definitely is or isn't of the specified
  66 ;;; type, then return T or NIL as appropriate. Otherwise quietly
  67 ;;; GIVE-UP-IR1-TRANSFORM.
  68 (defun ir1-transform-type-predicate (object type)
  69   (declare (type continuation object) (type ctype type))
  70   (let ((otype (continuation-type object)))
  71     (cond ((not (types-equal-or-intersect otype type))
  72            nil)
  73           ((csubtypep otype type)
  74            t)
  75           ((eq type *empty-type*)
  76            nil)
  77           (t
  78            (give-up-ir1-transform)))))
  79
  80 ;;; Flush %TYPEP tests whose result is known at compile time.
  81 (deftransform %typep ((object type))
  82   (unless (constant-continuation-p type)
  83     (give-up-ir1-transform))
  84   (ir1-transform-type-predicate
  85    object
  86    (ir1-transform-specifier-type (continuation-value type))))
  87
  88 ;;; This is the IR1 transform for simple type predicates. It checks
  89 ;;; whether the single argument is known to (not) be of the
  90 ;;; appropriate type, expanding to T or NIL as appropriate.
  91 (deftransform fold-type-predicate ((object) * * :node node :defun-only t)
  92   (let ((ctype (gethash (leaf-source-name
  93                          (ref-leaf
  94                           (continuation-use
  95                            (basic-combination-fun node))))
  96                         *backend-predicate-types*)))
  97     (aver ctype)
  98     (ir1-transform-type-predicate object ctype)))
  99
 100 ;;; If FIND-CLASS is called on a constant class, locate the CLASS-CELL
 101 ;;; at load time.
 102 (deftransform find-classoid ((name) ((constant-arg symbol)) *)
 103   (let* ((name (continuation-value name))
 104          (cell (find-classoid-cell name)))
 105     `(or (classoid-cell-classoid ',cell)
 106          (error "class not yet defined: ~S" name))))
 107 \f
 108 ;;;; standard type predicates, i.e. those defined in package COMMON-LISP,
 109 ;;;; plus at least one oddball (%INSTANCEP)
 110 ;;;;
 111 ;;;; Various other type predicates (e.g. low-level representation
 112 ;;;; stuff like SIMPLE-ARRAY-SINGLE-FLOAT-P) are defined elsewhere.
 113
 114 ;;; FIXME: This function is only called once, at top level. Why not
 115 ;;; just expand all its operations into toplevel code?
 116 (defun !define-standard-type-predicates ()
 117   (define-type-predicate arrayp array)
 118   ; (The ATOM predicate is handled separately as (NOT CONS).)
 119   (define-type-predicate bit-vector-p bit-vector)
 120   (define-type-predicate characterp character)
 121   (define-type-predicate compiled-function-p compiled-function)
 122   (define-type-predicate complexp complex)
 123   (define-type-predicate complex-rational-p (complex rational))
 124   (define-type-predicate complex-float-p (complex float))
 125   (define-type-predicate consp cons)
 126   (define-type-predicate floatp float)
 127   (define-type-predicate functionp function)
 128   (define-type-predicate integerp integer)
 129   (define-type-predicate keywordp keyword)
 130   (define-type-predicate listp list)
 131   (define-type-predicate null null)
 132   (define-type-predicate numberp number)
 133   (define-type-predicate rationalp rational)
 134   (define-type-predicate realp real)
 135   (define-type-predicate simple-bit-vector-p simple-bit-vector)
 136   (define-type-predicate simple-string-p simple-string)
 137   (define-type-predicate simple-vector-p simple-vector)
 138   (define-type-predicate stringp string)
 139   (define-type-predicate %instancep instance)
 140   (define-type-predicate funcallable-instance-p funcallable-instance)
 141   (define-type-predicate symbolp symbol)
 142   (define-type-predicate vectorp vector))
 143 (!define-standard-type-predicates)
 144 \f
 145 ;;;; transforms for type predicates not implemented primitively
 146 ;;;;
 147 ;;;; See also VM dependent transforms.
 148
 149 (define-source-transform atom (x)
 150   `(not (consp ,x)))
 151 \f
 152 ;;;; TYPEP source transform
 153
 154 ;;; Return a form that tests the variable N-OBJECT for being in the
 155 ;;; binds specified by TYPE. BASE is the name of the base type, for
 156 ;;; declaration. We make SAFETY locally 0 to inhibit any checking of
 157 ;;; this assertion.
 158 (defun transform-numeric-bound-test (n-object type base)
 159   (declare (type numeric-type type))
 160   (let ((low (numeric-type-low type))
 161         (high (numeric-type-high type)))
 162     `(locally
 163        (declare (optimize (safety 0)))
 164        (and ,@(when low
 165                 (if (consp low)
 166                     `((> (truly-the ,base ,n-object) ,(car low)))
 167                     `((>= (truly-the ,base ,n-object) ,low))))
 168             ,@(when high
 169                 (if (consp high)
 170                     `((< (truly-the ,base ,n-object) ,(car high)))
 171                     `((<= (truly-the ,base ,n-object) ,high))))))))
 172
 173 ;;; Do source transformation of a test of a known numeric type. We can
 174 ;;; assume that the type doesn't have a corresponding predicate, since
 175 ;;; those types have already been picked off. In particular, CLASS
 176 ;;; must be specified, since it is unspecified only in NUMBER and
 177 ;;; COMPLEX. Similarly, we assume that COMPLEXP is always specified.
 178 ;;;
 179 ;;; For non-complex types, we just test that the number belongs to the
 180 ;;; base type, and then test that it is in bounds. When CLASS is
 181 ;;; INTEGER, we check to see whether the range is no bigger than
 182 ;;; FIXNUM. If so, we check for FIXNUM instead of INTEGER. This allows
 183 ;;; us to use fixnum comparison to test the bounds.
 184 ;;;
 185 ;;; For complex types, we must test for complex, then do the above on
 186 ;;; both the real and imaginary parts. When CLASS is float, we need
 187 ;;; only check the type of the realpart, since the format of the
 188 ;;; realpart and the imagpart must be the same.
 189 (defun source-transform-numeric-typep (object type)
 190   (let* ((class (numeric-type-class type))
 191          (base (ecase class
 192                  (integer (containing-integer-type type))
 193                  (rational 'rational)
 194                  (float (or (numeric-type-format type) 'float))
 195                  ((nil) 'real))))
 196     (once-only ((n-object object))
 197       (ecase (numeric-type-complexp type)
 198         (:real
 199          `(and (typep ,n-object ',base)
 200                ,(transform-numeric-bound-test n-object type base)))
 201         (:complex
 202          `(and (complexp ,n-object)
 203                ,(once-only ((n-real `(realpart (truly-the complex ,n-object)))
 204                             (n-imag `(imagpart (truly-the complex ,n-object))))
 205                   `(progn
 206                      ,n-imag ; ignorable
 207                      (and (typep ,n-real ',base)
 208                           ,@(when (eq class 'integer)
 209                               `((typep ,n-imag ',base)))
 210                           ,(transform-numeric-bound-test n-real type base)
 211                           ,(transform-numeric-bound-test n-imag type
 212                                                          base))))))))))
 213
 214 ;;; Do the source transformation for a test of a hairy type. AND,
 215 ;;; SATISFIES and NOT are converted into the obvious code. We convert
 216 ;;; unknown types to %TYPEP, emitting an efficiency note if
 217 ;;; appropriate.
 218 (defun source-transform-hairy-typep (object type)
 219   (declare (type hairy-type type))
 220   (let ((spec (hairy-type-specifier type)))
 221     (cond ((unknown-type-p type)
 222            (when (policy *lexenv* (> speed inhibit-warnings))
 223              (compiler-notify "can't open-code test of unknown type ~S"
 224                               (type-specifier type)))
 225            `(%typep ,object ',spec))
 226           (t
 227            (ecase (first spec)
 228              (satisfies `(if (funcall #',(second spec) ,object) t nil))
 229              ((not and)
 230               (once-only ((n-obj object))
 231                 `(,(first spec) ,@(mapcar (lambda (x)
 232                                             `(typep ,n-obj ',x))
 233                                           (rest spec))))))))))
 234
 235 (defun source-transform-negation-typep (object type)
 236   (declare (type negation-type type))
 237   (let ((spec (type-specifier (negation-type-type type))))
 238     `(not (typep ,object ',spec))))
 239
 240 ;;; Do source transformation for TYPEP of a known union type. If a
 241 ;;; union type contains LIST, then we pull that out and make it into a
 242 ;;; single LISTP call. Note that if SYMBOL is in the union, then LIST
 243 ;;; will be a subtype even without there being any (member NIL). We
 244 ;;; just drop through to the general code in this case, rather than
 245 ;;; trying to optimize it.
 246 (defun source-transform-union-typep (object type)
 247   (let* ((types (union-type-types type))
 248          (type-list (specifier-type 'list))
 249          (type-cons (specifier-type 'cons))
 250          (mtype (find-if #'member-type-p types))
 251          (members (when mtype (member-type-members mtype))))
 252     (if (and mtype
 253              (memq nil members)
 254              (memq type-cons types))
 255         (once-only ((n-obj object))
 256           `(or (listp ,n-obj)
 257                (typep ,n-obj
 258                       '(or ,@(mapcar #'type-specifier
 259                                      (remove type-cons
 260                                              (remove mtype types)))
 261                         (member ,@(remove nil members))))))
 262         (once-only ((n-obj object))
 263           `(or ,@(mapcar (lambda (x)
 264                            `(typep ,n-obj ',(type-specifier x)))
 265                          types))))))
 266
 267 ;;; Do source transformation for TYPEP of a known intersection type.
 268 (defun source-transform-intersection-typep (object type)
 269   (once-only ((n-obj object))
 270     `(and ,@(mapcar (lambda (x)
 271                       `(typep ,n-obj ',(type-specifier x)))
 272                     (intersection-type-types type)))))
 273
 274 ;;; If necessary recurse to check the cons type.
 275 (defun source-transform-cons-typep (object type)
 276   (let* ((car-type (cons-type-car-type type))
 277          (cdr-type (cons-type-cdr-type type)))
 278     (let ((car-test-p (not (type= car-type *universal-type*)))
 279           (cdr-test-p (not (type= cdr-type *universal-type*))))
 280       (if (and (not car-test-p) (not cdr-test-p))
 281           `(consp ,object)
 282           (once-only ((n-obj object))
 283             `(and (consp ,n-obj)
 284                   ,@(if car-test-p
 285                         `((typep (car ,n-obj)
 286                                  ',(type-specifier car-type))))
 287                   ,@(if cdr-test-p
 288                         `((typep (cdr ,n-obj)
 289                                  ',(type-specifier cdr-type))))))))))
 290
 291 ;;; Return the predicate and type from the most specific entry in
 292 ;;; *TYPE-PREDICATES* that is a supertype of TYPE.
 293 (defun find-supertype-predicate (type)
 294   (declare (type ctype type))
 295   (let ((res nil)
 296         (res-type nil))
 297     (dolist (x *backend-type-predicates*)
 298       (let ((stype (car x)))
 299         (when (and (csubtypep type stype)
 300                    (or (not res-type)
 301                        (csubtypep stype res-type)))
 302           (setq res-type stype)
 303           (setq res (cdr x)))))
 304     (values res res-type)))
 305
 306 ;;; Return forms to test that OBJ has the rank and dimensions
 307 ;;; specified by TYPE, where STYPE is the type we have checked against
 308 ;;; (which is the same but for dimensions.)
 309 (defun test-array-dimensions (obj type stype)
 310   (declare (type array-type type stype))
 311   (let ((obj `(truly-the ,(type-specifier stype) ,obj))
 312         (dims (array-type-dimensions type)))
 313     (unless (eq dims '*)
 314       (collect ((res))
 315         (when (eq (array-type-dimensions stype) '*)
 316           (res `(= (array-rank ,obj) ,(length dims))))
 317         (do ((i 0 (1+ i))
 318              (dim dims (cdr dim)))
 319             ((null dim))
 320           (let ((dim (car dim)))
 321             (unless (eq dim '*)
 322               (res `(= (array-dimension ,obj ,i) ,dim)))))
 323         (res)))))
 324
 325 ;;; If we can find a type predicate that tests for the type without
 326 ;;; dimensions, then use that predicate and test for dimensions.
 327 ;;; Otherwise, just do %TYPEP.
 328 (defun source-transform-array-typep (obj type)
 329   (multiple-value-bind (pred stype) (find-supertype-predicate type)
 330     (if (and (array-type-p stype)
 331              ;; (If the element type hasn't been defined yet, it's
 332              ;; not safe to assume here that it will eventually
 333              ;; have (UPGRADED-ARRAY-ELEMENT-TYPE type)=T, so punt.)
 334              (not (unknown-type-p (array-type-element-type type)))
 335              (type= (array-type-specialized-element-type stype)
 336                     (array-type-specialized-element-type type))
 337              (eq (array-type-complexp stype) (array-type-complexp type)))
 338         (once-only ((n-obj obj))
 339           `(and (,pred ,n-obj)
 340                 ,@(test-array-dimensions n-obj type stype)))
 341         `(%typep ,obj ',(type-specifier type)))))
 342
 343 ;;; Transform a type test against some instance type. The type test is
 344 ;;; flushed if the result is known at compile time. If not properly
 345 ;;; named, error. If sealed and has no subclasses, just test for
 346 ;;; layout-EQ. If a structure then test for layout-EQ and then a
 347 ;;; general test based on layout-inherits. If safety is important,
 348 ;;; then we also check whether the layout for the object is invalid
 349 ;;; and signal an error if so. Otherwise, look up the indirect
 350 ;;; class-cell and call CLASS-CELL-TYPEP at runtime.
 351 (deftransform %instance-typep ((object spec) (* *) * :node node)
 352   (aver (constant-continuation-p spec))
 353   (let* ((spec (continuation-value spec))
 354          (class (specifier-type spec))
 355          (name (classoid-name class))
 356          (otype (continuation-type object))
 357          (layout (let ((res (info :type :compiler-layout name)))
 358                    (if (and res (not (layout-invalid res)))
 359                        res
 360                        nil))))
 361     (cond
 362       ;; Flush tests whose result is known at compile time.
 363       ((not (types-equal-or-intersect otype class))
 364        nil)
 365       ((csubtypep otype class)
 366        t)
 367       ;; If not properly named, error.
 368       ((not (and name (eq (find-classoid name) class)))
 369        (compiler-error "can't compile TYPEP of anonymous or undefined ~
 370                         class:~%  ~S"
 371                        class))
 372       (t
 373         ;; Delay the type transform to give type propagation a chance.
 374         (delay-ir1-transform node :constraint)
 375
 376        ;; Otherwise transform the type test.
 377        (multiple-value-bind (pred get-layout)
 378            (cond
 379              ((csubtypep class (specifier-type 'funcallable-instance))
 380               (values 'funcallable-instance-p '%funcallable-instance-layout))
 381              ((csubtypep class (specifier-type 'instance))
 382               (values '%instancep '%instance-layout))
 383              (t
 384               (values '(lambda (x) (declare (ignore x)) t) 'layout-of)))
 385          (cond
 386            ((and (eq (classoid-state class) :sealed) layout
 387                  (not (classoid-subclasses class)))
 388             ;; Sealed and has no subclasses.
 389             (let ((n-layout (gensym)))
 390               `(and (,pred object)
 391                     (let ((,n-layout (,get-layout object)))
 392                       ,@(when (policy *lexenv* (>= safety speed))
 393                               `((when (layout-invalid ,n-layout)
 394                                   (%layout-invalid-error object ',layout))))
 395                       (eq ,n-layout ',layout)))))
 396            ((and (typep class 'basic-structure-classoid) layout)
 397             ;; structure type tests; hierarchical layout depths
 398             (let ((depthoid (layout-depthoid layout))
 399                   (n-layout (gensym)))
 400               `(and (,pred object)
 401                     (let ((,n-layout (,get-layout object)))
 402                       ,@(when (policy *lexenv* (>= safety speed))
 403                               `((when (layout-invalid ,n-layout)
 404                                   (%layout-invalid-error object ',layout))))
 405                       (if (eq ,n-layout ',layout)
 406                           t
 407                           (and (> (layout-depthoid ,n-layout)
 408                                   ,depthoid)
 409                                (locally (declare (optimize (safety 0)))
 410                                  (eq (svref (layout-inherits ,n-layout)
 411                                             ,depthoid)
 412                                      ',layout))))))))
 413            ((and layout (>= (layout-depthoid layout) 0))
 414             ;; hierarchical layout depths for other things (e.g.
 415             ;; CONDITIONs)
 416             (let ((depthoid (layout-depthoid layout))
 417                   (n-layout (gensym))
 418                   (n-inherits (gensym)))
 419               `(and (,pred object)
 420                     (let ((,n-layout (,get-layout object)))
 421                       ,@(when (policy *lexenv* (>= safety speed))
 422                           `((when (layout-invalid ,n-layout)
 423                               (%layout-invalid-error object ',layout))))
 424                       (if (eq ,n-layout ',layout)
 425                           t
 426                           (let ((,n-inherits (layout-inherits ,n-layout)))
 427                             (declare (optimize (safety 0)))
 428                             (and (> (length ,n-inherits) ,depthoid)
 429                                  (eq (svref ,n-inherits ,depthoid)
 430                                      ',layout))))))))
 431            (t
 432             (/noshow "default case -- ,PRED and CLASS-CELL-TYPEP")
 433             `(and (,pred object)
 434                   (classoid-cell-typep (,get-layout object)
 435                                        ',(find-classoid-cell name)
 436                                        object)))))))))
 437
 438 ;;; If the specifier argument is a quoted constant, then we consider
 439 ;;; converting into a simple predicate or other stuff. If the type is
 440 ;;; constant, but we can't transform the call, then we convert to
 441 ;;; %TYPEP. We only pass when the type is non-constant. This allows us
 442 ;;; to recognize between calls that might later be transformed
 443 ;;; successfully when a constant type is discovered. We don't give an
 444 ;;; efficiency note when we pass, since the IR1 transform will give
 445 ;;; one if necessary and appropriate.
 446 ;;;
 447 ;;; If the type is TYPE= to a type that has a predicate, then expand
 448 ;;; to that predicate. Otherwise, we dispatch off of the type's type.
 449 ;;; These transformations can increase space, but it is hard to tell
 450 ;;; when, so we ignore policy and always do them.
 451 (define-source-transform typep (object spec)
 452   ;; KLUDGE: It looks bad to only do this on explicitly quoted forms,
 453   ;; since that would overlook other kinds of constants. But it turns
 454   ;; out that the DEFTRANSFORM for TYPEP detects any constant
 455   ;; continuation, transforms it into a quoted form, and gives this
 456   ;; source transform another chance, so it all works out OK, in a
 457   ;; weird roundabout way. -- WHN 2001-03-18
 458   (if (and (consp spec) (eq (car spec) 'quote))
 459       (let ((type (careful-specifier-type (cadr spec))))
 460         (or (when (not type)
 461               (compiler-warn "illegal type specifier for TYPEP: ~S"
 462                              (cadr spec))
 463               `(%typep ,object ,spec))
 464             (let ((pred (cdr (assoc type *backend-type-predicates*
 465                                     :test #'type=))))
 466               (when pred `(,pred ,object)))
 467             (typecase type
 468               (hairy-type
 469                (source-transform-hairy-typep object type))
 470               (negation-type
 471                (source-transform-negation-typep object type))
 472               (union-type
 473                (source-transform-union-typep object type))
 474               (intersection-type
 475                (source-transform-intersection-typep object type))
 476               (member-type
 477                `(member ,object ',(member-type-members type)))
 478               (args-type
 479                (compiler-warn "illegal type specifier for TYPEP: ~S"
 480                               (cadr spec))
 481                `(%typep ,object ,spec))
 482               (t nil))
 483             (typecase type
 484               (numeric-type
 485                (source-transform-numeric-typep object type))
 486               (classoid
 487                `(%instance-typep ,object ,spec))
 488               (array-type
 489                (source-transform-array-typep object type))
 490               (cons-type
 491                (source-transform-cons-typep object type))
 492               (t nil))
 493             `(%typep ,object ,spec)))
 494       (values nil t)))
 495 \f
 496 ;;;; coercion
 497
 498 (deftransform coerce ((x type) (* *) * :node node)
 499   (unless (constant-continuation-p type)
 500     (give-up-ir1-transform))
 501   (let ((tspec (ir1-transform-specifier-type (continuation-value type))))
 502     (if (csubtypep (continuation-type x) tspec)
 503         'x
 504         ;; Note: The THE here makes sure that specifiers like
 505         ;; (SINGLE-FLOAT 0.0 1.0) can raise a TYPE-ERROR.
 506         `(the ,(continuation-value type)
 507            ,(cond
 508              ((csubtypep tspec (specifier-type 'double-float))
 509               '(%double-float x))
 510              ;; FIXME: #!+long-float (t ,(error "LONG-FLOAT case needed"))
 511              ((csubtypep tspec (specifier-type 'float))
 512               '(%single-float x))
 513              ((and (csubtypep tspec (specifier-type 'simple-vector))
 514                    ;; Can we avoid checking for dimension issues like
 515                    ;; (COERCE FOO '(SIMPLE-VECTOR 5)) returning a
 516                    ;; vector of length 6?
 517                    (or (policy node (< safety 3)) ; no need in unsafe code
 518                        (and (array-type-p tspec) ; no need when no dimensions
 519                             (equal (array-type-dimensions tspec) '(*)))))
 520               `(if (simple-vector-p x)
 521                    x
 522                    (replace (make-array (length x)) x)))
 523              ;; FIXME: other VECTOR types?
 524              (t
 525               (give-up-ir1-transform)))))))
 526
 527