src/compiler/x86-64/c-call.lisp

   1 ;;;; the VOPs and other necessary machine specific support
   2 ;;;; routines for call-out to C
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!VM")
  14
  15 ;; The MOVE-ARG vop is going to store args on the stack for
  16 ;; call-out. These tn's will be used for that. move-arg is normally
  17 ;; used for things going down the stack but C wants to have args
  18 ;; indexed in the positive direction.
  19
  20 (defun my-make-wired-tn (prim-type-name sc-name offset)
  21   (make-wired-tn (primitive-type-or-lose prim-type-name)
  22                  (sc-number-or-lose sc-name)
  23                  offset))
  24
  25 (defstruct (arg-state (:copier nil))
  26   (register-args 0)
  27   (xmm-args 0)
  28   (stack-frame-size 0))
  29
  30 (defun int-arg (state prim-type reg-sc stack-sc)
  31   (let ((reg-args (arg-state-register-args state)))
  32     (cond ((< reg-args 6)
  33            (setf (arg-state-register-args state) (1+ reg-args))
  34            (my-make-wired-tn prim-type reg-sc
  35                              (nth reg-args *c-call-register-arg-offsets*)))
  36           (t
  37            (let ((frame-size (arg-state-stack-frame-size state)))
  38              (setf (arg-state-stack-frame-size state) (1+ frame-size))
  39              (my-make-wired-tn prim-type stack-sc frame-size))))))
  40
  41 (define-alien-type-method (integer :arg-tn) (type state)
  42   (if (alien-integer-type-signed type)
  43       (int-arg state 'signed-byte-64 'signed-reg 'signed-stack)
  44       (int-arg state 'unsigned-byte-64 'unsigned-reg 'unsigned-stack)))
  45
  46 (define-alien-type-method (system-area-pointer :arg-tn) (type state)
  47   (declare (ignore type))
  48   (int-arg state 'system-area-pointer 'sap-reg 'sap-stack))
  49
  50 (defun float-arg (state prim-type reg-sc stack-sc)
  51   (let ((xmm-args (arg-state-xmm-args state)))
  52     (cond ((< xmm-args 8)
  53            (setf (arg-state-xmm-args state) (1+ xmm-args))
  54            (my-make-wired-tn prim-type reg-sc
  55                              (nth xmm-args *float-regs*)))
  56           (t
  57            (let ((frame-size (arg-state-stack-frame-size state)))
  58              (setf (arg-state-stack-frame-size state) (1+ frame-size))
  59              (my-make-wired-tn prim-type stack-sc frame-size))))))
  60
  61 (define-alien-type-method (double-float :arg-tn) (type state)
  62   (declare (ignore type))
  63   (float-arg state 'double-float 'double-reg 'double-stack))
  64
  65 (define-alien-type-method (single-float :arg-tn) (type state)
  66   (declare (ignore type))
  67   (float-arg state 'single-float 'single-reg 'single-stack))
  68
  69 (defstruct (result-state (:copier nil))
  70   (num-results 0))
  71
  72 (defun result-reg-offset (slot)
  73   (ecase slot
  74     (0 eax-offset)
  75     (1 edx-offset)))
  76
  77 ;; XXX The return handling probably doesn't conform to the ABI
  78
  79 (define-alien-type-method (integer :result-tn) (type state)
  80   (let ((num-results (result-state-num-results state)))
  81     (setf (result-state-num-results state) (1+ num-results))
  82     (multiple-value-bind (ptype reg-sc)
  83         (if (alien-integer-type-signed type)
  84             (values 'signed-byte-64 'signed-reg)
  85             (values 'unsigned-byte-64 'unsigned-reg))
  86       (my-make-wired-tn ptype reg-sc (result-reg-offset num-results)))))
  87
  88 (define-alien-type-method (integer :naturalize-gen) (type alien)
  89   (if (and (alien-integer-type-signed type)
  90            (<= (alien-type-bits type) 32))
  91       `(sign-extend ,alien)
  92       alien))
  93
  94 (define-alien-type-method (system-area-pointer :result-tn) (type state)
  95   (declare (ignore type))
  96   (let ((num-results (result-state-num-results state)))
  97     (setf (result-state-num-results state) (1+ num-results))
  98     (my-make-wired-tn 'system-area-pointer 'sap-reg
  99                       (result-reg-offset num-results))))
 100
 101 (define-alien-type-method (double-float :result-tn) (type state)
 102   (declare (ignore type))
 103   (let ((num-results (result-state-num-results state)))
 104     (setf (result-state-num-results state) (1+ num-results))
 105     (my-make-wired-tn 'double-float 'double-reg num-results)))
 106
 107 (define-alien-type-method (single-float :result-tn) (type state)
 108   (declare (ignore type))
 109   (let ((num-results (result-state-num-results state)))
 110     (setf (result-state-num-results state) (1+ num-results))
 111     (my-make-wired-tn 'single-float 'single-reg num-results)))
 112
 113 (define-alien-type-method (values :result-tn) (type state)
 114   (let ((values (alien-values-type-values type)))
 115     (when (> (length values) 2)
 116       (error "Too many result values from c-call."))
 117     (mapcar (lambda (type)
 118               (invoke-alien-type-method :result-tn type state))
 119             values)))
 120
 121 (!def-vm-support-routine make-call-out-tns (type)
 122   (let ((arg-state (make-arg-state)))
 123     (collect ((arg-tns))
 124       (dolist (arg-type (alien-fun-type-arg-types type))
 125         (arg-tns (invoke-alien-type-method :arg-tn arg-type arg-state)))
 126       (values (my-make-wired-tn 'positive-fixnum 'any-reg esp-offset)
 127               (* (arg-state-stack-frame-size arg-state) n-word-bytes)
 128               (arg-tns)
 129               (invoke-alien-type-method :result-tn
 130                                         (alien-fun-type-result-type type)
 131                                         (make-result-state))))))
 132
 133
 134 (deftransform %alien-funcall ((function type &rest args) * * :node node)
 135   (aver (sb!c::constant-lvar-p type))
 136   (let* ((type (sb!c::lvar-value type))
 137          (env (sb!c::node-lexenv node))
 138          (arg-types (alien-fun-type-arg-types type))
 139          (result-type (alien-fun-type-result-type type)))
 140     (aver (= (length arg-types) (length args)))
 141     (if (or (some #'(lambda (type)
 142                       (and (alien-integer-type-p type)
 143                            (> (sb!alien::alien-integer-type-bits type) 64)))
 144                   arg-types)
 145             (and (alien-integer-type-p result-type)
 146                  (> (sb!alien::alien-integer-type-bits result-type) 64)))
 147         (collect ((new-args) (lambda-vars) (new-arg-types))
 148           (dolist (type arg-types)
 149             (let ((arg (gensym)))
 150               (lambda-vars arg)
 151               (cond ((and (alien-integer-type-p type)
 152                           (> (sb!alien::alien-integer-type-bits type) 64))
 153                      ;; CLH: FIXME! This should really be
 154                      ;; #xffffffffffffffff. nyef says: "Passing
 155                      ;; 128-bit integers to ALIEN functions on x86-64
 156                      ;; believed to be broken."
 157                      (new-args `(logand ,arg #xffffffff))
 158                      (new-args `(ash ,arg -64))
 159                      (new-arg-types (parse-alien-type '(unsigned 64) env))
 160                      (if (alien-integer-type-signed type)
 161                          (new-arg-types (parse-alien-type '(signed 64) env))
 162                          (new-arg-types (parse-alien-type '(unsigned 64) env))))
 163                     (t
 164                      (new-args arg)
 165                      (new-arg-types type)))))
 166           (cond ((and (alien-integer-type-p result-type)
 167                       (> (sb!alien::alien-integer-type-bits result-type) 64))
 168                  (let ((new-result-type
 169                         (let ((sb!alien::*values-type-okay* t))
 170                           (parse-alien-type
 171                            (if (alien-integer-type-signed result-type)
 172                                '(values (unsigned 64) (signed 64))
 173                                '(values (unsigned 64) (unsigned 64)))
 174                            env))))
 175                    `(lambda (function type ,@(lambda-vars))
 176                       (declare (ignore type))
 177                       (multiple-value-bind (low high)
 178                           (%alien-funcall function
 179                                           ',(make-alien-fun-type
 180                                              :arg-types (new-arg-types)
 181                                              :result-type new-result-type)
 182                                           ,@(new-args))
 183                         (logior low (ash high 64))))))
 184                 (t
 185                  `(lambda (function type ,@(lambda-vars))
 186                     (declare (ignore type))
 187                     (%alien-funcall function
 188                                     ',(make-alien-fun-type
 189                                        :arg-types (new-arg-types)
 190                                        :result-type result-type)
 191                                     ,@(new-args))))))
 192         (sb!c::give-up-ir1-transform))))
 193
 194 ;;; The ABI specifies that signed short/int's are returned as 32-bit
 195 ;;; values. Negative values need to be sign-extended to 64-bits (done
 196 ;;; in a :NATURALIZE-GEN alien-type-method).
 197 (defknown sign-extend ((signed-byte 32)) fixnum
 198           (foldable flushable movable))
 199
 200 (define-vop (sign-extend)
 201   (:translate sign-extend)
 202   (:policy :fast-safe)
 203   (:args (val :scs (signed-reg)))
 204   (:arg-types fixnum)
 205   (:results (res :scs (signed-reg)))
 206   (:result-types fixnum)
 207   (:generator 1
 208    (inst movsxd res
 209          (make-random-tn :kind :normal
 210                          :sc (sc-or-lose 'dword-reg)
 211                          :offset (tn-offset val)))))
 212
 213 (defun sign-extend (x)
 214   (declare (type (signed-byte 32) x))
 215   (sign-extend x))
 216
 217 (define-vop (foreign-symbol-sap)
 218   (:translate foreign-symbol-sap)
 219   (:policy :fast-safe)
 220   (:args)
 221   (:arg-types (:constant simple-string))
 222   (:info foreign-symbol)
 223   (:results (res :scs (sap-reg)))
 224   (:result-types system-area-pointer)
 225   (:generator 2
 226    (inst lea res (make-fixup foreign-symbol :foreign))))
 227
 228 #!+linkage-table
 229 (define-vop (foreign-symbol-dataref-sap)
 230   (:translate foreign-symbol-dataref-sap)
 231   (:policy :fast-safe)
 232   (:args)
 233   (:arg-types (:constant simple-string))
 234   (:info foreign-symbol)
 235   (:results (res :scs (sap-reg)))
 236   (:result-types system-area-pointer)
 237   (:generator 2
 238    (inst mov res (make-fixup foreign-symbol :foreign-dataref))))
 239
 240 (define-vop (call-out)
 241   (:args (function :scs (sap-reg))
 242          (args :more t))
 243   (:results (results :more t))
 244   (:temporary (:sc unsigned-reg :offset rax-offset :to :result) rax)
 245   (:ignore results)
 246   (:vop-var vop)
 247   (:save-p t)
 248   (:generator 0
 249     ;; ABI: Direction flag must be clear on function entry. -- JES, 2006-01-20
 250     (inst cld)
 251     ;; ABI: AL contains amount of arguments passed in XMM registers
 252     ;; for vararg calls.
 253     (move-immediate rax
 254                     (loop for tn-ref = args then (tn-ref-across tn-ref)
 255                        while tn-ref
 256                        count (eq (sb-name (sc-sb (tn-sc (tn-ref-tn tn-ref))))
 257                                  'float-registers)))
 258     (inst call function)
 259     ;; To give the debugger a clue. XX not really internal-error?
 260     (note-this-location vop :internal-error)))
 261
 262 (define-vop (alloc-number-stack-space)
 263   (:info amount)
 264   (:results (result :scs (sap-reg any-reg)))
 265   (:generator 0
 266     (aver (location= result rsp-tn))
 267     (unless (zerop amount)
 268       (let ((delta (logandc2 (+ amount 7) 7)))
 269         (inst sub rsp-tn delta)))
 270     ;; C stack must be 16 byte aligned
 271     (inst and rsp-tn -16)
 272     (move result rsp-tn)))
 273
 274 (define-vop (dealloc-number-stack-space)
 275   (:info amount)
 276   (:generator 0
 277     (unless (zerop amount)
 278       (let ((delta (logandc2 (+ amount 7) 7)))
 279         (inst add rsp-tn delta)))))
 280
 281 (define-vop (alloc-alien-stack-space)
 282   (:info amount)
 283   #!+sb-thread (:temporary (:sc unsigned-reg) temp)
 284   (:results (result :scs (sap-reg any-reg)))
 285   #!+sb-thread
 286   (:generator 0
 287     (aver (not (location= result rsp-tn)))
 288     (unless (zerop amount)
 289       (let ((delta (logandc2 (+ amount 7) 7)))
 290         (inst mov temp
 291               (make-ea :qword
 292                        :disp (+ nil-value
 293                                 (static-symbol-offset '*alien-stack*)
 294                                 (ash symbol-tls-index-slot word-shift)
 295                                 (- other-pointer-lowtag))))
 296         (inst sub (make-ea :qword :base thread-base-tn
 297                            :scale 1 :index temp) delta)))
 298     (load-tl-symbol-value result *alien-stack*))
 299   #!-sb-thread
 300   (:generator 0
 301     (aver (not (location= result rsp-tn)))
 302     (unless (zerop amount)
 303       (let ((delta (logandc2 (+ amount 7) 7)))
 304         (inst sub (make-ea :qword
 305                            :disp (+ nil-value
 306                                     (static-symbol-offset '*alien-stack*)
 307                                     (ash symbol-value-slot word-shift)
 308                                     (- other-pointer-lowtag)))
 309               delta)))
 310     (load-symbol-value result *alien-stack*)))
 311
 312 (define-vop (dealloc-alien-stack-space)
 313   (:info amount)
 314   #!+sb-thread (:temporary (:sc unsigned-reg) temp)
 315   #!+sb-thread
 316   (:generator 0
 317     (unless (zerop amount)
 318       (let ((delta (logandc2 (+ amount 7) 7)))
 319         (inst mov temp
 320               (make-ea :qword
 321                        :disp (+ nil-value
 322                                 (static-symbol-offset '*alien-stack*)
 323                                 (ash symbol-tls-index-slot word-shift)
 324                                 (- other-pointer-lowtag))))
 325         (inst add (make-ea :qword :base thread-base-tn :scale 1 :index temp)
 326               delta))))
 327   #!-sb-thread
 328   (:generator 0
 329     (unless (zerop amount)
 330       (let ((delta (logandc2 (+ amount 7) 7)))
 331         (inst add (make-ea :qword
 332                            :disp (+ nil-value
 333                                     (static-symbol-offset '*alien-stack*)
 334                                     (ash symbol-value-slot word-shift)
 335                                     (- other-pointer-lowtag)))
 336               delta)))))
 337
 338 ;;; these are not strictly part of the c-call convention, but are
 339 ;;; needed for the WITH-PRESERVED-POINTERS macro used for "locking
 340 ;;; down" lisp objects so that GC won't move them while foreign
 341 ;;; functions go to work.
 342
 343 (define-vop (push-word-on-c-stack)
 344     (:translate push-word-on-c-stack)
 345   (:args (val :scs (sap-reg)))
 346   (:policy :fast-safe)
 347   (:arg-types system-area-pointer)
 348   (:generator 2
 349     (inst push val)))
 350
 351 (define-vop (pop-words-from-c-stack)
 352     (:translate pop-words-from-c-stack)
 353   (:args)
 354   (:arg-types (:constant (unsigned-byte 60)))
 355   (:info number)
 356   (:policy :fast-safe)
 357   (:generator 2
 358     (inst add rsp-tn (fixnumize number))))
 359
 360 ;;; Callbacks
 361
 362 #-sb-xc-host
 363 (defun alien-callback-accessor-form (type sp offset)
 364   `(deref (sap-alien (sap+ ,sp ,offset) (* ,type))))
 365
 366 #-sb-xc-host
 367 (defun alien-callback-assembler-wrapper (index result-type argument-types)
 368   (labels ((make-tn-maker (sc-name)
 369              (lambda (offset)
 370                (make-random-tn :kind :normal
 371                                :sc (sc-or-lose sc-name)
 372                                :offset offset)))
 373            (out-of-registers-error ()
 374              (error "Too many arguments in callback")))
 375     (let* ((segment (make-segment))
 376            (rax rax-tn)
 377            (rcx rcx-tn)
 378            (rdi rdi-tn)
 379            (rsi rsi-tn)
 380            (rdx rdx-tn)
 381            (rbp rbp-tn)
 382            (rsp rsp-tn)
 383            (xmm0 float0-tn)
 384            ([rsp] (make-ea :qword :base rsp :disp 0))
 385            ;; How many arguments have been copied
 386            (arg-count 0)
 387            ;; How many arguments have been copied from the stack
 388            (stack-argument-count 0)
 389            (gprs (mapcar (make-tn-maker 'any-reg) *c-call-register-arg-offsets*))
 390            (fprs (mapcar (make-tn-maker 'double-reg)
 391                          ;; Only 8 first XMM registers are used for
 392                          ;; passing arguments
 393                          (subseq *float-regs* 0 8))))
 394       (assemble (segment)
 395         ;; Make room on the stack for arguments.
 396         (inst sub rsp (* n-word-bytes (length argument-types)))
 397         ;; Copy arguments from registers to stack
 398         (dolist (type argument-types)
 399           (let ((integerp (not (alien-float-type-p type)))
 400                 ;; A TN pointing to the stack location where the
 401                 ;; current argument should be stored for the purposes
 402                 ;; of ENTER-ALIEN-CALLBACK.
 403                 (target-tn (make-ea :qword :base rsp
 404                                    :disp (* arg-count
 405                                             n-word-bytes)))
 406                 ;; A TN pointing to the stack location that contains
 407                 ;; the next argument passed on the stack.
 408                 (stack-arg-tn (make-ea :qword :base rsp
 409                                        :disp (* (+ 1
 410                                                    (length argument-types)
 411                                                    stack-argument-count)
 412                                                 n-word-bytes))))
 413             (incf arg-count)
 414             (cond (integerp
 415                    (let ((gpr (pop gprs)))
 416                      ;; Argument not in register, copy it from the old
 417                      ;; stack location to a temporary register.
 418                      (unless gpr
 419                        (incf stack-argument-count)
 420                        (setf gpr temp-reg-tn)
 421                        (inst mov gpr stack-arg-tn))
 422                      ;; Copy from either argument register or temporary
 423                      ;; register to target.
 424                      (inst mov target-tn gpr)))
 425                   ((or (alien-single-float-type-p type)
 426                        (alien-double-float-type-p type))
 427                    (let ((fpr (pop fprs)))
 428                      (cond (fpr
 429                             ;; Copy from float register to target location.
 430                             (inst movq target-tn fpr))
 431                            (t
 432                             ;; Not in float register. Copy from stack to
 433                             ;; temporary (general purpose) register, and
 434                             ;; from there to the target location.
 435                             (incf stack-argument-count)
 436                             (inst mov temp-reg-tn stack-arg-tn)
 437                             (inst mov target-tn temp-reg-tn)))))
 438                   (t
 439                    (bug "Unknown alien floating point type: ~S" type)))))
 440
 441         ;; arg0 to FUNCALL3 (function)
 442         ;;
 443         ;; Indirect the access to ENTER-ALIEN-CALLBACK through
 444         ;; the symbol-value slot of SB-ALIEN::*ENTER-ALIEN-CALLBACK*
 445         ;; to ensure it'll work even if the GC moves ENTER-ALIEN-CALLBACK.
 446         ;; Skip any SB-THREAD TLS magic, since we don't expect anyone
 447         ;; to rebind the variable. -- JES, 2006-01-01
 448         (inst mov rdi (+ nil-value (static-symbol-offset
 449                                     'sb!alien::*enter-alien-callback*)))
 450         (loadw rdi rdi symbol-value-slot other-pointer-lowtag)
 451         ;; arg0 to ENTER-ALIEN-CALLBACK (trampoline index)
 452         (inst mov rsi (fixnumize index))
 453         ;; arg1 to ENTER-ALIEN-CALLBACK (pointer to argument vector)
 454         (inst mov rdx rsp)
 455         ;; add room on stack for return value
 456         (inst sub rsp 8)
 457         ;; arg2 to ENTER-ALIEN-CALLBACK (pointer to return value)
 458         (inst mov rcx rsp)
 459
 460         ;; Make new frame
 461         (inst push rbp)
 462         (inst mov  rbp rsp)
 463
 464         ;; Call
 465         (inst mov  rax (foreign-symbol-address "funcall3"))
 466         (inst call rax)
 467
 468         ;; Back! Restore frame
 469         (inst mov rsp rbp)
 470         (inst pop rbp)
 471
 472         ;; Result now on top of stack, put it in the right register
 473         (cond
 474           ((or (alien-integer-type-p result-type)
 475                (alien-pointer-type-p result-type)
 476                (alien-type-= #.(parse-alien-type 'system-area-pointer nil)
 477                              result-type))
 478            (inst mov rax [rsp]))
 479           ((or (alien-single-float-type-p result-type)
 480                (alien-double-float-type-p result-type))
 481            (inst movq xmm0 [rsp]))
 482           ((alien-void-type-p result-type))
 483           (t
 484            (error "unrecognized alien type: ~A" result-type)))
 485
 486         ;; Pop the arguments and the return value from the stack to get
 487         ;; the return address at top of stack.
 488         (inst add rsp (* (1+ (length argument-types)) n-word-bytes))
 489         ;; Return
 490         (inst ret))
 491       (finalize-segment segment)
 492       ;; Now that the segment is done, convert it to a static
 493       ;; vector we can point foreign code to.
 494       (let ((buffer (sb!assem::segment-buffer segment)))
 495         (make-static-vector (length buffer)
 496                             :element-type '(unsigned-byte 8)
 497                             :initial-contents buffer)))))