src/compiler/x86-64/vm.lisp

   1 ;;;; miscellaneous VM definition noise for the x86-64
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!VM")
  13
  14 ;;; the size of an INTEGER representation of a SYSTEM-AREA-POINTER, i.e.
  15 ;;; size of a native memory address
  16 (deftype sap-int () '(unsigned-byte 64))
  17 \f
  18 ;;;; register specs
  19
  20 (eval-when (:compile-toplevel :load-toplevel :execute)
  21   (defvar *byte-register-names* (make-array 32 :initial-element nil))
  22   (defvar *word-register-names* (make-array 32 :initial-element nil))
  23   (defvar *dword-register-names* (make-array 32 :initial-element nil))
  24   (defvar *qword-register-names* (make-array 32 :initial-element nil))
  25   (defvar *float-register-names* (make-array 16 :initial-element nil)))
  26
  27 (macrolet ((defreg (name offset size)
  28              (let ((offset-sym (symbolicate name "-OFFSET"))
  29                    (names-vector (symbolicate "*" size "-REGISTER-NAMES*")))
  30                `(progn
  31                   (eval-when (:compile-toplevel :load-toplevel :execute)
  32                     ;; EVAL-WHEN is necessary because stuff like #.EAX-OFFSET
  33                     ;; (in the same file) depends on compile-time evaluation
  34                     ;; of the DEFCONSTANT. -- AL 20010224
  35                     (def!constant ,offset-sym ,offset))
  36                   (setf (svref ,names-vector ,offset-sym)
  37                         ,(symbol-name name)))))
  38            ;; FIXME: It looks to me as though DEFREGSET should also
  39            ;; define the related *FOO-REGISTER-NAMES* variable.
  40            (defregset (name &rest regs)
  41              `(eval-when (:compile-toplevel :load-toplevel :execute)
  42                 (defparameter ,name
  43                   (list ,@(mapcar (lambda (name)
  44                                     (symbolicate name "-OFFSET"))
  45                                   regs))))))
  46
  47   ;; byte registers
  48   ;;
  49   ;; Note: the encoding here is different than that used by the chip.
  50   ;; We use this encoding so that the compiler thinks that AX (and
  51   ;; EAX) overlap AL and AH instead of AL and CL.
  52   ;;
  53   ;; High-byte are registers disabled on AMD64, since they can't be
  54   ;; encoded for an op that has a REX-prefix and we don't want to
  55   ;; add special cases into the code generation. The overlap doesn't
  56   ;; therefore exist anymore, but the numbering hasn't been changed
  57   ;; to reflect this.
  58   (defreg al    0 :byte)
  59   (defreg cl    2 :byte)
  60   (defreg dl    4 :byte)
  61   (defreg bl    6 :byte)
  62   (defreg sil  12 :byte)
  63   (defreg dil  14 :byte)
  64   (defreg r8b  16 :byte)
  65   (defreg r9b  18 :byte)
  66   (defreg r10b 20 :byte)
  67   (defreg r11b 22 :byte)
  68   (defreg r12b 24 :byte)
  69   (defreg r13b 26 :byte)
  70   (defreg r14b 28 :byte)
  71   (defreg r15b 30 :byte)
  72   (defregset *byte-regs*
  73       al cl dl bl sil dil r8b r9b r10b
  74       #+nil r11b #+nil r12b r13b r14b r15b)
  75
  76   ;; word registers
  77   (defreg ax 0 :word)
  78   (defreg cx 2 :word)
  79   (defreg dx 4 :word)
  80   (defreg bx 6 :word)
  81   (defreg sp 8 :word)
  82   (defreg bp 10 :word)
  83   (defreg si 12 :word)
  84   (defreg di 14 :word)
  85   (defreg r8w  16 :word)
  86   (defreg r9w  18 :word)
  87   (defreg r10w 20 :word)
  88   (defreg r11w 22 :word)
  89   (defreg r12w 24 :word)
  90   (defreg r13w 26 :word)
  91   (defreg r14w 28 :word)
  92   (defreg r15w 30 :word)
  93   (defregset *word-regs* ax cx dx bx si di r8w r9w r10w
  94              #+nil r11w #+nil r12w r13w r14w r15w)
  95
  96   ;; double word registers
  97   (defreg eax 0 :dword)
  98   (defreg ecx 2 :dword)
  99   (defreg edx 4 :dword)
 100   (defreg ebx 6 :dword)
 101   (defreg esp 8 :dword)
 102   (defreg ebp 10 :dword)
 103   (defreg esi 12 :dword)
 104   (defreg edi 14 :dword)
 105   (defreg r8d  16 :dword)
 106   (defreg r9d  18 :dword)
 107   (defreg r10d 20 :dword)
 108   (defreg r11d 22 :dword)
 109   (defreg r12d 24 :dword)
 110   (defreg r13d 26 :dword)
 111   (defreg r14d 28 :dword)
 112   (defreg r15d 30 :dword)
 113   (defregset *dword-regs* eax ecx edx ebx esi edi r8d r9d r10d
 114              #+nil r11d #+nil r12w r13d r14d r15d)
 115
 116   ;; quadword registers
 117   (defreg rax 0 :qword)
 118   (defreg rcx 2 :qword)
 119   (defreg rdx 4 :qword)
 120   (defreg rbx 6 :qword)
 121   (defreg rsp 8 :qword)
 122   (defreg rbp 10 :qword)
 123   (defreg rsi 12 :qword)
 124   (defreg rdi 14 :qword)
 125   (defreg r8  16 :qword)
 126   (defreg r9  18 :qword)
 127   (defreg r10 20 :qword)
 128   (defreg r11 22 :qword)
 129   (defreg r12 24 :qword)
 130   (defreg r13 26 :qword)
 131   (defreg r14 28 :qword)
 132   (defreg r15 30 :qword)
 133   ;; for no good reason at the time, r12 and r13 were missed from the
 134   ;; list of qword registers.  However
 135   ;; <jsnell> r13 is already used as temporary [#lisp irc 2005/01/30]
 136   ;; and we're now going to use r12 for the struct thread*
 137   ;;
 138   ;; Except that now we use r11 instead of r13 as the temporary,
 139   ;; since it's got a more compact encoding than r13, and experimentally
 140   ;; the temporary gets used more than the other registers that are never
 141   ;; wired. -- JES, 2005-11-02
 142   (defregset *qword-regs* rax rcx rdx rbx rsi rdi
 143              r8 r9 r10 #+nil r11 #+nil r12 r13  r14 r15)
 144
 145   ;; floating point registers
 146   (defreg float0 0 :float)
 147   (defreg float1 1 :float)
 148   (defreg float2 2 :float)
 149   (defreg float3 3 :float)
 150   (defreg float4 4 :float)
 151   (defreg float5 5 :float)
 152   (defreg float6 6 :float)
 153   (defreg float7 7 :float)
 154   (defreg float8 8 :float)
 155   (defreg float9 9 :float)
 156   (defreg float10 10 :float)
 157   (defreg float11 11 :float)
 158   (defreg float12 12 :float)
 159   (defreg float13 13 :float)
 160   (defreg float14 14 :float)
 161   (defreg float15 15 :float)
 162   (defregset *float-regs* float0 float1 float2 float3 float4 float5 float6 float7
 163              float8 float9 float10 float11 float12 float13 float14 float15)
 164
 165   ;; registers used to pass arguments
 166   ;;
 167   ;; the number of arguments/return values passed in registers
 168   (def!constant  register-arg-count 3)
 169   ;; names and offsets for registers used to pass arguments
 170   (eval-when (:compile-toplevel :load-toplevel :execute)
 171     (defparameter *register-arg-names* '(rdx rdi rsi)))
 172   (defregset    *register-arg-offsets* rdx rdi rsi)
 173   #!-win32
 174   (defregset    *c-call-register-arg-offsets* rdi rsi rdx rcx r8 r9)
 175   #!+win32
 176   (defregset    *c-call-register-arg-offsets* rcx rdx r8 r9))
 177 \f
 178 ;;;; SB definitions
 179
 180 ;;; There are 16 registers really, but we consider them 32 in order to
 181 ;;; describe the overlap of byte registers. The only thing we need to
 182 ;;; represent is what registers overlap. Therefore, we consider bytes
 183 ;;; to take one unit, and [dq]?words to take two. We don't need to
 184 ;;; tell the difference between [dq]?words, because you can't put two
 185 ;;; words in a dword register.
 186 (define-storage-base registers :finite :size 32)
 187
 188 (define-storage-base float-registers :finite :size 16)
 189
 190 (define-storage-base stack :unbounded :size 8)
 191 (define-storage-base constant :non-packed)
 192 (define-storage-base immediate-constant :non-packed)
 193 (define-storage-base noise :unbounded :size 2)
 194 \f
 195 ;;;; SC definitions
 196
 197 ;;; a handy macro so we don't have to keep changing all the numbers whenever
 198 ;;; we insert a new storage class
 199 ;;;
 200 (defmacro !define-storage-classes (&rest classes)
 201   (collect ((forms))
 202     (let ((index 0))
 203       (dolist (class classes)
 204         (let* ((sc-name (car class))
 205                (constant-name (symbolicate sc-name "-SC-NUMBER")))
 206           (forms `(define-storage-class ,sc-name ,index
 207                     ,@(cdr class)))
 208           (forms `(def!constant ,constant-name ,index))
 209           (incf index))))
 210     `(progn
 211        ,@(forms))))
 212
 213 ;;; The DEFINE-STORAGE-CLASS call for CATCH-BLOCK refers to the size
 214 ;;; of CATCH-BLOCK. The size of CATCH-BLOCK isn't calculated until
 215 ;;; later in the build process, and the calculation is entangled with
 216 ;;; code which has lots of predependencies, including dependencies on
 217 ;;; the prior call of DEFINE-STORAGE-CLASS. The proper way to
 218 ;;; unscramble this would be to untangle the code, so that the code
 219 ;;; which calculates the size of CATCH-BLOCK can be separated from the
 220 ;;; other lots-of-dependencies code, so that the code which calculates
 221 ;;; the size of CATCH-BLOCK can be executed early, so that this value
 222 ;;; is known properly at this point in compilation. However, that
 223 ;;; would be a lot of editing of code that I (WHN 19990131) can't test
 224 ;;; until the project is complete. So instead, I set the correct value
 225 ;;; by hand here (a sort of nondeterministic guess of the right
 226 ;;; answer:-) and add an assertion later, after the value is
 227 ;;; calculated, that the original guess was correct.
 228 ;;;
 229 ;;; (What a KLUDGE! Anyone who wants to come in and clean up this mess
 230 ;;; has my gratitude.) (FIXME: Maybe this should be me..)
 231 (eval-when (:compile-toplevel :load-toplevel :execute)
 232   (def!constant kludge-nondeterministic-catch-block-size 5))
 233
 234 (!define-storage-classes
 235
 236   ;; non-immediate constants in the constant pool
 237   (constant constant)
 238
 239   (fp-single-zero immediate-constant)
 240   (fp-double-zero immediate-constant)
 241   (fp-complex-single-zero immediate-constant)
 242   (fp-complex-double-zero immediate-constant)
 243
 244   (fp-single-immediate immediate-constant)
 245   (fp-double-immediate immediate-constant)
 246   (fp-complex-single-immediate immediate-constant)
 247   (fp-complex-double-immediate immediate-constant)
 248
 249   (immediate immediate-constant)
 250
 251   ;;
 252   ;; the stacks
 253   ;;
 254
 255   ;; the control stack
 256   (control-stack stack)                 ; may be pointers, scanned by GC
 257
 258   ;; the non-descriptor stacks
 259   ;; XXX alpha backend has :element-size 2 :alignment 2 in these entries
 260   (signed-stack stack)                  ; (signed-byte 64)
 261   (unsigned-stack stack)                ; (unsigned-byte 64)
 262   (character-stack stack)               ; non-descriptor characters.
 263   (sap-stack stack)                     ; System area pointers.
 264   (single-stack stack)                  ; single-floats
 265   (double-stack stack)
 266   (complex-single-stack stack)  ; complex-single-floats
 267   (complex-double-stack stack :element-size 2)  ; complex-double-floats
 268
 269
 270   ;;
 271   ;; magic SCs
 272   ;;
 273
 274   (ignore-me noise)
 275
 276   ;;
 277   ;; things that can go in the integer registers
 278   ;;
 279
 280   ;; On the X86, we don't have to distinguish between descriptor and
 281   ;; non-descriptor registers, because of the conservative GC.
 282   ;; Therefore, we use different scs only to distinguish between
 283   ;; descriptor and non-descriptor values and to specify size.
 284
 285   ;; immediate descriptor objects. Don't have to be seen by GC, but nothing
 286   ;; bad will happen if they are. (fixnums, characters, header values, etc).
 287   (any-reg registers
 288            :locations #.*qword-regs*
 289            :element-size 2 ; I think this is for the al/ah overlap thing
 290            :constant-scs (immediate)
 291            :save-p t
 292            :alternate-scs (control-stack))
 293
 294   ;; pointer descriptor objects -- must be seen by GC
 295   (descriptor-reg registers
 296                   :locations #.*qword-regs*
 297                   :element-size 2
 298 ;                 :reserve-locations (#.eax-offset)
 299                   :constant-scs (constant immediate)
 300                   :save-p t
 301                   :alternate-scs (control-stack))
 302
 303   ;; non-descriptor characters
 304   (character-reg registers
 305                  :locations #!-sb-unicode #.*byte-regs*
 306                             #!+sb-unicode #.*qword-regs*
 307                  #!+sb-unicode #!+sb-unicode
 308                  :element-size 2
 309                  #!-sb-unicode #!-sb-unicode
 310                  :reserve-locations (#.al-offset)
 311                  :constant-scs (immediate)
 312                  :save-p t
 313                  :alternate-scs (character-stack))
 314
 315   ;; non-descriptor SAPs (arbitrary pointers into address space)
 316   (sap-reg registers
 317            :locations #.*qword-regs*
 318            :element-size 2
 319 ;          :reserve-locations (#.eax-offset)
 320            :constant-scs (immediate)
 321            :save-p t
 322            :alternate-scs (sap-stack))
 323
 324   ;; non-descriptor (signed or unsigned) numbers
 325   (signed-reg registers
 326               :locations #.*qword-regs*
 327               :element-size 2
 328               :constant-scs (immediate)
 329               :save-p t
 330               :alternate-scs (signed-stack))
 331   (unsigned-reg registers
 332                 :locations #.*qword-regs*
 333                 :element-size 2
 334                 :constant-scs (immediate)
 335                 :save-p t
 336                 :alternate-scs (unsigned-stack))
 337
 338   ;; miscellaneous objects that must not be seen by GC. Used only as
 339   ;; temporaries.
 340   (word-reg registers
 341             :locations #.*word-regs*
 342             :element-size 2
 343             )
 344   (dword-reg registers
 345             :locations #.*dword-regs*
 346             :element-size 2
 347             )
 348   (byte-reg registers
 349             :locations #.*byte-regs*
 350             )
 351
 352   ;; that can go in the floating point registers
 353
 354   ;; non-descriptor SINGLE-FLOATs
 355   (single-reg float-registers
 356               :locations #.*float-regs*
 357               :constant-scs (fp-single-zero fp-single-immediate)
 358               :save-p t
 359               :alternate-scs (single-stack))
 360
 361   ;; non-descriptor DOUBLE-FLOATs
 362   (double-reg float-registers
 363               :locations #.*float-regs*
 364               :constant-scs (fp-double-zero fp-double-immediate)
 365               :save-p t
 366               :alternate-scs (double-stack))
 367
 368   (complex-single-reg float-registers
 369                       :locations #.*float-regs*
 370                       :constant-scs (fp-complex-single-zero fp-complex-single-immediate)
 371                       :save-p t
 372                       :alternate-scs (complex-single-stack))
 373
 374   (complex-double-reg float-registers
 375                       :locations #.*float-regs*
 376                       :constant-scs (fp-complex-double-zero fp-complex-double-immediate)
 377                       :save-p t
 378                       :alternate-scs (complex-double-stack))
 379
 380   ;; a catch or unwind block
 381   (catch-block stack :element-size kludge-nondeterministic-catch-block-size))
 382
 383 (eval-when (:compile-toplevel :load-toplevel :execute)
 384 (defparameter *byte-sc-names*
 385   '(#!-sb-unicode character-reg byte-reg #!-sb-unicode character-stack))
 386 (defparameter *word-sc-names* '(word-reg))
 387 (defparameter *dword-sc-names* '(dword-reg))
 388 (defparameter *qword-sc-names*
 389   '(any-reg descriptor-reg sap-reg signed-reg unsigned-reg control-stack
 390     signed-stack unsigned-stack sap-stack single-stack
 391     #!+sb-unicode character-reg #!+sb-unicode character-stack constant))
 392 ;;; added by jrd. I guess the right thing to do is to treat floats
 393 ;;; as a separate size...
 394 ;;;
 395 ;;; These are used to (at least) determine operand size.
 396 (defparameter *float-sc-names* '(single-reg))
 397 (defparameter *double-sc-names* '(double-reg double-stack))
 398 (defparameter *complex-sc-names* '(complex-single-reg complex-single-stack
 399                                    complex-double-reg complex-double-stack))
 400 ) ; EVAL-WHEN
 401 \f
 402 ;;;; miscellaneous TNs for the various registers
 403
 404 (macrolet ((def-misc-reg-tns (sc-name &rest reg-names)
 405              (collect ((forms))
 406                       (dolist (reg-name reg-names)
 407                         (let ((tn-name (symbolicate reg-name "-TN"))
 408                               (offset-name (symbolicate reg-name "-OFFSET")))
 409                           ;; FIXME: It'd be good to have the special
 410                           ;; variables here be named with the *FOO*
 411                           ;; convention.
 412                           (forms `(defparameter ,tn-name
 413                                     (make-random-tn :kind :normal
 414                                                     :sc (sc-or-lose ',sc-name)
 415                                                     :offset
 416                                                     ,offset-name)))))
 417                       `(progn ,@(forms)))))
 418
 419   (def-misc-reg-tns unsigned-reg rax rbx rcx rdx rbp rsp rdi rsi
 420                     r8 r9 r10 r11 r12 r13 r14 r15)
 421   (def-misc-reg-tns dword-reg eax ebx ecx edx ebp esp edi esi
 422                     r8d r9d r10d r11d r12d r13d r14d r15d)
 423   (def-misc-reg-tns word-reg ax bx cx dx bp sp di si
 424                     r8w r9w r10w r11w r12w r13w r14w r15w)
 425   (def-misc-reg-tns byte-reg al cl dl bl sil dil r8b r9b r10b
 426                     r11b r12b r13b r14b r15b)
 427   (def-misc-reg-tns single-reg
 428       float0 float1 float2 float3 float4 float5 float6 float7
 429       float8 float9 float10 float11 float12 float13 float14 float15))
 430
 431 (defun reg-in-size (tn size)
 432   (make-random-tn :kind :normal
 433                   :sc (sc-or-lose
 434                        (ecase size
 435                          (:byte 'byte-reg)
 436                          (:word 'word-reg)
 437                          (:dword 'dword-reg)
 438                          (:qword 'unsigned-reg)))
 439                   :offset (tn-offset tn)))
 440
 441 ;; A register that's never used by the code generator, and can therefore
 442 ;; be used as an assembly temporary in cases where a VOP :TEMPORARY can't
 443 ;; be used.
 444 (defparameter temp-reg-tn r11-tn)
 445
 446 ;;; TNs for registers used to pass arguments
 447 (defparameter *register-arg-tns*
 448   (mapcar (lambda (register-arg-name)
 449             (symbol-value (symbolicate register-arg-name "-TN")))
 450           *register-arg-names*))
 451
 452 (defparameter thread-base-tn
 453   (make-random-tn :kind :normal :sc (sc-or-lose 'unsigned-reg )
 454                   :offset r12-offset))
 455
 456 ;;; If value can be represented as an immediate constant, then return
 457 ;;; the appropriate SC number, otherwise return NIL.
 458 (!def-vm-support-routine immediate-constant-sc (value)
 459   (typecase value
 460     ((or (integer #.sb!xc:most-negative-fixnum #.sb!xc:most-positive-fixnum)
 461          character)
 462      (sc-number-or-lose 'immediate))
 463     (symbol
 464      (when (static-symbol-p value)
 465        (sc-number-or-lose 'immediate)))
 466     (single-float
 467        (sc-number-or-lose
 468         (if (eql value 0f0) 'fp-single-zero 'fp-single-immediate)))
 469     (double-float
 470        (sc-number-or-lose
 471         (if (eql value 0d0) 'fp-double-zero 'fp-double-immediate)))
 472     ((complex single-float)
 473        (sc-number-or-lose
 474         (if (eql value #c(0f0 0f0))
 475             'fp-complex-single-zero
 476             'fp-complex-single-immediate)))
 477     ((complex double-float)
 478        (sc-number-or-lose
 479         (if (eql value #c(0d0 0d0))
 480             'fp-complex-double-zero
 481             'fp-complex-double-immediate)))))
 482
 483 (!def-vm-support-routine boxed-immediate-sc-p (sc)
 484   (eql sc (sc-number-or-lose 'immediate)))
 485 \f
 486 ;;;; miscellaneous function call parameters
 487
 488 ;;; Offsets of special stack frame locations relative to RBP.
 489 ;;;
 490 ;;; Consider the standard prologue PUSH RBP; MOV RBP, RSP: the return
 491 ;;; address is at RBP+8, the old control stack frame pointer is at
 492 ;;; RBP, the magic 3rd slot is at RBP-8. Then come the locals from
 493 ;;; RBP-16 on.
 494 (def!constant return-pc-save-offset 0)
 495 (def!constant ocfp-save-offset 1)
 496 (def!constant code-save-offset 2)
 497 ;;; Let SP be the stack pointer before CALLing, and FP is the frame
 498 ;;; pointer after the standard prologue. SP +
 499 ;;; FRAME-WORD-OFFSET(SP->FP-OFFSET + I) = FP + FRAME-WORD-OFFSET(I).
 500 (def!constant sp->fp-offset 2)
 501
 502 (declaim (inline frame-word-offset))
 503 (defun frame-word-offset (index)
 504   (- (1- index)))
 505
 506 (declaim (inline frame-byte-offset))
 507 (defun frame-byte-offset (index)
 508   (* (frame-word-offset index) n-word-bytes))
 509
 510 (def!constant lra-save-offset return-pc-save-offset) ; ?
 511
 512 ;;; This is used by the debugger.
 513 (def!constant single-value-return-byte-offset 3)
 514 \f
 515 ;;; This function is called by debug output routines that want a pretty name
 516 ;;; for a TN's location. It returns a thing that can be printed with PRINC.
 517 (!def-vm-support-routine location-print-name (tn)
 518   (declare (type tn tn))
 519   (let* ((sc (tn-sc tn))
 520          (sb (sb-name (sc-sb sc)))
 521          (offset (tn-offset tn)))
 522     (ecase sb
 523       (registers
 524        (let* ((sc-name (sc-name sc))
 525               (name-vec (cond ((member sc-name *byte-sc-names*)
 526                                *byte-register-names*)
 527                               ((member sc-name *word-sc-names*)
 528                                *word-register-names*)
 529                               ((member sc-name *dword-sc-names*)
 530                                *dword-register-names*)
 531                               ((member sc-name *qword-sc-names*)
 532                                *qword-register-names*))))
 533          (or (and name-vec
 534                   (< -1 offset (length name-vec))
 535                   (svref name-vec offset))
 536              ;; FIXME: Shouldn't this be an ERROR?
 537              (format nil "<unknown reg: off=~W, sc=~A>" offset sc-name))))
 538       (float-registers (format nil "FLOAT~D" offset))
 539       (stack (format nil "S~D" offset))
 540       (constant (format nil "Const~D" offset))
 541       (immediate-constant "Immed")
 542       (noise (symbol-name (sc-name sc))))))
 543 ;;; FIXME: Could this, and everything that uses it, be made #!+SB-SHOW?
 544
 545 (defun dwords-for-quad (value)
 546   (let* ((lo (logand value (1- (ash 1 32))))
 547          (hi (ash value -32)))
 548     (values lo hi)))
 549
 550 (defun words-for-dword (value)
 551   (let* ((lo (logand value (1- (ash 1 16))))
 552          (hi (ash value -16)))
 553     (values lo hi)))
 554
 555 (def!constant cfp-offset rbp-offset) ; pfw - needed by stuff in /code
 556
 557 (!def-vm-support-routine combination-implementation-style (node)
 558   (declare (type sb!c::combination node))
 559   (flet ((valid-funtype (args result)
 560            (sb!c::valid-fun-use node
 561                                 (sb!c::specifier-type
 562                                  `(function ,args ,result)))))
 563     (case (sb!c::combination-fun-source-name node)
 564       (logtest
 565        (cond
 566          ((or (valid-funtype '(fixnum fixnum) '*)
 567               ;; todo: nothing prevents this from testing an unsigned word against
 568               ;; a signed word, except for the mess of VOPs it would demand
 569               (valid-funtype '((signed-byte 64) (signed-byte 64)) '*)
 570               (valid-funtype '((unsigned-byte 64) (unsigned-byte 64)) '*))
 571           (values :direct nil))
 572          (t
 573           (values :default nil))))
 574       (logbitp
 575        (cond
 576          ((or (and (valid-funtype '#.`((integer 0 ,(- 63 n-fixnum-tag-bits))
 577                                        fixnum) '*)
 578                    (sb!c::constant-lvar-p
 579                     (first (sb!c::basic-combination-args node))))
 580               (valid-funtype '((integer 0 63) (signed-byte 64)) '*)
 581               (valid-funtype '((integer 0 63) (unsigned-byte 64)) '*))
 582           (values :transform '(lambda (index integer)
 583                                (%logbitp integer index))))
 584          (t
 585           (values :default nil))))
 586       (t
 587        (values :default nil)))))