src/compiler/x86-64/move.lisp

   1 ;;;; the x86-64 VM definition of operand loading/saving and the MOVE vop
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!VM")
  13
  14 (defun make-byte-tn (tn)
  15   (aver (sc-is tn any-reg descriptor-reg unsigned-reg signed-reg))
  16   (make-random-tn :kind :normal
  17                   :sc (sc-or-lose 'byte-reg)
  18                   :offset (tn-offset tn)))
  19
  20 (defun make-dword-tn (tn)
  21   (aver (sc-is tn any-reg descriptor-reg character-reg
  22                unsigned-reg signed-reg))
  23   (make-random-tn :kind :normal
  24                   :sc (sc-or-lose 'dword-reg)
  25                   :offset (tn-offset tn)))
  26
  27 (defun zeroize (tn)
  28   (let ((offset (tn-offset tn)))
  29     ;; Using the 32-bit instruction accomplishes the same thing and is
  30     ;; one byte shorter.
  31     (if (<= offset edi-offset)
  32         (let ((tn (make-random-tn :kind :normal
  33                                   :sc (sc-or-lose 'dword-reg)
  34                                   :offset offset)))
  35           (inst xor tn tn))
  36         (inst xor tn tn))))
  37
  38 (define-move-fun (load-immediate 1) (vop x y)
  39   ((immediate)
  40    (any-reg descriptor-reg))
  41   (let ((val (tn-value x)))
  42     (etypecase val
  43       (integer
  44        (if (zerop val)
  45            (zeroize y)
  46          (inst mov y (fixnumize val))))
  47       (symbol
  48        (load-symbol y val))
  49       (character
  50        (inst mov y (logior (ash (char-code val) n-widetag-bits)
  51                            character-widetag))))))
  52
  53 (define-move-fun (load-number 1) (vop x y)
  54   ((immediate) (signed-reg unsigned-reg))
  55   (let ((val (tn-value x)))
  56     (if (zerop val)
  57         (zeroize y)
  58         (inst mov y val))))
  59
  60 (define-move-fun (load-character 1) (vop x y)
  61   ((immediate) (character-reg))
  62   (inst mov y (char-code (tn-value x))))
  63
  64 (define-move-fun (load-system-area-pointer 1) (vop x y)
  65   ((immediate) (sap-reg))
  66   (inst mov y (sap-int (tn-value x))))
  67
  68 (define-move-fun (load-constant 5) (vop x y)
  69   ((constant) (descriptor-reg any-reg))
  70   (inst mov y x))
  71
  72 (define-move-fun (load-stack 5) (vop x y)
  73   ((control-stack) (any-reg descriptor-reg)
  74    (character-stack) (character-reg)
  75    (sap-stack) (sap-reg)
  76    (signed-stack) (signed-reg)
  77    (unsigned-stack) (unsigned-reg))
  78   (inst mov y x))
  79
  80 (define-move-fun (store-stack 5) (vop x y)
  81   ((any-reg descriptor-reg) (control-stack)
  82    (character-reg) (character-stack)
  83    (sap-reg) (sap-stack)
  84    (signed-reg) (signed-stack)
  85    (unsigned-reg) (unsigned-stack))
  86   (inst mov y x))
  87 \f
  88 ;;;; the MOVE VOP
  89 (define-vop (move)
  90   (:args (x :scs (any-reg descriptor-reg immediate) :target y
  91             :load-if (not (location= x y))))
  92   (:results (y :scs (any-reg descriptor-reg)
  93                :load-if
  94                (not (or (location= x y)
  95                         (and (sc-is x any-reg descriptor-reg immediate)
  96                              (sc-is y control-stack))))))
  97   (:temporary (:sc unsigned-reg) temp)
  98   (:effects)
  99   (:affected)
 100   (:generator 0
 101     (if (and (sc-is x immediate)
 102              (sc-is y any-reg descriptor-reg control-stack))
 103         (let ((val (tn-value x)))
 104           (etypecase val
 105             (integer
 106              (if (and (zerop val) (sc-is y any-reg descriptor-reg))
 107                  (zeroize y)
 108                  (move-immediate y (fixnumize val) temp)))
 109             (symbol
 110              (inst mov y (+ nil-value (static-symbol-offset val))))
 111             (character
 112              (inst mov y (logior (ash (char-code val) n-widetag-bits)
 113                                  character-widetag)))))
 114         (move y x))))
 115
 116 (define-move-vop move :move
 117   (any-reg descriptor-reg immediate)
 118   (any-reg descriptor-reg))
 119
 120 ;;; Make MOVE the check VOP for T so that type check generation
 121 ;;; doesn't think it is a hairy type. This also allows checking of a
 122 ;;; few of the values in a continuation to fall out.
 123 (primitive-type-vop move (:check) t)
 124
 125 (defun move-immediate (target val &optional tmp-tn)
 126   (cond
 127     ;; If target is a register, we can just mov it there directly
 128     ((and (tn-p target)
 129           (sc-is target signed-reg unsigned-reg descriptor-reg any-reg))
 130      (inst mov target val))
 131     ;; Likewise if the value is small enough.
 132     ((typep val '(signed-byte 31))
 133      (inst mov target val))
 134     ;; Otherwise go through the temporary register
 135     (tmp-tn
 136      (inst mov tmp-tn val)
 137      (inst mov target tmp-tn))
 138     (t
 139      (error "~A is not a register, no temporary given, and immediate ~A too large" target val))))
 140
 141 ;;; The MOVE-ARG VOP is used for moving descriptor values into
 142 ;;; another frame for argument or known value passing.
 143 ;;;
 144 ;;; Note: It is not going to be possible to move a constant directly
 145 ;;; to another frame, except if the destination is a register and in
 146 ;;; this case the loading works out.
 147 (define-vop (move-arg)
 148   (:args (x :scs (any-reg descriptor-reg immediate) :target y
 149             :load-if (not (and (sc-is y any-reg descriptor-reg)
 150                                (sc-is x control-stack))))
 151          (fp :scs (any-reg)
 152              :load-if (not (sc-is y any-reg descriptor-reg))))
 153   (:results (y))
 154   (:generator 0
 155     (sc-case y
 156       ((any-reg descriptor-reg)
 157        (if (sc-is x immediate)
 158            (let ((val (tn-value x)))
 159              (etypecase val
 160                ((integer 0 0)
 161                 (zeroize y))
 162                ((or (signed-byte 29) (unsigned-byte 29))
 163                 (inst mov y (fixnumize val)))
 164                (integer
 165                 (move-immediate y (fixnumize val)))
 166                (symbol
 167                 (load-symbol y val))
 168                (character
 169                 (inst mov y (logior (ash (char-code val) n-widetag-bits)
 170                                     character-widetag)))))
 171            (move y x)))
 172       ((control-stack)
 173        (if (sc-is x immediate)
 174            (let ((val (tn-value x)))
 175              (if (= (tn-offset fp) esp-offset)
 176                  ;; C-call
 177                  (etypecase val
 178                    (integer
 179                     (storew (fixnumize val) fp (tn-offset y)))
 180                    (symbol
 181                     (storew (+ nil-value (static-symbol-offset val))
 182                             fp (tn-offset y)))
 183                    (character
 184                     (storew (logior (ash (char-code val) n-widetag-bits)
 185                                     character-widetag)
 186                             fp (tn-offset y))))
 187                ;; Lisp stack
 188                (etypecase val
 189                  (integer
 190                   (storew (fixnumize val) fp (frame-word-offset (tn-offset y))))
 191                  (symbol
 192                   (storew (+ nil-value (static-symbol-offset val))
 193                           fp (frame-word-offset (tn-offset y))))
 194                  (character
 195                   (storew (logior (ash (char-code val) n-widetag-bits)
 196                                   character-widetag)
 197                           fp (frame-word-offset (tn-offset y)))))))
 198          (if (= (tn-offset fp) esp-offset)
 199              ;; C-call
 200              (storew x fp (tn-offset y))
 201            ;; Lisp stack
 202            (storew x fp (frame-word-offset (tn-offset y)))))))))
 203
 204 (define-move-vop move-arg :move-arg
 205   (any-reg descriptor-reg)
 206   (any-reg descriptor-reg))
 207 \f
 208 ;;;; ILLEGAL-MOVE
 209
 210 ;;; This VOP exists just to begin the lifetime of a TN that couldn't
 211 ;;; be written legally due to a type error. An error is signalled
 212 ;;; before this VOP is so we don't need to do anything (not that there
 213 ;;; would be anything sensible to do anyway.)
 214 (define-vop (illegal-move)
 215   (:args (x) (type))
 216   (:results (y))
 217   (:ignore y)
 218   (:vop-var vop)
 219   (:save-p :compute-only)
 220   (:generator 666
 221     (error-call vop 'object-not-type-error x type)))
 222 \f
 223 ;;;; moves and coercions
 224
 225 ;;; These MOVE-TO-WORD VOPs move a tagged integer to a raw full-word
 226 ;;; representation. Similarly, the MOVE-FROM-WORD VOPs converts a raw
 227 ;;; integer to a tagged bignum or fixnum.
 228
 229 ;;; Arg is a fixnum, so just shift it. We need a type restriction
 230 ;;; because some possible arg SCs (control-stack) overlap with
 231 ;;; possible bignum arg SCs.
 232 (define-vop (move-to-word/fixnum)
 233   (:args (x :scs (any-reg descriptor-reg) :target y
 234             :load-if (not (location= x y))))
 235   (:results (y :scs (signed-reg unsigned-reg)
 236                :load-if (not (location= x y))))
 237   (:arg-types tagged-num)
 238   (:note "fixnum untagging")
 239   (:generator 1
 240     (move y x)
 241     (inst sar y n-fixnum-tag-bits)))
 242 (define-move-vop move-to-word/fixnum :move
 243   (any-reg descriptor-reg) (signed-reg unsigned-reg))
 244
 245 ;;; Arg is a non-immediate constant, load it.
 246 (define-vop (move-to-word-c)
 247   (:args (x :scs (constant)))
 248   (:results (y :scs (signed-reg unsigned-reg)))
 249   (:note "constant load")
 250   (:generator 1
 251     (cond ((sb!c::tn-leaf x)
 252            (inst mov y (tn-value x)))
 253           (t
 254            (inst mov y x)
 255            (inst sar y n-fixnum-tag-bits)))))
 256 (define-move-vop move-to-word-c :move
 257   (constant) (signed-reg unsigned-reg))
 258
 259
 260 ;;; Arg is a fixnum or bignum, figure out which and load if necessary.
 261 (define-vop (move-to-word/integer)
 262   (:args (x :scs (descriptor-reg) :target eax))
 263   (:results (y :scs (signed-reg unsigned-reg)))
 264   (:note "integer to untagged word coercion")
 265   (:temporary (:sc unsigned-reg :offset eax-offset
 266                    :from (:argument 0) :to (:result 0) :target y) eax)
 267   (:generator 4
 268     (move eax x)
 269     (inst test al-tn fixnum-tag-mask)
 270     (inst jmp :z FIXNUM)
 271     (loadw y eax bignum-digits-offset other-pointer-lowtag)
 272     (inst jmp DONE)
 273     FIXNUM
 274     (inst sar eax n-fixnum-tag-bits)
 275     (move y eax)
 276     DONE))
 277 (define-move-vop move-to-word/integer :move
 278   (descriptor-reg) (signed-reg unsigned-reg))
 279
 280
 281 ;;; Result is a fixnum, so we can just shift. We need the result type
 282 ;;; restriction because of the control-stack ambiguity noted above.
 283 (define-vop (move-from-word/fixnum)
 284   (:args (x :scs (signed-reg unsigned-reg) :target y
 285             :load-if (not (location= x y))))
 286   (:results (y :scs (any-reg descriptor-reg)
 287                :load-if (not (location= x y))))
 288   (:result-types tagged-num)
 289   (:note "fixnum tagging")
 290   (:generator 1
 291     (cond ((and (sc-is x signed-reg unsigned-reg)
 292                 (not (location= x y)))
 293            ;; Uses 7 bytes, but faster on the Pentium
 294            (inst lea y (make-ea :qword :index x
 295                                 :scale (ash 1 n-fixnum-tag-bits))))
 296           (t
 297            ;; Uses: If x is a reg 2 + 3; if x = y uses only 3 bytes
 298            (move y x)
 299            (inst shl y n-fixnum-tag-bits)))))
 300 (define-move-vop move-from-word/fixnum :move
 301   (signed-reg unsigned-reg) (any-reg descriptor-reg))
 302
 303 ;;; Convert an untagged signed word to a lispobj -- fixnum or bignum
 304 ;;; as the case may be. Fixnum case inline, bignum case in an assembly
 305 ;;; routine.
 306 (define-vop (move-from-signed)
 307   (:args (x :scs (signed-reg unsigned-reg) :to :result))
 308   (:results (y :scs (any-reg descriptor-reg) :from :argument))
 309   (:note "signed word to integer coercion")
 310   ;; Worst case cost to make sure people know they may be number consing.
 311   (:generator 20
 312      (aver (not (location= x y)))
 313      (let ((done (gen-label)))
 314        (inst imul y x #.(ash 1 n-fixnum-tag-bits))
 315        (inst jmp :no done)
 316        (inst mov y x)
 317        (inst lea temp-reg-tn
 318              (make-ea :qword :disp
 319                       (make-fixup (ecase (tn-offset y)
 320                                     (#.rax-offset 'alloc-signed-bignum-in-rax)
 321                                     (#.rcx-offset 'alloc-signed-bignum-in-rcx)
 322                                     (#.rdx-offset 'alloc-signed-bignum-in-rdx)
 323                                     (#.rbx-offset 'alloc-signed-bignum-in-rbx)
 324                                     (#.rsi-offset 'alloc-signed-bignum-in-rsi)
 325                                     (#.rdi-offset 'alloc-signed-bignum-in-rdi)
 326                                     (#.r8-offset  'alloc-signed-bignum-in-r8)
 327                                     (#.r9-offset  'alloc-signed-bignum-in-r9)
 328                                     (#.r10-offset 'alloc-signed-bignum-in-r10)
 329                                     (#.r12-offset 'alloc-signed-bignum-in-r12)
 330                                     (#.r13-offset 'alloc-signed-bignum-in-r13)
 331                                     (#.r14-offset 'alloc-signed-bignum-in-r14)
 332                                     (#.r15-offset 'alloc-signed-bignum-in-r15))
 333                                   :assembly-routine)))
 334        (inst call temp-reg-tn)
 335        (emit-label done))))
 336 (define-move-vop move-from-signed :move
 337   (signed-reg) (descriptor-reg))
 338
 339 ;;; Convert an untagged unsigned word to a lispobj -- fixnum or bignum
 340 ;;; as the case may be. Fixnum case inline, bignum case in an assembly
 341 ;;; routine.
 342 (define-vop (move-from-unsigned)
 343   (:args (x :scs (signed-reg unsigned-reg) :to :result))
 344   (:results (y :scs (any-reg descriptor-reg) :from :argument))
 345   (:note "unsigned word to integer coercion")
 346   ;; Worst case cost to make sure people know they may be number consing.
 347   (:generator 20
 348     (aver (not (location= x y)))
 349     (let ((done (gen-label)))
 350       (inst mov y #.(ash lowtag-mask n-positive-fixnum-bits))
 351       ;; The assembly routines test the sign flag from this one, so if
 352       ;; you change stuff here, make sure the sign flag doesn't get
 353       ;; overwritten before the CALL!
 354       (inst test x y)
 355       ;; Faster but bigger then SHL Y 4. The cost of doing this
 356       ;; speculatively should be noise compared to bignum consing if
 357       ;; that is needed and saves one branch.
 358       (inst lea y (make-ea :qword :index x :scale (ash 1 n-fixnum-tag-bits)))
 359       (inst jmp :z done)
 360       (inst mov y x)
 361       (inst lea temp-reg-tn
 362             (make-ea :qword :disp
 363                      (make-fixup (ecase (tn-offset y)
 364                                    (#.rax-offset 'alloc-unsigned-bignum-in-rax)
 365                                    (#.rcx-offset 'alloc-unsigned-bignum-in-rcx)
 366                                    (#.rdx-offset 'alloc-unsigned-bignum-in-rdx)
 367                                    (#.rbx-offset 'alloc-unsigned-bignum-in-rbx)
 368                                    (#.rsi-offset 'alloc-unsigned-bignum-in-rsi)
 369                                    (#.rdi-offset 'alloc-unsigned-bignum-in-rdi)
 370                                    (#.r8-offset  'alloc-unsigned-bignum-in-r8)
 371                                    (#.r9-offset  'alloc-unsigned-bignum-in-r9)
 372                                    (#.r10-offset 'alloc-unsigned-bignum-in-r10)
 373                                    (#.r12-offset 'alloc-unsigned-bignum-in-r12)
 374                                    (#.r13-offset 'alloc-unsigned-bignum-in-r13)
 375                                    (#.r14-offset 'alloc-unsigned-bignum-in-r14)
 376                                    (#.r15-offset 'alloc-unsigned-bignum-in-r15))
 377                                  :assembly-routine)))
 378       (inst call temp-reg-tn)
 379       (emit-label done))))
 380 (define-move-vop move-from-unsigned :move
 381   (unsigned-reg) (descriptor-reg))
 382
 383 ;;; Move untagged numbers.
 384 (define-vop (word-move)
 385   (:args (x :scs (signed-reg unsigned-reg) :target y
 386             :load-if (not (location= x y))))
 387   (:results (y :scs (signed-reg unsigned-reg)
 388                :load-if
 389                (not (or (location= x y)
 390                         (and (sc-is x signed-reg unsigned-reg)
 391                              (sc-is y signed-stack unsigned-stack))))))
 392   (:effects)
 393   (:affected)
 394   (:note "word integer move")
 395   (:generator 0
 396     (move y x)))
 397 (define-move-vop word-move :move
 398   (signed-reg unsigned-reg) (signed-reg unsigned-reg))
 399
 400 ;;; Move untagged number arguments/return-values.
 401 (define-vop (move-word-arg)
 402   (:args (x :scs (signed-reg unsigned-reg) :target y)
 403          (fp :scs (any-reg) :load-if (not (sc-is y sap-reg))))
 404   (:results (y))
 405   (:note "word integer argument move")
 406   (:generator 0
 407     (sc-case y
 408       ((signed-reg unsigned-reg)
 409        (move y x))
 410       ((signed-stack unsigned-stack)
 411        (if (= (tn-offset fp) esp-offset)
 412            (storew x fp (tn-offset y))  ; c-call
 413            (storew x fp (frame-word-offset (tn-offset y))))))))
 414 (define-move-vop move-word-arg :move-arg
 415   (descriptor-reg any-reg signed-reg unsigned-reg) (signed-reg unsigned-reg))
 416
 417 ;;; Use standard MOVE-ARG and coercion to move an untagged number
 418 ;;; to a descriptor passing location.
 419 (define-move-vop move-arg :move-arg
 420   (signed-reg unsigned-reg) (any-reg descriptor-reg))