src/compiler/x86/call.lisp

   1 ;;;; function call for the x86 VM
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!VM")
  13 \f
  14 ;;;; interfaces to IR2 conversion
  15
  16 ;;; Return a wired TN describing the N'th full call argument passing
  17 ;;; location.
  18 (!def-vm-support-routine standard-arg-location (n)
  19   (declare (type unsigned-byte n))
  20   (if (< n register-arg-count)
  21       (make-wired-tn *backend-t-primitive-type* descriptor-reg-sc-number
  22                      (nth n *register-arg-offsets*))
  23       (make-wired-tn *backend-t-primitive-type* control-stack-sc-number n)))
  24
  25 ;;; Make a passing location TN for a local call return PC.
  26 ;;;
  27 ;;; Always wire the return PC location to the stack in its standard
  28 ;;; location.
  29 (!def-vm-support-routine make-return-pc-passing-location (standard)
  30   (declare (ignore standard))
  31   (make-wired-tn (primitive-type-or-lose 'system-area-pointer)
  32                  sap-stack-sc-number return-pc-save-offset))
  33
  34 ;;; This is similar to MAKE-RETURN-PC-PASSING-LOCATION, but makes a
  35 ;;; location to pass OLD-FP in.
  36 ;;;
  37 ;;; This is wired in both the standard and the local-call conventions,
  38 ;;; because we want to be able to assume it's always there. Besides,
  39 ;;; the x86 doesn't have enough registers to really make it profitable
  40 ;;; to pass it in a register.
  41 (!def-vm-support-routine make-old-fp-passing-location (standard)
  42   (declare (ignore standard))
  43   (make-wired-tn *fixnum-primitive-type* control-stack-sc-number
  44                  ocfp-save-offset))
  45
  46 ;;; Make the TNs used to hold OLD-FP and RETURN-PC within the current
  47 ;;; function. We treat these specially so that the debugger can find
  48 ;;; them at a known location.
  49 ;;;
  50 ;;; Without using a save-tn - which does not make much sense if it is
  51 ;;; wired to the stack?
  52 (!def-vm-support-routine make-old-fp-save-location (physenv)
  53   (physenv-debug-live-tn (make-wired-tn *fixnum-primitive-type*
  54                                         control-stack-sc-number
  55                                         ocfp-save-offset)
  56                          physenv))
  57 (!def-vm-support-routine make-return-pc-save-location (physenv)
  58   (physenv-debug-live-tn
  59    (make-wired-tn (primitive-type-or-lose 'system-area-pointer)
  60                   sap-stack-sc-number return-pc-save-offset)
  61    physenv))
  62
  63 ;;; Make a TN for the standard argument count passing location. We only
  64 ;;; need to make the standard location, since a count is never passed when we
  65 ;;; are using non-standard conventions.
  66 (!def-vm-support-routine make-arg-count-location ()
  67   (make-wired-tn *fixnum-primitive-type* any-reg-sc-number ecx-offset))
  68
  69 ;;; Make a TN to hold the number-stack frame pointer. This is allocated
  70 ;;; once per component, and is component-live.
  71 (!def-vm-support-routine make-nfp-tn ()
  72   (make-restricted-tn *fixnum-primitive-type* ignore-me-sc-number))
  73
  74 (!def-vm-support-routine make-stack-pointer-tn ()
  75   (make-normal-tn *fixnum-primitive-type*))
  76
  77 (!def-vm-support-routine make-number-stack-pointer-tn ()
  78   (make-restricted-tn *fixnum-primitive-type* ignore-me-sc-number))
  79
  80 ;;; Return a list of TNs that can be used to represent an unknown-values
  81 ;;; continuation within a function.
  82 (!def-vm-support-routine make-unknown-values-locations ()
  83   (list (make-stack-pointer-tn)
  84         (make-normal-tn *fixnum-primitive-type*)))
  85
  86 ;;; This function is called by the ENTRY-ANALYZE phase, allowing
  87 ;;; VM-dependent initialization of the IR2-COMPONENT structure. We
  88 ;;; push placeholder entries in the CONSTANTS to leave room for
  89 ;;; additional noise in the code object header.
  90 (!def-vm-support-routine select-component-format (component)
  91   (declare (type component component))
  92   ;; The 1+ here is because for the x86 the first constant is a
  93   ;; pointer to a list of fixups, or NIL if the code object has none.
  94   ;; (If I understand correctly, the fixups are needed at GC copy
  95   ;; time because the X86 code isn't relocatable.)
  96   ;;
  97   ;; KLUDGE: It'd be cleaner to have the fixups entry be a named
  98   ;; element of the CODE (aka component) primitive object. However,
  99   ;; it's currently a large, tricky, error-prone chore to change
 100   ;; the layout of any primitive object, so for the foreseeable future
 101   ;; we'll just live with this ugliness. -- WHN 2002-01-02
 102   (dotimes (i (1+ code-constants-offset))
 103     (vector-push-extend nil
 104                         (ir2-component-constants (component-info component))))
 105   (values))
 106 \f
 107 ;;;; frame hackery
 108
 109 ;;; This is used for setting up the Old-FP in local call.
 110 (define-vop (current-fp)
 111   (:results (val :scs (any-reg control-stack)))
 112   (:generator 1
 113     (move val ebp-tn)))
 114
 115 ;;; We don't have a separate NFP, so we don't need to do anything here.
 116 (define-vop (compute-old-nfp)
 117   (:results (val))
 118   (:ignore val)
 119   (:generator 1
 120     nil))
 121
 122 (define-vop (xep-allocate-frame)
 123   (:info start-lab copy-more-arg-follows)
 124   (:vop-var vop)
 125   (:generator 1
 126     (align n-lowtag-bits)
 127     (trace-table-entry trace-table-fun-prologue)
 128     (emit-label start-lab)
 129     ;; Skip space for the function header.
 130     (inst simple-fun-header-word)
 131     (dotimes (i (1- simple-fun-code-offset))
 132       (inst dword 0))
 133
 134     ;; The start of the actual code.
 135     ;; Save the return-pc.
 136     (popw ebp-tn (- (1+ return-pc-save-offset)))
 137
 138     ;; If copy-more-arg follows it will allocate the correct stack
 139     ;; size. The stack is not allocated first here as this may expose
 140     ;; args on the stack if they take up more space than the frame!
 141     (unless copy-more-arg-follows
 142       ;; The args fit within the frame so just allocate the frame.
 143       (inst lea esp-tn
 144             (make-ea :dword :base ebp-tn
 145                      :disp (- (* n-word-bytes
 146                                  (max 3 (sb-allocated-size 'stack)))))))
 147
 148     (trace-table-entry trace-table-normal)))
 149
 150 ;;; This is emitted directly before either a known-call-local, call-local,
 151 ;;; or a multiple-call-local. All it does is allocate stack space for the
 152 ;;; callee (who has the same size stack as us).
 153 (define-vop (allocate-frame)
 154   (:results (res :scs (any-reg control-stack))
 155             (nfp))
 156   (:info callee)
 157   (:ignore nfp callee)
 158   (:generator 2
 159     (move res esp-tn)
 160     (inst sub esp-tn (* n-word-bytes (sb-allocated-size 'stack)))))
 161
 162 ;;; Allocate a partial frame for passing stack arguments in a full
 163 ;;; call. NARGS is the number of arguments passed. We allocate at
 164 ;;; least 3 slots, because the XEP noise is going to want to use them
 165 ;;; before it can extend the stack.
 166 (define-vop (allocate-full-call-frame)
 167   (:info nargs)
 168   (:results (res :scs (any-reg control-stack)))
 169   (:generator 2
 170     (move res esp-tn)
 171     (inst sub esp-tn (* (max nargs 3) n-word-bytes))))
 172 \f
 173 ;;; Emit code needed at the return-point from an unknown-values call
 174 ;;; for a fixed number of values. Values is the head of the TN-REF
 175 ;;; list for the locations that the values are to be received into.
 176 ;;; Nvals is the number of values that are to be received (should
 177 ;;; equal the length of Values).
 178 ;;;
 179 ;;; MOVE-TEMP is a DESCRIPTOR-REG TN used as a temporary.
 180 ;;;
 181 ;;; This code exploits the fact that in the unknown-values convention,
 182 ;;; a single value return returns at the return PC + 2, whereas a
 183 ;;; return of other than one value returns directly at the return PC.
 184 ;;;
 185 ;;; If 0 or 1 values are expected, then we just emit an instruction to
 186 ;;; reset the SP (which will only be executed when other than 1 value
 187 ;;; is returned.)
 188 ;;;
 189 ;;; In the general case we have to do three things:
 190 ;;;  -- Default unsupplied register values. This need only be done
 191 ;;;     when a single value is returned, since register values are
 192 ;;;     defaulted by the called in the non-single case.
 193 ;;;  -- Default unsupplied stack values. This needs to be done whenever
 194 ;;;     there are stack values.
 195 ;;;  -- Reset SP. This must be done whenever other than 1 value is
 196 ;;;     returned, regardless of the number of values desired.
 197 (defun default-unknown-values (vop values nvals)
 198   (declare (type (or tn-ref null) values)
 199            (type unsigned-byte nvals))
 200   (cond
 201    ((<= nvals 1)
 202     (note-this-location vop :single-value-return)
 203     (let ((single-value (gen-label)))
 204       (cond
 205        ((member :cmov *backend-subfeatures*)
 206         (inst cmov :c esp-tn ebx-tn))
 207        (t
 208         (inst jmp :nc single-value)
 209         (inst mov esp-tn ebx-tn)
 210         (emit-label single-value)))))
 211    ((<= nvals register-arg-count)
 212     (let ((regs-defaulted (gen-label)))
 213       (note-this-location vop :unknown-return)
 214       (inst jmp :c regs-defaulted)
 215       ;; Default the unsuppled registers.
 216       (let* ((2nd-tn-ref (tn-ref-across values))
 217              (2nd-tn (tn-ref-tn 2nd-tn-ref)))
 218         (inst mov 2nd-tn nil-value)
 219         (when (> nvals 2)
 220           (loop
 221             for tn-ref = (tn-ref-across 2nd-tn-ref)
 222             then (tn-ref-across tn-ref)
 223             for count from 2 below register-arg-count
 224             do (inst mov (tn-ref-tn tn-ref) 2nd-tn))))
 225       (inst mov ebx-tn esp-tn)
 226       (emit-label regs-defaulted)
 227       (inst mov esp-tn ebx-tn)))
 228    ((<= nvals 7)
 229     ;; The number of bytes depends on the relative jump instructions.
 230     ;; Best case is 31+(n-3)*14, worst case is 35+(n-3)*18. For
 231     ;; NVALS=6 that is 73/89 bytes, and for NVALS=7 that is 87/107
 232     ;; bytes which is likely better than using the blt below.
 233     (let ((regs-defaulted (gen-label))
 234           (defaulting-done (gen-label))
 235           (default-stack-slots (gen-label)))
 236       (note-this-location vop :unknown-return)
 237       ;; Branch off to the MV case.
 238       (inst jmp :c regs-defaulted)
 239       ;; Do the single value case.
 240       ;; Default the register args
 241       (inst mov eax-tn nil-value)
 242       (do ((i 1 (1+ i))
 243            (val (tn-ref-across values) (tn-ref-across val)))
 244           ((= i (min nvals register-arg-count)))
 245         (inst mov (tn-ref-tn val) eax-tn))
 246
 247       ;; Fake other registers so it looks like we returned with all the
 248       ;; registers filled in.
 249       (move ebx-tn esp-tn)
 250       (inst push edx-tn)
 251       (inst jmp default-stack-slots)
 252
 253       (emit-label regs-defaulted)
 254
 255       (inst mov eax-tn nil-value)
 256       (storew edx-tn ebx-tn -1)
 257       (collect ((defaults))
 258         (do ((i register-arg-count (1+ i))
 259              (val (do ((i 0 (1+ i))
 260                        (val values (tn-ref-across val)))
 261                       ((= i register-arg-count) val))
 262                   (tn-ref-across val)))
 263             ((null val))
 264           (let ((default-lab (gen-label))
 265                 (tn (tn-ref-tn val)))
 266             (defaults (cons default-lab tn))
 267
 268             (inst cmp ecx-tn (fixnumize i))
 269             (inst jmp :be default-lab)
 270             (loadw edx-tn ebx-tn (- (1+ i)))
 271             (inst mov tn edx-tn)))
 272
 273         (emit-label defaulting-done)
 274         (loadw edx-tn ebx-tn -1)
 275         (move esp-tn ebx-tn)
 276
 277         (let ((defaults (defaults)))
 278           (when defaults
 279             (assemble (*elsewhere*)
 280               (trace-table-entry trace-table-fun-prologue)
 281               (emit-label default-stack-slots)
 282               (dolist (default defaults)
 283                 (emit-label (car default))
 284                 (inst mov (cdr default) eax-tn))
 285               (inst jmp defaulting-done)
 286               (trace-table-entry trace-table-normal)))))))
 287    (t
 288     ;; 91 bytes for this branch.
 289     (let ((regs-defaulted (gen-label))
 290           (restore-edi (gen-label))
 291           (no-stack-args (gen-label))
 292           (default-stack-vals (gen-label))
 293           (count-okay (gen-label)))
 294       (note-this-location vop :unknown-return)
 295       ;; Branch off to the MV case.
 296       (inst jmp :c regs-defaulted)
 297
 298       ;; Default the register args, and set up the stack as if we
 299       ;; entered the MV return point.
 300       (inst mov ebx-tn esp-tn)
 301       (inst push edx-tn)
 302       (inst mov edi-tn nil-value)
 303       (inst push edi-tn)
 304       (inst mov esi-tn edi-tn)
 305       ;; Compute a pointer to where to put the [defaulted] stack values.
 306       (emit-label no-stack-args)
 307       (inst lea edi-tn
 308             (make-ea :dword :base ebp-tn
 309                      :disp (* (- (1+ register-arg-count)) n-word-bytes)))
 310       ;; Load EAX with NIL so we can quickly store it, and set up
 311       ;; stuff for the loop.
 312       (inst mov eax-tn nil-value)
 313       (inst std)
 314       (inst mov ecx-tn (- nvals register-arg-count))
 315       ;; solaris requires DF being zero.
 316       #!+sunos (inst cld)
 317       ;; Jump into the default loop.
 318       (inst jmp default-stack-vals)
 319
 320       ;; The regs are defaulted. We need to copy any stack arguments,
 321       ;; and then default the remaining stack arguments.
 322       (emit-label regs-defaulted)
 323       ;; Save EDI.
 324       (storew edi-tn ebx-tn (- (1+ 1)))
 325       ;; Compute the number of stack arguments, and if it's zero or
 326       ;; less, don't copy any stack arguments.
 327       (inst sub ecx-tn (fixnumize register-arg-count))
 328       (inst jmp :le no-stack-args)
 329
 330       ;; Throw away any unwanted args.
 331       (inst cmp ecx-tn (fixnumize (- nvals register-arg-count)))
 332       (inst jmp :be count-okay)
 333       (inst mov ecx-tn (fixnumize (- nvals register-arg-count)))
 334       (emit-label count-okay)
 335       ;; Save the number of stack values.
 336       (inst mov eax-tn ecx-tn)
 337       ;; Compute a pointer to where the stack args go.
 338       (inst lea edi-tn
 339             (make-ea :dword :base ebp-tn
 340                      :disp (* (- (1+ register-arg-count)) n-word-bytes)))
 341       ;; Save ESI, and compute a pointer to where the args come from.
 342       (storew esi-tn ebx-tn (- (1+ 2)))
 343       (inst lea esi-tn
 344             (make-ea :dword :base ebx-tn
 345                      :disp (* (- (1+ register-arg-count)) n-word-bytes)))
 346       ;; Do the copy.
 347       (inst shr ecx-tn word-shift)              ; make word count
 348       (inst std)
 349       (inst rep)
 350       (inst movs :dword)
 351       ;; solaris requires DF being zero.
 352       #!+sunos (inst cld)
 353       ;; Restore ESI.
 354       (loadw esi-tn ebx-tn (- (1+ 2)))
 355       ;; Now we have to default the remaining args. Find out how many.
 356       (inst sub eax-tn (fixnumize (- nvals register-arg-count)))
 357       (inst neg eax-tn)
 358       ;; If none, then just blow out of here.
 359       (inst jmp :le restore-edi)
 360       (inst mov ecx-tn eax-tn)
 361       (inst shr ecx-tn word-shift)      ; word count
 362       ;; Load EAX with NIL for fast storing.
 363       (inst mov eax-tn nil-value)
 364       ;; Do the store.
 365       (emit-label default-stack-vals)
 366       (inst rep)
 367       (inst stos eax-tn)
 368       ;; solaris requires DF being zero.
 369       #!+sunos (inst cld)
 370       ;; Restore EDI, and reset the stack.
 371       (emit-label restore-edi)
 372       (loadw edi-tn ebx-tn (- (1+ 1)))
 373       (inst mov esp-tn ebx-tn))))
 374   (values))
 375 \f
 376 ;;;; unknown values receiving
 377
 378 ;;; Emit code needed at the return point for an unknown-values call
 379 ;;; for an arbitrary number of values.
 380 ;;;
 381 ;;; We do the single and non-single cases with no shared code: there
 382 ;;; doesn't seem to be any potential overlap, and receiving a single
 383 ;;; value is more important efficiency-wise.
 384 ;;;
 385 ;;; When there is a single value, we just push it on the stack,
 386 ;;; returning the old SP and 1.
 387 ;;;
 388 ;;; When there is a variable number of values, we move all of the
 389 ;;; argument registers onto the stack, and return ARGS and NARGS.
 390 ;;;
 391 ;;; ARGS and NARGS are TNs wired to the named locations. We must
 392 ;;; explicitly allocate these TNs, since their lifetimes overlap with
 393 ;;; the results start and count. (Also, it's nice to be able to target
 394 ;;; them.)
 395 (defun receive-unknown-values (args nargs start count)
 396   (declare (type tn args nargs start count))
 397   (let ((variable-values (gen-label))
 398         (done (gen-label)))
 399     (inst jmp :c variable-values)
 400
 401     (cond ((location= start (first *register-arg-tns*))
 402            (inst push (first *register-arg-tns*))
 403            (inst lea start (make-ea :dword :base esp-tn :disp 4)))
 404           (t (inst mov start esp-tn)
 405              (inst push (first *register-arg-tns*))))
 406     (inst mov count (fixnumize 1))
 407     (inst jmp done)
 408
 409     (emit-label variable-values)
 410     ;; dtc: this writes the registers onto the stack even if they are
 411     ;; not needed, only the number specified in ecx are used and have
 412     ;; stack allocated to them. No harm is done.
 413     (loop
 414       for arg in *register-arg-tns*
 415       for i downfrom -1
 416       do (storew arg args i))
 417     (move start args)
 418     (move count nargs)
 419
 420     (emit-label done))
 421   (values))
 422
 423 ;;; VOP that can be inherited by unknown values receivers. The main thing this
 424 ;;; handles is allocation of the result temporaries.
 425 (define-vop (unknown-values-receiver)
 426   (:temporary (:sc descriptor-reg :offset ebx-offset
 427                    :from :eval :to (:result 0))
 428               values-start)
 429   (:temporary (:sc any-reg :offset ecx-offset
 430                :from :eval :to (:result 1))
 431               nvals)
 432   (:results (start :scs (any-reg control-stack))
 433             (count :scs (any-reg control-stack))))
 434 \f
 435 ;;;; local call with unknown values convention return
 436
 437 ;;; Non-TR local call for a fixed number of values passed according to
 438 ;;; the unknown values convention.
 439 ;;;
 440 ;;; FP is the frame pointer in install before doing the call.
 441 ;;;
 442 ;;; NFP would be the number-stack frame pointer if we had a separate
 443 ;;; number stack.
 444 ;;;
 445 ;;; Args are the argument passing locations, which are specified only
 446 ;;; to terminate their lifetimes in the caller.
 447 ;;;
 448 ;;; VALUES are the return value locations (wired to the standard
 449 ;;; passing locations). NVALS is the number of values received.
 450 ;;;
 451 ;;; Save is the save info, which we can ignore since saving has been
 452 ;;; done.
 453 ;;;
 454 ;;; TARGET is a continuation pointing to the start of the called
 455 ;;; function.
 456 (define-vop (call-local)
 457   (:args (fp)
 458          (nfp)
 459          (args :more t))
 460   (:results (values :more t))
 461   (:save-p t)
 462   (:move-args :local-call)
 463   (:info arg-locs callee target nvals)
 464   (:vop-var vop)
 465   (:ignore nfp arg-locs args #+nil callee)
 466   (:generator 5
 467     (trace-table-entry trace-table-call-site)
 468     (move ebp-tn fp)
 469
 470     (let ((ret-tn (callee-return-pc-tn callee)))
 471       #+nil
 472       (format t "*call-local ~S; tn-kind ~S; tn-save-tn ~S; its tn-kind ~S~%"
 473               ret-tn (sb!c::tn-kind ret-tn) (sb!c::tn-save-tn ret-tn)
 474               (sb!c::tn-kind (sb!c::tn-save-tn ret-tn)))
 475
 476       ;; Is the return-pc on the stack or in a register?
 477       (sc-case ret-tn
 478         ((sap-stack)
 479          #+nil (format t "*call-local: ret-tn on stack; offset=~S~%"
 480                        (tn-offset ret-tn))
 481          (storew (make-fixup nil :code-object return)
 482                  ebp-tn (- (1+ (tn-offset ret-tn)))))
 483         ((sap-reg)
 484          (inst lea ret-tn (make-fixup nil :code-object return)))))
 485
 486     (note-this-location vop :call-site)
 487     (inst jmp target)
 488     RETURN
 489     (default-unknown-values vop values nvals)
 490     (trace-table-entry trace-table-normal)))
 491
 492 ;;; Non-TR local call for a variable number of return values passed according
 493 ;;; to the unknown values convention. The results are the start of the values
 494 ;;; glob and the number of values received.
 495 (define-vop (multiple-call-local unknown-values-receiver)
 496   (:args (fp)
 497          (nfp)
 498          (args :more t))
 499   (:save-p t)
 500   (:move-args :local-call)
 501   (:info save callee target)
 502   (:ignore args save nfp #+nil callee)
 503   (:vop-var vop)
 504   (:generator 20
 505     (trace-table-entry trace-table-call-site)
 506     (move ebp-tn fp)
 507
 508     (let ((ret-tn (callee-return-pc-tn callee)))
 509       #+nil
 510       (format t "*multiple-call-local ~S; tn-kind ~S; tn-save-tn ~S; its tn-kind ~S~%"
 511               ret-tn (sb!c::tn-kind ret-tn) (sb!c::tn-save-tn ret-tn)
 512               (sb!c::tn-kind (sb!c::tn-save-tn ret-tn)))
 513
 514       ;; Is the return-pc on the stack or in a register?
 515       (sc-case ret-tn
 516         ((sap-stack)
 517          #+nil (format t "*multiple-call-local: ret-tn on stack; offset=~S~%"
 518                        (tn-offset ret-tn))
 519          ;; Stack
 520          (storew (make-fixup nil :code-object return)
 521                  ebp-tn (- (1+ (tn-offset ret-tn)))))
 522         ((sap-reg)
 523          ;; Register
 524          (inst lea ret-tn (make-fixup nil :code-object return)))))
 525
 526     (note-this-location vop :call-site)
 527     (inst jmp target)
 528     RETURN
 529     (note-this-location vop :unknown-return)
 530     (receive-unknown-values values-start nvals start count)
 531     (trace-table-entry trace-table-normal)))
 532 \f
 533 ;;;; local call with known values return
 534
 535 ;;; Non-TR local call with known return locations. Known-value return
 536 ;;; works just like argument passing in local call.
 537 ;;;
 538 ;;; Note: we can't use normal load-tn allocation for the fixed args,
 539 ;;; since all registers may be tied up by the more operand. Instead,
 540 ;;; we use MAYBE-LOAD-STACK-TN.
 541 (define-vop (known-call-local)
 542   (:args (fp)
 543          (nfp)
 544          (args :more t))
 545   (:results (res :more t))
 546   (:move-args :local-call)
 547   (:save-p t)
 548   (:info save callee target)
 549   (:ignore args res save nfp #+nil callee)
 550   (:vop-var vop)
 551   (:generator 5
 552     (trace-table-entry trace-table-call-site)
 553     (move ebp-tn fp)
 554
 555     (let ((ret-tn (callee-return-pc-tn callee)))
 556
 557       #+nil
 558       (format t "*known-call-local ~S; tn-kind ~S; tn-save-tn ~S; its tn-kind ~S~%"
 559               ret-tn (sb!c::tn-kind ret-tn) (sb!c::tn-save-tn ret-tn)
 560               (sb!c::tn-kind (sb!c::tn-save-tn ret-tn)))
 561
 562       ;; Is the return-pc on the stack or in a register?
 563       (sc-case ret-tn
 564         ((sap-stack)
 565          #+nil (format t "*known-call-local: ret-tn on stack; offset=~S~%"
 566                        (tn-offset ret-tn))
 567          ;; Stack
 568          (storew (make-fixup nil :code-object return)
 569                  ebp-tn (- (1+ (tn-offset ret-tn)))))
 570         ((sap-reg)
 571          ;; Register
 572          (inst lea ret-tn (make-fixup nil :code-object return)))))
 573
 574     (note-this-location vop :call-site)
 575     (inst jmp target)
 576     RETURN
 577     (note-this-location vop :known-return)
 578     (trace-table-entry trace-table-normal)))
 579 \f
 580 ;;; Return from known values call. We receive the return locations as
 581 ;;; arguments to terminate their lifetimes in the returning function. We
 582 ;;; restore FP and CSP and jump to the Return-PC.
 583 ;;;
 584 ;;; We can assume we know exactly where old-fp and return-pc are because
 585 ;;; make-old-fp-save-location and make-return-pc-save-location always
 586 ;;; return the same place.
 587 #+nil
 588 (define-vop (known-return)
 589   (:args (old-fp)
 590          (return-pc :scs (any-reg immediate-stack) :target rpc)
 591          (vals :more t))
 592   (:move-args :known-return)
 593   (:info val-locs)
 594   (:temporary (:sc unsigned-reg :from (:argument 1)) rpc)
 595   (:ignore val-locs vals)
 596   (:vop-var vop)
 597   (:generator 6
 598     (trace-table-entry trace-table-fun-epilogue)
 599     ;; Save the return-pc in a register 'cause the frame-pointer is
 600     ;; going away. Note this not in the usual stack location so we
 601     ;; can't use RET
 602     (move rpc return-pc)
 603     ;; Restore the stack.
 604     (move esp-tn ebp-tn)
 605     ;; Restore the old fp. We know OLD-FP is going to be in its stack
 606     ;; save slot, which is a different frame that than this one,
 607     ;; so we don't have to worry about having just cleared
 608     ;; most of the stack.
 609     (move ebp-tn old-fp)
 610     (inst jmp rpc)
 611     (trace-table-entry trace-table-normal)))
 612 \f
 613 ;;; From Douglas Crosher
 614 ;;; Return from known values call. We receive the return locations as
 615 ;;; arguments to terminate their lifetimes in the returning function. We
 616 ;;; restore FP and CSP and jump to the Return-PC.
 617 ;;;
 618 ;;; The old-fp may be either in a register or on the stack in its
 619 ;;; standard save locations - slot 0.
 620 ;;;
 621 ;;; The return-pc may be in a register or on the stack in any slot.
 622 (define-vop (known-return)
 623   (:args (old-fp)
 624          (return-pc)
 625          (vals :more t))
 626   (:move-args :known-return)
 627   (:info val-locs)
 628   (:ignore val-locs vals)
 629   (:vop-var vop)
 630   (:generator 6
 631     (trace-table-entry trace-table-fun-epilogue)
 632
 633     #+nil (format t "*known-return: old-fp ~S, tn-kind ~S; ~S ~S~%"
 634                   old-fp (sb!c::tn-kind old-fp) (sb!c::tn-save-tn old-fp)
 635                   (sb!c::tn-kind (sb!c::tn-save-tn old-fp)))
 636
 637     #+nil (format t "*known-return: return-pc ~S, tn-kind ~S; ~S ~S~%"
 638                   return-pc (sb!c::tn-kind return-pc)
 639                   (sb!c::tn-save-tn return-pc)
 640                   (sb!c::tn-kind (sb!c::tn-save-tn return-pc)))
 641
 642     ;; return-pc may be either in a register or on the stack.
 643     (sc-case return-pc
 644       ((sap-reg)
 645        (sc-case old-fp
 646          ((control-stack)
 647
 648           #+nil (format t "*known-return: old-fp ~S on stack; offset=~S~%"
 649                         old-fp (tn-offset old-fp))
 650
 651           (cond ((zerop (tn-offset old-fp))
 652                  ;; Zot all of the stack except for the old-fp.
 653                  (inst lea esp-tn (make-ea :dword :base ebp-tn
 654                                            :disp (- (* (1+ ocfp-save-offset)
 655                                                        n-word-bytes))))
 656                  ;; Restore the old fp from its save location on the stack,
 657                  ;; and zot the stack.
 658                  (inst pop ebp-tn))
 659
 660                 (t
 661                  (cerror "Continue anyway"
 662                          "VOP return-local doesn't work if old-fp (in slot ~
 663                           ~S) is not in slot 0"
 664                          (tn-offset old-fp)))))
 665
 666          ((any-reg descriptor-reg)
 667           ;; Zot all the stack.
 668           (move esp-tn ebp-tn)
 669           ;; Restore the old-fp.
 670           (move ebp-tn old-fp)))
 671
 672        ;; Return; return-pc is in a register.
 673        (inst jmp return-pc))
 674
 675       ((sap-stack)
 676
 677        #+nil (format t "*known-return: return-pc ~S on stack; offset=~S~%"
 678                      return-pc (tn-offset return-pc))
 679
 680        ;; Zot all of the stack except for the old-fp and return-pc.
 681        (inst lea esp-tn
 682              (make-ea :dword :base ebp-tn
 683                       :disp (- (* (1+ (tn-offset return-pc)) n-word-bytes))))
 684        ;; Restore the old fp. old-fp may be either on the stack in its
 685        ;; save location or in a register, in either case this restores it.
 686        (move ebp-tn old-fp)
 687        ;; The return pops the return address (4 bytes), then we need
 688        ;; to pop all the slots before the return-pc which includes the
 689        ;; 4 bytes for the old-fp.
 690        (inst ret (* (tn-offset return-pc) n-word-bytes))))
 691
 692     (trace-table-entry trace-table-normal)))
 693 \f
 694 ;;;; full call
 695 ;;;
 696 ;;; There is something of a cross-product effect with full calls.
 697 ;;; Different versions are used depending on whether we know the
 698 ;;; number of arguments or the name of the called function, and
 699 ;;; whether we want fixed values, unknown values, or a tail call.
 700 ;;;
 701 ;;; In full call, the arguments are passed creating a partial frame on
 702 ;;; the stack top and storing stack arguments into that frame. On
 703 ;;; entry to the callee, this partial frame is pointed to by FP.
 704
 705 ;;; This macro helps in the definition of full call VOPs by avoiding
 706 ;;; code replication in defining the cross-product VOPs.
 707 ;;;
 708 ;;; NAME is the name of the VOP to define.
 709 ;;;
 710 ;;; NAMED is true if the first argument is an fdefinition object whose
 711 ;;; definition is to be called.
 712 ;;;
 713 ;;; RETURN is either :FIXED, :UNKNOWN or :TAIL:
 714 ;;; -- If :FIXED, then the call is for a fixed number of values, returned in
 715 ;;;    the standard passing locations (passed as result operands).
 716 ;;; -- If :UNKNOWN, then the result values are pushed on the stack, and the
 717 ;;;    result values are specified by the Start and Count as in the
 718 ;;;    unknown-values continuation representation.
 719 ;;; -- If :TAIL, then do a tail-recursive call. No values are returned.
 720 ;;;    The Old-Fp and Return-PC are passed as the second and third arguments.
 721 ;;;
 722 ;;; In non-tail calls, the pointer to the stack arguments is passed as
 723 ;;; the last fixed argument. If Variable is false, then the passing
 724 ;;; locations are passed as a more arg. Variable is true if there are
 725 ;;; a variable number of arguments passed on the stack. Variable
 726 ;;; cannot be specified with :TAIL return. TR variable argument call
 727 ;;; is implemented separately.
 728 ;;;
 729 ;;; In tail call with fixed arguments, the passing locations are
 730 ;;; passed as a more arg, but there is no new-FP, since the arguments
 731 ;;; have been set up in the current frame.
 732 (macrolet ((define-full-call (name named return variable)
 733             (aver (not (and variable (eq return :tail))))
 734             `(define-vop (,name
 735                           ,@(when (eq return :unknown)
 736                               '(unknown-values-receiver)))
 737                (:args
 738                ,@(unless (eq return :tail)
 739                    '((new-fp :scs (any-reg) :to (:argument 1))))
 740
 741                (fun :scs (descriptor-reg control-stack)
 742                     :target eax :to (:argument 0))
 743
 744                ,@(when (eq return :tail)
 745                    '((old-fp)
 746                      (return-pc)))
 747
 748                ,@(unless variable '((args :more t :scs (descriptor-reg)))))
 749
 750                ,@(when (eq return :fixed)
 751                '((:results (values :more t))))
 752
 753                (:save-p ,(if (eq return :tail) :compute-only t))
 754
 755                ,@(unless (or (eq return :tail) variable)
 756                '((:move-args :full-call)))
 757
 758                (:vop-var vop)
 759                (:info
 760                ,@(unless (or variable (eq return :tail)) '(arg-locs))
 761                ,@(unless variable '(nargs))
 762                ,@(when (eq return :fixed) '(nvals))
 763                step-instrumenting)
 764
 765                (:ignore
 766                ,@(unless (or variable (eq return :tail)) '(arg-locs))
 767                ,@(unless variable '(args)))
 768
 769                ;; We pass either the fdefn object (for named call) or
 770                ;; the actual function object (for unnamed call) in
 771                ;; EAX. With named call, closure-tramp will replace it
 772                ;; with the real function and invoke the real function
 773                ;; for closures. Non-closures do not need this value,
 774                ;; so don't care what shows up in it.
 775                (:temporary
 776                (:sc descriptor-reg
 777                     :offset eax-offset
 778                     :from (:argument 0)
 779                     :to :eval)
 780                eax)
 781
 782                ;; We pass the number of arguments in ECX.
 783                (:temporary (:sc unsigned-reg :offset ecx-offset :to :eval) ecx)
 784
 785                ;; With variable call, we have to load the
 786                ;; register-args out of the (new) stack frame before
 787                ;; doing the call. Therefore, we have to tell the
 788                ;; lifetime stuff that we need to use them.
 789                ,@(when variable
 790                    (mapcar (lambda (name offset)
 791                              `(:temporary (:sc descriptor-reg
 792                                                :offset ,offset
 793                                                :from (:argument 0)
 794                                                :to :eval)
 795                                           ,name))
 796                            *register-arg-names* *register-arg-offsets*))
 797
 798                ,@(when (eq return :tail)
 799                    '((:temporary (:sc unsigned-reg
 800                                       :from (:argument 1)
 801                                       :to (:argument 2))
 802                                  old-fp-tmp)))
 803
 804                (:generator ,(+ (if named 5 0)
 805                                (if variable 19 1)
 806                                (if (eq return :tail) 0 10)
 807                                15
 808                                (if (eq return :unknown) 25 0))
 809                (trace-table-entry trace-table-call-site)
 810
 811                ;; This has to be done before the frame pointer is
 812                ;; changed! EAX stores the 'lexical environment' needed
 813                ;; for closures.
 814                (move eax fun)
 815
 816
 817                ,@(if variable
 818                      ;; For variable call, compute the number of
 819                      ;; arguments and move some of the arguments to
 820                      ;; registers.
 821                      (collect ((noise))
 822                               ;; Compute the number of arguments.
 823                               (noise '(inst mov ecx new-fp))
 824                               (noise '(inst sub ecx esp-tn))
 825                               ;; Move the necessary args to registers,
 826                               ;; this moves them all even if they are
 827                               ;; not all needed.
 828                               (loop
 829                                for name in *register-arg-names*
 830                                for index downfrom -1
 831                                do (noise `(loadw ,name new-fp ,index)))
 832                               (noise))
 833                    '((if (zerop nargs)
 834                          (inst xor ecx ecx)
 835                        (inst mov ecx (fixnumize nargs)))))
 836                ,@(cond ((eq return :tail)
 837                         '(;; Python has figured out what frame we should
 838                           ;; return to so might as well use that clue.
 839                           ;; This seems really important to the
 840                           ;; implementation of things like
 841                           ;; (without-interrupts ...)
 842                           ;;
 843                           ;; dtc; Could be doing a tail call from a
 844                           ;; known-local-call etc in which the old-fp
 845                           ;; or ret-pc are in regs or in non-standard
 846                           ;; places. If the passing location were
 847                           ;; wired to the stack in standard locations
 848                           ;; then these moves will be un-necessary;
 849                           ;; this is probably best for the x86.
 850                           (sc-case old-fp
 851                                    ((control-stack)
 852                                     (unless (= ocfp-save-offset
 853                                                (tn-offset old-fp))
 854                                       ;; FIXME: FORMAT T for stale
 855                                       ;; diagnostic output (several of
 856                                       ;; them around here), ick
 857                                       (format t "** tail-call old-fp not S0~%")
 858                                       (move old-fp-tmp old-fp)
 859                                       (storew old-fp-tmp
 860                                               ebp-tn
 861                                               (- (1+ ocfp-save-offset)))))
 862                                    ((any-reg descriptor-reg)
 863                                     (format t "** tail-call old-fp in reg not S0~%")
 864                                     (storew old-fp
 865                                             ebp-tn
 866                                             (- (1+ ocfp-save-offset)))))
 867
 868                           ;; For tail call, we have to push the
 869                           ;; return-pc so that it looks like we CALLed
 870                           ;; despite the fact that we are going to JMP.
 871                           (inst push return-pc)
 872                           ))
 873                        (t
 874                         ;; For non-tail call, we have to save our
 875                         ;; frame pointer and install the new frame
 876                         ;; pointer. We can't load stack tns after this
 877                         ;; point.
 878                         `(;; Python doesn't seem to allocate a frame
 879                           ;; here which doesn't leave room for the
 880                           ;; ofp/ret stuff.
 881
 882                           ;; The variable args are on the stack and
 883                           ;; become the frame, but there may be <3
 884                           ;; args and 3 stack slots are assumed
 885                           ;; allocate on the call. So need to ensure
 886                           ;; there are at least 3 slots. This hack
 887                           ;; just adds 3 more.
 888                           ,(if variable
 889                                '(inst sub esp-tn (fixnumize 3)))
 890
 891                           ;; Save the fp
 892                           (storew ebp-tn new-fp (- (1+ ocfp-save-offset)))
 893
 894                           (move ebp-tn new-fp) ; NB - now on new stack frame.
 895                           )))
 896
 897                (when step-instrumenting
 898                  (emit-single-step-test)
 899                  (inst jmp :eq DONE)
 900                  (inst break single-step-around-trap))
 901                DONE
 902
 903                (note-this-location vop :call-site)
 904
 905                (inst ,(if (eq return :tail) 'jmp 'call)
 906                      (make-ea :dword :base eax
 907                               :disp ,(if named
 908                                          '(- (* fdefn-raw-addr-slot
 909                                                 n-word-bytes)
 910                                              other-pointer-lowtag)
 911                                        '(- (* closure-fun-slot n-word-bytes)
 912                                            fun-pointer-lowtag))))
 913                ,@(ecase return
 914                    (:fixed
 915                     '((default-unknown-values vop values nvals)))
 916                    (:unknown
 917                     '((note-this-location vop :unknown-return)
 918                       (receive-unknown-values values-start nvals start count)))
 919                    (:tail))
 920                (trace-table-entry trace-table-normal)))))
 921
 922   (define-full-call call nil :fixed nil)
 923   (define-full-call call-named t :fixed nil)
 924   (define-full-call multiple-call nil :unknown nil)
 925   (define-full-call multiple-call-named t :unknown nil)
 926   (define-full-call tail-call nil :tail nil)
 927   (define-full-call tail-call-named t :tail nil)
 928
 929   (define-full-call call-variable nil :fixed t)
 930   (define-full-call multiple-call-variable nil :unknown t))
 931
 932 ;;; This is defined separately, since it needs special code that BLT's
 933 ;;; the arguments down. All the real work is done in the assembly
 934 ;;; routine. We just set things up so that it can find what it needs.
 935 (define-vop (tail-call-variable)
 936   (:args (args :scs (any-reg control-stack) :target esi)
 937          (function :scs (descriptor-reg control-stack) :target eax)
 938          (old-fp)
 939          (ret-addr))
 940   (:temporary (:sc unsigned-reg :offset esi-offset :from (:argument 0)) esi)
 941   (:temporary (:sc unsigned-reg :offset eax-offset :from (:argument 1)) eax)
 942 ;  (:ignore ret-addr old-fp)
 943   (:generator 75
 944     ;; Move these into the passing locations if they are not already there.
 945     (move esi args)
 946     (move eax function)
 947
 948     ;; The following assumes that the return-pc and old-fp are on the
 949     ;; stack in their standard save locations - Check this.
 950     (unless (and (sc-is old-fp control-stack)
 951                  (= (tn-offset old-fp) ocfp-save-offset))
 952             (error "tail-call-variable: ocfp not on stack in standard save location?"))
 953     (unless (and (sc-is ret-addr sap-stack)
 954                  (= (tn-offset ret-addr) return-pc-save-offset))
 955             (error "tail-call-variable: ret-addr not on stack in standard save location?"))
 956
 957
 958     ;; And jump to the assembly routine.
 959     (inst jmp (make-fixup 'tail-call-variable :assembly-routine))))
 960 \f
 961 ;;;; unknown values return
 962
 963 ;;; Return a single-value using the Unknown-Values convention. Specifically,
 964 ;;; we jump to clear the stack and jump to return-pc+2.
 965 ;;;
 966 ;;; We require old-fp to be in a register, because we want to reset ESP before
 967 ;;; restoring EBP. If old-fp were still on the stack, it could get clobbered
 968 ;;; by a signal.
 969 ;;;
 970 ;;; pfw--get wired-tn conflicts sometimes if register sc specd for args
 971 ;;; having problems targeting args to regs -- using temps instead.
 972 ;;;
 973 ;;; First off, modifying the return-pc defeats the branch-prediction
 974 ;;; optimizations on modern CPUs quite handily. Second, we can do all
 975 ;;; this without needing a temp register. Fixed the latter, at least.
 976 ;;; -- AB 2006/Feb/04
 977 (define-vop (return-single)
 978   (:args (old-fp)
 979          (return-pc)
 980          (value))
 981   (:ignore value)
 982   (:generator 6
 983     (trace-table-entry trace-table-fun-epilogue)
 984     ;; Code structure lifted from known-return.
 985     (sc-case return-pc
 986       ((sap-reg)
 987        ;; return PC in register for some reason (local call?)
 988        ;; we jmp to the return pc after fixing the stack and frame.
 989        (sc-case old-fp
 990          ((control-stack)
 991           ;; ofp on stack must be in slot 0 (the traditional storage place).
 992           ;; Drop the stack above it and pop it off.
 993           (cond ((zerop (tn-offset old-fp))
 994                  (inst lea esp-tn (make-ea :dword :base ebp-tn
 995                                            :disp (- (* (1+ ocfp-save-offset)
 996                                                        n-word-bytes))))
 997                  (inst pop ebp-tn))
 998                 (t
 999                  ;; Should this ever happen, we do the same as above, but
1000                  ;; using (tn-offset old-fp) instead of ocfp-save-offset
1001                  ;; (which is 0 anyway, see src/compiler/x86/vm.lisp) and
1002                  ;; then lea esp again against itself with a displacement
1003                  ;; of (* (tn-offset old-fp) n-word-bytes) to clear the
1004                  ;; rest of the stack.
1005                  (cerror "Continue anyway"
1006                          "VOP return-single doesn't work if old-fp (in slot ~S) is not in slot 0" (tn-offset old-fp)))))
1007          ((any-reg descriptor-reg)
1008           ;; ofp in reg, drop the stack and load the real fp.
1009           (move esp-tn ebp-tn)
1010           (move ebp-tn old-fp)))
1011
1012        ;; Set single-value-return flag
1013        (inst clc)
1014        ;; And return
1015        (inst jmp return-pc))
1016
1017       ((sap-stack)
1018        ;; Note that this will only work right if, when old-fp is on
1019        ;; the stack, it has a lower tn-offset than return-pc. One of
1020        ;; the comments in known-return indicate that this is the case
1021        ;; (in that it will be in its save location), but we may wish
1022        ;; to assert that (in either the weaker or stronger forms).
1023        ;; Should this ever not be the case, we should load old-fp
1024        ;; into a temp reg while we fix the stack.
1025        ;; Drop stack above return-pc
1026        (inst lea esp-tn (make-ea :dword :base ebp-tn
1027                                  :disp (- (* (1+ (tn-offset return-pc))
1028                                              n-word-bytes))))
1029        ;; Set single-value return flag
1030        (inst clc)
1031        ;; Restore the old frame pointer
1032        (move ebp-tn old-fp)
1033        ;; And return, dropping the rest of the stack as we go.
1034        (inst ret (* (tn-offset return-pc) n-word-bytes))))))
1035
1036 ;;; Do unknown-values return of a fixed (other than 1) number of
1037 ;;; values. The VALUES are required to be set up in the standard
1038 ;;; passing locations. NVALS is the number of values returned.
1039 ;;;
1040 ;;; Basically, we just load ECX with the number of values returned and
1041 ;;; EBX with a pointer to the values, set ESP to point to the end of
1042 ;;; the values, and jump directly to return-pc.
1043 (define-vop (return)
1044   (:args (old-fp)
1045          (return-pc :to (:eval 1))
1046          (values :more t))
1047   (:ignore values)
1048   (:info nvals)
1049
1050   ;; In the case of other than one value, we need these registers to
1051   ;; tell the caller where they are and how many there are.
1052   (:temporary (:sc unsigned-reg :offset ebx-offset) ebx)
1053   (:temporary (:sc unsigned-reg :offset ecx-offset) ecx)
1054
1055   ;; We need to stretch the lifetime of return-pc past the argument
1056   ;; registers so that we can default the argument registers without
1057   ;; trashing return-pc.
1058   (:temporary (:sc unsigned-reg :offset (first *register-arg-offsets*)
1059                    :from :eval) a0)
1060   (:temporary (:sc unsigned-reg :offset (second *register-arg-offsets*)
1061                    :from :eval) a1)
1062   (:temporary (:sc unsigned-reg :offset (third *register-arg-offsets*)
1063                    :from :eval) a2)
1064
1065   (:generator 6
1066     (trace-table-entry trace-table-fun-epilogue)
1067     ;; Establish the values pointer and values count.
1068     (move ebx ebp-tn)
1069     (if (zerop nvals)
1070         (inst xor ecx ecx) ; smaller
1071       (inst mov ecx (fixnumize nvals)))
1072     ;; Restore the frame pointer.
1073     (move ebp-tn old-fp)
1074     ;; Clear as much of the stack as possible, but not past the return
1075     ;; address.
1076     (inst lea esp-tn (make-ea :dword :base ebx
1077                               :disp (- (* (max nvals 2) n-word-bytes))))
1078     ;; Pre-default any argument register that need it.
1079     (when (< nvals register-arg-count)
1080       (let* ((arg-tns (nthcdr nvals (list a0 a1 a2)))
1081              (first (first arg-tns)))
1082         (inst mov first nil-value)
1083         (dolist (tn (cdr arg-tns))
1084           (inst mov tn first))))
1085     ;; Set multi-value return flag.
1086     (inst stc)
1087     ;; And away we go. Except that return-pc is still on the
1088     ;; stack and we've changed the stack pointer. So we have to
1089     ;; tell it to index off of EBX instead of EBP.
1090     (cond ((zerop nvals)
1091            ;; Return popping the return address and the OCFP.
1092            (inst ret n-word-bytes))
1093           ((= nvals 1)
1094            ;; Return popping the return, leaving 1 slot. Can this
1095            ;; happen, or is a single value return handled elsewhere?
1096            (inst ret))
1097           (t
1098            (inst jmp (make-ea :dword :base ebx
1099                               :disp (- (* (1+ (tn-offset return-pc))
1100                                           n-word-bytes))))))
1101
1102     (trace-table-entry trace-table-normal)))
1103
1104 ;;; Do unknown-values return of an arbitrary number of values (passed
1105 ;;; on the stack.) We check for the common case of a single return
1106 ;;; value, and do that inline using the normal single value return
1107 ;;; convention. Otherwise, we branch off to code that calls an
1108 ;;; assembly-routine.
1109 ;;;
1110 ;;; The assembly routine takes the following args:
1111 ;;;  EAX -- the return-pc to finally jump to.
1112 ;;;  EBX -- pointer to where to put the values.
1113 ;;;  ECX -- number of values to find there.
1114 ;;;  ESI -- pointer to where to find the values.
1115 (define-vop (return-multiple)
1116   (:args (old-fp :to (:eval 1) :target old-fp-temp)
1117          (return-pc :target eax)
1118          (vals :scs (any-reg) :target esi)
1119          (nvals :scs (any-reg) :target ecx))
1120
1121   (:temporary (:sc unsigned-reg :offset eax-offset :from (:argument 1)) eax)
1122   (:temporary (:sc unsigned-reg :offset esi-offset :from (:argument 2)) esi)
1123   (:temporary (:sc unsigned-reg :offset ecx-offset :from (:argument 3)) ecx)
1124   (:temporary (:sc unsigned-reg :offset ebx-offset :from (:eval 0)) ebx)
1125   (:temporary (:sc descriptor-reg :offset (first *register-arg-offsets*)
1126                    :from (:eval 0)) a0)
1127   (:temporary (:sc unsigned-reg :from (:eval 1)) old-fp-temp)
1128   (:node-var node)
1129
1130   (:generator 13
1131     (trace-table-entry trace-table-fun-epilogue)
1132     ;; Load the return-pc.
1133     (move eax return-pc)
1134     (unless (policy node (> space speed))
1135       ;; Check for the single case.
1136       (let ((not-single (gen-label)))
1137         (inst cmp nvals (fixnumize 1))
1138         (inst jmp :ne not-single)
1139
1140         ;; Return with one value.
1141         (loadw a0 vals -1)
1142         ;; Clear the stack. We load old-fp into a register before clearing
1143         ;; the stack.
1144         (move old-fp-temp old-fp)
1145         (move esp-tn ebp-tn)
1146         (move ebp-tn old-fp-temp)
1147         ;; Set the single-value return flag.
1148         (inst clc)
1149         ;; Out of here.
1150         (inst jmp eax)
1151
1152         ;; Nope, not the single case. Jump to the assembly routine.
1153         (emit-label not-single)))
1154     (move esi vals)
1155     (move ecx nvals)
1156     (move ebx ebp-tn)
1157     (move ebp-tn old-fp)
1158     (inst jmp (make-fixup 'return-multiple :assembly-routine))
1159     (trace-table-entry trace-table-normal)))
1160 \f
1161 ;;;; XEP hackery
1162
1163 ;;; We don't need to do anything special for regular functions.
1164 (define-vop (setup-environment)
1165   (:info label)
1166   (:ignore label)
1167   (:generator 0
1168     ;; Don't bother doing anything.
1169     nil))
1170
1171 ;;; Get the lexical environment from its passing location.
1172 (define-vop (setup-closure-environment)
1173   (:results (closure :scs (descriptor-reg)))
1174   (:info label)
1175   (:ignore label)
1176   (:generator 6
1177     ;; Get result.
1178     (move closure eax-tn)))
1179
1180 ;;; Copy a &MORE arg from the argument area to the end of the current
1181 ;;; frame. FIXED is the number of non-&MORE arguments.
1182 ;;;
1183 ;;; The tricky part is doing this without trashing any of the calling
1184 ;;; convention registers that are still needed. This vop is emitted
1185 ;;; directly after the xep-allocate frame. That means the registers
1186 ;;; are in use as follows:
1187 ;;;
1188 ;;;  EAX -- The lexenv.
1189 ;;;  EBX -- Available.
1190 ;;;  ECX -- The total number of arguments.
1191 ;;;  EDX -- The first arg.
1192 ;;;  EDI -- The second arg.
1193 ;;;  ESI -- The third arg.
1194 ;;;
1195 ;;; So basically, we have one register available for our use: EBX.
1196 ;;;
1197 ;;; What we can do is push the other regs onto the stack, and then
1198 ;;; restore their values by looking directly below where we put the
1199 ;;; more-args.
1200 (define-vop (copy-more-arg)
1201   (:info fixed)
1202   (:generator 20
1203     ;; Avoid the copy if there are no more args.
1204     (cond ((zerop fixed)
1205            (inst jecxz just-alloc-frame))
1206           (t
1207            (inst cmp ecx-tn (fixnumize fixed))
1208            (inst jmp :be just-alloc-frame)))
1209
1210     ;; Allocate the space on the stack.
1211     ;; stack = ebp - (max 3 frame-size) - (nargs - fixed)
1212     (inst lea ebx-tn
1213           (make-ea :dword :base ebp-tn
1214                    :disp (- (fixnumize fixed)
1215                             (* n-word-bytes
1216                                (max 3 (sb-allocated-size 'stack))))))
1217     (inst sub ebx-tn ecx-tn)  ; Got the new stack in ebx
1218     (inst mov esp-tn ebx-tn)
1219
1220     ;; Now: nargs>=1 && nargs>fixed
1221
1222     ;; Save the original count of args.
1223     (inst mov ebx-tn ecx-tn)
1224
1225     (cond ((< fixed register-arg-count)
1226            ;; We must stop when we run out of stack args, not when we
1227            ;; run out of more args.
1228            ;; Number to copy = nargs-3
1229            (inst sub ecx-tn (fixnumize register-arg-count))
1230            ;; Everything of interest in registers.
1231            (inst jmp :be do-regs))
1232           (t
1233            ;; Number to copy = nargs-fixed
1234            (inst sub ecx-tn (fixnumize fixed))))
1235
1236     ;; Save edi and esi register args.
1237     (inst push edi-tn)
1238     (inst push esi-tn)
1239     ;; Okay, we have pushed the register args. We can trash them
1240     ;; now.
1241
1242     ;; Initialize dst to be end of stack; skiping the values pushed
1243     ;; above.
1244     (inst lea edi-tn (make-ea :dword :base esp-tn :disp 8))
1245
1246     ;; Initialize src to be end of args.
1247     (inst mov esi-tn ebp-tn)
1248     (inst sub esi-tn ebx-tn)
1249
1250     (inst shr ecx-tn word-shift)        ; make word count
1251     ;; And copy the args.
1252     (inst cld)                          ; auto-inc ESI and EDI.
1253     (inst rep)
1254     (inst movs :dword)
1255
1256     ;; So now we need to restore EDI and ESI.
1257     (inst pop esi-tn)
1258     (inst pop edi-tn)
1259
1260     DO-REGS
1261
1262     ;; Restore ECX
1263     (inst mov ecx-tn ebx-tn)
1264
1265     ;; Here: nargs>=1 && nargs>fixed
1266     (when (< fixed register-arg-count)
1267           ;; Now we have to deposit any more args that showed up in
1268           ;; registers.
1269           (do ((i fixed))
1270               ( nil )
1271               ;; Store it relative to ebp
1272               (inst mov (make-ea :dword :base ebp-tn
1273                                  :disp (- (* 4
1274                                              (+ 1 (- i fixed)
1275                                                 (max 3 (sb-allocated-size 'stack))))))
1276                     (nth i *register-arg-tns*))
1277
1278               (incf i)
1279               (when (>= i register-arg-count)
1280                     (return))
1281
1282               ;; Don't deposit any more than there are.
1283               (if (zerop i)
1284                   (inst test ecx-tn ecx-tn)
1285                 (inst cmp ecx-tn (fixnumize i)))
1286               (inst jmp :eq done)))
1287
1288     (inst jmp done)
1289
1290     JUST-ALLOC-FRAME
1291     (inst lea esp-tn
1292           (make-ea :dword :base ebp-tn
1293                    :disp (- (* n-word-bytes
1294                                (max 3 (sb-allocated-size 'stack))))))
1295
1296     DONE))
1297
1298 (define-vop (more-kw-arg)
1299   (:translate sb!c::%more-kw-arg)
1300   (:policy :fast-safe)
1301   (:args (object :scs (descriptor-reg) :to (:result 1))
1302          (index :scs (any-reg immediate) :to (:result 1) :target keyword))
1303   (:arg-types * tagged-num)
1304   (:results (value :scs (descriptor-reg any-reg))
1305             (keyword :scs (descriptor-reg any-reg)))
1306   (:result-types * *)
1307   (:generator 4
1308     (sc-case index
1309       (immediate
1310        (inst mov value (make-ea :dword :base object :disp (tn-value index)))
1311        (inst mov keyword (make-ea :dword :base object
1312                                   :disp (+ (tn-value index) n-word-bytes))))
1313       (t
1314        (inst mov value (make-ea :dword :base object :index index))
1315        (inst mov keyword (make-ea :dword :base object :index index
1316                                   :disp n-word-bytes))))))
1317
1318 ;;; Turn more arg (context, count) into a list.
1319 (defoptimizer (%listify-rest-args stack-allocate-result) ((&rest args))
1320   t)
1321
1322 (define-vop (listify-rest-args)
1323   (:translate %listify-rest-args)
1324   (:policy :safe)
1325   (:args (context :scs (descriptor-reg) :target src)
1326          (count :scs (any-reg) :target ecx))
1327   (:arg-types * tagged-num)
1328   (:temporary (:sc unsigned-reg :offset esi-offset :from (:argument 0)) src)
1329   (:temporary (:sc unsigned-reg :offset ecx-offset :from (:argument 1)) ecx)
1330   (:temporary (:sc unsigned-reg :offset eax-offset) eax)
1331   (:temporary (:sc unsigned-reg) dst)
1332   (:results (result :scs (descriptor-reg)))
1333   (:node-var node)
1334   (:generator 20
1335     (let ((enter (gen-label))
1336           (loop (gen-label))
1337           (done (gen-label))
1338           (stack-allocate-p (node-stack-allocate-p node)))
1339       (move src context)
1340       (move ecx count)
1341       ;; Check to see whether there are no args, and just return NIL if so.
1342       (inst mov result nil-value)
1343       (inst jecxz done)
1344       (inst lea dst (make-ea :dword :index ecx :scale 2))
1345       (maybe-pseudo-atomic stack-allocate-p
1346        (allocation dst dst node stack-allocate-p)
1347        (inst lea dst (make-ea :byte :base dst :disp list-pointer-lowtag))
1348        ;; Convert the count into a raw value, so that we can use the
1349        ;; LOOP instruction.
1350        (inst shr ecx 2)
1351        ;; Set decrement mode (successive args at lower addresses)
1352        (inst std)
1353        ;; Set up the result.
1354        (move result dst)
1355        ;; Jump into the middle of the loop, 'cause that's were we want
1356        ;; to start.
1357        (inst jmp enter)
1358        (emit-label loop)
1359        ;; Compute a pointer to the next cons.
1360        (inst add dst (* cons-size n-word-bytes))
1361        ;; Store a pointer to this cons in the CDR of the previous cons.
1362        (storew dst dst -1 list-pointer-lowtag)
1363        (emit-label enter)
1364        ;; Grab one value and stash it in the car of this cons.
1365        (inst lods eax)
1366        (storew eax dst 0 list-pointer-lowtag)
1367        ;; Go back for more.
1368        (inst loop loop)
1369        ;; NIL out the last cons.
1370        (storew nil-value dst 1 list-pointer-lowtag))
1371       (emit-label done)
1372       ;; solaris requires DF being zero.
1373       #!+sunos (inst cld))))
1374
1375 ;;; Return the location and size of the &MORE arg glob created by
1376 ;;; COPY-MORE-ARG. SUPPLIED is the total number of arguments supplied
1377 ;;; (originally passed in ECX). FIXED is the number of non-rest
1378 ;;; arguments.
1379 ;;;
1380 ;;; We must duplicate some of the work done by COPY-MORE-ARG, since at
1381 ;;; that time the environment is in a pretty brain-damaged state,
1382 ;;; preventing this info from being returned as values. What we do is
1383 ;;; compute supplied - fixed, and return a pointer that many words
1384 ;;; below the current stack top.
1385 (define-vop (more-arg-context)
1386   (:policy :fast-safe)
1387   (:translate sb!c::%more-arg-context)
1388   (:args (supplied :scs (any-reg) :target count))
1389   (:arg-types positive-fixnum (:constant fixnum))
1390   (:info fixed)
1391   (:results (context :scs (descriptor-reg))
1392             (count :scs (any-reg)))
1393   (:result-types t tagged-num)
1394   (:note "more-arg-context")
1395   (:generator 5
1396     (move count supplied)
1397     ;; SP at this point points at the last arg pushed.
1398     ;; Point to the first more-arg, not above it.
1399     (inst lea context (make-ea :dword :base esp-tn
1400                                :index count :scale 1
1401                                :disp (- (+ (fixnumize fixed) 4))))
1402     (unless (zerop fixed)
1403       (inst sub count (fixnumize fixed)))))
1404
1405 ;;; Signal wrong argument count error if NARGS isn't equal to COUNT.
1406 (define-vop (verify-arg-count)
1407   (:policy :fast-safe)
1408   (:translate sb!c::%verify-arg-count)
1409   (:args (nargs :scs (any-reg)))
1410   (:arg-types positive-fixnum (:constant t))
1411   (:info count)
1412   (:vop-var vop)
1413   (:save-p :compute-only)
1414   (:generator 3
1415     (let ((err-lab
1416            (generate-error-code vop invalid-arg-count-error nargs)))
1417       (if (zerop count)
1418           (inst test nargs nargs)  ; smaller instruction
1419         (inst cmp nargs (fixnumize count)))
1420       (inst jmp :ne err-lab))))
1421
1422 ;;; Various other error signallers.
1423 (macrolet ((def (name error translate &rest args)
1424              `(define-vop (,name)
1425                 ,@(when translate
1426                     `((:policy :fast-safe)
1427                       (:translate ,translate)))
1428                 (:args ,@(mapcar (lambda (arg)
1429                                    `(,arg :scs (any-reg descriptor-reg)))
1430                                  args))
1431                 (:vop-var vop)
1432                 (:save-p :compute-only)
1433                 (:generator 1000
1434                   (error-call vop ,error ,@args)))))
1435   (def arg-count-error invalid-arg-count-error
1436     sb!c::%arg-count-error nargs)
1437   (def type-check-error object-not-type-error sb!c::%type-check-error
1438     object type)
1439   (def layout-invalid-error layout-invalid-error sb!c::%layout-invalid-error
1440     object layout)
1441   (def odd-key-args-error odd-key-args-error
1442     sb!c::%odd-key-args-error)
1443   (def unknown-key-arg-error unknown-key-arg-error
1444     sb!c::%unknown-key-arg-error key)
1445   (def nil-fun-returned-error nil-fun-returned-error nil fun))
1446
1447 ;;; Single-stepping
1448
1449 (defun emit-single-step-test ()
1450   ;; We use different ways of representing whether stepping is on on
1451   ;; +SB-THREAD / -SB-THREAD: on +SB-THREAD, we use a slot in the
1452   ;; thread structure. On -SB-THREAD we use the value of a static
1453   ;; symbol. Things are done this way, since reading a thread-local
1454   ;; slot from a symbol would require an extra register on +SB-THREAD,
1455   ;; and reading a slot from a thread structure would require an extra
1456   ;; register on -SB-THREAD.
1457   #!+sb-thread
1458   (progn
1459     (inst fs-segment-prefix)
1460     (inst cmp (make-ea :dword
1461                        :disp (* thread-stepping-slot n-word-bytes))
1462           nil-value))
1463   #!-sb-thread
1464   (inst cmp (make-ea :dword
1465                      :disp (+ nil-value (static-symbol-offset
1466                                          'sb!impl::*stepping*)
1467                               (* symbol-value-slot n-word-bytes)
1468                               (- other-pointer-lowtag)))
1469         nil-value))
1470
1471 (define-vop (step-instrument-before-vop)
1472   (:policy :fast-safe)
1473   (:vop-var vop)
1474   (:generator 3
1475      (emit-single-step-test)
1476      (inst jmp :eq DONE)
1477      (inst break single-step-before-trap)
1478      DONE
1479      (note-this-location vop :step-before-vop)))