src/compiler/x86/c-call.lisp

   1 ;;;; the VOPs and other necessary machine specific support
   2 ;;;; routines for call-out to C
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!VM")
  14
  15 ;; The MOVE-ARG vop is going to store args on the stack for
  16 ;; call-out. These tn's will be used for that. move-arg is normally
  17 ;; used for things going down the stack but C wants to have args
  18 ;; indexed in the positive direction.
  19
  20 (defun my-make-wired-tn (prim-type-name sc-name offset)
  21   (make-wired-tn (primitive-type-or-lose prim-type-name)
  22                  (sc-number-or-lose sc-name)
  23                  offset))
  24
  25 (defstruct (arg-state (:copier nil))
  26   (stack-frame-size 0))
  27
  28 (define-alien-type-method (integer :arg-tn) (type state)
  29   (let ((stack-frame-size (arg-state-stack-frame-size state)))
  30     (setf (arg-state-stack-frame-size state) (1+ stack-frame-size))
  31     (multiple-value-bind (ptype stack-sc)
  32         (if (alien-integer-type-signed type)
  33             (values 'signed-byte-32 'signed-stack)
  34             (values 'unsigned-byte-32 'unsigned-stack))
  35       (my-make-wired-tn ptype stack-sc stack-frame-size))))
  36
  37 (define-alien-type-method (system-area-pointer :arg-tn) (type state)
  38   (declare (ignore type))
  39   (let ((stack-frame-size (arg-state-stack-frame-size state)))
  40     (setf (arg-state-stack-frame-size state) (1+ stack-frame-size))
  41     (my-make-wired-tn 'system-area-pointer
  42                       'sap-stack
  43                       stack-frame-size)))
  44
  45 #!+long-float
  46 (define-alien-type-method (long-float :arg-tn) (type state)
  47   (declare (ignore type))
  48   (let ((stack-frame-size (arg-state-stack-frame-size state)))
  49     (setf (arg-state-stack-frame-size state) (+ stack-frame-size 3))
  50     (my-make-wired-tn 'long-float 'long-stack stack-frame-size)))
  51
  52 (define-alien-type-method (double-float :arg-tn) (type state)
  53   (declare (ignore type))
  54   (let ((stack-frame-size (arg-state-stack-frame-size state)))
  55     (setf (arg-state-stack-frame-size state) (+ stack-frame-size 2))
  56     (my-make-wired-tn 'double-float 'double-stack stack-frame-size)))
  57
  58 (define-alien-type-method (single-float :arg-tn) (type state)
  59   (declare (ignore type))
  60   (let ((stack-frame-size (arg-state-stack-frame-size state)))
  61     (setf (arg-state-stack-frame-size state) (1+ stack-frame-size))
  62     (my-make-wired-tn 'single-float 'single-stack stack-frame-size)))
  63
  64 (defstruct (result-state (:copier nil))
  65   (num-results 0))
  66
  67 (defun result-reg-offset (slot)
  68   (ecase slot
  69     (0 eax-offset)
  70     (1 edx-offset)))
  71
  72 (define-alien-type-method (integer :result-tn) (type state)
  73   (let ((num-results (result-state-num-results state)))
  74     (setf (result-state-num-results state) (1+ num-results))
  75     (multiple-value-bind (ptype reg-sc)
  76         (if (alien-integer-type-signed type)
  77             (values 'signed-byte-32 'signed-reg)
  78             (values 'unsigned-byte-32 'unsigned-reg))
  79       (my-make-wired-tn ptype reg-sc (result-reg-offset num-results)))))
  80
  81 (define-alien-type-method (system-area-pointer :result-tn) (type state)
  82   (declare (ignore type))
  83   (let ((num-results (result-state-num-results state)))
  84     (setf (result-state-num-results state) (1+ num-results))
  85     (my-make-wired-tn 'system-area-pointer 'sap-reg
  86                       (result-reg-offset num-results))))
  87
  88 #!+long-float
  89 (define-alien-type-method (long-float :result-tn) (type state)
  90   (declare (ignore type))
  91   (let ((num-results (result-state-num-results state)))
  92     (setf (result-state-num-results state) (1+ num-results))
  93     (my-make-wired-tn 'long-float 'long-reg (* num-results 2))))
  94
  95 (define-alien-type-method (double-float :result-tn) (type state)
  96   (declare (ignore type))
  97   (let ((num-results (result-state-num-results state)))
  98     (setf (result-state-num-results state) (1+ num-results))
  99     (my-make-wired-tn 'double-float 'double-reg (* num-results 2))))
 100
 101 (define-alien-type-method (single-float :result-tn) (type state)
 102   (declare (ignore type))
 103   (let ((num-results (result-state-num-results state)))
 104     (setf (result-state-num-results state) (1+ num-results))
 105     (my-make-wired-tn 'single-float 'single-reg (* num-results 2))))
 106
 107 (define-alien-type-method (values :result-tn) (type state)
 108   (let ((values (alien-values-type-values type)))
 109     (when (> (length values) 2)
 110       (error "Too many result values from c-call."))
 111     (mapcar (lambda (type)
 112               (invoke-alien-type-method :result-tn type state))
 113             values)))
 114
 115 (!def-vm-support-routine make-call-out-tns (type)
 116   (let ((arg-state (make-arg-state)))
 117     (collect ((arg-tns))
 118       (dolist (arg-type (alien-fun-type-arg-types type))
 119         (arg-tns (invoke-alien-type-method :arg-tn arg-type arg-state)))
 120       (values (my-make-wired-tn 'positive-fixnum 'any-reg esp-offset)
 121               (* (arg-state-stack-frame-size arg-state) n-word-bytes)
 122               (arg-tns)
 123               (invoke-alien-type-method :result-tn
 124                                         (alien-fun-type-result-type type)
 125                                         (make-result-state))))))
 126
 127
 128 (deftransform %alien-funcall ((function type &rest args) * * :node node)
 129   (aver (sb!c::constant-lvar-p type))
 130   (let* ((type (sb!c::lvar-value type))
 131          (env (sb!c::node-lexenv node))
 132          (arg-types (alien-fun-type-arg-types type))
 133          (result-type (alien-fun-type-result-type type)))
 134     (aver (= (length arg-types) (length args)))
 135     (if (or (some #'(lambda (type)
 136                       (and (alien-integer-type-p type)
 137                            (> (sb!alien::alien-integer-type-bits type) 32)))
 138                   arg-types)
 139             (and (alien-integer-type-p result-type)
 140                  (> (sb!alien::alien-integer-type-bits result-type) 32)))
 141         (collect ((new-args) (lambda-vars) (new-arg-types))
 142           (dolist (type arg-types)
 143             (let ((arg (gensym)))
 144               (lambda-vars arg)
 145               (cond ((and (alien-integer-type-p type)
 146                           (> (sb!alien::alien-integer-type-bits type) 32))
 147                      (new-args `(logand ,arg #xffffffff))
 148                      (new-args `(ash ,arg -32))
 149                      (new-arg-types (parse-alien-type '(unsigned 32) env))
 150                      (if (alien-integer-type-signed type)
 151                          (new-arg-types (parse-alien-type '(signed 32) env))
 152                          (new-arg-types (parse-alien-type '(unsigned 32) env))))
 153                     (t
 154                      (new-args arg)
 155                      (new-arg-types type)))))
 156           (cond ((and (alien-integer-type-p result-type)
 157                       (> (sb!alien::alien-integer-type-bits result-type) 32))
 158                  (let ((new-result-type
 159                         (let ((sb!alien::*values-type-okay* t))
 160                           (parse-alien-type
 161                            (if (alien-integer-type-signed result-type)
 162                                '(values (unsigned 32) (signed 32))
 163                                '(values (unsigned 32) (unsigned 32)))
 164                            env))))
 165                    `(lambda (function type ,@(lambda-vars))
 166                       (declare (ignore type))
 167                       (multiple-value-bind (low high)
 168                           (%alien-funcall function
 169                                           ',(make-alien-fun-type
 170                                              :arg-types (new-arg-types)
 171                                              :result-type new-result-type)
 172                                           ,@(new-args))
 173                         (logior low (ash high 32))))))
 174                 (t
 175                  `(lambda (function type ,@(lambda-vars))
 176                     (declare (ignore type))
 177                     (%alien-funcall function
 178                                     ',(make-alien-fun-type
 179                                        :arg-types (new-arg-types)
 180                                        :result-type result-type)
 181                                     ,@(new-args))))))
 182         (sb!c::give-up-ir1-transform))))
 183
 184
 185
 186
 187 (define-vop (foreign-symbol-address)
 188   (:translate foreign-symbol-address)
 189   (:policy :fast-safe)
 190   (:args)
 191   (:arg-types (:constant simple-base-string))
 192   (:info foreign-symbol)
 193   (:results (res :scs (sap-reg)))
 194   (:result-types system-area-pointer)
 195   (:generator 2
 196    (inst lea res (make-fixup (extern-alien-name foreign-symbol) :foreign))))
 197
 198 (define-vop (call-out)
 199   (:args (function :scs (sap-reg))
 200          (args :more t))
 201   (:results (results :more t))
 202   (:temporary (:sc unsigned-reg :offset eax-offset
 203                    :from :eval :to :result) eax)
 204   (:temporary (:sc unsigned-reg :offset ecx-offset
 205                    :from :eval :to :result) ecx)
 206   (:temporary (:sc unsigned-reg :offset edx-offset
 207                    :from :eval :to :result) edx)
 208   (:node-var node)
 209   (:vop-var vop)
 210   (:save-p t)
 211   (:ignore args ecx edx)
 212   (:generator 0
 213     (cond ((policy node (> space speed))
 214            (move eax function)
 215            (inst call (make-fixup (extern-alien-name "call_into_c") :foreign)))
 216           (t
 217            ;; Setup the NPX for C; all the FP registers need to be
 218            ;; empty; pop them all.
 219            (dotimes (i 8)
 220              (inst fstp fr0-tn))
 221
 222            (inst call function)
 223            ;; To give the debugger a clue. XX not really internal-error?
 224            (note-this-location vop :internal-error)
 225
 226            ;; Restore the NPX for lisp; ensure no regs are empty
 227            (dotimes (i 7)
 228              (inst fldz))
 229
 230            (if (and results
 231                     (location= (tn-ref-tn results) fr0-tn))
 232                ;; The return result is in fr0.
 233                (inst fxch fr7-tn) ; move the result back to fr0
 234                (inst fldz)) ; insure no regs are empty
 235            ))))
 236
 237 (define-vop (alloc-number-stack-space)
 238   (:info amount)
 239   (:results (result :scs (sap-reg any-reg)))
 240   (:node-var node)
 241   (:generator 0
 242     (aver (location= result esp-tn))
 243     (when (policy node (= sb!c::float-accuracy 3))
 244       (inst sub esp-tn 4)
 245       (inst fnstcw (make-ea :word :base esp-tn))
 246       (inst wait)
 247       (inst or (make-ea :word :base esp-tn) #x300)
 248       (inst fldcw (make-ea :word :base esp-tn))
 249       (inst wait))
 250     (unless (zerop amount)
 251       (let ((delta (logandc2 (+ amount 3) 3)))
 252         (inst sub esp-tn delta)))
 253     (move result esp-tn)))
 254
 255 (define-vop (dealloc-number-stack-space)
 256   (:info amount)
 257   (:node-var node)
 258   (:generator 0
 259     (unless (zerop amount)
 260       (let ((delta (logandc2 (+ amount 3) 3)))
 261         (inst add esp-tn delta)))
 262     (when (policy node (= sb!c::float-accuracy 3))
 263       (inst fnstcw (make-ea :word :base esp-tn))
 264       (inst wait)
 265       (inst and (make-ea :word :base esp-tn) #xfeff)
 266       (inst fldcw (make-ea :word :base esp-tn))
 267       (inst wait)
 268       (inst add esp-tn 4))))
 269
 270 (define-vop (alloc-alien-stack-space)
 271   (:info amount)
 272   #!+sb-thread (:temporary (:sc unsigned-reg) temp)
 273   (:results (result :scs (sap-reg any-reg)))
 274   #!+sb-thread
 275   (:generator 0
 276     (aver (not (location= result esp-tn)))
 277     (unless (zerop amount)
 278       (let ((delta (logandc2 (+ amount 3) 3)))
 279         (inst mov temp
 280               (make-ea :dword
 281                        :disp (+ nil-value
 282                                 (static-symbol-offset '*alien-stack*)
 283                                 (ash symbol-tls-index-slot word-shift)
 284                                 (- other-pointer-lowtag))))
 285         (inst fs-segment-prefix)
 286         (inst sub (make-ea :dword :scale 1 :index temp) delta)))
 287     (load-tl-symbol-value result *alien-stack*))
 288   #!-sb-thread
 289   (:generator 0
 290     (aver (not (location= result esp-tn)))
 291     (unless (zerop amount)
 292       (let ((delta (logandc2 (+ amount 3) 3)))
 293         (inst sub (make-ea :dword
 294                            :disp (+ nil-value
 295                                     (static-symbol-offset '*alien-stack*)
 296                                     (ash symbol-value-slot word-shift)
 297                                     (- other-pointer-lowtag)))
 298               delta)))
 299     (load-symbol-value result *alien-stack*)))
 300
 301 (define-vop (dealloc-alien-stack-space)
 302   (:info amount)
 303   #!+sb-thread (:temporary (:sc unsigned-reg) temp)
 304   #!+sb-thread
 305   (:generator 0
 306     (unless (zerop amount)
 307       (let ((delta (logandc2 (+ amount 3) 3)))
 308         (inst mov temp
 309               (make-ea :dword
 310                            :disp (+ nil-value
 311                                     (static-symbol-offset '*alien-stack*)
 312                                 (ash symbol-tls-index-slot word-shift)
 313                                 (- other-pointer-lowtag))))
 314         (inst fs-segment-prefix)
 315         (inst add (make-ea :dword :scale 1 :index temp) delta))))
 316   #!-sb-thread
 317   (:generator 0
 318     (unless (zerop amount)
 319       (let ((delta (logandc2 (+ amount 3) 3)))
 320         (inst add (make-ea :dword
 321                            :disp (+ nil-value
 322                                     (static-symbol-offset '*alien-stack*)
 323                                     (ash symbol-value-slot word-shift)
 324                                     (- other-pointer-lowtag)))
 325               delta)))))
 326
 327 ;;; these are not strictly part of the c-call convention, but are
 328 ;;; needed for the WITH-PRESERVED-POINTERS macro used for "locking
 329 ;;; down" lisp objects so that GC won't move them while foreign
 330 ;;; functions go to work.
 331
 332 (define-vop (push-word-on-c-stack)
 333     (:translate push-word-on-c-stack)
 334   (:args (val :scs (sap-reg)))
 335   (:policy :fast-safe)
 336   (:arg-types system-area-pointer)
 337   (:generator 2
 338     (inst push val)))
 339
 340 (define-vop (pop-words-from-c-stack)
 341     (:translate pop-words-from-c-stack)
 342   (:args)
 343   (:arg-types (:constant (unsigned-byte 29)))
 344   (:info number)
 345   (:policy :fast-safe)
 346   (:generator 2
 347     (inst add esp-tn (fixnumize number))))
 348