src/compiler/x86/cell.lisp

   1 ;;;; various primitive memory access VOPs for the x86 VM
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!VM")
  13 \f
  14 ;;;; data object ref/set stuff
  15
  16 (define-vop (slot)
  17   (:args (object :scs (descriptor-reg)))
  18   (:info name offset lowtag)
  19   (:ignore name)
  20   (:results (result :scs (descriptor-reg any-reg)))
  21   (:generator 1
  22     (loadw result object offset lowtag)))
  23
  24 (define-vop (set-slot)
  25   (:args (object :scs (descriptor-reg))
  26          (value :scs (descriptor-reg any-reg immediate)))
  27   (:info name offset lowtag)
  28   (:ignore name)
  29   (:results)
  30   (:generator 1
  31      (if (sc-is value immediate)
  32         (let ((val (tn-value value)))
  33            (etypecase val
  34               (integer
  35                (inst mov
  36                      (make-ea :dword :base object
  37                               :disp (- (* offset n-word-bytes) lowtag))
  38                      (fixnumize val)))
  39               (symbol
  40                (inst mov
  41                      (make-ea :dword :base object
  42                               :disp (- (* offset n-word-bytes) lowtag))
  43                      (+ nil-value (static-symbol-offset val))))
  44               (character
  45                (inst mov
  46                      (make-ea :dword :base object
  47                               :disp (- (* offset n-word-bytes) lowtag))
  48                      (logior (ash (char-code val) n-widetag-bits)
  49                              character-widetag)))))
  50        ;; Else, value not immediate.
  51        (storew value object offset lowtag))))
  52 \f
  53
  54
  55 ;;;; symbol hacking VOPs
  56
  57 ;;; these next two cf the sparc version, by jrd.
  58 ;;; FIXME: Deref this ^ reference.
  59
  60
  61 ;;; The compiler likes to be able to directly SET symbols.
  62 #!+sb-thread
  63 (define-vop (set)
  64   (:args (symbol :scs (descriptor-reg))
  65          (value :scs (descriptor-reg any-reg)))
  66   (:temporary (:sc descriptor-reg) tls)
  67   ;;(:policy :fast-safe)
  68   (:generator 4
  69     (let ((global-val (gen-label))
  70           (done (gen-label)))
  71       (loadw tls symbol symbol-tls-index-slot other-pointer-lowtag)
  72       (inst or tls tls)
  73       (inst jmp :z global-val)
  74       (inst fs-segment-prefix)
  75       (inst cmp (make-ea :dword :base tls) no-tls-value-marker-widetag)
  76       (inst jmp :z global-val)
  77       (inst fs-segment-prefix)
  78       (inst mov (make-ea :dword :base tls) value)
  79       (inst jmp done)
  80       (emit-label global-val)
  81       (storew value symbol symbol-value-slot other-pointer-lowtag)
  82       (emit-label done))))
  83
  84 ;; unithreaded it's a lot simpler ...
  85 #!-sb-thread
  86 (define-vop (set cell-set)
  87   (:variant symbol-value-slot other-pointer-lowtag))
  88
  89 ;;; Do a cell ref with an error check for being unbound.
  90 ;;; XXX stil used? I can't see where -dan
  91 (define-vop (checked-cell-ref)
  92   (:args (object :scs (descriptor-reg) :target obj-temp))
  93   (:results (value :scs (descriptor-reg any-reg)))
  94   (:policy :fast-safe)
  95   (:vop-var vop)
  96   (:save-p :compute-only)
  97   (:temporary (:sc descriptor-reg :from (:argument 0)) obj-temp))
  98
  99 ;;; With Symbol-Value, we check that the value isn't the trap object. So
 100 ;;; Symbol-Value of NIL is NIL.
 101 #!+sb-thread
 102 (define-vop (symbol-value)
 103   (:translate symbol-value)
 104   (:policy :fast-safe)
 105   (:args (object :scs (descriptor-reg) :to (:result 1)))
 106   (:results (value :scs (descriptor-reg any-reg)))
 107   (:vop-var vop)
 108   (:save-p :compute-only)
 109   (:generator 9
 110     (let* ((check-unbound-label (gen-label))
 111            (err-lab (generate-error-code vop unbound-symbol-error object))
 112            (ret-lab (gen-label)))
 113       (loadw value object symbol-tls-index-slot other-pointer-lowtag)
 114       (inst fs-segment-prefix)
 115       (inst mov value (make-ea :dword :base value))
 116       (inst cmp value no-tls-value-marker-widetag)
 117       (inst jmp :ne check-unbound-label)
 118       (loadw value object symbol-value-slot other-pointer-lowtag)
 119       (emit-label check-unbound-label)
 120       (inst cmp value unbound-marker-widetag)
 121       (inst jmp :e err-lab)
 122       (emit-label ret-lab))))
 123
 124 #!+sb-thread
 125 (define-vop (fast-symbol-value symbol-value)
 126   ;; KLUDGE: not really fast, in fact, because we're going to have to
 127   ;; do a full lookup of the thread-local area anyway.  But half of
 128   ;; the meaning of FAST-SYMBOL-VALUE is "do not signal an error if
 129   ;; unbound", which is used in the implementation of COPY-SYMBOL.  --
 130   ;; CSR, 2003-04-22
 131   (:policy :fast)
 132   (:translate symbol-value)
 133   (:generator 8
 134     (let ((ret-lab (gen-label)))
 135       (loadw value object symbol-tls-index-slot other-pointer-lowtag)
 136       (inst fs-segment-prefix)
 137       (inst mov value (make-ea :dword :base value))
 138       (inst cmp value no-tls-value-marker-widetag)
 139       (inst jmp :ne ret-lab)
 140       (loadw value object symbol-value-slot other-pointer-lowtag)
 141       (emit-label ret-lab))))
 142
 143 #!-sb-thread
 144 (define-vop (symbol-value)
 145   (:translate symbol-value)
 146   (:policy :fast-safe)
 147   (:args (object :scs (descriptor-reg) :to (:result 1)))
 148   (:results (value :scs (descriptor-reg any-reg)))
 149   (:vop-var vop)
 150   (:save-p :compute-only)
 151   (:generator 9
 152     (let ((err-lab (generate-error-code vop unbound-symbol-error object)))
 153       (loadw value object symbol-value-slot other-pointer-lowtag)
 154       (inst cmp value unbound-marker-widetag)
 155       (inst jmp :e err-lab))))
 156
 157 #!-sb-thread
 158 (define-vop (fast-symbol-value cell-ref)
 159   (:variant symbol-value-slot other-pointer-lowtag)
 160   (:policy :fast)
 161   (:translate symbol-value))
 162
 163 (defknown locked-symbol-global-value-add (symbol fixnum) fixnum ())
 164
 165 (define-vop (locked-symbol-global-value-add)
 166     (:args (object :scs (descriptor-reg) :to :result)
 167            (value :scs (any-reg) :target result))
 168   (:arg-types * tagged-num)
 169   (:results (result :scs (any-reg) :from (:argument 1)))
 170   (:policy :fast)
 171   (:translate locked-symbol-global-value-add)
 172   (:result-types tagged-num)
 173   (:policy :fast-safe)
 174   (:generator 4
 175     (move result value)
 176     (inst lock)
 177     (inst add (make-ea :dword :base object
 178                        :disp (- (* symbol-value-slot n-word-bytes)
 179                                 other-pointer-lowtag))
 180           value)))
 181
 182 #!+sb-thread
 183 (define-vop (boundp)
 184   (:translate boundp)
 185   (:policy :fast-safe)
 186   (:args (object :scs (descriptor-reg)))
 187   (:conditional)
 188   (:info target not-p)
 189   (:temporary (:sc descriptor-reg #+nil(:from (:argument 0))) value)
 190   (:generator 9
 191     (let ((check-unbound-label (gen-label)))
 192       (loadw value object symbol-tls-index-slot other-pointer-lowtag)
 193       (inst fs-segment-prefix)
 194       (inst mov value (make-ea :dword :base value))
 195       (inst cmp value no-tls-value-marker-widetag)
 196       (inst jmp :ne check-unbound-label)
 197       (loadw value object symbol-value-slot other-pointer-lowtag)
 198       (emit-label check-unbound-label)
 199       (inst cmp value unbound-marker-widetag)
 200       (inst jmp (if not-p :e :ne) target))))
 201
 202 #!-sb-thread
 203 (define-vop (boundp)
 204   (:translate boundp)
 205   (:policy :fast-safe)
 206   (:args (object :scs (descriptor-reg)))
 207   (:conditional)
 208   (:info target not-p)
 209   (:generator 9
 210     (inst cmp (make-ea-for-object-slot object symbol-value-slot
 211                                        other-pointer-lowtag)
 212           unbound-marker-widetag)
 213     (inst jmp (if not-p :e :ne) target)))
 214
 215
 216 (define-vop (symbol-hash)
 217   (:policy :fast-safe)
 218   (:translate symbol-hash)
 219   (:args (symbol :scs (descriptor-reg)))
 220   (:results (res :scs (any-reg)))
 221   (:result-types positive-fixnum)
 222   (:generator 2
 223     ;; The symbol-hash slot of NIL holds NIL because it is also the
 224     ;; cdr slot, so we have to strip off the two low bits to make sure
 225     ;; it is a fixnum.  The lowtag selection magic that is required to
 226     ;; ensure this is explained in the comment in objdef.lisp
 227     (loadw res symbol symbol-hash-slot other-pointer-lowtag)
 228     (inst and res (lognot #b11))))
 229 \f
 230 ;;;; fdefinition (FDEFN) objects
 231
 232 (define-vop (fdefn-fun cell-ref)        ; /pfw - alpha
 233   (:variant fdefn-fun-slot other-pointer-lowtag))
 234
 235 (define-vop (safe-fdefn-fun)
 236   (:args (object :scs (descriptor-reg) :to (:result 1)))
 237   (:results (value :scs (descriptor-reg any-reg)))
 238   (:vop-var vop)
 239   (:save-p :compute-only)
 240   (:generator 10
 241     (loadw value object fdefn-fun-slot other-pointer-lowtag)
 242     (inst cmp value nil-value)
 243     (let ((err-lab (generate-error-code vop undefined-fun-error object)))
 244       (inst jmp :e err-lab))))
 245
 246 (define-vop (set-fdefn-fun)
 247   (:policy :fast-safe)
 248   (:translate (setf fdefn-fun))
 249   (:args (function :scs (descriptor-reg) :target result)
 250          (fdefn :scs (descriptor-reg)))
 251   (:temporary (:sc unsigned-reg) raw)
 252   (:temporary (:sc byte-reg) type)
 253   (:results (result :scs (descriptor-reg)))
 254   (:generator 38
 255     (load-type type function (- fun-pointer-lowtag))
 256     (inst lea raw
 257           (make-ea :byte :base function
 258                    :disp (- (* simple-fun-code-offset n-word-bytes)
 259                             fun-pointer-lowtag)))
 260     (inst cmp type simple-fun-header-widetag)
 261     (inst jmp :e normal-fn)
 262     (inst lea raw (make-fixup "closure_tramp" :foreign))
 263     NORMAL-FN
 264     (storew function fdefn fdefn-fun-slot other-pointer-lowtag)
 265     (storew raw fdefn fdefn-raw-addr-slot other-pointer-lowtag)
 266     (move result function)))
 267
 268 (define-vop (fdefn-makunbound)
 269   (:policy :fast-safe)
 270   (:translate fdefn-makunbound)
 271   (:args (fdefn :scs (descriptor-reg) :target result))
 272   (:results (result :scs (descriptor-reg)))
 273   (:generator 38
 274     (storew nil-value fdefn fdefn-fun-slot other-pointer-lowtag)
 275     (storew (make-fixup "undefined_tramp" :foreign)
 276             fdefn fdefn-raw-addr-slot other-pointer-lowtag)
 277     (move result fdefn)))
 278 \f
 279 ;;;; binding and unbinding
 280
 281 ;;; BIND -- Establish VAL as a binding for SYMBOL. Save the old value and
 282 ;;; the symbol on the binding stack and stuff the new value into the
 283 ;;; symbol.
 284
 285 #!+sb-thread
 286 (define-vop (bind)
 287   (:args (val :scs (any-reg descriptor-reg))
 288          (symbol :scs (descriptor-reg)))
 289   (:temporary (:sc descriptor-reg :offset eax-offset) eax)
 290   (:temporary (:sc unsigned-reg) tls-index temp bsp)
 291   (:generator 10
 292     (let ((tls-index-valid (gen-label))
 293           (get-tls-index-lock (gen-label))
 294           (release-tls-index-lock (gen-label)))
 295       (load-binding-stack-pointer bsp)
 296       (loadw tls-index symbol symbol-tls-index-slot other-pointer-lowtag)
 297       (inst add bsp (* binding-size n-word-bytes))
 298       (store-binding-stack-pointer bsp)
 299       (inst or tls-index tls-index)
 300       (inst jmp :ne tls-index-valid)
 301
 302       (pseudo-atomic
 303        (emit-label get-tls-index-lock)
 304        (inst mov temp 1)
 305        (inst xor eax eax)
 306        (inst lock)
 307        (inst cmpxchg (make-ea-for-symbol-value *tls-index-lock*) temp)
 308        (inst jmp :ne get-tls-index-lock)
 309        ;; now with the lock held, see if the symbol's tls index has
 310        ;; been set in the meantime
 311        (loadw tls-index symbol symbol-tls-index-slot other-pointer-lowtag)
 312        (inst or tls-index tls-index)
 313        (inst jmp :ne release-tls-index-lock)
 314        ;; allocate a new tls-index
 315        (load-symbol-value tls-index *free-tls-index*)
 316        (inst add tls-index 4)          ;XXX surely we can do this more
 317        (store-symbol-value tls-index *free-tls-index*) ;succintly
 318        (inst sub tls-index 4)
 319        (storew tls-index symbol symbol-tls-index-slot other-pointer-lowtag)
 320        (emit-label release-tls-index-lock)
 321        (store-symbol-value 0 *tls-index-lock*))
 322
 323       (emit-label tls-index-valid)
 324       (inst fs-segment-prefix)
 325       (inst mov temp (make-ea :dword :base tls-index))
 326       (storew temp bsp (- binding-value-slot binding-size))
 327       (storew symbol bsp (- binding-symbol-slot binding-size))
 328       (inst fs-segment-prefix)
 329       (inst mov (make-ea :dword :base tls-index) val))))
 330
 331 #!-sb-thread
 332 (define-vop (bind)
 333   (:args (val :scs (any-reg descriptor-reg))
 334          (symbol :scs (descriptor-reg)))
 335   (:temporary (:sc unsigned-reg) temp bsp)
 336   (:generator 5
 337     (load-symbol-value bsp *binding-stack-pointer*)
 338     (loadw temp symbol symbol-value-slot other-pointer-lowtag)
 339     (inst add bsp (* binding-size n-word-bytes))
 340     (store-symbol-value bsp *binding-stack-pointer*)
 341     (storew temp bsp (- binding-value-slot binding-size))
 342     (storew symbol bsp (- binding-symbol-slot binding-size))
 343     (storew val symbol symbol-value-slot other-pointer-lowtag)))
 344
 345
 346 #!+sb-thread
 347 (define-vop (unbind)
 348     ;; four temporaries?
 349   (:temporary (:sc unsigned-reg) symbol value bsp tls-index)
 350   (:generator 0
 351     (load-binding-stack-pointer bsp)
 352     (loadw symbol bsp (- binding-symbol-slot binding-size))
 353     (loadw value bsp (- binding-value-slot binding-size))
 354
 355     (loadw tls-index symbol symbol-tls-index-slot other-pointer-lowtag)
 356     (inst fs-segment-prefix)
 357     (inst mov (make-ea :dword :base tls-index) value)
 358
 359     (storew 0 bsp (- binding-value-slot binding-size))
 360     (storew 0 bsp (- binding-symbol-slot binding-size))
 361     (inst sub bsp (* binding-size n-word-bytes))
 362     (store-binding-stack-pointer bsp)))
 363
 364 #!-sb-thread
 365 (define-vop (unbind)
 366   (:temporary (:sc unsigned-reg) symbol value bsp)
 367   (:generator 0
 368     (load-symbol-value bsp *binding-stack-pointer*)
 369     (loadw symbol bsp (- binding-symbol-slot binding-size))
 370     (loadw value bsp (- binding-value-slot binding-size))
 371     (storew value symbol symbol-value-slot other-pointer-lowtag)
 372     (storew 0 bsp (- binding-value-slot binding-size))
 373     (storew 0 bsp (- binding-symbol-slot binding-size))
 374     (inst sub bsp (* binding-size n-word-bytes))
 375     (store-symbol-value bsp *binding-stack-pointer*)))
 376
 377
 378 (define-vop (unbind-to-here)
 379   (:args (where :scs (descriptor-reg any-reg)))
 380   (:temporary (:sc unsigned-reg) symbol value bsp #!+sb-thread tls-index)
 381   (:generator 0
 382     (load-binding-stack-pointer bsp)
 383     (inst cmp where bsp)
 384     (inst jmp :e done)
 385
 386     LOOP
 387     (loadw symbol bsp (- binding-symbol-slot binding-size))
 388     (inst or symbol symbol)
 389     (inst jmp :z skip)
 390     (loadw value bsp (- binding-value-slot binding-size))
 391     #!-sb-thread (storew value symbol symbol-value-slot other-pointer-lowtag)
 392
 393     #!+sb-thread (loadw
 394                   tls-index symbol symbol-tls-index-slot other-pointer-lowtag)
 395     #!+sb-thread (inst fs-segment-prefix)
 396     #!+sb-thread (inst mov (make-ea :dword :base tls-index) value)
 397     (storew 0 bsp (- binding-value-slot binding-size))
 398     (storew 0 bsp (- binding-symbol-slot binding-size))
 399
 400     SKIP
 401     (inst sub bsp (* binding-size n-word-bytes))
 402     (inst cmp where bsp)
 403     (inst jmp :ne loop)
 404     (store-binding-stack-pointer bsp)
 405
 406     DONE))
 407 \f
 408
 409 \f
 410 ;;;; closure indexing
 411
 412 (define-full-reffer closure-index-ref *
 413   closure-info-offset fun-pointer-lowtag
 414   (any-reg descriptor-reg) * %closure-index-ref)
 415
 416 (define-full-setter set-funcallable-instance-info *
 417   funcallable-instance-info-offset fun-pointer-lowtag
 418   (any-reg descriptor-reg) * %set-funcallable-instance-info)
 419
 420 (define-full-reffer funcallable-instance-info *
 421   funcallable-instance-info-offset fun-pointer-lowtag
 422   (descriptor-reg any-reg) * %funcallable-instance-info)
 423
 424 (define-vop (funcallable-instance-lexenv cell-ref)
 425   (:variant funcallable-instance-lexenv-slot fun-pointer-lowtag))
 426
 427 (define-vop (closure-ref slot-ref)
 428   (:variant closure-info-offset fun-pointer-lowtag))
 429
 430 (define-vop (closure-init slot-set)
 431   (:variant closure-info-offset fun-pointer-lowtag))
 432 \f
 433 ;;;; value cell hackery
 434
 435 (define-vop (value-cell-ref cell-ref)
 436   (:variant value-cell-value-slot other-pointer-lowtag))
 437
 438 (define-vop (value-cell-set cell-set)
 439   (:variant value-cell-value-slot other-pointer-lowtag))
 440 \f
 441 ;;;; structure hackery
 442
 443 (define-vop (instance-length)
 444   (:policy :fast-safe)
 445   (:translate %instance-length)
 446   (:args (struct :scs (descriptor-reg)))
 447   (:results (res :scs (unsigned-reg)))
 448   (:result-types positive-fixnum)
 449   (:generator 4
 450     (loadw res struct 0 instance-pointer-lowtag)
 451     (inst shr res n-widetag-bits)))
 452
 453 (define-full-reffer instance-index-ref * instance-slots-offset
 454   instance-pointer-lowtag (any-reg descriptor-reg) * %instance-ref)
 455
 456 (define-full-setter instance-index-set * instance-slots-offset
 457   instance-pointer-lowtag (any-reg descriptor-reg) * %instance-set)
 458
 459
 460 (defknown %instance-set-conditional (instance index t t) t
 461           (unsafe))
 462
 463 (define-vop (instance-set-conditional)
 464   (:translate %instance-set-conditional)
 465   (:args (object :scs (descriptor-reg) :to :eval)
 466          (slot :scs (any-reg) :to :result)
 467          (old-value :scs (descriptor-reg any-reg) :target eax)
 468          (new-value :scs (descriptor-reg any-reg)))
 469   (:arg-types instance positive-fixnum * *)
 470   (:temporary (:sc descriptor-reg :offset eax-offset
 471                    :from (:argument 2) :to :result :target result)  eax)
 472   (:results (result :scs (descriptor-reg any-reg)))
 473   ;(:guard (backend-featurep :i486))
 474   (:policy :fast-safe)
 475   (:generator 5
 476     (move eax old-value)
 477     (inst lock)
 478     (inst cmpxchg (make-ea :dword :base object :index slot :scale 1
 479                            :disp (- (* instance-slots-offset n-word-bytes)
 480                                     instance-pointer-lowtag))
 481           new-value)
 482     (move result eax)))
 483
 484
 485 \f
 486 ;;;; code object frobbing
 487
 488 (define-full-reffer code-header-ref * 0 other-pointer-lowtag
 489   (any-reg descriptor-reg) * code-header-ref)
 490
 491 (define-full-setter code-header-set * 0 other-pointer-lowtag
 492   (any-reg descriptor-reg) * code-header-set)
 493
 494
 495 \f
 496 ;;;; raw instance slot accessors
 497
 498 (define-vop (raw-instance-ref/word)
 499   (:translate %raw-instance-ref/word)
 500   (:policy :fast-safe)
 501   (:args (object :scs (descriptor-reg)) (index :scs (any-reg)))
 502   (:arg-types * tagged-num)
 503   (:temporary (:sc unsigned-reg) tmp)
 504   (:results (value :scs (unsigned-reg)))
 505   (:result-types unsigned-num)
 506   (:generator 5
 507     (loadw tmp object 0 instance-pointer-lowtag)
 508     (inst shr tmp n-widetag-bits)
 509     (inst shl tmp 2)
 510     (inst sub tmp index)
 511     (inst mov
 512           value
 513           (make-ea :dword
 514                    :base object
 515                    :index tmp
 516                    :disp (- (* (1- instance-slots-offset) n-word-bytes)
 517                             instance-pointer-lowtag)))))
 518
 519 (define-vop (raw-instance-set/word)
 520   (:translate %raw-instance-set/word)
 521   (:policy :fast-safe)
 522   (:args (object :scs (descriptor-reg))
 523          (index :scs (any-reg))
 524          (value :scs (unsigned-reg) :target result))
 525   (:arg-types * tagged-num unsigned-num)
 526   (:temporary (:sc unsigned-reg) tmp)
 527   (:results (result :scs (unsigned-reg)))
 528   (:result-types unsigned-num)
 529   (:generator 5
 530     (loadw tmp object 0 instance-pointer-lowtag)
 531     (inst shr tmp n-widetag-bits)
 532     (inst shl tmp 2)
 533     (inst sub tmp index)
 534     (inst mov
 535           (make-ea :dword
 536                    :base object
 537                    :index tmp
 538                    :disp (- (* (1- instance-slots-offset) n-word-bytes)
 539                             instance-pointer-lowtag))
 540           value)
 541     (move result value)))
 542
 543 (define-vop (raw-instance-ref/single)
 544   (:translate %raw-instance-ref/single)
 545   (:policy :fast-safe)
 546   (:args (object :scs (descriptor-reg)) (index :scs (any-reg)))
 547   (:arg-types * tagged-num)
 548   (:temporary (:sc unsigned-reg) tmp)
 549   (:results (value :scs (single-reg)))
 550   (:result-types single-float)
 551   (:generator 5
 552     (loadw tmp object 0 instance-pointer-lowtag)
 553     (inst shr tmp n-widetag-bits)
 554     (inst shl tmp 2)
 555     (inst sub tmp index)
 556     (with-empty-tn@fp-top(value)
 557       (inst fld
 558             (make-ea :dword
 559                      :base object
 560                      :index tmp
 561                      :disp (- (* (1- instance-slots-offset) n-word-bytes)
 562                               instance-pointer-lowtag))))))
 563
 564 (define-vop (raw-instance-set/single)
 565   (:translate %raw-instance-set/single)
 566   (:policy :fast-safe)
 567   (:args (object :scs (descriptor-reg))
 568          (index :scs (any-reg))
 569          (value :scs (single-reg) :target result))
 570   (:arg-types * tagged-num single-float)
 571   (:temporary (:sc unsigned-reg) tmp)
 572   (:results (result :scs (single-reg)))
 573   (:result-types single-float)
 574   (:generator 5
 575     (loadw tmp object 0 instance-pointer-lowtag)
 576     (inst shr tmp n-widetag-bits)
 577     (inst shl tmp 2)
 578     (inst sub tmp index)
 579     (unless (zerop (tn-offset value))
 580       (inst fxch value))
 581     (inst fst
 582           (make-ea :dword
 583                    :base object
 584                    :index tmp
 585                    :disp (- (* (1- instance-slots-offset) n-word-bytes)
 586                             instance-pointer-lowtag)))
 587     (cond
 588       ((zerop (tn-offset value))
 589         (unless (zerop (tn-offset result))
 590           (inst fst result)))
 591       ((zerop (tn-offset result))
 592         (inst fst value))
 593       (t
 594         (unless (location= value result)
 595           (inst fst result))
 596         (inst fxch value)))))
 597
 598 (define-vop (raw-instance-ref/double)
 599   (:translate %raw-instance-ref/double)
 600   (:policy :fast-safe)
 601   (:args (object :scs (descriptor-reg)) (index :scs (any-reg)))
 602   (:arg-types * tagged-num)
 603   (:temporary (:sc unsigned-reg) tmp)
 604   (:results (value :scs (double-reg)))
 605   (:result-types double-float)
 606   (:generator 5
 607     (loadw tmp object 0 instance-pointer-lowtag)
 608     (inst shr tmp n-widetag-bits)
 609     (inst shl tmp 2)
 610     (inst sub tmp index)
 611     (with-empty-tn@fp-top(value)
 612       (inst fldd
 613             (make-ea :dword
 614                      :base object
 615                      :index tmp
 616                      :disp (- (* (- instance-slots-offset 2) n-word-bytes)
 617                               instance-pointer-lowtag))))))
 618
 619 (define-vop (raw-instance-set/double)
 620   (:translate %raw-instance-set/double)
 621   (:policy :fast-safe)
 622   (:args (object :scs (descriptor-reg))
 623          (index :scs (any-reg))
 624          (value :scs (double-reg) :target result))
 625   (:arg-types * tagged-num double-float)
 626   (:temporary (:sc unsigned-reg) tmp)
 627   (:results (result :scs (double-reg)))
 628   (:result-types double-float)
 629   (:generator 5
 630     (loadw tmp object 0 instance-pointer-lowtag)
 631     (inst shr tmp n-widetag-bits)
 632     (inst shl tmp 2)
 633     (inst sub tmp index)
 634     (unless (zerop (tn-offset value))
 635       (inst fxch value))
 636     (inst fstd
 637           (make-ea :dword
 638                    :base object
 639                    :index tmp
 640                    :disp (- (* (- instance-slots-offset 2) n-word-bytes)
 641                             instance-pointer-lowtag)))
 642     (cond
 643       ((zerop (tn-offset value))
 644         (unless (zerop (tn-offset result))
 645           (inst fstd result)))
 646       ((zerop (tn-offset result))
 647         (inst fstd value))
 648       (t
 649         (unless (location= value result)
 650           (inst fstd result))
 651         (inst fxch value)))))
 652
 653 (define-vop (raw-instance-ref/complex-single)
 654   (:translate %raw-instance-ref/complex-single)
 655   (:policy :fast-safe)
 656   (:args (object :scs (descriptor-reg))
 657          (index :scs (any-reg)))
 658   (:arg-types * positive-fixnum)
 659   (:temporary (:sc unsigned-reg) tmp)
 660   (:results (value :scs (complex-single-reg)))
 661   (:result-types complex-single-float)
 662   (:generator 5
 663     (loadw tmp object 0 instance-pointer-lowtag)
 664     (inst shr tmp n-widetag-bits)
 665     (inst shl tmp 2)
 666     (inst sub tmp index)
 667     (let ((real-tn (complex-single-reg-real-tn value)))
 668       (with-empty-tn@fp-top (real-tn)
 669         (inst fld (make-ea :dword
 670                            :base object
 671                            :index tmp
 672                            :disp (- (* (- instance-slots-offset 2)
 673                                        n-word-bytes)
 674                                     instance-pointer-lowtag)))))
 675     (let ((imag-tn (complex-single-reg-imag-tn value)))
 676       (with-empty-tn@fp-top (imag-tn)
 677         (inst fld (make-ea :dword
 678                            :base object
 679                            :index tmp
 680                            :disp (- (* (1- instance-slots-offset)
 681                                        n-word-bytes)
 682                                     instance-pointer-lowtag)))))))
 683
 684 (define-vop (raw-instance-set/complex-single)
 685   (:translate %raw-instance-set/complex-single)
 686   (:policy :fast-safe)
 687   (:args (object :scs (descriptor-reg))
 688          (index :scs (any-reg))
 689          (value :scs (complex-single-reg) :target result))
 690   (:arg-types * positive-fixnum complex-single-float)
 691   (:temporary (:sc unsigned-reg) tmp)
 692   (:results (result :scs (complex-single-reg)))
 693   (:result-types complex-single-float)
 694   (:generator 5
 695     (loadw tmp object 0 instance-pointer-lowtag)
 696     (inst shr tmp n-widetag-bits)
 697     (inst shl tmp 2)
 698     (inst sub tmp index)
 699     (let ((value-real (complex-single-reg-real-tn value))
 700           (result-real (complex-single-reg-real-tn result)))
 701       (cond ((zerop (tn-offset value-real))
 702              ;; Value is in ST0.
 703              (inst fst (make-ea :dword
 704                                 :base object
 705                                 :index tmp
 706                                 :disp (- (* (- instance-slots-offset 2)
 707                                             n-word-bytes)
 708                                          instance-pointer-lowtag)))
 709              (unless (zerop (tn-offset result-real))
 710                ;; Value is in ST0 but not result.
 711                (inst fst result-real)))
 712             (t
 713              ;; Value is not in ST0.
 714              (inst fxch value-real)
 715              (inst fst (make-ea :dword
 716                                 :base object
 717                                 :index tmp
 718                                 :disp (- (* (- instance-slots-offset 2)
 719                                             n-word-bytes)
 720                                          instance-pointer-lowtag)))
 721              (cond ((zerop (tn-offset result-real))
 722                     ;; The result is in ST0.
 723                     (inst fst value-real))
 724                    (t
 725                     ;; Neither value or result are in ST0
 726                     (unless (location= value-real result-real)
 727                       (inst fst result-real))
 728                     (inst fxch value-real))))))
 729     (let ((value-imag (complex-single-reg-imag-tn value))
 730           (result-imag (complex-single-reg-imag-tn result)))
 731       (inst fxch value-imag)
 732       (inst fst (make-ea :dword
 733                          :base object
 734                          :index tmp
 735                          :disp (- (* (1- instance-slots-offset)
 736                                      n-word-bytes)
 737                                   instance-pointer-lowtag)))
 738       (unless (location= value-imag result-imag)
 739         (inst fst result-imag))
 740       (inst fxch value-imag))))
 741
 742 (define-vop (raw-instance-ref/complex-double)
 743   (:translate %raw-instance-ref/complex-double)
 744   (:policy :fast-safe)
 745   (:args (object :scs (descriptor-reg))
 746          (index :scs (any-reg)))
 747   (:arg-types * positive-fixnum)
 748   (:temporary (:sc unsigned-reg) tmp)
 749   (:results (value :scs (complex-double-reg)))
 750   (:result-types complex-double-float)
 751   (:generator 7
 752     (loadw tmp object 0 instance-pointer-lowtag)
 753     (inst shr tmp n-widetag-bits)
 754     (inst shl tmp 2)
 755     (inst sub tmp index)
 756     (let ((real-tn (complex-double-reg-real-tn value)))
 757       (with-empty-tn@fp-top (real-tn)
 758         (inst fldd (make-ea :dword
 759                             :base object
 760                             :index tmp
 761                             :disp (- (* (- instance-slots-offset 4)
 762                                         n-word-bytes)
 763                                      instance-pointer-lowtag)))))
 764     (let ((imag-tn (complex-double-reg-imag-tn value)))
 765       (with-empty-tn@fp-top (imag-tn)
 766         (inst fldd (make-ea :dword
 767                             :base object
 768                             :index tmp
 769                             :disp (- (* (- instance-slots-offset 2)
 770                                         n-word-bytes)
 771                                      instance-pointer-lowtag)))))))
 772
 773 (define-vop (raw-instance-set/complex-double)
 774   (:translate %raw-instance-set/complex-double)
 775   (:policy :fast-safe)
 776   (:args (object :scs (descriptor-reg))
 777          (index :scs (any-reg))
 778          (value :scs (complex-double-reg) :target result))
 779   (:arg-types * positive-fixnum complex-double-float)
 780   (:temporary (:sc unsigned-reg) tmp)
 781   (:results (result :scs (complex-double-reg)))
 782   (:result-types complex-double-float)
 783   (:generator 20
 784     (loadw tmp object 0 instance-pointer-lowtag)
 785     (inst shr tmp n-widetag-bits)
 786     (inst shl tmp 2)
 787     (inst sub tmp index)
 788     (let ((value-real (complex-double-reg-real-tn value))
 789           (result-real (complex-double-reg-real-tn result)))
 790       (cond ((zerop (tn-offset value-real))
 791              ;; Value is in ST0.
 792              (inst fstd (make-ea :dword
 793                                  :base object
 794                                  :index tmp
 795                                  :disp (- (* (- instance-slots-offset 4)
 796                                              n-word-bytes)
 797                                           instance-pointer-lowtag)))
 798              (unless (zerop (tn-offset result-real))
 799                ;; Value is in ST0 but not result.
 800                (inst fstd result-real)))
 801             (t
 802              ;; Value is not in ST0.
 803              (inst fxch value-real)
 804              (inst fstd (make-ea :dword
 805                                  :base object
 806                                  :index tmp
 807                                  :disp (- (* (- instance-slots-offset 4)
 808                                              n-word-bytes)
 809                                           instance-pointer-lowtag)))
 810              (cond ((zerop (tn-offset result-real))
 811                     ;; The result is in ST0.
 812                     (inst fstd value-real))
 813                    (t
 814                     ;; Neither value or result are in ST0
 815                     (unless (location= value-real result-real)
 816                       (inst fstd result-real))
 817                     (inst fxch value-real))))))
 818     (let ((value-imag (complex-double-reg-imag-tn value))
 819           (result-imag (complex-double-reg-imag-tn result)))
 820       (inst fxch value-imag)
 821       (inst fstd (make-ea :dword
 822                           :base object
 823                           :index tmp
 824                           :disp (- (* (- instance-slots-offset 2)
 825                                       n-word-bytes)
 826                                    instance-pointer-lowtag)))
 827       (unless (location= value-imag result-imag)
 828         (inst fstd result-imag))
 829       (inst fxch value-imag))))