src/compiler/x86-64/type-vops.lisp

   1 ;;;; type testing and checking VOPs for the x86-64 VM
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!VM")
  13 \f
  14 ;;;; test generation utilities
  15
  16 ;;; Optimize the case of moving a 64-bit value into RAX when not caring
  17 ;;; about the upper 32 bits: often the REX prefix can be spared.
  18 (defun move-qword-to-eax (value)
  19   (if (and (sc-is value any-reg descriptor-reg)
  20            (< (tn-offset value) r8-offset))
  21       (move eax-tn (make-dword-tn value))
  22       (move rax-tn value)))
  23
  24 (defun generate-fixnum-test (value)
  25   "zero flag set if VALUE is fixnum"
  26   (inst test
  27         (cond ((sc-is value any-reg descriptor-reg)
  28                (make-byte-tn value))
  29               ((sc-is value control-stack)
  30                (make-ea :byte :base rbp-tn
  31                         :disp (frame-byte-offset (tn-offset value))))
  32               (t
  33                value))
  34         sb!vm::fixnum-tag-mask))
  35
  36 (defun %test-fixnum (value target not-p)
  37   (generate-fixnum-test value)
  38   (inst jmp (if not-p :nz :z) target))
  39
  40 (defun %test-fixnum-and-headers (value target not-p headers)
  41   (let ((drop-through (gen-label)))
  42     (generate-fixnum-test value)
  43     (inst jmp :z (if not-p drop-through target))
  44     (%test-headers value target not-p nil headers drop-through)))
  45
  46 (defun %test-fixnum-and-immediate (value target not-p immediate)
  47   (let ((drop-through (gen-label)))
  48     (generate-fixnum-test value)
  49     (inst jmp :z (if not-p drop-through target))
  50     (%test-immediate value target not-p immediate drop-through)))
  51
  52 (defun %test-fixnum-immediate-and-headers (value target not-p immediate
  53                                            headers)
  54   (let ((drop-through (gen-label)))
  55     (generate-fixnum-test value)
  56     (inst jmp :z (if not-p drop-through target))
  57     (%test-immediate-and-headers value target not-p immediate headers
  58                                  drop-through)))
  59
  60 (defun %test-immediate (value target not-p immediate
  61                         &optional (drop-through (gen-label)))
  62   ;; Code a single instruction byte test if possible.
  63   (cond ((sc-is value any-reg descriptor-reg)
  64          (inst cmp (make-byte-tn value) immediate))
  65         (t
  66          (move rax-tn value)
  67          (inst cmp al-tn immediate)))
  68   (inst jmp (if not-p :ne :e) target)
  69   (emit-label drop-through))
  70
  71 (defun %test-immediate-and-headers (value target not-p immediate headers
  72                                     &optional (drop-through (gen-label)))
  73   ;; Code a single instruction byte test if possible.
  74   (cond ((sc-is value any-reg descriptor-reg)
  75          (inst cmp (make-byte-tn value) immediate))
  76         (t
  77          (move rax-tn value)
  78          (inst cmp al-tn immediate)))
  79   (inst jmp :e (if not-p drop-through target))
  80   (%test-headers value target not-p nil headers drop-through))
  81
  82 (defun %test-lowtag (value target not-p lowtag)
  83   (move-qword-to-eax value)
  84   (inst and al-tn lowtag-mask)
  85   (inst cmp al-tn lowtag)
  86   (inst jmp (if not-p :ne :e) target))
  87
  88 (defun %test-headers (value target not-p function-p headers
  89                             &optional (drop-through (gen-label)))
  90   (let ((lowtag (if function-p fun-pointer-lowtag other-pointer-lowtag)))
  91     (multiple-value-bind (equal less-or-equal greater-or-equal when-true
  92                                 when-false)
  93         ;; EQUAL, LESS-OR-EQUAL, and GREATER-OR-EQUAL are the conditions
  94         ;; for branching to TARGET.  WHEN-TRUE and WHEN-FALSE are the
  95         ;; labels to branch to when we know it's true and when we know
  96         ;; it's false respectively.
  97         (if not-p
  98             (values :ne :a :b drop-through target)
  99             (values :e :na :nb target drop-through))
 100       (%test-lowtag value when-false t lowtag)
 101       (do ((remaining headers (cdr remaining))
 102            ;; It is preferable (smaller and faster code) to directly
 103            ;; compare the value in memory instead of loading it into
 104            ;; a register first. Find out if this is possible and set
 105            ;; WIDETAG-TN accordingly. If impossible, generate the
 106            ;; register load.
 107            ;; Compared to x86 we additionally optimize the cases of a
 108            ;; range starting with BIGNUM-WIDETAG or ending with
 109            ;; COMPLEX-ARRAY-WIDETAG.
 110            (widetag-tn (if (and (null (cdr headers))
 111                                 (or (atom (car headers))
 112                                     (= (caar headers) bignum-widetag)
 113                                     (= (cdar headers) complex-array-widetag)))
 114                            (make-ea :byte :base value :disp (- lowtag))
 115                            (progn
 116                              (inst mov eax-tn (make-ea :dword :base value
 117                                                        :disp (- lowtag)))
 118                              al-tn))))
 119           ((null remaining))
 120         (let ((header (car remaining))
 121               (last (null (cdr remaining))))
 122           (cond
 123            ((atom header)
 124             (inst cmp widetag-tn header)
 125             (if last
 126                 (inst jmp equal target)
 127                 (inst jmp :e when-true)))
 128            (t
 129              (let ((start (car header))
 130                    (end (cdr header)))
 131                (cond
 132                  ((= start bignum-widetag)
 133                   (inst cmp widetag-tn end)
 134                   (if last
 135                       (inst jmp less-or-equal target)
 136                       (inst jmp :be when-true)))
 137                  ((= end complex-array-widetag)
 138                   (inst cmp widetag-tn start)
 139                   (if last
 140                       (inst jmp greater-or-equal target)
 141                       (inst jmp :b when-false)))
 142                  ((not last)
 143                   (inst cmp al-tn start)
 144                   (inst jmp :b when-false)
 145                   (inst cmp al-tn end)
 146                   (inst jmp :be when-true))
 147                  (t
 148                   (inst sub al-tn start)
 149                   (inst cmp al-tn (- end start))
 150                   (inst jmp less-or-equal target))))))))
 151       (emit-label drop-through))))
 152
 153 \f
 154 ;;;; type checking and testing
 155
 156 (define-vop (check-type)
 157   (:args (value :target result :scs (any-reg descriptor-reg)))
 158   (:results (result :scs (any-reg descriptor-reg)))
 159   (:temporary (:sc unsigned-reg :offset eax-offset :to (:result 0)) eax)
 160   (:ignore eax)
 161   (:vop-var vop)
 162   (:save-p :compute-only))
 163
 164 (define-vop (type-predicate)
 165   (:args (value :scs (any-reg descriptor-reg)))
 166   (:temporary (:sc unsigned-reg :offset eax-offset) eax)
 167   (:ignore eax)
 168   (:conditional)
 169   (:info target not-p)
 170   (:policy :fast-safe))
 171
 172 ;;; simpler VOP that don't need a temporary register
 173 (define-vop (simple-check-type)
 174   (:args (value :target result :scs (any-reg descriptor-reg)))
 175   (:results (result :scs (any-reg descriptor-reg)
 176                     :load-if (not (and (sc-is value any-reg descriptor-reg)
 177                                        (sc-is result control-stack)))))
 178   (:vop-var vop)
 179   (:save-p :compute-only))
 180
 181 (define-vop (simple-type-predicate)
 182   (:args (value :scs (any-reg descriptor-reg control-stack)))
 183   (:conditional)
 184   (:info target not-p)
 185   (:policy :fast-safe))
 186
 187 (defun cost-to-test-types (type-codes)
 188   (+ (* 2 (length type-codes))
 189      (if (> (apply #'max type-codes) lowtag-limit) 7 2)))
 190
 191 (defmacro !define-type-vops (pred-name check-name ptype error-code
 192                              (&rest type-codes)
 193                              &key (variant nil variant-p) &allow-other-keys)
 194   ;; KLUDGE: UGH. Why do we need this eval? Can't we put this in the
 195   ;; expansion?
 196   (let* ((cost (cost-to-test-types (mapcar #'eval type-codes)))
 197          (prefix (if variant-p
 198                      (concatenate 'string (string variant) "-")
 199                      "")))
 200     `(progn
 201        ,@(when pred-name
 202            `((define-vop (,pred-name ,(intern (concatenate 'string prefix "TYPE-PREDICATE")))
 203                (:translate ,pred-name)
 204                (:generator ,cost
 205                  (test-type value target not-p (,@type-codes))))))
 206        ,@(when check-name
 207            `((define-vop (,check-name ,(intern (concatenate 'string prefix "CHECK-TYPE")))
 208                (:generator ,cost
 209                  (let ((err-lab
 210                         (generate-error-code vop ',error-code value)))
 211                    (test-type value err-lab t (,@type-codes))
 212                    (move result value))))))
 213        ,@(when ptype
 214            `((primitive-type-vop ,check-name (:check) ,ptype))))))
 215 \f
 216 ;;;; other integer ranges
 217
 218 (define-vop (fixnump/unsigned-byte-64 simple-type-predicate)
 219   (:args (value :scs (unsigned-reg)))
 220   (:arg-types unsigned-num)
 221   (:translate fixnump)
 222   (:temporary (:sc unsigned-reg :from (:argument 0)) tmp)
 223   (:info)
 224   (:conditional :z)
 225   (:generator 5
 226     (move tmp value)
 227     (inst shr tmp n-positive-fixnum-bits)))
 228
 229 #-#.(cl:if (cl:= sb!vm:n-fixnum-tag-bits 1) '(:and) '(:or))
 230 (define-vop (fixnump/signed-byte-64 simple-type-predicate)
 231   (:args (value :scs (signed-reg)))
 232   (:info)
 233   (:conditional :z)
 234   (:temporary (:sc unsigned-reg :offset eax-offset) eax)
 235   (:arg-types signed-num)
 236   (:translate fixnump)
 237   (:generator 5
 238     ;; Hackers Delight, p. 53: signed
 239     ;;    a <= x <= a + 2^n - 1
 240     ;; is equivalent to unsigned
 241     ;;    ((x-a) >> n) = 0
 242     (inst mov rax-tn #.(- sb!xc:most-negative-fixnum))
 243     (inst add rax-tn value)
 244     (inst shr rax-tn n-fixnum-bits)))
 245
 246 #+#.(cl:if (cl:= sb!vm:n-fixnum-tag-bits 1) '(:and) '(:or))
 247 (define-vop (fixnump/signed-byte-64 simple-type-predicate)
 248   (:args (value :scs (signed-reg) :target temp))
 249   (:info)
 250   (:conditional :no)
 251   (:temporary (:sc unsigned-reg :from (:argument 0)) temp)
 252   (:arg-types signed-num)
 253   (:translate fixnump)
 254   (:generator 5
 255     (move temp value)
 256     ;; The overflow flag will be set if the reg's sign bit changes.
 257     (inst shl temp 1)))
 258
 259 ;;; A (SIGNED-BYTE 64) can be represented with either fixnum or a bignum with
 260 ;;; exactly one digit.
 261
 262 (define-vop (signed-byte-64-p type-predicate)
 263   (:translate signed-byte-64-p)
 264   (:generator 45
 265     (multiple-value-bind (yep nope)
 266         (if not-p
 267             (values not-target target)
 268             (values target not-target))
 269       (generate-fixnum-test value)
 270       (inst jmp :e yep)
 271       (move-qword-to-eax value)
 272       (inst and al-tn lowtag-mask)
 273       (inst cmp al-tn other-pointer-lowtag)
 274       (inst jmp :ne nope)
 275       (inst cmp (make-ea-for-object-slot value 0 other-pointer-lowtag)
 276             (+ (ash 1 n-widetag-bits) bignum-widetag))
 277       (inst jmp (if not-p :ne :e) target))
 278     NOT-TARGET))
 279
 280 (define-vop (check-signed-byte-64 check-type)
 281   (:generator 45
 282     (let ((nope (generate-error-code vop
 283                                      'object-not-signed-byte-64-error
 284                                      value)))
 285       (generate-fixnum-test value)
 286       (inst jmp :e yep)
 287       (move-qword-to-eax value)
 288       (inst and al-tn lowtag-mask)
 289       (inst cmp al-tn other-pointer-lowtag)
 290       (inst jmp :ne nope)
 291       (inst cmp (make-ea-for-object-slot value 0 other-pointer-lowtag)
 292             (+ (ash 1 n-widetag-bits) bignum-widetag))
 293       (inst jmp :ne nope))
 294     YEP
 295     (move result value)))
 296
 297 ;;; An (unsigned-byte 64) can be represented with either a positive
 298 ;;; fixnum, a bignum with exactly one positive digit, or a bignum with
 299 ;;; exactly two digits and the second digit all zeros.
 300 (define-vop (unsigned-byte-64-p type-predicate)
 301   (:translate unsigned-byte-64-p)
 302   (:generator 45
 303     (let ((not-target (gen-label))
 304           (single-word (gen-label))
 305           (fixnum (gen-label)))
 306       (multiple-value-bind (yep nope)
 307           (if not-p
 308               (values not-target target)
 309               (values target not-target))
 310         ;; Is it a fixnum?
 311         (generate-fixnum-test value)
 312         (move rax-tn value)
 313         (inst jmp :e fixnum)
 314
 315         ;; If not, is it an other pointer?
 316         (inst and al-tn lowtag-mask)
 317         (inst cmp al-tn other-pointer-lowtag)
 318         (inst jmp :ne nope)
 319         ;; Get the header.
 320         (loadw rax-tn value 0 other-pointer-lowtag)
 321         ;; Is it one?
 322         (inst cmp rax-tn (+ (ash 1 n-widetag-bits) bignum-widetag))
 323         (inst jmp :e single-word)
 324         ;; If it's other than two, we can't be an (unsigned-byte 64)
 325         (inst cmp rax-tn (+ (ash 2 n-widetag-bits) bignum-widetag))
 326         (inst jmp :ne nope)
 327         ;; Get the second digit.
 328         (loadw rax-tn value (1+ bignum-digits-offset) other-pointer-lowtag)
 329         ;; All zeros, its an (unsigned-byte 64).
 330         (inst test rax-tn rax-tn)
 331         (inst jmp :z yep)
 332         (inst jmp nope)
 333
 334         (emit-label single-word)
 335         ;; Get the single digit.
 336         (loadw rax-tn value bignum-digits-offset other-pointer-lowtag)
 337
 338         ;; positive implies (unsigned-byte 64).
 339         (emit-label fixnum)
 340         (inst test rax-tn rax-tn)
 341         (inst jmp (if not-p :s :ns) target)
 342
 343         (emit-label not-target)))))
 344
 345 (define-vop (check-unsigned-byte-64 check-type)
 346   (:generator 45
 347     (let ((nope
 348            (generate-error-code vop 'object-not-unsigned-byte-64-error value))
 349           (yep (gen-label))
 350           (fixnum (gen-label))
 351           (single-word (gen-label)))
 352
 353       ;; Is it a fixnum?
 354       (generate-fixnum-test value)
 355       (move rax-tn value)
 356       (inst jmp :e fixnum)
 357
 358       ;; If not, is it an other pointer?
 359       (inst and al-tn lowtag-mask)
 360       (inst cmp al-tn other-pointer-lowtag)
 361       (inst jmp :ne nope)
 362       ;; Get the header.
 363       (loadw rax-tn value 0 other-pointer-lowtag)
 364       ;; Is it one?
 365       (inst cmp rax-tn (+ (ash 1 n-widetag-bits) bignum-widetag))
 366       (inst jmp :e single-word)
 367       ;; If it's other than two, we can't be an (unsigned-byte 64)
 368       (inst cmp rax-tn (+ (ash 2 n-widetag-bits) bignum-widetag))
 369       (inst jmp :ne nope)
 370       ;; Get the second digit.
 371       (loadw rax-tn value (1+ bignum-digits-offset) other-pointer-lowtag)
 372       ;; All zeros, its an (unsigned-byte 64).
 373       (inst test rax-tn rax-tn)
 374       (inst jmp :z yep)
 375       (inst jmp nope)
 376
 377       (emit-label single-word)
 378       ;; Get the single digit.
 379       (loadw rax-tn value bignum-digits-offset other-pointer-lowtag)
 380
 381       ;; positive implies (unsigned-byte 64).
 382       (emit-label fixnum)
 383       (inst test rax-tn rax-tn)
 384       (inst jmp :s nope)
 385
 386       (emit-label yep)
 387       (move result value))))
 388 \f
 389 ;;;; list/symbol types
 390 ;;;
 391 ;;; symbolp (or symbol (eq nil))
 392 ;;; consp (and list (not (eq nil)))
 393
 394 (define-vop (symbolp type-predicate)
 395   (:translate symbolp)
 396   (:generator 12
 397     (let ((is-symbol-label (if not-p DROP-THRU target)))
 398       (inst cmp value nil-value)
 399       (inst jmp :e is-symbol-label)
 400       (test-type value target not-p (symbol-header-widetag)))
 401     DROP-THRU))
 402
 403 (define-vop (check-symbol check-type)
 404   (:generator 12
 405     (let ((error (generate-error-code vop 'object-not-symbol-error value)))
 406       (inst cmp value nil-value)
 407       (inst jmp :e DROP-THRU)
 408       (test-type value error t (symbol-header-widetag)))
 409     DROP-THRU
 410     (move result value)))
 411
 412 (define-vop (consp type-predicate)
 413   (:translate consp)
 414   (:generator 8
 415     (let ((is-not-cons-label (if not-p target DROP-THRU)))
 416       (inst cmp value nil-value)
 417       (inst jmp :e is-not-cons-label)
 418       (test-type value target not-p (list-pointer-lowtag)))
 419     DROP-THRU))
 420
 421 (define-vop (check-cons check-type)
 422   (:generator 8
 423     (let ((error (generate-error-code vop 'object-not-cons-error value)))
 424       (inst cmp value nil-value)
 425       (inst jmp :e error)
 426       (test-type value error t (list-pointer-lowtag))
 427       (move result value))))