src/compiler/x86/c-call.lisp

   1 ;;;; the VOPs and other necessary machine specific support
   2 ;;;; routines for call-out to C
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!VM")
  14
  15 ;; The MOVE-ARG vop is going to store args on the stack for
  16 ;; call-out. These tn's will be used for that. move-arg is normally
  17 ;; used for things going down the stack but C wants to have args
  18 ;; indexed in the positive direction.
  19
  20 (defun my-make-wired-tn (prim-type-name sc-name offset)
  21   (make-wired-tn (primitive-type-or-lose prim-type-name)
  22                  (sc-number-or-lose sc-name)
  23                  offset))
  24
  25 (defstruct (arg-state (:copier nil))
  26   (stack-frame-size 0))
  27
  28 (define-alien-type-method (integer :arg-tn) (type state)
  29   (let ((stack-frame-size (arg-state-stack-frame-size state)))
  30     (setf (arg-state-stack-frame-size state) (1+ stack-frame-size))
  31     (multiple-value-bind (ptype stack-sc)
  32         (if (alien-integer-type-signed type)
  33             (values 'signed-byte-32 'signed-stack)
  34             (values 'unsigned-byte-32 'unsigned-stack))
  35       (my-make-wired-tn ptype stack-sc stack-frame-size))))
  36
  37 (define-alien-type-method (system-area-pointer :arg-tn) (type state)
  38   (declare (ignore type))
  39   (let ((stack-frame-size (arg-state-stack-frame-size state)))
  40     (setf (arg-state-stack-frame-size state) (1+ stack-frame-size))
  41     (my-make-wired-tn 'system-area-pointer
  42                       'sap-stack
  43                       stack-frame-size)))
  44
  45 #!+long-float
  46 (define-alien-type-method (long-float :arg-tn) (type state)
  47   (declare (ignore type))
  48   (let ((stack-frame-size (arg-state-stack-frame-size state)))
  49     (setf (arg-state-stack-frame-size state) (+ stack-frame-size 3))
  50     (my-make-wired-tn 'long-float 'long-stack stack-frame-size)))
  51
  52 (define-alien-type-method (double-float :arg-tn) (type state)
  53   (declare (ignore type))
  54   (let ((stack-frame-size (arg-state-stack-frame-size state)))
  55     (setf (arg-state-stack-frame-size state) (+ stack-frame-size 2))
  56     (my-make-wired-tn 'double-float 'double-stack stack-frame-size)))
  57
  58 (define-alien-type-method (single-float :arg-tn) (type state)
  59   (declare (ignore type))
  60   (let ((stack-frame-size (arg-state-stack-frame-size state)))
  61     (setf (arg-state-stack-frame-size state) (1+ stack-frame-size))
  62     (my-make-wired-tn 'single-float 'single-stack stack-frame-size)))
  63
  64 (defstruct (result-state (:copier nil))
  65   (num-results 0))
  66
  67 (defun result-reg-offset (slot)
  68   (ecase slot
  69     (0 eax-offset)
  70     (1 edx-offset)))
  71
  72 (define-alien-type-method (integer :result-tn) (type state)
  73   (let ((num-results (result-state-num-results state)))
  74     (setf (result-state-num-results state) (1+ num-results))
  75     (multiple-value-bind (ptype reg-sc)
  76         (if (alien-integer-type-signed type)
  77             (values 'signed-byte-32 'signed-reg)
  78             (values 'unsigned-byte-32 'unsigned-reg))
  79       (my-make-wired-tn ptype reg-sc (result-reg-offset num-results)))))
  80
  81 (define-alien-type-method (system-area-pointer :result-tn) (type state)
  82   (declare (ignore type))
  83   (let ((num-results (result-state-num-results state)))
  84     (setf (result-state-num-results state) (1+ num-results))
  85     (my-make-wired-tn 'system-area-pointer 'sap-reg
  86                       (result-reg-offset num-results))))
  87
  88 #!+long-float
  89 (define-alien-type-method (long-float :result-tn) (type state)
  90   (declare (ignore type))
  91   (let ((num-results (result-state-num-results state)))
  92     (setf (result-state-num-results state) (1+ num-results))
  93     (my-make-wired-tn 'long-float 'long-reg (* num-results 2))))
  94
  95 (define-alien-type-method (double-float :result-tn) (type state)
  96   (declare (ignore type))
  97   (let ((num-results (result-state-num-results state)))
  98     (setf (result-state-num-results state) (1+ num-results))
  99     (my-make-wired-tn 'double-float 'double-reg (* num-results 2))))
 100
 101 (define-alien-type-method (single-float :result-tn) (type state)
 102   (declare (ignore type))
 103   (let ((num-results (result-state-num-results state)))
 104     (setf (result-state-num-results state) (1+ num-results))
 105     (my-make-wired-tn 'single-float 'single-reg (* num-results 2))))
 106
 107 (define-alien-type-method (values :result-tn) (type state)
 108   (let ((values (alien-values-type-values type)))
 109     (when (> (length values) 2)
 110       (error "Too many result values from c-call."))
 111     (mapcar (lambda (type)
 112               (invoke-alien-type-method :result-tn type state))
 113             values)))
 114
 115 (!def-vm-support-routine make-call-out-tns (type)
 116   (let ((arg-state (make-arg-state)))
 117     (collect ((arg-tns))
 118       (dolist (arg-type (alien-fun-type-arg-types type))
 119         (arg-tns (invoke-alien-type-method :arg-tn arg-type arg-state)))
 120       (values (my-make-wired-tn 'positive-fixnum 'any-reg esp-offset)
 121               (* (arg-state-stack-frame-size arg-state) n-word-bytes)
 122               (arg-tns)
 123               (invoke-alien-type-method :result-tn
 124                                         (alien-fun-type-result-type type)
 125                                         (make-result-state))))))
 126
 127
 128 (deftransform %alien-funcall ((function type &rest args) * * :node node)
 129   (aver (sb!c::constant-lvar-p type))
 130   (let* ((type (sb!c::lvar-value type))
 131          (env (sb!c::node-lexenv node))
 132          (arg-types (alien-fun-type-arg-types type))
 133          (result-type (alien-fun-type-result-type type)))
 134     (aver (= (length arg-types) (length args)))
 135     (if (or (some #'(lambda (type)
 136                       (and (alien-integer-type-p type)
 137                            (> (sb!alien::alien-integer-type-bits type) 32)))
 138                   arg-types)
 139             (and (alien-integer-type-p result-type)
 140                  (> (sb!alien::alien-integer-type-bits result-type) 32)))
 141         (collect ((new-args) (lambda-vars) (new-arg-types))
 142           (dolist (type arg-types)
 143             (let ((arg (gensym)))
 144               (lambda-vars arg)
 145               (cond ((and (alien-integer-type-p type)
 146                           (> (sb!alien::alien-integer-type-bits type) 32))
 147                      (new-args `(logand ,arg #xffffffff))
 148                      (new-args `(ash ,arg -32))
 149                      (new-arg-types (parse-alien-type '(unsigned 32) env))
 150                      (if (alien-integer-type-signed type)
 151                          (new-arg-types (parse-alien-type '(signed 32) env))
 152                          (new-arg-types (parse-alien-type '(unsigned 32) env))))
 153                     (t
 154                      (new-args arg)
 155                      (new-arg-types type)))))
 156           (cond ((and (alien-integer-type-p result-type)
 157                       (> (sb!alien::alien-integer-type-bits result-type) 32))
 158                  (let ((new-result-type
 159                         (let ((sb!alien::*values-type-okay* t))
 160                           (parse-alien-type
 161                            (if (alien-integer-type-signed result-type)
 162                                '(values (unsigned 32) (signed 32))
 163                                '(values (unsigned 32) (unsigned 32)))
 164                            env))))
 165                    `(lambda (function type ,@(lambda-vars))
 166                       (declare (ignore type))
 167                       (multiple-value-bind (low high)
 168                           (%alien-funcall function
 169                                           ',(make-alien-fun-type
 170                                              :arg-types (new-arg-types)
 171                                              :result-type new-result-type)
 172                                           ,@(new-args))
 173                         (logior low (ash high 32))))))
 174                 (t
 175                  `(lambda (function type ,@(lambda-vars))
 176                     (declare (ignore type))
 177                     (%alien-funcall function
 178                                     ',(make-alien-fun-type
 179                                        :arg-types (new-arg-types)
 180                                        :result-type result-type)
 181                                     ,@(new-args))))))
 182         (sb!c::give-up-ir1-transform))))
 183
 184 (define-vop (foreign-symbol-sap)
 185   (:translate foreign-symbol-sap)
 186   (:policy :fast-safe)
 187   (:args)
 188   (:arg-types (:constant simple-string))
 189   (:info foreign-symbol)
 190   (:results (res :scs (sap-reg)))
 191   (:result-types system-area-pointer)
 192   (:generator 2
 193    (inst lea res (make-fixup foreign-symbol :foreign))))
 194
 195 #!+linkage-table
 196 (define-vop (foreign-symbol-dataref-sap)
 197   (:translate foreign-symbol-dataref-sap)
 198   (:policy :fast-safe)
 199   (:args)
 200   (:arg-types (:constant simple-string))
 201   (:info foreign-symbol)
 202   (:results (res :scs (sap-reg)))
 203   (:result-types system-area-pointer)
 204   (:generator 2
 205    (inst mov res (make-fixup foreign-symbol :foreign-dataref))))
 206
 207 (define-vop (call-out)
 208   (:args (function :scs (sap-reg))
 209          (args :more t))
 210   (:results (results :more t))
 211   (:temporary (:sc unsigned-reg :offset eax-offset
 212                    :from :eval :to :result) eax)
 213   (:temporary (:sc unsigned-reg :offset ecx-offset
 214                    :from :eval :to :result) ecx)
 215   (:temporary (:sc unsigned-reg :offset edx-offset
 216                    :from :eval :to :result) edx)
 217   (:node-var node)
 218   (:vop-var vop)
 219   (:save-p t)
 220   (:ignore args ecx edx)
 221   (:generator 0
 222     (cond ((policy node (> space speed))
 223            (move eax function)
 224            (inst call (make-fixup "call_into_c" :foreign)))
 225           (t
 226            ;; Setup the NPX for C; all the FP registers need to be
 227            ;; empty; pop them all.
 228            (dotimes (i 8)
 229              (inst fstp fr0-tn))
 230
 231            #!+win32 (inst cld)
 232
 233            (inst call function)
 234            ;; To give the debugger a clue. XX not really internal-error?
 235            (note-this-location vop :internal-error)
 236
 237            ;; Restore the NPX for lisp; ensure no regs are empty
 238            (dotimes (i 7)
 239              (inst fldz))
 240
 241            (if (and results
 242                     (location= (tn-ref-tn results) fr0-tn))
 243                ;; The return result is in fr0.
 244                (inst fxch fr7-tn) ; move the result back to fr0
 245                (inst fldz)) ; insure no regs are empty
 246            ))))
 247
 248 ;;; While SBCL uses the FPU in 53-bit mode, most C libraries assume that
 249 ;;; the FPU is in 64-bit mode. So we change the FPU mode to 64-bit with
 250 ;;; the SET-FPU-WORD-FOR-C VOP before calling out to C and set it back
 251 ;;; to 53-bit mode after coming back using the SET-FPU-WORD-FOR-LISP VOP.
 252 (define-vop (set-fpu-word-for-c)
 253   (:node-var node)
 254   (:generator 0
 255     (when (policy node (= sb!c::float-accuracy 3))
 256       (inst sub esp-tn 4)
 257       (inst fnstcw (make-ea :word :base esp-tn))
 258       (inst wait)
 259       (inst or (make-ea :word :base esp-tn) #x300)
 260       (inst fldcw (make-ea :word :base esp-tn))
 261       (inst wait))))
 262
 263 (define-vop (set-fpu-word-for-lisp)
 264   (:node-var node)
 265   (:generator 0
 266     (when (policy node (= sb!c::float-accuracy 3))
 267       (inst fnstcw (make-ea :word :base esp-tn))
 268       (inst wait)
 269       (inst and (make-ea :word :base esp-tn) #xfeff)
 270       (inst fldcw (make-ea :word :base esp-tn))
 271       (inst wait)
 272       (inst add esp-tn 4))))
 273
 274 (define-vop (alloc-number-stack-space)
 275   (:info amount)
 276   (:results (result :scs (sap-reg any-reg)))
 277   (:generator 0
 278     (aver (location= result esp-tn))
 279     (unless (zerop amount)
 280       (let ((delta (logandc2 (+ amount 3) 3)))
 281         (inst sub esp-tn delta)))
 282     ;; C stack should probably be 16 byte aligned on Darwin
 283     #!+darwin (inst and esp-tn -16)
 284     (move result esp-tn)))
 285
 286 (define-vop (dealloc-number-stack-space)
 287   (:info amount)
 288   (:generator 0
 289     (unless (zerop amount)
 290       (let ((delta (logandc2 (+ amount 3) 3)))
 291         (inst add esp-tn delta)))))
 292
 293 (define-vop (alloc-alien-stack-space)
 294   (:info amount)
 295   #!+sb-thread (:temporary (:sc unsigned-reg) temp)
 296   (:results (result :scs (sap-reg any-reg)))
 297   #!+sb-thread
 298   (:generator 0
 299     (aver (not (location= result esp-tn)))
 300     (unless (zerop amount)
 301       (let ((delta (logandc2 (+ amount 3) 3)))
 302         (inst mov temp
 303               (make-ea :dword
 304                        :disp (+ nil-value
 305                                 (static-symbol-offset '*alien-stack*)
 306                                 (ash symbol-tls-index-slot word-shift)
 307                                 (- other-pointer-lowtag))))
 308         (inst fs-segment-prefix)
 309         (inst sub (make-ea :dword :scale 1 :index temp) delta)))
 310     (load-tl-symbol-value result *alien-stack*))
 311   #!-sb-thread
 312   (:generator 0
 313     (aver (not (location= result esp-tn)))
 314     (unless (zerop amount)
 315       (let ((delta (logandc2 (+ amount 3) 3)))
 316         (inst sub (make-ea :dword
 317                            :disp (+ nil-value
 318                                     (static-symbol-offset '*alien-stack*)
 319                                     (ash symbol-value-slot word-shift)
 320                                     (- other-pointer-lowtag)))
 321               delta)))
 322     (load-symbol-value result *alien-stack*)))
 323
 324 (define-vop (dealloc-alien-stack-space)
 325   (:info amount)
 326   #!+sb-thread (:temporary (:sc unsigned-reg) temp)
 327   #!+sb-thread
 328   (:generator 0
 329     (unless (zerop amount)
 330       (let ((delta (logandc2 (+ amount 3) 3)))
 331         (inst mov temp
 332               (make-ea :dword
 333                            :disp (+ nil-value
 334                                     (static-symbol-offset '*alien-stack*)
 335                                 (ash symbol-tls-index-slot word-shift)
 336                                 (- other-pointer-lowtag))))
 337         (inst fs-segment-prefix)
 338         (inst add (make-ea :dword :scale 1 :index temp) delta))))
 339   #!-sb-thread
 340   (:generator 0
 341     (unless (zerop amount)
 342       (let ((delta (logandc2 (+ amount 3) 3)))
 343         (inst add (make-ea :dword
 344                            :disp (+ nil-value
 345                                     (static-symbol-offset '*alien-stack*)
 346                                     (ash symbol-value-slot word-shift)
 347                                     (- other-pointer-lowtag)))
 348               delta)))))
 349
 350 ;;; these are not strictly part of the c-call convention, but are
 351 ;;; needed for the WITH-PRESERVED-POINTERS macro used for "locking
 352 ;;; down" lisp objects so that GC won't move them while foreign
 353 ;;; functions go to work.
 354
 355 (define-vop (push-word-on-c-stack)
 356     (:translate push-word-on-c-stack)
 357   (:args (val :scs (sap-reg)))
 358   (:policy :fast-safe)
 359   (:arg-types system-area-pointer)
 360   (:generator 2
 361     (inst push val)))
 362
 363 (define-vop (pop-words-from-c-stack)
 364     (:translate pop-words-from-c-stack)
 365   (:args)
 366   (:arg-types (:constant (unsigned-byte 29)))
 367   (:info number)
 368   (:policy :fast-safe)
 369   (:generator 2
 370     (inst add esp-tn (fixnumize number))))
 371
 372 #-sb-xc-host
 373 (defun alien-callback-accessor-form (type sp offset)
 374   `(deref (sap-alien (sap+ ,sp ,offset) (* ,type))))
 375
 376 #-sb-xc-host
 377 (defun alien-callback-assembler-wrapper (index return-type arg-types)
 378   "Cons up a piece of code which calls call-callback with INDEX and a
 379 pointer to the arguments."
 380   (declare (ignore arg-types))
 381   (let* ((segment (make-segment))
 382          (eax eax-tn)
 383          (edx edx-tn)
 384          (ebp ebp-tn)
 385          (esp esp-tn)
 386          ([ebp-8] (make-ea :dword :base ebp :disp -8))
 387          ([ebp-4] (make-ea :dword :base ebp :disp -4)))
 388     (assemble (segment)
 389               (inst push ebp)                       ; save old frame pointer
 390               (inst mov  ebp esp)                   ; establish new frame
 391               (inst mov  eax esp)                   ;
 392               (inst sub  eax 8)                     ; place for result
 393               (inst push eax)                       ; arg2
 394               (inst add  eax 16)                    ; arguments
 395               (inst push eax)                       ; arg1
 396               (inst push (ash index 2))             ; arg0
 397
 398               ;; Indirect the access to ENTER-ALIEN-CALLBACK through
 399               ;; the symbol-value slot of SB-ALIEN::*ENTER-ALIEN-CALLBACK*
 400               ;; to ensure it'll work even if the GC moves ENTER-ALIEN-CALLBACK.
 401               ;; Skip any SB-THREAD TLS magic, since we don't expecte anyone
 402               ;; to rebind the variable. -- JES, 2006-01-01
 403               (inst mov eax (+ nil-value (static-symbol-offset
 404                                           'sb!alien::*enter-alien-callback*)))
 405               (loadw eax eax symbol-value-slot other-pointer-lowtag)
 406               (inst push eax) ; function
 407               (inst mov  eax (foreign-symbol-address "funcall3"))
 408               (inst call eax)
 409               ;; now put the result into the right register
 410               (cond
 411                 ((and (alien-integer-type-p return-type)
 412                       (eql (alien-type-bits return-type) 64))
 413                  (inst mov eax [ebp-8])
 414                  (inst mov edx [ebp-4]))
 415                 ((or (alien-integer-type-p return-type)
 416                      (alien-pointer-type-p return-type)
 417                      (alien-type-= #.(parse-alien-type 'system-area-pointer nil)
 418                                    return-type))
 419                  (inst mov eax [ebp-8]))
 420                 ((alien-single-float-type-p return-type)
 421                  (inst fld  [ebp-8]))
 422                 ((alien-double-float-type-p return-type)
 423                  (inst fldd [ebp-8]))
 424                 ((alien-void-type-p return-type))
 425                 (t
 426                  (error "unrecognized alien type: ~A" return-type)))
 427               (inst mov esp ebp)                   ; discard frame
 428               (inst pop ebp)                       ; restore frame pointer
 429               (inst ret))
 430     (finalize-segment segment)
 431     ;; Now that the segment is done, convert it to a static
 432     ;; vector we can point foreign code to.
 433     (let ((buffer (sb!assem::segment-buffer segment)))
 434       (make-static-vector (length buffer)
 435                           :element-type '(unsigned-byte 8)
 436                           :initial-contents buffer))))