src/compiler/x86-64/move.lisp

   1 ;;;; the x86-64 VM definition of operand loading/saving and the MOVE vop
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!VM")
  13
  14 (defun make-byte-tn (tn)
  15   (aver (sc-is tn any-reg descriptor-reg unsigned-reg signed-reg))
  16   (make-random-tn :kind :normal
  17                   :sc (sc-or-lose 'byte-reg)
  18                   :offset (tn-offset tn)))
  19
  20 (defun make-dword-tn (tn)
  21   (aver (sc-is tn any-reg descriptor-reg character-reg
  22                unsigned-reg signed-reg))
  23   (make-random-tn :kind :normal
  24                   :sc (sc-or-lose 'dword-reg)
  25                   :offset (tn-offset tn)))
  26
  27 (defun zeroize (tn)
  28   (let ((offset (tn-offset tn)))
  29     ;; Using the 32-bit instruction accomplishes the same thing and is
  30     ;; one byte shorter.
  31     (if (<= offset edi-offset)
  32         (let ((tn (make-random-tn :kind :normal
  33                                   :sc (sc-or-lose 'dword-reg)
  34                                   :offset offset)))
  35           (inst xor tn tn))
  36         (inst xor tn tn))))
  37
  38 (define-move-fun (load-immediate 1) (vop x y)
  39   ((immediate)
  40    (any-reg descriptor-reg))
  41   (let ((val (tn-value x)))
  42     (etypecase val
  43       (integer
  44        (if (zerop val)
  45            (zeroize y)
  46          (inst mov y (fixnumize val))))
  47       (symbol
  48        (load-symbol y val))
  49       (character
  50        (inst mov y (logior (ash (char-code val) n-widetag-bits)
  51                            character-widetag))))))
  52
  53 (define-move-fun (load-number 1) (vop x y)
  54   ((immediate) (signed-reg unsigned-reg))
  55   (let ((val (tn-value x)))
  56     (if (zerop val)
  57         (zeroize y)
  58         (inst mov y val))))
  59
  60 (define-move-fun (load-character 1) (vop x y)
  61   ((immediate) (character-reg))
  62   (inst mov y (char-code (tn-value x))))
  63
  64 (define-move-fun (load-system-area-pointer 1) (vop x y)
  65   ((immediate) (sap-reg))
  66   (inst mov y (sap-int (tn-value x))))
  67
  68 (define-move-fun (load-constant 5) (vop x y)
  69   ((constant) (descriptor-reg any-reg))
  70   (inst mov y x))
  71
  72 (define-move-fun (load-stack 5) (vop x y)
  73   ((control-stack) (any-reg descriptor-reg)
  74    (character-stack) (character-reg)
  75    (sap-stack) (sap-reg)
  76    (signed-stack) (signed-reg)
  77    (unsigned-stack) (unsigned-reg))
  78   (inst mov y x))
  79
  80 (define-move-fun (store-stack 5) (vop x y)
  81   ((any-reg descriptor-reg) (control-stack)
  82    (character-reg) (character-stack)
  83    (sap-reg) (sap-stack)
  84    (signed-reg) (signed-stack)
  85    (unsigned-reg) (unsigned-stack))
  86   (inst mov y x))
  87 \f
  88 ;;;; the MOVE VOP
  89 (define-vop (move)
  90   (:args (x :scs (any-reg descriptor-reg immediate) :target y
  91             :load-if (not (location= x y))))
  92   (:results (y :scs (any-reg descriptor-reg)
  93                :load-if
  94                (not (or (location= x y)
  95                         (and (sc-is x any-reg descriptor-reg immediate)
  96                              (sc-is y control-stack))))))
  97   (:temporary (:sc unsigned-reg) temp)
  98   (:effects)
  99   (:affected)
 100   (:generator 0
 101     (if (and (sc-is x immediate)
 102              (sc-is y any-reg descriptor-reg control-stack))
 103         (let ((val (tn-value x)))
 104           (etypecase val
 105             (integer
 106              (if (and (zerop val) (sc-is y any-reg descriptor-reg))
 107                  (zeroize y)
 108                  (move-immediate y (fixnumize val) temp)))
 109             (symbol
 110              (inst mov y (+ nil-value (static-symbol-offset val))))
 111             (character
 112              (inst mov y (logior (ash (char-code val) n-widetag-bits)
 113                                  character-widetag)))))
 114         (move y x))))
 115
 116 (define-move-vop move :move
 117   (any-reg descriptor-reg immediate)
 118   (any-reg descriptor-reg))
 119
 120 ;;; Make MOVE the check VOP for T so that type check generation
 121 ;;; doesn't think it is a hairy type. This also allows checking of a
 122 ;;; few of the values in a continuation to fall out.
 123 (primitive-type-vop move (:check) t)
 124
 125 (defun move-immediate (target val &optional tmp-tn)
 126   (cond
 127     ;; If target is a register, we can just mov it there directly
 128     ((and (tn-p target)
 129           (sc-is target signed-reg unsigned-reg descriptor-reg any-reg))
 130      (inst mov target val))
 131     ;; Likewise if the value is small enough.
 132     ((typep val '(signed-byte 32))
 133      (inst mov target val))
 134     ;; Otherwise go through the temporary register
 135     (tmp-tn
 136      (inst mov tmp-tn val)
 137      (inst mov target tmp-tn))
 138     (t
 139      (error "~A is not a register, no temporary given, and immediate ~A too large" target val))))
 140
 141 ;;; The MOVE-ARG VOP is used for moving descriptor values into
 142 ;;; another frame for argument or known value passing.
 143 ;;;
 144 ;;; Note: It is not going to be possible to move a constant directly
 145 ;;; to another frame, except if the destination is a register and in
 146 ;;; this case the loading works out.
 147 (define-vop (move-arg)
 148   (:args (x :scs (any-reg descriptor-reg immediate) :target y
 149             :load-if (not (and (sc-is y any-reg descriptor-reg)
 150                                (sc-is x control-stack))))
 151          (fp :scs (any-reg)
 152              :load-if (not (sc-is y any-reg descriptor-reg))))
 153   (:results (y))
 154   (:generator 0
 155     (sc-case y
 156       ((any-reg descriptor-reg)
 157        (if (sc-is x immediate)
 158            (let ((val (tn-value x)))
 159              (etypecase val
 160                ((integer 0 0)
 161                 (zeroize y))
 162                (integer
 163                 (inst mov y (fixnumize val)))
 164                (symbol
 165                 (load-symbol y val))
 166                (character
 167                 (inst mov y (logior (ash (char-code val) n-widetag-bits)
 168                                     character-widetag)))))
 169            (move y x)))
 170       ((control-stack)
 171        (if (sc-is x immediate)
 172            (let ((val (tn-value x)))
 173              (if (= (tn-offset fp) esp-offset)
 174                  ;; C-call
 175                  (etypecase val
 176                    (integer
 177                     (storew (fixnumize val) fp (tn-offset y)))
 178                    (symbol
 179                     (storew (+ nil-value (static-symbol-offset val))
 180                             fp (tn-offset y)))
 181                    (character
 182                     (storew (logior (ash (char-code val) n-widetag-bits)
 183                                     character-widetag)
 184                             fp (tn-offset y))))
 185                ;; Lisp stack
 186                (etypecase val
 187                  (integer
 188                   (storew (fixnumize val) fp (frame-word-offset (tn-offset y))))
 189                  (symbol
 190                   (storew (+ nil-value (static-symbol-offset val))
 191                           fp (frame-word-offset (tn-offset y))))
 192                  (character
 193                   (storew (logior (ash (char-code val) n-widetag-bits)
 194                                   character-widetag)
 195                           fp (frame-word-offset (tn-offset y)))))))
 196          (if (= (tn-offset fp) esp-offset)
 197              ;; C-call
 198              (storew x fp (tn-offset y))
 199            ;; Lisp stack
 200            (storew x fp (frame-word-offset (tn-offset y)))))))))
 201
 202 (define-move-vop move-arg :move-arg
 203   (any-reg descriptor-reg)
 204   (any-reg descriptor-reg))
 205 \f
 206 ;;;; ILLEGAL-MOVE
 207
 208 ;;; This VOP exists just to begin the lifetime of a TN that couldn't
 209 ;;; be written legally due to a type error. An error is signalled
 210 ;;; before this VOP is so we don't need to do anything (not that there
 211 ;;; would be anything sensible to do anyway.)
 212 (define-vop (illegal-move)
 213   (:args (x) (type))
 214   (:results (y))
 215   (:ignore y)
 216   (:vop-var vop)
 217   (:save-p :compute-only)
 218   (:generator 666
 219     (error-call vop 'object-not-type-error x type)))
 220 \f
 221 ;;;; moves and coercions
 222
 223 ;;; These MOVE-TO-WORD VOPs move a tagged integer to a raw full-word
 224 ;;; representation. Similarly, the MOVE-FROM-WORD VOPs converts a raw
 225 ;;; integer to a tagged bignum or fixnum.
 226
 227 ;;; Arg is a fixnum, so just shift it. We need a type restriction
 228 ;;; because some possible arg SCs (control-stack) overlap with
 229 ;;; possible bignum arg SCs.
 230 (define-vop (move-to-word/fixnum)
 231   (:args (x :scs (any-reg descriptor-reg) :target y
 232             :load-if (not (location= x y))))
 233   (:results (y :scs (signed-reg unsigned-reg)
 234                :load-if (not (location= x y))))
 235   (:arg-types tagged-num)
 236   (:note "fixnum untagging")
 237   (:generator 1
 238     (move y x)
 239     (inst sar y n-fixnum-tag-bits)))
 240 (define-move-vop move-to-word/fixnum :move
 241   (any-reg descriptor-reg) (signed-reg unsigned-reg))
 242
 243 ;;; Arg is a non-immediate constant, load it.
 244 (define-vop (move-to-word-c)
 245   (:args (x :scs (constant)))
 246   (:results (y :scs (signed-reg unsigned-reg)))
 247   (:note "constant load")
 248   (:generator 1
 249     (cond ((sb!c::tn-leaf x)
 250            (inst mov y (tn-value x)))
 251           (t
 252            (inst mov y x)
 253            (inst sar y n-fixnum-tag-bits)))))
 254 (define-move-vop move-to-word-c :move
 255   (constant) (signed-reg unsigned-reg))
 256
 257
 258 ;;; Arg is a fixnum or bignum, figure out which and load if necessary.
 259 (define-vop (move-to-word/integer)
 260   (:args (x :scs (descriptor-reg) :target eax))
 261   (:results (y :scs (signed-reg unsigned-reg)))
 262   (:note "integer to untagged word coercion")
 263   (:temporary (:sc unsigned-reg :offset eax-offset
 264                    :from (:argument 0) :to (:result 0) :target y) eax)
 265   (:generator 4
 266     (move eax x)
 267     (inst test al-tn fixnum-tag-mask)
 268     (inst jmp :z FIXNUM)
 269     (loadw y eax bignum-digits-offset other-pointer-lowtag)
 270     (inst jmp DONE)
 271     FIXNUM
 272     (inst sar eax n-fixnum-tag-bits)
 273     (move y eax)
 274     DONE))
 275 (define-move-vop move-to-word/integer :move
 276   (descriptor-reg) (signed-reg unsigned-reg))
 277
 278
 279 ;;; Result is a fixnum, so we can just shift. We need the result type
 280 ;;; restriction because of the control-stack ambiguity noted above.
 281 (define-vop (move-from-word/fixnum)
 282   (:args (x :scs (signed-reg unsigned-reg) :target y
 283             :load-if (not (location= x y))))
 284   (:results (y :scs (any-reg descriptor-reg)
 285                :load-if (not (location= x y))))
 286   (:result-types tagged-num)
 287   (:note "fixnum tagging")
 288   (:generator 1
 289     (cond ((and (sc-is x signed-reg unsigned-reg)
 290                 (not (location= x y)))
 291            (if (= n-fixnum-tag-bits 1)
 292                (inst lea y (make-ea :qword :base x :index x))
 293                (inst lea y (make-ea :qword :index x
 294                                     :scale (ash 1 n-fixnum-tag-bits)))))
 295           (t
 296            ;; Uses: If x is a reg 2 + 3; if x = y uses only 3 bytes
 297            (move y x)
 298            (inst shl y n-fixnum-tag-bits)))))
 299 (define-move-vop move-from-word/fixnum :move
 300   (signed-reg unsigned-reg) (any-reg descriptor-reg))
 301
 302 ;;; Convert an untagged signed word to a lispobj -- fixnum or bignum
 303 ;;; as the case may be. Fixnum case inline, bignum case in an assembly
 304 ;;; routine.
 305 (define-vop (move-from-signed)
 306   (:args (x :scs (signed-reg unsigned-reg) :to :result))
 307   (:results (y :scs (any-reg descriptor-reg) :from :argument))
 308   (:note "signed word to integer coercion")
 309   ;; Worst case cost to make sure people know they may be number consing.
 310   (:generator 20
 311      (aver (not (location= x y)))
 312      (let ((done (gen-label)))
 313        (inst imul y x #.(ash 1 n-fixnum-tag-bits))
 314        (inst jmp :no done)
 315        (inst mov y x)
 316        (inst lea temp-reg-tn
 317              (make-ea :qword :disp
 318                       (make-fixup (ecase (tn-offset y)
 319                                     (#.rax-offset 'alloc-signed-bignum-in-rax)
 320                                     (#.rcx-offset 'alloc-signed-bignum-in-rcx)
 321                                     (#.rdx-offset 'alloc-signed-bignum-in-rdx)
 322                                     (#.rbx-offset 'alloc-signed-bignum-in-rbx)
 323                                     (#.rsi-offset 'alloc-signed-bignum-in-rsi)
 324                                     (#.rdi-offset 'alloc-signed-bignum-in-rdi)
 325                                     (#.r8-offset  'alloc-signed-bignum-in-r8)
 326                                     (#.r9-offset  'alloc-signed-bignum-in-r9)
 327                                     (#.r10-offset 'alloc-signed-bignum-in-r10)
 328                                     (#.r12-offset 'alloc-signed-bignum-in-r12)
 329                                     (#.r13-offset 'alloc-signed-bignum-in-r13)
 330                                     (#.r14-offset 'alloc-signed-bignum-in-r14)
 331                                     (#.r15-offset 'alloc-signed-bignum-in-r15))
 332                                   :assembly-routine)))
 333        (inst call temp-reg-tn)
 334        (emit-label done))))
 335 (define-move-vop move-from-signed :move
 336   (signed-reg) (descriptor-reg))
 337
 338 ;;; Convert an untagged unsigned word to a lispobj -- fixnum or bignum
 339 ;;; as the case may be. Fixnum case inline, bignum case in an assembly
 340 ;;; routine.
 341 (define-vop (move-from-unsigned)
 342   (:args (x :scs (signed-reg unsigned-reg) :to :result))
 343   (:results (y :scs (any-reg descriptor-reg) :from :argument))
 344   (:note "unsigned word to integer coercion")
 345   ;; Worst case cost to make sure people know they may be number consing.
 346   (:generator 20
 347     (aver (not (location= x y)))
 348     (let ((done (gen-label)))
 349       (inst mov y #.(ash (1- (ash 1 (1+ n-fixnum-tag-bits)))
 350                          n-positive-fixnum-bits))
 351       ;; The assembly routines test the sign flag from this one, so if
 352       ;; you change stuff here, make sure the sign flag doesn't get
 353       ;; overwritten before the CALL!
 354       (inst test x y)
 355       ;; Using LEA is faster but bigger than MOV+SHL; it also doesn't
 356       ;; twiddle the sign flag.  The cost of doing this speculatively
 357       ;; should be noise compared to bignum consing if that is needed
 358       ;; and saves one branch.
 359       (if (= n-fixnum-tag-bits 1)
 360           (inst lea y (make-ea :qword :base x :index x))
 361           (inst lea y (make-ea :qword :index x
 362                                :scale (ash 1 n-fixnum-tag-bits))))
 363       (inst jmp :z done)
 364       (inst mov y x)
 365       (inst lea temp-reg-tn
 366             (make-ea :qword :disp
 367                      (make-fixup (ecase (tn-offset y)
 368                                    (#.rax-offset 'alloc-unsigned-bignum-in-rax)
 369                                    (#.rcx-offset 'alloc-unsigned-bignum-in-rcx)
 370                                    (#.rdx-offset 'alloc-unsigned-bignum-in-rdx)
 371                                    (#.rbx-offset 'alloc-unsigned-bignum-in-rbx)
 372                                    (#.rsi-offset 'alloc-unsigned-bignum-in-rsi)
 373                                    (#.rdi-offset 'alloc-unsigned-bignum-in-rdi)
 374                                    (#.r8-offset  'alloc-unsigned-bignum-in-r8)
 375                                    (#.r9-offset  'alloc-unsigned-bignum-in-r9)
 376                                    (#.r10-offset 'alloc-unsigned-bignum-in-r10)
 377                                    (#.r12-offset 'alloc-unsigned-bignum-in-r12)
 378                                    (#.r13-offset 'alloc-unsigned-bignum-in-r13)
 379                                    (#.r14-offset 'alloc-unsigned-bignum-in-r14)
 380                                    (#.r15-offset 'alloc-unsigned-bignum-in-r15))
 381                                  :assembly-routine)))
 382       (inst call temp-reg-tn)
 383       (emit-label done))))
 384 (define-move-vop move-from-unsigned :move
 385   (unsigned-reg) (descriptor-reg))
 386
 387 ;;; Move untagged numbers.
 388 (define-vop (word-move)
 389   (:args (x :scs (signed-reg unsigned-reg) :target y
 390             :load-if (not (location= x y))))
 391   (:results (y :scs (signed-reg unsigned-reg)
 392                :load-if
 393                (not (or (location= x y)
 394                         (and (sc-is x signed-reg unsigned-reg)
 395                              (sc-is y signed-stack unsigned-stack))))))
 396   (:effects)
 397   (:affected)
 398   (:note "word integer move")
 399   (:generator 0
 400     (move y x)))
 401 (define-move-vop word-move :move
 402   (signed-reg unsigned-reg) (signed-reg unsigned-reg))
 403
 404 ;;; Move untagged number arguments/return-values.
 405 (define-vop (move-word-arg)
 406   (:args (x :scs (signed-reg unsigned-reg) :target y)
 407          (fp :scs (any-reg) :load-if (not (sc-is y sap-reg))))
 408   (:results (y))
 409   (:note "word integer argument move")
 410   (:generator 0
 411     (sc-case y
 412       ((signed-reg unsigned-reg)
 413        (move y x))
 414       ((signed-stack unsigned-stack)
 415        (if (= (tn-offset fp) esp-offset)
 416            (storew x fp (tn-offset y))  ; c-call
 417            (storew x fp (frame-word-offset (tn-offset y))))))))
 418 (define-move-vop move-word-arg :move-arg
 419   (descriptor-reg any-reg signed-reg unsigned-reg) (signed-reg unsigned-reg))
 420
 421 ;;; Use standard MOVE-ARG and coercion to move an untagged number
 422 ;;; to a descriptor passing location.
 423 (define-move-vop move-arg :move-arg
 424   (signed-reg unsigned-reg) (any-reg descriptor-reg))