src/pcl/boot.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 #|
  27
  28 The CommonLoops evaluator is meta-circular.
  29
  30 Most of the code in PCL is methods on generic functions, including
  31 most of the code that actually implements generic functions and method
  32 lookup.
  33
  34 So, we have a classic bootstrapping problem. The solution to this is
  35 to first get a cheap implementation of generic functions running,
  36 these are called early generic functions. These early generic
  37 functions and the corresponding early methods and early method lookup
  38 are used to get enough of the system running that it is possible to
  39 create real generic functions and methods and implement real method
  40 lookup. At that point (done in the file FIXUP) the function
  41 !FIX-EARLY-GENERIC-FUNCTIONS is called to convert all the early generic
  42 functions to real generic functions.
  43
  44 The cheap generic functions are built using the same
  45 FUNCALLABLE-INSTANCE objects that real generic functions are made out of.
  46 This means that as PCL is being bootstrapped, the cheap generic
  47 function objects which are being created are the same objects which
  48 will later be real generic functions. This is good because:
  49   - we don't cons garbage structure, and
  50   - we can keep pointers to the cheap generic function objects
  51     during booting because those pointers will still point to
  52     the right object after the generic functions are all fixed up.
  53
  54 This file defines the DEFMETHOD macro and the mechanism used to expand
  55 it. This includes the mechanism for processing the body of a method.
  56 DEFMETHOD basically expands into a call to LOAD-DEFMETHOD, which
  57 basically calls ADD-METHOD to add the method to the generic function.
  58 These expansions can be loaded either during bootstrapping or when PCL
  59 is fully up and running.
  60
  61 An important effect of this arrangement is it means we can compile
  62 files with DEFMETHOD forms in them in a completely running PCL, but
  63 then load those files back in during bootstrapping. This makes
  64 development easier. It also means there is only one set of code for
  65 processing DEFMETHOD. Bootstrapping works by being sure to have
  66 LOAD-METHOD be careful to call only primitives which work during
  67 bootstrapping.
  68
  69 |#
  70
  71 (declaim (notinline make-a-method
  72                     add-named-method
  73                     ensure-generic-function-using-class
  74                     add-method
  75                     remove-method))
  76
  77 (defvar *!early-functions*
  78         '((make-a-method early-make-a-method
  79                          real-make-a-method)
  80           (add-named-method early-add-named-method
  81                             real-add-named-method)
  82           ))
  83
  84 ;;; For each of the early functions, arrange to have it point to its
  85 ;;; early definition. Do this in a way that makes sure that if we
  86 ;;; redefine one of the early definitions the redefinition will take
  87 ;;; effect. This makes development easier.
  88 (dolist (fns *!early-functions*)
  89   (let ((name (car fns))
  90         (early-name (cadr fns)))
  91     (setf (gdefinition name)
  92             (set-fun-name
  93              (lambda (&rest args)
  94                (apply (fdefinition early-name) args))
  95              name))))
  96
  97 ;;; *!GENERIC-FUNCTION-FIXUPS* is used by !FIX-EARLY-GENERIC-FUNCTIONS
  98 ;;; to convert the few functions in the bootstrap which are supposed
  99 ;;; to be generic functions but can't be early on.
 100 (defvar *!generic-function-fixups*
 101   '((add-method
 102      ((generic-function method)  ;lambda-list
 103       (standard-generic-function method) ;specializers
 104       real-add-method))          ;method-function
 105     (remove-method
 106      ((generic-function method)
 107       (standard-generic-function method)
 108       real-remove-method))
 109     (get-method
 110      ((generic-function qualifiers specializers &optional (errorp t))
 111       (standard-generic-function t t)
 112       real-get-method))
 113     (ensure-generic-function-using-class
 114      ((generic-function fun-name
 115                         &key generic-function-class environment
 116                         &allow-other-keys)
 117       (generic-function t)
 118       real-ensure-gf-using-class--generic-function)
 119      ((generic-function fun-name
 120                         &key generic-function-class environment
 121                         &allow-other-keys)
 122       (null t)
 123       real-ensure-gf-using-class--null))
 124     (make-method-lambda
 125      ((proto-generic-function proto-method lambda-expression environment)
 126       (standard-generic-function standard-method t t)
 127       real-make-method-lambda))
 128     (make-method-initargs-form
 129      ((proto-generic-function proto-method
 130                               lambda-expression
 131                               lambda-list environment)
 132       (standard-generic-function standard-method t t t)
 133       real-make-method-initargs-form))
 134     (compute-effective-method
 135      ((generic-function combin applicable-methods)
 136       (generic-function standard-method-combination t)
 137       standard-compute-effective-method))))
 138 \f
 139 (defmacro defgeneric (fun-name lambda-list &body options)
 140   (declare (type list lambda-list))
 141   (unless (legal-fun-name-p fun-name)
 142     (error 'simple-program-error
 143            :format-control "illegal generic function name ~S"
 144            :format-arguments (list fun-name)))
 145   (check-gf-lambda-list lambda-list)
 146   (let ((initargs ())
 147         (methods ()))
 148     (flet ((duplicate-option (name)
 149              (error 'simple-program-error
 150                     :format-control "The option ~S appears more than once."
 151                     :format-arguments (list name)))
 152            (expand-method-definition (qab) ; QAB = qualifiers, arglist, body
 153              (let* ((arglist-pos (position-if #'listp qab))
 154                     (arglist (elt qab arglist-pos))
 155                     (qualifiers (subseq qab 0 arglist-pos))
 156                     (body (nthcdr (1+ arglist-pos) qab)))
 157                `(push (defmethod ,fun-name ,@qualifiers ,arglist ,@body)
 158                       (generic-function-initial-methods (fdefinition ',fun-name))))))
 159       (macrolet ((initarg (key) `(getf initargs ,key)))
 160         (dolist (option options)
 161           (let ((car-option (car option)))
 162             (case car-option
 163               (declare
 164                (when (and
 165                       (consp (cadr option))
 166                       (member (first (cadr option))
 167                               ;; FIXME: this list is slightly weird.
 168                               ;; ANSI (on the DEFGENERIC page) in one
 169                               ;; place allows only OPTIMIZE; in
 170                               ;; another place gives this list of
 171                               ;; disallowed declaration specifiers.
 172                               ;; This seems to be the only place where
 173                               ;; the FUNCTION declaration is
 174                               ;; mentioned; TYPE seems to be missing.
 175                               ;; Very strange.  -- CSR, 2002-10-21
 176                               '(declaration ftype function
 177                                 inline notinline special)))
 178                  (error 'simple-program-error
 179                         :format-control "The declaration specifier ~S ~
 180                                          is not allowed inside DEFGENERIC."
 181                         :format-arguments (list (cadr option))))
 182                (push (cadr option) (initarg :declarations)))
 183               (:method-combination
 184                (when (initarg car-option)
 185                  (duplicate-option car-option))
 186                (unless (symbolp (cadr option))
 187                  (error 'simple-program-error
 188                         :format-control "METHOD-COMBINATION name not a ~
 189                                          symbol: ~S"
 190                         :format-arguments (list (cadr option))))
 191                (setf (initarg car-option)
 192                      `',(cdr option)))
 193               (:argument-precedence-order
 194                (let* ((required (parse-lambda-list lambda-list))
 195                       (supplied (cdr option)))
 196                  (unless (= (length required) (length supplied))
 197                    (error 'simple-program-error
 198                           :format-control "argument count discrepancy in ~
 199                                            :ARGUMENT-PRECEDENCE-ORDER clause."
 200                           :format-arguments nil))
 201                  (when (set-difference required supplied)
 202                    (error 'simple-program-error
 203                           :format-control "unequal sets for ~
 204                                            :ARGUMENT-PRECEDENCE-ORDER clause: ~
 205                                            ~S and ~S"
 206                           :format-arguments (list required supplied)))
 207                  (setf (initarg car-option)
 208                        `',(cdr option))))
 209               ((:documentation :generic-function-class :method-class)
 210                (unless (proper-list-of-length-p option 2)
 211                  (error "bad list length for ~S" option))
 212                (if (initarg car-option)
 213                    (duplicate-option car-option)
 214                    (setf (initarg car-option) `',(cadr option))))
 215               (:method
 216                (push (cdr option) methods))
 217               (t
 218                ;; ANSI requires that unsupported things must get a
 219                ;; PROGRAM-ERROR.
 220                (error 'simple-program-error
 221                       :format-control "unsupported option ~S"
 222                       :format-arguments (list option))))))
 223
 224         (when (initarg :declarations)
 225           (setf (initarg :declarations)
 226                 `',(initarg :declarations))))
 227       `(progn
 228          (eval-when (:compile-toplevel :load-toplevel :execute)
 229            (compile-or-load-defgeneric ',fun-name))
 230          (load-defgeneric ',fun-name ',lambda-list
 231                           (sb-c:source-location) ,@initargs)
 232         ,@(mapcar #'expand-method-definition methods)
 233         (fdefinition ',fun-name)))))
 234
 235 (defun compile-or-load-defgeneric (fun-name)
 236   (proclaim-as-fun-name fun-name)
 237   (note-name-defined fun-name :function)
 238   (unless (eq (info :function :where-from fun-name) :declared)
 239     (setf (info :function :where-from fun-name) :defined)
 240     (setf (info :function :type fun-name)
 241           (specifier-type 'function))))
 242
 243 (defun load-defgeneric (fun-name lambda-list source-location &rest initargs)
 244   (when (fboundp fun-name)
 245     (style-warn "redefining ~S in DEFGENERIC" fun-name)
 246     (let ((fun (fdefinition fun-name)))
 247       (when (generic-function-p fun)
 248         (loop for method in (generic-function-initial-methods fun)
 249               do (remove-method fun method))
 250         (setf (generic-function-initial-methods fun) '()))))
 251   (apply #'ensure-generic-function
 252          fun-name
 253          :lambda-list lambda-list
 254          :definition-source source-location
 255          initargs))
 256
 257 (define-condition generic-function-lambda-list-error
 258     (reference-condition simple-program-error)
 259   ()
 260   (:default-initargs :references (list '(:ansi-cl :section (3 4 2)))))
 261
 262 (defun check-gf-lambda-list (lambda-list)
 263   (flet ((ensure (arg ok)
 264            (unless ok
 265              (error 'generic-function-lambda-list-error
 266                     :format-control
 267                     "~@<invalid ~S ~_in the generic function lambda list ~S~:>"
 268                     :format-arguments (list arg lambda-list)))))
 269     (multiple-value-bind (required optional restp rest keyp keys allowp
 270                           auxp aux morep more-context more-count)
 271         (parse-lambda-list lambda-list)
 272       (declare (ignore required)) ; since they're no different in a gf ll
 273       (declare (ignore restp rest)) ; since they're no different in a gf ll
 274       (declare (ignore allowp)) ; since &ALLOW-OTHER-KEYS is fine either way
 275       (declare (ignore aux)) ; since we require AUXP=NIL
 276       (declare (ignore more-context more-count)) ; safely ignored unless MOREP
 277       ;; no defaults allowed for &OPTIONAL arguments
 278       (dolist (i optional)
 279         (ensure i (or (symbolp i)
 280                       (and (consp i) (symbolp (car i)) (null (cdr i))))))
 281       ;; no defaults allowed for &KEY arguments
 282       (when keyp
 283         (dolist (i keys)
 284           (ensure i (or (symbolp i)
 285                         (and (consp i)
 286                              (or (symbolp (car i))
 287                                  (and (consp (car i))
 288                                       (symbolp (caar i))
 289                                       (symbolp (cadar i))
 290                                       (null (cddar i))))
 291                              (null (cdr i)))))))
 292       ;; no &AUX allowed
 293       (when auxp
 294         (error "&AUX is not allowed in a generic function lambda list: ~S"
 295                lambda-list))
 296       ;; Oh, *puhlease*... not specifically as per section 3.4.2 of
 297       ;; the ANSI spec, but the CMU CL &MORE extension does not
 298       ;; belong here!
 299       (aver (not morep)))))
 300 \f
 301 (defmacro defmethod (&rest args &environment env)
 302   (multiple-value-bind (name qualifiers lambda-list body)
 303       (parse-defmethod args)
 304     (multiple-value-bind (proto-gf proto-method)
 305         (prototypes-for-make-method-lambda name)
 306       (expand-defmethod name
 307                         proto-gf
 308                         proto-method
 309                         qualifiers
 310                         lambda-list
 311                         body
 312                         env))))
 313
 314 (defun prototypes-for-make-method-lambda (name)
 315   (if (not (eq *boot-state* 'complete))
 316       (values nil nil)
 317       (let ((gf? (and (fboundp name)
 318                       (gdefinition name))))
 319         (if (or (null gf?)
 320                 (not (generic-function-p gf?)))
 321             (values (class-prototype (find-class 'standard-generic-function))
 322                     (class-prototype (find-class 'standard-method)))
 323             (values gf?
 324                     (class-prototype (or (generic-function-method-class gf?)
 325                                          (find-class 'standard-method))))))))
 326
 327 ;;; Take a name which is either a generic function name or a list specifying
 328 ;;; a SETF generic function (like: (SETF <generic-function-name>)). Return
 329 ;;; the prototype instance of the method-class for that generic function.
 330 ;;;
 331 ;;; If there is no generic function by that name, this returns the
 332 ;;; default value, the prototype instance of the class
 333 ;;; STANDARD-METHOD. This default value is also returned if the spec
 334 ;;; names an ordinary function or even a macro. In effect, this leaves
 335 ;;; the signalling of the appropriate error until load time.
 336 ;;;
 337 ;;; Note: During bootstrapping, this function is allowed to return NIL.
 338 (defun method-prototype-for-gf (name)
 339   (let ((gf? (and (fboundp name)
 340                   (gdefinition name))))
 341     (cond ((neq *boot-state* 'complete) nil)
 342           ((or (null gf?)
 343                (not (generic-function-p gf?)))          ; Someone else MIGHT
 344                                                         ; error at load time.
 345            (class-prototype (find-class 'standard-method)))
 346           (t
 347             (class-prototype (or (generic-function-method-class gf?)
 348                                  (find-class 'standard-method)))))))
 349 \f
 350 (defun expand-defmethod (name
 351                          proto-gf
 352                          proto-method
 353                          qualifiers
 354                          lambda-list
 355                          body
 356                          env)
 357   (multiple-value-bind (method-lambda unspecialized-lambda-list specializers)
 358       (add-method-declarations name qualifiers lambda-list body env)
 359     (multiple-value-bind (method-function-lambda initargs)
 360         (make-method-lambda proto-gf proto-method method-lambda env)
 361       (let ((initargs-form (make-method-initargs-form proto-gf
 362                                                       proto-method
 363                                                       method-function-lambda
 364                                                       initargs
 365                                                       env)))
 366         `(progn
 367           ;; Note: We could DECLAIM the ftype of the generic function
 368           ;; here, since ANSI specifies that we create it if it does
 369           ;; not exist. However, I chose not to, because I think it's
 370           ;; more useful to support a style of programming where every
 371           ;; generic function has an explicit DEFGENERIC and any typos
 372           ;; in DEFMETHODs are warned about. Otherwise
 373           ;;
 374           ;;   (DEFGENERIC FOO-BAR-BLETCH ((X T)))
 375           ;;   (DEFMETHOD FOO-BAR-BLETCH ((X HASH-TABLE)) ..)
 376           ;;   (DEFMETHOD FOO-BRA-BLETCH ((X SIMPLE-VECTOR)) ..)
 377           ;;   (DEFMETHOD FOO-BAR-BLETCH ((X VECTOR)) ..)
 378           ;;   (DEFMETHOD FOO-BAR-BLETCH ((X ARRAY)) ..)
 379           ;;   (DEFMETHOD FOO-BAR-BLETCH ((X LIST)) ..)
 380           ;;
 381           ;; compiles without raising an error and runs without
 382           ;; raising an error (since SIMPLE-VECTOR cases fall through
 383           ;; to VECTOR) but still doesn't do what was intended. I hate
 384           ;; that kind of bug (code which silently gives the wrong
 385           ;; answer), so we don't do a DECLAIM here. -- WHN 20000229
 386           ,(make-defmethod-form name qualifiers specializers
 387                                 unspecialized-lambda-list
 388                                 (if proto-method
 389                                     (class-name (class-of proto-method))
 390                                     'standard-method)
 391                                 initargs-form
 392                                 (getf (getf initargs :plist)
 393                                       :pv-table-symbol)))))))
 394
 395 (defun interned-symbol-p (x)
 396   (and (symbolp x) (symbol-package x)))
 397
 398 (defun make-defmethod-form (name qualifiers specializers
 399                                  unspecialized-lambda-list method-class-name
 400                                  initargs-form &optional pv-table-symbol)
 401   (let (fn
 402         fn-lambda)
 403     (if (and (interned-symbol-p (fun-name-block-name name))
 404              (every #'interned-symbol-p qualifiers)
 405              (every (lambda (s)
 406                       (if (consp s)
 407                           (and (eq (car s) 'eql)
 408                                (constantp (cadr s))
 409                                (let ((sv (eval (cadr s))))
 410                                  (or (interned-symbol-p sv)
 411                                      (integerp sv)
 412                                      (and (characterp sv)
 413                                           (standard-char-p sv)))))
 414                           (interned-symbol-p s)))
 415                     specializers)
 416              (consp initargs-form)
 417              (eq (car initargs-form) 'list*)
 418              (memq (cadr initargs-form) '(:function :fast-function))
 419              (consp (setq fn (caddr initargs-form)))
 420              (eq (car fn) 'function)
 421              (consp (setq fn-lambda (cadr fn)))
 422              (eq (car fn-lambda) 'lambda))
 423         (let* ((specls (mapcar (lambda (specl)
 424                                  (if (consp specl)
 425                                      `(,(car specl) ,(eval (cadr specl)))
 426                                    specl))
 427                                specializers))
 428                (mname `(,(if (eq (cadr initargs-form) :function)
 429                              'slow-method 'fast-method)
 430                         ,name ,@qualifiers ,specls)))
 431           `(progn
 432              (defun ,mname ,(cadr fn-lambda)
 433                ,@(cddr fn-lambda))
 434              ,(make-defmethod-form-internal
 435                name qualifiers `',specls
 436                unspecialized-lambda-list method-class-name
 437                `(list* ,(cadr initargs-form)
 438                        #',mname
 439                        ,@(cdddr initargs-form))
 440                pv-table-symbol)))
 441         (make-defmethod-form-internal
 442          name qualifiers
 443          `(list ,@(mapcar (lambda (specializer)
 444                             (if (consp specializer)
 445                                 ``(,',(car specializer)
 446                                       ,,(cadr specializer))
 447                                 `',specializer))
 448                           specializers))
 449          unspecialized-lambda-list
 450          method-class-name
 451          initargs-form
 452          pv-table-symbol))))
 453
 454 (defun make-defmethod-form-internal
 455     (name qualifiers specializers-form unspecialized-lambda-list
 456      method-class-name initargs-form &optional pv-table-symbol)
 457   `(load-defmethod
 458     ',method-class-name
 459     ',name
 460     ',qualifiers
 461     ,specializers-form
 462     ',unspecialized-lambda-list
 463     ,initargs-form
 464     ;; Paper over a bug in KCL by passing the cache-symbol here in
 465     ;; addition to in the list. FIXME: We should no longer need to do
 466     ;; this, since the CLOS code is now SBCL-specific, and doesn't
 467     ;; need to be ported to every buggy compiler in existence.
 468     ',pv-table-symbol
 469     (sb-c:source-location)))
 470
 471 (defmacro make-method-function (method-lambda &environment env)
 472   (make-method-function-internal method-lambda env))
 473
 474 (defun make-method-function-internal (method-lambda &optional env)
 475   (multiple-value-bind (proto-gf proto-method)
 476       (prototypes-for-make-method-lambda nil)
 477     (multiple-value-bind (method-function-lambda initargs)
 478         (make-method-lambda proto-gf proto-method method-lambda env)
 479       (make-method-initargs-form proto-gf
 480                                  proto-method
 481                                  method-function-lambda
 482                                  initargs
 483                                  env))))
 484
 485 (defun add-method-declarations (name qualifiers lambda-list body env)
 486   (declare (ignore env))
 487   (multiple-value-bind (parameters unspecialized-lambda-list specializers)
 488       (parse-specialized-lambda-list lambda-list)
 489     (multiple-value-bind (real-body declarations documentation)
 490         (parse-body body)
 491       (values `(lambda ,unspecialized-lambda-list
 492                  ,@(when documentation `(,documentation))
 493                  ;; (Old PCL code used a somewhat different style of
 494                  ;; list for %METHOD-NAME values. Our names use
 495                  ;; ,@QUALIFIERS instead of ,QUALIFIERS so that the
 496                  ;; method names look more like what you see in a
 497                  ;; DEFMETHOD form.)
 498                  ;;
 499                  ;; FIXME: As of sbcl-0.7.0.6, code elsewhere, at
 500                  ;; least the code to set up named BLOCKs around the
 501                  ;; bodies of methods, depends on the function's base
 502                  ;; name being the first element of the %METHOD-NAME
 503                  ;; list. It would be good to remove this dependency,
 504                  ;; perhaps by building the BLOCK here, or by using
 505                  ;; another declaration (e.g. %BLOCK-NAME), so that
 506                  ;; our method debug names are free to have any format,
 507                  ;; e.g. (:METHOD PRINT-OBJECT :AROUND (CLOWN T)).
 508                  ;;
 509                  ;; Further, as of sbcl-0.7.9.10, the code to
 510                  ;; implement NO-NEXT-METHOD is coupled to the form of
 511                  ;; this declaration; see the definition of
 512                  ;; CALL-NO-NEXT-METHOD (and the passing of
 513                  ;; METHOD-NAME-DECLARATION arguments around the
 514                  ;; various CALL-NEXT-METHOD logic).
 515                  (declare (%method-name (,name
 516                                          ,@qualifiers
 517                                          ,specializers)))
 518                  (declare (%method-lambda-list ,@lambda-list))
 519                  ,@declarations
 520                  ,@real-body)
 521               unspecialized-lambda-list specializers))))
 522
 523 (defun real-make-method-initargs-form (proto-gf proto-method
 524                                        method-lambda initargs env)
 525   (declare (ignore proto-gf proto-method))
 526   (unless (and (consp method-lambda)
 527                (eq (car method-lambda) 'lambda))
 528     (error "The METHOD-LAMBDA argument to MAKE-METHOD-FUNCTION, ~S, ~
 529             is not a lambda form."
 530            method-lambda))
 531   (make-method-initargs-form-internal method-lambda initargs env))
 532
 533 (unless (fboundp 'make-method-initargs-form)
 534   (setf (gdefinition 'make-method-initargs-form)
 535         (symbol-function 'real-make-method-initargs-form)))
 536
 537 (defun real-make-method-lambda (proto-gf proto-method method-lambda env)
 538   (declare (ignore proto-gf proto-method))
 539   (make-method-lambda-internal method-lambda env))
 540
 541 ;;; a helper function for creating Python-friendly type declarations
 542 ;;; in DEFMETHOD forms
 543 (defun parameter-specializer-declaration-in-defmethod (parameter specializer)
 544   (cond ((and (consp specializer)
 545               (eq (car specializer) 'eql))
 546          ;; KLUDGE: ANSI, in its wisdom, says that
 547          ;; EQL-SPECIALIZER-FORMs in EQL specializers are evaluated at
 548          ;; DEFMETHOD expansion time. Thus, although one might think
 549          ;; that in
 550          ;;   (DEFMETHOD FOO ((X PACKAGE)
 551          ;;                   (Y (EQL 12))
 552          ;;      ..))
 553          ;; the PACKAGE and (EQL 12) forms are both parallel type
 554          ;; names, they're not, as is made clear when you do
 555          ;;   (DEFMETHOD FOO ((X PACKAGE)
 556          ;;                   (Y (EQL 'BAR)))
 557          ;;     ..)
 558          ;; where Y needs to be a symbol named "BAR", not some cons
 559          ;; made by (CONS 'QUOTE 'BAR). I.e. when the
 560          ;; EQL-SPECIALIZER-FORM is (EQL 'X), it requires an argument
 561          ;; to be of type (EQL X). It'd be easy to transform one to
 562          ;; the other, but it'd be somewhat messier to do so while
 563          ;; ensuring that the EQL-SPECIALIZER-FORM is only EVAL'd
 564          ;; once. (The new code wouldn't be messy, but it'd require a
 565          ;; big transformation of the old code.) So instead we punt.
 566          ;; -- WHN 20000610
 567          '(ignorable))
 568         ((member specializer
 569                  ;; KLUDGE: For some low-level implementation
 570                  ;; classes, perhaps because of some problems related
 571                  ;; to the incomplete integration of PCL into SBCL's
 572                  ;; type system, some specializer classes can't be
 573                  ;; declared as argument types. E.g.
 574                  ;;   (DEFMETHOD FOO ((X SLOT-OBJECT))
 575                  ;;     (DECLARE (TYPE SLOT-OBJECT X))
 576                  ;;     ..)
 577                  ;; loses when
 578                  ;;   (DEFSTRUCT BAR A B)
 579                  ;;   (FOO (MAKE-BAR))
 580                  ;; perhaps because of the way that STRUCTURE-OBJECT
 581                  ;; inherits both from SLOT-OBJECT and from
 582                  ;; SB-KERNEL:INSTANCE. In an effort to sweep such
 583                  ;; problems under the rug, we exclude these problem
 584                  ;; cases by blacklisting them here. -- WHN 2001-01-19
 585                  '(slot-object))
 586          '(ignorable))
 587         ((not (eq *boot-state* 'complete))
 588          ;; KLUDGE: PCL, in its wisdom, sometimes calls methods with
 589          ;; types which don't match their specializers. (Specifically,
 590          ;; it calls ENSURE-CLASS-USING-CLASS (T NULL) with a non-NULL
 591          ;; second argument.) Hopefully it only does this kind of
 592          ;; weirdness when bootstrapping.. -- WHN 20000610
 593          '(ignorable))
 594         ((var-globally-special-p parameter)
 595          ;; KLUDGE: Don't declare types for global special variables
 596          ;; -- our rebinding magic for SETQ cases don't work right
 597          ;; there.
 598          ;;
 599          ;; FIXME: It would be better to detect the SETQ earlier and
 600          ;; skip declarations for specials only when needed, not
 601          ;; always.
 602          ;;
 603          ;; --NS 2004-10-14
 604          '(ignorable))
 605         (t
 606          ;; Otherwise, we can usually make Python very happy.
 607          (let ((kind (info :type :kind specializer)))
 608            (ecase kind
 609              ((:primitive) `(type ,specializer ,parameter))
 610              ((:defined)
 611               (let ((class (find-class specializer nil)))
 612                 ;; CLASS can be null here if the user has erroneously
 613                 ;; tried to use a defined type as a specializer; it
 614                 ;; can be a non-BUILT-IN-CLASS if the user defines a
 615                 ;; type and calls (SETF FIND-CLASS) in a consistent
 616                 ;; way.
 617                 (when (and class (typep class 'built-in-class))
 618                   `(type ,specializer ,parameter))))
 619              ((:instance nil)
 620               (let ((class (find-class specializer nil)))
 621                 (cond
 622                   (class
 623                    (if (typep class '(or built-in-class structure-class))
 624                        `(type ,specializer ,parameter)
 625                        ;; don't declare CLOS classes as parameters;
 626                        ;; it's too expensive.
 627                        '(ignorable)))
 628                   (t
 629                    ;; we can get here, and still not have a failure
 630                    ;; case, by doing MOP programming like (PROGN
 631                    ;; (ENSURE-CLASS 'FOO) (DEFMETHOD BAR ((X FOO))
 632                    ;; ...)).  Best to let the user know we haven't
 633                    ;; been able to extract enough information:
 634                    (style-warn
 635                     "~@<can't find type for presumed class ~S in ~S.~@:>"
 636                     specializer
 637                     'parameter-specializer-declaration-in-defmethod)
 638                    '(ignorable)))))
 639              ((:forthcoming-defclass-type) '(ignorable)))))))
 640
 641 (defun make-method-lambda-internal (method-lambda &optional env)
 642   (unless (and (consp method-lambda) (eq (car method-lambda) 'lambda))
 643     (error "The METHOD-LAMBDA argument to MAKE-METHOD-LAMBDA, ~S, ~
 644             is not a lambda form."
 645            method-lambda))
 646   (multiple-value-bind (real-body declarations documentation)
 647       (parse-body (cddr method-lambda))
 648     (let* ((name-decl (get-declaration '%method-name declarations))
 649            (sll-decl (get-declaration '%method-lambda-list declarations))
 650            (method-name (when (consp name-decl) (car name-decl)))
 651            (generic-function-name (when method-name (car method-name)))
 652            (specialized-lambda-list (or sll-decl (cadr method-lambda))))
 653       (multiple-value-bind (parameters lambda-list specializers)
 654           (parse-specialized-lambda-list specialized-lambda-list)
 655         (let* ((required-parameters
 656                 (mapcar (lambda (r s) (declare (ignore s)) r)
 657                         parameters
 658                         specializers))
 659                (slots (mapcar #'list required-parameters))
 660                (calls (list nil))
 661                (class-declarations
 662                 `(declare
 663                   ;; These declarations seem to be used by PCL to pass
 664                   ;; information to itself; when I tried to delete 'em
 665                   ;; ca. 0.6.10 it didn't work. I'm not sure how
 666                   ;; they work, but note the (VAR-DECLARATION '%CLASS ..)
 667                   ;; expression in CAN-OPTIMIZE-ACCESS1. -- WHN 2000-12-30
 668                   ,@(remove nil
 669                             (mapcar (lambda (a s) (and (symbolp s)
 670                                                        (neq s t)
 671                                                        `(%class ,a ,s)))
 672                                     parameters
 673                                     specializers))
 674                   ;; These TYPE declarations weren't in the original
 675                   ;; PCL code, but the Python compiler likes them a
 676                   ;; lot. (We're telling the compiler about our
 677                   ;; knowledge of specialized argument types so that
 678                   ;; it can avoid run-time type dispatch overhead,
 679                   ;; which can be a huge win for Python.)
 680                   ;;
 681                   ;; KLUDGE: when I tried moving these to
 682                   ;; ADD-METHOD-DECLARATIONS, things broke.  No idea
 683                   ;; why.  -- CSR, 2004-06-16
 684                   ,@(mapcar #'parameter-specializer-declaration-in-defmethod
 685                             parameters
 686                             specializers)))
 687                (method-lambda
 688                 ;; Remove the documentation string and insert the
 689                 ;; appropriate class declarations. The documentation
 690                 ;; string is removed to make it easy for us to insert
 691                 ;; new declarations later, they will just go after the
 692                 ;; CADR of the method lambda. The class declarations
 693                 ;; are inserted to communicate the class of the method's
 694                 ;; arguments to the code walk.
 695                 `(lambda ,lambda-list
 696                    ;; The default ignorability of method parameters
 697                    ;; doesn't seem to be specified by ANSI. PCL had
 698                    ;; them basically ignorable but was a little
 699                    ;; inconsistent. E.g. even though the two
 700                    ;; method definitions
 701                    ;;   (DEFMETHOD FOO ((X T) (Y T)) "Z")
 702                    ;;   (DEFMETHOD FOO ((X T) Y) "Z")
 703                    ;; are otherwise equivalent, PCL treated Y as
 704                    ;; ignorable in the first definition but not in the
 705                    ;; second definition. We make all required
 706                    ;; parameters ignorable as a way of systematizing
 707                    ;; the old PCL behavior. -- WHN 2000-11-24
 708                    (declare (ignorable ,@required-parameters))
 709                    ,class-declarations
 710                    ,@declarations
 711                    (block ,(fun-name-block-name generic-function-name)
 712                      ,@real-body)))
 713                (constant-value-p (and (null (cdr real-body))
 714                                       (constantp (car real-body))))
 715                (constant-value (and constant-value-p
 716                                     (eval (car real-body))))
 717                (plist (and constant-value-p
 718                            (or (typep constant-value
 719                                       '(or number character))
 720                                (and (symbolp constant-value)
 721                                     (symbol-package constant-value)))
 722                            (list :constant-value constant-value)))
 723                (applyp (dolist (p lambda-list nil)
 724                          (cond ((memq p '(&optional &rest &key))
 725                                 (return t))
 726                                ((eq p '&aux)
 727                                 (return nil))))))
 728           (multiple-value-bind
 729                 (walked-lambda call-next-method-p closurep
 730                                next-method-p-p setq-p)
 731               (walk-method-lambda method-lambda
 732                                   required-parameters
 733                                   env
 734                                   slots
 735                                   calls)
 736             (multiple-value-bind (walked-lambda-body
 737                                   walked-declarations
 738                                   walked-documentation)
 739                 (parse-body (cddr walked-lambda))
 740               (declare (ignore walked-documentation))
 741               (when (or next-method-p-p call-next-method-p)
 742                 (setq plist (list* :needs-next-methods-p t plist)))
 743               (when (some #'cdr slots)
 744                 (multiple-value-bind (slot-name-lists call-list)
 745                     (slot-name-lists-from-slots slots calls)
 746                   (let ((pv-table-symbol (make-symbol "pv-table")))
 747                     (setq plist
 748                           `(,@(when slot-name-lists
 749                                 `(:slot-name-lists ,slot-name-lists))
 750                               ,@(when call-list
 751                                   `(:call-list ,call-list))
 752                               :pv-table-symbol ,pv-table-symbol
 753                               ,@plist))
 754                     (setq walked-lambda-body
 755                           `((pv-binding (,required-parameters
 756                                          ,slot-name-lists
 757                                          ,pv-table-symbol)
 758                                         ,@walked-lambda-body))))))
 759               (when (and (memq '&key lambda-list)
 760                          (not (memq '&allow-other-keys lambda-list)))
 761                 (let ((aux (memq '&aux lambda-list)))
 762                 (setq lambda-list (nconc (ldiff lambda-list aux)
 763                                          (list '&allow-other-keys)
 764                                          aux))))
 765               (values `(lambda (.method-args. .next-methods.)
 766                          (simple-lexical-method-functions
 767                           (,lambda-list .method-args. .next-methods.
 768                                         :call-next-method-p
 769                                         ,call-next-method-p
 770                                         :next-method-p-p ,next-method-p-p
 771                                         :setq-p ,setq-p
 772                                         ;; we need to pass this along
 773                                         ;; so that NO-NEXT-METHOD can
 774                                         ;; be given a suitable METHOD
 775                                         ;; argument; we need the
 776                                         ;; QUALIFIERS and SPECIALIZERS
 777                                         ;; inside the declaration to
 778                                         ;; give to FIND-METHOD.
 779                                         :method-name-declaration ,name-decl
 780                                         :closurep ,closurep
 781                                         :applyp ,applyp)
 782                           ,@walked-declarations
 783                           ,@walked-lambda-body))
 784                       `(,@(when plist
 785                       `(:plist ,plist))
 786                           ,@(when documentation
 787                           `(:documentation ,documentation)))))))))))
 788
 789 (unless (fboundp 'make-method-lambda)
 790   (setf (gdefinition 'make-method-lambda)
 791         (symbol-function 'real-make-method-lambda)))
 792
 793 (defmacro simple-lexical-method-functions ((lambda-list
 794                                             method-args
 795                                             next-methods
 796                                             &rest lmf-options)
 797                                            &body body)
 798   `(progn
 799      ,method-args ,next-methods
 800      (bind-simple-lexical-method-macros (,method-args ,next-methods)
 801        (bind-lexical-method-functions (,@lmf-options)
 802          (bind-args (,lambda-list ,method-args)
 803            ,@body)))))
 804
 805 (defmacro fast-lexical-method-functions ((lambda-list
 806                                           next-method-call
 807                                           args
 808                                           rest-arg
 809                                           &rest lmf-options)
 810                                          &body body)
 811   `(bind-fast-lexical-method-macros (,args ,rest-arg ,next-method-call)
 812      (bind-lexical-method-functions (,@lmf-options)
 813        (bind-args (,(nthcdr (length args) lambda-list) ,rest-arg)
 814          ,@body))))
 815
 816 (defmacro bind-simple-lexical-method-macros ((method-args next-methods)
 817                                              &body body)
 818   `(macrolet ((call-next-method-bind (&body body)
 819                `(let ((.next-method. (car ,',next-methods))
 820                       (,',next-methods (cdr ,',next-methods)))
 821                  .next-method. ,',next-methods
 822                  ,@body))
 823               (check-cnm-args-body (&environment env method-name-declaration cnm-args)
 824                (if (safe-code-p env)
 825                    `(%check-cnm-args ,cnm-args ,',method-args ',method-name-declaration)
 826                    nil))
 827               (call-next-method-body (method-name-declaration cnm-args)
 828                `(if .next-method.
 829                     (funcall (if (std-instance-p .next-method.)
 830                                  (method-function .next-method.)
 831                              .next-method.) ; for early methods
 832                              (or ,cnm-args ,',method-args)
 833                              ,',next-methods)
 834                     (apply #'call-no-next-method ',method-name-declaration
 835                             (or ,cnm-args ,',method-args))))
 836               (next-method-p-body ()
 837                `(not (null .next-method.)))
 838               (with-rebound-original-args ((call-next-method-p setq-p)
 839                                            &body body)
 840                 (declare (ignore call-next-method-p setq-p))
 841                 `(let () ,@body)))
 842     ,@body))
 843
 844 (defun call-no-next-method (method-name-declaration &rest args)
 845   (destructuring-bind (name) method-name-declaration
 846     (destructuring-bind (name &rest qualifiers-and-specializers) name
 847       ;; KLUDGE: inefficient traversal, but hey.  This should only
 848       ;; happen on the slow error path anyway.
 849       (let* ((qualifiers (butlast qualifiers-and-specializers))
 850              (specializers (car (last qualifiers-and-specializers)))
 851              (method (find-method (gdefinition name) qualifiers specializers)))
 852         (apply #'no-next-method
 853                (method-generic-function method)
 854                method
 855                args)))))
 856
 857 (defstruct (method-call (:copier nil))
 858   (function #'identity :type function)
 859   call-method-args)
 860
 861 #-sb-fluid (declaim (sb-ext:freeze-type method-call))
 862
 863 (defmacro invoke-method-call1 (function args cm-args)
 864   `(let ((.function. ,function)
 865          (.args. ,args)
 866          (.cm-args. ,cm-args))
 867      (if (and .cm-args. (null (cdr .cm-args.)))
 868          (funcall .function. .args. (car .cm-args.))
 869          (apply .function. .args. .cm-args.))))
 870
 871 (defmacro invoke-method-call (method-call restp &rest required-args+rest-arg)
 872   `(invoke-method-call1 (method-call-function ,method-call)
 873                         ,(if restp
 874                              `(list* ,@required-args+rest-arg)
 875                              `(list ,@required-args+rest-arg))
 876                         (method-call-call-method-args ,method-call)))
 877
 878 (defstruct (fast-method-call (:copier nil))
 879   (function #'identity :type function)
 880   pv-cell
 881   next-method-call
 882   arg-info)
 883
 884 #-sb-fluid (declaim (sb-ext:freeze-type fast-method-call))
 885
 886 (defmacro fmc-funcall (fn pv-cell next-method-call &rest args)
 887   `(funcall ,fn ,pv-cell ,next-method-call ,@args))
 888
 889 (defmacro invoke-fast-method-call (method-call &rest required-args+rest-arg)
 890   `(fmc-funcall (fast-method-call-function ,method-call)
 891                 (fast-method-call-pv-cell ,method-call)
 892                 (fast-method-call-next-method-call ,method-call)
 893                 ,@required-args+rest-arg))
 894
 895 (defstruct (fast-instance-boundp (:copier nil))
 896   (index 0 :type fixnum))
 897
 898 #-sb-fluid (declaim (sb-ext:freeze-type fast-instance-boundp))
 899
 900 (eval-when (:compile-toplevel :load-toplevel :execute)
 901   (defvar *allow-emf-call-tracing-p* nil)
 902   (defvar *enable-emf-call-tracing-p* #-sb-show nil #+sb-show t))
 903 \f
 904 ;;;; effective method functions
 905
 906 (defvar *emf-call-trace-size* 200)
 907 (defvar *emf-call-trace* nil)
 908 (defvar *emf-call-trace-index* 0)
 909
 910 ;;; This function was in the CMU CL version of PCL (ca Debian 2.4.8)
 911 ;;; without explanation. It appears to be intended for debugging, so
 912 ;;; it might be useful someday, so I haven't deleted it.
 913 ;;; But it isn't documented and isn't used for anything now, so
 914 ;;; I've conditionalized it out of the base system. -- WHN 19991213
 915 #+sb-show
 916 (defun show-emf-call-trace ()
 917   (when *emf-call-trace*
 918     (let ((j *emf-call-trace-index*)
 919           (*enable-emf-call-tracing-p* nil))
 920       (format t "~&(The oldest entries are printed first)~%")
 921       (dotimes-fixnum (i *emf-call-trace-size*)
 922         (let ((ct (aref *emf-call-trace* j)))
 923           (when ct (print ct)))
 924         (incf j)
 925         (when (= j *emf-call-trace-size*)
 926           (setq j 0))))))
 927
 928 (defun trace-emf-call-internal (emf format args)
 929   (unless *emf-call-trace*
 930     (setq *emf-call-trace* (make-array *emf-call-trace-size*)))
 931   (setf (aref *emf-call-trace* *emf-call-trace-index*)
 932         (list* emf format args))
 933   (incf *emf-call-trace-index*)
 934   (when (= *emf-call-trace-index* *emf-call-trace-size*)
 935     (setq *emf-call-trace-index* 0)))
 936
 937 (defmacro trace-emf-call (emf format args)
 938   (when *allow-emf-call-tracing-p*
 939     `(when *enable-emf-call-tracing-p*
 940        (trace-emf-call-internal ,emf ,format ,args))))
 941
 942 (defmacro invoke-effective-method-function-fast
 943     (emf restp &rest required-args+rest-arg)
 944   `(progn
 945      (trace-emf-call ,emf ,restp (list ,@required-args+rest-arg))
 946      (invoke-fast-method-call ,emf ,@required-args+rest-arg)))
 947
 948 (defmacro invoke-effective-method-function (emf restp
 949                                                 &rest required-args+rest-arg)
 950   (unless (constantp restp)
 951     (error "The RESTP argument is not constant."))
 952   ;; FIXME: The RESTP handling here is confusing and maybe slightly
 953   ;; broken if RESTP evaluates to a non-self-evaluating form. E.g. if
 954   ;;   (INVOKE-EFFECTIVE-METHOD-FUNCTION EMF '(ERROR "gotcha") ...)
 955   ;; then TRACE-EMF-CALL-CALL-INTERNAL might die on a gotcha error.
 956   (setq restp (eval restp))
 957   `(progn
 958      (trace-emf-call ,emf ,restp (list ,@required-args+rest-arg))
 959      (cond ((typep ,emf 'fast-method-call)
 960             (invoke-fast-method-call ,emf ,@required-args+rest-arg))
 961            ;; "What," you may wonder, "do these next two clauses do?"
 962            ;; In that case, you are not a PCL implementor, for they
 963            ;; considered this to be self-documenting.:-| Or CSR, for
 964            ;; that matter, since he can also figure it out by looking
 965            ;; at it without breaking stride. For the rest of us,
 966            ;; though: From what the code is doing with .SLOTS. and
 967            ;; whatnot, evidently it's implementing SLOT-VALUEish and
 968            ;; GET-SLOT-VALUEish things. Then we can reason backwards
 969            ;; and conclude that setting EMF to a FIXNUM is an
 970            ;; optimized way to represent these slot access operations.
 971            ,@(when (and (null restp) (= 1 (length required-args+rest-arg)))
 972                `(((typep ,emf 'fixnum)
 973                   (let* ((.slots. (get-slots-or-nil
 974                                    ,(car required-args+rest-arg)))
 975                          (value (when .slots. (clos-slots-ref .slots. ,emf))))
 976                     (if (eq value +slot-unbound+)
 977                         (slot-unbound-internal ,(car required-args+rest-arg)
 978                                                ,emf)
 979                         value)))))
 980            ,@(when (and (null restp) (= 2 (length required-args+rest-arg)))
 981                `(((typep ,emf 'fixnum)
 982                   (let ((.new-value. ,(car required-args+rest-arg))
 983                         (.slots. (get-slots-or-nil
 984                                   ,(cadr required-args+rest-arg))))
 985                     (when .slots.
 986                       (setf (clos-slots-ref .slots. ,emf) .new-value.))))))
 987            ;; (In cmucl-2.4.8 there was a commented-out third ,@(WHEN
 988            ;; ...) clause here to handle SLOT-BOUNDish stuff. Since
 989            ;; there was no explanation and presumably the code is 10+
 990            ;; years stale, I simply deleted it. -- WHN)
 991            (t
 992             (etypecase ,emf
 993               (method-call
 994                (invoke-method-call ,emf ,restp ,@required-args+rest-arg))
 995               (function
 996                ,(if restp
 997                     `(apply (the function ,emf) ,@required-args+rest-arg)
 998                     `(funcall (the function ,emf)
 999                               ,@required-args+rest-arg))))))))
1000
1001 (defun invoke-emf (emf args)
1002   (trace-emf-call emf t args)
1003   (etypecase emf
1004     (fast-method-call
1005      (let* ((arg-info (fast-method-call-arg-info emf))
1006             (restp (cdr arg-info))
1007             (nreq (car arg-info)))
1008        (if restp
1009            (let* ((rest-args (nthcdr nreq args))
1010                   (req-args (ldiff args rest-args)))
1011              (apply (fast-method-call-function emf)
1012                     (fast-method-call-pv-cell emf)
1013                     (fast-method-call-next-method-call emf)
1014                     (nconc req-args (list rest-args))))
1015            (cond ((null args)
1016                   (if (eql nreq 0)
1017                       (invoke-fast-method-call emf)
1018                       (error 'simple-program-error
1019                              :format-control "invalid number of arguments: 0"
1020                              :format-arguments nil)))
1021                  ((null (cdr args))
1022                   (if (eql nreq 1)
1023                       (invoke-fast-method-call emf (car args))
1024                       (error 'simple-program-error
1025                              :format-control "invalid number of arguments: 1"
1026                              :format-arguments nil)))
1027                  ((null (cddr args))
1028                   (if (eql nreq 2)
1029                       (invoke-fast-method-call emf (car args) (cadr args))
1030                       (error 'simple-program-error
1031                              :format-control "invalid number of arguments: 2"
1032                              :format-arguments nil)))
1033                  (t
1034                   (apply (fast-method-call-function emf)
1035                          (fast-method-call-pv-cell emf)
1036                          (fast-method-call-next-method-call emf)
1037                          args))))))
1038     (method-call
1039      (apply (method-call-function emf)
1040             args
1041             (method-call-call-method-args emf)))
1042     (fixnum
1043      (cond ((null args)
1044             (error 'simple-program-error
1045                    :format-control "invalid number of arguments: 0"
1046                    :format-arguments nil))
1047            ((null (cdr args))
1048             (let* ((slots (get-slots (car args)))
1049                    (value (clos-slots-ref slots emf)))
1050               (if (eq value +slot-unbound+)
1051                   (slot-unbound-internal (car args) emf)
1052                   value)))
1053            ((null (cddr args))
1054             (setf (clos-slots-ref (get-slots (cadr args)) emf)
1055                   (car args)))
1056            (t (error 'simple-program-error
1057                      :format-control "invalid number of arguments"
1058                      :format-arguments nil))))
1059     (fast-instance-boundp
1060      (if (or (null args) (cdr args))
1061          (error 'simple-program-error
1062                 :format-control "invalid number of arguments"
1063                 :format-arguments nil)
1064          (let ((slots (get-slots (car args))))
1065            (not (eq (clos-slots-ref slots (fast-instance-boundp-index emf))
1066                     +slot-unbound+)))))
1067     (function
1068      (apply emf args))))
1069 \f
1070 (defmacro bind-fast-lexical-method-macros ((args rest-arg next-method-call)
1071                                            &body body
1072                                            &environment env)
1073   (let* ((all-params (append args (when rest-arg (list rest-arg))))
1074          (rebindings (mapcar (lambda (x) (list x x)) all-params)))
1075     `(macrolet ((narrowed-emf (emf)
1076                  ;; INVOKE-EFFECTIVE-METHOD-FUNCTION has code in it to
1077                  ;; dispatch on the possibility that EMF might be of
1078                  ;; type FIXNUM (as an optimized representation of a
1079                  ;; slot accessor). But as far as I (WHN 2002-06-11)
1080                  ;; can tell, it's impossible for such a representation
1081                  ;; to end up as .NEXT-METHOD-CALL. By reassuring
1082                  ;; INVOKE-E-M-F that when called from this context
1083                  ;; it needn't worry about the FIXNUM case, we can
1084                  ;; keep those cases from being compiled, which is
1085                  ;; good both because it saves bytes and because it
1086                  ;; avoids annoying type mismatch compiler warnings.
1087                  ;;
1088                  ;; KLUDGE: In sbcl-0.7.4.29, the compiler's type
1089                  ;; system isn't smart enough about NOT and
1090                  ;; intersection types to benefit from a (NOT FIXNUM)
1091                  ;; declaration here. -- WHN 2002-06-12 (FIXME: maybe
1092                  ;; it is now... -- CSR, 2003-06-07)
1093                  ;;
1094                  ;; FIXME: Might the FUNCTION type be omittable here,
1095                  ;; leaving only METHOD-CALLs? Failing that, could this
1096                  ;; be documented somehow? (It'd be nice if the types
1097                  ;; involved could be understood without solving the
1098                  ;; halting problem.)
1099                  `(the (or function method-call fast-method-call)
1100                    ,emf))
1101                 (call-next-method-bind (&body body)
1102                  `(let () ,@body))
1103                 (check-cnm-args-body (&environment env method-name-declaration cnm-args)
1104                  (if (safe-code-p env)
1105                      `(%check-cnm-args ,cnm-args (list ,@',args)
1106                        ',method-name-declaration)
1107                      nil))
1108                 (call-next-method-body (method-name-declaration cnm-args)
1109                  `(if ,',next-method-call
1110                       ,(locally
1111                         ;; This declaration suppresses a "deleting
1112                         ;; unreachable code" note for the following IF
1113                         ;; when REST-ARG is NIL. It is not nice for
1114                         ;; debugging SBCL itself, but at least it
1115                         ;; keeps us from annoying users.
1116                         (declare (optimize (inhibit-warnings 3)))
1117                         (if (and (null ',rest-arg)
1118                                  (consp cnm-args)
1119                                  (eq (car cnm-args) 'list))
1120                             `(invoke-effective-method-function
1121                               (narrowed-emf ,',next-method-call)
1122                               nil
1123                               ,@(cdr cnm-args))
1124                             (let ((call `(invoke-effective-method-function
1125                                           (narrowed-emf ,',next-method-call)
1126                                           ,',(not (null rest-arg))
1127                                           ,@',args
1128                                           ,@',(when rest-arg `(,rest-arg)))))
1129                               `(if ,cnm-args
1130                                 (bind-args ((,@',args
1131                                              ,@',(when rest-arg
1132                                                        `(&rest ,rest-arg)))
1133                                             ,cnm-args)
1134                                  ,call)
1135                                 ,call))))
1136                       ,(locally
1137                         ;; As above, this declaration suppresses code
1138                         ;; deletion notes.
1139                         (declare (optimize (inhibit-warnings 3)))
1140                         (if (and (null ',rest-arg)
1141                                  (consp cnm-args)
1142                                  (eq (car cnm-args) 'list))
1143                             `(call-no-next-method ',method-name-declaration
1144                               ,@(cdr cnm-args))
1145                             `(call-no-next-method ',method-name-declaration
1146                               ,@',args
1147                               ,@',(when rest-arg
1148                                         `(,rest-arg)))))))
1149                 (next-method-p-body ()
1150                  `(not (null ,',next-method-call)))
1151                 (with-rebound-original-args ((cnm-p setq-p) &body body)
1152                   (if (or cnm-p setq-p)
1153                       `(let ,',rebindings
1154                         (declare (ignorable ,@',all-params))
1155                         ,@body)
1156                       `(let () ,@body))))
1157       ,@body)))
1158
1159 (defmacro bind-lexical-method-functions
1160     ((&key call-next-method-p next-method-p-p setq-p
1161            closurep applyp method-name-declaration)
1162      &body body)
1163   (cond ((and (null call-next-method-p) (null next-method-p-p)
1164               (null closurep) (null applyp) (null setq-p))
1165          `(let () ,@body))
1166         (t
1167          `(call-next-method-bind
1168             (flet (,@(and call-next-method-p
1169                           `((call-next-method (&rest cnm-args)
1170                              (check-cnm-args-body ,method-name-declaration cnm-args)
1171                              (call-next-method-body ,method-name-declaration cnm-args))))
1172                    ,@(and next-method-p-p
1173                           '((next-method-p ()
1174                              (next-method-p-body)))))
1175               (with-rebound-original-args (,call-next-method-p ,setq-p)
1176                 ,@body))))))
1177
1178 ;;; CMUCL comment (Gerd Moellmann):
1179 ;;;
1180 ;;; The standard says it's an error if CALL-NEXT-METHOD is called with
1181 ;;; arguments, and the set of methods applicable to those arguments is
1182 ;;; different from the set of methods applicable to the original
1183 ;;; method arguments.  (According to Barry Margolin, this rule was
1184 ;;; probably added to ensure that before and around methods are always
1185 ;;; run before primary methods.)
1186 ;;;
1187 ;;; This could be optimized for the case that the generic function
1188 ;;; doesn't have hairy methods, does have standard method combination,
1189 ;;; is a standard generic function, there are no methods defined on it
1190 ;;; for COMPUTE-APPLICABLE-METHODS and probably a lot more of such
1191 ;;; preconditions.  That looks hairy and is probably not worth it,
1192 ;;; because this check will never be fast.
1193 (defun %check-cnm-args (cnm-args orig-args method-name-declaration)
1194   (when cnm-args
1195     (let* ((gf (fdefinition (caar method-name-declaration)))
1196            (omethods (compute-applicable-methods gf orig-args))
1197            (nmethods (compute-applicable-methods gf cnm-args)))
1198       (unless (equal omethods nmethods)
1199         (error "~@<The set of methods ~S applicable to argument~P ~
1200                 ~{~S~^, ~} to call-next-method is different from ~
1201                 the set of methods ~S applicable to the original ~
1202                 method argument~P ~{~S~^, ~}.~@:>"
1203                nmethods (length cnm-args) cnm-args omethods
1204                (length orig-args) orig-args)))))
1205
1206 (defmacro bind-args ((lambda-list args) &body body)
1207   (let ((args-tail '.args-tail.)
1208         (key '.key.)
1209         (state 'required))
1210     (flet ((process-var (var)
1211              (if (memq var lambda-list-keywords)
1212                  (progn
1213                    (case var
1214                      (&optional       (setq state 'optional))
1215                      (&key            (setq state 'key))
1216                      (&allow-other-keys)
1217                      (&rest           (setq state 'rest))
1218                      (&aux            (setq state 'aux))
1219                      (otherwise
1220                       (error
1221                        "encountered the non-standard lambda list keyword ~S"
1222                        var)))
1223                    nil)
1224                  (case state
1225                    (required `((,var (pop ,args-tail))))
1226                    (optional (cond ((not (consp var))
1227                                     `((,var (when ,args-tail
1228                                               (pop ,args-tail)))))
1229                                    ((null (cddr var))
1230                                     `((,(car var) (if ,args-tail
1231                                                       (pop ,args-tail)
1232                                                       ,(cadr var)))))
1233                                    (t
1234                                     `((,(caddr var) ,args-tail)
1235                                       (,(car var) (if ,args-tail
1236                                                       (pop ,args-tail)
1237                                                       ,(cadr var)))))))
1238                    (rest `((,var ,args-tail)))
1239                    (key (cond ((not (consp var))
1240                                `((,var (car
1241                                         (get-key-arg-tail ,(keywordicate var)
1242                                                           ,args-tail)))))
1243                               ((null (cddr var))
1244                                (multiple-value-bind (keyword variable)
1245                                    (if (consp (car var))
1246                                        (values (caar var)
1247                                                (cadar var))
1248                                        (values (keywordicate (car var))
1249                                                (car var)))
1250                                  `((,key (get-key-arg-tail ',keyword
1251                                                            ,args-tail))
1252                                    (,variable (if ,key
1253                                                   (car ,key)
1254                                                   ,(cadr var))))))
1255                               (t
1256                                (multiple-value-bind (keyword variable)
1257                                    (if (consp (car var))
1258                                        (values (caar var)
1259                                                (cadar var))
1260                                        (values (keywordicate (car var))
1261                                                (car var)))
1262                                  `((,key (get-key-arg-tail ',keyword
1263                                                            ,args-tail))
1264                                    (,(caddr var) ,key)
1265                                    (,variable (if ,key
1266                                                   (car ,key)
1267                                                   ,(cadr var))))))))
1268                    (aux `(,var))))))
1269       (let ((bindings (mapcan #'process-var lambda-list)))
1270         `(let* ((,args-tail ,args)
1271                 ,@bindings
1272                 (.dummy0.
1273                  ,@(when (eq state 'optional)
1274                      `((unless (null ,args-tail)
1275                          (error 'simple-program-error
1276                                 :format-control "surplus arguments: ~S"
1277                                 :format-arguments (list ,args-tail)))))))
1278            (declare (ignorable ,args-tail .dummy0.))
1279            ,@body)))))
1280
1281 (defun get-key-arg-tail (keyword list)
1282   (loop for (key . tail) on list by #'cddr
1283         when (null tail) do
1284           ;; FIXME: Do we want to export this symbol? Or maybe use an
1285           ;; (ERROR 'SIMPLE-PROGRAM-ERROR) form?
1286           (sb-c::%odd-key-args-error)
1287         when (eq key keyword)
1288           return tail))
1289
1290 (defun walk-method-lambda (method-lambda required-parameters env slots calls)
1291   (let ((call-next-method-p nil)   ; flag indicating that CALL-NEXT-METHOD
1292                                    ; should be in the method definition
1293         (closurep nil)             ; flag indicating that #'CALL-NEXT-METHOD
1294                                    ; was seen in the body of a method
1295         (next-method-p-p nil)      ; flag indicating that NEXT-METHOD-P
1296                                    ; should be in the method definition
1297         (setq-p nil))
1298     (flet ((walk-function (form context env)
1299              (cond ((not (eq context :eval)) form)
1300                    ;; FIXME: Jumping to a conclusion from the way it's used
1301                    ;; above, perhaps CONTEXT should be called SITUATION
1302                    ;; (after the term used in the ANSI specification of
1303                    ;; EVAL-WHEN) and given modern ANSI keyword values
1304                    ;; like :LOAD-TOPLEVEL.
1305                    ((not (listp form)) form)
1306                    ((eq (car form) 'call-next-method)
1307                     (setq call-next-method-p t)
1308                     form)
1309                    ((eq (car form) 'next-method-p)
1310                     (setq next-method-p-p t)
1311                     form)
1312                    ((memq (car form) '(setq multiple-value-setq))
1313                     ;; FIXME: this is possibly a little strong as
1314                     ;; conditions go.  Ideally we would want to detect
1315                     ;; which, if any, of the method parameters are
1316                     ;; being set, and communicate that information to
1317                     ;; e.g. SPLIT-DECLARATIONS.  However, the brute
1318                     ;; force method doesn't really cost much; a little
1319                     ;; loss of discrimination over IGNORED variables
1320                     ;; should be all.  -- CSR, 2004-07-01
1321                     (setq setq-p t)
1322                     form)
1323                    ((and (eq (car form) 'function)
1324                          (cond ((eq (cadr form) 'call-next-method)
1325                                 (setq call-next-method-p t)
1326                                 (setq closurep t)
1327                                 form)
1328                                ((eq (cadr form) 'next-method-p)
1329                                 (setq next-method-p-p t)
1330                                 (setq closurep t)
1331                                 form)
1332                                (t nil))))
1333                    ((and (memq (car form)
1334                                '(slot-value set-slot-value slot-boundp))
1335                          (constantp (caddr form)))
1336                      (let ((parameter (can-optimize-access form
1337                                                            required-parameters
1338                                                            env)))
1339                       (let ((fun (ecase (car form)
1340                                    (slot-value #'optimize-slot-value)
1341                                    (set-slot-value #'optimize-set-slot-value)
1342                                    (slot-boundp #'optimize-slot-boundp))))
1343                         (funcall fun slots parameter form))))
1344                    ((and (eq (car form) 'apply)
1345                          (consp (cadr form))
1346                          (eq (car (cadr form)) 'function)
1347                          (generic-function-name-p (cadr (cadr form))))
1348                     (optimize-generic-function-call
1349                      form required-parameters env slots calls))
1350                    ((generic-function-name-p (car form))
1351                     (optimize-generic-function-call
1352                      form required-parameters env slots calls))
1353                    (t form))))
1354
1355       (let ((walked-lambda (walk-form method-lambda env #'walk-function)))
1356         (values walked-lambda
1357                 call-next-method-p
1358                 closurep
1359                 next-method-p-p
1360                 setq-p)))))
1361
1362 (defun generic-function-name-p (name)
1363   (and (legal-fun-name-p name)
1364        (fboundp name)
1365        (if (eq *boot-state* 'complete)
1366            (standard-generic-function-p (gdefinition name))
1367            (funcallable-instance-p (gdefinition name)))))
1368 \f
1369 (defvar *method-function-plist* (make-hash-table :test 'eq))
1370 (defvar *mf1* nil)
1371 (defvar *mf1p* nil)
1372 (defvar *mf1cp* nil)
1373 (defvar *mf2* nil)
1374 (defvar *mf2p* nil)
1375 (defvar *mf2cp* nil)
1376
1377 (defun method-function-plist (method-function)
1378   (unless (eq method-function *mf1*)
1379     (rotatef *mf1* *mf2*)
1380     (rotatef *mf1p* *mf2p*)
1381     (rotatef *mf1cp* *mf2cp*))
1382   (unless (or (eq method-function *mf1*) (null *mf1cp*))
1383     (setf (gethash *mf1* *method-function-plist*) *mf1p*))
1384   (unless (eq method-function *mf1*)
1385     (setf *mf1* method-function
1386           *mf1cp* nil
1387           *mf1p* (gethash method-function *method-function-plist*)))
1388   *mf1p*)
1389
1390 (defun (setf method-function-plist)
1391     (val method-function)
1392   (unless (eq method-function *mf1*)
1393     (rotatef *mf1* *mf2*)
1394     (rotatef *mf1cp* *mf2cp*)
1395     (rotatef *mf1p* *mf2p*))
1396   (unless (or (eq method-function *mf1*) (null *mf1cp*))
1397     (setf (gethash *mf1* *method-function-plist*) *mf1p*))
1398   (setf *mf1* method-function
1399         *mf1cp* t
1400         *mf1p* val))
1401
1402 (defun method-function-get (method-function key &optional default)
1403   (getf (method-function-plist method-function) key default))
1404
1405 (defun (setf method-function-get)
1406     (val method-function key)
1407   (setf (getf (method-function-plist method-function) key) val))
1408
1409 (defun method-function-pv-table (method-function)
1410   (method-function-get method-function :pv-table))
1411
1412 (defun method-function-method (method-function)
1413   (method-function-get method-function :method))
1414
1415 (defun method-function-needs-next-methods-p (method-function)
1416   (method-function-get method-function :needs-next-methods-p t))
1417 \f
1418 (defmacro method-function-closure-generator (method-function)
1419   `(method-function-get ,method-function 'closure-generator))
1420
1421 (defun load-defmethod
1422     (class name quals specls ll initargs pv-table-symbol source-location)
1423   (setq initargs (copy-tree initargs))
1424   (let ((method-spec (or (getf initargs :method-spec)
1425                          (make-method-spec name quals specls))))
1426     (setf (getf initargs :method-spec) method-spec)
1427     (load-defmethod-internal class name quals specls
1428                              ll initargs pv-table-symbol
1429                              source-location)))
1430
1431 (defun load-defmethod-internal
1432     (method-class gf-spec qualifiers specializers lambda-list
1433                   initargs pv-table-symbol source-location)
1434   (when pv-table-symbol
1435     (setf (getf (getf initargs :plist) :pv-table-symbol)
1436           pv-table-symbol))
1437   (when (and (eq *boot-state* 'complete)
1438              (fboundp gf-spec))
1439     (let* ((gf (fdefinition gf-spec))
1440            (method (and (generic-function-p gf)
1441                         (generic-function-methods gf)
1442                         (find-method gf
1443                                      qualifiers
1444                                      (parse-specializers specializers)
1445                                      nil))))
1446       (when method
1447         (style-warn "redefining ~S~{ ~S~} ~S in DEFMETHOD"
1448                     gf-spec qualifiers specializers))))
1449   (let ((method (apply #'add-named-method
1450                        gf-spec qualifiers specializers lambda-list
1451                        :definition-source source-location
1452                        initargs)))
1453     (unless (or (eq method-class 'standard-method)
1454                 (eq (find-class method-class nil) (class-of method)))
1455       ;; FIXME: should be STYLE-WARNING?
1456       (format *error-output*
1457               "~&At the time the method with qualifiers ~:S and~%~
1458                specializers ~:S on the generic function ~S~%~
1459                was compiled, the method-class for that generic function was~%~
1460                ~S. But, the method class is now ~S, this~%~
1461                may mean that this method was compiled improperly.~%"
1462               qualifiers specializers gf-spec
1463               method-class (class-name (class-of method))))
1464     method))
1465
1466 (defun make-method-spec (gf-spec qualifiers unparsed-specializers)
1467   `(slow-method ,gf-spec ,@qualifiers ,unparsed-specializers))
1468
1469 (defun initialize-method-function (initargs &optional return-function-p method)
1470   (let* ((mf (getf initargs :function))
1471          (method-spec (getf initargs :method-spec))
1472          (plist (getf initargs :plist))
1473          (pv-table-symbol (getf plist :pv-table-symbol))
1474          (pv-table nil)
1475          (mff (getf initargs :fast-function)))
1476     (flet ((set-mf-property (p v)
1477              (when mf
1478                (setf (method-function-get mf p) v))
1479              (when mff
1480                (setf (method-function-get mff p) v))))
1481       (when method-spec
1482         (when mf
1483           (setq mf (set-fun-name mf method-spec)))
1484         (when mff
1485           (let ((name `(fast-method ,@(cdr method-spec))))
1486             (set-fun-name mff name)
1487             (unless mf
1488               (set-mf-property :name name)))))
1489       (when plist
1490         (let ((snl (getf plist :slot-name-lists))
1491               (cl (getf plist :call-list)))
1492           (when (or snl cl)
1493             (setq pv-table (intern-pv-table :slot-name-lists snl
1494                                             :call-list cl))
1495             (when pv-table (set pv-table-symbol pv-table))
1496             (set-mf-property :pv-table pv-table)))
1497         (loop (when (null plist) (return nil))
1498               (set-mf-property (pop plist) (pop plist)))
1499         (when method
1500           (set-mf-property :method method))
1501         (when return-function-p
1502           (or mf (method-function-from-fast-function mff)))))))
1503 \f
1504 (defun analyze-lambda-list (lambda-list)
1505   (flet (;; FIXME: Is this redundant with SB-C::MAKE-KEYWORD-FOR-ARG?
1506          (parse-key-arg (arg)
1507            (if (listp arg)
1508                (if (listp (car arg))
1509                    (caar arg)
1510                    (keywordicate (car arg)))
1511                (keywordicate arg))))
1512     (let ((nrequired 0)
1513           (noptional 0)
1514           (keysp nil)
1515           (restp nil)
1516           (nrest 0)
1517           (allow-other-keys-p nil)
1518           (keywords ())
1519           (keyword-parameters ())
1520           (state 'required))
1521       (dolist (x lambda-list)
1522         (if (memq x lambda-list-keywords)
1523             (case x
1524               (&optional         (setq state 'optional))
1525               (&key              (setq keysp t
1526                                        state 'key))
1527               (&allow-other-keys (setq allow-other-keys-p t))
1528               (&rest             (setq restp t
1529                                        state 'rest))
1530               (&aux           (return t))
1531               (otherwise
1532                 (error "encountered the non-standard lambda list keyword ~S"
1533                        x)))
1534             (ecase state
1535               (required  (incf nrequired))
1536               (optional  (incf noptional))
1537               (key       (push (parse-key-arg x) keywords)
1538                          (push x keyword-parameters))
1539               (rest      (incf nrest)))))
1540       (when (and restp (zerop nrest))
1541         (error "Error in lambda-list:~%~
1542                 After &REST, a DEFGENERIC lambda-list ~
1543                 must be followed by at least one variable."))
1544       (values nrequired noptional keysp restp allow-other-keys-p
1545               (reverse keywords)
1546               (reverse keyword-parameters)))))
1547
1548 (defun keyword-spec-name (x)
1549   (let ((key (if (atom x) x (car x))))
1550     (if (atom key)
1551         (keywordicate key)
1552         (car key))))
1553
1554 (defun ftype-declaration-from-lambda-list (lambda-list name)
1555   (multiple-value-bind (nrequired noptional keysp restp allow-other-keys-p
1556                                   keywords keyword-parameters)
1557       (analyze-lambda-list lambda-list)
1558     (declare (ignore keyword-parameters))
1559     (let* ((old (info :function :type name)) ;FIXME:FDOCUMENTATION instead?
1560            (old-ftype (if (fun-type-p old) old nil))
1561            (old-restp (and old-ftype (fun-type-rest old-ftype)))
1562            (old-keys (and old-ftype
1563                           (mapcar #'key-info-name
1564                                   (fun-type-keywords
1565                                    old-ftype))))
1566            (old-keysp (and old-ftype (fun-type-keyp old-ftype)))
1567            (old-allowp (and old-ftype
1568                             (fun-type-allowp old-ftype)))
1569            (keywords (union old-keys (mapcar #'keyword-spec-name keywords))))
1570       `(function ,(append (make-list nrequired :initial-element t)
1571                           (when (plusp noptional)
1572                             (append '(&optional)
1573                                     (make-list noptional :initial-element t)))
1574                           (when (or restp old-restp)
1575                             '(&rest t))
1576                           (when (or keysp old-keysp)
1577                             (append '(&key)
1578                                     (mapcar (lambda (key)
1579                                               `(,key t))
1580                                             keywords)
1581                                     (when (or allow-other-keys-p old-allowp)
1582                                       '(&allow-other-keys)))))
1583                  *))))
1584
1585 (defun defgeneric-declaration (spec lambda-list)
1586   `(ftype ,(ftype-declaration-from-lambda-list lambda-list spec) ,spec))
1587 \f
1588 ;;;; early generic function support
1589
1590 (defvar *!early-generic-functions* ())
1591
1592 (defun ensure-generic-function (fun-name
1593                                 &rest all-keys
1594                                 &key environment source-location
1595                                 &allow-other-keys)
1596   (declare (ignore environment))
1597   (let ((existing (and (fboundp fun-name)
1598                        (gdefinition fun-name))))
1599     (if (and existing
1600              (eq *boot-state* 'complete)
1601              (null (generic-function-p existing)))
1602         (generic-clobbers-function fun-name)
1603         (apply #'ensure-generic-function-using-class
1604                existing fun-name all-keys))))
1605
1606 (defun generic-clobbers-function (fun-name)
1607   (error 'simple-program-error
1608          :format-control "~S already names an ordinary function or a macro."
1609          :format-arguments (list fun-name)))
1610
1611 (defvar *sgf-wrapper*
1612   (boot-make-wrapper (early-class-size 'standard-generic-function)
1613                      'standard-generic-function))
1614
1615 (defvar *sgf-slots-init*
1616   (mapcar (lambda (canonical-slot)
1617             (if (memq (getf canonical-slot :name) '(arg-info source))
1618                 +slot-unbound+
1619                 (let ((initfunction (getf canonical-slot :initfunction)))
1620                   (if initfunction
1621                       (funcall initfunction)
1622                       +slot-unbound+))))
1623           (early-collect-inheritance 'standard-generic-function)))
1624
1625 (defvar *sgf-method-class-index*
1626   (!bootstrap-slot-index 'standard-generic-function 'method-class))
1627
1628 (defun early-gf-p (x)
1629   (and (fsc-instance-p x)
1630        (eq (clos-slots-ref (get-slots x) *sgf-method-class-index*)
1631            +slot-unbound+)))
1632
1633 (defvar *sgf-methods-index*
1634   (!bootstrap-slot-index 'standard-generic-function 'methods))
1635
1636 (defmacro early-gf-methods (gf)
1637   `(clos-slots-ref (get-slots ,gf) *sgf-methods-index*))
1638
1639 (defvar *sgf-arg-info-index*
1640   (!bootstrap-slot-index 'standard-generic-function 'arg-info))
1641
1642 (defmacro early-gf-arg-info (gf)
1643   `(clos-slots-ref (get-slots ,gf) *sgf-arg-info-index*))
1644
1645 (defvar *sgf-dfun-state-index*
1646   (!bootstrap-slot-index 'standard-generic-function 'dfun-state))
1647
1648 (defstruct (arg-info
1649             (:conc-name nil)
1650             (:constructor make-arg-info ())
1651             (:copier nil))
1652   (arg-info-lambda-list :no-lambda-list)
1653   arg-info-precedence
1654   arg-info-metatypes
1655   arg-info-number-optional
1656   arg-info-key/rest-p
1657   arg-info-keys   ;nil        no &KEY or &REST allowed
1658                   ;(k1 k2 ..) Each method must accept these &KEY arguments.
1659                   ;T          must have &KEY or &REST
1660
1661   gf-info-simple-accessor-type ; nil, reader, writer, boundp
1662   (gf-precompute-dfun-and-emf-p nil) ; set by set-arg-info
1663
1664   gf-info-static-c-a-m-emf
1665   (gf-info-c-a-m-emf-std-p t)
1666   gf-info-fast-mf-p)
1667
1668 #-sb-fluid (declaim (sb-ext:freeze-type arg-info))
1669
1670 (defun arg-info-valid-p (arg-info)
1671   (not (null (arg-info-number-optional arg-info))))
1672
1673 (defun arg-info-applyp (arg-info)
1674   (or (plusp (arg-info-number-optional arg-info))
1675       (arg-info-key/rest-p arg-info)))
1676
1677 (defun arg-info-number-required (arg-info)
1678   (length (arg-info-metatypes arg-info)))
1679
1680 (defun arg-info-nkeys (arg-info)
1681   (count-if (lambda (x) (neq x t)) (arg-info-metatypes arg-info)))
1682
1683 (defun create-gf-lambda-list (lambda-list)
1684   ;;; Create a gf lambda list from a method lambda list
1685   (loop for x in lambda-list
1686         collect (if (consp x) (list (car x)) x)
1687         if (eq x '&key) do (loop-finish)))
1688
1689 (defun set-arg-info (gf &key new-method (lambda-list nil lambda-list-p)
1690                         argument-precedence-order)
1691   (let* ((arg-info (if (eq *boot-state* 'complete)
1692                        (gf-arg-info gf)
1693                        (early-gf-arg-info gf)))
1694          (methods (if (eq *boot-state* 'complete)
1695                       (generic-function-methods gf)
1696                       (early-gf-methods gf)))
1697          (was-valid-p (integerp (arg-info-number-optional arg-info)))
1698          (first-p (and new-method (null (cdr methods)))))
1699     (when (and (not lambda-list-p) methods)
1700       (setq lambda-list (gf-lambda-list gf)))
1701     (when (or lambda-list-p
1702               (and first-p
1703                    (eq (arg-info-lambda-list arg-info) :no-lambda-list)))
1704       (multiple-value-bind (nreq nopt keysp restp allow-other-keys-p keywords)
1705           (analyze-lambda-list lambda-list)
1706         (when (and methods (not first-p))
1707           (let ((gf-nreq (arg-info-number-required arg-info))
1708                 (gf-nopt (arg-info-number-optional arg-info))
1709                 (gf-key/rest-p (arg-info-key/rest-p arg-info)))
1710             (unless (and (= nreq gf-nreq)
1711                          (= nopt gf-nopt)
1712                          (eq (or keysp restp) gf-key/rest-p))
1713               (error "The lambda-list ~S is incompatible with ~
1714                      existing methods of ~S."
1715                      lambda-list gf))))
1716         (setf (arg-info-lambda-list arg-info)
1717               (if lambda-list-p
1718                   lambda-list
1719                    (create-gf-lambda-list lambda-list)))
1720         (when (or lambda-list-p argument-precedence-order
1721                   (null (arg-info-precedence arg-info)))
1722           (setf (arg-info-precedence arg-info)
1723                 (compute-precedence lambda-list nreq argument-precedence-order)))
1724         (setf (arg-info-metatypes arg-info) (make-list nreq))
1725         (setf (arg-info-number-optional arg-info) nopt)
1726         (setf (arg-info-key/rest-p arg-info) (not (null (or keysp restp))))
1727         (setf (arg-info-keys arg-info)
1728               (if lambda-list-p
1729                   (if allow-other-keys-p t keywords)
1730                   (arg-info-key/rest-p arg-info)))))
1731     (when new-method
1732       (check-method-arg-info gf arg-info new-method))
1733     (set-arg-info1 gf arg-info new-method methods was-valid-p first-p)
1734     arg-info))
1735
1736 (defun check-method-arg-info (gf arg-info method)
1737   (multiple-value-bind (nreq nopt keysp restp allow-other-keys-p keywords)
1738       (analyze-lambda-list (if (consp method)
1739                                (early-method-lambda-list method)
1740                                (method-lambda-list method)))
1741     (flet ((lose (string &rest args)
1742              (error 'simple-program-error
1743                     :format-control "~@<attempt to add the method~2I~_~S~I~_~
1744                                      to the generic function~2I~_~S;~I~_~
1745                                      but ~?~:>"
1746                     :format-arguments (list method gf string args)))
1747            (comparison-description (x y)
1748              (if (> x y) "more" "fewer")))
1749       (let ((gf-nreq (arg-info-number-required arg-info))
1750             (gf-nopt (arg-info-number-optional arg-info))
1751             (gf-key/rest-p (arg-info-key/rest-p arg-info))
1752             (gf-keywords (arg-info-keys arg-info)))
1753         (unless (= nreq gf-nreq)
1754           (lose
1755            "the method has ~A required arguments than the generic function."
1756            (comparison-description nreq gf-nreq)))
1757         (unless (= nopt gf-nopt)
1758           (lose
1759            "the method has ~A optional arguments than the generic function."
1760            (comparison-description nopt gf-nopt)))
1761         (unless (eq (or keysp restp) gf-key/rest-p)
1762           (lose
1763            "the method and generic function differ in whether they accept~_~
1764             &REST or &KEY arguments."))
1765         (when (consp gf-keywords)
1766           (unless (or (and restp (not keysp))
1767                       allow-other-keys-p
1768                       (every (lambda (k) (memq k keywords)) gf-keywords))
1769             (lose "the method does not accept each of the &KEY arguments~2I~_~
1770                    ~S."
1771                   gf-keywords)))))))
1772
1773 (defun set-arg-info1 (gf arg-info new-method methods was-valid-p first-p)
1774   (let* ((existing-p (and methods (cdr methods) new-method))
1775          (nreq (length (arg-info-metatypes arg-info)))
1776          (metatypes (if existing-p
1777                         (arg-info-metatypes arg-info)
1778                         (make-list nreq)))
1779          (type (if existing-p
1780                    (gf-info-simple-accessor-type arg-info)
1781                    nil)))
1782     (when (arg-info-valid-p arg-info)
1783       (dolist (method (if new-method (list new-method) methods))
1784         (let* ((specializers (if (or (eq *boot-state* 'complete)
1785                                      (not (consp method)))
1786                                  (method-specializers method)
1787                                  (early-method-specializers method t)))
1788                (class (if (or (eq *boot-state* 'complete) (not (consp method)))
1789                           (class-of method)
1790                           (early-method-class method)))
1791                (new-type (when (and class
1792                                     (or (not (eq *boot-state* 'complete))
1793                                         (eq (generic-function-method-combination gf)
1794                                             *standard-method-combination*)))
1795                            (cond ((eq class *the-class-standard-reader-method*)
1796                                   'reader)
1797                                  ((eq class *the-class-standard-writer-method*)
1798                                   'writer)
1799                                  ((eq class *the-class-standard-boundp-method*)
1800                                   'boundp)))))
1801           (setq metatypes (mapcar #'raise-metatype metatypes specializers))
1802           (setq type (cond ((null type) new-type)
1803                            ((eq type new-type) type)
1804                            (t nil)))))
1805       (setf (arg-info-metatypes arg-info) metatypes)
1806       (setf (gf-info-simple-accessor-type arg-info) type)))
1807   (when (or (not was-valid-p) first-p)
1808     (multiple-value-bind (c-a-m-emf std-p)
1809         (if (early-gf-p gf)
1810             (values t t)
1811             (compute-applicable-methods-emf gf))
1812       (setf (gf-info-static-c-a-m-emf arg-info) c-a-m-emf)
1813       (setf (gf-info-c-a-m-emf-std-p arg-info) std-p)
1814       (unless (gf-info-c-a-m-emf-std-p arg-info)
1815         (setf (gf-info-simple-accessor-type arg-info) t))))
1816   (unless was-valid-p
1817     (let ((name (if (eq *boot-state* 'complete)
1818                     (generic-function-name gf)
1819                     (!early-gf-name gf))))
1820       (setf (gf-precompute-dfun-and-emf-p arg-info)
1821             (cond
1822               ((and (consp name)
1823                     (member (car name)
1824                             *internal-pcl-generalized-fun-name-symbols*))
1825                 nil)
1826               (t (let* ((symbol (fun-name-block-name name))
1827                         (package (symbol-package symbol)))
1828                    (and (or (eq package *pcl-package*)
1829                             (memq package (package-use-list *pcl-package*)))
1830                         ;; FIXME: this test will eventually be
1831                         ;; superseded by the *internal-pcl...* test,
1832                         ;; above.  While we are in a process of
1833                         ;; transition, however, it should probably
1834                         ;; remain.
1835                         (not (find #\Space (symbol-name symbol))))))))))
1836   (setf (gf-info-fast-mf-p arg-info)
1837         (or (not (eq *boot-state* 'complete))
1838             (let* ((method-class (generic-function-method-class gf))
1839                    (methods (compute-applicable-methods
1840                              #'make-method-lambda
1841                              (list gf (class-prototype method-class)
1842                                    '(lambda) nil))))
1843               (and methods (null (cdr methods))
1844                    (let ((specls (method-specializers (car methods))))
1845                      (and (classp (car specls))
1846                           (eq 'standard-generic-function
1847                               (class-name (car specls)))
1848                           (classp (cadr specls))
1849                           (eq 'standard-method
1850                               (class-name (cadr specls)))))))))
1851   arg-info)
1852
1853 ;;; This is the early definition of ENSURE-GENERIC-FUNCTION-USING-CLASS.
1854 ;;;
1855 ;;; The STATIC-SLOTS field of the funcallable instances used as early
1856 ;;; generic functions is used to store the early methods and early
1857 ;;; discriminator code for the early generic function. The static
1858 ;;; slots field of the fins contains a list whose:
1859 ;;;    CAR    -   a list of the early methods on this early gf
1860 ;;;    CADR   -   the early discriminator code for this method
1861 (defun ensure-generic-function-using-class (existing spec &rest keys
1862                                             &key (lambda-list nil
1863                                                               lambda-list-p)
1864                                             argument-precedence-order
1865                                             source-location
1866                                             &allow-other-keys)
1867   (declare (ignore keys))
1868   (cond ((and existing (early-gf-p existing))
1869          (when lambda-list-p
1870            (set-arg-info existing :lambda-list lambda-list))
1871          existing)
1872         ((assoc spec *!generic-function-fixups* :test #'equal)
1873          (if existing
1874              (make-early-gf spec lambda-list lambda-list-p existing
1875                             argument-precedence-order source-location)
1876              (error "The function ~S is not already defined." spec)))
1877         (existing
1878          (error "~S should be on the list ~S."
1879                 spec
1880                 '*!generic-function-fixups*))
1881         (t
1882          (pushnew spec *!early-generic-functions* :test #'equal)
1883          (make-early-gf spec lambda-list lambda-list-p nil
1884                         argument-precedence-order source-location))))
1885
1886 (defun make-early-gf (spec &optional lambda-list lambda-list-p
1887                       function argument-precedence-order source-location)
1888   (let ((fin (allocate-funcallable-instance *sgf-wrapper* *sgf-slots-init*)))
1889     (set-funcallable-instance-function
1890      fin
1891      (or function
1892          (if (eq spec 'print-object)
1893              #'(lambda (instance stream)
1894                  (print-unreadable-object (instance stream :identity t)
1895                    (format stream "std-instance")))
1896              #'(lambda (&rest args)
1897                  (declare (ignore args))
1898                  (error "The function of the funcallable-instance ~S~
1899                          has not been set." fin)))))
1900     (setf (gdefinition spec) fin)
1901     (!bootstrap-set-slot 'standard-generic-function fin 'name spec)
1902     (!bootstrap-set-slot 'standard-generic-function
1903                          fin
1904                          'source
1905                          source-location)
1906     (set-fun-name fin spec)
1907     (let ((arg-info (make-arg-info)))
1908       (setf (early-gf-arg-info fin) arg-info)
1909       (when lambda-list-p
1910         (proclaim (defgeneric-declaration spec lambda-list))
1911         (if argument-precedence-order
1912             (set-arg-info fin
1913                           :lambda-list lambda-list
1914                           :argument-precedence-order argument-precedence-order)
1915             (set-arg-info fin :lambda-list lambda-list))))
1916     fin))
1917
1918 (defun set-dfun (gf &optional dfun cache info)
1919   (when cache
1920     (setf (cache-owner cache) gf))
1921   (let ((new-state (if (and dfun (or cache info))
1922                        (list* dfun cache info)
1923                        dfun)))
1924     (if (eq *boot-state* 'complete)
1925         (setf (gf-dfun-state gf) new-state)
1926         (setf (clos-slots-ref (get-slots gf) *sgf-dfun-state-index*)
1927               new-state)))
1928   dfun)
1929
1930 (defun gf-dfun-cache (gf)
1931   (let ((state (if (eq *boot-state* 'complete)
1932                    (gf-dfun-state gf)
1933                    (clos-slots-ref (get-slots gf) *sgf-dfun-state-index*))))
1934     (typecase state
1935       (function nil)
1936       (cons (cadr state)))))
1937
1938 (defun gf-dfun-info (gf)
1939   (let ((state (if (eq *boot-state* 'complete)
1940                    (gf-dfun-state gf)
1941                    (clos-slots-ref (get-slots gf) *sgf-dfun-state-index*))))
1942     (typecase state
1943       (function nil)
1944       (cons (cddr state)))))
1945
1946 (defvar *sgf-name-index*
1947   (!bootstrap-slot-index 'standard-generic-function 'name))
1948
1949 (defun !early-gf-name (gf)
1950   (clos-slots-ref (get-slots gf) *sgf-name-index*))
1951
1952 (defun gf-lambda-list (gf)
1953   (let ((arg-info (if (eq *boot-state* 'complete)
1954                       (gf-arg-info gf)
1955                       (early-gf-arg-info gf))))
1956     (if (eq :no-lambda-list (arg-info-lambda-list arg-info))
1957         (let ((methods (if (eq *boot-state* 'complete)
1958                            (generic-function-methods gf)
1959                            (early-gf-methods gf))))
1960           (if (null methods)
1961               (progn
1962                 (warn "no way to determine the lambda list for ~S" gf)
1963                 nil)
1964               (let* ((method (car (last methods)))
1965                      (ll (if (consp method)
1966                              (early-method-lambda-list method)
1967                              (method-lambda-list method))))
1968                 (create-gf-lambda-list ll))))
1969         (arg-info-lambda-list arg-info))))
1970
1971 (defmacro real-ensure-gf-internal (gf-class all-keys env)
1972   `(progn
1973      (cond ((symbolp ,gf-class)
1974             (setq ,gf-class (find-class ,gf-class t ,env)))
1975            ((classp ,gf-class))
1976            (t
1977             (error "The :GENERIC-FUNCTION-CLASS argument (~S) was neither a~%~
1978                     class nor a symbol that names a class."
1979                    ,gf-class)))
1980      (remf ,all-keys :generic-function-class)
1981      (remf ,all-keys :environment)
1982      (let ((combin (getf ,all-keys :method-combination '.shes-not-there.)))
1983        (unless (eq combin '.shes-not-there.)
1984          (setf (getf ,all-keys :method-combination)
1985                (find-method-combination (class-prototype ,gf-class)
1986                                         (car combin)
1987                                         (cdr combin)))))
1988     (let ((method-class (getf ,all-keys :method-class '.shes-not-there.)))
1989       (unless (eq method-class '.shes-not-there.)
1990         (setf (getf ,all-keys :method-class)
1991               (cond ((classp method-class)
1992                      method-class)
1993                     (t (find-class method-class t ,env))))))))
1994
1995 (defun real-ensure-gf-using-class--generic-function
1996        (existing
1997         fun-name
1998         &rest all-keys
1999         &key environment (lambda-list nil lambda-list-p)
2000              (generic-function-class 'standard-generic-function gf-class-p)
2001         &allow-other-keys)
2002   (real-ensure-gf-internal generic-function-class all-keys environment)
2003   (unless (or (null gf-class-p)
2004               (eq (class-of existing) generic-function-class))
2005     (change-class existing generic-function-class))
2006   (prog1
2007       (apply #'reinitialize-instance existing all-keys)
2008     (when lambda-list-p
2009       (proclaim (defgeneric-declaration fun-name lambda-list)))))
2010
2011 (defun real-ensure-gf-using-class--null
2012        (existing
2013         fun-name
2014         &rest all-keys
2015         &key environment (lambda-list nil lambda-list-p)
2016              (generic-function-class 'standard-generic-function)
2017         &allow-other-keys)
2018   (declare (ignore existing))
2019   (real-ensure-gf-internal generic-function-class all-keys environment)
2020   (prog1
2021       (setf (gdefinition fun-name)
2022             (apply #'make-instance generic-function-class
2023                    :name fun-name all-keys))
2024     (when lambda-list-p
2025       (proclaim (defgeneric-declaration fun-name lambda-list)))))
2026 \f
2027 ;;; FIXME: this function took on a slightly greater role than it
2028 ;;; previously had around 2005-11-02, when CSR fixed the bug whereby
2029 ;;; having more than one subclass of standard-generic-function caused
2030 ;;; the whole system to die horribly through a metacircle in
2031 ;;; GF-ARG-INFO.  The fix is to be slightly more disciplined about
2032 ;;; calling accessor methods -- we call GET-GENERIC-FUN-INFO when
2033 ;;; computing discriminating functions, so we need to be careful about
2034 ;;; having a base case for the recursion, and we provide that with the
2035 ;;; STANDARD-GENERIC-FUNCTION case below.  However, we are not (yet)
2036 ;;; as disciplined as CLISP's CLOS/MOP, and it would be nice to get to
2037 ;;; that stage, where all potentially dangerous cases are enumerated
2038 ;;; and stopped.  -- CSR, 2005-11-02.
2039 (defun get-generic-fun-info (gf)
2040   ;; values   nreq applyp metatypes nkeys arg-info
2041   (multiple-value-bind (applyp metatypes arg-info)
2042       (let* ((arg-info (if (early-gf-p gf)
2043                            (early-gf-arg-info gf)
2044                            (if (eq (class-of gf) *the-class-standard-generic-function*)
2045                                (clos-slots-ref (fsc-instance-slots gf) *sgf-arg-info-index*)
2046                                (gf-arg-info gf))))
2047              (metatypes (arg-info-metatypes arg-info)))
2048         (values (arg-info-applyp arg-info)
2049                 metatypes
2050                 arg-info))
2051     (values (length metatypes) applyp metatypes
2052             (count-if (lambda (x) (neq x t)) metatypes)
2053             arg-info)))
2054
2055 (defun early-make-a-method (class qualifiers arglist specializers initargs doc
2056                             &optional slot-name)
2057   (initialize-method-function initargs)
2058   (let ((parsed ())
2059         (unparsed ()))
2060     ;; Figure out whether we got class objects or class names as the
2061     ;; specializers and set parsed and unparsed appropriately. If we
2062     ;; got class objects, then we can compute unparsed, but if we got
2063     ;; class names we don't try to compute parsed.
2064     ;;
2065     ;; Note that the use of not symbolp in this call to every should be
2066     ;; read as 'classp' we can't use classp itself because it doesn't
2067     ;; exist yet.
2068     (if (every (lambda (s) (not (symbolp s))) specializers)
2069         (setq parsed specializers
2070               unparsed (mapcar (lambda (s)
2071                                  (if (eq s t) t (class-name s)))
2072                                specializers))
2073         (setq unparsed specializers
2074               parsed ()))
2075     (list :early-method           ;This is an early method dammit!
2076
2077           (getf initargs :function)
2078           (getf initargs :fast-function)
2079
2080           parsed                  ;The parsed specializers. This is used
2081                                   ;by early-method-specializers to cache
2082                                   ;the parse. Note that this only comes
2083                                   ;into play when there is more than one
2084                                   ;early method on an early gf.
2085
2086           (list class        ;A list to which real-make-a-method
2087                 qualifiers      ;can be applied to make a real method
2088                 arglist    ;corresponding to this early one.
2089                 unparsed
2090                 initargs
2091                 doc
2092                 slot-name))))
2093
2094 (defun real-make-a-method
2095        (class qualifiers lambda-list specializers initargs doc
2096         &optional slot-name)
2097   (setq specializers (parse-specializers specializers))
2098   (apply #'make-instance class
2099          :qualifiers qualifiers
2100          :lambda-list lambda-list
2101          :specializers specializers
2102          :documentation doc
2103          :slot-name slot-name
2104          :allow-other-keys t
2105          initargs))
2106
2107 (defun early-method-function (early-method)
2108   (values (cadr early-method) (caddr early-method)))
2109
2110 (defun early-method-class (early-method)
2111   (find-class (car (fifth early-method))))
2112
2113 (defun early-method-standard-accessor-p (early-method)
2114   (let ((class (first (fifth early-method))))
2115     (or (eq class 'standard-reader-method)
2116         (eq class 'standard-writer-method)
2117         (eq class 'standard-boundp-method))))
2118
2119 (defun early-method-standard-accessor-slot-name (early-method)
2120   (seventh (fifth early-method)))
2121
2122 ;;; Fetch the specializers of an early method. This is basically just
2123 ;;; a simple accessor except that when the second argument is t, this
2124 ;;; converts the specializers from symbols into class objects. The
2125 ;;; class objects are cached in the early method, this makes
2126 ;;; bootstrapping faster because the class objects only have to be
2127 ;;; computed once.
2128 ;;;
2129 ;;; NOTE:
2130 ;;;  The second argument should only be passed as T by
2131 ;;;  early-lookup-method. This is to implement the rule that only when
2132 ;;;  there is more than one early method on a generic function is the
2133 ;;;  conversion from class names to class objects done. This
2134 ;;;  corresponds to the fact that we are only allowed to have one
2135 ;;;  method on any generic function up until the time classes exist.
2136 (defun early-method-specializers (early-method &optional objectsp)
2137   (if (and (listp early-method)
2138            (eq (car early-method) :early-method))
2139       (cond ((eq objectsp t)
2140              (or (fourth early-method)
2141                  (setf (fourth early-method)
2142                        (mapcar #'find-class (cadddr (fifth early-method))))))
2143             (t
2144              (cadddr (fifth early-method))))
2145       (error "~S is not an early-method." early-method)))
2146
2147 (defun early-method-qualifiers (early-method)
2148   (cadr (fifth early-method)))
2149
2150 (defun early-method-lambda-list (early-method)
2151   (caddr (fifth early-method)))
2152
2153 (defun early-add-named-method (generic-function-name
2154                                qualifiers
2155                                specializers
2156                                arglist
2157                                &rest initargs)
2158   (let* ((gf (ensure-generic-function generic-function-name))
2159          (existing
2160            (dolist (m (early-gf-methods gf))
2161              (when (and (equal (early-method-specializers m) specializers)
2162                         (equal (early-method-qualifiers m) qualifiers))
2163                (return m))))
2164          (new (make-a-method 'standard-method
2165                              qualifiers
2166                              arglist
2167                              specializers
2168                              initargs
2169                              ())))
2170     (when existing (remove-method gf existing))
2171     (add-method gf new)))
2172
2173 ;;; This is the early version of ADD-METHOD. Later this will become a
2174 ;;; generic function. See !FIX-EARLY-GENERIC-FUNCTIONS which has
2175 ;;; special knowledge about ADD-METHOD.
2176 (defun add-method (generic-function method)
2177   (when (not (fsc-instance-p generic-function))
2178     (error "Early ADD-METHOD didn't get a funcallable instance."))
2179   (when (not (and (listp method) (eq (car method) :early-method)))
2180     (error "Early ADD-METHOD didn't get an early method."))
2181   (push method (early-gf-methods generic-function))
2182   (set-arg-info generic-function :new-method method)
2183   (unless (assoc (!early-gf-name generic-function)
2184                  *!generic-function-fixups*
2185                  :test #'equal)
2186     (update-dfun generic-function)))
2187
2188 ;;; This is the early version of REMOVE-METHOD. See comments on
2189 ;;; the early version of ADD-METHOD.
2190 (defun remove-method (generic-function method)
2191   (when (not (fsc-instance-p generic-function))
2192     (error "An early remove-method didn't get a funcallable instance."))
2193   (when (not (and (listp method) (eq (car method) :early-method)))
2194     (error "An early remove-method didn't get an early method."))
2195   (setf (early-gf-methods generic-function)
2196         (remove method (early-gf-methods generic-function)))
2197   (set-arg-info generic-function)
2198   (unless (assoc (!early-gf-name generic-function)
2199                  *!generic-function-fixups*
2200                  :test #'equal)
2201     (update-dfun generic-function)))
2202
2203 ;;; This is the early version of GET-METHOD. See comments on the early
2204 ;;; version of ADD-METHOD.
2205 (defun get-method (generic-function qualifiers specializers
2206                                     &optional (errorp t))
2207   (if (early-gf-p generic-function)
2208       (or (dolist (m (early-gf-methods generic-function))
2209             (when (and (or (equal (early-method-specializers m nil)
2210                                   specializers)
2211                            (equal (early-method-specializers m t)
2212                                   specializers))
2213                        (equal (early-method-qualifiers m) qualifiers))
2214               (return m)))
2215           (if errorp
2216               (error "can't get early method")
2217               nil))
2218       (real-get-method generic-function qualifiers specializers errorp)))
2219
2220 (defun !fix-early-generic-functions ()
2221   (let ((accessors nil))
2222     ;; Rearrange *!EARLY-GENERIC-FUNCTIONS* to speed up
2223     ;; FIX-EARLY-GENERIC-FUNCTIONS.
2224     (dolist (early-gf-spec *!early-generic-functions*)
2225       (when (every #'early-method-standard-accessor-p
2226                    (early-gf-methods (gdefinition early-gf-spec)))
2227         (push early-gf-spec accessors)))
2228     (dolist (spec (nconc accessors
2229                          '(accessor-method-slot-name
2230                            generic-function-methods
2231                            method-specializers
2232                            specializerp
2233                            specializer-type
2234                            specializer-class
2235                            slot-definition-location
2236                            slot-definition-name
2237                            class-slots
2238                            gf-arg-info
2239                            class-precedence-list
2240                            slot-boundp-using-class
2241                            (setf slot-value-using-class)
2242                            slot-value-using-class
2243                            structure-class-p
2244                            standard-class-p
2245                            funcallable-standard-class-p
2246                            specializerp)))
2247       (/show spec)
2248       (setq *!early-generic-functions*
2249             (cons spec
2250                   (delete spec *!early-generic-functions* :test #'equal))))
2251
2252     (dolist (early-gf-spec *!early-generic-functions*)
2253       (/show early-gf-spec)
2254       (let* ((gf (gdefinition early-gf-spec))
2255              (methods (mapcar (lambda (early-method)
2256                                 (let ((args (copy-list (fifth
2257                                                         early-method))))
2258                                   (setf (fourth args)
2259                                         (early-method-specializers
2260                                          early-method t))
2261                                   (apply #'real-make-a-method args)))
2262                               (early-gf-methods gf))))
2263         (setf (generic-function-method-class gf) *the-class-standard-method*)
2264         (setf (generic-function-method-combination gf)
2265               *standard-method-combination*)
2266         (set-methods gf methods)))
2267
2268     (dolist (fn *!early-functions*)
2269       (/show fn)
2270       (setf (gdefinition (car fn)) (fdefinition (caddr fn))))
2271
2272     (dolist (fixup *!generic-function-fixups*)
2273       (/show fixup)
2274       (let* ((fspec (car fixup))
2275              (gf (gdefinition fspec))
2276              (methods (mapcar (lambda (method)
2277                                 (let* ((lambda-list (first method))
2278                                        (specializers (second method))
2279                                        (method-fn-name (third method))
2280                                        (fn-name (or method-fn-name fspec))
2281                                        (fn (fdefinition fn-name))
2282                                        (initargs
2283                                         (list :function
2284                                               (set-fun-name
2285                                                (lambda (args next-methods)
2286                                                  (declare (ignore
2287                                                            next-methods))
2288                                                  (apply fn args))
2289                                                `(call ,fn-name)))))
2290                                   (declare (type function fn))
2291                                   (make-a-method 'standard-method
2292                                                  ()
2293                                                  lambda-list
2294                                                  specializers
2295                                                  initargs
2296                                                  nil)))
2297                               (cdr fixup))))
2298         (setf (generic-function-method-class gf) *the-class-standard-method*)
2299         (setf (generic-function-method-combination gf)
2300               *standard-method-combination*)
2301         (set-methods gf methods))))
2302   (/show "leaving !FIX-EARLY-GENERIC-FUNCTIONS"))
2303 \f
2304 ;;; PARSE-DEFMETHOD is used by DEFMETHOD to parse the &REST argument
2305 ;;; into the 'real' arguments. This is where the syntax of DEFMETHOD
2306 ;;; is really implemented.
2307 (defun parse-defmethod (cdr-of-form)
2308   (declare (list cdr-of-form))
2309   (let ((name (pop cdr-of-form))
2310         (qualifiers ())
2311         (spec-ll ()))
2312     (loop (if (and (car cdr-of-form) (atom (car cdr-of-form)))
2313               (push (pop cdr-of-form) qualifiers)
2314               (return (setq qualifiers (nreverse qualifiers)))))
2315     (setq spec-ll (pop cdr-of-form))
2316     (values name qualifiers spec-ll cdr-of-form)))
2317
2318 (defun parse-specializers (specializers)
2319   (declare (list specializers))
2320   (flet ((parse (spec)
2321            (let ((result (specializer-from-type spec)))
2322              (if (specializerp result)
2323                  result
2324                  (if (symbolp spec)
2325                      (error "~S was used as a specializer,~%~
2326                              but is not the name of a class."
2327                             spec)
2328                      (error "~S is not a legal specializer." spec))))))
2329     (mapcar #'parse specializers)))
2330
2331 (defun unparse-specializers (specializers-or-method)
2332   (if (listp specializers-or-method)
2333       (flet ((unparse (spec)
2334                (if (specializerp spec)
2335                    (let ((type (specializer-type spec)))
2336                      (if (and (consp type)
2337                               (eq (car type) 'class))
2338                          (let* ((class (cadr type))
2339                                 (class-name (class-name class)))
2340                            (if (eq class (find-class class-name nil))
2341                                class-name
2342                                type))
2343                          type))
2344                    (error "~S is not a legal specializer." spec))))
2345         (mapcar #'unparse specializers-or-method))
2346       (unparse-specializers (method-specializers specializers-or-method))))
2347
2348 (defun parse-method-or-spec (spec &optional (errorp t))
2349   (let (gf method name temp)
2350     (if (method-p spec)
2351         (setq method spec
2352               gf (method-generic-function method)
2353               temp (and gf (generic-function-name gf))
2354               name (if temp
2355                        (make-method-spec temp
2356                                          (method-qualifiers method)
2357                                          (unparse-specializers
2358                                           (method-specializers method)))
2359                        (make-symbol (format nil "~S" method))))
2360         (multiple-value-bind (gf-spec quals specls)
2361             (parse-defmethod spec)
2362           (and (setq gf (and (or errorp (fboundp gf-spec))
2363                              (gdefinition gf-spec)))
2364                (let ((nreq (compute-discriminating-function-arglist-info gf)))
2365                  (setq specls (append (parse-specializers specls)
2366                                       (make-list (- nreq (length specls))
2367                                                  :initial-element
2368                                                  *the-class-t*)))
2369                  (and
2370                    (setq method (get-method gf quals specls errorp))
2371                    (setq name
2372                          (make-method-spec
2373                           gf-spec quals (unparse-specializers specls))))))))
2374     (values gf method name)))
2375 \f
2376 (defun extract-parameters (specialized-lambda-list)
2377   (multiple-value-bind (parameters ignore1 ignore2)
2378       (parse-specialized-lambda-list specialized-lambda-list)
2379     (declare (ignore ignore1 ignore2))
2380     parameters))
2381
2382 (defun extract-lambda-list (specialized-lambda-list)
2383   (multiple-value-bind (ignore1 lambda-list ignore2)
2384       (parse-specialized-lambda-list specialized-lambda-list)
2385     (declare (ignore ignore1 ignore2))
2386     lambda-list))
2387
2388 (defun extract-specializer-names (specialized-lambda-list)
2389   (multiple-value-bind (ignore1 ignore2 specializers)
2390       (parse-specialized-lambda-list specialized-lambda-list)
2391     (declare (ignore ignore1 ignore2))
2392     specializers))
2393
2394 (defun extract-required-parameters (specialized-lambda-list)
2395   (multiple-value-bind (ignore1 ignore2 ignore3 required-parameters)
2396       (parse-specialized-lambda-list specialized-lambda-list)
2397     (declare (ignore ignore1 ignore2 ignore3))
2398     required-parameters))
2399
2400 (define-condition specialized-lambda-list-error
2401     (reference-condition simple-program-error)
2402   ()
2403   (:default-initargs :references (list '(:ansi-cl :section (3 4 3)))))
2404
2405 (defun parse-specialized-lambda-list
2406     (arglist
2407      &optional supplied-keywords (allowed-keywords '(&optional &rest &key &aux))
2408      &aux (specialized-lambda-list-keywords
2409            '(&optional &rest &key &allow-other-keys &aux)))
2410   (let ((arg (car arglist)))
2411     (cond ((null arglist) (values nil nil nil nil))
2412           ((eq arg '&aux)
2413            (values nil arglist nil nil))
2414           ((memq arg lambda-list-keywords)
2415            ;; non-standard lambda-list-keywords are errors.
2416            (unless (memq arg specialized-lambda-list-keywords)
2417              (error 'specialized-lambda-list-error
2418                     :format-control "unknown specialized-lambda-list ~
2419                                      keyword ~S~%"
2420                     :format-arguments (list arg)))
2421            ;; no multiple &rest x &rest bla specifying
2422            (when (memq arg supplied-keywords)
2423              (error 'specialized-lambda-list-error
2424                     :format-control "multiple occurrence of ~
2425                                      specialized-lambda-list keyword ~S~%"
2426                     :format-arguments (list arg)))
2427            ;; And no placing &key in front of &optional, either.
2428            (unless (memq arg allowed-keywords)
2429              (error 'specialized-lambda-list-error
2430                     :format-control "misplaced specialized-lambda-list ~
2431                                      keyword ~S~%"
2432                     :format-arguments (list arg)))
2433            ;; When we are at a lambda-list keyword, the parameters
2434            ;; don't include the lambda-list keyword; the lambda-list
2435            ;; does include the lambda-list keyword; and no
2436            ;; specializers are allowed to follow the lambda-list
2437            ;; keywords (at least for now).
2438            (multiple-value-bind (parameters lambda-list)
2439                (parse-specialized-lambda-list (cdr arglist)
2440                                               (cons arg supplied-keywords)
2441                                               (if (eq arg '&key)
2442                                                   (cons '&allow-other-keys
2443                                                         (cdr (member arg allowed-keywords)))
2444                                                 (cdr (member arg allowed-keywords))))
2445              (when (and (eq arg '&rest)
2446                         (or (null lambda-list)
2447                             (memq (car lambda-list)
2448                                   specialized-lambda-list-keywords)
2449                             (not (or (null (cadr lambda-list))
2450                                      (memq (cadr lambda-list)
2451                                            specialized-lambda-list-keywords)))))
2452                (error 'specialized-lambda-list-error
2453                       :format-control
2454                       "in a specialized-lambda-list, excactly one ~
2455                        variable must follow &REST.~%"
2456                       :format-arguments nil))
2457              (values parameters
2458                      (cons arg lambda-list)
2459                      ()
2460                      ())))
2461           (supplied-keywords
2462            ;; After a lambda-list keyword there can be no specializers.
2463            (multiple-value-bind (parameters lambda-list)
2464                (parse-specialized-lambda-list (cdr arglist)
2465                                               supplied-keywords
2466                                               allowed-keywords)
2467              (values (cons (if (listp arg) (car arg) arg) parameters)
2468                      (cons arg lambda-list)
2469                      ()
2470                      ())))
2471           (t
2472            (multiple-value-bind (parameters lambda-list specializers required)
2473                (parse-specialized-lambda-list (cdr arglist))
2474              (values (cons (if (listp arg) (car arg) arg) parameters)
2475                      (cons (if (listp arg) (car arg) arg) lambda-list)
2476                      (cons (if (listp arg) (cadr arg) t) specializers)
2477                      (cons (if (listp arg) (car arg) arg) required)))))))
2478 \f
2479 (setq *boot-state* 'early)
2480 \f
2481 ;;; FIXME: In here there was a #-CMU definition of SYMBOL-MACROLET
2482 ;;; which used %WALKER stuff. That suggests to me that maybe the code
2483 ;;; walker stuff was only used for implementing stuff like that; maybe
2484 ;;; it's not needed any more? Hunt down what it was used for and see.
2485
2486 (defmacro with-slots (slots instance &body body)
2487   (let ((in (gensym)))
2488     `(let ((,in ,instance))
2489        (declare (ignorable ,in))
2490        ,@(let ((instance (if (and (consp instance) (eq (car instance) 'the))
2491                              (third instance)
2492                              instance)))
2493            (and (symbolp instance)
2494                 `((declare (%variable-rebinding ,in ,instance)))))
2495        ,in
2496        (symbol-macrolet ,(mapcar (lambda (slot-entry)
2497                                    (let ((var-name
2498                                           (if (symbolp slot-entry)
2499                                               slot-entry
2500                                               (car slot-entry)))
2501                                          (slot-name
2502                                           (if (symbolp slot-entry)
2503                                               slot-entry
2504                                               (cadr slot-entry))))
2505                                      `(,var-name
2506                                        (slot-value ,in ',slot-name))))
2507                                  slots)
2508                         ,@body))))
2509
2510 (defmacro with-accessors (slots instance &body body)
2511   (let ((in (gensym)))
2512     `(let ((,in ,instance))
2513        (declare (ignorable ,in))
2514        ,@(let ((instance (if (and (consp instance) (eq (car instance) 'the))
2515                              (third instance)
2516                              instance)))
2517            (and (symbolp instance)
2518                 `((declare (%variable-rebinding ,in ,instance)))))
2519        ,in
2520        (symbol-macrolet ,(mapcar (lambda (slot-entry)
2521                                    (let ((var-name (car slot-entry))
2522                                          (accessor-name (cadr slot-entry)))
2523                                      `(,var-name (,accessor-name ,in))))
2524                                  slots)
2525           ,@body))))