src/compiler/x86/alloc.lisp

   1 ;;;; allocation VOPs for the x86
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!VM")
  13 \f
  14 ;;;; LIST and LIST*
  15 (defoptimizer (list stack-allocate-result) ((&rest args))
  16   (not (null args)))
  17 (defoptimizer (list* stack-allocate-result) ((&rest args))
  18   (not (null (rest args))))
  19
  20 (define-vop (list-or-list*)
  21   (:args (things :more t))
  22   (:temporary (:sc unsigned-reg) ptr temp)
  23   (:temporary (:sc unsigned-reg :to (:result 0) :target result) res)
  24   (:info num)
  25   (:results (result :scs (descriptor-reg)))
  26   (:variant-vars star)
  27   (:policy :safe)
  28   (:node-var node)
  29   (:generator 0
  30     (cond ((zerop num)
  31            ;; (move result nil-value)
  32            (inst mov result nil-value))
  33           ((and star (= num 1))
  34            (move result (tn-ref-tn things)))
  35           (t
  36            (macrolet
  37                ((store-car (tn list &optional (slot cons-car-slot))
  38                   `(let ((reg
  39                           (sc-case ,tn
  40                             ((any-reg descriptor-reg) ,tn)
  41                             ((control-stack)
  42                              (move temp ,tn)
  43                              temp))))
  44                      (storew reg ,list ,slot list-pointer-lowtag))))
  45              (let ((cons-cells (if star (1- num) num)))
  46                (pseudo-atomic
  47                 (allocation res (* (pad-data-block cons-size) cons-cells) node
  48                             (awhen (sb!c::node-lvar node) (sb!c::lvar-dynamic-extent it)))
  49                 (inst lea res
  50                       (make-ea :byte :base res :disp list-pointer-lowtag))
  51                 (move ptr res)
  52                 (dotimes (i (1- cons-cells))
  53                   (store-car (tn-ref-tn things) ptr)
  54                   (setf things (tn-ref-across things))
  55                   (inst add ptr (pad-data-block cons-size))
  56                   (storew ptr ptr (- cons-cdr-slot cons-size)
  57                           list-pointer-lowtag))
  58                 (store-car (tn-ref-tn things) ptr)
  59                 (cond (star
  60                        (setf things (tn-ref-across things))
  61                        (store-car (tn-ref-tn things) ptr cons-cdr-slot))
  62                       (t
  63                        (storew nil-value ptr cons-cdr-slot
  64                                list-pointer-lowtag)))
  65                 (aver (null (tn-ref-across things)))))
  66              (move result res))))))
  67
  68 (define-vop (list list-or-list*)
  69   (:variant nil))
  70
  71 (define-vop (list* list-or-list*)
  72   (:variant t))
  73 \f
  74 ;;;; special-purpose inline allocators
  75 (defoptimizer (allocate-vector stack-allocate-result) ((type length words))
  76   t)
  77
  78 (define-vop (allocate-vector)
  79   (:args (type :scs (unsigned-reg))
  80          (length :scs (any-reg))
  81          (words :scs (any-reg)))
  82   (:results (result :scs (descriptor-reg) :from :load))
  83   (:arg-types positive-fixnum
  84               positive-fixnum
  85               positive-fixnum)
  86   (:translate allocate-vector)
  87   (:policy :fast-safe)
  88   (:node-var node)
  89   (:generator 100
  90     (inst lea result (make-ea :byte :base words :disp
  91                               (+ (1- (ash 1 n-lowtag-bits))
  92                                  (* vector-data-offset n-word-bytes))))
  93     (inst and result (lognot lowtag-mask))
  94     (let ((stack-allocate-p (awhen (sb!c::node-lvar node)
  95                               (sb!c::lvar-dynamic-extent it))))
  96       (maybe-pseudo-atomic stack-allocate-p
  97         ;; FIXME: It would be good to check for stack overflow here.
  98         (allocation result result node stack-allocate-p)
  99         (inst lea result (make-ea :byte :base result :disp other-pointer-lowtag))
 100         (storew type result 0 other-pointer-lowtag)
 101         (storew length result vector-length-slot other-pointer-lowtag)))))
 102
 103 (define-vop (allocate-code-object)
 104   (:args (boxed-arg :scs (any-reg) :target boxed)
 105          (unboxed-arg :scs (any-reg) :target unboxed))
 106   (:results (result :scs (descriptor-reg) :from :eval))
 107   (:temporary (:sc unsigned-reg :from (:argument 0)) boxed)
 108   (:temporary (:sc unsigned-reg :from (:argument 1)) unboxed)
 109   (:node-var node)
 110   (:generator 100
 111     (move boxed boxed-arg)
 112     (inst add boxed (fixnumize (1+ code-trace-table-offset-slot)))
 113     (inst and boxed (lognot lowtag-mask))
 114     (move unboxed unboxed-arg)
 115     (inst shr unboxed word-shift)
 116     (inst add unboxed lowtag-mask)
 117     (inst and unboxed (lognot lowtag-mask))
 118     (inst mov result boxed)
 119     (inst add result unboxed)
 120     (pseudo-atomic
 121      (allocation result result node)
 122      (inst lea result (make-ea :byte :base result :disp other-pointer-lowtag))
 123      (inst shl boxed (- n-widetag-bits word-shift))
 124      (inst or boxed code-header-widetag)
 125      (storew boxed result 0 other-pointer-lowtag)
 126      (storew unboxed result code-code-size-slot other-pointer-lowtag)
 127      (storew nil-value result code-entry-points-slot other-pointer-lowtag))
 128     (storew nil-value result code-debug-info-slot other-pointer-lowtag)))
 129 \f
 130 (define-vop (make-fdefn)
 131   (:policy :fast-safe)
 132   (:translate make-fdefn)
 133   (:args (name :scs (descriptor-reg) :to :eval))
 134   (:results (result :scs (descriptor-reg) :from :argument))
 135   (:node-var node)
 136   (:generator 37
 137     (with-fixed-allocation (result fdefn-widetag fdefn-size node)
 138       (storew name result fdefn-name-slot other-pointer-lowtag)
 139       (storew nil-value result fdefn-fun-slot other-pointer-lowtag)
 140       (storew (make-fixup "undefined_tramp" :foreign)
 141               result fdefn-raw-addr-slot other-pointer-lowtag))))
 142
 143 (define-vop (make-closure)
 144   (:args (function :to :save :scs (descriptor-reg)))
 145   (:info length stack-allocate-p)
 146   (:temporary (:sc any-reg) temp)
 147   (:results (result :scs (descriptor-reg)))
 148   (:node-var node)
 149   (:generator 10
 150    (maybe-pseudo-atomic stack-allocate-p
 151      (let ((size (+ length closure-info-offset)))
 152        (allocation result (pad-data-block size) node
 153                    stack-allocate-p)
 154        (inst lea result
 155              (make-ea :byte :base result :disp fun-pointer-lowtag))
 156        (storew (logior (ash (1- size) n-widetag-bits) closure-header-widetag)
 157                result 0 fun-pointer-lowtag))
 158     (loadw temp function closure-fun-slot fun-pointer-lowtag)
 159     (storew temp result closure-fun-slot fun-pointer-lowtag))))
 160
 161 ;;; The compiler likes to be able to directly make value cells.
 162 (define-vop (make-value-cell)
 163   (:args (value :scs (descriptor-reg any-reg) :to :result))
 164   (:results (result :scs (descriptor-reg) :from :eval))
 165   (:node-var node)
 166   (:generator 10
 167     (with-fixed-allocation
 168         (result value-cell-header-widetag value-cell-size node))
 169     (storew value result value-cell-value-slot other-pointer-lowtag)))
 170 \f
 171 ;;;; automatic allocators for primitive objects
 172
 173 (define-vop (make-unbound-marker)
 174   (:args)
 175   (:results (result :scs (any-reg)))
 176   (:generator 1
 177     (inst mov result unbound-marker-widetag)))
 178
 179 (define-vop (fixed-alloc)
 180   (:args)
 181   (:info name words type lowtag)
 182   (:ignore name)
 183   (:results (result :scs (descriptor-reg)))
 184   (:node-var node)
 185   (:generator 50
 186     (pseudo-atomic
 187      (allocation result (pad-data-block words) node)
 188      (inst lea result (make-ea :byte :base result :disp lowtag))
 189      (when type
 190        (storew (logior (ash (1- words) n-widetag-bits) type)
 191                result
 192                0
 193                lowtag)))))
 194
 195 (define-vop (var-alloc)
 196   (:args (extra :scs (any-reg)))
 197   (:arg-types positive-fixnum)
 198   (:info name words type lowtag)
 199   (:ignore name)
 200   (:results (result :scs (descriptor-reg) :from (:eval 1)))
 201   (:temporary (:sc any-reg :from :eval :to (:eval 1)) bytes)
 202   (:temporary (:sc any-reg :from :eval :to :result) header)
 203   (:node-var node)
 204   (:generator 50
 205     (inst lea bytes
 206           (make-ea :dword :base extra :disp (* (1+ words) n-word-bytes)))
 207     (inst mov header bytes)
 208     (inst shl header (- n-widetag-bits 2)) ; w+1 to length field
 209     (inst lea header                    ; (w-1 << 8) | type
 210           (make-ea :dword :base header :disp (+ (ash -2 n-widetag-bits) type)))
 211     (inst and bytes (lognot lowtag-mask))
 212     (pseudo-atomic
 213      (allocation result bytes node)
 214      (inst lea result (make-ea :byte :base result :disp lowtag))
 215      (storew header result 0 lowtag))))
 216
 217