src/compiler/x86/move.lisp

   1 ;;;; the x86 VM definition of operand loading/saving and the MOVE vop
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!VM")
  13
  14 (file-comment
  15  "$Header$")
  16
  17 (define-move-function (load-immediate 1) (vop x y)
  18   ((immediate)
  19    (any-reg descriptor-reg))
  20   (let ((val (tn-value x)))
  21     (etypecase val
  22       (integer
  23        (if (zerop val)
  24            (inst xor y y)
  25          (inst mov y (fixnumize val))))
  26       (symbol
  27        (load-symbol y val))
  28       (character
  29        (inst mov y (logior (ash (char-code val) type-bits)
  30                            base-char-type))))))
  31
  32 (define-move-function (load-number 1) (vop x y)
  33   ((immediate) (signed-reg unsigned-reg))
  34   (inst mov y (tn-value x)))
  35
  36 (define-move-function (load-base-char 1) (vop x y)
  37   ((immediate) (base-char-reg))
  38   (inst mov y (char-code (tn-value x))))
  39
  40 (define-move-function (load-system-area-pointer 1) (vop x y)
  41   ((immediate) (sap-reg))
  42   (inst mov y (sap-int (tn-value x))))
  43
  44 (define-move-function (load-constant 5) (vop x y)
  45   ((constant) (descriptor-reg any-reg))
  46   (inst mov y x))
  47
  48 (define-move-function (load-stack 5) (vop x y)
  49   ((control-stack) (any-reg descriptor-reg)
  50    (base-char-stack) (base-char-reg)
  51    (sap-stack) (sap-reg)
  52    (signed-stack) (signed-reg)
  53    (unsigned-stack) (unsigned-reg))
  54   (inst mov y x))
  55
  56 (define-move-function (store-stack 5) (vop x y)
  57   ((any-reg descriptor-reg) (control-stack)
  58    (base-char-reg) (base-char-stack)
  59    (sap-reg) (sap-stack)
  60    (signed-reg) (signed-stack)
  61    (unsigned-reg) (unsigned-stack))
  62   (inst mov y x))
  63 \f
  64 ;;;; the MOVE VOP
  65 (define-vop (move)
  66   (:args (x :scs (any-reg descriptor-reg immediate) :target y
  67             :load-if (not (location= x y))))
  68   (:results (y :scs (any-reg descriptor-reg)
  69                :load-if
  70                (not (or (location= x y)
  71                         (and (sc-is x any-reg descriptor-reg immediate)
  72                              (sc-is y control-stack))))))
  73   (:effects)
  74   (:affected)
  75   (:generator 0
  76     (if (and (sc-is x immediate)
  77              (sc-is y any-reg descriptor-reg control-stack))
  78         (let ((val (tn-value x)))
  79           (etypecase val
  80             (integer
  81              (if (and (zerop val) (sc-is y any-reg descriptor-reg))
  82                  (inst xor y y)
  83                (inst mov y (fixnumize val))))
  84             (symbol
  85              (inst mov y (+ nil-value (static-symbol-offset val))))
  86             (character
  87              (inst mov y (logior (ash (char-code val) type-bits)
  88                                  base-char-type)))))
  89       (move y x))))
  90
  91 (define-move-vop move :move
  92   (any-reg descriptor-reg immediate)
  93   (any-reg descriptor-reg))
  94
  95 ;;; Make Move the check VOP for T so that type check generation
  96 ;;; doesn't think it is a hairy type. This also allows checking of a
  97 ;;; few of the values in a continuation to fall out.
  98 (primitive-type-vop move (:check) t)
  99
 100 ;;; The Move-Argument VOP is used for moving descriptor values into
 101 ;;; another frame for argument or known value passing.
 102 ;;;
 103 ;;; Note: It is not going to be possible to move a constant directly
 104 ;;; to another frame, except if the destination is a register and in
 105 ;;; this case the loading works out.
 106 (define-vop (move-argument)
 107   (:args (x :scs (any-reg descriptor-reg immediate) :target y
 108             :load-if (not (and (sc-is y any-reg descriptor-reg)
 109                                (sc-is x control-stack))))
 110          (fp :scs (any-reg)
 111              :load-if (not (sc-is y any-reg descriptor-reg))))
 112   (:results (y))
 113   (:generator 0
 114     (sc-case y
 115       ((any-reg descriptor-reg)
 116        (if (sc-is x immediate)
 117            (let ((val (tn-value x)))
 118              (etypecase val
 119               (integer
 120                (if (zerop val)
 121                    (inst xor y y)
 122                  (inst mov y (fixnumize val))))
 123               (symbol
 124                (load-symbol y val))
 125               (character
 126                (inst mov y (logior (ash (char-code val) type-bits)
 127                                    base-char-type)))))
 128          (move y x)))
 129       ((control-stack)
 130        (if (sc-is x immediate)
 131            (let ((val (tn-value x)))
 132              (if (= (tn-offset fp) esp-offset)
 133                  ;; C-call
 134                  (etypecase val
 135                    (integer
 136                     (storew (fixnumize val) fp (tn-offset y)))
 137                    (symbol
 138                     (storew (+ nil-value (static-symbol-offset val))
 139                             fp (tn-offset y)))
 140                    (character
 141                     (storew (logior (ash (char-code val) type-bits)
 142                                     base-char-type)
 143                             fp (tn-offset y))))
 144                ;; Lisp stack
 145                (etypecase val
 146                  (integer
 147                   (storew (fixnumize val) fp (- (1+ (tn-offset y)))))
 148                  (symbol
 149                   (storew (+ nil-value (static-symbol-offset val))
 150                           fp (- (1+ (tn-offset y)))))
 151                  (character
 152                   (storew (logior (ash (char-code val) type-bits)
 153                                   base-char-type)
 154                           fp (- (1+ (tn-offset y))))))))
 155          (if (= (tn-offset fp) esp-offset)
 156              ;; C-call
 157              (storew x fp (tn-offset y))
 158            ;; Lisp stack
 159            (storew x fp (- (1+ (tn-offset y))))))))))
 160
 161 (define-move-vop move-argument :move-argument
 162   (any-reg descriptor-reg)
 163   (any-reg descriptor-reg))
 164 \f
 165 ;;;; ILLEGAL-MOVE
 166
 167 ;;; This VOP exists just to begin the lifetime of a TN that couldn't
 168 ;;; be written legally due to a type error. An error is signalled
 169 ;;; before this VOP is so we don't need to do anything (not that there
 170 ;;; would be anything sensible to do anyway.)
 171 (define-vop (illegal-move)
 172   (:args (x) (type))
 173   (:results (y))
 174   (:ignore y)
 175   (:vop-var vop)
 176   (:save-p :compute-only)
 177   (:generator 666
 178     (error-call vop object-not-type-error x type)))
 179 \f
 180 ;;;; moves and coercions
 181
 182 ;;; These MOVE-TO-WORD VOPs move a tagged integer to a raw full-word
 183 ;;; representation. Similarly, the MOVE-FROM-WORD VOPs converts a raw
 184 ;;; integer to a tagged bignum or fixnum.
 185
 186 ;;; Arg is a fixnum, so just shift it. We need a type restriction
 187 ;;; because some possible arg SCs (control-stack) overlap with
 188 ;;; possible bignum arg SCs.
 189 (define-vop (move-to-word/fixnum)
 190   (:args (x :scs (any-reg descriptor-reg) :target y
 191             :load-if (not (location= x y))))
 192   (:results (y :scs (signed-reg unsigned-reg)
 193                :load-if (not (location= x y))))
 194   (:arg-types tagged-num)
 195   (:note "fixnum untagging")
 196   (:generator 1
 197     (move y x)
 198     (inst sar y 2)))
 199 (define-move-vop move-to-word/fixnum :move
 200   (any-reg descriptor-reg) (signed-reg unsigned-reg))
 201
 202 ;;; Arg is a non-immediate constant, load it.
 203 (define-vop (move-to-word-c)
 204   (:args (x :scs (constant)))
 205   (:results (y :scs (signed-reg unsigned-reg)))
 206   (:note "constant load")
 207   (:generator 1
 208     (inst mov y (tn-value x))))
 209 (define-move-vop move-to-word-c :move
 210   (constant) (signed-reg unsigned-reg))
 211
 212
 213 ;;; Arg is a fixnum or bignum, figure out which and load if necessary.
 214 (define-vop (move-to-word/integer)
 215   (:args (x :scs (descriptor-reg) :target eax))
 216   (:results (y :scs (signed-reg unsigned-reg)))
 217   (:note "integer to untagged word coercion")
 218   (:temporary (:sc unsigned-reg :offset eax-offset
 219                    :from (:argument 0) :to (:result 0) :target y) eax)
 220   (:generator 4
 221     (move eax x)
 222     (inst test al-tn 3)
 223     (inst jmp :z fixnum)
 224     (loadw y eax bignum-digits-offset other-pointer-type)
 225     (inst jmp done)
 226     FIXNUM
 227     (inst sar eax 2)
 228     (move y eax)
 229     DONE))
 230 (define-move-vop move-to-word/integer :move
 231   (descriptor-reg) (signed-reg unsigned-reg))
 232
 233
 234 ;;; Result is a fixnum, so we can just shift. We need the result type
 235 ;;; restriction because of the control-stack ambiguity noted above.
 236 (define-vop (move-from-word/fixnum)
 237   (:args (x :scs (signed-reg unsigned-reg) :target y
 238             :load-if (not (location= x y))))
 239   (:results (y :scs (any-reg descriptor-reg)
 240                :load-if (not (location= x y))))
 241   (:result-types tagged-num)
 242   (:note "fixnum tagging")
 243   (:generator 1
 244     (cond ((and (sc-is x signed-reg unsigned-reg)
 245                 (not (location= x y)))
 246            ;; Uses 7 bytes, but faster on the Pentium
 247            (inst lea y (make-ea :dword :index x :scale 4)))
 248           (t
 249            ;; Uses: If x is a reg 2 + 3; if x = y uses only 3 bytes
 250            (move y x)
 251            (inst shl y 2)))))
 252 (define-move-vop move-from-word/fixnum :move
 253   (signed-reg unsigned-reg) (any-reg descriptor-reg))
 254
 255 ;;; Result may be a bignum, so we have to check. Use a worst-case cost
 256 ;;; to make sure people know they may be number consing.
 257 ;;;
 258 ;;; KLUDGE: I assume this is suppressed in favor of the "faster inline
 259 ;;; version" below. (See also mysterious comment "we don't want a VOP
 260 ;;; on this one" on DEFINE-ASSEMBLY-ROUTINE (MOVE-FROM-SIGNED) in
 261 ;;; "src/assembly/x86/alloc.lisp".) -- WHN 19990916
 262 #+nil
 263 (define-vop (move-from-signed)
 264   (:args (x :scs (signed-reg unsigned-reg) :target eax))
 265   (:temporary (:sc unsigned-reg :offset eax-offset :from (:argument 0)) eax)
 266   (:temporary (:sc unsigned-reg :offset ebx-offset :to (:result 0) :target y)
 267               ebx)
 268   (:temporary (:sc unsigned-reg :offset ecx-offset
 269                    :from (:argument 0) :to (:result 0)) ecx)
 270   (:ignore ecx)
 271   (:results (y :scs (any-reg descriptor-reg)))
 272   (:note "signed word to integer coercion")
 273   (:generator 20
 274     (move eax x)
 275     (inst call (make-fixup 'move-from-signed :assembly-routine))
 276     (move y ebx)))
 277 ;;; Faster inline version,
 278 ;;; KLUDGE: Do we really want the faster inline version? It's sorta big.
 279 ;;; It is nice that it doesn't use any temporaries, though. -- WHN 19990916
 280 (define-vop (move-from-signed)
 281   (:args (x :scs (signed-reg unsigned-reg) :to :result))
 282   (:results (y :scs (any-reg descriptor-reg) :from :argument))
 283   (:note "signed word to integer coercion")
 284   (:node-var node)
 285   (:generator 20
 286      (assert (not (location= x y)))
 287      (let ((bignum (gen-label))
 288            (done (gen-label)))
 289        (inst mov y x)
 290        (inst shl y 1)
 291        (inst jmp :o bignum)
 292        (inst shl y 1)
 293        (inst jmp :o bignum)
 294        (emit-label done)
 295        ;; KLUDGE: The sequence above leaves a DESCRIPTOR-REG Y in a
 296        ;; non-descriptor state for a while. Does that matter? Does it matter in
 297        ;; GENGC but not in GENCGC? Is this written down anywhere?
 298        ;;   -- WHN 19990916
 299        ;;
 300        ;; Also, the sequence above seems rather twisty. Why not something
 301        ;; more obvious along the lines of
 302        ;;   inst move y x
 303        ;;   inst tst x #xc0000000
 304        ;;   inst jmp :nz bignum
 305        ;;   inst shl y 2
 306        ;;   emit-label done
 307
 308        (assemble (*elsewhere*)
 309           (emit-label bignum)
 310           (with-fixed-allocation
 311               (y bignum-type (+ bignum-digits-offset 1) node)
 312             (storew x y bignum-digits-offset other-pointer-type))
 313           (inst jmp done)))))
 314 (define-move-vop move-from-signed :move
 315   (signed-reg) (descriptor-reg))
 316
 317 ;;; Check for fixnum, and possibly allocate one or two word bignum
 318 ;;; result. Use a worst-case cost to make sure people know they may be
 319 ;;; number consing.
 320 #+nil
 321 (define-vop (move-from-unsigned)
 322   (:args (x :scs (signed-reg unsigned-reg) :target eax))
 323   (:temporary (:sc unsigned-reg :offset eax-offset :from (:argument 0)) eax)
 324   (:temporary (:sc unsigned-reg :offset ebx-offset :to (:result 0) :target y)
 325               ebx)
 326   (:temporary (:sc unsigned-reg :offset ecx-offset
 327                    :from (:argument 0) :to (:result 0)) ecx)
 328   (:ignore ecx)
 329   (:results (y :scs (any-reg descriptor-reg)))
 330   (:note "unsigned word to integer coercion")
 331   (:generator 20
 332     (move eax x)
 333     (inst call (make-fixup 'move-from-unsigned :assembly-routine))
 334     (move y ebx)))
 335 ;;; Faster inline version.
 336 ;;; KLUDGE: Do we really want the faster inline version? It seems awfully big..
 337 ;;; If we really want speed, most likely it's only important in the non-consing
 338 ;;; case, so how about about making the *ELSEWHERE* stuff into a subroutine? --
 339 ;;; WHN 19990916
 340 (define-vop (move-from-unsigned)
 341   (:args (x :scs (signed-reg unsigned-reg) :to :save))
 342   (:temporary (:sc unsigned-reg) alloc)
 343   (:results (y :scs (any-reg descriptor-reg)))
 344   (:node-var node)
 345   (:note "unsigned word to integer coercion")
 346   (:generator 20
 347     (assert (not (location= x y)))
 348     (assert (not (location= x alloc)))
 349     (assert (not (location= y alloc)))
 350     (let ((bignum (gen-label))
 351           (done (gen-label))
 352           (one-word-bignum (gen-label))
 353           (L1 (gen-label)))
 354       (inst test x #xe0000000)
 355       (inst jmp :nz bignum)
 356       ;; Fixnum.
 357       (inst lea y (make-ea :dword :index x :scale 4)) ; Faster but bigger.
 358       ;(inst mov y x)
 359       ;(inst shl y 2)
 360       (emit-label done)
 361
 362       (assemble (*elsewhere*)
 363          (emit-label bignum)
 364          ;; Note: As on the mips port, space for a two word bignum is
 365          ;; always allocated and the header size is set to either one
 366          ;; or two words as appropriate.
 367          (inst jmp :ns one-word-bignum)
 368          ;; Two word bignum.
 369          (inst mov y (logior (ash (1- (+ bignum-digits-offset 2))
 370                                   sb!vm:type-bits)
 371                              bignum-type))
 372          (inst jmp L1)
 373          (emit-label one-word-bignum)
 374          (inst mov y (logior (ash (1- (+ bignum-digits-offset 1))
 375                                   sb!vm:type-bits)
 376                              bignum-type))
 377          (emit-label L1)
 378          (pseudo-atomic
 379           (allocation alloc (pad-data-block (+ bignum-digits-offset 2)) node)
 380           (storew y alloc)
 381           (inst lea y (make-ea :byte :base alloc :disp other-pointer-type))
 382           (storew x y bignum-digits-offset other-pointer-type))
 383          (inst jmp done)))))
 384 (define-move-vop move-from-unsigned :move
 385   (unsigned-reg) (descriptor-reg))
 386
 387 ;;; Move untagged numbers.
 388 (define-vop (word-move)
 389   (:args (x :scs (signed-reg unsigned-reg) :target y
 390             :load-if (not (location= x y))))
 391   (:results (y :scs (signed-reg unsigned-reg)
 392                :load-if
 393                (not (or (location= x y)
 394                         (and (sc-is x signed-reg unsigned-reg)
 395                              (sc-is y signed-stack unsigned-stack))))))
 396   (:effects)
 397   (:affected)
 398   (:note "word integer move")
 399   (:generator 0
 400     (move y x)))
 401 (define-move-vop word-move :move
 402   (signed-reg unsigned-reg) (signed-reg unsigned-reg))
 403
 404 ;;; Move untagged number arguments/return-values.
 405 (define-vop (move-word-argument)
 406   (:args (x :scs (signed-reg unsigned-reg) :target y)
 407          (fp :scs (any-reg) :load-if (not (sc-is y sap-reg))))
 408   (:results (y))
 409   (:note "word integer argument move")
 410   (:generator 0
 411     (sc-case y
 412       ((signed-reg unsigned-reg)
 413        (move y x))
 414       ((signed-stack unsigned-stack)
 415        (if (= (tn-offset fp) esp-offset)
 416            (storew x fp (tn-offset y))  ; c-call
 417            (storew x fp (- (1+ (tn-offset y)))))))))
 418 (define-move-vop move-word-argument :move-argument
 419   (descriptor-reg any-reg signed-reg unsigned-reg) (signed-reg unsigned-reg))
 420
 421 ;;; Use standard MOVE-ARGUMENT and coercion to move an untagged number
 422 ;;; to a descriptor passing location.
 423 (define-move-vop move-argument :move-argument
 424   (signed-reg unsigned-reg) (any-reg descriptor-reg))