src/compiler/x86-64/macros.lisp

   1 ;;;; a bunch of handy macros for the x86
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!VM")
  13
  14 ;;;; instruction-like macros
  15
  16 (defmacro move (dst src)
  17   #!+sb-doc
  18   "Move SRC into DST unless they are location=."
  19   (once-only ((n-dst dst)
  20               (n-src src))
  21     `(unless (location= ,n-dst ,n-src)
  22        (sc-case ,n-dst
  23          ((single-reg complex-single-reg)
  24           (aver (xmm-register-p ,n-src))
  25           (inst movaps ,n-dst ,n-src))
  26          ((double-reg complex-double-reg)
  27           (aver (xmm-register-p ,n-src))
  28           (inst movapd ,n-dst ,n-src))
  29          (t
  30           (inst mov ,n-dst ,n-src))))))
  31
  32 (defmacro make-ea-for-object-slot (ptr slot lowtag)
  33   `(make-ea :qword :base ,ptr :disp (- (* ,slot n-word-bytes) ,lowtag)))
  34 (defmacro make-ea-for-object-slot-half (ptr slot lowtag)
  35   `(make-ea :dword :base ,ptr :disp (- (* ,slot n-word-bytes) ,lowtag)))
  36
  37 (defmacro loadw (value ptr &optional (slot 0) (lowtag 0))
  38   `(inst mov ,value (make-ea-for-object-slot ,ptr ,slot ,lowtag)))
  39
  40 (defmacro storew (value ptr &optional (slot 0) (lowtag 0))
  41   (once-only ((value value))
  42     `(cond ((and (integerp ,value)
  43                  (not (typep ,value '(signed-byte 32))))
  44             (inst mov temp-reg-tn ,value)
  45             (inst mov (make-ea-for-object-slot ,ptr ,slot ,lowtag) temp-reg-tn))
  46            (t
  47             (inst mov (make-ea-for-object-slot ,ptr ,slot ,lowtag) ,value)))))
  48
  49 (defmacro pushw (ptr &optional (slot 0) (lowtag 0))
  50   `(inst push (make-ea-for-object-slot ,ptr ,slot ,lowtag)))
  51
  52 (defmacro popw (ptr &optional (slot 0) (lowtag 0))
  53   `(inst pop (make-ea-for-object-slot ,ptr ,slot ,lowtag)))
  54 \f
  55 ;;;; macros to generate useful values
  56
  57 (defmacro load-symbol (reg symbol)
  58   `(inst mov ,reg (+ nil-value (static-symbol-offset ,symbol))))
  59
  60 (defmacro make-ea-for-symbol-value (symbol)
  61   `(make-ea :qword
  62     :disp (+ nil-value
  63            (static-symbol-offset ',symbol)
  64            (ash symbol-value-slot word-shift)
  65            (- other-pointer-lowtag))))
  66
  67 (defmacro load-symbol-value (reg symbol)
  68   `(inst mov ,reg (make-ea-for-symbol-value ,symbol)))
  69
  70 (defmacro store-symbol-value (reg symbol)
  71   `(inst mov (make-ea-for-symbol-value ,symbol) ,reg))
  72
  73 #!+sb-thread
  74 (defmacro make-ea-for-symbol-tls-index (symbol)
  75   `(make-ea :qword
  76     :disp (+ nil-value
  77            (static-symbol-offset ',symbol)
  78            (ash symbol-tls-index-slot word-shift)
  79            (- other-pointer-lowtag))))
  80
  81 #!+sb-thread
  82 (defmacro load-tl-symbol-value (reg symbol)
  83   `(progn
  84     (inst mov ,reg (make-ea-for-symbol-tls-index ,symbol))
  85     (inst mov ,reg (make-ea :qword :base thread-base-tn :scale 1 :index ,reg))))
  86 #!-sb-thread
  87 (defmacro load-tl-symbol-value (reg symbol) `(load-symbol-value ,reg ,symbol))
  88
  89 #!+sb-thread
  90 (defmacro store-tl-symbol-value (reg symbol temp)
  91   `(progn
  92     (inst mov ,temp (make-ea-for-symbol-tls-index ,symbol))
  93     (inst mov (make-ea :qword :base thread-base-tn :scale 1 :index ,temp) ,reg)))
  94 #!-sb-thread
  95 (defmacro store-tl-symbol-value (reg symbol temp)
  96   (declare (ignore temp))
  97   `(store-symbol-value ,reg ,symbol))
  98
  99 (defmacro load-binding-stack-pointer (reg)
 100   #!+sb-thread
 101   `(inst mov ,reg (make-ea :qword :base thread-base-tn
 102                    :disp (* n-word-bytes thread-binding-stack-pointer-slot)))
 103   #!-sb-thread
 104   `(load-symbol-value ,reg *binding-stack-pointer*))
 105
 106 (defmacro store-binding-stack-pointer (reg)
 107   #!+sb-thread
 108   `(inst mov (make-ea :qword :base thread-base-tn
 109               :disp (* n-word-bytes thread-binding-stack-pointer-slot))
 110     ,reg)
 111   #!-sb-thread
 112   `(store-symbol-value ,reg *binding-stack-pointer*))
 113
 114 (defmacro load-type (target source &optional (offset 0))
 115   #!+sb-doc
 116   "Loads the type bits of a pointer into target independent of
 117    byte-ordering issues."
 118   (once-only ((n-target target)
 119               (n-source source)
 120               (n-offset offset))
 121     (ecase *backend-byte-order*
 122       (:little-endian
 123        `(inst movzx ,n-target
 124               (make-ea :byte :base ,n-source :disp ,n-offset)))
 125       (:big-endian
 126        `(inst movzx ,n-target
 127               (make-ea :byte :base ,n-source
 128                              :disp (+ ,n-offset (1- n-word-bytes))))))))
 129 \f
 130 ;;;; allocation helpers
 131
 132 ;;; All allocation is done by calls to assembler routines that
 133 ;;; eventually invoke the C alloc() function.
 134
 135 ;;; Emit code to allocate an object with a size in bytes given by
 136 ;;; Size. The size may be an integer of a TN. If Inline is a VOP
 137 ;;; node-var then it is used to make an appropriate speed vs size
 138 ;;; decision.
 139
 140 (defun allocation-dynamic-extent (alloc-tn size lowtag)
 141   (inst sub rsp-tn size)
 142   ;; see comment in x86/macros.lisp implementation of this
 143   (inst and rsp-tn #.(lognot lowtag-mask))
 144   (aver (not (location= alloc-tn rsp-tn)))
 145   (inst lea alloc-tn (make-ea :byte :base rsp-tn :disp lowtag))
 146   (values))
 147
 148 ;;; This macro should only be used inside a pseudo-atomic section,
 149 ;;; which should also cover subsequent initialization of the
 150 ;;; object.
 151 (defun allocation-tramp (alloc-tn size lowtag)
 152   (inst push size)
 153   (inst lea temp-reg-tn (make-ea :qword
 154                             :disp (make-fixup "alloc_tramp" :foreign)))
 155   (inst call temp-reg-tn)
 156   (inst pop alloc-tn)
 157   (when lowtag
 158     (inst lea alloc-tn (make-ea :byte :base alloc-tn :disp lowtag)))
 159   (values))
 160
 161 (defun allocation (alloc-tn size &optional ignored dynamic-extent lowtag)
 162   (declare (ignore ignored))
 163   (when dynamic-extent
 164     (allocation-dynamic-extent alloc-tn size lowtag)
 165     (return-from allocation (values)))
 166   (let ((NOT-INLINE (gen-label))
 167         (DONE (gen-label))
 168         ;; Yuck.
 169         (in-elsewhere (eq *elsewhere* sb!assem::**current-segment**))
 170         ;; thread->alloc_region.free_pointer
 171         (free-pointer
 172          #!+sb-thread
 173          (make-ea :qword
 174                   :base thread-base-tn :scale 1
 175                   :disp (* n-word-bytes thread-alloc-region-slot))
 176          #!-sb-thread
 177          (make-ea :qword
 178                   :scale 1 :disp
 179                   (make-fixup "boxed_region" :foreign)))
 180         ;; thread->alloc_region.end_addr
 181         (end-addr
 182          #!+sb-thread
 183          (make-ea :qword
 184                   :base thread-base-tn :scale 1
 185                   :disp (* n-word-bytes (1+ thread-alloc-region-slot)))
 186          #!-sb-thread
 187          (make-ea :qword
 188                   :scale 1 :disp
 189                   (make-fixup "boxed_region" :foreign 8))))
 190     (cond (in-elsewhere
 191            (allocation-tramp alloc-tn size lowtag))
 192           (t
 193            (inst mov temp-reg-tn free-pointer)
 194            (if (tn-p size)
 195                (if (location= alloc-tn size)
 196                    (inst add alloc-tn temp-reg-tn)
 197                    (inst lea alloc-tn
 198                          (make-ea :qword :base temp-reg-tn :index size)))
 199                (inst lea alloc-tn
 200                      (make-ea :qword :base temp-reg-tn :disp size)))
 201            (inst cmp end-addr alloc-tn)
 202            (inst jmp :be NOT-INLINE)
 203            (inst mov free-pointer alloc-tn)
 204            (if lowtag
 205                (inst lea alloc-tn (make-ea :byte :base temp-reg-tn :disp lowtag))
 206                (inst mov alloc-tn temp-reg-tn))
 207            (emit-label DONE)
 208            (assemble (*elsewhere*)
 209              (emit-label NOT-INLINE)
 210              (cond ((numberp size)
 211                     (allocation-tramp alloc-tn size lowtag))
 212                    (t
 213                     (inst sub alloc-tn free-pointer)
 214                     (allocation-tramp alloc-tn alloc-tn lowtag)))
 215              (inst jmp DONE))))
 216     (values)))
 217
 218 ;;; Allocate an other-pointer object of fixed SIZE with a single word
 219 ;;; header having the specified WIDETAG value. The result is placed in
 220 ;;; RESULT-TN.
 221 (defmacro with-fixed-allocation ((result-tn widetag size &optional inline stack-allocate-p)
 222                                  &body forms)
 223   (unless forms
 224     (bug "empty &body in WITH-FIXED-ALLOCATION"))
 225   (once-only ((result-tn result-tn) (size size) (stack-allocate-p stack-allocate-p))
 226     `(maybe-pseudo-atomic ,stack-allocate-p
 227       (allocation ,result-tn (pad-data-block ,size) ,inline ,stack-allocate-p
 228                   other-pointer-lowtag)
 229       (storew (logior (ash (1- ,size) n-widetag-bits) ,widetag)
 230               ,result-tn 0 other-pointer-lowtag)
 231       ,@forms)))
 232 \f
 233 ;;;; error code
 234 (defun emit-error-break (vop kind code values)
 235   (assemble ()
 236     #!-ud2-breakpoints
 237     (inst int 3)                  ; i386 breakpoint instruction
 238     ;; On Darwin, we need to use #x0b0f instead of int3 in order
 239     ;; to generate a SIGILL instead of a SIGTRAP as darwin/x86
 240     ;; doesn't seem to be reliably firing SIGTRAP
 241     ;; handlers. Hopefully this will be fixed by Apple at a
 242     ;; later date. Do the same on x86-64 as we do on x86 until this gets
 243     ;; sorted out.
 244     #!+ud2-breakpoints
 245     (inst word #x0b0f)
 246     ;; The return PC points here; note the location for the debugger.
 247     (when vop
 248       (note-this-location vop :internal-error))
 249     (inst byte kind)                       ; eg trap_Xyyy
 250     (with-adjustable-vector (vector)       ; interr arguments
 251       (write-var-integer code vector)
 252       (dolist (tn values)
 253         ;; classic CMU CL comment:
 254         ;;   zzzzz jrd here. tn-offset is zero for constant
 255         ;;   tns.
 256         (write-var-integer (make-sc-offset (sc-number (tn-sc tn))
 257                                            (or (tn-offset tn) 0))
 258                            vector))
 259       (inst byte (length vector))
 260       (dotimes (i (length vector))
 261         (inst byte (aref vector i))))))
 262
 263 (defun error-call (vop error-code &rest values)
 264   #!+sb-doc
 265   "Cause an error. ERROR-CODE is the error to cause."
 266   (emit-error-break vop error-trap (error-number-or-lose error-code) values))
 267
 268 (defun generate-error-code (vop error-code &rest values)
 269   #!+sb-doc
 270   "Generate-Error-Code Error-code Value*
 271   Emit code for an error with the specified Error-Code and context Values."
 272   (assemble (*elsewhere*)
 273     (let ((start-lab (gen-label)))
 274       (emit-label start-lab)
 275       (emit-error-break vop error-trap (error-number-or-lose error-code) values)
 276        start-lab)))
 277
 278 \f
 279 ;;;; PSEUDO-ATOMIC
 280
 281 ;;; This is used to wrap operations which leave untagged memory lying
 282 ;;; around.  It's an operation which the AOP weenies would describe as
 283 ;;; having "cross-cutting concerns", meaning it appears all over the
 284 ;;; place and there's no logical single place to attach documentation.
 285 ;;; grep (mostly in src/runtime) is your friend
 286
 287 (defmacro maybe-pseudo-atomic (not-really-p &body body)
 288   `(if ,not-really-p
 289        (progn ,@body)
 290        (pseudo-atomic ,@body)))
 291
 292 ;;; Unsafely clear pa flags so that the image can properly lose in a
 293 ;;; pa section.
 294 #!+sb-thread
 295 (defmacro %clear-pseudo-atomic ()
 296   '(inst mov (make-ea :qword :base thread-base-tn
 297               :disp (* n-word-bytes thread-pseudo-atomic-bits-slot))
 298     0))
 299
 300 #!+sb-safepoint
 301 (defun emit-safepoint ()
 302   (inst test al-tn (make-ea :byte :disp sb!vm::gc-safepoint-page-addr)))
 303
 304 #!+sb-thread
 305 (defmacro pseudo-atomic (&rest forms)
 306   #!+sb-safepoint-strictly
 307   `(progn ,@forms (emit-safepoint))
 308   #!-sb-safepoint-strictly
 309   (with-unique-names (label)
 310     `(let ((,label (gen-label)))
 311        (inst mov (make-ea :qword
 312                           :base thread-base-tn
 313                           :disp (* n-word-bytes thread-pseudo-atomic-bits-slot))
 314              rbp-tn)
 315        ,@forms
 316        (inst xor (make-ea :qword
 317                           :base thread-base-tn
 318                           :disp (* n-word-bytes thread-pseudo-atomic-bits-slot))
 319              rbp-tn)
 320        (inst jmp :z ,label)
 321        ;; if PAI was set, interrupts were disabled at the same time
 322        ;; using the process signal mask.
 323        (inst break pending-interrupt-trap)
 324        (emit-label ,label)
 325        #!+sb-safepoint
 326        ;; In this case, when allocation thinks a GC should be done, it
 327        ;; does not mark PA as interrupted, but schedules a safepoint
 328        ;; trap instead.  Let's take the opportunity to trigger that
 329        ;; safepoint right now.
 330        (emit-safepoint))))
 331
 332
 333 #!-sb-thread
 334 (defmacro pseudo-atomic (&rest forms)
 335   (with-unique-names (label)
 336     `(let ((,label (gen-label)))
 337        ;; FIXME: The MAKE-EA noise should become a MACROLET macro or
 338        ;; something. (perhaps SVLB, for static variable low byte)
 339        (inst mov (make-ea :qword :disp (+ nil-value
 340                                           (static-symbol-offset
 341                                            '*pseudo-atomic-bits*)
 342                                           (ash symbol-value-slot word-shift)
 343                                           (- other-pointer-lowtag)))
 344              rbp-tn)
 345        ,@forms
 346        (inst xor (make-ea :qword :disp (+ nil-value
 347                                           (static-symbol-offset
 348                                            '*pseudo-atomic-bits*)
 349                                           (ash symbol-value-slot word-shift)
 350                                           (- other-pointer-lowtag)))
 351              rbp-tn)
 352        (inst jmp :z ,label)
 353        ;; if PAI was set, interrupts were disabled at the same time
 354        ;; using the process signal mask.
 355        (inst break pending-interrupt-trap)
 356        (emit-label ,label))))
 357 \f
 358 ;;;; indexed references
 359
 360 (defmacro define-full-compare-and-swap
 361     (name type offset lowtag scs el-type &optional translate)
 362   `(progn
 363      (define-vop (,name)
 364          ,@(when translate `((:translate ,translate)))
 365        (:policy :fast-safe)
 366        (:args (object :scs (descriptor-reg) :to :eval)
 367               (index :scs (any-reg) :to :result)
 368               (old-value :scs ,scs :target rax)
 369               (new-value :scs ,scs))
 370        (:arg-types ,type tagged-num ,el-type ,el-type)
 371        (:temporary (:sc descriptor-reg :offset rax-offset
 372                         :from (:argument 2) :to :result :target value)  rax)
 373        (:results (value :scs ,scs))
 374        (:result-types ,el-type)
 375        (:generator 5
 376          (move rax old-value)
 377          (inst cmpxchg (make-ea :qword :base object :index index
 378                                 :scale (ash 1 (- word-shift n-fixnum-tag-bits))
 379                                 :disp (- (* ,offset n-word-bytes) ,lowtag))
 380                new-value :lock)
 381          (move value rax)))))
 382
 383 (defmacro define-full-reffer (name type offset lowtag scs el-type &optional translate)
 384   `(progn
 385      (define-vop (,name)
 386        ,@(when translate
 387            `((:translate ,translate)))
 388        (:policy :fast-safe)
 389        (:args (object :scs (descriptor-reg))
 390               (index :scs (any-reg)))
 391        (:arg-types ,type tagged-num)
 392        (:results (value :scs ,scs))
 393        (:result-types ,el-type)
 394        (:generator 3                    ; pw was 5
 395          (inst mov value (make-ea :qword :base object :index index
 396                                   :scale (ash 1 (- word-shift n-fixnum-tag-bits))
 397                                   :disp (- (* ,offset n-word-bytes)
 398                                            ,lowtag)))))
 399      (define-vop (,(symbolicate name "-C"))
 400        ,@(when translate
 401            `((:translate ,translate)))
 402        (:policy :fast-safe)
 403        (:args (object :scs (descriptor-reg)))
 404        (:info index)
 405        (:arg-types ,type
 406                    (:constant (load/store-index ,n-word-bytes ,(eval lowtag)
 407                                                 ,(eval offset))))
 408        (:results (value :scs ,scs))
 409        (:result-types ,el-type)
 410        (:generator 2                    ; pw was 5
 411          (inst mov value (make-ea :qword :base object
 412                                   :disp (- (* (+ ,offset index) n-word-bytes)
 413                                            ,lowtag)))))))
 414
 415 (defmacro define-full-reffer+offset (name type offset lowtag scs el-type &optional translate)
 416   `(progn
 417      (define-vop (,name)
 418        ,@(when translate
 419            `((:translate ,translate)))
 420        (:policy :fast-safe)
 421        (:args (object :scs (descriptor-reg))
 422               (index :scs (any-reg)))
 423        (:info offset)
 424        (:arg-types ,type tagged-num
 425                    (:constant (constant-displacement other-pointer-lowtag
 426                                                      n-word-bytes vector-data-offset)))
 427        (:results (value :scs ,scs))
 428        (:result-types ,el-type)
 429        (:generator 3                    ; pw was 5
 430          (inst mov value (make-ea :qword :base object :index index
 431                                   :scale (ash 1 (- word-shift n-fixnum-tag-bits))
 432                                   :disp (- (* (+ ,offset offset) n-word-bytes)
 433                                            ,lowtag)))))
 434      (define-vop (,(symbolicate name "-C"))
 435        ,@(when translate
 436            `((:translate ,translate)))
 437        (:policy :fast-safe)
 438        (:args (object :scs (descriptor-reg)))
 439        (:info index offset)
 440        (:arg-types ,type
 441                    (:constant (load/store-index ,n-word-bytes ,(eval lowtag)
 442                                                 ,(eval offset)))
 443                    (:constant (constant-displacement other-pointer-lowtag
 444                                                      n-word-bytes vector-data-offset)))
 445        (:results (value :scs ,scs))
 446        (:result-types ,el-type)
 447        (:generator 2                    ; pw was 5
 448          (inst mov value (make-ea :qword :base object
 449                                   :disp (- (* (+ ,offset index offset) n-word-bytes)
 450                                            ,lowtag)))))))
 451
 452 (defmacro define-full-setter (name type offset lowtag scs el-type &optional translate)
 453   `(progn
 454      (define-vop (,name)
 455        ,@(when translate
 456            `((:translate ,translate)))
 457        (:policy :fast-safe)
 458        (:args (object :scs (descriptor-reg))
 459               (index :scs (any-reg))
 460               (value :scs ,scs :target result))
 461        (:arg-types ,type tagged-num ,el-type)
 462        (:results (result :scs ,scs))
 463        (:result-types ,el-type)
 464        (:generator 4                    ; was 5
 465          (inst mov (make-ea :qword :base object :index index
 466                             :scale (ash 1 (- word-shift n-fixnum-tag-bits))
 467                             :disp (- (* ,offset n-word-bytes) ,lowtag))
 468                value)
 469          (move result value)))
 470      (define-vop (,(symbolicate name "-C"))
 471        ,@(when translate
 472            `((:translate ,translate)))
 473        (:policy :fast-safe)
 474        (:args (object :scs (descriptor-reg))
 475               (value :scs ,scs :target result))
 476        (:info index)
 477        (:arg-types ,type
 478                    (:constant (load/store-index ,n-word-bytes ,(eval lowtag)
 479                                                 ,(eval offset)))
 480                    ,el-type)
 481        (:results (result :scs ,scs))
 482        (:result-types ,el-type)
 483        (:generator 3                    ; was 5
 484          (inst mov (make-ea :qword :base object
 485                             :disp (- (* (+ ,offset index) n-word-bytes)
 486                                      ,lowtag))
 487                value)
 488          (move result value)))))
 489
 490 (defmacro define-full-setter+offset (name type offset lowtag scs el-type &optional translate)
 491   `(progn
 492      (define-vop (,name)
 493        ,@(when translate
 494            `((:translate ,translate)))
 495        (:policy :fast-safe)
 496        (:args (object :scs (descriptor-reg))
 497               (index :scs (any-reg))
 498               (value :scs ,scs :target result))
 499        (:info offset)
 500        (:arg-types ,type tagged-num
 501                    (:constant (constant-displacement other-pointer-lowtag
 502                                                      n-word-bytes
 503                                                      vector-data-offset))
 504                    ,el-type)
 505        (:results (result :scs ,scs))
 506        (:result-types ,el-type)
 507        (:generator 4                    ; was 5
 508          (inst mov (make-ea :qword :base object :index index
 509                             :scale (ash 1 (- word-shift n-fixnum-tag-bits))
 510                             :disp (- (* (+ ,offset offset) n-word-bytes) ,lowtag))
 511                value)
 512          (move result value)))
 513      (define-vop (,(symbolicate name "-C"))
 514        ,@(when translate
 515            `((:translate ,translate)))
 516        (:policy :fast-safe)
 517        (:args (object :scs (descriptor-reg))
 518               (value :scs ,scs :target result))
 519        (:info index offset)
 520        (:arg-types ,type
 521                    (:constant (load/store-index ,n-word-bytes ,(eval lowtag)
 522                                                 ,(eval offset)))
 523                    (:constant (constant-displacement other-pointer-lowtag
 524                                                      n-word-bytes
 525                                                      vector-data-offset))
 526                    ,el-type)
 527        (:results (result :scs ,scs))
 528        (:result-types ,el-type)
 529        (:generator 3                    ; was 5
 530          (inst mov (make-ea :qword :base object
 531                             :disp (- (* (+ ,offset index offset) n-word-bytes)
 532                                      ,lowtag))
 533                value)
 534          (move result value)))))
 535
 536 ;;; helper for alien stuff.
 537
 538 (def!macro with-pinned-objects ((&rest objects) &body body)
 539   "Arrange with the garbage collector that the pages occupied by
 540 OBJECTS will not be moved in memory for the duration of BODY.
 541 Useful for e.g. foreign calls where another thread may trigger
 542 collection."
 543   (if objects
 544       (let ((pins (make-gensym-list (length objects)))
 545             (wpo (sb!xc:gensym "WITH-PINNED-OBJECTS-THUNK")))
 546         ;; BODY is stuffed in a function to preserve the lexical
 547         ;; environment.
 548         `(flet ((,wpo () (progn ,@body)))
 549            (declare (muffle-conditions compiler-note))
 550            ;; PINS are dx-allocated in case the compiler for some
 551            ;; unfathomable reason decides to allocate value-cells
 552            ;; for them -- since we have DX value-cells on x86oid
 553            ;; platforms this still forces them on the stack.
 554            (dx-let ,(mapcar #'list pins objects)
 555              (multiple-value-prog1 (,wpo)
 556                ;; TOUCH-OBJECT has a VOP with an empty body: compiler
 557                ;; thinks we're using the argument and doesn't flush
 558                ;; the variable, but we don't have to pay any extra
 559                ;; beyond that -- and MULTIPLE-VALUE-PROG1 keeps them
 560                ;; live till the body has finished. *whew*
 561                ,@(mapcar (lambda (pin)
 562                            `(touch-object ,pin))
 563                          pins)))))
 564       `(progn ,@body)))