src/compiler/x86-64/type-vops.lisp

   1 ;;;; type testing and checking VOPs for the x86-64 VM
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!VM")
  13 \f
  14 ;;;; test generation utilities
  15
  16 (defun generate-fixnum-test (value)
  17   "zero flag set if VALUE is fixnum"
  18   (inst test
  19         (cond ((sc-is value any-reg descriptor-reg)
  20                (make-byte-tn value))
  21               ((sc-is value control-stack)
  22                (make-ea :byte :base rbp-tn
  23                         :disp (- (* (1+ (tn-offset value)) n-word-bytes))))
  24               (t
  25                value))
  26         sb!vm::fixnum-tag-mask))
  27
  28 (defun %test-fixnum (value target not-p)
  29   (generate-fixnum-test value)
  30   (inst jmp (if not-p :nz :z) target))
  31
  32 (defun %test-fixnum-and-headers (value target not-p headers)
  33   (let ((drop-through (gen-label)))
  34     (generate-fixnum-test value)
  35     (inst jmp :z (if not-p drop-through target))
  36     (%test-headers value target not-p nil headers drop-through)))
  37
  38 (defun %test-fixnum-and-immediate (value target not-p immediate)
  39   (let ((drop-through (gen-label)))
  40     (generate-fixnum-test value)
  41     (inst jmp :z (if not-p drop-through target))
  42     (%test-immediate value target not-p immediate drop-through)))
  43
  44 (defun %test-fixnum-immediate-and-headers (value target not-p immediate
  45                                            headers)
  46   (let ((drop-through (gen-label)))
  47     (generate-fixnum-test value)
  48     (inst jmp :z (if not-p drop-through target))
  49     (%test-immediate-and-headers value target not-p immediate headers
  50                                  drop-through)))
  51
  52 (defun %test-immediate (value target not-p immediate
  53                         &optional (drop-through (gen-label)))
  54   ;; Code a single instruction byte test if possible.
  55   (cond ((sc-is value any-reg descriptor-reg)
  56          (inst cmp (make-byte-tn value) immediate))
  57         (t
  58          (move rax-tn value)
  59          (inst cmp al-tn immediate)))
  60   (inst jmp (if not-p :ne :e) target)
  61   (emit-label drop-through))
  62
  63 (defun %test-immediate-and-headers (value target not-p immediate headers
  64                                     &optional (drop-through (gen-label)))
  65   ;; Code a single instruction byte test if possible.
  66   (cond ((sc-is value any-reg descriptor-reg)
  67          (inst cmp (make-byte-tn value) immediate))
  68         (t
  69          (move rax-tn value)
  70          (inst cmp al-tn immediate)))
  71   (inst jmp :e (if not-p drop-through target))
  72   (%test-headers value target not-p nil headers drop-through))
  73
  74 (defun %test-lowtag (value target not-p lowtag)
  75   (if (and (sc-is value any-reg descriptor-reg)
  76            (< (tn-offset value) r8-offset))
  77       (move eax-tn (make-dword-tn value)) ; shorter encoding (no REX prefix)
  78       (move rax-tn value))
  79   (inst and al-tn lowtag-mask)
  80   (inst cmp al-tn lowtag)
  81   (inst jmp (if not-p :ne :e) target))
  82
  83 (defun %test-headers (value target not-p function-p headers
  84                             &optional (drop-through (gen-label)))
  85   (let ((lowtag (if function-p fun-pointer-lowtag other-pointer-lowtag)))
  86     (multiple-value-bind (equal less-or-equal when-true when-false)
  87         ;; EQUAL and LESS-OR-EQUAL are the conditions for branching to TARGET.
  88         ;; WHEN-TRUE and WHEN-FALSE are the labels to branch to when we know
  89         ;; it's true and when we know it's false respectively.
  90         (if not-p
  91             (values :ne :a drop-through target)
  92             (values :e :na target drop-through))
  93       (%test-lowtag value when-false t lowtag)
  94       (inst mov al-tn (make-ea :byte :base value :disp (- lowtag)))
  95       (do ((remaining headers (cdr remaining)))
  96           ((null remaining))
  97         (let ((header (car remaining))
  98               (last (null (cdr remaining))))
  99           (cond
 100            ((atom header)
 101             (inst cmp al-tn header)
 102             (if last
 103                 (inst jmp equal target)
 104                 (inst jmp :e when-true)))
 105            (t
 106              (let ((start (car header))
 107                    (end (cdr header)))
 108                (unless (= start bignum-widetag)
 109                  (inst cmp al-tn start)
 110                  (inst jmp :b when-false)) ; was :l
 111                (inst cmp al-tn end)
 112                (if last
 113                    (inst jmp less-or-equal target)
 114                    (inst jmp :be when-true))))))) ; was :le
 115       (emit-label drop-through))))
 116
 117 \f
 118 ;;;; type checking and testing
 119
 120 (define-vop (check-type)
 121   (:args (value :target result :scs (any-reg descriptor-reg)))
 122   (:results (result :scs (any-reg descriptor-reg)))
 123   (:temporary (:sc unsigned-reg :offset eax-offset :to (:result 0)) eax)
 124   (:ignore eax)
 125   (:vop-var vop)
 126   (:save-p :compute-only))
 127
 128 (define-vop (type-predicate)
 129   (:args (value :scs (any-reg descriptor-reg)))
 130   (:temporary (:sc unsigned-reg :offset eax-offset) eax)
 131   (:ignore eax)
 132   (:conditional)
 133   (:info target not-p)
 134   (:policy :fast-safe))
 135
 136 ;;; simpler VOP that don't need a temporary register
 137 (define-vop (simple-check-type)
 138   (:args (value :target result :scs (any-reg descriptor-reg)))
 139   (:results (result :scs (any-reg descriptor-reg)
 140                     :load-if (not (and (sc-is value any-reg descriptor-reg)
 141                                        (sc-is result control-stack)))))
 142   (:vop-var vop)
 143   (:save-p :compute-only))
 144
 145 (define-vop (simple-type-predicate)
 146   (:args (value :scs (any-reg descriptor-reg control-stack)))
 147   (:conditional)
 148   (:info target not-p)
 149   (:policy :fast-safe))
 150
 151 (defun cost-to-test-types (type-codes)
 152   (+ (* 2 (length type-codes))
 153      (if (> (apply #'max type-codes) lowtag-limit) 7 2)))
 154
 155 (defmacro !define-type-vops (pred-name check-name ptype error-code
 156                              (&rest type-codes)
 157                              &key (variant nil variant-p) &allow-other-keys)
 158   ;; KLUDGE: UGH. Why do we need this eval? Can't we put this in the
 159   ;; expansion?
 160   (let* ((cost (cost-to-test-types (mapcar #'eval type-codes)))
 161          (prefix (if variant-p
 162                      (concatenate 'string (string variant) "-")
 163                      "")))
 164     `(progn
 165        ,@(when pred-name
 166            `((define-vop (,pred-name ,(intern (concatenate 'string prefix "TYPE-PREDICATE")))
 167                (:translate ,pred-name)
 168                (:generator ,cost
 169                  (test-type value target not-p (,@type-codes))))))
 170        ,@(when check-name
 171            `((define-vop (,check-name ,(intern (concatenate 'string prefix "CHECK-TYPE")))
 172                (:generator ,cost
 173                  (let ((err-lab
 174                         (generate-error-code vop ',error-code value)))
 175                    (test-type value err-lab t (,@type-codes))
 176                    (move result value))))))
 177        ,@(when ptype
 178            `((primitive-type-vop ,check-name (:check) ,ptype))))))
 179 \f
 180 ;;;; other integer ranges
 181
 182 (define-vop (fixnump/unsigned-byte-64 simple-type-predicate)
 183   (:args (value :scs (unsigned-reg)))
 184   (:arg-types unsigned-num)
 185   (:translate fixnump)
 186   (:temporary (:sc unsigned-reg) tmp)
 187   (:info)
 188   (:conditional :z)
 189   (:generator 5
 190     (inst mov tmp value)
 191     (inst shr tmp n-positive-fixnum-bits)))
 192
 193 ;;; A (SIGNED-BYTE 64) can be represented with either fixnum or a bignum with
 194 ;;; exactly one digit.
 195
 196 (define-vop (signed-byte-64-p type-predicate)
 197   (:translate signed-byte-64-p)
 198   (:generator 45
 199     (multiple-value-bind (yep nope)
 200         (if not-p
 201             (values not-target target)
 202             (values target not-target))
 203       (generate-fixnum-test value)
 204       (inst jmp :e yep)
 205       (move rax-tn value)
 206       (inst and al-tn lowtag-mask)
 207       (inst cmp al-tn other-pointer-lowtag)
 208       (inst jmp :ne nope)
 209       (loadw rax-tn value 0 other-pointer-lowtag)
 210       (inst cmp rax-tn (+ (ash 1 n-widetag-bits) bignum-widetag))
 211       (inst jmp (if not-p :ne :e) target))
 212     NOT-TARGET))
 213
 214 (define-vop (check-signed-byte-64 check-type)
 215   (:generator 45
 216     (let ((nope (generate-error-code vop
 217                                      'object-not-signed-byte-64-error
 218                                      value)))
 219       (generate-fixnum-test value)
 220       (inst jmp :e yep)
 221       (move rax-tn value)
 222       (inst and al-tn lowtag-mask)
 223       (inst cmp al-tn other-pointer-lowtag)
 224       (inst jmp :ne nope)
 225       (loadw rax-tn value 0 other-pointer-lowtag)
 226       (inst cmp rax-tn (+ (ash 1 n-widetag-bits) bignum-widetag))
 227       (inst jmp :ne nope))
 228     YEP
 229     (move result value)))
 230
 231 ;;; An (unsigned-byte 64) can be represented with either a positive
 232 ;;; fixnum, a bignum with exactly one positive digit, or a bignum with
 233 ;;; exactly two digits and the second digit all zeros.
 234 (define-vop (unsigned-byte-64-p type-predicate)
 235   (:translate unsigned-byte-64-p)
 236   (:generator 45
 237     (let ((not-target (gen-label))
 238           (single-word (gen-label))
 239           (fixnum (gen-label)))
 240       (multiple-value-bind (yep nope)
 241           (if not-p
 242               (values not-target target)
 243               (values target not-target))
 244         ;; Is it a fixnum?
 245         (generate-fixnum-test value)
 246         (move rax-tn value)
 247         (inst jmp :e fixnum)
 248
 249         ;; If not, is it an other pointer?
 250         (inst and rax-tn lowtag-mask)
 251         (inst cmp rax-tn other-pointer-lowtag)
 252         (inst jmp :ne nope)
 253         ;; Get the header.
 254         (loadw rax-tn value 0 other-pointer-lowtag)
 255         ;; Is it one?
 256         (inst cmp rax-tn (+ (ash 1 n-widetag-bits) bignum-widetag))
 257         (inst jmp :e single-word)
 258         ;; If it's other than two, we can't be an (unsigned-byte 64)
 259         (inst cmp rax-tn (+ (ash 2 n-widetag-bits) bignum-widetag))
 260         (inst jmp :ne nope)
 261         ;; Get the second digit.
 262         (loadw rax-tn value (1+ bignum-digits-offset) other-pointer-lowtag)
 263         ;; All zeros, its an (unsigned-byte 64).
 264         (inst or rax-tn rax-tn)
 265         (inst jmp :z yep)
 266         (inst jmp nope)
 267
 268         (emit-label single-word)
 269         ;; Get the single digit.
 270         (loadw rax-tn value bignum-digits-offset other-pointer-lowtag)
 271
 272         ;; positive implies (unsigned-byte 64).
 273         (emit-label fixnum)
 274         (inst or rax-tn rax-tn)
 275         (inst jmp (if not-p :s :ns) target)
 276
 277         (emit-label not-target)))))
 278
 279 (define-vop (check-unsigned-byte-64 check-type)
 280   (:generator 45
 281     (let ((nope
 282            (generate-error-code vop 'object-not-unsigned-byte-64-error value))
 283           (yep (gen-label))
 284           (fixnum (gen-label))
 285           (single-word (gen-label)))
 286
 287       ;; Is it a fixnum?
 288       (generate-fixnum-test value)
 289       (move rax-tn value)
 290       (inst jmp :e fixnum)
 291
 292       ;; If not, is it an other pointer?
 293       (inst and rax-tn lowtag-mask)
 294       (inst cmp rax-tn other-pointer-lowtag)
 295       (inst jmp :ne nope)
 296       ;; Get the header.
 297       (loadw rax-tn value 0 other-pointer-lowtag)
 298       ;; Is it one?
 299       (inst cmp rax-tn (+ (ash 1 n-widetag-bits) bignum-widetag))
 300       (inst jmp :e single-word)
 301       ;; If it's other than two, we can't be an (unsigned-byte 64)
 302       (inst cmp rax-tn (+ (ash 2 n-widetag-bits) bignum-widetag))
 303       (inst jmp :ne nope)
 304       ;; Get the second digit.
 305       (loadw rax-tn value (1+ bignum-digits-offset) other-pointer-lowtag)
 306       ;; All zeros, its an (unsigned-byte 64).
 307       (inst or rax-tn rax-tn)
 308       (inst jmp :z yep)
 309       (inst jmp nope)
 310
 311       (emit-label single-word)
 312       ;; Get the single digit.
 313       (loadw rax-tn value bignum-digits-offset other-pointer-lowtag)
 314
 315       ;; positive implies (unsigned-byte 64).
 316       (emit-label fixnum)
 317       (inst or rax-tn rax-tn)
 318       (inst jmp :s nope)
 319
 320       (emit-label yep)
 321       (move result value))))
 322 \f
 323 ;;;; list/symbol types
 324 ;;;
 325 ;;; symbolp (or symbol (eq nil))
 326 ;;; consp (and list (not (eq nil)))
 327
 328 (define-vop (symbolp type-predicate)
 329   (:translate symbolp)
 330   (:generator 12
 331     (let ((is-symbol-label (if not-p DROP-THRU target)))
 332       (inst cmp value nil-value)
 333       (inst jmp :e is-symbol-label)
 334       (test-type value target not-p (symbol-header-widetag)))
 335     DROP-THRU))
 336
 337 (define-vop (check-symbol check-type)
 338   (:generator 12
 339     (let ((error (generate-error-code vop 'object-not-symbol-error value)))
 340       (inst cmp value nil-value)
 341       (inst jmp :e DROP-THRU)
 342       (test-type value error t (symbol-header-widetag)))
 343     DROP-THRU
 344     (move result value)))
 345
 346 (define-vop (consp type-predicate)
 347   (:translate consp)
 348   (:generator 8
 349     (let ((is-not-cons-label (if not-p target DROP-THRU)))
 350       (inst cmp value nil-value)
 351       (inst jmp :e is-not-cons-label)
 352       (test-type value target not-p (list-pointer-lowtag)))
 353     DROP-THRU))
 354
 355 (define-vop (check-cons check-type)
 356   (:generator 8
 357     (let ((error (generate-error-code vop 'object-not-cons-error value)))
 358       (inst cmp value nil-value)
 359       (inst jmp :e error)
 360       (test-type value error t (list-pointer-lowtag))
 361       (move result value))))