src/compiler/x86/alloc.lisp

   1 ;;;; allocation VOPs for the x86
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!VM")
  13 \f
  14 ;;;; CONS, LIST and LIST*
  15 (define-vop (list-or-list*)
  16   (:args (things :more t))
  17   (:temporary (:sc unsigned-reg) ptr temp)
  18   (:temporary (:sc unsigned-reg :to (:result 0) :target result) res)
  19   (:info num)
  20   (:results (result :scs (descriptor-reg)))
  21   (:variant-vars star)
  22   (:policy :safe)
  23   (:node-var node)
  24   (:generator 0
  25     (cond ((zerop num)
  26            ;; (move result nil-value)
  27            (inst mov result nil-value))
  28           ((and star (= num 1))
  29            (move result (tn-ref-tn things)))
  30           (t
  31            (macrolet
  32                ((store-car (tn list &optional (slot cons-car-slot))
  33                   `(let ((reg
  34                           (sc-case ,tn
  35                             ((any-reg descriptor-reg) ,tn)
  36                             ((control-stack)
  37                              (move temp ,tn)
  38                              temp))))
  39                      (storew reg ,list ,slot list-pointer-lowtag))))
  40              (let ((cons-cells (if star (1- num) num))
  41                    (stack-allocate-p (awhen (sb!c::node-lvar node)
  42                                        (sb!c::lvar-dynamic-extent it))))
  43                (maybe-pseudo-atomic stack-allocate-p
  44                 (allocation res (* (pad-data-block cons-size) cons-cells) node
  45                             stack-allocate-p list-pointer-lowtag)
  46                 (move ptr res)
  47                 (dotimes (i (1- cons-cells))
  48                   (store-car (tn-ref-tn things) ptr)
  49                   (setf things (tn-ref-across things))
  50                   (inst add ptr (pad-data-block cons-size))
  51                   (storew ptr ptr (- cons-cdr-slot cons-size)
  52                           list-pointer-lowtag))
  53                 (store-car (tn-ref-tn things) ptr)
  54                 (cond (star
  55                        (setf things (tn-ref-across things))
  56                        (store-car (tn-ref-tn things) ptr cons-cdr-slot))
  57                       (t
  58                        (storew nil-value ptr cons-cdr-slot
  59                                list-pointer-lowtag)))
  60                 (aver (null (tn-ref-across things)))))
  61              (move result res))))))
  62
  63 (define-vop (list list-or-list*)
  64   (:variant nil))
  65
  66 (define-vop (list* list-or-list*)
  67   (:variant t))
  68 \f
  69 ;;;; special-purpose inline allocators
  70
  71 ;;; ALLOCATE-VECTOR
  72 (define-vop (allocate-vector-on-heap)
  73   (:args (type :scs (unsigned-reg immediate))
  74          (length :scs (any-reg immediate))
  75          (words :scs (any-reg immediate)))
  76   (:results (result :scs (descriptor-reg) :from :load))
  77   (:arg-types positive-fixnum
  78               positive-fixnum
  79               positive-fixnum)
  80   (:policy :fast-safe)
  81   (:generator 100
  82     (let ((size (sc-case words
  83                   (immediate
  84                    (logandc2 (+ (fixnumize (tn-value words))
  85                                 (+ (1- (ash 1 n-lowtag-bits))
  86                                    (* vector-data-offset n-word-bytes)))
  87                              lowtag-mask))
  88                   (t
  89                    (inst lea result (make-ea :byte :base words :disp
  90                                              (+ (1- (ash 1 n-lowtag-bits))
  91                                                 (* vector-data-offset
  92                                                    n-word-bytes))))
  93                    (inst and result (lognot lowtag-mask))
  94                    result))))
  95       (pseudo-atomic
  96        (allocation result size)
  97        (inst lea result (make-ea :byte :base result :disp other-pointer-lowtag))
  98        (sc-case type
  99          (immediate
 100           (aver (typep (tn-value type) '(unsigned-byte 8)))
 101           (storeb (tn-value type) result 0 other-pointer-lowtag))
 102          (t
 103           (storew type result 0 other-pointer-lowtag)))
 104        (sc-case length
 105          (immediate
 106           (let ((fixnum-length (fixnumize (tn-value length))))
 107             (typecase fixnum-length
 108               ((unsigned-byte 8)
 109                (storeb fixnum-length result
 110                        vector-length-slot other-pointer-lowtag))
 111               (t
 112                (storew fixnum-length result
 113                        vector-length-slot other-pointer-lowtag)))))
 114          (t
 115           (storew length result vector-length-slot other-pointer-lowtag)))))))
 116
 117 (define-vop (allocate-vector-on-stack)
 118   (:args (type :scs (unsigned-reg immediate))
 119          (length :scs (any-reg))
 120          (words :scs (any-reg) :target ecx))
 121   (:temporary (:sc any-reg :offset ecx-offset :from (:argument 2)) ecx)
 122   (:temporary (:sc any-reg :offset eax-offset :from (:argument 2)) zero)
 123   (:temporary (:sc any-reg :offset edi-offset :from (:argument 0)) res)
 124   (:results (result :scs (descriptor-reg) :from :load))
 125   (:arg-types positive-fixnum
 126               positive-fixnum
 127               positive-fixnum)
 128   (:translate allocate-vector)
 129   (:policy :fast-safe)
 130   (:node-var node)
 131   (:generator 100
 132     (inst lea result (make-ea :byte :base words :disp
 133                               (+ (1- (ash 1 n-lowtag-bits))
 134                                  (* vector-data-offset n-word-bytes))))
 135     (inst and result (lognot lowtag-mask))
 136     ;; FIXME: It would be good to check for stack overflow here.
 137     (move ecx words)
 138     (inst shr ecx n-fixnum-tag-bits)
 139     (allocation result result node t other-pointer-lowtag)
 140     (inst cld)
 141     (inst lea res
 142           (make-ea :byte :base result :disp (- (* vector-data-offset n-word-bytes)
 143                                                other-pointer-lowtag)))
 144     (sc-case type
 145       (immediate
 146        (aver (typep (tn-value type) '(unsigned-byte 8)))
 147        (storeb (tn-value type) result 0 other-pointer-lowtag))
 148       (t
 149        (storew type result 0 other-pointer-lowtag)))
 150     (storew length result vector-length-slot other-pointer-lowtag)
 151     (inst xor zero zero)
 152     (inst rep)
 153     (inst stos zero)))
 154
 155 ;;;
 156 (define-vop (allocate-code-object)
 157   (:args (boxed-arg :scs (any-reg) :target boxed)
 158          (unboxed-arg :scs (any-reg) :target unboxed))
 159   (:results (result :scs (descriptor-reg) :from :eval))
 160   (:temporary (:sc unsigned-reg :from (:argument 0)) boxed)
 161   (:temporary (:sc unsigned-reg :from (:argument 1)) unboxed)
 162   (:node-var node)
 163   (:generator 100
 164     (move boxed boxed-arg)
 165     (inst add boxed (fixnumize (1+ code-trace-table-offset-slot)))
 166     (inst and boxed (lognot lowtag-mask))
 167     (move unboxed unboxed-arg)
 168     (inst shr unboxed word-shift)
 169     (inst add unboxed lowtag-mask)
 170     (inst and unboxed (lognot lowtag-mask))
 171     (inst mov result boxed)
 172     (inst add result unboxed)
 173     (pseudo-atomic
 174      (allocation result result node)
 175      (inst lea result (make-ea :byte :base result :disp other-pointer-lowtag))
 176      (inst shl boxed (- n-widetag-bits word-shift))
 177      (inst or boxed code-header-widetag)
 178      (storew boxed result 0 other-pointer-lowtag)
 179      (storew unboxed result code-code-size-slot other-pointer-lowtag)
 180      (storew nil-value result code-entry-points-slot other-pointer-lowtag))
 181     (storew nil-value result code-debug-info-slot other-pointer-lowtag)))
 182 \f
 183 (define-vop (make-fdefn)
 184   (:policy :fast-safe)
 185   (:translate make-fdefn)
 186   (:args (name :scs (descriptor-reg) :to :eval))
 187   (:results (result :scs (descriptor-reg) :from :argument))
 188   (:node-var node)
 189   (:generator 37
 190     (with-fixed-allocation (result fdefn-widetag fdefn-size node)
 191       (storew name result fdefn-name-slot other-pointer-lowtag)
 192       (storew nil-value result fdefn-fun-slot other-pointer-lowtag)
 193       (storew (make-fixup "undefined_tramp" :foreign)
 194               result fdefn-raw-addr-slot other-pointer-lowtag))))
 195
 196 (define-vop (make-closure)
 197   (:args (function :to :save :scs (descriptor-reg)))
 198   (:info length stack-allocate-p)
 199   (:temporary (:sc any-reg) temp)
 200   (:results (result :scs (descriptor-reg)))
 201   (:node-var node)
 202   (:generator 10
 203    (maybe-pseudo-atomic stack-allocate-p
 204      (let ((size (+ length closure-info-offset)))
 205        (allocation result (pad-data-block size) node
 206                    stack-allocate-p
 207                    fun-pointer-lowtag)
 208        (storew (logior (ash (1- size) n-widetag-bits) closure-header-widetag)
 209                result 0 fun-pointer-lowtag))
 210     (loadw temp function closure-fun-slot fun-pointer-lowtag)
 211     (storew temp result closure-fun-slot fun-pointer-lowtag))))
 212
 213 ;;; The compiler likes to be able to directly make value cells.
 214 (define-vop (make-value-cell)
 215   (:args (value :scs (descriptor-reg any-reg) :to :result))
 216   (:results (result :scs (descriptor-reg) :from :eval))
 217   (:info stack-allocate-p)
 218   (:node-var node)
 219   (:generator 10
 220     (with-fixed-allocation
 221         (result value-cell-header-widetag value-cell-size node stack-allocate-p)
 222       (storew value result value-cell-value-slot other-pointer-lowtag))))
 223 \f
 224 ;;;; automatic allocators for primitive objects
 225
 226 (define-vop (make-unbound-marker)
 227   (:args)
 228   (:results (result :scs (any-reg)))
 229   (:generator 1
 230     (inst mov result unbound-marker-widetag)))
 231
 232 (define-vop (make-funcallable-instance-tramp)
 233   (:args)
 234   (:results (result :scs (any-reg)))
 235   (:generator 1
 236     (inst lea result (make-fixup "funcallable_instance_tramp" :foreign))))
 237
 238 (define-vop (fixed-alloc)
 239   (:args)
 240   (:info name words type lowtag stack-allocate-p)
 241   (:ignore name)
 242   (:results (result :scs (descriptor-reg)))
 243   (:node-var node)
 244   (:generator 50
 245     ;; We special case the allocation of conses, because they're
 246     ;; extremely common and because the pseudo-atomic sequence on x86
 247     ;; is relatively heavyweight.  However, if the user asks for top
 248     ;; speed, we accomodate him.  The primary reason that we don't
 249     ;; also check for (< SPEED SPACE) is because we want the space
 250     ;; savings that these out-of-line allocation routines bring whilst
 251     ;; compiling SBCL itself.  --njf, 2006-07-08
 252     (if (and (not stack-allocate-p)
 253              (= lowtag list-pointer-lowtag) (policy node (< speed 3)))
 254         (let ((dst
 255                ;; FIXME: out-of-line dx-allocation
 256                #.(loop for offset in *dword-regs*
 257                     collect `(,offset
 258                               ',(intern (format nil "ALLOCATE-CONS-TO-~A"
 259                                                 (svref *dword-register-names*
 260                                                        offset)))) into cases
 261                     finally (return `(case (tn-offset result)
 262                                        ,@cases)))))
 263           (aver (null type))
 264           (inst call (make-fixup dst :assembly-routine)))
 265         (maybe-pseudo-atomic stack-allocate-p
 266          (allocation result (pad-data-block words) node stack-allocate-p lowtag)
 267          (when type
 268            (storew (logior (ash (1- words) n-widetag-bits) type)
 269                    result
 270                    0
 271                    lowtag))))))
 272
 273 (define-vop (var-alloc)
 274   (:args (extra :scs (any-reg)))
 275   (:arg-types positive-fixnum)
 276   (:info name words type lowtag)
 277   (:ignore name)
 278   (:results (result :scs (descriptor-reg) :from (:eval 1)))
 279   (:temporary (:sc any-reg :from :eval :to (:eval 1)) bytes)
 280   (:temporary (:sc any-reg :from :eval :to :result) header)
 281   (:node-var node)
 282   (:generator 50
 283     (inst lea bytes
 284           (make-ea :dword :base extra :disp (* (1+ words) n-word-bytes)))
 285     (inst mov header bytes)
 286     (inst shl header (- n-widetag-bits 2)) ; w+1 to length field
 287     (inst lea header                    ; (w-1 << 8) | type
 288           (make-ea :dword :base header :disp (+ (ash -2 n-widetag-bits) type)))
 289     (inst and bytes (lognot lowtag-mask))
 290     (pseudo-atomic
 291      (allocation result bytes node)
 292      (inst lea result (make-ea :byte :base result :disp lowtag))
 293      (storew header result 0 lowtag))))