src/compiler/x86-64/macros.lisp

   1 ;;;; a bunch of handy macros for the x86
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!VM")
  13
  14 ;;;; instruction-like macros
  15
  16 (defmacro move (dst src)
  17   #!+sb-doc
  18   "Move SRC into DST unless they are location=."
  19   (once-only ((n-dst dst)
  20               (n-src src))
  21     `(unless (location= ,n-dst ,n-src)
  22        (inst mov ,n-dst ,n-src))))
  23
  24 (defmacro make-ea-for-object-slot (ptr slot lowtag)
  25   `(make-ea :qword :base ,ptr :disp (- (* ,slot n-word-bytes) ,lowtag)))
  26 (defmacro make-ea-for-object-slot-half (ptr slot lowtag)
  27   `(make-ea :dword :base ,ptr :disp (- (* ,slot n-word-bytes) ,lowtag)))
  28
  29 (defmacro loadw (value ptr &optional (slot 0) (lowtag 0))
  30   `(inst mov ,value (make-ea-for-object-slot ,ptr ,slot ,lowtag)))
  31
  32 (defmacro storew (value ptr &optional (slot 0) (lowtag 0))
  33   (once-only ((value value))
  34     `(cond ((and (integerp ,value)
  35                  (not (typep ,value '(signed-byte 32))))
  36             (multiple-value-bind (lo hi) (dwords-for-quad ,value)
  37               (inst mov (make-ea-for-object-slot-half
  38                          ,ptr ,slot ,lowtag) lo)
  39               (inst mov (make-ea-for-object-slot-half
  40                          ,ptr (+ ,slot 1/2) ,lowtag) hi)))
  41            (t
  42             (inst mov (make-ea-for-object-slot ,ptr ,slot ,lowtag) ,value)))))
  43
  44 (defmacro pushw (ptr &optional (slot 0) (lowtag 0))
  45   `(inst push (make-ea-for-object-slot ,ptr ,slot ,lowtag)))
  46
  47 (defmacro popw (ptr &optional (slot 0) (lowtag 0))
  48   `(inst pop (make-ea-for-object-slot ,ptr ,slot ,lowtag)))
  49 \f
  50 ;;;; macros to generate useful values
  51
  52 (defmacro load-symbol (reg symbol)
  53   `(inst mov ,reg (+ nil-value (static-symbol-offset ,symbol))))
  54
  55 (defmacro make-ea-for-symbol-value (symbol)
  56   `(make-ea :qword
  57     :disp (+ nil-value
  58            (static-symbol-offset ',symbol)
  59            (ash symbol-value-slot word-shift)
  60            (- other-pointer-lowtag))))
  61
  62 (defmacro load-symbol-value (reg symbol)
  63   `(inst mov ,reg (make-ea-for-symbol-value ,symbol)))
  64
  65 (defmacro store-symbol-value (reg symbol)
  66   `(inst mov (make-ea-for-symbol-value ,symbol) ,reg))
  67
  68 #!+sb-thread
  69 (defmacro make-ea-for-symbol-tls-index (symbol)
  70   `(make-ea :qword
  71     :disp (+ nil-value
  72            (static-symbol-offset ',symbol)
  73            (ash symbol-tls-index-slot word-shift)
  74            (- other-pointer-lowtag))))
  75
  76 #!+sb-thread
  77 (defmacro load-tl-symbol-value (reg symbol)
  78   `(progn
  79     (inst mov ,reg (make-ea-for-symbol-tls-index ,symbol))
  80     (inst mov ,reg (make-ea :qword :base thread-base-tn :scale 1 :index ,reg))))
  81 #!-sb-thread
  82 (defmacro load-tl-symbol-value (reg symbol) `(load-symbol-value ,reg ,symbol))
  83
  84 #!+sb-thread
  85 (defmacro store-tl-symbol-value (reg symbol temp)
  86   `(progn
  87     (inst mov ,temp (make-ea-for-symbol-tls-index ,symbol))
  88     (inst mov (make-ea :qword :base thread-base-tn :scale 1 :index ,temp) ,reg)))
  89 #!-sb-thread
  90 (defmacro store-tl-symbol-value (reg symbol temp)
  91   (declare (ignore temp))
  92   `(store-symbol-value ,reg ,symbol))
  93
  94 (defmacro load-type (target source &optional (offset 0))
  95   #!+sb-doc
  96   "Loads the type bits of a pointer into target independent of
  97    byte-ordering issues."
  98   (once-only ((n-target target)
  99               (n-source source)
 100               (n-offset offset))
 101     (ecase *backend-byte-order*
 102       (:little-endian
 103        `(inst mov ,n-target
 104               (make-ea :byte :base ,n-source :disp ,n-offset)))
 105       (:big-endian
 106        `(inst mov ,n-target
 107               (make-ea :byte :base ,n-source :disp (+ ,n-offset 4)))))))
 108 \f
 109 ;;;; allocation helpers
 110
 111 ;;; All allocation is done by calls to assembler routines that
 112 ;;; eventually invoke the C alloc() function.
 113
 114 ;;; Emit code to allocate an object with a size in bytes given by
 115 ;;; Size. The size may be an integer of a TN. If Inline is a VOP
 116 ;;; node-var then it is used to make an appropriate speed vs size
 117 ;;; decision.
 118
 119 (defun allocation-dynamic-extent (alloc-tn size)
 120   (inst sub rsp-tn size)
 121   ;; see comment in x86/macros.lisp implementation of this
 122   (inst and rsp-tn #.(lognot lowtag-mask))
 123   (aver (not (location= alloc-tn rsp-tn)))
 124   (inst mov alloc-tn rsp-tn)
 125   (values))
 126
 127 ;;; This macro should only be used inside a pseudo-atomic section,
 128 ;;; which should also cover subsequent initialization of the
 129 ;;; object.
 130 (defun allocation-tramp (alloc-tn size &optional ignored)
 131   (declare (ignore ignored))
 132   (inst push size)
 133   (inst lea temp-reg-tn (make-ea :qword
 134                             :disp (make-fixup "alloc_tramp" :foreign)))
 135   (inst call temp-reg-tn)
 136   (inst pop alloc-tn)
 137   (values))
 138
 139 (defun allocation (alloc-tn size &optional ignored dynamic-extent)
 140   (declare (ignore ignored))
 141   (when dynamic-extent
 142     (allocation-dynamic-extent alloc-tn size)
 143     (return-from allocation (values)))
 144   (let ((NOT-INLINE (gen-label))
 145         (DONE (gen-label))
 146         ;; Yuck.
 147         (in-elsewhere (eq *elsewhere* sb!assem::**current-segment**))
 148         ;; thread->alloc_region.free_pointer
 149         (free-pointer
 150          #!+sb-thread
 151          (make-ea :qword
 152                   :base thread-base-tn :scale 1
 153                   :disp (* n-word-bytes thread-alloc-region-slot))
 154          #!-sb-thread
 155          (make-ea :qword
 156                   :scale 1 :disp
 157                   (make-fixup (extern-alien-name "boxed_region") :foreign)))
 158         ;; thread->alloc_region.end_addr
 159         (end-addr
 160          #!+sb-thread
 161          (make-ea :qword
 162                   :base thread-base-tn :scale 1
 163                   :disp (* n-word-bytes (1+ thread-alloc-region-slot)))
 164          #!-sb-thread
 165          (make-ea :qword
 166                   :scale 1 :disp
 167                   (make-fixup (extern-alien-name "boxed_region") :foreign 8))))
 168     (cond (in-elsewhere
 169            (allocation-tramp alloc-tn size))
 170           (t
 171            (inst mov temp-reg-tn free-pointer)
 172            (if (tn-p size)
 173                (if (location= alloc-tn size)
 174                    (inst add alloc-tn temp-reg-tn)
 175                    (inst lea alloc-tn
 176                          (make-ea :qword :base temp-reg-tn :index size)))
 177                (inst lea alloc-tn
 178                      (make-ea :qword :base temp-reg-tn :disp size)))
 179            (inst cmp end-addr alloc-tn)
 180            (inst jmp :be NOT-INLINE)
 181            (inst mov free-pointer alloc-tn)
 182            (inst mov alloc-tn temp-reg-tn)
 183            (emit-label DONE)
 184            (assemble (*elsewhere*)
 185              (emit-label NOT-INLINE)
 186              (cond ((numberp size)
 187                     (allocation-tramp alloc-tn size))
 188                    (t
 189                     (inst sub alloc-tn free-pointer)
 190                     (allocation-tramp alloc-tn alloc-tn)))
 191              (inst jmp DONE))
 192            (values)))))
 193
 194 #+nil
 195 (defun allocation (alloc-tn size &optional ignored)
 196   (declare (ignore ignored))
 197   (inst push size)
 198   (inst lea temp-reg-tn (make-ea :qword
 199                             :disp (make-fixup "alloc_tramp" :foreign)))
 200   (inst call temp-reg-tn)
 201   (inst pop alloc-tn)
 202   (values))
 203
 204 ;;; Allocate an other-pointer object of fixed SIZE with a single word
 205 ;;; header having the specified WIDETAG value. The result is placed in
 206 ;;; RESULT-TN.
 207 (defmacro with-fixed-allocation ((result-tn widetag size &optional inline)
 208                                  &body forms)
 209   (unless forms
 210     (bug "empty &body in WITH-FIXED-ALLOCATION"))
 211   (once-only ((result-tn result-tn) (size size))
 212     `(pseudo-atomic
 213       (allocation ,result-tn (pad-data-block ,size) ,inline)
 214       (storew (logior (ash (1- ,size) n-widetag-bits) ,widetag)
 215               ,result-tn)
 216       (inst lea ,result-tn
 217             (make-ea :qword :base ,result-tn :disp other-pointer-lowtag))
 218       ,@forms)))
 219 \f
 220 ;;;; error code
 221 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
 222   (defun emit-error-break (vop kind code values)
 223     (let ((vector (gensym)))
 224       `((inst int 3)                            ; i386 breakpoint instruction
 225         ;; The return PC points here; note the location for the debugger.
 226         (let ((vop ,vop))
 227           (when vop
 228                 (note-this-location vop :internal-error)))
 229         (inst byte ,kind)                       ; eg trap_Xyyy
 230         (with-adjustable-vector (,vector)       ; interr arguments
 231           (write-var-integer (error-number-or-lose ',code) ,vector)
 232           ,@(mapcar (lambda (tn)
 233                       `(let ((tn ,tn))
 234                          ;; classic CMU CL comment:
 235                          ;;   zzzzz jrd here. tn-offset is zero for constant
 236                          ;;   tns.
 237                          (write-var-integer (make-sc-offset (sc-number
 238                                                              (tn-sc tn))
 239                                                             (or (tn-offset tn)
 240                                                                 0))
 241                                             ,vector)))
 242                     values)
 243           (inst byte (length ,vector))
 244           (dotimes (i (length ,vector))
 245             (inst byte (aref ,vector i))))))))
 246
 247 (defmacro error-call (vop error-code &rest values)
 248   #!+sb-doc
 249   "Cause an error. ERROR-CODE is the error to cause."
 250   (cons 'progn
 251         (emit-error-break vop error-trap error-code values)))
 252
 253 (defmacro generate-error-code (vop error-code &rest values)
 254   #!+sb-doc
 255   "Generate-Error-Code Error-code Value*
 256   Emit code for an error with the specified Error-Code and context Values."
 257   `(assemble (*elsewhere*)
 258      (let ((start-lab (gen-label)))
 259        (emit-label start-lab)
 260        (error-call ,vop ,error-code ,@values)
 261        start-lab)))
 262
 263 \f
 264 ;;;; PSEUDO-ATOMIC
 265
 266 ;;; This is used to wrap operations which leave untagged memory lying
 267 ;;; around.  It's an operation which the AOP weenies would describe as
 268 ;;; having "cross-cutting concerns", meaning it appears all over the
 269 ;;; place and there's no logical single place to attach documentation.
 270 ;;; grep (mostly in src/runtime) is your friend
 271
 272 ;;; FIXME: *PSEUDO-ATOMIC-FOO* could be made into *PSEUDO-ATOMIC-BITS*,
 273 ;;; set with a single operation and cleared with SHR *PSEUDO-ATOMIC-BITS*,-2;
 274 ;;; the ATOMIC bit is bit 0, the INTERRUPTED bit is bit 1, and you check
 275 ;;; the C flag after the shift to see whether you were interrupted.
 276
 277 ;;; FIXME: THIS NAME IS BACKWARDS!
 278 (defmacro maybe-pseudo-atomic (really-p &body body)
 279   `(if ,really-p
 280        (progn ,@body)
 281        (pseudo-atomic ,@body)))
 282
 283 #!+sb-thread
 284 (defmacro pseudo-atomic (&rest forms)
 285   (with-unique-names (label)
 286     `(let ((,label (gen-label)))
 287       (inst mov (make-ea :byte
 288                  :base thread-base-tn
 289                  :disp (* 8 thread-pseudo-atomic-atomic-slot))
 290             (fixnumize 1))
 291       ,@forms
 292       (inst mov (make-ea :byte
 293                  :base thread-base-tn
 294                  :disp (* 8 thread-pseudo-atomic-atomic-slot)) 0)
 295       (inst cmp (make-ea :byte
 296                  :base thread-base-tn
 297                  :disp (* 8 thread-pseudo-atomic-interrupted-slot)) 0)
 298       (inst jmp :eq ,label)
 299       ;; if PAI was set, interrupts were disabled at the same
 300       ;; time using the process signal mask.
 301       (inst break pending-interrupt-trap)
 302       (emit-label ,label))))
 303
 304
 305 #!-sb-thread
 306 (defmacro pseudo-atomic (&rest forms)
 307   (with-unique-names (label)
 308     `(let ((,label (gen-label)))
 309       ;; FIXME: The MAKE-EA noise should become a MACROLET macro or
 310       ;; something. (perhaps SVLB, for static variable low byte)
 311       (inst mov (make-ea :byte :disp (+ nil-value
 312                                         (static-symbol-offset
 313                                          '*pseudo-atomic-atomic*)
 314                                         (ash symbol-value-slot word-shift)
 315                                         (- other-pointer-lowtag)))
 316        (fixnumize 1))
 317       ,@forms
 318       (inst mov (make-ea :byte :disp (+ nil-value
 319                                         (static-symbol-offset
 320                                          '*pseudo-atomic-atomic*)
 321                                         (ash symbol-value-slot word-shift)
 322                                         (- other-pointer-lowtag)))
 323        0)
 324       (inst cmp (make-ea :byte
 325                  :disp (+ nil-value
 326                           (static-symbol-offset
 327                            '*pseudo-atomic-interrupted*)
 328                           (ash symbol-value-slot word-shift)
 329                           (- other-pointer-lowtag)))
 330        0)
 331       (inst jmp :eq ,label)
 332       ;; if PAI was set, interrupts were disabled at the same time
 333       ;; using the process signal mask.
 334       (inst break pending-interrupt-trap)
 335       (emit-label ,label))))
 336
 337
 338 \f
 339 ;;;; indexed references
 340
 341 (defmacro define-full-reffer (name type offset lowtag scs el-type &optional translate)
 342   `(progn
 343      (define-vop (,name)
 344        ,@(when translate
 345            `((:translate ,translate)))
 346        (:policy :fast-safe)
 347        (:args (object :scs (descriptor-reg))
 348               (index :scs (any-reg)))
 349        (:arg-types ,type tagged-num)
 350        (:results (value :scs ,scs))
 351        (:result-types ,el-type)
 352        (:generator 3                    ; pw was 5
 353          (inst mov value (make-ea :qword :base object :index index
 354                                   :disp (- (* ,offset n-word-bytes)
 355                                            ,lowtag)))))
 356      (define-vop (,(symbolicate name "-C"))
 357        ,@(when translate
 358            `((:translate ,translate)))
 359        (:policy :fast-safe)
 360        (:args (object :scs (descriptor-reg)))
 361        (:info index)
 362        (:arg-types ,type
 363                    (:constant (load/store-index ,n-word-bytes ,(eval lowtag)
 364                                                 ,(eval offset))))
 365        (:results (value :scs ,scs))
 366        (:result-types ,el-type)
 367        (:generator 2                    ; pw was 5
 368          (inst mov value (make-ea :qword :base object
 369                                   :disp (- (* (+ ,offset index) n-word-bytes)
 370                                            ,lowtag)))))))
 371
 372 (defmacro define-full-setter (name type offset lowtag scs el-type &optional translate)
 373   `(progn
 374      (define-vop (,name)
 375        ,@(when translate
 376            `((:translate ,translate)))
 377        (:policy :fast-safe)
 378        (:args (object :scs (descriptor-reg))
 379               (index :scs (any-reg))
 380               (value :scs ,scs :target result))
 381        (:arg-types ,type tagged-num ,el-type)
 382        (:results (result :scs ,scs))
 383        (:result-types ,el-type)
 384        (:generator 4                    ; was 5
 385          (inst mov (make-ea :qword :base object :index index
 386                             :disp (- (* ,offset n-word-bytes) ,lowtag))
 387                value)
 388          (move result value)))
 389      (define-vop (,(symbolicate name "-C"))
 390        ,@(when translate
 391            `((:translate ,translate)))
 392        (:policy :fast-safe)
 393        (:args (object :scs (descriptor-reg))
 394               (value :scs ,scs :target result))
 395        (:info index)
 396        (:arg-types ,type
 397                    (:constant (load/store-index ,n-word-bytes ,(eval lowtag)
 398                                                 ,(eval offset)))
 399                    ,el-type)
 400        (:results (result :scs ,scs))
 401        (:result-types ,el-type)
 402        (:generator 3                    ; was 5
 403          (inst mov (make-ea :qword :base object
 404                             :disp (- (* (+ ,offset index) n-word-bytes)
 405                                      ,lowtag))
 406                value)
 407          (move result value)))))
 408
 409 ;;; helper for alien stuff.
 410 (defmacro with-pinned-objects ((&rest objects) &body body)
 411   "Arrange with the garbage collector that the pages occupied by
 412 OBJECTS will not be moved in memory for the duration of BODY.
 413 Useful for e.g. foreign calls where another thread may trigger
 414 garbage collection"
 415   `(multiple-value-prog1
 416        (progn
 417          ,@(loop for p in objects
 418                  collect `(push-word-on-c-stack
 419                            (int-sap (sb!kernel:get-lisp-obj-address ,p))))
 420          ,@body)
 421      ;; If the body returned normally, we should restore the stack pointer
 422      ;; for the benefit of any following code in the same function.  If
 423      ;; there's a non-local exit in the body, sp is garbage anyway and
 424      ;; will get set appropriately from {a, the} frame pointer before it's
 425      ;; next needed
 426      (pop-words-from-c-stack ,(length objects))))