src/compiler/x86-64/values.lisp

   1 ;;;; unknown-values VOPs for the x86 VM
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!VM")
  13
  14 (define-vop (reset-stack-pointer)
  15   (:args (ptr :scs (any-reg)))
  16   (:generator 1
  17     (move rsp-tn ptr)))
  18
  19 (define-vop (%%nip-values)
  20   (:args (last-nipped-ptr :scs (any-reg) :target rdi)
  21          (last-preserved-ptr :scs (any-reg) :target rsi)
  22          (moved-ptrs :scs (any-reg) :more t))
  23   (:results (r-moved-ptrs :scs (any-reg) :more t)
  24             ;; same as MOVED-PTRS
  25             )
  26   (:temporary (:sc any-reg :offset rsi-offset) rsi)
  27   (:temporary (:sc any-reg :offset rdi-offset) rdi)
  28   (:ignore r-moved-ptrs)
  29   (:generator 1
  30     (move rdi last-nipped-ptr)
  31     (move rsi last-preserved-ptr)
  32     (inst sub rsi n-word-bytes)
  33     (inst sub rdi n-word-bytes)
  34     (inst cmp rsp-tn rsi)
  35     (inst jmp :a DONE)
  36     (inst std)
  37     LOOP
  38     (inst movs :qword)
  39     (inst cmp rsp-tn rsi)
  40     (inst jmp :be LOOP)
  41     (inst cld)
  42     DONE
  43     (inst lea rsp-tn (make-ea :qword :base rdi :disp n-word-bytes))
  44     (inst sub rdi rsi)
  45     (loop for moved = moved-ptrs then (tn-ref-across moved)
  46           while moved
  47           do (inst add (tn-ref-tn moved) rdi))))
  48
  49 ;;; Push some values onto the stack, returning the start and number of values
  50 ;;; pushed as results. It is assumed that the Vals are wired to the standard
  51 ;;; argument locations. Nvals is the number of values to push.
  52 ;;;
  53 ;;; The generator cost is pseudo-random. We could get it right by defining a
  54 ;;; bogus SC that reflects the costs of the memory-to-memory moves for each
  55 ;;; operand, but this seems unworthwhile.
  56 (define-vop (push-values)
  57   (:args (vals :more t))
  58   (:temporary (:sc unsigned-reg :to (:result 0) :target start) temp)
  59   (:results (start) (count))
  60   (:info nvals)
  61   (:generator 20
  62     (move temp rsp-tn)                  ; WARN pointing 1 below
  63     (do ((val vals (tn-ref-across val)))
  64         ((null val))
  65       (inst push (tn-ref-tn val)))
  66     (move start temp)
  67     (inst mov count (fixnumize nvals))))
  68
  69 ;;; Push a list of values on the stack, returning Start and Count as used in
  70 ;;; unknown values continuations.
  71 (define-vop (values-list)
  72   (:args (arg :scs (descriptor-reg) :target list))
  73   (:arg-types list)
  74   (:policy :fast-safe)
  75   (:results (start :scs (any-reg))
  76             (count :scs (any-reg)))
  77   (:temporary (:sc descriptor-reg :from (:argument 0) :to (:result 1)) list)
  78   (:temporary (:sc dword-reg :offset eax-offset :to (:result 1)) eax)
  79   (:ignore eax)
  80   (:vop-var vop)
  81   (:save-p :compute-only)
  82   (:generator 0
  83     (move list arg)
  84     (move start rsp-tn)                 ; WARN pointing 1 below
  85
  86     LOOP
  87     (inst cmp list nil-value)
  88     (inst jmp :e DONE)
  89     (pushw list cons-car-slot list-pointer-lowtag)
  90     (loadw list list cons-cdr-slot list-pointer-lowtag)
  91     (%test-lowtag list LOOP nil list-pointer-lowtag)
  92     (error-call vop 'bogus-arg-to-values-list-error list)
  93
  94     DONE
  95     (inst mov count start)              ; start is high address
  96     (inst sub count rsp-tn)             ; stackp is low address
  97     #!-#.(cl:if (cl:= sb!vm:word-shift sb!vm:n-fixnum-tag-bits) '(and) '(or))
  98     (inst shr count (- word-shift n-fixnum-tag-bits))))
  99
 100 ;;; Copy the more arg block to the top of the stack so we can use them
 101 ;;; as function arguments.
 102 ;;;
 103 ;;; Accepts a context as produced by more-arg-context; points to the first
 104 ;;; value on the stack, not 4 bytes above as in other contexts.
 105 ;;;
 106 ;;; Return a context that is 4 bytes above the first value, suitable for
 107 ;;; defining a new stack frame.
 108 (define-vop (%more-arg-values)
 109   (:args (context :scs (descriptor-reg any-reg) :target src)
 110          (num :scs (any-reg) :target count))
 111   (:arg-types * positive-fixnum)
 112   (:temporary (:sc any-reg :from (:argument 0)) src)
 113   (:temporary (:sc descriptor-reg) temp)
 114   (:temporary (:sc unsigned-reg :offset rcx-offset) loop-index)
 115   (:results (start :scs (any-reg))
 116             (count :scs (any-reg)))
 117   (:generator 20
 118     (move src context)
 119     (move count num)
 120
 121     (inst lea loop-index (make-ea :byte :index count
 122                                         :scale (ash 1 (- word-shift n-fixnum-tag-bits))))
 123     (inst mov start rsp-tn)
 124     (inst jrcxz DONE)  ; check for 0 count?
 125
 126     (inst sub rsp-tn loop-index)
 127     (inst sub src loop-index)
 128
 129     LOOP
 130     (inst mov temp (make-ea :qword :base src :index loop-index))
 131     (inst sub loop-index n-word-bytes)
 132     (inst mov (make-ea :qword :base rsp-tn :index loop-index) temp)
 133     (inst jmp :nz LOOP)
 134
 135     DONE))
 136