src/compiler/x86-64/c-call.lisp

   1 ;;;; the VOPs and other necessary machine specific support
   2 ;;;; routines for call-out to C
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!VM")
  14
  15 ;; The MOVE-ARG vop is going to store args on the stack for
  16 ;; call-out. These tn's will be used for that. move-arg is normally
  17 ;; used for things going down the stack but C wants to have args
  18 ;; indexed in the positive direction.
  19
  20 (defun my-make-wired-tn (prim-type-name sc-name offset)
  21   (make-wired-tn (primitive-type-or-lose prim-type-name)
  22                  (sc-number-or-lose sc-name)
  23                  offset))
  24
  25 (defstruct (arg-state (:copier nil))
  26   (register-args 0)
  27   (xmm-args 0)
  28   (stack-frame-size 0))
  29
  30 (defun int-arg (state prim-type reg-sc stack-sc)
  31   (let ((reg-args (arg-state-register-args state)))
  32     (cond ((< reg-args 6)
  33            (setf (arg-state-register-args state) (1+ reg-args))
  34            (my-make-wired-tn prim-type reg-sc
  35                              (nth reg-args *c-call-register-arg-offsets*)))
  36           (t
  37            (let ((frame-size (arg-state-stack-frame-size state)))
  38              (setf (arg-state-stack-frame-size state) (1+ frame-size))
  39              (my-make-wired-tn prim-type stack-sc frame-size))))))
  40
  41 (define-alien-type-method (integer :arg-tn) (type state)
  42   (if (alien-integer-type-signed type)
  43       (int-arg state 'signed-byte-64 'signed-reg 'signed-stack)
  44       (int-arg state 'unsigned-byte-64 'unsigned-reg 'unsigned-stack)))
  45
  46 (define-alien-type-method (system-area-pointer :arg-tn) (type state)
  47   (declare (ignore type))
  48   (int-arg state 'system-area-pointer 'sap-reg 'sap-stack))
  49
  50 (defun float-arg (state prim-type reg-sc stack-sc)
  51   (let ((xmm-args (arg-state-xmm-args state)))
  52     (cond ((< xmm-args 8)
  53            (setf (arg-state-xmm-args state) (1+ xmm-args))
  54            (my-make-wired-tn prim-type reg-sc
  55                              (nth xmm-args *float-regs*)))
  56           (t
  57            (let ((frame-size (arg-state-stack-frame-size state)))
  58              (setf (arg-state-stack-frame-size state) (1+ frame-size))
  59              (my-make-wired-tn prim-type stack-sc frame-size))))))
  60
  61 (define-alien-type-method (double-float :arg-tn) (type state)
  62   (declare (ignore type))
  63   (float-arg state 'double-float 'double-reg 'double-stack))
  64
  65 (define-alien-type-method (single-float :arg-tn) (type state)
  66   (declare (ignore type))
  67   (float-arg state 'single-float 'single-reg 'single-stack))
  68
  69 (defstruct (result-state (:copier nil))
  70   (num-results 0))
  71
  72 (defun result-reg-offset (slot)
  73   (ecase slot
  74     (0 eax-offset)
  75     (1 edx-offset)))
  76
  77 (define-alien-type-method (integer :result-tn) (type state)
  78   (let ((num-results (result-state-num-results state)))
  79     (setf (result-state-num-results state) (1+ num-results))
  80     (multiple-value-bind (ptype reg-sc)
  81         (if (alien-integer-type-signed type)
  82             (values 'signed-byte-64 'signed-reg)
  83             (values 'unsigned-byte-64 'unsigned-reg))
  84       (my-make-wired-tn ptype reg-sc (result-reg-offset num-results)))))
  85
  86 (define-alien-type-method (integer :naturalize-gen) (type alien)
  87   (if (<= (alien-type-bits type) 32)
  88       (if (alien-integer-type-signed type)
  89           `(sign-extend ,alien ,(alien-type-bits type))
  90           `(logand ,alien ,(1- (ash 1 (alien-type-bits type)))))
  91       alien))
  92
  93 (define-alien-type-method (system-area-pointer :result-tn) (type state)
  94   (declare (ignore type))
  95   (let ((num-results (result-state-num-results state)))
  96     (setf (result-state-num-results state) (1+ num-results))
  97     (my-make-wired-tn 'system-area-pointer 'sap-reg
  98                       (result-reg-offset num-results))))
  99
 100 (define-alien-type-method (double-float :result-tn) (type state)
 101   (declare (ignore type))
 102   (let ((num-results (result-state-num-results state)))
 103     (setf (result-state-num-results state) (1+ num-results))
 104     (my-make-wired-tn 'double-float 'double-reg num-results)))
 105
 106 (define-alien-type-method (single-float :result-tn) (type state)
 107   (declare (ignore type))
 108   (let ((num-results (result-state-num-results state)))
 109     (setf (result-state-num-results state) (1+ num-results))
 110     (my-make-wired-tn 'single-float 'single-reg num-results)))
 111
 112 (define-alien-type-method (values :result-tn) (type state)
 113   (let ((values (alien-values-type-values type)))
 114     (when (> (length values) 2)
 115       (error "Too many result values from c-call."))
 116     (mapcar (lambda (type)
 117               (invoke-alien-type-method :result-tn type state))
 118             values)))
 119
 120 (!def-vm-support-routine make-call-out-tns (type)
 121   (let ((arg-state (make-arg-state)))
 122     (collect ((arg-tns))
 123       (dolist (arg-type (alien-fun-type-arg-types type))
 124         (arg-tns (invoke-alien-type-method :arg-tn arg-type arg-state)))
 125       (values (my-make-wired-tn 'positive-fixnum 'any-reg esp-offset)
 126               (* (arg-state-stack-frame-size arg-state) n-word-bytes)
 127               (arg-tns)
 128               (invoke-alien-type-method :result-tn
 129                                         (alien-fun-type-result-type type)
 130                                         (make-result-state))))))
 131
 132
 133 (deftransform %alien-funcall ((function type &rest args) * * :node node)
 134   (aver (sb!c::constant-lvar-p type))
 135   (let* ((type (sb!c::lvar-value type))
 136          (env (sb!c::node-lexenv node))
 137          (arg-types (alien-fun-type-arg-types type))
 138          (result-type (alien-fun-type-result-type type)))
 139     (aver (= (length arg-types) (length args)))
 140     (if (or (some #'(lambda (type)
 141                       (and (alien-integer-type-p type)
 142                            (> (sb!alien::alien-integer-type-bits type) 64)))
 143                   arg-types)
 144             (and (alien-integer-type-p result-type)
 145                  (> (sb!alien::alien-integer-type-bits result-type) 64)))
 146         (collect ((new-args) (lambda-vars) (new-arg-types))
 147           (dolist (type arg-types)
 148             (let ((arg (gensym)))
 149               (lambda-vars arg)
 150               (cond ((and (alien-integer-type-p type)
 151                           (> (sb!alien::alien-integer-type-bits type) 64))
 152                      ;; CLH: FIXME! This should really be
 153                      ;; #xffffffffffffffff. nyef says: "Passing
 154                      ;; 128-bit integers to ALIEN functions on x86-64
 155                      ;; believed to be broken."
 156                      (new-args `(logand ,arg #xffffffff))
 157                      (new-args `(ash ,arg -64))
 158                      (new-arg-types (parse-alien-type '(unsigned 64) env))
 159                      (if (alien-integer-type-signed type)
 160                          (new-arg-types (parse-alien-type '(signed 64) env))
 161                          (new-arg-types (parse-alien-type '(unsigned 64) env))))
 162                     (t
 163                      (new-args arg)
 164                      (new-arg-types type)))))
 165           (cond ((and (alien-integer-type-p result-type)
 166                       (> (sb!alien::alien-integer-type-bits result-type) 64))
 167                  (let ((new-result-type
 168                         (let ((sb!alien::*values-type-okay* t))
 169                           (parse-alien-type
 170                            (if (alien-integer-type-signed result-type)
 171                                '(values (unsigned 64) (signed 64))
 172                                '(values (unsigned 64) (unsigned 64)))
 173                            env))))
 174                    `(lambda (function type ,@(lambda-vars))
 175                       (declare (ignore type))
 176                       (multiple-value-bind (low high)
 177                           (%alien-funcall function
 178                                           ',(make-alien-fun-type
 179                                              :arg-types (new-arg-types)
 180                                              :result-type new-result-type)
 181                                           ,@(new-args))
 182                         (logior low (ash high 64))))))
 183                 (t
 184                  `(lambda (function type ,@(lambda-vars))
 185                     (declare (ignore type))
 186                     (%alien-funcall function
 187                                     ',(make-alien-fun-type
 188                                        :arg-types (new-arg-types)
 189                                        :result-type result-type)
 190                                     ,@(new-args))))))
 191         (sb!c::give-up-ir1-transform))))
 192
 193 ;;; The ABI is vague about how signed sub-word integer return values
 194 ;;; are handled, but since gcc versions >=4.3 no longer do sign
 195 ;;; extension in the callee, we need to do it in the caller.  FIXME:
 196 ;;; If the value to be extended is known to already be of the target
 197 ;;; type at compile time, we can (and should) elide the extension.
 198 (defknown sign-extend ((signed-byte 64) t) fixnum
 199     (foldable flushable movable))
 200
 201 (define-vop (sign-extend)
 202   (:translate sign-extend)
 203   (:policy :fast-safe)
 204   (:args (val :scs (signed-reg)))
 205   (:arg-types signed-num (:constant fixnum))
 206   (:info size)
 207   (:results (res :scs (signed-reg)))
 208   (:result-types fixnum)
 209   (:generator 1
 210    (inst movsxd res
 211          (make-random-tn :kind :normal
 212                          :sc (sc-or-lose (ecase size
 213                                            (8 'byte-reg)
 214                                            (16 'word-reg)
 215                                            (32 'dword-reg)))
 216                          :offset (tn-offset val)))))
 217
 218 #-sb-xc-host
 219 (defun sign-extend (x size)
 220   (declare (type (signed-byte 64) x))
 221   (ecase size
 222     (8 (sign-extend x size))
 223     (16 (sign-extend x size))
 224     (32 (sign-extend x size))))
 225
 226 #+sb-xc-host
 227 (defun sign-extend (x size)
 228   (if (logbitp (1- size) x)
 229       (dpb x (byte size 0) -1)
 230       x))
 231
 232 (define-vop (foreign-symbol-sap)
 233   (:translate foreign-symbol-sap)
 234   (:policy :fast-safe)
 235   (:args)
 236   (:arg-types (:constant simple-string))
 237   (:info foreign-symbol)
 238   (:results (res :scs (sap-reg)))
 239   (:result-types system-area-pointer)
 240   (:generator 2
 241    (inst lea res (make-fixup foreign-symbol :foreign))))
 242
 243 #!+linkage-table
 244 (define-vop (foreign-symbol-dataref-sap)
 245   (:translate foreign-symbol-dataref-sap)
 246   (:policy :fast-safe)
 247   (:args)
 248   (:arg-types (:constant simple-string))
 249   (:info foreign-symbol)
 250   (:results (res :scs (sap-reg)))
 251   (:result-types system-area-pointer)
 252   (:generator 2
 253    (inst mov res (make-fixup foreign-symbol :foreign-dataref))))
 254
 255 (define-vop (call-out)
 256   (:args (function :scs (sap-reg))
 257          (args :more t))
 258   (:results (results :more t))
 259   (:temporary (:sc unsigned-reg :offset rax-offset :to :result) rax)
 260   (:ignore results)
 261   (:vop-var vop)
 262   (:save-p t)
 263   (:generator 0
 264     ;; ABI: Direction flag must be clear on function entry. -- JES, 2006-01-20
 265     (inst cld)
 266     ;; ABI: AL contains amount of arguments passed in XMM registers
 267     ;; for vararg calls.
 268     (move-immediate rax
 269                     (loop for tn-ref = args then (tn-ref-across tn-ref)
 270                        while tn-ref
 271                        count (eq (sb-name (sc-sb (tn-sc (tn-ref-tn tn-ref))))
 272                                  'float-registers)))
 273     (inst call function)
 274     ;; To give the debugger a clue. XX not really internal-error?
 275     (note-this-location vop :internal-error)))
 276
 277 (define-vop (alloc-number-stack-space)
 278   (:info amount)
 279   (:results (result :scs (sap-reg any-reg)))
 280   (:result-types system-area-pointer)
 281   (:generator 0
 282     (aver (location= result rsp-tn))
 283     (unless (zerop amount)
 284       (let ((delta (logandc2 (+ amount 7) 7)))
 285         (inst sub rsp-tn delta)))
 286     ;; C stack must be 16 byte aligned
 287     (inst and rsp-tn -16)
 288     (move result rsp-tn)))
 289
 290 (define-vop (dealloc-number-stack-space)
 291   (:info amount)
 292   (:generator 0
 293     (unless (zerop amount)
 294       (let ((delta (logandc2 (+ amount 7) 7)))
 295         (inst add rsp-tn delta)))))
 296
 297 (define-vop (alloc-alien-stack-space)
 298   (:info amount)
 299   #!+sb-thread (:temporary (:sc unsigned-reg) temp)
 300   (:results (result :scs (sap-reg any-reg)))
 301   (:result-types system-area-pointer)
 302   #!+sb-thread
 303   (:generator 0
 304     (aver (not (location= result rsp-tn)))
 305     (unless (zerop amount)
 306       (let ((delta (logandc2 (+ amount 7) 7)))
 307         (inst mov temp
 308               (make-ea :qword
 309                        :disp (+ nil-value
 310                                 (static-symbol-offset '*alien-stack*)
 311                                 (ash symbol-tls-index-slot word-shift)
 312                                 (- other-pointer-lowtag))))
 313         (inst sub (make-ea :qword :base thread-base-tn
 314                            :scale 1 :index temp) delta)))
 315     (load-tl-symbol-value result *alien-stack*))
 316   #!-sb-thread
 317   (:generator 0
 318     (aver (not (location= result rsp-tn)))
 319     (unless (zerop amount)
 320       (let ((delta (logandc2 (+ amount 7) 7)))
 321         (inst sub (make-ea :qword
 322                            :disp (+ nil-value
 323                                     (static-symbol-offset '*alien-stack*)
 324                                     (ash symbol-value-slot word-shift)
 325                                     (- other-pointer-lowtag)))
 326               delta)))
 327     (load-symbol-value result *alien-stack*)))
 328
 329 (define-vop (dealloc-alien-stack-space)
 330   (:info amount)
 331   #!+sb-thread (:temporary (:sc unsigned-reg) temp)
 332   #!+sb-thread
 333   (:generator 0
 334     (unless (zerop amount)
 335       (let ((delta (logandc2 (+ amount 7) 7)))
 336         (inst mov temp
 337               (make-ea :qword
 338                        :disp (+ nil-value
 339                                 (static-symbol-offset '*alien-stack*)
 340                                 (ash symbol-tls-index-slot word-shift)
 341                                 (- other-pointer-lowtag))))
 342         (inst add (make-ea :qword :base thread-base-tn :scale 1 :index temp)
 343               delta))))
 344   #!-sb-thread
 345   (:generator 0
 346     (unless (zerop amount)
 347       (let ((delta (logandc2 (+ amount 7) 7)))
 348         (inst add (make-ea :qword
 349                            :disp (+ nil-value
 350                                     (static-symbol-offset '*alien-stack*)
 351                                     (ash symbol-value-slot word-shift)
 352                                     (- other-pointer-lowtag)))
 353               delta)))))
 354
 355 ;;; not strictly part of the c-call convention, but needed for the
 356 ;;; WITH-PINNED-OBJECTS macro used for "locking down" lisp objects so
 357 ;;; that GC won't move them while foreign functions go to work.
 358 (define-vop (touch-object)
 359   (:translate touch-object)
 360   (:args (object))
 361   (:ignore object)
 362   (:policy :fast-safe)
 363   (:arg-types t)
 364   (:generator 0))
 365
 366 ;;; Callbacks
 367
 368 #-sb-xc-host
 369 (defun alien-callback-accessor-form (type sp offset)
 370   `(deref (sap-alien (sap+ ,sp ,offset) (* ,type))))
 371
 372 #-sb-xc-host
 373 (defun alien-callback-assembler-wrapper (index result-type argument-types)
 374   (labels ((make-tn-maker (sc-name)
 375              (lambda (offset)
 376                (make-random-tn :kind :normal
 377                                :sc (sc-or-lose sc-name)
 378                                :offset offset)))
 379            (out-of-registers-error ()
 380              (error "Too many arguments in callback")))
 381     (let* ((segment (make-segment))
 382            (rax rax-tn)
 383            (rcx rcx-tn)
 384            (rdi rdi-tn)
 385            (rsi rsi-tn)
 386            (rdx rdx-tn)
 387            (rbp rbp-tn)
 388            (rsp rsp-tn)
 389            (xmm0 float0-tn)
 390            ([rsp] (make-ea :qword :base rsp :disp 0))
 391            ;; How many arguments have been copied
 392            (arg-count 0)
 393            ;; How many arguments have been copied from the stack
 394            (stack-argument-count 0)
 395            (gprs (mapcar (make-tn-maker 'any-reg) *c-call-register-arg-offsets*))
 396            (fprs (mapcar (make-tn-maker 'double-reg)
 397                          ;; Only 8 first XMM registers are used for
 398                          ;; passing arguments
 399                          (subseq *float-regs* 0 8))))
 400       (assemble (segment)
 401         ;; Make room on the stack for arguments.
 402         (inst sub rsp (* n-word-bytes (length argument-types)))
 403         ;; Copy arguments from registers to stack
 404         (dolist (type argument-types)
 405           (let ((integerp (not (alien-float-type-p type)))
 406                 ;; A TN pointing to the stack location where the
 407                 ;; current argument should be stored for the purposes
 408                 ;; of ENTER-ALIEN-CALLBACK.
 409                 (target-tn (make-ea :qword :base rsp
 410                                    :disp (* arg-count
 411                                             n-word-bytes)))
 412                 ;; A TN pointing to the stack location that contains
 413                 ;; the next argument passed on the stack.
 414                 (stack-arg-tn (make-ea :qword :base rsp
 415                                        :disp (* (+ 1
 416                                                    (length argument-types)
 417                                                    stack-argument-count)
 418                                                 n-word-bytes))))
 419             (incf arg-count)
 420             (cond (integerp
 421                    (let ((gpr (pop gprs)))
 422                      ;; Argument not in register, copy it from the old
 423                      ;; stack location to a temporary register.
 424                      (unless gpr
 425                        (incf stack-argument-count)
 426                        (setf gpr temp-reg-tn)
 427                        (inst mov gpr stack-arg-tn))
 428                      ;; Copy from either argument register or temporary
 429                      ;; register to target.
 430                      (inst mov target-tn gpr)))
 431                   ((or (alien-single-float-type-p type)
 432                        (alien-double-float-type-p type))
 433                    (let ((fpr (pop fprs)))
 434                      (cond (fpr
 435                             ;; Copy from float register to target location.
 436                             (inst movq target-tn fpr))
 437                            (t
 438                             ;; Not in float register. Copy from stack to
 439                             ;; temporary (general purpose) register, and
 440                             ;; from there to the target location.
 441                             (incf stack-argument-count)
 442                             (inst mov temp-reg-tn stack-arg-tn)
 443                             (inst mov target-tn temp-reg-tn)))))
 444                   (t
 445                    (bug "Unknown alien floating point type: ~S" type)))))
 446
 447         ;; arg0 to FUNCALL3 (function)
 448         ;;
 449         ;; Indirect the access to ENTER-ALIEN-CALLBACK through
 450         ;; the symbol-value slot of SB-ALIEN::*ENTER-ALIEN-CALLBACK*
 451         ;; to ensure it'll work even if the GC moves ENTER-ALIEN-CALLBACK.
 452         ;; Skip any SB-THREAD TLS magic, since we don't expect anyone
 453         ;; to rebind the variable. -- JES, 2006-01-01
 454         (inst mov rdi (+ nil-value (static-symbol-offset
 455                                     'sb!alien::*enter-alien-callback*)))
 456         (loadw rdi rdi symbol-value-slot other-pointer-lowtag)
 457         ;; arg0 to ENTER-ALIEN-CALLBACK (trampoline index)
 458         (inst mov rsi (fixnumize index))
 459         ;; arg1 to ENTER-ALIEN-CALLBACK (pointer to argument vector)
 460         (inst mov rdx rsp)
 461         ;; add room on stack for return value
 462         (inst sub rsp 8)
 463         ;; arg2 to ENTER-ALIEN-CALLBACK (pointer to return value)
 464         (inst mov rcx rsp)
 465
 466         ;; Make new frame
 467         (inst push rbp)
 468         (inst mov  rbp rsp)
 469
 470         ;; Call
 471         (inst mov  rax (foreign-symbol-address "funcall3"))
 472         (inst call rax)
 473
 474         ;; Back! Restore frame
 475         (inst mov rsp rbp)
 476         (inst pop rbp)
 477
 478         ;; Result now on top of stack, put it in the right register
 479         (cond
 480           ((or (alien-integer-type-p result-type)
 481                (alien-pointer-type-p result-type)
 482                (alien-type-= #.(parse-alien-type 'system-area-pointer nil)
 483                              result-type))
 484            (inst mov rax [rsp]))
 485           ((or (alien-single-float-type-p result-type)
 486                (alien-double-float-type-p result-type))
 487            (inst movq xmm0 [rsp]))
 488           ((alien-void-type-p result-type))
 489           (t
 490            (error "unrecognized alien type: ~A" result-type)))
 491
 492         ;; Pop the arguments and the return value from the stack to get
 493         ;; the return address at top of stack.
 494         (inst add rsp (* (1+ (length argument-types)) n-word-bytes))
 495         ;; Return
 496         (inst ret))
 497       (finalize-segment segment)
 498       ;; Now that the segment is done, convert it to a static
 499       ;; vector we can point foreign code to.
 500       (let ((buffer (sb!assem::segment-buffer segment)))
 501         (make-static-vector (length buffer)
 502                             :element-type '(unsigned-byte 8)
 503                             :initial-contents buffer)))))