src/compiler/x86/cell.lisp

   1 ;;;; various primitive memory access VOPs for the x86 VM
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!VM")
  13 \f
  14 ;;;; data object ref/set stuff
  15
  16 (define-vop (slot)
  17   (:args (object :scs (descriptor-reg)))
  18   (:info name offset lowtag)
  19   (:ignore name)
  20   (:results (result :scs (descriptor-reg any-reg)))
  21   (:generator 1
  22     (loadw result object offset lowtag)))
  23
  24 (define-vop (set-slot)
  25   (:args (object :scs (descriptor-reg))
  26          (value :scs (descriptor-reg any-reg immediate)))
  27   (:info name offset lowtag)
  28   (:ignore name)
  29   (:results)
  30   (:generator 1
  31      (if (sc-is value immediate)
  32         (let ((val (tn-value value)))
  33            (etypecase val
  34               (integer
  35                (inst mov
  36                      (make-ea :dword :base object
  37                               :disp (- (* offset n-word-bytes) lowtag))
  38                      (fixnumize val)))
  39               (symbol
  40                (inst mov
  41                      (make-ea :dword :base object
  42                               :disp (- (* offset n-word-bytes) lowtag))
  43                      (+ nil-value (static-symbol-offset val))))
  44               (character
  45                (inst mov
  46                      (make-ea :dword :base object
  47                               :disp (- (* offset n-word-bytes) lowtag))
  48                      (logior (ash (char-code val) n-widetag-bits)
  49                              base-char-widetag)))))
  50        ;; Else, value not immediate.
  51        (storew value object offset lowtag))))
  52 \f
  53
  54
  55 ;;;; symbol hacking VOPs
  56
  57 ;;; these next two cf the sparc version, by jrd.
  58 ;;; FIXME: Deref this ^ reference.
  59
  60
  61 ;;; The compiler likes to be able to directly SET symbols.
  62 #!+sb-thread
  63 (define-vop (set)
  64   (:args (symbol :scs (descriptor-reg))
  65          (value :scs (descriptor-reg any-reg)))
  66   (:translate sb!kernel:%set-symbol-value)
  67   (:temporary (:sc descriptor-reg ) tls)
  68   ;;(:policy :fast-safe)
  69   (:generator 4
  70     (let ((global-val (gen-label))
  71           (done (gen-label)))
  72       (loadw tls symbol symbol-tls-index-slot other-pointer-lowtag)
  73       (inst or tls tls)
  74       (inst jmp :z global-val)
  75       (inst fs-segment-prefix)
  76       (inst cmp (make-ea :dword :scale 1 :index tls) unbound-marker-widetag)
  77       (inst jmp :z global-val)
  78       (inst fs-segment-prefix)
  79       (inst mov (make-ea :dword :scale 1 :index tls) value)
  80       (inst jmp done)
  81       (emit-label global-val)
  82       (storew value symbol symbol-value-slot other-pointer-lowtag)
  83       (emit-label done))))
  84
  85 ;; unithreaded it's a lot simpler ...
  86 #!-sb-thread
  87 (define-vop (set cell-set)
  88   (:variant symbol-value-slot other-pointer-lowtag))
  89
  90 ;;; Do a cell ref with an error check for being unbound.
  91 ;;; XXX stil used? I can't see where -dan
  92 (define-vop (checked-cell-ref)
  93   (:args (object :scs (descriptor-reg) :target obj-temp))
  94   (:results (value :scs (descriptor-reg any-reg)))
  95   (:policy :fast-safe)
  96   (:vop-var vop)
  97   (:save-p :compute-only)
  98   (:temporary (:sc descriptor-reg :from (:argument 0)) obj-temp))
  99
 100 ;;; With Symbol-Value, we check that the value isn't the trap object. So
 101 ;;; Symbol-Value of NIL is NIL.
 102 #!+sb-thread
 103 (define-vop (symbol-value)
 104   (:translate symbol-value)
 105   (:policy :fast-safe)
 106   (:args (object :scs (descriptor-reg) :to (:result 1)))
 107   (:results (value :scs (descriptor-reg any-reg)))
 108   (:vop-var vop)
 109   (:save-p :compute-only)
 110   (:generator 9
 111     (let* ((err-lab (generate-error-code vop unbound-symbol-error object))
 112            (ret-lab (gen-label)))
 113       (loadw value object symbol-tls-index-slot other-pointer-lowtag)
 114       (inst fs-segment-prefix)
 115       (inst mov value (make-ea :dword :index value :scale 1))
 116       (inst cmp value unbound-marker-widetag)
 117       (inst jmp :ne ret-lab)
 118       (loadw value object symbol-value-slot other-pointer-lowtag)
 119       (inst cmp value unbound-marker-widetag)
 120       (inst jmp :e err-lab)
 121       (emit-label ret-lab))))
 122
 123 #!+sb-thread
 124 (define-vop (fast-symbol-value symbol-value)
 125   (:policy :fast)
 126   (:translate symbol-value))
 127
 128 #!-sb-thread
 129 (define-vop (symbol-value)
 130   (:translate symbol-value)
 131   (:policy :fast-safe)
 132   (:args (object :scs (descriptor-reg) :to (:result 1)))
 133   (:results (value :scs (descriptor-reg any-reg)))
 134   (:vop-var vop)
 135   (:save-p :compute-only)
 136   (:generator 9
 137     (let ((err-lab (generate-error-code vop unbound-symbol-error object)))
 138       (loadw value object symbol-value-slot other-pointer-lowtag)
 139       (inst cmp value unbound-marker-widetag)
 140       (inst jmp :e err-lab))))
 141
 142 #!-sb-thread
 143 (define-vop (fast-symbol-value cell-ref)
 144   (:variant symbol-value-slot other-pointer-lowtag)
 145   (:policy :fast)
 146   (:translate symbol-value))
 147
 148 (defknown locked-symbol-global-value-add (symbol fixnum) fixnum ())
 149
 150 (define-vop (locked-symbol-global-value-add)
 151     (:args (object :scs (descriptor-reg) :to :result)
 152            (value :scs (any-reg) :target result))
 153   (:arg-types * tagged-num)
 154   (:results (result :scs (any-reg) :from (:argument 1)))
 155   (:policy :fast)
 156   (:translate locked-symbol-global-value-add)
 157   (:result-types tagged-num)
 158   (:policy :fast-safe)
 159   (:generator 4
 160     (move result value)
 161     (inst lock)
 162     (inst add (make-ea :dword :base object
 163                        :disp (- (* symbol-value-slot n-word-bytes)
 164                                 other-pointer-lowtag))
 165           value)))
 166
 167 #!+sb-thread
 168 (define-vop (boundp)
 169   (:translate boundp)
 170   (:policy :fast-safe)
 171   (:args (object :scs (descriptor-reg)))
 172   (:conditional)
 173   (:info target not-p)
 174   (:temporary (:sc descriptor-reg #+nil(:from (:argument 0))) value)
 175   (:generator 9
 176     (if not-p
 177         (let ((not-target (gen-label)))
 178           (loadw value object symbol-value-slot other-pointer-lowtag)
 179           (inst cmp value unbound-marker-widetag)
 180           (inst jmp :ne not-target)
 181           (loadw value object symbol-tls-index-slot other-pointer-lowtag)
 182           (inst fs-segment-prefix)
 183           (inst cmp (make-ea :dword :index value :scale 1) unbound-marker-widetag)
 184           (inst jmp  :e  target)
 185           (emit-label not-target))
 186         (progn
 187           (loadw value object symbol-value-slot other-pointer-lowtag)
 188           (inst cmp value unbound-marker-widetag)
 189           (inst jmp :ne target)
 190           (loadw value object symbol-tls-index-slot other-pointer-lowtag)
 191           (inst fs-segment-prefix)
 192           (inst cmp (make-ea :dword :index value :scale 1) unbound-marker-widetag)
 193           (inst jmp  :ne  target)))))
 194
 195 #!-sb-thread
 196 (define-vop (boundp)
 197   (:translate boundp)
 198   (:policy :fast-safe)
 199   (:args (object :scs (descriptor-reg)))
 200   (:conditional)
 201   (:info target not-p)
 202   (:temporary (:sc descriptor-reg :from (:argument 0)) value)
 203   (:generator 9
 204     (loadw value object symbol-value-slot other-pointer-lowtag)
 205     (inst cmp value unbound-marker-widetag)
 206     (inst jmp (if not-p :e :ne) target)))
 207
 208
 209 (define-vop (symbol-hash)
 210   (:policy :fast-safe)
 211   (:translate symbol-hash)
 212   (:args (symbol :scs (descriptor-reg)))
 213   (:results (res :scs (any-reg)))
 214   (:result-types positive-fixnum)
 215   (:generator 2
 216     ;; The symbol-hash slot of NIL holds NIL because it is also the
 217     ;; cdr slot, so we have to strip off the two low bits to make sure
 218     ;; it is a fixnum.  The lowtag selection magic that is required to
 219     ;; ensure this is explained in the comment in objdef.lisp
 220     (loadw res symbol symbol-hash-slot other-pointer-lowtag)
 221     (inst and res (lognot #b11))))
 222 \f
 223 ;;;; fdefinition (FDEFN) objects
 224
 225 (define-vop (fdefn-fun cell-ref)        ; /pfw - alpha
 226   (:variant fdefn-fun-slot other-pointer-lowtag))
 227
 228 (define-vop (safe-fdefn-fun)
 229   (:args (object :scs (descriptor-reg) :to (:result 1)))
 230   (:results (value :scs (descriptor-reg any-reg)))
 231   (:vop-var vop)
 232   (:save-p :compute-only)
 233   (:generator 10
 234     (loadw value object fdefn-fun-slot other-pointer-lowtag)
 235     (inst cmp value nil-value)
 236     (let ((err-lab (generate-error-code vop undefined-fun-error object)))
 237       (inst jmp :e err-lab))))
 238
 239 (define-vop (set-fdefn-fun)
 240   (:policy :fast-safe)
 241   (:translate (setf fdefn-fun))
 242   (:args (function :scs (descriptor-reg) :target result)
 243          (fdefn :scs (descriptor-reg)))
 244   (:temporary (:sc unsigned-reg) raw)
 245   (:temporary (:sc byte-reg) type)
 246   (:results (result :scs (descriptor-reg)))
 247   (:generator 38
 248     (load-type type function (- fun-pointer-lowtag))
 249     (inst lea raw
 250           (make-ea :byte :base function
 251                    :disp (- (* simple-fun-code-offset n-word-bytes)
 252                             fun-pointer-lowtag)))
 253     (inst cmp type simple-fun-header-widetag)
 254     (inst jmp :e normal-fn)
 255     (inst lea raw (make-fixup (extern-alien-name "closure_tramp") :foreign))
 256     NORMAL-FN
 257     (storew function fdefn fdefn-fun-slot other-pointer-lowtag)
 258     (storew raw fdefn fdefn-raw-addr-slot other-pointer-lowtag)
 259     (move result function)))
 260
 261 (define-vop (fdefn-makunbound)
 262   (:policy :fast-safe)
 263   (:translate fdefn-makunbound)
 264   (:args (fdefn :scs (descriptor-reg) :target result))
 265   (:results (result :scs (descriptor-reg)))
 266   (:generator 38
 267     (storew nil-value fdefn fdefn-fun-slot other-pointer-lowtag)
 268     (storew (make-fixup (extern-alien-name "undefined_tramp") :foreign)
 269             fdefn fdefn-raw-addr-slot other-pointer-lowtag)
 270     (move result fdefn)))
 271 \f
 272 ;;;; binding and unbinding
 273
 274 ;;; BIND -- Establish VAL as a binding for SYMBOL. Save the old value and
 275 ;;; the symbol on the binding stack and stuff the new value into the
 276 ;;; symbol.
 277
 278 #!+sb-thread
 279 (define-vop (bind)
 280   (:args (val :scs (any-reg descriptor-reg))
 281          (symbol :scs (descriptor-reg)))
 282   (:temporary (:sc unsigned-reg) tls-index temp bsp)
 283   (:generator 5
 284     (let ((tls-index-valid (gen-label)))
 285       (load-tl-symbol-value bsp *binding-stack-pointer*)
 286       (loadw tls-index symbol symbol-tls-index-slot other-pointer-lowtag)
 287       (inst add bsp (* binding-size n-word-bytes))
 288       (store-tl-symbol-value bsp *binding-stack-pointer* temp)
 289
 290       (inst or tls-index tls-index)
 291       (inst jmp :ne tls-index-valid)
 292       ;; allocate a new tls-index
 293       (load-symbol-value tls-index *free-tls-index*)
 294       (inst add tls-index 4)            ;XXX surely we can do this more
 295       (store-symbol-value tls-index *free-tls-index*) ;succintly
 296       (inst sub tls-index 4)
 297       (storew tls-index symbol symbol-tls-index-slot other-pointer-lowtag)
 298       (emit-label tls-index-valid)
 299       (inst fs-segment-prefix)
 300       (inst mov temp (make-ea :dword :scale 1 :index tls-index))
 301       (storew temp bsp (- binding-value-slot binding-size))
 302       (storew symbol bsp (- binding-symbol-slot binding-size))
 303       (inst fs-segment-prefix)
 304       (inst mov (make-ea :dword :scale 1 :index tls-index) val))))
 305
 306 #!-sb-thread
 307 (define-vop (bind)
 308   (:args (val :scs (any-reg descriptor-reg))
 309          (symbol :scs (descriptor-reg)))
 310   (:temporary (:sc unsigned-reg) temp bsp)
 311   (:generator 5
 312     (load-symbol-value bsp *binding-stack-pointer*)
 313     (loadw temp symbol symbol-value-slot other-pointer-lowtag)
 314     (inst add bsp (* binding-size n-word-bytes))
 315     (store-symbol-value bsp *binding-stack-pointer*)
 316     (storew temp bsp (- binding-value-slot binding-size))
 317     (storew symbol bsp (- binding-symbol-slot binding-size))
 318     (storew val symbol symbol-value-slot other-pointer-lowtag)))
 319
 320
 321 #!+sb-thread
 322 (define-vop (unbind)
 323     ;; four temporaries?
 324   (:temporary (:sc unsigned-reg) symbol value bsp tls-index)
 325   (:generator 0
 326     (load-tl-symbol-value bsp *binding-stack-pointer*)
 327     (loadw symbol bsp (- binding-symbol-slot binding-size))
 328     (loadw value bsp (- binding-value-slot binding-size))
 329
 330     (loadw tls-index symbol symbol-tls-index-slot other-pointer-lowtag)
 331     (inst fs-segment-prefix)
 332     (inst mov (make-ea :dword :scale 1 :index tls-index) value)
 333
 334     (storew 0 bsp (- binding-symbol-slot binding-size))
 335     (inst sub bsp (* binding-size n-word-bytes))
 336     ;; we're done with value, so we can use it as a temp here
 337     (store-tl-symbol-value bsp *binding-stack-pointer* value)))
 338
 339 #!-sb-thread
 340 (define-vop (unbind)
 341   (:temporary (:sc unsigned-reg) symbol value bsp)
 342   (:generator 0
 343     (load-symbol-value bsp *binding-stack-pointer*)
 344     (loadw symbol bsp (- binding-symbol-slot binding-size))
 345     (loadw value bsp (- binding-value-slot binding-size))
 346     (storew value symbol symbol-value-slot other-pointer-lowtag)
 347     (storew 0 bsp (- binding-symbol-slot binding-size))
 348     (inst sub bsp (* binding-size n-word-bytes))
 349     (store-symbol-value bsp *binding-stack-pointer*)))
 350
 351
 352 (define-vop (unbind-to-here)
 353   (:args (where :scs (descriptor-reg any-reg)))
 354   (:temporary (:sc unsigned-reg) symbol value bsp #!+sb-thread tls-index)
 355   (:generator 0
 356     (load-tl-symbol-value bsp *binding-stack-pointer*)
 357     (inst cmp where bsp)
 358     (inst jmp :e done)
 359
 360     LOOP
 361     (loadw symbol bsp (- binding-symbol-slot binding-size))
 362     (inst or symbol symbol)
 363     (inst jmp :z skip)
 364     (loadw value bsp (- binding-value-slot binding-size))
 365     #!-sb-thread (storew value symbol symbol-value-slot other-pointer-lowtag)
 366
 367     #!+sb-thread (loadw
 368                   tls-index symbol symbol-tls-index-slot other-pointer-lowtag)
 369     #!+sb-thread (inst fs-segment-prefix)
 370     #!+sb-thread (inst mov (make-ea :dword :scale 1 :index tls-index) value)
 371     (storew 0 bsp (- binding-symbol-slot binding-size))
 372
 373     SKIP
 374     (inst sub bsp (* binding-size n-word-bytes))
 375     (inst cmp where bsp)
 376     (inst jmp :ne loop)
 377     ;; we're done with value, so can use it as a temporary
 378     (store-tl-symbol-value bsp *binding-stack-pointer* value)
 379
 380     DONE))
 381 \f
 382
 383 \f
 384 ;;;; closure indexing
 385
 386 (define-full-reffer closure-index-ref *
 387   closure-info-offset fun-pointer-lowtag
 388   (any-reg descriptor-reg) * %closure-index-ref)
 389
 390 (define-full-setter set-funcallable-instance-info *
 391   funcallable-instance-info-offset fun-pointer-lowtag
 392   (any-reg descriptor-reg) * %set-funcallable-instance-info)
 393
 394 (define-full-reffer funcallable-instance-info *
 395   funcallable-instance-info-offset fun-pointer-lowtag
 396   (descriptor-reg any-reg) * %funcallable-instance-info)
 397
 398 (define-vop (funcallable-instance-lexenv cell-ref)
 399   (:variant funcallable-instance-lexenv-slot fun-pointer-lowtag))
 400
 401 (define-vop (closure-ref slot-ref)
 402   (:variant closure-info-offset fun-pointer-lowtag))
 403
 404 (define-vop (closure-init slot-set)
 405   (:variant closure-info-offset fun-pointer-lowtag))
 406 \f
 407 ;;;; value cell hackery
 408
 409 (define-vop (value-cell-ref cell-ref)
 410   (:variant value-cell-value-slot other-pointer-lowtag))
 411
 412 (define-vop (value-cell-set cell-set)
 413   (:variant value-cell-value-slot other-pointer-lowtag))
 414 \f
 415 ;;;; structure hackery
 416
 417 (define-vop (instance-length)
 418   (:policy :fast-safe)
 419   (:translate %instance-length)
 420   (:args (struct :scs (descriptor-reg)))
 421   (:results (res :scs (unsigned-reg)))
 422   (:result-types positive-fixnum)
 423   (:generator 4
 424     (loadw res struct 0 instance-pointer-lowtag)
 425     (inst shr res n-widetag-bits)))
 426
 427 (define-vop (instance-ref slot-ref)
 428   (:variant instance-slots-offset instance-pointer-lowtag)
 429   (:policy :fast-safe)
 430   (:translate %instance-ref)
 431   (:arg-types instance (:constant index)))
 432
 433 (define-vop (instance-set slot-set)
 434   (:policy :fast-safe)
 435   (:translate %instance-set)
 436   (:variant instance-slots-offset instance-pointer-lowtag)
 437   (:arg-types instance (:constant index) *))
 438
 439 (define-full-reffer instance-index-ref * instance-slots-offset
 440   instance-pointer-lowtag (any-reg descriptor-reg) * %instance-ref)
 441
 442 (define-full-setter instance-index-set * instance-slots-offset
 443   instance-pointer-lowtag (any-reg descriptor-reg) * %instance-set)
 444
 445
 446 (defknown %instance-set-conditional (instance index t t) t
 447           (unsafe))
 448
 449 (define-vop (instance-set-conditional)
 450   (:translate %instance-set-conditional)
 451   (:args (object :scs (descriptor-reg) :to :eval)
 452          (slot :scs (any-reg) :to :result)
 453          (old-value :scs (descriptor-reg any-reg) :target eax)
 454          (new-value :scs (descriptor-reg any-reg)))
 455   (:arg-types instance positive-fixnum * *)
 456   (:temporary (:sc descriptor-reg :offset eax-offset
 457                    :from (:argument 2) :to :result :target result)  eax)
 458   (:results (result :scs (descriptor-reg any-reg)))
 459   ;(:guard (backend-featurep :i486))
 460   (:policy :fast-safe)
 461   (:generator 5
 462     (move eax old-value)
 463     (inst lock)
 464     (inst cmpxchg (make-ea :dword :base object :index slot :scale 1
 465                            :disp (- (* instance-slots-offset n-word-bytes)
 466                                     instance-pointer-lowtag))
 467           new-value)
 468     (move result eax)))
 469
 470
 471 \f
 472 ;;;; code object frobbing
 473
 474 (define-full-reffer code-header-ref * 0 other-pointer-lowtag
 475   (any-reg descriptor-reg) * code-header-ref)
 476
 477 (define-full-setter code-header-set * 0 other-pointer-lowtag
 478   (any-reg descriptor-reg) * code-header-set)