src/compiler.lisp

   1 ;;; compiler.lisp ---
   2
   3 ;; copyright (C) 2012, 2013 David Vazquez
   4 ;; Copyright (C) 2012 Raimon Grau
   5
   6 ;; JSCL is free software: you can redistribute it and/or
   7 ;; modify it under the terms of the GNU General Public License as
   8 ;; published by the Free Software Foundation, either version 3 of the
   9 ;; License, or (at your option) any later version.
  10 ;;
  11 ;; JSCL is distributed in the hope that it will be useful, but
  12 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 ;; General Public License for more details.
  15 ;;
  16 ;; You should have received a copy of the GNU General Public License
  17 ;; along with JSCL.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 ;;;; Compiler
  20
  21 ;;; Translate the Lisp code to Javascript. It will compile the special
  22 ;;; forms. Some primitive functions are compiled as special forms
  23 ;;; too. The respective real functions are defined in the target (see
  24 ;;; the beginning of this file) as well as some primitive functions.
  25
  26 (defun code (&rest args)
  27   (mapconcat (lambda (arg)
  28                (cond
  29                  ((null arg) "")
  30                  ((integerp arg) (integer-to-string arg))
  31                  ((floatp arg) (float-to-string arg))
  32                  ((stringp arg) arg)
  33                  (t (error "Unknown argument `~S'." arg))))
  34              args))
  35
  36 ;;; Wrap X with a Javascript code to convert the result from
  37 ;;; Javascript generalized booleans to T or NIL.
  38 (defun js!bool (x)
  39   (code "(" x "?" (ls-compile t) ": " (ls-compile nil) ")"))
  40
  41 ;;; Concatenate the arguments and wrap them with a self-calling
  42 ;;; Javascript anonymous function. It is used to make some Javascript
  43 ;;; statements valid expressions and provide a private scope as well.
  44 ;;; It could be defined as function, but we could do some
  45 ;;; preprocessing in the future.
  46 (defmacro js!selfcall (&body body)
  47   `(code "(function(){" *newline* (indent ,@body) "})()"))
  48
  49 ;;; Like CODE, but prefix each line with four spaces. Two versions
  50 ;;; of this function are available, because the Ecmalisp version is
  51 ;;; very slow and bootstraping was annoying.
  52
  53 #+jscl
  54 (defun indent (&rest string)
  55   (let ((input (apply #'code string)))
  56     (let ((output "")
  57           (index 0)
  58           (size (length input)))
  59       (when (plusp (length input)) (concatf output "    "))
  60       (while (< index size)
  61         (let ((str
  62                (if (and (char= (char input index) #\newline)
  63                         (< index (1- size))
  64                         (not (char= (char input (1+ index)) #\newline)))
  65                    (concat (string #\newline) "    ")
  66                    (string (char input index)))))
  67           (concatf output str))
  68         (incf index))
  69       output)))
  70
  71 #-jscl
  72 (defun indent (&rest string)
  73   (with-output-to-string (*standard-output*)
  74     (with-input-from-string (input (apply #'code string))
  75       (loop
  76          for line = (read-line input nil)
  77          while line
  78          do (write-string "    ")
  79          do (write-line line)))))
  80
  81
  82 ;;; A Form can return a multiple values object calling VALUES, like
  83 ;;; values(arg1, arg2, ...). It will work in any context, as well as
  84 ;;; returning an individual object. However, if the special variable
  85 ;;; `*multiple-value-p*' is NIL, is granted that only the primary
  86 ;;; value will be used, so we can optimize to avoid the VALUES
  87 ;;; function call.
  88 (defvar *multiple-value-p* nil)
  89
  90 ;;; Environment
  91
  92 (def!struct binding
  93   name
  94   type
  95   value
  96   declarations)
  97
  98 (def!struct lexenv
  99   variable
 100   function
 101   block
 102   gotag)
 103
 104 (defun lookup-in-lexenv (name lexenv namespace)
 105   (find name (ecase namespace
 106                 (variable (lexenv-variable lexenv))
 107                 (function (lexenv-function lexenv))
 108                 (block    (lexenv-block    lexenv))
 109                 (gotag    (lexenv-gotag    lexenv)))
 110         :key #'binding-name))
 111
 112 (defun push-to-lexenv (binding lexenv namespace)
 113   (ecase namespace
 114     (variable (push binding (lexenv-variable lexenv)))
 115     (function (push binding (lexenv-function lexenv)))
 116     (block    (push binding (lexenv-block    lexenv)))
 117     (gotag    (push binding (lexenv-gotag    lexenv)))))
 118
 119 (defun extend-lexenv (bindings lexenv namespace)
 120   (let ((env (copy-lexenv lexenv)))
 121     (dolist (binding (reverse bindings) env)
 122       (push-to-lexenv binding env namespace))))
 123
 124
 125 (defvar *environment* (make-lexenv))
 126
 127 (defvar *variable-counter* 0)
 128
 129 (defun gvarname (symbol)
 130   (declare (ignore symbol))
 131   (code "v" (incf *variable-counter*)))
 132
 133 (defun translate-variable (symbol)
 134   (awhen (lookup-in-lexenv symbol *environment* 'variable)
 135     (binding-value it)))
 136
 137 (defun extend-local-env (args)
 138   (let ((new (copy-lexenv *environment*)))
 139     (dolist (symbol args new)
 140       (let ((b (make-binding :name symbol :type 'variable :value (gvarname symbol))))
 141         (push-to-lexenv b new 'variable)))))
 142
 143 ;;; Toplevel compilations
 144 (defvar *toplevel-compilations* nil)
 145
 146 (defun toplevel-compilation (string)
 147   (push string *toplevel-compilations*))
 148
 149 (defun null-or-empty-p (x)
 150   (zerop (length x)))
 151
 152 (defun get-toplevel-compilations ()
 153   (reverse (remove-if #'null-or-empty-p *toplevel-compilations*)))
 154
 155 (defun %compile-defmacro (name lambda)
 156   (toplevel-compilation (ls-compile `',name))
 157   (let ((binding (make-binding :name name :type 'macro :value lambda)))
 158     (push-to-lexenv binding  *environment* 'function))
 159   name)
 160
 161 (defun global-binding (name type namespace)
 162   (or (lookup-in-lexenv name *environment* namespace)
 163       (let ((b (make-binding :name name :type type :value nil)))
 164         (push-to-lexenv b *environment* namespace)
 165         b)))
 166
 167 (defun claimp (symbol namespace claim)
 168   (let ((b (lookup-in-lexenv symbol *environment* namespace)))
 169     (and b (member claim (binding-declarations b)))))
 170
 171 (defun !proclaim (decl)
 172   (case (car decl)
 173     (special
 174      (dolist (name (cdr decl))
 175        (let ((b (global-binding name 'variable 'variable)))
 176          (push 'special (binding-declarations b)))))
 177     (notinline
 178      (dolist (name (cdr decl))
 179        (let ((b (global-binding name 'function 'function)))
 180          (push 'notinline (binding-declarations b)))))
 181     (constant
 182      (dolist (name (cdr decl))
 183        (let ((b (global-binding name 'variable 'variable)))
 184          (push 'constant (binding-declarations b)))))))
 185
 186 #+jscl
 187 (fset 'proclaim #'!proclaim)
 188
 189 (defun %define-symbol-macro (name expansion)
 190   (let ((b (make-binding :name name :type 'macro :value expansion)))
 191     (push-to-lexenv b *environment* 'variable)
 192     name))
 193
 194 #+jscl
 195 (defmacro define-symbol-macro (name expansion)
 196   `(%define-symbol-macro ',name ',expansion))
 197
 198
 199 ;;; Special forms
 200
 201 (defvar *compilations* nil)
 202
 203 (defmacro define-compilation (name args &body body)
 204   ;; Creates a new primitive `name' with parameters args and
 205   ;; @body. The body can access to the local environment through the
 206   ;; variable *ENVIRONMENT*.
 207   `(push (list ',name (lambda ,args (block ,name ,@body)))
 208          *compilations*))
 209
 210 (define-compilation if (condition true false)
 211   (code "(" (ls-compile condition) " !== " (ls-compile nil)
 212         " ? " (ls-compile true *multiple-value-p*)
 213         " : " (ls-compile false *multiple-value-p*)
 214         ")"))
 215
 216 (defvar *ll-keywords* '(&optional &rest &key))
 217
 218 (defun list-until-keyword (list)
 219   (if (or (null list) (member (car list) *ll-keywords*))
 220       nil
 221       (cons (car list) (list-until-keyword (cdr list)))))
 222
 223 (defun ll-section (keyword ll)
 224   (list-until-keyword (cdr (member keyword ll))))
 225
 226 (defun ll-required-arguments (ll)
 227   (list-until-keyword ll))
 228
 229 (defun ll-optional-arguments-canonical (ll)
 230   (mapcar #'ensure-list (ll-section '&optional ll)))
 231
 232 (defun ll-optional-arguments (ll)
 233   (mapcar #'car (ll-optional-arguments-canonical ll)))
 234
 235 (defun ll-rest-argument (ll)
 236   (let ((rest (ll-section '&rest ll)))
 237     (when (cdr rest)
 238       (error "Bad lambda-list `~S'." ll))
 239     (car rest)))
 240
 241 (defun ll-keyword-arguments-canonical (ll)
 242   (flet ((canonicalize (keyarg)
 243            ;; Build a canonical keyword argument descriptor, filling
 244            ;; the optional fields. The result is a list of the form
 245            ;; ((keyword-name var) init-form).
 246            (let ((arg (ensure-list keyarg)))
 247              (cons (if (listp (car arg))
 248                        (car arg)
 249                        (list (intern (symbol-name (car arg)) "KEYWORD") (car arg)))
 250                    (cdr arg)))))
 251     (mapcar #'canonicalize (ll-section '&key ll))))
 252
 253 (defun ll-keyword-arguments (ll)
 254   (mapcar (lambda (keyarg) (second (first keyarg)))
 255           (ll-keyword-arguments-canonical ll)))
 256
 257 (defun ll-svars (lambda-list)
 258   (let ((args
 259          (append
 260           (ll-keyword-arguments-canonical lambda-list)
 261           (ll-optional-arguments-canonical lambda-list))))
 262     (remove nil (mapcar #'third args))))
 263
 264 (defun lambda-name/docstring-wrapper (name docstring &rest strs)
 265   (if (or name docstring)
 266       (js!selfcall
 267         "var func = " (join strs) ";" *newline*
 268         (when name
 269           (code "func.fname = \"" (escape-string name) "\";" *newline*))
 270         (when docstring
 271           (code "func.docstring = \"" (escape-string docstring) "\";" *newline*))
 272         "return func;" *newline*)
 273       (apply #'code strs)))
 274
 275 (defun lambda-check-argument-count
 276     (n-required-arguments n-optional-arguments rest-p)
 277   ;; Note: Remember that we assume that the number of arguments of a
 278   ;; call is at least 1 (the values argument).
 279   (let ((min n-required-arguments)
 280         (max (if rest-p 'n/a (+ n-required-arguments n-optional-arguments))))
 281     (block nil
 282       ;; Special case: a positive exact number of arguments.
 283       (when (and (< 0 min) (eql min max))
 284         (return (code "checkArgs(nargs, " min ");" *newline*)))
 285       ;; General case:
 286       (code
 287        (when (< 0 min)
 288          (code "checkArgsAtLeast(nargs, " min ");" *newline*))
 289        (when (numberp max)
 290          (code "checkArgsAtMost(nargs, " max ");" *newline*))))))
 291
 292 (defun compile-lambda-optional (ll)
 293   (let* ((optional-arguments (ll-optional-arguments-canonical ll))
 294          (n-required-arguments (length (ll-required-arguments ll)))
 295          (n-optional-arguments (length optional-arguments)))
 296     (when optional-arguments
 297       (code "switch(nargs){" *newline*
 298             (let ((cases nil)
 299                   (idx 0))
 300               (progn
 301                 (while (< idx n-optional-arguments)
 302                   (let ((arg (nth idx optional-arguments)))
 303                     (push (code "case " (+ idx n-required-arguments) ":" *newline*
 304                                 (indent (translate-variable (car arg))
 305                                         "="
 306                                         (ls-compile (cadr arg)) ";" *newline*)
 307                                 (when (third arg)
 308                                   (indent (translate-variable (third arg))
 309                                           "="
 310                                           (ls-compile nil)
 311                                           ";" *newline*)))
 312                           cases)
 313                     (incf idx)))
 314                 (push (code "default: break;" *newline*) cases)
 315                 (join (reverse cases))))
 316             "}" *newline*))))
 317
 318 (defun compile-lambda-rest (ll)
 319   (let ((n-required-arguments (length (ll-required-arguments ll)))
 320         (n-optional-arguments (length (ll-optional-arguments ll)))
 321         (rest-argument (ll-rest-argument ll)))
 322     (when rest-argument
 323       (let ((js!rest (translate-variable rest-argument)))
 324         (code "var " js!rest "= " (ls-compile nil) ";" *newline*
 325               "for (var i = nargs-1; i>=" (+ n-required-arguments n-optional-arguments)
 326               "; i--)" *newline*
 327               (indent js!rest " = {car: arguments[i+2], cdr: " js!rest "};" *newline*))))))
 328
 329 (defun compile-lambda-parse-keywords (ll)
 330   (let ((n-required-arguments
 331          (length (ll-required-arguments ll)))
 332         (n-optional-arguments
 333          (length (ll-optional-arguments ll)))
 334         (keyword-arguments
 335          (ll-keyword-arguments-canonical ll)))
 336     (code
 337      ;; Declare variables
 338      (mapconcat (lambda (arg)
 339                   (let ((var (second (car arg))))
 340                     (code "var " (translate-variable var) "; " *newline*
 341                           (when (third arg)
 342                             (code "var " (translate-variable (third arg))
 343                                   " = " (ls-compile nil)
 344                                   ";" *newline*)))))
 345                 keyword-arguments)
 346      ;; Parse keywords
 347      (flet ((parse-keyword (keyarg)
 348               ;; ((keyword-name var) init-form)
 349               (code "for (i=" (+ n-required-arguments n-optional-arguments)
 350                     "; i<nargs; i+=2){" *newline*
 351                     (indent
 352                      "if (arguments[i+2] === " (ls-compile (caar keyarg)) "){" *newline*
 353                      (indent (translate-variable (cadr (car keyarg)))
 354                              " = arguments[i+3];"
 355                              *newline*
 356                              (let ((svar (third keyarg)))
 357                                (when svar
 358                                  (code (translate-variable svar) " = " (ls-compile t) ";" *newline*)))
 359                              "break;" *newline*)
 360                      "}" *newline*)
 361                     "}" *newline*
 362                     ;; Default value
 363                     "if (i == nargs){" *newline*
 364                     (indent (translate-variable (cadr (car keyarg))) " = " (ls-compile (cadr keyarg)) ";" *newline*)
 365                     "}" *newline*)))
 366        (when keyword-arguments
 367          (code "var i;" *newline*
 368                (mapconcat #'parse-keyword keyword-arguments))))
 369      ;; Check for unknown keywords
 370      (when keyword-arguments
 371        (code "for (i=" (+ n-required-arguments n-optional-arguments)
 372              "; i<nargs; i+=2){" *newline*
 373              (indent "if ("
 374                      (join (mapcar (lambda (x)
 375                                      (concat "arguments[i+2] !== " (ls-compile (caar x))))
 376                                    keyword-arguments)
 377                            " && ")
 378                      ")" *newline*
 379                      (indent
 380                       "throw 'Unknown keyword argument ' + xstring(arguments[i].name);" *newline*))
 381              "}" *newline*)))))
 382
 383 (defun parse-lambda-list (ll)
 384   (values (ll-required-arguments ll)
 385           (ll-optional-arguments ll)
 386           (ll-keyword-arguments  ll)
 387           (ll-rest-argument      ll)))
 388
 389 ;;; Process BODY for declarations and/or docstrings. Return as
 390 ;;; multiple values the BODY without docstrings or declarations, the
 391 ;;; list of declaration forms and the docstring.
 392 (defun parse-body (body &key declarations docstring)
 393   (let ((value-declarations)
 394         (value-docstring))
 395     ;; Parse declarations
 396     (when declarations
 397       (do* ((rest body (cdr rest))
 398             (form (car rest) (car rest)))
 399            ((or (atom form) (not (eq (car form) 'declare)))
 400             (setf body rest))
 401         (push form value-declarations)))
 402     ;; Parse docstring
 403     (when (and docstring
 404                (stringp (car body))
 405                (not (null (cdr body))))
 406       (setq value-docstring (car body))
 407       (setq body (cdr body)))
 408     (values body value-declarations value-docstring)))
 409
 410 ;;; Compile a lambda function with lambda list LL and body BODY. If
 411 ;;; NAME is given, it should be a constant string and it will become
 412 ;;; the name of the function. If BLOCK is non-NIL, a named block is
 413 ;;; created around the body. NOTE: No block (even anonymous) is
 414 ;;; created if BLOCk is NIL.
 415 (defun compile-lambda (ll body &key name block)
 416   (multiple-value-bind (required-arguments
 417                         optional-arguments
 418                         keyword-arguments
 419                         rest-argument)
 420       (parse-lambda-list ll)
 421     (multiple-value-bind (body decls documentation)
 422         (parse-body body :declarations t :docstring t)
 423       (declare (ignore decls))
 424       (let ((n-required-arguments (length required-arguments))
 425             (n-optional-arguments (length optional-arguments))
 426             (*environment* (extend-local-env
 427                             (append (ensure-list rest-argument)
 428                                     required-arguments
 429                                     optional-arguments
 430                                     keyword-arguments
 431                                     (ll-svars ll)))))
 432         (lambda-name/docstring-wrapper name documentation
 433          "(function ("
 434          (join (list* "values"
 435                       "nargs"
 436                       (mapcar #'translate-variable
 437                               (append required-arguments optional-arguments)))
 438                ",")
 439          "){" *newline*
 440          (indent
 441           ;; Check number of arguments
 442           (lambda-check-argument-count n-required-arguments
 443                                        n-optional-arguments
 444                                        (or rest-argument keyword-arguments))
 445                                         (compile-lambda-optional ll)
 446                                         (compile-lambda-rest ll)
 447                                         (compile-lambda-parse-keywords ll)
 448                                         (let ((*multiple-value-p* t))
 449                                           (if block
 450                                               (ls-compile-block `((block ,block ,@body)) t)
 451                                               (ls-compile-block body t))))
 452          "})")))))
 453
 454
 455 (defun setq-pair (var val)
 456   (let ((b (lookup-in-lexenv var *environment* 'variable)))
 457     (cond
 458       ((and b
 459             (eq (binding-type b) 'variable)
 460             (not (member 'special (binding-declarations b)))
 461             (not (member 'constant (binding-declarations b))))
 462        (code (binding-value b) " = " (ls-compile val)))
 463       ((and b (eq (binding-type b) 'macro))
 464        (ls-compile `(setf ,var ,val)))
 465       (t
 466        (ls-compile `(set ',var ,val))))))
 467
 468
 469 (define-compilation setq (&rest pairs)
 470   (let ((result ""))
 471     (while t
 472       (cond
 473         ((null pairs) (return))
 474         ((null (cdr pairs))
 475          (error "Odd pairs in SETQ"))
 476         (t
 477          (concatf result
 478            (concat (setq-pair (car pairs) (cadr pairs))
 479                    (if (null (cddr pairs)) "" ", ")))
 480          (setq pairs (cddr pairs)))))
 481     (code "(" result ")")))
 482
 483
 484 ;;; Compilation of literals an object dumping
 485
 486 (defun escape-string (string)
 487   (let ((output "")
 488         (index 0)
 489         (size (length string)))
 490     (while (< index size)
 491       (let ((ch (char string index)))
 492         (when (or (char= ch #\") (char= ch #\\))
 493           (setq output (concat output "\\")))
 494         (when (or (char= ch #\newline))
 495           (setq output (concat output "\\"))
 496           (setq ch #\n))
 497         (setq output (concat output (string ch))))
 498       (incf index))
 499     output))
 500
 501 ;;; BOOTSTRAP MAGIC: We record the macro definitions as lists during
 502 ;;; the bootstrap. Once everything is compiled, we want to dump the
 503 ;;; whole global environment to the output file to reproduce it in the
 504 ;;; run-time. However, the environment must contain expander functions
 505 ;;; rather than lists. We do not know how to dump function objects
 506 ;;; itself, so we mark the list definitions with this object and the
 507 ;;; compiler will be called when this object has to be dumped.
 508 ;;; Backquote/unquote does a similar magic, but this use is exclusive.
 509 ;;;
 510 ;;; Indeed, perhaps to compile the object other macros need to be
 511 ;;; evaluated. For this reason we define a valid macro-function for
 512 ;;; this symbol.
 513 (defvar *magic-unquote-marker* (gensym "MAGIC-UNQUOTE"))
 514 #-jscl
 515 (setf (macro-function *magic-unquote-marker*)
 516       (lambda (form &optional environment)
 517         (declare (ignore environment))
 518         (second form)))
 519
 520 (defvar *literal-table* nil)
 521 (defvar *literal-counter* 0)
 522
 523 (defun genlit ()
 524   (code "l" (incf *literal-counter*)))
 525
 526 (defun dump-symbol (symbol)
 527   #-jscl
 528   (let ((package (symbol-package symbol)))
 529     (if (eq package (find-package "KEYWORD"))
 530         (code "(new Symbol(" (dump-string (symbol-name symbol)) ", " (dump-string (package-name package)) "))")
 531         (code "(new Symbol(" (dump-string (symbol-name symbol)) "))")))
 532   #+jscl
 533   (let ((package (symbol-package symbol)))
 534     (if (null package)
 535         (code "(new Symbol(" (dump-string (symbol-name symbol)) "))")
 536         (ls-compile `(intern ,(symbol-name symbol) ,(package-name package))))))
 537
 538 (defun dump-cons (cons)
 539   (let ((head (butlast cons))
 540         (tail (last cons)))
 541     (code "QIList("
 542           (join-trailing (mapcar (lambda (x) (literal x t)) head) ",")
 543           (literal (car tail) t)
 544           ","
 545           (literal (cdr tail) t)
 546           ")")))
 547
 548 (defun dump-array (array)
 549   (let ((elements (vector-to-list array)))
 550     (concat "[" (join (mapcar #'literal elements) ", ") "]")))
 551
 552 (defun dump-string (string)
 553   (code "make_lisp_string(\"" (escape-string string) "\")"))
 554
 555 (defun literal (sexp &optional recursive)
 556   (cond
 557     ((integerp sexp) (integer-to-string sexp))
 558     ((floatp sexp) (float-to-string sexp))
 559     ((characterp sexp) (code "\"" (escape-string (string sexp)) "\""))
 560     (t
 561      (or (cdr (assoc sexp *literal-table* :test #'eql))
 562          (let ((dumped (typecase sexp
 563                          (symbol (dump-symbol sexp))
 564                          (string (dump-string sexp))
 565                          (cons
 566                           ;; BOOTSTRAP MAGIC: See the root file
 567                           ;; jscl.lisp and the function
 568                           ;; `dump-global-environment' for futher
 569                           ;; information.
 570                           (if (eq (car sexp) *magic-unquote-marker*)
 571                               (ls-compile (second sexp))
 572                               (dump-cons sexp)))
 573                          (array (dump-array sexp)))))
 574            (if (and recursive (not (symbolp sexp)))
 575                dumped
 576                (let ((jsvar (genlit)))
 577                  (push (cons sexp jsvar) *literal-table*)
 578                  (toplevel-compilation (code "var " jsvar " = " dumped))
 579                  (when (keywordp sexp)
 580                    (toplevel-compilation (code jsvar ".value = " jsvar)))
 581                  jsvar)))))))
 582
 583
 584 (define-compilation quote (sexp)
 585   (literal sexp))
 586
 587 (define-compilation %while (pred &rest body)
 588   (js!selfcall
 589     "while(" (ls-compile pred) " !== " (ls-compile nil) "){" *newline*
 590     (indent (ls-compile-block body))
 591     "}"
 592     "return " (ls-compile nil) ";" *newline*))
 593
 594 (define-compilation function (x)
 595   (cond
 596     ((and (listp x) (eq (car x) 'lambda))
 597      (compile-lambda (cadr x) (cddr x)))
 598     ((and (listp x) (eq (car x) 'named-lambda))
 599      ;; TODO: destructuring-bind now! Do error checking manually is
 600      ;; very annoying.
 601      (let ((name (cadr x))
 602            (ll (caddr x))
 603            (body (cdddr x)))
 604        (compile-lambda ll body
 605                        :name (symbol-name name)
 606                        :block name)))
 607     ((symbolp x)
 608      (let ((b (lookup-in-lexenv x *environment* 'function)))
 609        (if b
 610            (binding-value b)
 611            (ls-compile `(symbol-function ',x)))))))
 612
 613
 614 (defun make-function-binding (fname)
 615   (make-binding :name fname :type 'function :value (gvarname fname)))
 616
 617 (defun compile-function-definition (list)
 618   (compile-lambda (car list) (cdr list)))
 619
 620 (defun translate-function (name)
 621   (let ((b (lookup-in-lexenv name *environment* 'function)))
 622     (and b (binding-value b))))
 623
 624 (define-compilation flet (definitions &rest body)
 625   (let* ((fnames (mapcar #'car definitions))
 626          (cfuncs (mapcar (lambda (def)
 627                            (compile-lambda (cadr def)
 628                                            `((block ,(car def)
 629                                                ,@(cddr def)))))
 630                          definitions))
 631          (*environment*
 632           (extend-lexenv (mapcar #'make-function-binding fnames)
 633                          *environment*
 634                          'function)))
 635     (code "(function("
 636           (join (mapcar #'translate-function fnames) ",")
 637           "){" *newline*
 638           (let ((body (ls-compile-block body t)))
 639             (indent body))
 640           "})(" (join cfuncs ",") ")")))
 641
 642 (define-compilation labels (definitions &rest body)
 643   (let* ((fnames (mapcar #'car definitions))
 644          (*environment*
 645           (extend-lexenv (mapcar #'make-function-binding fnames)
 646                          *environment*
 647                          'function)))
 648     (js!selfcall
 649       (mapconcat (lambda (func)
 650                    (code "var " (translate-function (car func))
 651                          " = " (compile-lambda (cadr func)
 652                                                `((block ,(car func) ,@(cddr func))))
 653                          ";" *newline*))
 654                  definitions)
 655       (ls-compile-block body t))))
 656
 657
 658 (defvar *compiling-file* nil)
 659 (define-compilation eval-when-compile (&rest body)
 660   (if *compiling-file*
 661       (progn
 662         (eval (cons 'progn body))
 663         nil)
 664       (ls-compile `(progn ,@body))))
 665
 666 (defmacro define-transformation (name args form)
 667   `(define-compilation ,name ,args
 668      (ls-compile ,form)))
 669
 670 (define-compilation progn (&rest body)
 671   (if (null (cdr body))
 672       (ls-compile (car body) *multiple-value-p*)
 673       (code "("
 674             (join
 675              (remove-if #'null-or-empty-p
 676                         (append
 677                          (mapcar #'ls-compile (butlast body))
 678                          (list (ls-compile (car (last body)) t))))
 679                   ",")
 680             ")")))
 681
 682 (defun special-variable-p (x)
 683   (and (claimp x 'variable 'special) t))
 684
 685 ;;; Wrap CODE to restore the symbol values of the dynamic
 686 ;;; bindings. BINDINGS is a list of pairs of the form
 687 ;;; (SYMBOL . PLACE),  where PLACE is a Javascript variable
 688 ;;; name to initialize the symbol value and where to stored
 689 ;;; the old value.
 690 (defun let-binding-wrapper (bindings body)
 691   (when (null bindings)
 692     (return-from let-binding-wrapper body))
 693   (code
 694    "try {" *newline*
 695    (indent "var tmp;" *newline*
 696            (mapconcat
 697             (lambda (b)
 698               (let ((s (ls-compile `(quote ,(car b)))))
 699                 (code "tmp = " s ".value;" *newline*
 700                       s ".value = " (cdr b) ";" *newline*
 701                       (cdr b) " = tmp;" *newline*)))
 702             bindings)
 703            body *newline*)
 704    "}" *newline*
 705    "finally {"  *newline*
 706    (indent
 707     (mapconcat (lambda (b)
 708                  (let ((s (ls-compile `(quote ,(car b)))))
 709                    (code s ".value" " = " (cdr b) ";" *newline*)))
 710                bindings))
 711    "}" *newline*))
 712
 713 (define-compilation let (bindings &rest body)
 714   (let* ((bindings (mapcar #'ensure-list bindings))
 715          (variables (mapcar #'first bindings))
 716          (cvalues (mapcar #'ls-compile (mapcar #'second bindings)))
 717          (*environment* (extend-local-env (remove-if #'special-variable-p variables)))
 718          (dynamic-bindings))
 719     (code "(function("
 720           (join (mapcar (lambda (x)
 721                           (if (special-variable-p x)
 722                               (let ((v (gvarname x)))
 723                                 (push (cons x v) dynamic-bindings)
 724                                 v)
 725                               (translate-variable x)))
 726                         variables)
 727                 ",")
 728           "){" *newline*
 729           (let ((body (ls-compile-block body t t)))
 730             (indent (let-binding-wrapper dynamic-bindings body)))
 731           "})(" (join cvalues ",") ")")))
 732
 733
 734 ;;; Return the code to initialize BINDING, and push it extending the
 735 ;;; current lexical environment if the variable is not special.
 736 (defun let*-initialize-value (binding)
 737   (let ((var (first binding))
 738         (value (second binding)))
 739     (if (special-variable-p var)
 740         (code (ls-compile `(setq ,var ,value)) ";" *newline*)
 741         (let* ((v (gvarname var))
 742                (b (make-binding :name var :type 'variable :value v)))
 743           (prog1 (code "var " v " = " (ls-compile value) ";" *newline*)
 744             (push-to-lexenv b *environment* 'variable))))))
 745
 746 ;;; Wrap BODY to restore the symbol values of SYMBOLS after body. It
 747 ;;; DOES NOT generate code to initialize the value of the symbols,
 748 ;;; unlike let-binding-wrapper.
 749 (defun let*-binding-wrapper (symbols body)
 750   (when (null symbols)
 751     (return-from let*-binding-wrapper body))
 752   (let ((store (mapcar (lambda (s) (cons s (gvarname s)))
 753                        (remove-if-not #'special-variable-p symbols))))
 754     (code
 755      "try {" *newline*
 756      (indent
 757       (mapconcat (lambda (b)
 758                    (let ((s (ls-compile `(quote ,(car b)))))
 759                      (code "var " (cdr b) " = " s ".value;" *newline*)))
 760                  store)
 761       body)
 762      "}" *newline*
 763      "finally {" *newline*
 764      (indent
 765       (mapconcat (lambda (b)
 766                    (let ((s (ls-compile `(quote ,(car b)))))
 767                      (code s ".value" " = " (cdr b) ";" *newline*)))
 768                  store))
 769      "}" *newline*)))
 770
 771 (define-compilation let* (bindings &rest body)
 772   (let ((bindings (mapcar #'ensure-list bindings))
 773         (*environment* (copy-lexenv *environment*)))
 774     (js!selfcall
 775       (let ((specials (remove-if-not #'special-variable-p (mapcar #'first bindings)))
 776             (body (concat (mapconcat #'let*-initialize-value bindings)
 777                           (ls-compile-block body t t))))
 778         (let*-binding-wrapper specials body)))))
 779
 780
 781 (define-compilation block (name &rest body)
 782   ;; We use Javascript exceptions to implement non local control
 783   ;; transfer. Exceptions has dynamic scoping, so we use a uniquely
 784   ;; generated object to identify the block. The instance of a empty
 785   ;; array is used to distinguish between nested dynamic Javascript
 786   ;; exceptions. See https://github.com/davazp/jscl/issues/64 for
 787   ;; futher details.
 788   (let* ((idvar (gvarname name))
 789          (b (make-binding :name name :type 'block :value idvar)))
 790     (when *multiple-value-p*
 791       (push 'multiple-value (binding-declarations b)))
 792     (let* ((*environment* (extend-lexenv (list b) *environment* 'block))
 793            (cbody (ls-compile-block body t)))
 794       (if (member 'used (binding-declarations b))
 795           (js!selfcall
 796             "try {" *newline*
 797             "var " idvar " = [];" *newline*
 798             (indent cbody)
 799             "}" *newline*
 800             "catch (cf){" *newline*
 801             "    if (cf.type == 'block' && cf.id == " idvar ")" *newline*
 802             (if *multiple-value-p*
 803                 "        return values.apply(this, forcemv(cf.values));"
 804                 "        return cf.values;")
 805             *newline*
 806             "    else" *newline*
 807             "        throw cf;" *newline*
 808             "}" *newline*)
 809           (js!selfcall cbody)))))
 810
 811 (define-compilation return-from (name &optional value)
 812   (let* ((b (lookup-in-lexenv name *environment* 'block))
 813          (multiple-value-p (member 'multiple-value (binding-declarations b))))
 814     (when (null b)
 815       (error "Return from unknown block `~S'." (symbol-name name)))
 816     (push 'used (binding-declarations b))
 817     ;; The binding value is the name of a variable, whose value is the
 818     ;; unique identifier of the block as exception. We can't use the
 819     ;; variable name itself, because it could not to be unique, so we
 820     ;; capture it in a closure.
 821     (js!selfcall
 822       (when multiple-value-p (code "var values = mv;" *newline*))
 823       "throw ({"
 824       "type: 'block', "
 825       "id: " (binding-value b) ", "
 826       "values: " (ls-compile value multiple-value-p) ", "
 827       "message: 'Return from unknown block " (symbol-name name) ".'"
 828       "})")))
 829
 830 (define-compilation catch (id &rest body)
 831   (js!selfcall
 832     "var id = " (ls-compile id) ";" *newline*
 833     "try {" *newline*
 834     (indent (ls-compile-block body t)) *newline*
 835     "}" *newline*
 836     "catch (cf){" *newline*
 837     "    if (cf.type == 'catch' && cf.id == id)" *newline*
 838     (if *multiple-value-p*
 839         "        return values.apply(this, forcemv(cf.values));"
 840         "        return pv.apply(this, forcemv(cf.values));")
 841     *newline*
 842     "    else" *newline*
 843     "        throw cf;" *newline*
 844     "}" *newline*))
 845
 846 (define-compilation throw (id value)
 847   (js!selfcall
 848     "var values = mv;" *newline*
 849     "throw ({"
 850     "type: 'catch', "
 851     "id: " (ls-compile id) ", "
 852     "values: " (ls-compile value t) ", "
 853     "message: 'Throw uncatched.'"
 854     "})"))
 855
 856 (defun go-tag-p (x)
 857   (or (integerp x) (symbolp x)))
 858
 859 (defun declare-tagbody-tags (tbidx body)
 860   (let* ((go-tag-counter 0)
 861          (bindings
 862           (mapcar (lambda (label)
 863                     (let ((tagidx (integer-to-string (incf go-tag-counter))))
 864                       (make-binding :name label :type 'gotag :value (list tbidx tagidx))))
 865                   (remove-if-not #'go-tag-p body))))
 866     (extend-lexenv bindings *environment* 'gotag)))
 867
 868 (define-compilation tagbody (&rest body)
 869   ;; Ignore the tagbody if it does not contain any go-tag. We do this
 870   ;; because 1) it is easy and 2) many built-in forms expand to a
 871   ;; implicit tagbody, so we save some space.
 872   (unless (some #'go-tag-p body)
 873     (return-from tagbody (ls-compile `(progn ,@body nil))))
 874   ;; The translation assumes the first form in BODY is a label
 875   (unless (go-tag-p (car body))
 876     (push (gensym "START") body))
 877   ;; Tagbody compilation
 878   (let ((branch (gvarname 'branch))
 879         (tbidx (gvarname 'tbidx)))
 880     (let ((*environment* (declare-tagbody-tags tbidx body))
 881           initag)
 882       (let ((b (lookup-in-lexenv (first body) *environment* 'gotag)))
 883         (setq initag (second (binding-value b))))
 884       (js!selfcall
 885         ;; TAGBODY branch to take
 886         "var " branch " = " initag ";" *newline*
 887         "var " tbidx " = [];" *newline*
 888         "tbloop:" *newline*
 889         "while (true) {" *newline*
 890         (indent "try {" *newline*
 891                 (indent (let ((content ""))
 892                           (code "switch(" branch "){" *newline*
 893                                 "case " initag ":" *newline*
 894                                 (dolist (form (cdr body) content)
 895                                   (concatf content
 896                                     (if (not (go-tag-p form))
 897                                         (indent (ls-compile form) ";" *newline*)
 898                                         (let ((b (lookup-in-lexenv form *environment* 'gotag)))
 899                                           (code "case " (second (binding-value b)) ":" *newline*)))))
 900                                 "default:" *newline*
 901                                 "    break tbloop;" *newline*
 902                                 "}" *newline*)))
 903                 "}" *newline*
 904                 "catch (jump) {" *newline*
 905                 "    if (jump.type == 'tagbody' && jump.id == " tbidx ")" *newline*
 906                 "        " branch " = jump.label;" *newline*
 907                 "    else" *newline*
 908                 "        throw(jump);" *newline*
 909                 "}" *newline*)
 910         "}" *newline*
 911         "return " (ls-compile nil) ";" *newline*))))
 912
 913 (define-compilation go (label)
 914   (let ((b (lookup-in-lexenv label *environment* 'gotag))
 915         (n (cond
 916              ((symbolp label) (symbol-name label))
 917              ((integerp label) (integer-to-string label)))))
 918     (when (null b)
 919       (error "Unknown tag `~S'" label))
 920     (js!selfcall
 921       "throw ({"
 922       "type: 'tagbody', "
 923       "id: " (first (binding-value b)) ", "
 924       "label: " (second (binding-value b)) ", "
 925       "message: 'Attempt to GO to non-existing tag " n "'"
 926       "})" *newline*)))
 927
 928 (define-compilation unwind-protect (form &rest clean-up)
 929   (js!selfcall
 930     "var ret = " (ls-compile nil) ";" *newline*
 931     "try {" *newline*
 932     (indent "ret = " (ls-compile form) ";" *newline*)
 933     "} finally {" *newline*
 934     (indent (ls-compile-block clean-up))
 935     "}" *newline*
 936     "return ret;" *newline*))
 937
 938 (define-compilation multiple-value-call (func-form &rest forms)
 939   (js!selfcall
 940     "var func = " (ls-compile func-form) ";" *newline*
 941     "var args = [" (if *multiple-value-p* "values" "pv") ", 0];" *newline*
 942     "return "
 943     (js!selfcall
 944       "var values = mv;" *newline*
 945       "var vs;" *newline*
 946       (mapconcat (lambda (form)
 947                    (code "vs = " (ls-compile form t) ";" *newline*
 948                          "if (typeof vs === 'object' && 'multiple-value' in vs)" *newline*
 949                          (indent "args = args.concat(vs);" *newline*)
 950                          "else" *newline*
 951                          (indent "args.push(vs);" *newline*)))
 952                  forms)
 953       "args[1] = args.length-2;" *newline*
 954       "return func.apply(window, args);" *newline*) ";" *newline*))
 955
 956 (define-compilation multiple-value-prog1 (first-form &rest forms)
 957   (js!selfcall
 958     "var args = " (ls-compile first-form *multiple-value-p*) ";" *newline*
 959     (ls-compile-block forms)
 960     "return args;" *newline*))
 961
 962 (define-transformation backquote (form)
 963   (bq-completely-process form))
 964
 965
 966 ;;; Primitives
 967
 968 (defvar *builtins* nil)
 969
 970 (defmacro define-raw-builtin (name args &body body)
 971   ;; Creates a new primitive function `name' with parameters args and
 972   ;; @body. The body can access to the local environment through the
 973   ;; variable *ENVIRONMENT*.
 974   `(push (list ',name (lambda ,args (block ,name ,@body)))
 975          *builtins*))
 976
 977 (defmacro define-builtin (name args &body body)
 978   `(define-raw-builtin ,name ,args
 979      (let ,(mapcar (lambda (arg) `(,arg (ls-compile ,arg))) args)
 980        ,@body)))
 981
 982 ;;; DECLS is a list of (JSVARNAME TYPE LISPFORM) declarations.
 983 (defmacro type-check (decls &body body)
 984   `(js!selfcall
 985      ,@(mapcar (lambda (decl)
 986                  `(code "var " ,(first decl) " = " ,(third decl) ";" *newline*))
 987                decls)
 988      ,@(mapcar (lambda (decl)
 989                  `(code "if (typeof " ,(first decl) " != '" ,(second decl) "')" *newline*
 990                         (indent "throw 'The value ' + "
 991                                 ,(first decl)
 992                                 " + ' is not a type "
 993                                 ,(second decl)
 994                                 ".';"
 995                                 *newline*)))
 996                decls)
 997      (code "return " (progn ,@body) ";" *newline*)))
 998
 999 ;;; VARIABLE-ARITY compiles variable arity operations. ARGS stands for
1000 ;;; a variable which holds a list of forms. It will compile them and
1001 ;;; store the result in some Javascript variables. BODY is evaluated
1002 ;;; with ARGS bound to the list of these variables to generate the
1003 ;;; code which performs the transformation on these variables.
1004
1005 (defun variable-arity-call (args function)
1006   (unless (consp args)
1007     (error "ARGS must be a non-empty list"))
1008   (let ((counter 0)
1009         (fargs '())
1010         (prelude ""))
1011     (dolist (x args)
1012       (cond
1013         ((floatp x) (push (float-to-string x) fargs))
1014         ((numberp x) (push (integer-to-string x) fargs))
1015         (t (let ((v (code "x" (incf counter))))
1016              (push v fargs)
1017              (concatf prelude
1018                (code "var " v " = " (ls-compile x) ";" *newline*
1019                      "if (typeof " v " !== 'number') throw 'Not a number!';"
1020                      *newline*))))))
1021     (js!selfcall prelude (funcall function (reverse fargs)))))
1022
1023
1024 (defmacro variable-arity (args &body body)
1025   (unless (symbolp args)
1026     (error "`~S' is not a symbol." args))
1027   `(variable-arity-call ,args
1028                         (lambda (,args)
1029                           (code "return " ,@body ";" *newline*))))
1030
1031 (defun num-op-num (x op y)
1032   (type-check (("x" "number" x) ("y" "number" y))
1033     (code "x" op "y")))
1034
1035 (define-raw-builtin + (&rest numbers)
1036   (if (null numbers)
1037       "0"
1038       (variable-arity numbers
1039         (join numbers "+"))))
1040
1041 (define-raw-builtin - (x &rest others)
1042   (let ((args (cons x others)))
1043     (variable-arity args
1044       (if (null others)
1045           (concat "-" (car args))
1046           (join args "-")))))
1047
1048 (define-raw-builtin * (&rest numbers)
1049   (if (null numbers)
1050       "1"
1051       (variable-arity numbers
1052         (join numbers "*"))))
1053
1054 (define-raw-builtin / (x &rest others)
1055   (let ((args (cons x others)))
1056     (variable-arity args
1057       (if (null others)
1058           (concat "1 /" (car args))
1059           (join args "/")))))
1060
1061 (define-builtin mod (x y) (num-op-num x "%" y))
1062
1063
1064 (defun comparison-conjuntion (vars op)
1065   (cond
1066     ((null (cdr vars))
1067      "true")
1068     ((null (cddr vars))
1069      (concat (car vars) op (cadr vars)))
1070     (t
1071      (concat (car vars) op (cadr vars)
1072              " && "
1073              (comparison-conjuntion (cdr vars) op)))))
1074
1075 (defmacro define-builtin-comparison (op sym)
1076   `(define-raw-builtin ,op (x &rest args)
1077      (let ((args (cons x args)))
1078        (variable-arity args
1079          (js!bool (comparison-conjuntion args ,sym))))))
1080
1081 (define-builtin-comparison > ">")
1082 (define-builtin-comparison < "<")
1083 (define-builtin-comparison >= ">=")
1084 (define-builtin-comparison <= "<=")
1085 (define-builtin-comparison = "==")
1086 (define-builtin-comparison /= "!=")
1087
1088 (define-builtin numberp (x)
1089   (js!bool (code "(typeof (" x ") == \"number\")")))
1090
1091 (define-builtin floor (x)
1092   (type-check (("x" "number" x))
1093     "Math.floor(x)"))
1094
1095 (define-builtin expt (x y)
1096   (type-check (("x" "number" x)
1097                ("y" "number" y))
1098     "Math.pow(x, y)"))
1099
1100 (define-builtin float-to-string (x)
1101   (type-check (("x" "number" x))
1102     "make_lisp_string(x.toString())"))
1103
1104 (define-builtin cons (x y)
1105   (code "({car: " x ", cdr: " y "})"))
1106
1107 (define-builtin consp (x)
1108   (js!bool
1109    (js!selfcall
1110      "var tmp = " x ";" *newline*
1111      "return (typeof tmp == 'object' && 'car' in tmp);" *newline*)))
1112
1113 (define-builtin car (x)
1114   (js!selfcall
1115     "var tmp = " x ";" *newline*
1116     "return tmp === " (ls-compile nil)
1117     "? " (ls-compile nil)
1118     ": tmp.car;" *newline*))
1119
1120 (define-builtin cdr (x)
1121   (js!selfcall
1122     "var tmp = " x ";" *newline*
1123     "return tmp === " (ls-compile nil) "? "
1124     (ls-compile nil)
1125     ": tmp.cdr;" *newline*))
1126
1127 (define-builtin rplaca (x new)
1128   (type-check (("x" "object" x))
1129     (code "(x.car = " new ", x)")))
1130
1131 (define-builtin rplacd (x new)
1132   (type-check (("x" "object" x))
1133     (code "(x.cdr = " new ", x)")))
1134
1135 (define-builtin symbolp (x)
1136   (js!bool (code "(" x " instanceof Symbol)")))
1137
1138 (define-builtin make-symbol (name)
1139   (code "(new Symbol(" name "))"))
1140
1141 (define-builtin symbol-name (x)
1142   (code "(" x ").name"))
1143
1144 (define-builtin set (symbol value)
1145   (code "(" symbol ").value = " value))
1146
1147 (define-builtin fset (symbol value)
1148   (code "(" symbol ").fvalue = " value))
1149
1150 (define-builtin boundp (x)
1151   (js!bool (code "(" x ".value !== undefined)")))
1152
1153 (define-builtin fboundp (x)
1154   (js!bool (code "(" x ".fvalue !== undefined)")))
1155
1156 (define-builtin symbol-value (x)
1157   (js!selfcall
1158     "var symbol = " x ";" *newline*
1159     "var value = symbol.value;" *newline*
1160     "if (value === undefined) throw \"Variable `\" + xstring(symbol.name) + \"' is unbound.\";" *newline*
1161     "return value;" *newline*))
1162
1163 (define-builtin symbol-function (x)
1164   (js!selfcall
1165     "var symbol = " x ";" *newline*
1166     "var func = symbol.fvalue;" *newline*
1167     "if (func === undefined) throw \"Function `\" + xstring(symbol.name) + \"' is undefined.\";" *newline*
1168     "return func;" *newline*))
1169
1170 (define-builtin symbol-plist (x)
1171   (code "((" x ").plist || " (ls-compile nil) ")"))
1172
1173 (define-builtin lambda-code (x)
1174   (code "make_lisp_string((" x ").toString())"))
1175
1176 (define-builtin eq (x y)
1177   (js!bool (code "(" x " === " y ")")))
1178
1179 (define-builtin char-code (x)
1180   (type-check (("x" "string" x))
1181     "x.charCodeAt(0)"))
1182
1183 (define-builtin code-char (x)
1184   (type-check (("x" "number" x))
1185     "String.fromCharCode(x)"))
1186
1187 (define-builtin characterp (x)
1188   (js!bool
1189    (js!selfcall
1190      "var x = " x ";" *newline*
1191      "return (typeof(" x ") == \"string\") && x.length == 1;")))
1192
1193 (define-builtin char-upcase (x)
1194   (code x ".toUpperCase()"))
1195
1196 (define-builtin char-downcase (x)
1197   (code x ".toLowerCase()"))
1198
1199 (define-builtin stringp (x)
1200   (js!bool
1201    (js!selfcall
1202      "var x = " x ";" *newline*
1203      "return typeof(x) == 'object' && 'length' in x && x.stringp == 1;")))
1204
1205 (define-raw-builtin funcall (func &rest args)
1206   (js!selfcall
1207     "var f = " (ls-compile func) ";" *newline*
1208     "return (typeof f === 'function'? f: f.fvalue)("
1209     (join (list* (if *multiple-value-p* "values" "pv")
1210                  (integer-to-string (length args))
1211                  (mapcar #'ls-compile args))
1212           ", ")
1213     ")"))
1214
1215 (define-raw-builtin apply (func &rest args)
1216   (if (null args)
1217       (code "(" (ls-compile func) ")()")
1218       (let ((args (butlast args))
1219             (last (car (last args))))
1220         (js!selfcall
1221           "var f = " (ls-compile func) ";" *newline*
1222           "var args = [" (join (list* (if *multiple-value-p* "values" "pv")
1223                                       (integer-to-string (length args))
1224                                       (mapcar #'ls-compile args))
1225                                ", ")
1226           "];" *newline*
1227           "var tail = (" (ls-compile last) ");" *newline*
1228           "while (tail != " (ls-compile nil) "){" *newline*
1229           "    args.push(tail.car);" *newline*
1230           "    args[1] += 1;" *newline*
1231           "    tail = tail.cdr;" *newline*
1232           "}" *newline*
1233           "return (typeof f === 'function'? f : f.fvalue).apply(this, args);" *newline*))))
1234
1235 (define-builtin js-eval (string)
1236   (if *multiple-value-p*
1237       (js!selfcall
1238         "var v = globalEval(xstring(" string "));" *newline*
1239         "return values.apply(this, forcemv(v));" *newline*)
1240       (code "globalEval(xstring(" string "))")))
1241
1242 (define-builtin %throw (string)
1243   (js!selfcall "throw " string ";" *newline*))
1244
1245 (define-builtin new () "{}")
1246
1247 (define-builtin objectp (x)
1248   (js!bool (code "(typeof (" x ") === 'object')")))
1249
1250 (define-builtin oget (object key)
1251   (js!selfcall
1252     "var tmp = " "(" object ")[xstring(" key ")];" *newline*
1253     "return tmp == undefined? " (ls-compile nil) ": tmp ;" *newline*))
1254
1255 (define-builtin oset (object key value)
1256   (code "((" object ")[xstring(" key ")] = " value ")"))
1257
1258 (define-builtin in (key object)
1259   (js!bool (code "(xstring(" key ") in (" object "))")))
1260
1261 (define-builtin map-for-in (function object)
1262   (js!selfcall
1263    "var f = " function ";" *newline*
1264    "var g = (typeof f === 'function' ? f : f.fvalue);" *newline*
1265    "var o = " object ";" *newline*
1266    "for (var key in o){" *newline*
1267    (indent "g(" (if *multiple-value-p* "values" "pv") ", 1, o[key]);" *newline*)
1268    "}"
1269    " return " (ls-compile nil) ";" *newline*))
1270
1271 (define-builtin functionp (x)
1272   (js!bool (code "(typeof " x " == 'function')")))
1273
1274 (define-builtin write-string (x)
1275   (code "lisp.write(" x ")"))
1276
1277
1278 ;;; Storage vectors. They are used to implement arrays and (in the
1279 ;;; future) structures.
1280
1281 (define-builtin storage-vector-p (x)
1282   (js!bool
1283    (js!selfcall
1284      "var x = " x ";" *newline*
1285      "return typeof x === 'object' && 'length' in x;")))
1286
1287 (define-builtin make-storage-vector (n)
1288   (js!selfcall
1289     "var r = [];" *newline*
1290     "r.length = " n ";" *newline*
1291     "return r;" *newline*))
1292
1293 (define-builtin storage-vector-size (x)
1294   (code x ".length"))
1295
1296 (define-builtin resize-storage-vector (vector new-size)
1297   (code "(" vector ".length = " new-size ")"))
1298
1299 (define-builtin storage-vector-ref (vector n)
1300   (js!selfcall
1301     "var x = " "(" vector ")[" n "];" *newline*
1302     "if (x === undefined) throw 'Out of range';" *newline*
1303     "return x;" *newline*))
1304
1305 (define-builtin storage-vector-set (vector n value)
1306   (js!selfcall
1307     "var x = " vector ";" *newline*
1308     "var i = " n ";" *newline*
1309     "if (i < 0 || i >= x.length) throw 'Out of range';" *newline*
1310     "return x[i] = " value ";" *newline*))
1311
1312
1313
1314 (define-builtin get-internal-real-time ()
1315   "(new Date()).getTime()")
1316
1317 (define-builtin values-array (array)
1318   (if *multiple-value-p*
1319       (code "values.apply(this, " array ")")
1320       (code "pv.apply(this, " array ")")))
1321
1322 (define-raw-builtin values (&rest args)
1323   (if *multiple-value-p*
1324       (code "values(" (join (mapcar #'ls-compile args) ", ") ")")
1325       (code "pv(" (join (mapcar #'ls-compile args) ", ") ")")))
1326
1327
1328 ;;; Javascript FFI
1329
1330 (define-compilation %js-vref (var)
1331   (code "js_to_lisp(" var ")"))
1332
1333 (define-compilation %js-vset (var val)
1334   (code "(" var " = lisp_to_js(" (ls-compile val) "))"))
1335
1336 (define-setf-expander %js-vref (var)
1337   (let ((new-value (gensym)))
1338     (unless (stringp var)
1339       (error "`~S' is not a string." var))
1340     (values nil
1341             (list var)
1342             (list new-value)
1343             `(%js-vset ,var ,new-value)
1344             `(%js-vref ,var))))
1345
1346
1347 #-jscl
1348 (defvar *macroexpander-cache*
1349   (make-hash-table :test #'eq))
1350
1351 (defun !macro-function (symbol)
1352   (unless (symbolp symbol)
1353     (error "`~S' is not a symbol." symbol))
1354   (let ((b (lookup-in-lexenv symbol *environment* 'function)))
1355     (if (and b (eq (binding-type b) 'macro))
1356         (let ((expander (binding-value b)))
1357           (cond
1358             #-jscl
1359             ((gethash b *macroexpander-cache*)
1360              (setq expander (gethash b *macroexpander-cache*)))
1361             ((listp expander)
1362              (let ((compiled (eval expander)))
1363                ;; The list representation are useful while
1364                ;; bootstrapping, as we can dump the definition of the
1365                ;; macros easily, but they are slow because we have to
1366                ;; evaluate them and compile them now and again. So, let
1367                ;; us replace the list representation version of the
1368                ;; function with the compiled one.
1369                ;;
1370                #+jscl (setf (binding-value b) compiled)
1371                #-jscl (setf (gethash b *macroexpander-cache*) compiled)
1372                (setq expander compiled))))
1373           expander)
1374         nil)))
1375
1376 (defun !macroexpand-1 (form)
1377   (cond
1378     ((symbolp form)
1379      (let ((b (lookup-in-lexenv form *environment* 'variable)))
1380        (if (and b (eq (binding-type b) 'macro))
1381            (values (binding-value b) t)
1382            (values form nil))))
1383     ((and (consp form) (symbolp (car form)))
1384      (let ((macrofun (!macro-function (car form))))
1385        (if macrofun
1386            (values (funcall macrofun (cdr form)) t)
1387            (values form nil))))
1388     (t
1389      (values form nil))))
1390
1391 (defun compile-funcall (function args)
1392   (let* ((values-funcs (if *multiple-value-p* "values" "pv"))
1393          (arglist (concat "(" (join (list* values-funcs
1394                                            (integer-to-string (length args))
1395                                            (mapcar #'ls-compile args)) ", ") ")")))
1396     (unless (or (symbolp function)
1397                 (and (consp function)
1398                      (eq (car function) 'lambda)))
1399       (error "Bad function designator `~S'" function))
1400     (cond
1401       ((translate-function function)
1402        (concat (translate-function function) arglist))
1403       ((and (symbolp function)
1404             #+jscl (eq (symbol-package function) (find-package "COMMON-LISP"))
1405             #-jscl t)
1406        (code (ls-compile `',function) ".fvalue" arglist))
1407       (t
1408        (code (ls-compile `#',function) arglist)))))
1409
1410 (defun ls-compile-block (sexps &optional return-last-p decls-allowed-p)
1411   (multiple-value-bind (sexps decls)
1412       (parse-body sexps :declarations decls-allowed-p)
1413     (declare (ignore decls))
1414     (if return-last-p
1415         (code (ls-compile-block (butlast sexps) nil decls-allowed-p)
1416               "return " (ls-compile (car (last sexps)) *multiple-value-p*) ";")
1417         (join-trailing
1418          (remove-if #'null-or-empty-p (mapcar #'ls-compile sexps))
1419          (concat ";" *newline*)))))
1420
1421 (defun ls-compile (sexp &optional multiple-value-p)
1422   (multiple-value-bind (sexp expandedp) (!macroexpand-1 sexp)
1423     (when expandedp
1424       (return-from ls-compile (ls-compile sexp multiple-value-p)))
1425     ;; The expression has been macroexpanded. Now compile it!
1426     (let ((*multiple-value-p* multiple-value-p))
1427       (cond
1428         ((symbolp sexp)
1429          (let ((b (lookup-in-lexenv sexp *environment* 'variable)))
1430            (cond
1431              ((and b (not (member 'special (binding-declarations b))))
1432               (binding-value b))
1433              ((or (keywordp sexp)
1434                   (and b (member 'constant (binding-declarations b))))
1435               (code (ls-compile `',sexp) ".value"))
1436              (t
1437               (ls-compile `(symbol-value ',sexp))))))
1438         ((or (integerp sexp) (floatp sexp) (characterp sexp) (stringp sexp) (arrayp sexp))
1439          (literal sexp))
1440         ((listp sexp)
1441          (let ((name (car sexp))
1442                (args (cdr sexp)))
1443            (cond
1444              ;; Special forms
1445              ((assoc name *compilations*)
1446               (let ((comp (second (assoc name *compilations*))))
1447                 (apply comp args)))
1448              ;; Built-in functions
1449              ((and (assoc name *builtins*)
1450                    (not (claimp name 'function 'notinline)))
1451               (let ((comp (second (assoc name *builtins*))))
1452                 (apply comp args)))
1453              (t
1454               (compile-funcall name args)))))
1455         (t
1456          (error "How should I compile `~S'?" sexp))))))
1457
1458
1459 (defvar *compile-print-toplevels* nil)
1460
1461 (defun truncate-string (string &optional (width 60))
1462   (let ((n (or (position #\newline string)
1463                (min width (length string)))))
1464     (subseq string 0 n)))
1465
1466 (defun ls-compile-toplevel (sexp &optional multiple-value-p)
1467   (let ((*toplevel-compilations* nil))
1468     (cond
1469       ((and (consp sexp) (eq (car sexp) 'progn))
1470        (let ((subs (mapcar (lambda (s)
1471                              (ls-compile-toplevel s t))
1472                            (cdr sexp))))
1473          (join (remove-if #'null-or-empty-p subs))))
1474       (t
1475        (when *compile-print-toplevels*
1476          (let ((form-string (prin1-to-string sexp)))
1477            (format t "Compiling ~a..." (truncate-string form-string))))
1478        (let ((code (ls-compile sexp multiple-value-p)))
1479          (code (join-trailing (get-toplevel-compilations)
1480                               (code ";" *newline*))
1481                (when code
1482                  (code code ";" *newline*))))))))