src/compiler/x86/alloc.lisp

   1 ;;;; allocation VOPs for the x86
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!VM")
  13 \f
  14 ;;;; LIST and LIST*
  15 (defoptimizer (list stack-allocate-result) ((&rest args))
  16   (not (null args)))
  17 (defoptimizer (list* stack-allocate-result) ((&rest args))
  18   (not (null (rest args))))
  19
  20 (define-vop (list-or-list*)
  21   (:args (things :more t))
  22   (:temporary (:sc unsigned-reg) ptr temp)
  23   (:temporary (:sc unsigned-reg :to (:result 0) :target result) res)
  24   (:info num)
  25   (:results (result :scs (descriptor-reg)))
  26   (:variant-vars star)
  27   (:policy :safe)
  28   (:node-var node)
  29   (:generator 0
  30     (cond ((zerop num)
  31            ;; (move result nil-value)
  32            (inst mov result nil-value))
  33           ((and star (= num 1))
  34            (move result (tn-ref-tn things)))
  35           (t
  36            (macrolet
  37                ((store-car (tn list &optional (slot cons-car-slot))
  38                   `(let ((reg
  39                           (sc-case ,tn
  40                             ((any-reg descriptor-reg) ,tn)
  41                             ((control-stack)
  42                              (move temp ,tn)
  43                              temp))))
  44                      (storew reg ,list ,slot list-pointer-lowtag))))
  45              (let ((cons-cells (if star (1- num) num)))
  46                (pseudo-atomic
  47                 (allocation res (* (pad-data-block cons-size) cons-cells) node
  48                             (awhen (sb!c::node-lvar node) (sb!c::lvar-dynamic-extent it)))
  49                 (inst lea res
  50                       (make-ea :byte :base res :disp list-pointer-lowtag))
  51                 (move ptr res)
  52                 (dotimes (i (1- cons-cells))
  53                   (store-car (tn-ref-tn things) ptr)
  54                   (setf things (tn-ref-across things))
  55                   (inst add ptr (pad-data-block cons-size))
  56                   (storew ptr ptr (- cons-cdr-slot cons-size)
  57                           list-pointer-lowtag))
  58                 (store-car (tn-ref-tn things) ptr)
  59                 (cond (star
  60                        (setf things (tn-ref-across things))
  61                        (store-car (tn-ref-tn things) ptr cons-cdr-slot))
  62                       (t
  63                        (storew nil-value ptr cons-cdr-slot
  64                                list-pointer-lowtag)))
  65                 (aver (null (tn-ref-across things)))))
  66              (move result res))))))
  67
  68 (define-vop (list list-or-list*)
  69   (:variant nil))
  70
  71 (define-vop (list* list-or-list*)
  72   (:variant t))
  73 \f
  74 ;;;; special-purpose inline allocators
  75
  76 ;;; ALLOCATE-VECTOR
  77 (define-vop (allocate-vector-on-heap)
  78   (:args (type :scs (unsigned-reg))
  79          (length :scs (any-reg))
  80          (words :scs (any-reg)))
  81   (:results (result :scs (descriptor-reg) :from :load))
  82   (:arg-types positive-fixnum
  83               positive-fixnum
  84               positive-fixnum)
  85   (:policy :fast-safe)
  86   (:generator 100
  87     (inst lea result (make-ea :byte :base words :disp
  88                               (+ (1- (ash 1 n-lowtag-bits))
  89                                  (* vector-data-offset n-word-bytes))))
  90     (inst and result (lognot lowtag-mask))
  91     (pseudo-atomic
  92       (allocation result result)
  93       (inst lea result (make-ea :byte :base result :disp other-pointer-lowtag))
  94       (storew type result 0 other-pointer-lowtag)
  95       (storew length result vector-length-slot other-pointer-lowtag))))
  96
  97 (define-vop (allocate-vector-on-stack)
  98   (:args (type :scs (unsigned-reg))
  99          (length :scs (any-reg))
 100          (words :scs (any-reg) :target ecx))
 101   (:temporary (:sc any-reg :offset ecx-offset :from (:argument 2)) ecx)
 102   (:temporary (:sc any-reg :offset eax-offset :from (:argument 2)) zero)
 103   (:temporary (:sc any-reg :offset edi-offset :from (:argument 0)) res)
 104   (:results (result :scs (descriptor-reg) :from :load))
 105   (:arg-types positive-fixnum
 106               positive-fixnum
 107               positive-fixnum)
 108   (:translate allocate-vector)
 109   (:policy :fast-safe)
 110   (:node-var node)
 111   (:generator 100
 112     (inst lea result (make-ea :byte :base words :disp
 113                               (+ (1- (ash 1 n-lowtag-bits))
 114                                  (* vector-data-offset n-word-bytes))))
 115     (inst and result (lognot lowtag-mask))
 116     ;; FIXME: It would be good to check for stack overflow here.
 117     (move ecx words)
 118     (inst shr ecx n-fixnum-tag-bits)
 119     (allocation result result node t)
 120     (inst cld)
 121     (inst lea res
 122           (make-ea :byte :base result :disp (* vector-data-offset n-word-bytes)))
 123     (inst lea result (make-ea :byte :base result :disp other-pointer-lowtag))
 124     (storew type result 0 other-pointer-lowtag)
 125     (storew length result vector-length-slot other-pointer-lowtag)
 126     (inst xor zero zero)
 127     (inst rep)
 128     (inst stos zero)))
 129
 130 (in-package "SB!C")
 131
 132 (defoptimizer (allocate-vector stack-allocate-result)
 133     ((type length words) node)
 134   (ecase (policy node stack-allocate-vector)
 135     (0 nil)
 136     ((1 2)
 137      ;; a vector object should fit in one page
 138      (values-subtypep (lvar-derived-type words)
 139                       (load-time-value
 140                        (specifier-type `(integer 0 ,(- (/ sb!vm::*backend-page-size*
 141                                                           sb!vm:n-word-bytes)
 142                                                        sb!vm:vector-data-offset))))))
 143     (3 t)))
 144
 145 (defoptimizer (allocate-vector ltn-annotate) ((type length words) call ltn-policy)
 146   (let ((args (basic-combination-args call))
 147         (template (template-or-lose (if (awhen (node-lvar call)
 148                                           (lvar-dynamic-extent it))
 149                                         'sb!vm::allocate-vector-on-stack
 150                                         'sb!vm::allocate-vector-on-heap))))
 151     (dolist (arg args)
 152       (setf (lvar-info arg)
 153             (make-ir2-lvar (primitive-type (lvar-type arg)))))
 154     (unless (is-ok-template-use template call (ltn-policy-safe-p ltn-policy))
 155       (ltn-default-call call)
 156       (return-from allocate-vector-ltn-annotate-optimizer (values)))
 157     (setf (basic-combination-info call) template)
 158     (setf (node-tail-p call) nil)
 159
 160     (dolist (arg args)
 161       (annotate-1-value-lvar arg))))
 162
 163 (in-package "SB!VM")
 164
 165 ;;;
 166 (define-vop (allocate-code-object)
 167   (:args (boxed-arg :scs (any-reg) :target boxed)
 168          (unboxed-arg :scs (any-reg) :target unboxed))
 169   (:results (result :scs (descriptor-reg) :from :eval))
 170   (:temporary (:sc unsigned-reg :from (:argument 0)) boxed)
 171   (:temporary (:sc unsigned-reg :from (:argument 1)) unboxed)
 172   (:node-var node)
 173   (:generator 100
 174     (move boxed boxed-arg)
 175     (inst add boxed (fixnumize (1+ code-trace-table-offset-slot)))
 176     (inst and boxed (lognot lowtag-mask))
 177     (move unboxed unboxed-arg)
 178     (inst shr unboxed word-shift)
 179     (inst add unboxed lowtag-mask)
 180     (inst and unboxed (lognot lowtag-mask))
 181     (inst mov result boxed)
 182     (inst add result unboxed)
 183     (pseudo-atomic
 184      (allocation result result node)
 185      (inst lea result (make-ea :byte :base result :disp other-pointer-lowtag))
 186      (inst shl boxed (- n-widetag-bits word-shift))
 187      (inst or boxed code-header-widetag)
 188      (storew boxed result 0 other-pointer-lowtag)
 189      (storew unboxed result code-code-size-slot other-pointer-lowtag)
 190      (storew nil-value result code-entry-points-slot other-pointer-lowtag))
 191     (storew nil-value result code-debug-info-slot other-pointer-lowtag)))
 192 \f
 193 (define-vop (make-fdefn)
 194   (:policy :fast-safe)
 195   (:translate make-fdefn)
 196   (:args (name :scs (descriptor-reg) :to :eval))
 197   (:results (result :scs (descriptor-reg) :from :argument))
 198   (:node-var node)
 199   (:generator 37
 200     (with-fixed-allocation (result fdefn-widetag fdefn-size node)
 201       (storew name result fdefn-name-slot other-pointer-lowtag)
 202       (storew nil-value result fdefn-fun-slot other-pointer-lowtag)
 203       (storew (make-fixup "undefined_tramp" :foreign)
 204               result fdefn-raw-addr-slot other-pointer-lowtag))))
 205
 206 (define-vop (make-closure)
 207   (:args (function :to :save :scs (descriptor-reg)))
 208   (:info length stack-allocate-p)
 209   (:temporary (:sc any-reg) temp)
 210   (:results (result :scs (descriptor-reg)))
 211   (:node-var node)
 212   (:generator 10
 213    (maybe-pseudo-atomic stack-allocate-p
 214      (let ((size (+ length closure-info-offset)))
 215        (allocation result (pad-data-block size) node
 216                    stack-allocate-p)
 217        (inst lea result
 218              (make-ea :byte :base result :disp fun-pointer-lowtag))
 219        (storew (logior (ash (1- size) n-widetag-bits) closure-header-widetag)
 220                result 0 fun-pointer-lowtag))
 221     (storew result result closure-self-slot fun-pointer-lowtag)
 222     (loadw temp function closure-fun-slot fun-pointer-lowtag)
 223     (storew temp result closure-fun-slot fun-pointer-lowtag))))
 224
 225 ;;; The compiler likes to be able to directly make value cells.
 226 (define-vop (make-value-cell)
 227   (:args (value :scs (descriptor-reg any-reg) :to :result))
 228   (:results (result :scs (descriptor-reg) :from :eval))
 229   (:node-var node)
 230   (:generator 10
 231     (with-fixed-allocation
 232         (result value-cell-header-widetag value-cell-size node)
 233       (storew value result value-cell-value-slot other-pointer-lowtag))))
 234 \f
 235 ;;;; automatic allocators for primitive objects
 236
 237 (define-vop (make-unbound-marker)
 238   (:args)
 239   (:results (result :scs (any-reg)))
 240   (:generator 1
 241     (inst mov result unbound-marker-widetag)))
 242
 243 (define-vop (fixed-alloc)
 244   (:args)
 245   (:info name words type lowtag)
 246   (:ignore name)
 247   (:results (result :scs (descriptor-reg)))
 248   (:node-var node)
 249   (:generator 50
 250     ;; We special case the allocation of conses, because they're
 251     ;; extremely common and because the pseudo-atomic sequence on x86
 252     ;; is relatively heavyweight.  However, if the user asks for top
 253     ;; speed, we accomodate him.  The primary reason that we don't
 254     ;; also check for (< SPEED SPACE) is because we want the space
 255     ;; savings that these out-of-line allocation routines bring whilst
 256     ;; compiling SBCL itself.  --njf, 2006-07-08
 257     (if (and (= lowtag list-pointer-lowtag) (policy node (< speed 3)))
 258         (let ((dst
 259                #.(loop for offset in *dword-regs*
 260                     collect `(,offset
 261                               ',(intern (format nil "ALLOCATE-CONS-TO-~A"
 262                                                 (svref *dword-register-names*
 263                                                        offset)))) into cases
 264                     finally (return `(case (tn-offset result)
 265                                        ,@cases)))))
 266           (aver (null type))
 267           (inst call (make-fixup dst :assembly-routine)))
 268         (pseudo-atomic
 269          (allocation result (pad-data-block words) node)
 270          (inst lea result (make-ea :byte :base result :disp lowtag))
 271          (when type
 272            (storew (logior (ash (1- words) n-widetag-bits) type)
 273                    result
 274                    0
 275                    lowtag))))))
 276
 277 (define-vop (var-alloc)
 278   (:args (extra :scs (any-reg)))
 279   (:arg-types positive-fixnum)
 280   (:info name words type lowtag)
 281   (:ignore name)
 282   (:results (result :scs (descriptor-reg) :from (:eval 1)))
 283   (:temporary (:sc any-reg :from :eval :to (:eval 1)) bytes)
 284   (:temporary (:sc any-reg :from :eval :to :result) header)
 285   (:node-var node)
 286   (:generator 50
 287     (inst lea bytes
 288           (make-ea :dword :base extra :disp (* (1+ words) n-word-bytes)))
 289     (inst mov header bytes)
 290     (inst shl header (- n-widetag-bits 2)) ; w+1 to length field
 291     (inst lea header                    ; (w-1 << 8) | type
 292           (make-ea :dword :base header :disp (+ (ash -2 n-widetag-bits) type)))
 293     (inst and bytes (lognot lowtag-mask))
 294     (pseudo-atomic
 295      (allocation result bytes node)
 296      (inst lea result (make-ea :byte :base result :disp lowtag))
 297      (storew header result 0 lowtag))))