src/compiler/x86/alloc.lisp

   1 ;;;; allocation VOPs for the x86
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!VM")
  13 \f
  14 ;;;; LIST and LIST*
  15 (defoptimizer (list stack-allocate-result) ((&rest args))
  16   (not (null args)))
  17 (defoptimizer (list* stack-allocate-result) ((&rest args))
  18   (not (null (rest args))))
  19
  20 (define-vop (list-or-list*)
  21   (:args (things :more t))
  22   (:temporary (:sc unsigned-reg) ptr temp)
  23   (:temporary (:sc unsigned-reg :to (:result 0) :target result) res)
  24   (:info num)
  25   (:results (result :scs (descriptor-reg)))
  26   (:variant-vars star)
  27   (:policy :safe)
  28   (:node-var node)
  29   (:generator 0
  30     (cond ((zerop num)
  31            ;; (move result nil-value)
  32            (inst mov result nil-value))
  33           ((and star (= num 1))
  34            (move result (tn-ref-tn things)))
  35           (t
  36            (macrolet
  37                ((store-car (tn list &optional (slot cons-car-slot))
  38                   `(let ((reg
  39                           (sc-case ,tn
  40                             ((any-reg descriptor-reg) ,tn)
  41                             ((control-stack)
  42                              (move temp ,tn)
  43                              temp))))
  44                      (storew reg ,list ,slot list-pointer-lowtag))))
  45              (let ((cons-cells (if star (1- num) num)))
  46                (pseudo-atomic
  47                 (allocation res (* (pad-data-block cons-size) cons-cells) node
  48                             (awhen (sb!c::node-lvar node) (sb!c::lvar-dynamic-extent it)))
  49                 (inst lea res
  50                       (make-ea :byte :base res :disp list-pointer-lowtag))
  51                 (move ptr res)
  52                 (dotimes (i (1- cons-cells))
  53                   (store-car (tn-ref-tn things) ptr)
  54                   (setf things (tn-ref-across things))
  55                   (inst add ptr (pad-data-block cons-size))
  56                   (storew ptr ptr (- cons-cdr-slot cons-size)
  57                           list-pointer-lowtag))
  58                 (store-car (tn-ref-tn things) ptr)
  59                 (cond (star
  60                        (setf things (tn-ref-across things))
  61                        (store-car (tn-ref-tn things) ptr cons-cdr-slot))
  62                       (t
  63                        (storew nil-value ptr cons-cdr-slot
  64                                list-pointer-lowtag)))
  65                 (aver (null (tn-ref-across things)))))
  66              (move result res))))))
  67
  68 (define-vop (list list-or-list*)
  69   (:variant nil))
  70
  71 (define-vop (list* list-or-list*)
  72   (:variant t))
  73 \f
  74 ;;;; special-purpose inline allocators
  75
  76 ;;; ALLOCATE-VECTOR
  77 (define-vop (allocate-vector-on-heap)
  78   (:args (type :scs (unsigned-reg immediate))
  79          (length :scs (any-reg immediate))
  80          (words :scs (any-reg immediate)))
  81   (:results (result :scs (descriptor-reg) :from :load))
  82   (:arg-types positive-fixnum
  83               positive-fixnum
  84               positive-fixnum)
  85   (:policy :fast-safe)
  86   (:generator 100
  87     (let ((size (sc-case words
  88                   (immediate
  89                    (logandc2 (+ (fixnumize (tn-value words))
  90                                 (+ (1- (ash 1 n-lowtag-bits))
  91                                    (* vector-data-offset n-word-bytes)))
  92                              lowtag-mask))
  93                   (t
  94                    (inst lea result (make-ea :byte :base words :disp
  95                                              (+ (1- (ash 1 n-lowtag-bits))
  96                                                 (* vector-data-offset
  97                                                    n-word-bytes))))
  98                    (inst and result (lognot lowtag-mask))
  99                    result))))
 100       (pseudo-atomic
 101        (allocation result size)
 102        (inst lea result (make-ea :byte :base result :disp other-pointer-lowtag))
 103        (sc-case type
 104          (immediate
 105           (aver (typep (tn-value type) '(unsigned-byte 8)))
 106           (storeb (tn-value type) result 0 other-pointer-lowtag))
 107          (t
 108           (storew type result 0 other-pointer-lowtag)))
 109        (sc-case length
 110          (immediate
 111           (let ((fixnum-length (fixnumize (tn-value length))))
 112             (typecase fixnum-length
 113               ((unsigned-byte 8)
 114                (storeb fixnum-length result
 115                        vector-length-slot other-pointer-lowtag))
 116               (t
 117                (storew fixnum-length result
 118                        vector-length-slot other-pointer-lowtag)))))
 119          (t
 120           (storew length result vector-length-slot other-pointer-lowtag)))))))
 121
 122 (define-vop (allocate-vector-on-stack)
 123   (:args (type :scs (unsigned-reg immediate))
 124          (length :scs (any-reg))
 125          (words :scs (any-reg) :target ecx))
 126   (:temporary (:sc any-reg :offset ecx-offset :from (:argument 2)) ecx)
 127   (:temporary (:sc any-reg :offset eax-offset :from (:argument 2)) zero)
 128   (:temporary (:sc any-reg :offset edi-offset :from (:argument 0)) res)
 129   (:results (result :scs (descriptor-reg) :from :load))
 130   (:arg-types positive-fixnum
 131               positive-fixnum
 132               positive-fixnum)
 133   (:translate allocate-vector)
 134   (:policy :fast-safe)
 135   (:node-var node)
 136   (:generator 100
 137     (let ((unboxed-elements-p (and (sc-is type immediate)
 138                                    (/= (tn-value type)
 139                                        simple-vector-widetag))))
 140       (inst lea result (make-ea :byte :base words :disp
 141                                 (+ (1- (ash 1 n-lowtag-bits))
 142                                    (* vector-data-offset n-word-bytes))))
 143       (inst and result (lognot lowtag-mask))
 144       ;; FIXME: It would be good to check for stack overflow here.
 145       (move ecx words)
 146       (inst shr ecx n-fixnum-tag-bits)
 147       (allocation result result node t)
 148       (unless unboxed-elements-p
 149         (inst cld))
 150       (inst lea res
 151             (make-ea :byte :base result :disp (* vector-data-offset n-word-bytes)))
 152       (inst lea result (make-ea :byte :base result :disp other-pointer-lowtag))
 153       (sc-case type
 154         (immediate
 155          (aver (typep (tn-value type) '(unsigned-byte 8)))
 156          (storeb (tn-value type) result 0 other-pointer-lowtag))
 157         (t
 158          (storew type result 0 other-pointer-lowtag)))
 159       (storew length result vector-length-slot other-pointer-lowtag)
 160       (unless unboxed-elements-p
 161         (inst xor zero zero)
 162         (inst rep)
 163         (inst stos zero)))))
 164
 165 (in-package "SB!C")
 166
 167 (defoptimizer (allocate-vector stack-allocate-result)
 168     ((type length words) node)
 169   (ecase (policy node stack-allocate-vector)
 170     (0 nil)
 171     ((1 2)
 172      ;; a vector object should fit in one page
 173      (values-subtypep (lvar-derived-type words)
 174                       (load-time-value
 175                        (specifier-type `(integer 0 ,(- (/ sb!vm::*backend-page-size*
 176                                                           sb!vm:n-word-bytes)
 177                                                        sb!vm:vector-data-offset))))))
 178     (3 t)))
 179
 180 (defoptimizer (allocate-vector ltn-annotate) ((type length words) call ltn-policy)
 181   (let ((args (basic-combination-args call))
 182         (template (template-or-lose (if (awhen (node-lvar call)
 183                                           (lvar-dynamic-extent it))
 184                                         'sb!vm::allocate-vector-on-stack
 185                                         'sb!vm::allocate-vector-on-heap))))
 186     (dolist (arg args)
 187       (setf (lvar-info arg)
 188             (make-ir2-lvar (primitive-type (lvar-type arg)))))
 189     (unless (is-ok-template-use template call (ltn-policy-safe-p ltn-policy))
 190       (ltn-default-call call)
 191       (return-from allocate-vector-ltn-annotate-optimizer (values)))
 192     (setf (basic-combination-info call) template)
 193     (setf (node-tail-p call) nil)
 194
 195     (dolist (arg args)
 196       (annotate-1-value-lvar arg))))
 197
 198 (in-package "SB!VM")
 199
 200 ;;;
 201 (define-vop (allocate-code-object)
 202   (:args (boxed-arg :scs (any-reg) :target boxed)
 203          (unboxed-arg :scs (any-reg) :target unboxed))
 204   (:results (result :scs (descriptor-reg) :from :eval))
 205   (:temporary (:sc unsigned-reg :from (:argument 0)) boxed)
 206   (:temporary (:sc unsigned-reg :from (:argument 1)) unboxed)
 207   (:node-var node)
 208   (:generator 100
 209     (move boxed boxed-arg)
 210     (inst add boxed (fixnumize (1+ code-trace-table-offset-slot)))
 211     (inst and boxed (lognot lowtag-mask))
 212     (move unboxed unboxed-arg)
 213     (inst shr unboxed word-shift)
 214     (inst add unboxed lowtag-mask)
 215     (inst and unboxed (lognot lowtag-mask))
 216     (inst mov result boxed)
 217     (inst add result unboxed)
 218     (pseudo-atomic
 219      (allocation result result node)
 220      (inst lea result (make-ea :byte :base result :disp other-pointer-lowtag))
 221      (inst shl boxed (- n-widetag-bits word-shift))
 222      (inst or boxed code-header-widetag)
 223      (storew boxed result 0 other-pointer-lowtag)
 224      (storew unboxed result code-code-size-slot other-pointer-lowtag)
 225      (storew nil-value result code-entry-points-slot other-pointer-lowtag))
 226     (storew nil-value result code-debug-info-slot other-pointer-lowtag)))
 227 \f
 228 (define-vop (make-fdefn)
 229   (:policy :fast-safe)
 230   (:translate make-fdefn)
 231   (:args (name :scs (descriptor-reg) :to :eval))
 232   (:results (result :scs (descriptor-reg) :from :argument))
 233   (:node-var node)
 234   (:generator 37
 235     (with-fixed-allocation (result fdefn-widetag fdefn-size node)
 236       (storew name result fdefn-name-slot other-pointer-lowtag)
 237       (storew nil-value result fdefn-fun-slot other-pointer-lowtag)
 238       (storew (make-fixup "undefined_tramp" :foreign)
 239               result fdefn-raw-addr-slot other-pointer-lowtag))))
 240
 241 (define-vop (make-closure)
 242   (:args (function :to :save :scs (descriptor-reg)))
 243   (:info length stack-allocate-p)
 244   (:temporary (:sc any-reg) temp)
 245   (:results (result :scs (descriptor-reg)))
 246   (:node-var node)
 247   (:generator 10
 248    (maybe-pseudo-atomic stack-allocate-p
 249      (let ((size (+ length closure-info-offset)))
 250        (allocation result (pad-data-block size) node
 251                    stack-allocate-p)
 252        (inst lea result
 253              (make-ea :byte :base result :disp fun-pointer-lowtag))
 254        (storew (logior (ash (1- size) n-widetag-bits) closure-header-widetag)
 255                result 0 fun-pointer-lowtag))
 256     (loadw temp function closure-fun-slot fun-pointer-lowtag)
 257     (storew temp result closure-fun-slot fun-pointer-lowtag))))
 258
 259 ;;; The compiler likes to be able to directly make value cells.
 260 (define-vop (make-value-cell)
 261   (:args (value :scs (descriptor-reg any-reg) :to :result))
 262   (:results (result :scs (descriptor-reg) :from :eval))
 263   (:node-var node)
 264   (:generator 10
 265     (with-fixed-allocation
 266         (result value-cell-header-widetag value-cell-size node)
 267       (storew value result value-cell-value-slot other-pointer-lowtag))))
 268 \f
 269 ;;;; automatic allocators for primitive objects
 270
 271 (define-vop (make-unbound-marker)
 272   (:args)
 273   (:results (result :scs (any-reg)))
 274   (:generator 1
 275     (inst mov result unbound-marker-widetag)))
 276
 277 (define-vop (make-funcallable-instance-tramp)
 278   (:args)
 279   (:results (result :scs (any-reg)))
 280   (:generator 1
 281     (inst lea result (make-fixup "funcallable_instance_tramp" :foreign))))
 282
 283 (define-vop (fixed-alloc)
 284   (:args)
 285   (:info name words type lowtag)
 286   (:ignore name)
 287   (:results (result :scs (descriptor-reg)))
 288   (:node-var node)
 289   (:generator 50
 290     ;; We special case the allocation of conses, because they're
 291     ;; extremely common and because the pseudo-atomic sequence on x86
 292     ;; is relatively heavyweight.  However, if the user asks for top
 293     ;; speed, we accomodate him.  The primary reason that we don't
 294     ;; also check for (< SPEED SPACE) is because we want the space
 295     ;; savings that these out-of-line allocation routines bring whilst
 296     ;; compiling SBCL itself.  --njf, 2006-07-08
 297     (if (and (= lowtag list-pointer-lowtag) (policy node (< speed 3)))
 298         (let ((dst
 299                #.(loop for offset in *dword-regs*
 300                     collect `(,offset
 301                               ',(intern (format nil "ALLOCATE-CONS-TO-~A"
 302                                                 (svref *dword-register-names*
 303                                                        offset)))) into cases
 304                     finally (return `(case (tn-offset result)
 305                                        ,@cases)))))
 306           (aver (null type))
 307           (inst call (make-fixup dst :assembly-routine)))
 308         (pseudo-atomic
 309          (allocation result (pad-data-block words) node)
 310          (inst lea result (make-ea :byte :base result :disp lowtag))
 311          (when type
 312            (storew (logior (ash (1- words) n-widetag-bits) type)
 313                    result
 314                    0
 315                    lowtag))))))
 316
 317 (define-vop (var-alloc)
 318   (:args (extra :scs (any-reg)))
 319   (:arg-types positive-fixnum)
 320   (:info name words type lowtag)
 321   (:ignore name)
 322   (:results (result :scs (descriptor-reg) :from (:eval 1)))
 323   (:temporary (:sc any-reg :from :eval :to (:eval 1)) bytes)
 324   (:temporary (:sc any-reg :from :eval :to :result) header)
 325   (:node-var node)
 326   (:generator 50
 327     (inst lea bytes
 328           (make-ea :dword :base extra :disp (* (1+ words) n-word-bytes)))
 329     (inst mov header bytes)
 330     (inst shl header (- n-widetag-bits 2)) ; w+1 to length field
 331     (inst lea header                    ; (w-1 << 8) | type
 332           (make-ea :dword :base header :disp (+ (ash -2 n-widetag-bits) type)))
 333     (inst and bytes (lognot lowtag-mask))
 334     (pseudo-atomic
 335      (allocation result bytes node)
 336      (inst lea result (make-ea :byte :base result :disp lowtag))
 337      (storew header result 0 lowtag))))