src/compiler/x86-64/cell.lisp

   1 ;;;; various primitive memory access VOPs for the x86 VM
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!VM")
  13 \f
  14 ;;;; data object ref/set stuff
  15
  16 (define-vop (slot)
  17   (:args (object :scs (descriptor-reg)))
  18   (:info name offset lowtag)
  19   (:ignore name)
  20   (:results (result :scs (descriptor-reg any-reg)))
  21   (:generator 1
  22     (loadw result object offset lowtag)))
  23
  24 (define-vop (set-slot)
  25   (:args (object :scs (descriptor-reg))
  26          (value :scs (descriptor-reg any-reg immediate)))
  27   (:temporary (:sc descriptor-reg) temp)
  28   (:info name offset lowtag)
  29   (:ignore name)
  30   (:results)
  31   (:generator 1
  32     (if (sc-is value immediate)
  33         (let ((val (tn-value value)))
  34           (move-immediate (make-ea :qword
  35                                    :base object
  36                                    :disp (- (* offset n-word-bytes)
  37                                             lowtag))
  38                           (etypecase val
  39                             (integer
  40                              (fixnumize val))
  41                             (symbol
  42                              (+ nil-value (static-symbol-offset val)))
  43                             (character
  44                              (logior (ash (char-code val) n-widetag-bits)
  45                                      character-widetag)))
  46                           temp))
  47         ;; Else, value not immediate.
  48         (storew value object offset lowtag))))
  49 \f
  50
  51
  52 ;;;; symbol hacking VOPs
  53
  54 ;;; these next two cf the sparc version, by jrd.
  55 ;;; FIXME: Deref this ^ reference.
  56
  57
  58 ;;; The compiler likes to be able to directly SET symbols.
  59 #!+sb-thread
  60 (define-vop (set)
  61   (:args (symbol :scs (descriptor-reg))
  62          (value :scs (descriptor-reg any-reg)))
  63   (:temporary (:sc descriptor-reg) tls)
  64   ;;(:policy :fast-safe)
  65   (:generator 4
  66     (let ((global-val (gen-label))
  67           (done (gen-label)))
  68       (loadw tls symbol symbol-tls-index-slot other-pointer-lowtag)
  69       (inst or tls tls)
  70       (inst jmp :z global-val)
  71       (inst fs-segment-prefix)
  72       (inst cmp (make-ea :dword :scale 1 :index tls) unbound-marker-widetag)
  73       (inst jmp :z global-val)
  74       (inst fs-segment-prefix)
  75       (inst mov (make-ea :dword :scale 1 :index tls) value)
  76       (inst jmp done)
  77       (emit-label global-val)
  78       (storew value symbol symbol-value-slot other-pointer-lowtag)
  79       (emit-label done))))
  80
  81 ;; unithreaded it's a lot simpler ...
  82 #!-sb-thread
  83 (define-vop (set cell-set)
  84   (:variant symbol-value-slot other-pointer-lowtag))
  85
  86 ;;; Do a cell ref with an error check for being unbound.
  87 ;;; XXX stil used? I can't see where -dan
  88 (define-vop (checked-cell-ref)
  89   (:args (object :scs (descriptor-reg) :target obj-temp))
  90   (:results (value :scs (descriptor-reg any-reg)))
  91   (:policy :fast-safe)
  92   (:vop-var vop)
  93   (:save-p :compute-only)
  94   (:temporary (:sc descriptor-reg :from (:argument 0)) obj-temp))
  95
  96 ;;; With Symbol-Value, we check that the value isn't the trap object. So
  97 ;;; Symbol-Value of NIL is NIL.
  98 #!+sb-thread
  99 (define-vop (symbol-value)
 100   (:translate symbol-value)
 101   (:policy :fast-safe)
 102   (:args (object :scs (descriptor-reg) :to (:result 1)))
 103   (:results (value :scs (descriptor-reg any-reg)))
 104   (:vop-var vop)
 105   (:save-p :compute-only)
 106   (:generator 9
 107     (let* ((err-lab (generate-error-code vop unbound-symbol-error object))
 108            (ret-lab (gen-label)))
 109       (loadw value object symbol-tls-index-slot other-pointer-lowtag)
 110       (inst fs-segment-prefix)
 111       (inst mov value (make-ea :dword :index value :scale 1))
 112       (inst cmp value unbound-marker-widetag)
 113       (inst jmp :ne ret-lab)
 114       (loadw value object symbol-value-slot other-pointer-lowtag)
 115       (inst cmp value unbound-marker-widetag)
 116       (inst jmp :e err-lab)
 117       (emit-label ret-lab))))
 118
 119 #!+sb-thread
 120 (define-vop (fast-symbol-value symbol-value)
 121   ;; KLUDGE: not really fast, in fact, because we're going to have to
 122   ;; do a full lookup of the thread-local area anyway.  But half of
 123   ;; the meaning of FAST-SYMBOL-VALUE is "do not signal an error if
 124   ;; unbound", which is used in the implementation of COPY-SYMBOL.  --
 125   ;; CSR, 2003-04-22
 126   (:policy :fast)
 127   (:translate symbol-value)
 128   (:generator 8
 129     (let ((ret-lab (gen-label)))
 130       (loadw value object symbol-tls-index-slot other-pointer-lowtag)
 131       (inst fs-segment-prefix)
 132       (inst mov value (make-ea :dword :index value :scale 1))
 133       (inst cmp value unbound-marker-widetag)
 134       (inst jmp :ne ret-lab)
 135       (loadw value object symbol-value-slot other-pointer-lowtag)
 136       (emit-label ret-lab))))
 137
 138 #!-sb-thread
 139 (define-vop (symbol-value)
 140   (:translate symbol-value)
 141   (:policy :fast-safe)
 142   (:args (object :scs (descriptor-reg) :to (:result 1)))
 143   (:results (value :scs (descriptor-reg any-reg)))
 144   (:vop-var vop)
 145   (:save-p :compute-only)
 146   (:generator 9
 147     (let ((err-lab (generate-error-code vop unbound-symbol-error object)))
 148       (loadw value object symbol-value-slot other-pointer-lowtag)
 149       (inst cmp value unbound-marker-widetag)
 150       (inst jmp :e err-lab))))
 151
 152 #!-sb-thread
 153 (define-vop (fast-symbol-value cell-ref)
 154   (:variant symbol-value-slot other-pointer-lowtag)
 155   (:policy :fast)
 156   (:translate symbol-value))
 157
 158 (defknown locked-symbol-global-value-add (symbol fixnum) fixnum ())
 159
 160 (define-vop (locked-symbol-global-value-add)
 161     (:args (object :scs (descriptor-reg) :to :result)
 162            (value :scs (any-reg) :target result))
 163   (:arg-types * tagged-num)
 164   (:results (result :scs (any-reg) :from (:argument 1)))
 165   (:policy :fast)
 166   (:translate locked-symbol-global-value-add)
 167   (:result-types tagged-num)
 168   (:policy :fast-safe)
 169   (:generator 4
 170     (move result value)
 171     (inst lock)
 172     (inst add (make-ea :dword :base object
 173                        :disp (- (* symbol-value-slot n-word-bytes)
 174                                 other-pointer-lowtag))
 175           value)))
 176
 177 #!+sb-thread
 178 (define-vop (boundp)
 179   (:translate boundp)
 180   (:policy :fast-safe)
 181   (:args (object :scs (descriptor-reg)))
 182   (:conditional)
 183   (:info target not-p)
 184   (:temporary (:sc descriptor-reg #+nil(:from (:argument 0))) value)
 185   (:generator 9
 186     (if not-p
 187         (let ((not-target (gen-label)))
 188           (loadw value object symbol-value-slot other-pointer-lowtag)
 189           (inst cmp value unbound-marker-widetag)
 190           (inst jmp :ne not-target)
 191           (loadw value object symbol-tls-index-slot other-pointer-lowtag)
 192           (inst fs-segment-prefix)
 193           (inst cmp (make-ea :dword :index value :scale 1) unbound-marker-widetag)
 194           (inst jmp  :e  target)
 195           (emit-label not-target))
 196         (progn
 197           (loadw value object symbol-value-slot other-pointer-lowtag)
 198           (inst cmp value unbound-marker-widetag)
 199           (inst jmp :ne target)
 200           (loadw value object symbol-tls-index-slot other-pointer-lowtag)
 201           (inst fs-segment-prefix)
 202           (inst cmp (make-ea :dword :index value :scale 1) unbound-marker-widetag)
 203           (inst jmp  :ne  target)))))
 204
 205 #!-sb-thread
 206 (define-vop (boundp)
 207   (:translate boundp)
 208   (:policy :fast-safe)
 209   (:args (object :scs (descriptor-reg)))
 210   (:conditional)
 211   (:info target not-p)
 212   (:temporary (:sc descriptor-reg :from (:argument 0)) value)
 213   (:generator 9
 214     (loadw value object symbol-value-slot other-pointer-lowtag)
 215     (inst cmp value unbound-marker-widetag)
 216     (inst jmp (if not-p :e :ne) target)))
 217
 218
 219 (define-vop (symbol-hash)
 220   (:policy :fast-safe)
 221   (:translate symbol-hash)
 222   (:args (symbol :scs (descriptor-reg)))
 223   (:results (res :scs (any-reg)))
 224   (:result-types positive-fixnum)
 225   (:generator 2
 226     ;; The symbol-hash slot of NIL holds NIL because it is also the
 227     ;; cdr slot, so we have to strip off the three low bits to make sure
 228     ;; it is a fixnum.  The lowtag selection magic that is required to
 229     ;; ensure this is explained in the comment in objdef.lisp
 230     (loadw res symbol symbol-hash-slot other-pointer-lowtag)
 231     (inst and res (lognot #b111))))
 232 \f
 233 ;;;; fdefinition (FDEFN) objects
 234
 235 (define-vop (fdefn-fun cell-ref)        ; /pfw - alpha
 236   (:variant fdefn-fun-slot other-pointer-lowtag))
 237
 238 (define-vop (safe-fdefn-fun)
 239   (:args (object :scs (descriptor-reg) :to (:result 1)))
 240   (:results (value :scs (descriptor-reg any-reg)))
 241   (:vop-var vop)
 242   (:save-p :compute-only)
 243   (:generator 10
 244     (loadw value object fdefn-fun-slot other-pointer-lowtag)
 245     (inst cmp value nil-value)
 246     (let ((err-lab (generate-error-code vop undefined-fun-error object)))
 247       (inst jmp :e err-lab))))
 248
 249 (define-vop (set-fdefn-fun)
 250   (:policy :fast-safe)
 251   (:translate (setf fdefn-fun))
 252   (:args (function :scs (descriptor-reg) :target result)
 253          (fdefn :scs (descriptor-reg)))
 254   (:temporary (:sc unsigned-reg) raw)
 255   (:temporary (:sc byte-reg) type)
 256   (:results (result :scs (descriptor-reg)))
 257   (:generator 38
 258     (load-type type function (- fun-pointer-lowtag))
 259     (inst lea raw
 260           (make-ea :byte :base function
 261                    :disp (- (* simple-fun-code-offset n-word-bytes)
 262                             fun-pointer-lowtag)))
 263     (inst cmp type simple-fun-header-widetag)
 264     (inst jmp :e normal-fn)
 265     (inst lea raw (make-fixup (extern-alien-name "closure_tramp") :foreign))
 266     NORMAL-FN
 267     (storew function fdefn fdefn-fun-slot other-pointer-lowtag)
 268     (storew raw fdefn fdefn-raw-addr-slot other-pointer-lowtag)
 269     (move result function)))
 270
 271 (define-vop (fdefn-makunbound)
 272   (:policy :fast-safe)
 273   (:translate fdefn-makunbound)
 274   (:args (fdefn :scs (descriptor-reg) :target result))
 275   (:results (result :scs (descriptor-reg)))
 276   (:generator 38
 277     (storew nil-value fdefn fdefn-fun-slot other-pointer-lowtag)
 278     (storew (make-fixup (extern-alien-name "undefined_tramp") :foreign)
 279             fdefn fdefn-raw-addr-slot other-pointer-lowtag)
 280     (move result fdefn)))
 281 \f
 282 ;;;; binding and unbinding
 283
 284 ;;; BIND -- Establish VAL as a binding for SYMBOL. Save the old value and
 285 ;;; the symbol on the binding stack and stuff the new value into the
 286 ;;; symbol.
 287
 288 #!+sb-thread
 289 (define-vop (bind)
 290   (:args (val :scs (any-reg descriptor-reg))
 291          (symbol :scs (descriptor-reg)))
 292   (:temporary (:sc unsigned-reg) tls-index temp bsp)
 293   (:generator 5
 294     (let ((tls-index-valid (gen-label)))
 295       (load-tl-symbol-value bsp *binding-stack-pointer*)
 296       (loadw tls-index symbol symbol-tls-index-slot other-pointer-lowtag)
 297       (inst add bsp (* binding-size n-word-bytes))
 298       (store-tl-symbol-value bsp *binding-stack-pointer* temp)
 299
 300       (inst or tls-index tls-index)
 301       (inst jmp :ne tls-index-valid)
 302       ;; allocate a new tls-index
 303       (load-symbol-value tls-index *free-tls-index*)
 304       (inst add tls-index 4)            ;XXX surely we can do this more
 305       (store-symbol-value tls-index *free-tls-index*) ;succintly
 306       (inst sub tls-index 4)
 307       (storew tls-index symbol symbol-tls-index-slot other-pointer-lowtag)
 308       (emit-label tls-index-valid)
 309       (inst fs-segment-prefix)
 310       (inst mov temp (make-ea :dword :scale 1 :index tls-index))
 311       (storew temp bsp (- binding-value-slot binding-size))
 312       (storew symbol bsp (- binding-symbol-slot binding-size))
 313       (inst fs-segment-prefix)
 314       (inst mov (make-ea :dword :scale 1 :index tls-index) val))))
 315
 316 #!-sb-thread
 317 (define-vop (bind)
 318   (:args (val :scs (any-reg descriptor-reg))
 319          (symbol :scs (descriptor-reg)))
 320   (:temporary (:sc unsigned-reg) temp bsp)
 321   (:generator 5
 322     (load-symbol-value bsp *binding-stack-pointer*)
 323     (loadw temp symbol symbol-value-slot other-pointer-lowtag)
 324     (inst add bsp (* binding-size n-word-bytes))
 325     (store-symbol-value bsp *binding-stack-pointer*)
 326     (storew temp bsp (- binding-value-slot binding-size))
 327     (storew symbol bsp (- binding-symbol-slot binding-size))
 328     (storew val symbol symbol-value-slot other-pointer-lowtag)))
 329
 330
 331 #!+sb-thread
 332 (define-vop (unbind)
 333     ;; four temporaries?
 334   (:temporary (:sc unsigned-reg) symbol value bsp tls-index)
 335   (:generator 0
 336     (load-tl-symbol-value bsp *binding-stack-pointer*)
 337     (loadw symbol bsp (- binding-symbol-slot binding-size))
 338     (loadw value bsp (- binding-value-slot binding-size))
 339
 340     (loadw tls-index symbol symbol-tls-index-slot other-pointer-lowtag)
 341     (inst fs-segment-prefix)
 342     (inst mov (make-ea :dword :scale 1 :index tls-index) value)
 343
 344     (storew 0 bsp (- binding-symbol-slot binding-size))
 345     (inst sub bsp (* binding-size n-word-bytes))
 346     ;; we're done with value, so we can use it as a temp here
 347     (store-tl-symbol-value bsp *binding-stack-pointer* value)))
 348
 349 #!-sb-thread
 350 (define-vop (unbind)
 351   (:temporary (:sc unsigned-reg) symbol value bsp)
 352   (:generator 0
 353     (load-symbol-value bsp *binding-stack-pointer*)
 354     (loadw symbol bsp (- binding-symbol-slot binding-size))
 355     (loadw value bsp (- binding-value-slot binding-size))
 356     (storew value symbol symbol-value-slot other-pointer-lowtag)
 357     (storew 0 bsp (- binding-symbol-slot binding-size))
 358     (inst sub bsp (* binding-size n-word-bytes))
 359     (store-symbol-value bsp *binding-stack-pointer*)))
 360
 361
 362 (define-vop (unbind-to-here)
 363   (:args (where :scs (descriptor-reg any-reg)))
 364   (:temporary (:sc unsigned-reg) symbol value bsp #!+sb-thread tls-index)
 365   (:generator 0
 366     (load-tl-symbol-value bsp *binding-stack-pointer*)
 367     (inst cmp where bsp)
 368     (inst jmp :e done)
 369
 370     LOOP
 371     (loadw symbol bsp (- binding-symbol-slot binding-size))
 372     (inst or symbol symbol)
 373     (inst jmp :z skip)
 374     (loadw value bsp (- binding-value-slot binding-size))
 375     #!-sb-thread (storew value symbol symbol-value-slot other-pointer-lowtag)
 376
 377     #!+sb-thread (loadw
 378                   tls-index symbol symbol-tls-index-slot other-pointer-lowtag)
 379     #!+sb-thread (inst fs-segment-prefix)
 380     #!+sb-thread (inst mov (make-ea :dword :scale 1 :index tls-index) value)
 381     (storew 0 bsp (- binding-symbol-slot binding-size))
 382
 383     SKIP
 384     (inst sub bsp (* binding-size n-word-bytes))
 385     (inst cmp where bsp)
 386     (inst jmp :ne loop)
 387     ;; we're done with value, so can use it as a temporary
 388     (store-tl-symbol-value bsp *binding-stack-pointer* value)
 389
 390     DONE))
 391 \f
 392
 393 \f
 394 ;;;; closure indexing
 395
 396 (define-full-reffer closure-index-ref *
 397   closure-info-offset fun-pointer-lowtag
 398   (any-reg descriptor-reg) * %closure-index-ref)
 399
 400 (define-full-setter set-funcallable-instance-info *
 401   funcallable-instance-info-offset fun-pointer-lowtag
 402   (any-reg descriptor-reg) * %set-funcallable-instance-info)
 403
 404 (define-full-reffer funcallable-instance-info *
 405   funcallable-instance-info-offset fun-pointer-lowtag
 406   (descriptor-reg any-reg) * %funcallable-instance-info)
 407
 408 (define-vop (funcallable-instance-lexenv cell-ref)
 409   (:variant funcallable-instance-lexenv-slot fun-pointer-lowtag))
 410
 411 (define-vop (closure-ref slot-ref)
 412   (:variant closure-info-offset fun-pointer-lowtag))
 413
 414 (define-vop (closure-init slot-set)
 415   (:variant closure-info-offset fun-pointer-lowtag))
 416 \f
 417 ;;;; value cell hackery
 418
 419 (define-vop (value-cell-ref cell-ref)
 420   (:variant value-cell-value-slot other-pointer-lowtag))
 421
 422 (define-vop (value-cell-set cell-set)
 423   (:variant value-cell-value-slot other-pointer-lowtag))
 424 \f
 425 ;;;; structure hackery
 426
 427 (define-vop (instance-length)
 428   (:policy :fast-safe)
 429   (:translate %instance-length)
 430   (:args (struct :scs (descriptor-reg)))
 431   (:results (res :scs (unsigned-reg)))
 432   (:result-types positive-fixnum)
 433   (:generator 4
 434     (loadw res struct 0 instance-pointer-lowtag)
 435     (inst shr res n-widetag-bits)))
 436
 437 (define-vop (instance-ref slot-ref)
 438   (:variant instance-slots-offset instance-pointer-lowtag)
 439   (:policy :fast-safe)
 440   (:translate %instance-ref)
 441   (:arg-types instance (:constant index)))
 442
 443 (define-vop (instance-set slot-set)
 444   (:policy :fast-safe)
 445   (:translate %instance-set)
 446   (:variant instance-slots-offset instance-pointer-lowtag)
 447   (:arg-types instance (:constant index) *))
 448
 449 (define-full-reffer instance-index-ref * instance-slots-offset
 450   instance-pointer-lowtag (any-reg descriptor-reg) * %instance-ref)
 451
 452 (define-full-setter instance-index-set * instance-slots-offset
 453   instance-pointer-lowtag (any-reg descriptor-reg) * %instance-set)
 454
 455
 456 (defknown %instance-set-conditional (instance index t t) t
 457           (unsafe))
 458
 459 (define-vop (instance-set-conditional)
 460   (:translate %instance-set-conditional)
 461   (:args (object :scs (descriptor-reg) :to :eval)
 462          (slot :scs (any-reg) :to :result)
 463          (old-value :scs (descriptor-reg any-reg) :target eax)
 464          (new-value :scs (descriptor-reg any-reg)))
 465   (:arg-types instance positive-fixnum * *)
 466   (:temporary (:sc descriptor-reg :offset eax-offset
 467                    :from (:argument 2) :to :result :target result)  eax)
 468   (:results (result :scs (descriptor-reg any-reg)))
 469   ;(:guard (backend-featurep :i486))
 470   (:policy :fast-safe)
 471   (:generator 5
 472     (move eax old-value)
 473     (inst lock)
 474     (inst cmpxchg (make-ea :dword :base object :index slot :scale 1
 475                            :disp (- (* instance-slots-offset n-word-bytes)
 476                                     instance-pointer-lowtag))
 477           new-value)
 478     (move result eax)))
 479
 480
 481 \f
 482 ;;;; code object frobbing
 483
 484 (define-full-reffer code-header-ref * 0 other-pointer-lowtag
 485   (any-reg descriptor-reg) * code-header-ref)
 486
 487 (define-full-setter code-header-set * 0 other-pointer-lowtag
 488   (any-reg descriptor-reg) * code-header-set)