src/compiler/x86-64/macros.lisp

   1 ;;;; a bunch of handy macros for the x86
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!VM")
  13
  14 ;;;; instruction-like macros
  15
  16 (defmacro move (dst src)
  17   #!+sb-doc
  18   "Move SRC into DST unless they are location=."
  19   (once-only ((n-dst dst)
  20               (n-src src))
  21     `(unless (location= ,n-dst ,n-src)
  22        (sc-case ,n-dst
  23          ((single-reg complex-single-reg)
  24           (aver (xmm-register-p ,n-src))
  25           (inst movaps ,n-dst ,n-src))
  26          ((double-reg complex-double-reg)
  27           (aver (xmm-register-p ,n-src))
  28           (inst movapd ,n-dst ,n-src))
  29          (t
  30           (inst mov ,n-dst ,n-src))))))
  31
  32 (defmacro make-ea-for-object-slot (ptr slot lowtag)
  33   `(make-ea :qword :base ,ptr :disp (- (* ,slot n-word-bytes) ,lowtag)))
  34 (defmacro make-ea-for-object-slot-half (ptr slot lowtag)
  35   `(make-ea :dword :base ,ptr :disp (- (* ,slot n-word-bytes) ,lowtag)))
  36
  37 (defmacro loadw (value ptr &optional (slot 0) (lowtag 0))
  38   `(inst mov ,value (make-ea-for-object-slot ,ptr ,slot ,lowtag)))
  39
  40 (defmacro storew (value ptr &optional (slot 0) (lowtag 0))
  41   (once-only ((value value))
  42     `(cond ((and (integerp ,value)
  43                  (not (typep ,value '(signed-byte 32))))
  44             (inst mov temp-reg-tn ,value)
  45             (inst mov (make-ea-for-object-slot ,ptr ,slot ,lowtag) temp-reg-tn))
  46            (t
  47             (inst mov (make-ea-for-object-slot ,ptr ,slot ,lowtag) ,value)))))
  48
  49 (defmacro pushw (ptr &optional (slot 0) (lowtag 0))
  50   `(inst push (make-ea-for-object-slot ,ptr ,slot ,lowtag)))
  51
  52 (defmacro popw (ptr &optional (slot 0) (lowtag 0))
  53   `(inst pop (make-ea-for-object-slot ,ptr ,slot ,lowtag)))
  54 \f
  55 ;;;; macros to generate useful values
  56
  57 (defmacro load-symbol (reg symbol)
  58   `(inst mov ,reg (+ nil-value (static-symbol-offset ,symbol))))
  59
  60 (defmacro make-ea-for-symbol-value (symbol)
  61   `(make-ea :qword
  62     :disp (+ nil-value
  63            (static-symbol-offset ',symbol)
  64            (ash symbol-value-slot word-shift)
  65            (- other-pointer-lowtag))))
  66
  67 (defmacro load-symbol-value (reg symbol)
  68   `(inst mov ,reg (make-ea-for-symbol-value ,symbol)))
  69
  70 (defmacro store-symbol-value (reg symbol)
  71   `(inst mov (make-ea-for-symbol-value ,symbol) ,reg))
  72
  73 #!+sb-thread
  74 (defmacro make-ea-for-symbol-tls-index (symbol)
  75   `(make-ea :qword
  76     :disp (+ nil-value
  77            (static-symbol-offset ',symbol)
  78            (ash symbol-tls-index-slot word-shift)
  79            (- other-pointer-lowtag))))
  80
  81 #!+sb-thread
  82 (defmacro load-tl-symbol-value (reg symbol)
  83   `(progn
  84     (inst mov ,reg (make-ea-for-symbol-tls-index ,symbol))
  85     (inst mov ,reg (make-ea :qword :base thread-base-tn :scale 1 :index ,reg))))
  86 #!-sb-thread
  87 (defmacro load-tl-symbol-value (reg symbol) `(load-symbol-value ,reg ,symbol))
  88
  89 #!+sb-thread
  90 (defmacro store-tl-symbol-value (reg symbol temp)
  91   `(progn
  92     (inst mov ,temp (make-ea-for-symbol-tls-index ,symbol))
  93     (inst mov (make-ea :qword :base thread-base-tn :scale 1 :index ,temp) ,reg)))
  94 #!-sb-thread
  95 (defmacro store-tl-symbol-value (reg symbol temp)
  96   (declare (ignore temp))
  97   `(store-symbol-value ,reg ,symbol))
  98
  99 (defmacro load-binding-stack-pointer (reg)
 100   #!+sb-thread
 101   `(inst mov ,reg (make-ea :qword :base thread-base-tn
 102                    :disp (* 8 thread-binding-stack-pointer-slot)))
 103   #!-sb-thread
 104   `(load-symbol-value ,reg *binding-stack-pointer*))
 105
 106 (defmacro store-binding-stack-pointer (reg)
 107   #!+sb-thread
 108   `(inst mov (make-ea :qword :base thread-base-tn
 109               :disp (* 8 thread-binding-stack-pointer-slot))
 110     ,reg)
 111   #!-sb-thread
 112   `(store-symbol-value ,reg *binding-stack-pointer*))
 113
 114 (defmacro load-type (target source &optional (offset 0))
 115   #!+sb-doc
 116   "Loads the type bits of a pointer into target independent of
 117    byte-ordering issues."
 118   (once-only ((n-target target)
 119               (n-source source)
 120               (n-offset offset))
 121     (ecase *backend-byte-order*
 122       (:little-endian
 123        `(inst mov ,n-target
 124               (make-ea :byte :base ,n-source :disp ,n-offset)))
 125       (:big-endian
 126        `(inst mov ,n-target
 127               (make-ea :byte :base ,n-source
 128                              :disp (+ ,n-offset (1- n-word-bytes))))))))
 129 \f
 130 ;;;; allocation helpers
 131
 132 ;;; All allocation is done by calls to assembler routines that
 133 ;;; eventually invoke the C alloc() function.
 134
 135 ;;; Emit code to allocate an object with a size in bytes given by
 136 ;;; Size. The size may be an integer of a TN. If Inline is a VOP
 137 ;;; node-var then it is used to make an appropriate speed vs size
 138 ;;; decision.
 139
 140 (defun allocation-dynamic-extent (alloc-tn size lowtag)
 141   (inst sub rsp-tn size)
 142   ;; see comment in x86/macros.lisp implementation of this
 143   (inst and rsp-tn #.(lognot lowtag-mask))
 144   (aver (not (location= alloc-tn rsp-tn)))
 145   (inst lea alloc-tn (make-ea :byte :base rsp-tn :disp lowtag))
 146   (values))
 147
 148 ;;; This macro should only be used inside a pseudo-atomic section,
 149 ;;; which should also cover subsequent initialization of the
 150 ;;; object.
 151 (defun allocation-tramp (alloc-tn size lowtag)
 152   (inst push size)
 153   (inst lea temp-reg-tn (make-ea :qword
 154                             :disp (make-fixup "alloc_tramp" :foreign)))
 155   (inst call temp-reg-tn)
 156   (inst pop alloc-tn)
 157   (when lowtag
 158     (inst lea alloc-tn (make-ea :byte :base alloc-tn :disp lowtag)))
 159   (values))
 160
 161 (defun allocation (alloc-tn size &optional ignored dynamic-extent lowtag)
 162   (declare (ignore ignored))
 163   (when dynamic-extent
 164     (allocation-dynamic-extent alloc-tn size lowtag)
 165     (return-from allocation (values)))
 166   (let ((NOT-INLINE (gen-label))
 167         (DONE (gen-label))
 168         ;; Yuck.
 169         (in-elsewhere (eq *elsewhere* sb!assem::**current-segment**))
 170         ;; thread->alloc_region.free_pointer
 171         (free-pointer
 172          #!+sb-thread
 173          (make-ea :qword
 174                   :base thread-base-tn :scale 1
 175                   :disp (* n-word-bytes thread-alloc-region-slot))
 176          #!-sb-thread
 177          (make-ea :qword
 178                   :scale 1 :disp
 179                   (make-fixup "boxed_region" :foreign)))
 180         ;; thread->alloc_region.end_addr
 181         (end-addr
 182          #!+sb-thread
 183          (make-ea :qword
 184                   :base thread-base-tn :scale 1
 185                   :disp (* n-word-bytes (1+ thread-alloc-region-slot)))
 186          #!-sb-thread
 187          (make-ea :qword
 188                   :scale 1 :disp
 189                   (make-fixup "boxed_region" :foreign 8))))
 190     (cond (in-elsewhere
 191            (allocation-tramp alloc-tn size lowtag))
 192           (t
 193            (inst mov temp-reg-tn free-pointer)
 194            (if (tn-p size)
 195                (if (location= alloc-tn size)
 196                    (inst add alloc-tn temp-reg-tn)
 197                    (inst lea alloc-tn
 198                          (make-ea :qword :base temp-reg-tn :index size)))
 199                (inst lea alloc-tn
 200                      (make-ea :qword :base temp-reg-tn :disp size)))
 201            (inst cmp end-addr alloc-tn)
 202            (inst jmp :be NOT-INLINE)
 203            (inst mov free-pointer alloc-tn)
 204            (if lowtag
 205                (inst lea alloc-tn (make-ea :byte :base temp-reg-tn :disp lowtag))
 206                (inst mov alloc-tn temp-reg-tn))
 207            (emit-label DONE)
 208            (assemble (*elsewhere*)
 209              (emit-label NOT-INLINE)
 210              (cond ((numberp size)
 211                     (allocation-tramp alloc-tn size lowtag))
 212                    (t
 213                     (inst sub alloc-tn free-pointer)
 214                     (allocation-tramp alloc-tn alloc-tn lowtag)))
 215              (inst jmp DONE))))
 216     (values)))
 217
 218 ;;; Allocate an other-pointer object of fixed SIZE with a single word
 219 ;;; header having the specified WIDETAG value. The result is placed in
 220 ;;; RESULT-TN.
 221 (defmacro with-fixed-allocation ((result-tn widetag size &optional inline stack-allocate-p)
 222                                  &body forms)
 223   (unless forms
 224     (bug "empty &body in WITH-FIXED-ALLOCATION"))
 225   (once-only ((result-tn result-tn) (size size) (stack-allocate-p stack-allocate-p))
 226     `(maybe-pseudo-atomic ,stack-allocate-p
 227       (allocation ,result-tn (pad-data-block ,size) ,inline ,stack-allocate-p
 228                   other-pointer-lowtag)
 229       (storew (logior (ash (1- ,size) n-widetag-bits) ,widetag)
 230               ,result-tn 0 other-pointer-lowtag)
 231       ,@forms)))
 232 \f
 233 ;;;; error code
 234 (defun emit-error-break (vop kind code values)
 235   (assemble ()
 236     #!-ud2-breakpoints
 237     (inst int 3)                  ; i386 breakpoint instruction
 238     ;; On Darwin, we need to use #x0b0f instead of int3 in order
 239     ;; to generate a SIGILL instead of a SIGTRAP as darwin/x86
 240     ;; doesn't seem to be reliably firing SIGTRAP
 241     ;; handlers. Hopefully this will be fixed by Apple at a
 242     ;; later date. Do the same on x86-64 as we do on x86 until this gets
 243     ;; sorted out.
 244     #!+ud2-breakpoints
 245     (inst word #x0b0f)
 246     ;; The return PC points here; note the location for the debugger.
 247     (when vop
 248       (note-this-location vop :internal-error))
 249     (inst byte kind)                       ; eg trap_Xyyy
 250     (with-adjustable-vector (vector)       ; interr arguments
 251       (write-var-integer code vector)
 252       (dolist (tn values)
 253         ;; classic CMU CL comment:
 254         ;;   zzzzz jrd here. tn-offset is zero for constant
 255         ;;   tns.
 256         (write-var-integer (make-sc-offset (sc-number (tn-sc tn))
 257                                            (or (tn-offset tn) 0))
 258                            vector))
 259       (inst byte (length vector))
 260       (dotimes (i (length vector))
 261         (inst byte (aref vector i))))))
 262
 263 (defun error-call (vop error-code &rest values)
 264   #!+sb-doc
 265   "Cause an error. ERROR-CODE is the error to cause."
 266   (emit-error-break vop error-trap (error-number-or-lose error-code) values))
 267
 268 (defun generate-error-code (vop error-code &rest values)
 269   #!+sb-doc
 270   "Generate-Error-Code Error-code Value*
 271   Emit code for an error with the specified Error-Code and context Values."
 272   (assemble (*elsewhere*)
 273     (let ((start-lab (gen-label)))
 274       (emit-label start-lab)
 275       (emit-error-break vop error-trap (error-number-or-lose error-code) values)
 276        start-lab)))
 277
 278 \f
 279 ;;;; PSEUDO-ATOMIC
 280
 281 ;;; This is used to wrap operations which leave untagged memory lying
 282 ;;; around.  It's an operation which the AOP weenies would describe as
 283 ;;; having "cross-cutting concerns", meaning it appears all over the
 284 ;;; place and there's no logical single place to attach documentation.
 285 ;;; grep (mostly in src/runtime) is your friend
 286
 287 (defmacro maybe-pseudo-atomic (not-really-p &body body)
 288   `(if ,not-really-p
 289        (progn ,@body)
 290        (pseudo-atomic ,@body)))
 291
 292 ;;; Unsafely clear pa flags so that the image can properly lose in a
 293 ;;; pa section.
 294 #!+sb-thread
 295 (defmacro %clear-pseudo-atomic ()
 296   '(inst mov (make-ea :qword :base thread-base-tn
 297               :disp (* 8 thread-pseudo-atomic-bits-slot))
 298     0))
 299
 300 #!+sb-thread
 301 (defmacro pseudo-atomic (&rest forms)
 302   (with-unique-names (label)
 303     `(let ((,label (gen-label)))
 304        (inst mov (make-ea :qword
 305                           :base thread-base-tn
 306                           :disp (* 8 thread-pseudo-atomic-bits-slot))
 307              rbp-tn)
 308        ,@forms
 309        (inst xor (make-ea :qword
 310                           :base thread-base-tn
 311                           :disp (* 8 thread-pseudo-atomic-bits-slot))
 312              rbp-tn)
 313        (inst jmp :z ,label)
 314        ;; if PAI was set, interrupts were disabled at the same time
 315        ;; using the process signal mask.
 316        (inst break pending-interrupt-trap)
 317        (emit-label ,label))))
 318
 319
 320 #!-sb-thread
 321 (defmacro pseudo-atomic (&rest forms)
 322   (with-unique-names (label)
 323     `(let ((,label (gen-label)))
 324        ;; FIXME: The MAKE-EA noise should become a MACROLET macro or
 325        ;; something. (perhaps SVLB, for static variable low byte)
 326        (inst mov (make-ea :qword :disp (+ nil-value
 327                                           (static-symbol-offset
 328                                            '*pseudo-atomic-bits*)
 329                                           (ash symbol-value-slot word-shift)
 330                                           (- other-pointer-lowtag)))
 331              rbp-tn)
 332        ,@forms
 333        (inst xor (make-ea :qword :disp (+ nil-value
 334                                           (static-symbol-offset
 335                                            '*pseudo-atomic-bits*)
 336                                           (ash symbol-value-slot word-shift)
 337                                           (- other-pointer-lowtag)))
 338              rbp-tn)
 339        (inst jmp :z ,label)
 340        ;; if PAI was set, interrupts were disabled at the same time
 341        ;; using the process signal mask.
 342        (inst break pending-interrupt-trap)
 343        (emit-label ,label))))
 344 \f
 345 ;;;; indexed references
 346
 347 (defmacro define-full-compare-and-swap
 348     (name type offset lowtag scs el-type &optional translate)
 349   `(progn
 350      (define-vop (,name)
 351          ,@(when translate `((:translate ,translate)))
 352        (:policy :fast-safe)
 353        (:args (object :scs (descriptor-reg) :to :eval)
 354               (index :scs (any-reg) :to :result)
 355               (old-value :scs ,scs :target rax)
 356               (new-value :scs ,scs))
 357        (:arg-types ,type tagged-num ,el-type ,el-type)
 358        (:temporary (:sc descriptor-reg :offset rax-offset
 359                         :from (:argument 2) :to :result :target value)  rax)
 360        (:results (value :scs ,scs))
 361        (:result-types ,el-type)
 362        (:generator 5
 363          (move rax old-value)
 364          (inst cmpxchg (make-ea :qword :base object :index index
 365                                 :disp (- (* ,offset n-word-bytes) ,lowtag))
 366                new-value :lock)
 367          (move value rax)))))
 368
 369 (defmacro define-full-reffer (name type offset lowtag scs el-type &optional translate)
 370   `(progn
 371      (define-vop (,name)
 372        ,@(when translate
 373            `((:translate ,translate)))
 374        (:policy :fast-safe)
 375        (:args (object :scs (descriptor-reg))
 376               (index :scs (any-reg)))
 377        (:arg-types ,type tagged-num)
 378        (:results (value :scs ,scs))
 379        (:result-types ,el-type)
 380        (:generator 3                    ; pw was 5
 381          (inst mov value (make-ea :qword :base object :index index
 382                                   :disp (- (* ,offset n-word-bytes)
 383                                            ,lowtag)))))
 384      (define-vop (,(symbolicate name "-C"))
 385        ,@(when translate
 386            `((:translate ,translate)))
 387        (:policy :fast-safe)
 388        (:args (object :scs (descriptor-reg)))
 389        (:info index)
 390        (:arg-types ,type
 391                    (:constant (load/store-index ,n-word-bytes ,(eval lowtag)
 392                                                 ,(eval offset))))
 393        (:results (value :scs ,scs))
 394        (:result-types ,el-type)
 395        (:generator 2                    ; pw was 5
 396          (inst mov value (make-ea :qword :base object
 397                                   :disp (- (* (+ ,offset index) n-word-bytes)
 398                                            ,lowtag)))))))
 399
 400 (defmacro define-full-reffer+offset (name type offset lowtag scs el-type &optional translate)
 401   `(progn
 402      (define-vop (,name)
 403        ,@(when translate
 404            `((:translate ,translate)))
 405        (:policy :fast-safe)
 406        (:args (object :scs (descriptor-reg))
 407               (index :scs (any-reg)))
 408        (:info offset)
 409        (:arg-types ,type tagged-num
 410                    (:constant (constant-displacement other-pointer-lowtag
 411                                                      n-word-bytes vector-data-offset)))
 412        (:results (value :scs ,scs))
 413        (:result-types ,el-type)
 414        (:generator 3                    ; pw was 5
 415          (inst mov value (make-ea :qword :base object :index index
 416                                   :disp (- (* (+ ,offset offset) n-word-bytes)
 417                                            ,lowtag)))))
 418      (define-vop (,(symbolicate name "-C"))
 419        ,@(when translate
 420            `((:translate ,translate)))
 421        (:policy :fast-safe)
 422        (:args (object :scs (descriptor-reg)))
 423        (:info index offset)
 424        (:arg-types ,type
 425                    (:constant (load/store-index ,n-word-bytes ,(eval lowtag)
 426                                                 ,(eval offset)))
 427                    (:constant (constant-displacement other-pointer-lowtag
 428                                                      n-word-bytes vector-data-offset)))
 429        (:results (value :scs ,scs))
 430        (:result-types ,el-type)
 431        (:generator 2                    ; pw was 5
 432          (inst mov value (make-ea :qword :base object
 433                                   :disp (- (* (+ ,offset index offset) n-word-bytes)
 434                                            ,lowtag)))))))
 435
 436 (defmacro define-full-setter (name type offset lowtag scs el-type &optional translate)
 437   `(progn
 438      (define-vop (,name)
 439        ,@(when translate
 440            `((:translate ,translate)))
 441        (:policy :fast-safe)
 442        (:args (object :scs (descriptor-reg))
 443               (index :scs (any-reg))
 444               (value :scs ,scs :target result))
 445        (:arg-types ,type tagged-num ,el-type)
 446        (:results (result :scs ,scs))
 447        (:result-types ,el-type)
 448        (:generator 4                    ; was 5
 449          (inst mov (make-ea :qword :base object :index index
 450                             :disp (- (* ,offset n-word-bytes) ,lowtag))
 451                value)
 452          (move result value)))
 453      (define-vop (,(symbolicate name "-C"))
 454        ,@(when translate
 455            `((:translate ,translate)))
 456        (:policy :fast-safe)
 457        (:args (object :scs (descriptor-reg))
 458               (value :scs ,scs :target result))
 459        (:info index)
 460        (:arg-types ,type
 461                    (:constant (load/store-index ,n-word-bytes ,(eval lowtag)
 462                                                 ,(eval offset)))
 463                    ,el-type)
 464        (:results (result :scs ,scs))
 465        (:result-types ,el-type)
 466        (:generator 3                    ; was 5
 467          (inst mov (make-ea :qword :base object
 468                             :disp (- (* (+ ,offset index) n-word-bytes)
 469                                      ,lowtag))
 470                value)
 471          (move result value)))))
 472
 473 (defmacro define-full-setter+offset (name type offset lowtag scs el-type &optional translate)
 474   `(progn
 475      (define-vop (,name)
 476        ,@(when translate
 477            `((:translate ,translate)))
 478        (:policy :fast-safe)
 479        (:args (object :scs (descriptor-reg))
 480               (index :scs (any-reg))
 481               (value :scs ,scs :target result))
 482        (:info offset)
 483        (:arg-types ,type tagged-num
 484                    (:constant (constant-displacement other-pointer-lowtag
 485                                                      n-word-bytes
 486                                                      vector-data-offset))
 487                    ,el-type)
 488        (:results (result :scs ,scs))
 489        (:result-types ,el-type)
 490        (:generator 4                    ; was 5
 491          (inst mov (make-ea :qword :base object :index index
 492                             :disp (- (* (+ ,offset offset) n-word-bytes) ,lowtag))
 493                value)
 494          (move result value)))
 495      (define-vop (,(symbolicate name "-C"))
 496        ,@(when translate
 497            `((:translate ,translate)))
 498        (:policy :fast-safe)
 499        (:args (object :scs (descriptor-reg))
 500               (value :scs ,scs :target result))
 501        (:info index offset)
 502        (:arg-types ,type
 503                    (:constant (load/store-index ,n-word-bytes ,(eval lowtag)
 504                                                 ,(eval offset)))
 505                    (:constant (constant-displacement other-pointer-lowtag
 506                                                      n-word-bytes
 507                                                      vector-data-offset))
 508                    ,el-type)
 509        (:results (result :scs ,scs))
 510        (:result-types ,el-type)
 511        (:generator 3                    ; was 5
 512          (inst mov (make-ea :qword :base object
 513                             :disp (- (* (+ ,offset index offset) n-word-bytes)
 514                                      ,lowtag))
 515                value)
 516          (move result value)))))
 517
 518 ;;; helper for alien stuff.
 519
 520 (def!macro with-pinned-objects ((&rest objects) &body body)
 521   "Arrange with the garbage collector that the pages occupied by
 522 OBJECTS will not be moved in memory for the duration of BODY.
 523 Useful for e.g. foreign calls where another thread may trigger
 524 collection."
 525   (if objects
 526       (let ((pins (make-gensym-list (length objects)))
 527             (wpo (block-gensym "WPO")))
 528         ;; BODY is stuffed in a function to preserve the lexical
 529         ;; environment.
 530         `(flet ((,wpo () (progn ,@body)))
 531            (declare (muffle-conditions compiler-note))
 532            ;; PINS are dx-allocated in case the compiler for some
 533            ;; unfathomable reason decides to allocate value-cells
 534            ;; for them -- since we have DX value-cells on x86oid
 535            ;; platforms this still forces them on the stack.
 536            (dx-let ,(mapcar #'list pins objects)
 537              (multiple-value-prog1 (,wpo)
 538                ;; TOUCH-OBJECT has a VOP with an empty body: compiler
 539                ;; thinks we're using the argument and doesn't flush
 540                ;; the variable, but we don't have to pay any extra
 541                ;; beyond that -- and MULTIPLE-VALUE-PROG1 keeps them
 542                ;; live till the body has finished. *whew*
 543                ,@(mapcar (lambda (pin)
 544                            `(touch-object ,pin))
 545                          pins)))))
 546       `(progn ,@body)))