src/compiler/x86/static-fn.lisp

   1 ;;;; the VOPs and macro magic required to call static functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!VM")
  13
  14 (define-vop (static-function-template)
  15   (:save-p t)
  16   (:policy :safe)
  17   (:variant-vars function)
  18   (:vop-var vop)
  19   (:node-var node)
  20   (:temporary (:sc unsigned-reg :offset ebx-offset
  21                    :from (:eval 0) :to (:eval 2)) ebx)
  22   (:temporary (:sc unsigned-reg :offset ecx-offset
  23                    :from (:eval 0) :to (:eval 2)) ecx))
  24
  25 (eval-when (:compile-toplevel :load-toplevel :execute)
  26
  27 (defun static-function-template-name (num-args num-results)
  28   (intern (format nil "~:@(~R-arg-~R-result-static-function~)"
  29                   num-args num-results)))
  30
  31 (defun moves (dst src)
  32   (collect ((moves))
  33     (do ((dst dst (cdr dst))
  34          (src src (cdr src)))
  35         ((or (null dst) (null src)))
  36       (moves `(move ,(car dst) ,(car src))))
  37     (moves)))
  38
  39 (defun static-function-template-vop (num-args num-results)
  40   (unless (and (<= num-args register-arg-count)
  41                (<= num-results register-arg-count))
  42     (error "either too many args (~D) or too many results (~D); max = ~D"
  43            num-args num-results register-arg-count))
  44   (let ((num-temps (max num-args num-results)))
  45     (collect ((temp-names) (temps) (arg-names) (args) (result-names) (results))
  46       (dotimes (i num-results)
  47         (let ((result-name (intern (format nil "RESULT-~D" i))))
  48           (result-names result-name)
  49           (results `(,result-name :scs (any-reg descriptor-reg)))))
  50       (dotimes (i num-temps)
  51         (let ((temp-name (intern (format nil "TEMP-~D" i))))
  52           (temp-names temp-name)
  53           (temps `(:temporary (:sc descriptor-reg
  54                                :offset ,(nth i *register-arg-offsets*)
  55                                :from ,(if (< i num-args)
  56                                           `(:argument ,i)
  57                                           '(:eval 1))
  58                                :to ,(if (< i num-results)
  59                                         `(:result ,i)
  60                                         '(:eval 1))
  61                                ,@(when (< i num-results)
  62                                    `(:target ,(nth i (result-names)))))
  63                               ,temp-name))))
  64       (dotimes (i num-args)
  65         (let ((arg-name (intern (format nil "ARG-~D" i))))
  66           (arg-names arg-name)
  67           (args `(,arg-name
  68                   :scs (any-reg descriptor-reg)
  69                   :target ,(nth i (temp-names))))))
  70       `(define-vop (,(static-function-template-name num-args num-results)
  71                     static-function-template)
  72         (:args ,@(args))
  73         ,@(temps)
  74         (:results ,@(results))
  75         (:generator ,(+ 50 num-args num-results)
  76          ,@(moves (temp-names) (arg-names))
  77
  78          ;; If speed not more important than size, duplicate the
  79          ;; effect of the ENTER with discrete instructions. Takes
  80          ;; 2+1+3+2=8 bytes as opposed to 4+3=7 bytes.
  81          (cond ((policy node (>= speed space))
  82                 (inst mov ebx esp-tn)
  83                 ;; Save the old-fp
  84                 (inst push ebp-tn)
  85                 ;; Ensure that at least three slots are available; one
  86                 ;; above, two more needed.
  87                 (inst sub esp-tn (fixnumize 2))
  88                 (inst mov ebp-tn ebx))
  89                (t
  90                 (inst enter (fixnumize 2))
  91                 ;; The enter instruction pushes EBP and then copies
  92                 ;; ESP into EBP. We want the new EBP to be the
  93                 ;; original ESP, so we fix it up afterwards.
  94                 (inst add ebp-tn (fixnumize 1))))
  95
  96          ,(if (zerop num-args)
  97               '(inst xor ecx ecx)
  98               `(inst mov ecx (fixnumize ,num-args)))
  99
 100          (note-this-location vop :call-site)
 101          ;; Static-function-offset gives the offset from the start of
 102          ;; the nil object to the static function fdefn and has the
 103          ;; low tag of 1 added. When the nil symbol value with its
 104          ;; low tag of 3 is added the resulting value points to the
 105          ;; raw address slot of the fdefn (at +4).
 106          (inst call (make-ea :dword
 107                              :disp (+ nil-value
 108                                       (static-function-offset function))))
 109          ,(collect ((bindings) (links))
 110                    (do ((temp (temp-names) (cdr temp))
 111                         (name 'values (gensym))
 112                         (prev nil name)
 113                         (i 0 (1+ i)))
 114                        ((= i num-results))
 115                      (bindings `(,name
 116                                  (make-tn-ref ,(car temp) nil)))
 117                      (when prev
 118                        (links `(setf (tn-ref-across ,prev) ,name))))
 119                    `(let ,(bindings)
 120                      ,@(links)
 121                      (default-unknown-values
 122                          vop
 123                          ,(if (zerop num-results) nil 'values)
 124                        ,num-results)))
 125          ,@(moves (result-names) (temp-names)))))))
 126
 127 ) ; EVAL-WHEN
 128
 129 (macrolet ((frob (num-args num-res)
 130              (static-function-template-vop (eval num-args) (eval num-res))))
 131   (frob 0 1)
 132   (frob 1 1)
 133   (frob 2 1)
 134   (frob 3 1))
 135
 136 (defmacro define-static-function (name args &key (results '(x)) translate
 137                                        policy cost arg-types result-types)
 138   `(define-vop (,name
 139                 ,(static-function-template-name (length args)
 140                                                 (length results)))
 141      (:variant ',name)
 142      (:note ,(format nil "static-function ~@(~S~)" name))
 143      ,@(when translate
 144          `((:translate ,translate)))
 145      ,@(when policy
 146          `((:policy ,policy)))
 147      ,@(when cost
 148          `((:generator-cost ,cost)))
 149      ,@(when arg-types
 150          `((:arg-types ,@arg-types)))
 151      ,@(when result-types
 152          `((:result-types ,@result-types)))))