src/compiler/x86/macros.lisp

   1 ;;;; a bunch of handy macros for the x86
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!VM")
  13
  14 ;;; We can load/store into fp registers through the top of stack
  15 ;;; %st(0) (fr0 here). Loads imply a push to an empty register which
  16 ;;; then changes all the reg numbers. These macros help manage that.
  17
  18 ;;; Use this when we don't have to load anything. It preserves old tos
  19 ;;; value, but probably destroys tn with operation.
  20 (defmacro with-tn@fp-top((tn) &body body)
  21   `(progn
  22     (unless (zerop (tn-offset ,tn))
  23       (inst fxch ,tn))
  24     ,@body
  25     (unless (zerop (tn-offset ,tn))
  26       (inst fxch ,tn))))
  27
  28 ;;; Use this to prepare for load of new value from memory. This
  29 ;;; changes the register numbering so the next instruction had better
  30 ;;; be a FP load from memory; a register load from another register
  31 ;;; will probably be loading the wrong register!
  32 (defmacro with-empty-tn@fp-top((tn) &body body)
  33   `(progn
  34      (inst fstp ,tn)
  35      ,@body
  36      (unless (zerop (tn-offset ,tn))
  37        (inst fxch ,tn))))                ; save into new dest and restore st(0)
  38 \f
  39 ;;;; instruction-like macros
  40
  41 (defmacro move (dst src)
  42   #!+sb-doc
  43   "Move SRC into DST unless they are location=."
  44   (once-only ((n-dst dst)
  45               (n-src src))
  46     `(unless (location= ,n-dst ,n-src)
  47        (inst mov ,n-dst ,n-src))))
  48
  49 (defmacro align-stack-pointer (tn)
  50   #!-darwin (declare (ignore tn))
  51   #!+darwin
  52   ;; 16 byte alignment.
  53   `(inst and ,tn #xfffffff0))
  54
  55 (defmacro make-ea-for-object-slot (ptr slot lowtag &optional (size :dword))
  56   `(make-ea ,size :base ,ptr :disp (- (* ,slot n-word-bytes) ,lowtag)))
  57
  58 (defmacro loadw (value ptr &optional (slot 0) (lowtag 0))
  59   `(inst mov ,value (make-ea-for-object-slot ,ptr ,slot ,lowtag)))
  60
  61 (defmacro storew (value ptr &optional (slot 0) (lowtag 0))
  62   (once-only ((value value))
  63     `(inst mov (make-ea-for-object-slot ,ptr ,slot ,lowtag) ,value)))
  64
  65 ;;; A handy macro for storing widetags.
  66 (defmacro storeb (value ptr &optional (slot 0) (lowtag 0))
  67   (once-only ((value value))
  68     `(inst mov (make-ea-for-object-slot ,ptr ,slot ,lowtag :byte) ,value)))
  69
  70 (defmacro pushw (ptr &optional (slot 0) (lowtag 0))
  71   `(inst push (make-ea-for-object-slot ,ptr ,slot ,lowtag)))
  72
  73 (defmacro popw (ptr &optional (slot 0) (lowtag 0))
  74   `(inst pop (make-ea-for-object-slot ,ptr ,slot ,lowtag)))
  75
  76 (defmacro make-ea-for-vector-data (object &key (size :dword) (offset 0)
  77                                    index (scale (ash (width-bits size) -3)))
  78   `(make-ea ,size :base ,object :index ,index :scale ,scale
  79             :disp (- (+ (* vector-data-offset n-word-bytes)
  80                         (* ,offset ,scale))
  81                      other-pointer-lowtag)))
  82 \f
  83 ;;;; macros to generate useful values
  84
  85 (defmacro load-symbol (reg symbol)
  86   `(inst mov ,reg (+ nil-value (static-symbol-offset ,symbol))))
  87
  88 (defmacro make-ea-for-symbol-value (symbol &optional (width :dword))
  89   (declare (type symbol symbol))
  90   `(make-ea ,width
  91     :disp (+ nil-value
  92            (static-symbol-offset ',symbol)
  93            (ash symbol-value-slot word-shift)
  94            (- other-pointer-lowtag))))
  95
  96 (defmacro load-symbol-value (reg symbol)
  97   `(inst mov ,reg (make-ea-for-symbol-value ,symbol)))
  98
  99 (defmacro store-symbol-value (reg symbol)
 100   `(inst mov (make-ea-for-symbol-value ,symbol) ,reg))
 101
 102 #!+sb-thread
 103 (defmacro make-ea-for-symbol-tls-index (symbol)
 104   (declare (type symbol symbol))
 105   `(make-ea :dword
 106     :disp (+ nil-value
 107            (static-symbol-offset ',symbol)
 108            (ash symbol-tls-index-slot word-shift)
 109            (- other-pointer-lowtag))))
 110
 111 #!+sb-thread
 112 (defmacro load-tl-symbol-value (reg symbol)
 113   `(progn
 114     (inst mov ,reg (make-ea-for-symbol-tls-index ,symbol))
 115     (inst fs-segment-prefix)
 116     (inst mov ,reg (make-ea :dword :base ,reg))))
 117 #!-sb-thread
 118 (defmacro load-tl-symbol-value (reg symbol) `(load-symbol-value ,reg ,symbol))
 119
 120 #!+sb-thread
 121 (defmacro store-tl-symbol-value (reg symbol temp)
 122   `(progn
 123     (inst mov ,temp (make-ea-for-symbol-tls-index ,symbol))
 124     (inst fs-segment-prefix)
 125     (inst mov (make-ea :dword :base ,temp) ,reg)))
 126 #!-sb-thread
 127 (defmacro store-tl-symbol-value (reg symbol temp)
 128   (declare (ignore temp))
 129   `(store-symbol-value ,reg ,symbol))
 130
 131 (defmacro load-binding-stack-pointer (reg)
 132   #!+sb-thread
 133   `(progn
 134      (inst fs-segment-prefix)
 135      (inst mov ,reg (make-ea :dword
 136                              :disp (* 4 thread-binding-stack-pointer-slot))))
 137   #!-sb-thread
 138   `(load-symbol-value ,reg *binding-stack-pointer*))
 139
 140 (defmacro store-binding-stack-pointer (reg)
 141   #!+sb-thread
 142   `(progn
 143      (inst fs-segment-prefix)
 144      (inst mov (make-ea :dword
 145                         :disp (* 4 thread-binding-stack-pointer-slot))
 146            ,reg))
 147   #!-sb-thread
 148   `(store-symbol-value ,reg *binding-stack-pointer*))
 149
 150 (defmacro load-type (target source &optional (offset 0))
 151   #!+sb-doc
 152   "Loads the type bits of a pointer into target independent of
 153    byte-ordering issues."
 154   (once-only ((n-target target)
 155               (n-source source)
 156               (n-offset offset))
 157     (ecase *backend-byte-order*
 158       (:little-endian
 159        `(inst mov ,n-target
 160               (make-ea :byte :base ,n-source :disp ,n-offset)))
 161       (:big-endian
 162        `(inst mov ,n-target
 163               (make-ea :byte :base ,n-source
 164                              :disp (+ ,n-offset (1- n-word-bytes))))))))
 165 \f
 166 ;;;; allocation helpers
 167
 168 ;;; Allocation within alloc_region (which is thread local) can be done
 169 ;;; inline.  If the alloc_region is overflown allocation is done by
 170 ;;; calling the C alloc() function.
 171
 172 ;;; C calls for allocation don't /seem/ to make an awful lot of
 173 ;;; difference to speed. On pure consing it's about a 25%
 174 ;;; gain. Guessing from historical context, it looks like inline
 175 ;;; allocation was introduced before pseudo-atomic, at which time all
 176 ;;; calls to alloc() would have needed a syscall to mask signals for
 177 ;;; the duration.  Now we have pseudoatomic there's no need for that
 178 ;;; overhead.
 179
 180 (defun allocation-dynamic-extent (alloc-tn size lowtag)
 181   (inst sub esp-tn size)
 182   ;; FIXME: SIZE _should_ be double-word aligned (suggested but
 183   ;; unfortunately not enforced by PAD-DATA-BLOCK and
 184   ;; WITH-FIXED-ALLOCATION), so that ESP is always divisible by 8 (for
 185   ;; 32-bit lispobjs).  In that case, this AND instruction is
 186   ;; unneccessary and could be removed.  If not, explain why.  -- CSR,
 187   ;; 2004-03-30
 188   (inst and esp-tn (lognot lowtag-mask))
 189   (aver (not (location= alloc-tn esp-tn)))
 190   (inst lea alloc-tn (make-ea :byte :base esp-tn :disp lowtag))
 191   (values))
 192
 193 (defun allocation-notinline (alloc-tn size)
 194   (let* ((alloc-tn-offset (tn-offset alloc-tn))
 195          ;; C call to allocate via dispatch routines. Each
 196          ;; destination has a special entry point. The size may be a
 197          ;; register or a constant.
 198          (tn-text (ecase alloc-tn-offset
 199                     (#.eax-offset "eax")
 200                     (#.ecx-offset "ecx")
 201                     (#.edx-offset "edx")
 202                     (#.ebx-offset "ebx")
 203                     (#.esi-offset "esi")
 204                     (#.edi-offset "edi")))
 205          (size-text (case size (8 "8_") (16 "16_") (t ""))))
 206     (unless (or (eql size 8) (eql size 16))
 207       (unless (and (tn-p size) (location= alloc-tn size))
 208         (inst mov alloc-tn size)))
 209     (inst call (make-fixup (concatenate 'string
 210                                          "alloc_" size-text
 211                                          "to_" tn-text)
 212                            :foreign))))
 213
 214 (defun allocation-inline (alloc-tn size)
 215   (let ((ok (gen-label))
 216         (done (gen-label))
 217         (free-pointer
 218          (make-ea :dword :disp
 219                   #!+sb-thread (* n-word-bytes thread-alloc-region-slot)
 220                   #!-sb-thread (make-fixup "boxed_region" :foreign)
 221                   :scale 1)) ; thread->alloc_region.free_pointer
 222         (end-addr
 223          (make-ea :dword :disp
 224                   #!+sb-thread (* n-word-bytes (1+ thread-alloc-region-slot))
 225                   #!-sb-thread (make-fixup "boxed_region" :foreign 4)
 226                   :scale 1)))   ; thread->alloc_region.end_addr
 227     (unless (and (tn-p size) (location= alloc-tn size))
 228       (inst mov alloc-tn size))
 229     #!+sb-thread (inst fs-segment-prefix)
 230     (inst add alloc-tn free-pointer)
 231     #!+sb-thread (inst fs-segment-prefix)
 232     (inst cmp alloc-tn end-addr)
 233     (inst jmp :be ok)
 234     (let ((dst (ecase (tn-offset alloc-tn)
 235                  (#.eax-offset "alloc_overflow_eax")
 236                  (#.ecx-offset "alloc_overflow_ecx")
 237                  (#.edx-offset "alloc_overflow_edx")
 238                  (#.ebx-offset "alloc_overflow_ebx")
 239                  (#.esi-offset "alloc_overflow_esi")
 240                  (#.edi-offset "alloc_overflow_edi"))))
 241       (inst call (make-fixup dst :foreign)))
 242     (inst jmp-short done)
 243     (emit-label ok)
 244     ;; Swap ALLOC-TN and FREE-POINTER
 245     (cond ((and (tn-p size) (location= alloc-tn size))
 246            ;; XCHG is extremely slow, use the xor swap trick
 247            #!+sb-thread (inst fs-segment-prefix)
 248            (inst xor alloc-tn free-pointer)
 249            #!+sb-thread (inst fs-segment-prefix)
 250            (inst xor free-pointer alloc-tn)
 251            #!+sb-thread (inst fs-segment-prefix)
 252            (inst xor alloc-tn free-pointer))
 253           (t
 254            ;; It's easier if SIZE is still available.
 255            #!+sb-thread (inst fs-segment-prefix)
 256            (inst mov free-pointer alloc-tn)
 257            (inst sub alloc-tn size)))
 258     (emit-label done))
 259   (values))
 260
 261
 262 ;;; Emit code to allocate an object with a size in bytes given by
 263 ;;; SIZE.  The size may be an integer or a TN. If Inline is a VOP
 264 ;;; node-var then it is used to make an appropriate speed vs size
 265 ;;; decision.
 266
 267 ;;; Allocation should only be used inside a pseudo-atomic section, which
 268 ;;; should also cover subsequent initialization of the object.
 269
 270 ;;; (FIXME: so why aren't we asserting this?)
 271
 272 (defun allocation (alloc-tn size &optional inline dynamic-extent lowtag)
 273   (cond
 274     (dynamic-extent
 275      (allocation-dynamic-extent alloc-tn size lowtag))
 276     ((or (null inline) (policy inline (>= speed space)))
 277      (allocation-inline alloc-tn size))
 278     (t
 279      (allocation-notinline alloc-tn size)))
 280   (when (and lowtag (not dynamic-extent))
 281     (inst lea alloc-tn (make-ea :byte :base alloc-tn :disp lowtag)))
 282   (values))
 283
 284 ;;; Allocate an other-pointer object of fixed SIZE with a single word
 285 ;;; header having the specified WIDETAG value. The result is placed in
 286 ;;; RESULT-TN.
 287 (defmacro with-fixed-allocation ((result-tn widetag size &optional inline stack-allocate-p)
 288                                  &body forms)
 289   (unless forms
 290     (bug "empty &body in WITH-FIXED-ALLOCATION"))
 291   (once-only ((result-tn result-tn) (size size) (stack-allocate-p stack-allocate-p))
 292     `(maybe-pseudo-atomic ,stack-allocate-p
 293        (allocation ,result-tn (pad-data-block ,size) ,inline ,stack-allocate-p
 294                    other-pointer-lowtag)
 295        (storew (logior (ash (1- ,size) n-widetag-bits) ,widetag)
 296                ,result-tn 0 other-pointer-lowtag)
 297        ,@forms)))
 298 \f
 299 ;;;; error code
 300 (defun emit-error-break (vop kind code values)
 301   (assemble ()
 302     #!-darwin
 303     (inst int 3)                        ; i386 breakpoint instruction
 304     ;; CLH 20060314
 305     ;; On Darwin, we need to use #x0b0f instead of int3 in order
 306     ;; to generate a SIGILL instead of a SIGTRAP as darwin/x86
 307     ;; doesn't seem to be reliably firing SIGTRAP
 308     ;; handlers. Hopefully this will be fixed by Apple at a
 309     ;; later date.
 310     #!+darwin
 311     (inst word #x0b0f)
 312     ;; The return PC points here; note the location for the debugger.
 313     (when vop
 314       (note-this-location vop :internal-error))
 315     (inst byte kind)                    ; e.g. trap_xyyy
 316     (with-adjustable-vector (vector)    ; interr arguments
 317       (write-var-integer code vector)
 318       (dolist (tn values)
 319         ;; classic CMU CL comment:
 320         ;;   zzzzz jrd here. tn-offset is zero for constant
 321         ;;   tns.
 322         (write-var-integer (make-sc-offset (sc-number (tn-sc tn))
 323                                            (or (tn-offset tn) 0))
 324                            vector))
 325       (inst byte (length vector))
 326       (dotimes (i (length vector))
 327         (inst byte (aref vector i))))))
 328
 329 (defun error-call (vop error-code &rest values)
 330   #!+sb-doc
 331   "Cause an error. ERROR-CODE is the error to cause."
 332   (emit-error-break vop error-trap (error-number-or-lose error-code) values))
 333
 334 (defun generate-error-code (vop error-code &rest values)
 335   #!+sb-doc
 336   "Generate-Error-Code Error-code Value*
 337   Emit code for an error with the specified Error-Code and context Values."
 338   (assemble (*elsewhere*)
 339     (let ((start-lab (gen-label)))
 340       (emit-label start-lab)
 341       (emit-error-break vop error-trap (error-number-or-lose error-code) values)
 342       start-lab)))
 343
 344 \f
 345 ;;;; PSEUDO-ATOMIC
 346
 347 ;;; This is used to wrap operations which leave untagged memory lying
 348 ;;; around.  It's an operation which the AOP weenies would describe as
 349 ;;; having "cross-cutting concerns", meaning it appears all over the
 350 ;;; place and there's no logical single place to attach documentation.
 351 ;;; grep (mostly in src/runtime) is your friend
 352
 353 ;;; KLUDGE: since the stack on the x86 is treated conservatively, it
 354 ;;; does not matter whether a signal occurs during construction of a
 355 ;;; dynamic-extent object, as the half-finished construction of the
 356 ;;; object will not cause any difficulty.  We can therefore elide
 357 (defmacro maybe-pseudo-atomic (not-really-p &body forms)
 358   `(if ,not-really-p
 359        (progn ,@forms)
 360        (pseudo-atomic ,@forms)))
 361
 362 #!+sb-thread
 363 (defmacro pseudo-atomic (&rest forms)
 364   (with-unique-names (label)
 365     `(let ((,label (gen-label)))
 366        (inst fs-segment-prefix)
 367        (inst or (make-ea :byte :disp (* 4 thread-pseudo-atomic-bits-slot))
 368             (fixnumize 1))
 369        ,@forms
 370        (inst fs-segment-prefix)
 371        (inst xor (make-ea :byte :disp (* 4 thread-pseudo-atomic-bits-slot))
 372              (fixnumize 1))
 373        (inst jmp :z ,label)
 374        ;; if PAI was set, interrupts were disabled at the same
 375        ;; time using the process signal mask.
 376        (inst break pending-interrupt-trap)
 377        (emit-label ,label))))
 378
 379 #!-sb-thread
 380 (defmacro pseudo-atomic (&rest forms)
 381   (with-unique-names (label)
 382     `(let ((,label (gen-label)))
 383        (inst or (make-ea-for-symbol-value *pseudo-atomic-bits* :byte)
 384              (fixnumize 1))
 385        ,@forms
 386        (inst xor (make-ea-for-symbol-value *pseudo-atomic-bits* :byte)
 387              (fixnumize 1))
 388        (inst jmp :z ,label)
 389        ;; if PAI was set, interrupts were disabled at the same
 390        ;; time using the process signal mask.
 391        (inst break pending-interrupt-trap)
 392        (emit-label ,label))))
 393 \f
 394 ;;;; indexed references
 395
 396 (defmacro define-full-compare-and-swap
 397     (name type offset lowtag scs el-type &optional translate)
 398   `(progn
 399      (define-vop (,name)
 400          ,@(when translate `((:translate ,translate)))
 401        (:policy :fast-safe)
 402        (:args (object :scs (descriptor-reg) :to :eval)
 403               (index :scs (any-reg immediate unsigned-reg) :to :result)
 404               (old-value :scs ,scs :target eax)
 405               (new-value :scs ,scs))
 406        (:arg-types ,type tagged-num ,el-type ,el-type)
 407        (:temporary (:sc descriptor-reg :offset eax-offset
 408                         :from (:argument 2) :to :result :target value)  eax)
 409        (:results (value :scs ,scs))
 410        (:result-types ,el-type)
 411        (:generator 5
 412          (move eax old-value)
 413          #!+sb-thread
 414          (inst lock)
 415          (let ((ea (sc-case index
 416                      (immediate
 417                       (make-ea :dword :base object
 418                                :disp (- (* (+ ,offset (tn-value index))
 419                                            n-word-bytes)
 420                                         ,lowtag)))
 421                      (unsigned-reg
 422                       (make-ea :dword :base object :index index :scale 4
 423                                :disp (- (* ,offset n-word-bytes)
 424                                         ,lowtag)))
 425                      (t
 426                       (make-ea :dword :base object :index index
 427                                :disp (- (* ,offset n-word-bytes)
 428                                         ,lowtag))))))
 429            (inst cmpxchg ea new-value))
 430          (move value eax)))))
 431
 432 (defmacro define-full-reffer (name type offset lowtag scs el-type &optional translate)
 433   `(progn
 434      (define-vop (,name)
 435        ,@(when translate
 436            `((:translate ,translate)))
 437        (:policy :fast-safe)
 438        (:args (object :scs (descriptor-reg))
 439               (index :scs (any-reg immediate unsigned-reg)))
 440        (:arg-types ,type tagged-num)
 441        (:results (value :scs ,scs))
 442        (:result-types ,el-type)
 443        (:generator 3                    ; pw was 5
 444          (sc-case index
 445            (immediate
 446             (inst mov value (make-ea :dword :base object
 447                                      :disp (- (* (+ ,offset (tn-value index))
 448                                                  n-word-bytes)
 449                                               ,lowtag))))
 450            (unsigned-reg
 451             (inst mov value (make-ea :dword :base object :index index :scale 4
 452                                      :disp (- (* ,offset n-word-bytes)
 453                                               ,lowtag))))
 454            (t
 455             (inst mov value (make-ea :dword :base object :index index
 456                                      :disp (- (* ,offset n-word-bytes)
 457                                               ,lowtag)))))))))
 458
 459 (defmacro define-full-reffer+offset (name type offset lowtag scs el-type &optional translate)
 460   `(progn
 461      (define-vop (,name)
 462        ,@(when translate
 463            `((:translate ,translate)))
 464        (:policy :fast-safe)
 465        (:args (object :scs (descriptor-reg))
 466               (index :scs (any-reg immediate unsigned-reg)))
 467        (:arg-types ,type tagged-num
 468                    (:constant (constant-displacement ,lowtag sb!vm:n-word-bytes ,offset)))
 469        (:info offset)
 470        (:results (value :scs ,scs))
 471        (:result-types ,el-type)
 472        (:generator 3                    ; pw was 5
 473          (sc-case index
 474            (immediate
 475             (inst mov value (make-ea :dword :base object
 476                                      :disp (- (* (+ ,offset
 477                                                     (tn-value index)
 478                                                     offset)
 479                                                  n-word-bytes)
 480                                               ,lowtag))))
 481            (unsigned-reg
 482             (inst mov value (make-ea :dword :base object :index index :scale 4
 483                                      :disp (- (* (+ ,offset offset)
 484                                                  n-word-bytes)
 485                                               ,lowtag))))
 486            (t
 487             (inst mov value (make-ea :dword :base object :index index
 488                                      :disp (- (* (+ ,offset offset)
 489                                                  n-word-bytes)
 490                                               ,lowtag)))))))))
 491
 492 (defmacro define-full-setter (name type offset lowtag scs el-type &optional translate)
 493   `(progn
 494      (define-vop (,name)
 495        ,@(when translate
 496            `((:translate ,translate)))
 497        (:policy :fast-safe)
 498        (:args (object :scs (descriptor-reg))
 499               (index :scs (any-reg immediate))
 500               (value :scs ,scs :target result))
 501        (:arg-types ,type tagged-num ,el-type)
 502        (:results (result :scs ,scs))
 503        (:result-types ,el-type)
 504        (:generator 4                    ; was 5
 505          (sc-case index
 506            (immediate
 507             (inst mov (make-ea :dword :base object
 508                                :disp (- (* (+ ,offset (tn-value index))
 509                                            n-word-bytes)
 510                                         ,lowtag))
 511                   value))
 512            (t
 513             (inst mov (make-ea :dword :base object :index index
 514                                :disp (- (* ,offset n-word-bytes) ,lowtag))
 515                   value)))
 516         (move result value)))))
 517
 518 (defmacro define-full-setter+offset (name type offset lowtag scs el-type &optional translate)
 519   `(progn
 520      (define-vop (,name)
 521        ,@(when translate
 522            `((:translate ,translate)))
 523        (:policy :fast-safe)
 524        (:args (object :scs (descriptor-reg))
 525               (index :scs (any-reg immediate))
 526               (value :scs ,scs :target result))
 527        (:info offset)
 528        (:arg-types ,type tagged-num
 529                    (:constant (constant-displacement ,lowtag sb!vm:n-word-bytes ,offset)) ,el-type)
 530        (:results (result :scs ,scs))
 531        (:result-types ,el-type)
 532        (:generator 4                    ; was 5
 533          (sc-case index
 534            (immediate
 535             (inst mov (make-ea :dword :base object
 536                                :disp (- (* (+ ,offset (tn-value index) offset)
 537                                            n-word-bytes)
 538                                         ,lowtag))
 539                   value))
 540            (t
 541             (inst mov (make-ea :dword :base object :index index
 542                                :disp (- (* (+ ,offset offset)
 543                                            n-word-bytes) ,lowtag))
 544                   value)))
 545         (move result value)))))
 546
 547 ;;; helper for alien stuff.
 548
 549 (def!macro with-pinned-objects ((&rest objects) &body body)
 550   "Arrange with the garbage collector that the pages occupied by
 551 OBJECTS will not be moved in memory for the duration of BODY.
 552 Useful for e.g. foreign calls where another thread may trigger
 553 collection."
 554   (if objects
 555       (let ((pins (make-gensym-list (length objects)))
 556             (wpo (block-gensym "WPO")))
 557         ;; BODY is stuffed in a function to preserve the lexical
 558         ;; environment.
 559         `(flet ((,wpo () (progn ,@body)))
 560            ;; PINS are dx-allocated in case the compiler for some
 561            ;; unfathomable reason decides to allocate value-cells
 562            ;; for them -- since we have DX value-cells on x86oid
 563            ;; platforms this still forces them on the stack.
 564            (dx-let ,(mapcar #'list pins objects)
 565              (multiple-value-prog1 (,wpo)
 566                ;; TOUCH-OBJECT has a VOP with an empty body: compiler
 567                ;; thinks we're using the argument and doesn't flush
 568                ;; the variable, but we don't have to pay any extra
 569                ;; beyond that -- and MULTIPLE-VALUE-PROG1 keeps them
 570                ;; live till the body has finished. *whew*
 571                ,@(mapcar (lambda (pin)
 572                            `(touch-object ,pin))
 573                          pins)))))
 574       `(progn ,@body)))