src/pcl/boot.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 #|
  27
  28 The CommonLoops evaluator is meta-circular.
  29
  30 Most of the code in PCL is methods on generic functions, including
  31 most of the code that actually implements generic functions and method
  32 lookup.
  33
  34 So, we have a classic bootstrapping problem. The solution to this is
  35 to first get a cheap implementation of generic functions running,
  36 these are called early generic functions. These early generic
  37 functions and the corresponding early methods and early method lookup
  38 are used to get enough of the system running that it is possible to
  39 create real generic functions and methods and implement real method
  40 lookup. At that point (done in the file FIXUP) the function
  41 !FIX-EARLY-GENERIC-FUNCTIONS is called to convert all the early generic
  42 functions to real generic functions.
  43
  44 The cheap generic functions are built using the same
  45 FUNCALLABLE-INSTANCE objects that real generic functions are made out of.
  46 This means that as PCL is being bootstrapped, the cheap generic
  47 function objects which are being created are the same objects which
  48 will later be real generic functions. This is good because:
  49   - we don't cons garbage structure, and
  50   - we can keep pointers to the cheap generic function objects
  51     during booting because those pointers will still point to
  52     the right object after the generic functions are all fixed up.
  53
  54 This file defines the DEFMETHOD macro and the mechanism used to expand
  55 it. This includes the mechanism for processing the body of a method.
  56 DEFMETHOD basically expands into a call to LOAD-DEFMETHOD, which
  57 basically calls ADD-METHOD to add the method to the generic function.
  58 These expansions can be loaded either during bootstrapping or when PCL
  59 is fully up and running.
  60
  61 An important effect of this arrangement is it means we can compile
  62 files with DEFMETHOD forms in them in a completely running PCL, but
  63 then load those files back in during bootstrapping. This makes
  64 development easier. It also means there is only one set of code for
  65 processing DEFMETHOD. Bootstrapping works by being sure to have
  66 LOAD-METHOD be careful to call only primitives which work during
  67 bootstrapping.
  68
  69 |#
  70
  71 ;;; FIXME: As of sbcl-0.6.9.10, PCL still uses this nonstandard type
  72 ;;; of declaration internally. It would be good to figure out how to
  73 ;;; get rid of it, or failing that, (1) document why it's needed and
  74 ;;; (2) use a private symbol with a forbidding name which suggests
  75 ;;; it's not to be messed with by the user (e.g. SB-PCL:%CLASS)
  76 ;;; instead of the too-inviting CLASS. (I tried just deleting the
  77 ;;; declarations in MAKE-METHOD-LAMBDA-INTERNAL ca. sbcl-0.6.9.10, but
  78 ;;; then things break.)
  79 (declaim (declaration class))
  80
  81 (declaim (notinline make-a-method
  82                     add-named-method
  83                     ensure-generic-function-using-class
  84                     add-method
  85                     remove-method))
  86
  87 (defvar *!early-functions*
  88         '((make-a-method early-make-a-method
  89                          real-make-a-method)
  90           (add-named-method early-add-named-method
  91                             real-add-named-method)
  92           ))
  93
  94 ;;; For each of the early functions, arrange to have it point to its
  95 ;;; early definition. Do this in a way that makes sure that if we
  96 ;;; redefine one of the early definitions the redefinition will take
  97 ;;; effect. This makes development easier.
  98 (dolist (fns *!early-functions*)
  99   (let ((name (car fns))
 100         (early-name (cadr fns)))
 101     (setf (gdefinition name)
 102             (set-fun-name
 103              (lambda (&rest args)
 104                (apply (fdefinition early-name) args))
 105              name))))
 106
 107 ;;; *!GENERIC-FUNCTION-FIXUPS* is used by !FIX-EARLY-GENERIC-FUNCTIONS
 108 ;;; to convert the few functions in the bootstrap which are supposed
 109 ;;; to be generic functions but can't be early on.
 110 (defvar *!generic-function-fixups*
 111   '((add-method
 112      ((generic-function method)  ;lambda-list
 113       (standard-generic-function method) ;specializers
 114       real-add-method))          ;method-function
 115     (remove-method
 116      ((generic-function method)
 117       (standard-generic-function method)
 118       real-remove-method))
 119     (get-method
 120      ((generic-function qualifiers specializers &optional (errorp t))
 121       (standard-generic-function t t)
 122       real-get-method))
 123     (ensure-generic-function-using-class
 124      ((generic-function fun-name
 125                         &key generic-function-class environment
 126                         &allow-other-keys)
 127       (generic-function t)
 128       real-ensure-gf-using-class--generic-function)
 129      ((generic-function fun-name
 130                         &key generic-function-class environment
 131                         &allow-other-keys)
 132       (null t)
 133       real-ensure-gf-using-class--null))
 134     (make-method-lambda
 135      ((proto-generic-function proto-method lambda-expression environment)
 136       (standard-generic-function standard-method t t)
 137       real-make-method-lambda))
 138     (make-method-initargs-form
 139      ((proto-generic-function proto-method
 140                               lambda-expression
 141                               lambda-list environment)
 142       (standard-generic-function standard-method t t t)
 143       real-make-method-initargs-form))
 144     (compute-effective-method
 145      ((generic-function combin applicable-methods)
 146       (generic-function standard-method-combination t)
 147       standard-compute-effective-method))))
 148 \f
 149 (defmacro defgeneric (fun-name lambda-list &body options)
 150   (declare (type list lambda-list))
 151   (unless (legal-fun-name-p fun-name)
 152     (error 'simple-program-error
 153            :format-control "illegal generic function name ~S"
 154            :format-arguments (list fun-name)))
 155   (check-gf-lambda-list lambda-list)
 156   (let ((initargs ())
 157         (methods ()))
 158     (flet ((duplicate-option (name)
 159              (error 'simple-program-error
 160                     :format-control "The option ~S appears more than once."
 161                     :format-arguments (list name)))
 162            (expand-method-definition (qab) ; QAB = qualifiers, arglist, body
 163              (let* ((arglist-pos (position-if #'listp qab))
 164                     (arglist (elt qab arglist-pos))
 165                     (qualifiers (subseq qab 0 arglist-pos))
 166                     (body (nthcdr (1+ arglist-pos) qab)))
 167                `(push (defmethod ,fun-name ,@qualifiers ,arglist ,@body)
 168                       (generic-function-initial-methods #',fun-name)))))
 169       (macrolet ((initarg (key) `(getf initargs ,key)))
 170         (dolist (option options)
 171           (let ((car-option (car option)))
 172             (case car-option
 173               (declare
 174                (when (and
 175                       (consp (cadr option))
 176                       (member (first (cadr option))
 177                               ;; FIXME: this list is slightly weird.
 178                               ;; ANSI (on the DEFGENERIC page) in one
 179                               ;; place allows only OPTIMIZE; in
 180                               ;; another place gives this list of
 181                               ;; disallowed declaration specifiers.
 182                               ;; This seems to be the only place where
 183                               ;; the FUNCTION declaration is
 184                               ;; mentioned; TYPE seems to be missing.
 185                               ;; Very strange.  -- CSR, 2002-10-21
 186                               '(declaration ftype function
 187                                 inline notinline special)))
 188                  (error 'simple-program-error
 189                         :format-control "The declaration specifier ~S ~
 190                                          is not allowed inside DEFGENERIC."
 191                         :format-arguments (list (cadr option))))
 192                (push (cadr option) (initarg :declarations)))
 193               (:method-combination
 194                (when (initarg car-option)
 195                  (duplicate-option car-option))
 196                (unless (symbolp (cadr option))
 197                  (error 'simple-program-error
 198                         :format-control "METHOD-COMBINATION name not a ~
 199                                          symbol: ~S"
 200                         :format-arguments (list (cadr option))))
 201                (setf (initarg car-option)
 202                      `',(cdr option)))
 203               (:argument-precedence-order
 204                (let* ((required (parse-lambda-list lambda-list))
 205                       (supplied (cdr option)))
 206                  (unless (= (length required) (length supplied))
 207                    (error 'simple-program-error
 208                           :format-control "argument count discrepancy in ~
 209                                            :ARGUMENT-PRECEDENCE-ORDER clause."
 210                           :format-arguments nil))
 211                  (when (set-difference required supplied)
 212                    (error 'simple-program-error
 213                           :format-control "unequal sets for ~
 214                                            :ARGUMENT-PRECEDENCE-ORDER clause: ~
 215                                            ~S and ~S"
 216                           :format-arguments (list required supplied)))
 217                  (setf (initarg car-option)
 218                        `',(cdr option))))
 219               ((:documentation :generic-function-class :method-class)
 220                (unless (proper-list-of-length-p option 2)
 221                  (error "bad list length for ~S" option))
 222                (if (initarg car-option)
 223                    (duplicate-option car-option)
 224                    (setf (initarg car-option) `',(cadr option))))
 225               (:method
 226                (push (cdr option) methods))
 227               (t
 228                ;; ANSI requires that unsupported things must get a
 229                ;; PROGRAM-ERROR.
 230                (error 'simple-program-error
 231                       :format-control "unsupported option ~S"
 232                       :format-arguments (list option))))))
 233
 234         (when (initarg :declarations)
 235           (setf (initarg :declarations)
 236                 `',(initarg :declarations))))
 237       `(progn
 238          (eval-when (:compile-toplevel :load-toplevel :execute)
 239            (compile-or-load-defgeneric ',fun-name))
 240          (load-defgeneric ',fun-name ',lambda-list ,@initargs)
 241         ,@(mapcar #'expand-method-definition methods)
 242          #',fun-name))))
 243
 244 (defun compile-or-load-defgeneric (fun-name)
 245   (proclaim-as-fun-name fun-name)
 246   (note-name-defined fun-name :function)
 247   (unless (eq (info :function :where-from fun-name) :declared)
 248     (setf (info :function :where-from fun-name) :defined)
 249     (setf (info :function :type fun-name)
 250           (specifier-type 'function))))
 251
 252 (defun load-defgeneric (fun-name lambda-list &rest initargs)
 253   (when (fboundp fun-name)
 254     (style-warn "redefining ~S in DEFGENERIC" fun-name)
 255     (let ((fun (fdefinition fun-name)))
 256       (when (generic-function-p fun)
 257         (loop for method in (generic-function-initial-methods fun)
 258               do (remove-method fun method))
 259         (setf (generic-function-initial-methods fun) '()))))
 260   (apply #'ensure-generic-function
 261          fun-name
 262          :lambda-list lambda-list
 263          :definition-source `((defgeneric ,fun-name) ,*load-pathname*)
 264          initargs))
 265
 266 ;;; As per section 3.4.2 of the ANSI spec, generic function lambda
 267 ;;; lists have some special limitations, which we check here.
 268 (defun check-gf-lambda-list (lambda-list)
 269   (flet ((ensure (arg ok)
 270            (unless ok
 271              (error
 272               ;; (s/invalid/non-ANSI-conforming/ because the old PCL
 273               ;; implementation allowed this, so people got used to
 274               ;; it, and maybe this phrasing will help them to guess
 275               ;; why their program which worked under PCL no longer works.)
 276               "~@<non-ANSI-conforming argument ~S ~_in the generic function lambda list ~S~:>"
 277               arg lambda-list))))
 278     (multiple-value-bind (required optional restp rest keyp keys allowp
 279                           auxp aux morep more-context more-count)
 280         (parse-lambda-list lambda-list)
 281       (declare (ignore required)) ; since they're no different in a gf ll
 282       (declare (ignore restp rest)) ; since they're no different in a gf ll
 283       (declare (ignore allowp)) ; since &ALLOW-OTHER-KEYS is fine either way
 284       (declare (ignore aux)) ; since we require AUXP=NIL
 285       (declare (ignore more-context more-count)) ; safely ignored unless MOREP
 286       ;; no defaults allowed for &OPTIONAL arguments
 287       (dolist (i optional)
 288         (ensure i (or (symbolp i)
 289                       (and (consp i) (symbolp (car i)) (null (cdr i))))))
 290       ;; no defaults allowed for &KEY arguments
 291       (when keyp
 292         (dolist (i keys)
 293           (ensure i (or (symbolp i)
 294                         (and (consp i)
 295                              (or (symbolp (car i))
 296                                  (and (consp (car i))
 297                                       (symbolp (caar i))
 298                                       (symbolp (cadar i))
 299                                       (null (cddar i))))
 300                              (null (cdr i)))))))
 301       ;; no &AUX allowed
 302       (when auxp
 303         (error "&AUX is not allowed in a generic function lambda list: ~S"
 304                lambda-list))
 305       ;; Oh, *puhlease*... not specifically as per section 3.4.2 of
 306       ;; the ANSI spec, but the CMU CL &MORE extension does not
 307       ;; belong here!
 308       (aver (not morep)))))
 309 \f
 310 (defmacro defmethod (&rest args &environment env)
 311   (multiple-value-bind (name qualifiers lambda-list body)
 312       (parse-defmethod args)
 313     (multiple-value-bind (proto-gf proto-method)
 314         (prototypes-for-make-method-lambda name)
 315       (expand-defmethod name
 316                         proto-gf
 317                         proto-method
 318                         qualifiers
 319                         lambda-list
 320                         body
 321                         env))))
 322
 323 (defun prototypes-for-make-method-lambda (name)
 324   (if (not (eq *boot-state* 'complete))
 325       (values nil nil)
 326       (let ((gf? (and (gboundp name)
 327                       (gdefinition name))))
 328         (if (or (null gf?)
 329                 (not (generic-function-p gf?)))
 330             (values (class-prototype (find-class 'standard-generic-function))
 331                     (class-prototype (find-class 'standard-method)))
 332             (values gf?
 333                     (class-prototype (or (generic-function-method-class gf?)
 334                                          (find-class 'standard-method))))))))
 335
 336 ;;; Take a name which is either a generic function name or a list specifying
 337 ;;; a SETF generic function (like: (SETF <generic-function-name>)). Return
 338 ;;; the prototype instance of the method-class for that generic function.
 339 ;;;
 340 ;;; If there is no generic function by that name, this returns the
 341 ;;; default value, the prototype instance of the class
 342 ;;; STANDARD-METHOD. This default value is also returned if the spec
 343 ;;; names an ordinary function or even a macro. In effect, this leaves
 344 ;;; the signalling of the appropriate error until load time.
 345 ;;;
 346 ;;; Note: During bootstrapping, this function is allowed to return NIL.
 347 (defun method-prototype-for-gf (name)
 348   (let ((gf? (and (gboundp name)
 349                   (gdefinition name))))
 350     (cond ((neq *boot-state* 'complete) nil)
 351           ((or (null gf?)
 352                (not (generic-function-p gf?)))          ; Someone else MIGHT
 353                                                         ; error at load time.
 354            (class-prototype (find-class 'standard-method)))
 355           (t
 356             (class-prototype (or (generic-function-method-class gf?)
 357                                  (find-class 'standard-method)))))))
 358 \f
 359 (defun expand-defmethod (name
 360                          proto-gf
 361                          proto-method
 362                          qualifiers
 363                          lambda-list
 364                          body
 365                          env)
 366   (multiple-value-bind (method-lambda unspecialized-lambda-list specializers)
 367       (add-method-declarations name qualifiers lambda-list body env)
 368     (multiple-value-bind (method-function-lambda initargs)
 369         (make-method-lambda proto-gf proto-method method-lambda env)
 370       (let ((initargs-form (make-method-initargs-form proto-gf
 371                                                       proto-method
 372                                                       method-function-lambda
 373                                                       initargs
 374                                                       env)))
 375         `(progn
 376           ;; Note: We could DECLAIM the ftype of the generic function
 377           ;; here, since ANSI specifies that we create it if it does
 378           ;; not exist. However, I chose not to, because I think it's
 379           ;; more useful to support a style of programming where every
 380           ;; generic function has an explicit DEFGENERIC and any typos
 381           ;; in DEFMETHODs are warned about. Otherwise
 382           ;;
 383           ;;   (DEFGENERIC FOO-BAR-BLETCH ((X T)))
 384           ;;   (DEFMETHOD FOO-BAR-BLETCH ((X HASH-TABLE)) ..)
 385           ;;   (DEFMETHOD FOO-BRA-BLETCH ((X SIMPLE-VECTOR)) ..)
 386           ;;   (DEFMETHOD FOO-BAR-BLETCH ((X VECTOR)) ..)
 387           ;;   (DEFMETHOD FOO-BAR-BLETCH ((X ARRAY)) ..)
 388           ;;   (DEFMETHOD FOO-BAR-BLETCH ((X LIST)) ..)
 389           ;;
 390           ;; compiles without raising an error and runs without
 391           ;; raising an error (since SIMPLE-VECTOR cases fall through
 392           ;; to VECTOR) but still doesn't do what was intended. I hate
 393           ;; that kind of bug (code which silently gives the wrong
 394           ;; answer), so we don't do a DECLAIM here. -- WHN 20000229
 395           ,(make-defmethod-form name qualifiers specializers
 396                                 unspecialized-lambda-list
 397                                 (if proto-method
 398                                     (class-name (class-of proto-method))
 399                                     'standard-method)
 400                                 initargs-form
 401                                 (getf (getf initargs :plist)
 402                                       :pv-table-symbol)))))))
 403
 404 (defun interned-symbol-p (x)
 405   (and (symbolp x) (symbol-package x)))
 406
 407 (defun make-defmethod-form (name qualifiers specializers
 408                                  unspecialized-lambda-list method-class-name
 409                                  initargs-form &optional pv-table-symbol)
 410   (let (fn
 411         fn-lambda)
 412     (if (and (interned-symbol-p (fun-name-block-name name))
 413              (every #'interned-symbol-p qualifiers)
 414              (every (lambda (s)
 415                       (if (consp s)
 416                           (and (eq (car s) 'eql)
 417                                (constantp (cadr s))
 418                                (let ((sv (eval (cadr s))))
 419                                  (or (interned-symbol-p sv)
 420                                      (integerp sv)
 421                                      (and (characterp sv)
 422                                           (standard-char-p sv)))))
 423                           (interned-symbol-p s)))
 424                     specializers)
 425              (consp initargs-form)
 426              (eq (car initargs-form) 'list*)
 427              (memq (cadr initargs-form) '(:function :fast-function))
 428              (consp (setq fn (caddr initargs-form)))
 429              (eq (car fn) 'function)
 430              (consp (setq fn-lambda (cadr fn)))
 431              (eq (car fn-lambda) 'lambda))
 432         (let* ((specls (mapcar (lambda (specl)
 433                                  (if (consp specl)
 434                                      `(,(car specl) ,(eval (cadr specl)))
 435                                    specl))
 436                                specializers))
 437                (mname `(,(if (eq (cadr initargs-form) :function)
 438                              'method 'fast-method)
 439                         ,name ,@qualifiers ,specls))
 440                (mname-sym (intern (let ((*print-pretty* nil)
 441                                         ;; (We bind *PACKAGE* to
 442                                         ;; KEYWORD here as a way to
 443                                         ;; force symbols to be printed
 444                                         ;; with explicit package
 445                                         ;; prefixes.)
 446                                         (*package* *keyword-package*))
 447                                     (format nil "~S" mname)))))
 448           `(progn
 449              (defun ,mname-sym ,(cadr fn-lambda)
 450                ,@(cddr fn-lambda))
 451              ,(make-defmethod-form-internal
 452                name qualifiers `',specls
 453                unspecialized-lambda-list method-class-name
 454                `(list* ,(cadr initargs-form)
 455                        #',mname-sym
 456                        ,@(cdddr initargs-form))
 457                pv-table-symbol)))
 458         (make-defmethod-form-internal
 459          name qualifiers
 460          `(list ,@(mapcar (lambda (specializer)
 461                             (if (consp specializer)
 462                                 ``(,',(car specializer)
 463                                    ,,(cadr specializer))
 464                                 `',specializer))
 465                           specializers))
 466          unspecialized-lambda-list
 467          method-class-name
 468          initargs-form
 469          pv-table-symbol))))
 470
 471 (defun make-defmethod-form-internal
 472     (name qualifiers specializers-form unspecialized-lambda-list
 473      method-class-name initargs-form &optional pv-table-symbol)
 474   `(load-defmethod
 475     ',method-class-name
 476     ',name
 477     ',qualifiers
 478     ,specializers-form
 479     ',unspecialized-lambda-list
 480     ,initargs-form
 481     ;; Paper over a bug in KCL by passing the cache-symbol here in
 482     ;; addition to in the list. FIXME: We should no longer need to do
 483     ;; this, since the CLOS code is now SBCL-specific, and doesn't
 484     ;; need to be ported to every buggy compiler in existence.
 485     ',pv-table-symbol))
 486
 487 (defmacro make-method-function (method-lambda &environment env)
 488   (make-method-function-internal method-lambda env))
 489
 490 (defun make-method-function-internal (method-lambda &optional env)
 491   (multiple-value-bind (proto-gf proto-method)
 492       (prototypes-for-make-method-lambda nil)
 493     (multiple-value-bind (method-function-lambda initargs)
 494         (make-method-lambda proto-gf proto-method method-lambda env)
 495       (make-method-initargs-form proto-gf
 496                                  proto-method
 497                                  method-function-lambda
 498                                  initargs
 499                                  env))))
 500
 501 (defun add-method-declarations (name qualifiers lambda-list body env)
 502   (multiple-value-bind (parameters unspecialized-lambda-list specializers)
 503       (parse-specialized-lambda-list lambda-list)
 504     (declare (ignore parameters))
 505     (multiple-value-bind (real-body declarations documentation)
 506         (parse-body body env)
 507       (values `(lambda ,unspecialized-lambda-list
 508                  ,@(when documentation `(,documentation))
 509                  ;; (Old PCL code used a somewhat different style of
 510                  ;; list for %METHOD-NAME values. Our names use
 511                  ;; ,@QUALIFIERS instead of ,QUALIFIERS so that the
 512                  ;; method names look more like what you see in a
 513                  ;; DEFMETHOD form.)
 514                  ;;
 515                  ;; FIXME: As of sbcl-0.7.0.6, code elsewhere, at
 516                  ;; least the code to set up named BLOCKs around the
 517                  ;; bodies of methods, depends on the function's base
 518                  ;; name being the first element of the %METHOD-NAME
 519                  ;; list. It would be good to remove this dependency,
 520                  ;; perhaps by building the BLOCK here, or by using
 521                  ;; another declaration (e.g. %BLOCK-NAME), so that
 522                  ;; our method debug names are free to have any format,
 523                  ;; e.g. (:METHOD PRINT-OBJECT :AROUND (CLOWN T)).
 524                  ;;
 525                  ;; Further, as of sbcl-0.7.9.10, the code to
 526                  ;; implement NO-NEXT-METHOD is coupled to the form of
 527                  ;; this declaration; see the definition of
 528                  ;; CALL-NO-NEXT-METHOD (and the passing of
 529                  ;; METHOD-NAME-DECLARATION arguments around the
 530                  ;; various CALL-NEXT-METHOD logic).
 531                  (declare (%method-name (,name
 532                                          ,@qualifiers
 533                                          ,specializers)))
 534                  (declare (%method-lambda-list ,@lambda-list))
 535                  ,@declarations
 536                  ,@real-body)
 537               unspecialized-lambda-list specializers))))
 538
 539 (defun real-make-method-initargs-form (proto-gf proto-method
 540                                        method-lambda initargs env)
 541   (declare (ignore proto-gf proto-method))
 542   (unless (and (consp method-lambda)
 543                (eq (car method-lambda) 'lambda))
 544     (error "The METHOD-LAMBDA argument to MAKE-METHOD-FUNCTION, ~S, ~
 545             is not a lambda form."
 546            method-lambda))
 547   (make-method-initargs-form-internal method-lambda initargs env))
 548
 549 (unless (fboundp 'make-method-initargs-form)
 550   (setf (gdefinition 'make-method-initargs-form)
 551         (symbol-function 'real-make-method-initargs-form)))
 552
 553 (defun real-make-method-lambda (proto-gf proto-method method-lambda env)
 554   (declare (ignore proto-gf proto-method))
 555   (make-method-lambda-internal method-lambda env))
 556
 557 ;;; a helper function for creating Python-friendly type declarations
 558 ;;; in DEFMETHOD forms
 559 (defun parameter-specializer-declaration-in-defmethod (parameter specializer)
 560   (cond ((and (consp specializer)
 561               (eq (car specializer) 'eql))
 562          ;; KLUDGE: ANSI, in its wisdom, says that
 563          ;; EQL-SPECIALIZER-FORMs in EQL specializers are evaluated at
 564          ;; DEFMETHOD expansion time. Thus, although one might think
 565          ;; that in
 566          ;;   (DEFMETHOD FOO ((X PACKAGE)
 567          ;;                   (Y (EQL 12))
 568          ;;      ..))
 569          ;; the PACKAGE and (EQL 12) forms are both parallel type
 570          ;; names, they're not, as is made clear when you do
 571          ;;   (DEFMETHOD FOO ((X PACKAGE)
 572          ;;                   (Y (EQL 'BAR)))
 573          ;;     ..)
 574          ;; where Y needs to be a symbol named "BAR", not some cons
 575          ;; made by (CONS 'QUOTE 'BAR). I.e. when the
 576          ;; EQL-SPECIALIZER-FORM is (EQL 'X), it requires an argument
 577          ;; to be of type (EQL X). It'd be easy to transform one to
 578          ;; the other, but it'd be somewhat messier to do so while
 579          ;; ensuring that the EQL-SPECIALIZER-FORM is only EVAL'd
 580          ;; once. (The new code wouldn't be messy, but it'd require a
 581          ;; big transformation of the old code.) So instead we punt.
 582          ;; -- WHN 20000610
 583          '(ignorable))
 584         ((member specializer
 585                  ;; KLUDGE: For some low-level implementation
 586                  ;; classes, perhaps because of some problems related
 587                  ;; to the incomplete integration of PCL into SBCL's
 588                  ;; type system, some specializer classes can't be
 589                  ;; declared as argument types. E.g.
 590                  ;;   (DEFMETHOD FOO ((X SLOT-OBJECT))
 591                  ;;     (DECLARE (TYPE SLOT-OBJECT X))
 592                  ;;     ..)
 593                  ;; loses when
 594                  ;;   (DEFSTRUCT BAR A B)
 595                  ;;   (FOO (MAKE-BAR))
 596                  ;; perhaps because of the way that STRUCTURE-OBJECT
 597                  ;; inherits both from SLOT-OBJECT and from
 598                  ;; SB-KERNEL:INSTANCE. In an effort to sweep such
 599                  ;; problems under the rug, we exclude these problem
 600                  ;; cases by blacklisting them here. -- WHN 2001-01-19
 601                  '(slot-object))
 602          '(ignorable))
 603         ((not (eq *boot-state* 'complete))
 604          ;; KLUDGE: PCL, in its wisdom, sometimes calls methods with
 605          ;; types which don't match their specializers. (Specifically,
 606          ;; it calls ENSURE-CLASS-USING-CLASS (T NULL) with a non-NULL
 607          ;; second argument.) Hopefully it only does this kind of
 608          ;; weirdness when bootstrapping.. -- WHN 20000610
 609          '(ignorable))
 610         (t
 611          ;; Otherwise, we can usually make Python very happy.
 612          (let ((type (info :type :kind specializer)))
 613            (ecase type
 614              ((:primitive :defined :instance :forthcoming-defclass-type)
 615               `(type ,specializer ,parameter))
 616              ((nil)
 617               (let ((class (find-class specializer nil)))
 618                 (if class
 619                     `(type ,(class-name class) ,parameter)
 620                     (progn
 621                       ;; we can get here, and still not have a failure
 622                       ;; case, by doing MOP programming like (PROGN
 623                       ;; (ENSURE-CLASS 'FOO) (DEFMETHOD BAR ((X FOO))
 624                       ;; ...)).  Best to let the user know we haven't
 625                       ;; been able to extract enough information:
 626                       (style-warn
 627                        "~@<can't find type for presumed class ~S in ~S.~@:>"
 628                        specializer
 629                        'parameter-specializer-declaration-in-defmethod)
 630                       '(ignorable))))))))))
 631
 632 (defun make-method-lambda-internal (method-lambda &optional env)
 633   (unless (and (consp method-lambda) (eq (car method-lambda) 'lambda))
 634     (error "The METHOD-LAMBDA argument to MAKE-METHOD-LAMBDA, ~S, ~
 635             is not a lambda form."
 636            method-lambda))
 637   (multiple-value-bind (real-body declarations documentation)
 638       (parse-body (cddr method-lambda) env)
 639     (let* ((name-decl (get-declaration '%method-name declarations))
 640            (sll-decl (get-declaration '%method-lambda-list declarations))
 641            (method-name (when (consp name-decl) (car name-decl)))
 642            (generic-function-name (when method-name (car method-name)))
 643            (specialized-lambda-list (or sll-decl (cadr method-lambda))))
 644       (multiple-value-bind (parameters lambda-list specializers)
 645           (parse-specialized-lambda-list specialized-lambda-list)
 646         (let* ((required-parameters
 647                 (mapcar (lambda (r s) (declare (ignore s)) r)
 648                         parameters
 649                         specializers))
 650                (slots (mapcar #'list required-parameters))
 651                (calls (list nil))
 652                (class-declarations
 653                 `(declare
 654                   ;; These declarations seem to be used by PCL to pass
 655                   ;; information to itself; when I tried to delete 'em
 656                   ;; ca. 0.6.10 it didn't work. I'm not sure how
 657                   ;; they work, but note the (VAR-DECLARATION '%CLASS ..)
 658                   ;; expression in CAN-OPTIMIZE-ACCESS1. -- WHN 2000-12-30
 659                   ,@(remove nil
 660                             (mapcar (lambda (a s) (and (symbolp s)
 661                                                        (neq s t)
 662                                                        `(%class ,a ,s)))
 663                                     parameters
 664                                     specializers))
 665                   ;; These TYPE declarations weren't in the original
 666                   ;; PCL code, but the Python compiler likes them a
 667                   ;; lot. (We're telling the compiler about our
 668                   ;; knowledge of specialized argument types so that
 669                   ;; it can avoid run-time type dispatch overhead,
 670                   ;; which can be a huge win for Python.)
 671                   ;;
 672                   ;; FIXME: Perhaps these belong in
 673                   ;; ADD-METHOD-DECLARATIONS instead of here?
 674                   ,@(mapcar #'parameter-specializer-declaration-in-defmethod
 675                             parameters
 676                             specializers)))
 677                (method-lambda
 678                 ;; Remove the documentation string and insert the
 679                 ;; appropriate class declarations. The documentation
 680                 ;; string is removed to make it easy for us to insert
 681                 ;; new declarations later, they will just go after the
 682                 ;; CADR of the method lambda. The class declarations
 683                 ;; are inserted to communicate the class of the method's
 684                 ;; arguments to the code walk.
 685                 `(lambda ,lambda-list
 686                    ;; The default ignorability of method parameters
 687                    ;; doesn't seem to be specified by ANSI. PCL had
 688                    ;; them basically ignorable but was a little
 689                    ;; inconsistent. E.g. even though the two
 690                    ;; method definitions
 691                    ;;   (DEFMETHOD FOO ((X T) (Y T)) "Z")
 692                    ;;   (DEFMETHOD FOO ((X T) Y) "Z")
 693                    ;; are otherwise equivalent, PCL treated Y as
 694                    ;; ignorable in the first definition but not in the
 695                    ;; second definition. We make all required
 696                    ;; parameters ignorable as a way of systematizing
 697                    ;; the old PCL behavior. -- WHN 2000-11-24
 698                    (declare (ignorable ,@required-parameters))
 699                    ,class-declarations
 700                    ,@declarations
 701                    (block ,(fun-name-block-name generic-function-name)
 702                      ,@real-body)))
 703                (constant-value-p (and (null (cdr real-body))
 704                                       (constantp (car real-body))))
 705                (constant-value (and constant-value-p
 706                                     (eval (car real-body))))
 707                (plist (and constant-value-p
 708                            (or (typep constant-value
 709                                       '(or number character))
 710                                (and (symbolp constant-value)
 711                                     (symbol-package constant-value)))
 712                            (list :constant-value constant-value)))
 713                (applyp (dolist (p lambda-list nil)
 714                          (cond ((memq p '(&optional &rest &key))
 715                                 (return t))
 716                                ((eq p '&aux)
 717                                 (return nil))))))
 718           (multiple-value-bind
 719               (walked-lambda call-next-method-p closurep next-method-p-p)
 720               (walk-method-lambda method-lambda
 721                                   required-parameters
 722                                   env
 723                                   slots
 724                                   calls)
 725             (multiple-value-bind (walked-lambda-body
 726                                   walked-declarations
 727                                   walked-documentation)
 728                 (parse-body (cddr walked-lambda) env)
 729               (declare (ignore walked-documentation))
 730               (when (or next-method-p-p call-next-method-p)
 731                 (setq plist (list* :needs-next-methods-p t plist)))
 732               (when (some #'cdr slots)
 733                 (multiple-value-bind (slot-name-lists call-list)
 734                     (slot-name-lists-from-slots slots calls)
 735                   (let ((pv-table-symbol (make-symbol "pv-table")))
 736                     (setq plist
 737                           `(,@(when slot-name-lists
 738                                 `(:slot-name-lists ,slot-name-lists))
 739                               ,@(when call-list
 740                                   `(:call-list ,call-list))
 741                               :pv-table-symbol ,pv-table-symbol
 742                               ,@plist))
 743                     (setq walked-lambda-body
 744                           `((pv-binding (,required-parameters
 745                                          ,slot-name-lists
 746                                          ,pv-table-symbol)
 747                                         ,@walked-lambda-body))))))
 748               (when (and (memq '&key lambda-list)
 749                          (not (memq '&allow-other-keys lambda-list)))
 750                 (let ((aux (memq '&aux lambda-list)))
 751                 (setq lambda-list (nconc (ldiff lambda-list aux)
 752                                          (list '&allow-other-keys)
 753                                          aux))))
 754               (values `(lambda (.method-args. .next-methods.)
 755                          (simple-lexical-method-functions
 756                           (,lambda-list .method-args. .next-methods.
 757                                         :call-next-method-p
 758                                         ,call-next-method-p
 759                                         :next-method-p-p ,next-method-p-p
 760                                         ;; we need to pass this along
 761                                         ;; so that NO-NEXT-METHOD can
 762                                         ;; be given a suitable METHOD
 763                                         ;; argument; we need the
 764                                         ;; QUALIFIERS and SPECIALIZERS
 765                                         ;; inside the declaration to
 766                                         ;; give to FIND-METHOD.
 767                                         :method-name-declaration ,name-decl
 768                                         :closurep ,closurep
 769                                         :applyp ,applyp)
 770                           ,@walked-declarations
 771                           ,@walked-lambda-body))
 772                       `(,@(when plist
 773                       `(:plist ,plist))
 774                           ,@(when documentation
 775                           `(:documentation ,documentation)))))))))))
 776
 777 (unless (fboundp 'make-method-lambda)
 778   (setf (gdefinition 'make-method-lambda)
 779         (symbol-function 'real-make-method-lambda)))
 780
 781 (defmacro simple-lexical-method-functions ((lambda-list
 782                                             method-args
 783                                             next-methods
 784                                             &rest lmf-options)
 785                                            &body body)
 786   `(progn
 787      ,method-args ,next-methods
 788      (bind-simple-lexical-method-macros (,method-args ,next-methods)
 789        (bind-lexical-method-functions (,@lmf-options)
 790          (bind-args (,lambda-list ,method-args)
 791            ,@body)))))
 792
 793 (defmacro fast-lexical-method-functions ((lambda-list
 794                                           next-method-call
 795                                           args
 796                                           rest-arg
 797                                           &rest lmf-options)
 798                                          &body body)
 799   `(bind-fast-lexical-method-macros (,args ,rest-arg ,next-method-call)
 800      (bind-lexical-method-functions (,@lmf-options)
 801        (bind-args (,(nthcdr (length args) lambda-list) ,rest-arg)
 802          ,@body))))
 803
 804 (defmacro bind-simple-lexical-method-macros ((method-args next-methods)
 805                                              &body body)
 806   `(macrolet ((call-next-method-bind (&body body)
 807                `(let ((.next-method. (car ,',next-methods))
 808                       (,',next-methods (cdr ,',next-methods)))
 809                  .next-method. ,',next-methods
 810                  ,@body))
 811               (call-next-method-body (method-name-declaration cnm-args)
 812                `(if .next-method.
 813                     (funcall (if (std-instance-p .next-method.)
 814                                  (method-function .next-method.)
 815                              .next-method.) ; for early methods
 816                              (or ,cnm-args ,',method-args)
 817                              ,',next-methods)
 818                     (apply #'call-no-next-method ',method-name-declaration
 819                             (or ,cnm-args ,',method-args))))
 820               (next-method-p-body ()
 821                `(not (null .next-method.)))
 822               (with-rebound-original-args ((call-next-method-p) &body body)
 823                 (declare (ignore call-next-method-p))
 824                 `(let () ,@body)))
 825     ,@body))
 826
 827 (defun call-no-next-method (method-name-declaration &rest args)
 828   (destructuring-bind (name) method-name-declaration
 829     (destructuring-bind (name &rest qualifiers-and-specializers) name
 830       ;; KLUDGE: inefficient traversal, but hey.  This should only
 831       ;; happen on the slow error path anyway.
 832       (let* ((qualifiers (butlast qualifiers-and-specializers))
 833              (specializers (car (last qualifiers-and-specializers)))
 834              (method (find-method (gdefinition name) qualifiers specializers)))
 835         (apply #'no-next-method
 836                (method-generic-function method)
 837                method
 838                args)))))
 839
 840 (defstruct (method-call (:copier nil))
 841   (function #'identity :type function)
 842   call-method-args)
 843
 844 #-sb-fluid (declaim (sb-ext:freeze-type method-call))
 845
 846 (defmacro invoke-method-call1 (function args cm-args)
 847   `(let ((.function. ,function)
 848          (.args. ,args)
 849          (.cm-args. ,cm-args))
 850      (if (and .cm-args. (null (cdr .cm-args.)))
 851          (funcall .function. .args. (car .cm-args.))
 852          (apply .function. .args. .cm-args.))))
 853
 854 (defmacro invoke-method-call (method-call restp &rest required-args+rest-arg)
 855   `(invoke-method-call1 (method-call-function ,method-call)
 856                         ,(if restp
 857                              `(list* ,@required-args+rest-arg)
 858                              `(list ,@required-args+rest-arg))
 859                         (method-call-call-method-args ,method-call)))
 860
 861 (defstruct (fast-method-call (:copier nil))
 862   (function #'identity :type function)
 863   pv-cell
 864   next-method-call
 865   arg-info)
 866
 867 #-sb-fluid (declaim (sb-ext:freeze-type fast-method-call))
 868
 869 (defmacro fmc-funcall (fn pv-cell next-method-call &rest args)
 870   `(funcall ,fn ,pv-cell ,next-method-call ,@args))
 871
 872 (defmacro invoke-fast-method-call (method-call &rest required-args+rest-arg)
 873   `(fmc-funcall (fast-method-call-function ,method-call)
 874                 (fast-method-call-pv-cell ,method-call)
 875                 (fast-method-call-next-method-call ,method-call)
 876                 ,@required-args+rest-arg))
 877
 878 (defstruct (fast-instance-boundp (:copier nil))
 879   (index 0 :type fixnum))
 880
 881 #-sb-fluid (declaim (sb-ext:freeze-type fast-instance-boundp))
 882
 883 (eval-when (:compile-toplevel :load-toplevel :execute)
 884   (defvar *allow-emf-call-tracing-p* nil)
 885   (defvar *enable-emf-call-tracing-p* #-sb-show nil #+sb-show t))
 886 \f
 887 ;;;; effective method functions
 888
 889 (defvar *emf-call-trace-size* 200)
 890 (defvar *emf-call-trace* nil)
 891 (defvar *emf-call-trace-index* 0)
 892
 893 ;;; This function was in the CMU CL version of PCL (ca Debian 2.4.8)
 894 ;;; without explanation. It appears to be intended for debugging, so
 895 ;;; it might be useful someday, so I haven't deleted it.
 896 ;;; But it isn't documented and isn't used for anything now, so
 897 ;;; I've conditionalized it out of the base system. -- WHN 19991213
 898 #+sb-show
 899 (defun show-emf-call-trace ()
 900   (when *emf-call-trace*
 901     (let ((j *emf-call-trace-index*)
 902           (*enable-emf-call-tracing-p* nil))
 903       (format t "~&(The oldest entries are printed first)~%")
 904       (dotimes-fixnum (i *emf-call-trace-size*)
 905         (let ((ct (aref *emf-call-trace* j)))
 906           (when ct (print ct)))
 907         (incf j)
 908         (when (= j *emf-call-trace-size*)
 909           (setq j 0))))))
 910
 911 (defun trace-emf-call-internal (emf format args)
 912   (unless *emf-call-trace*
 913     (setq *emf-call-trace* (make-array *emf-call-trace-size*)))
 914   (setf (aref *emf-call-trace* *emf-call-trace-index*)
 915         (list* emf format args))
 916   (incf *emf-call-trace-index*)
 917   (when (= *emf-call-trace-index* *emf-call-trace-size*)
 918     (setq *emf-call-trace-index* 0)))
 919
 920 (defmacro trace-emf-call (emf format args)
 921   (when *allow-emf-call-tracing-p*
 922     `(when *enable-emf-call-tracing-p*
 923        (trace-emf-call-internal ,emf ,format ,args))))
 924
 925 (defmacro invoke-effective-method-function-fast
 926     (emf restp &rest required-args+rest-arg)
 927   `(progn
 928      (trace-emf-call ,emf ,restp (list ,@required-args+rest-arg))
 929      (invoke-fast-method-call ,emf ,@required-args+rest-arg)))
 930
 931 (defmacro invoke-effective-method-function (emf restp
 932                                                 &rest required-args+rest-arg)
 933   (unless (constantp restp)
 934     (error "The RESTP argument is not constant."))
 935   ;; FIXME: The RESTP handling here is confusing and maybe slightly
 936   ;; broken if RESTP evaluates to a non-self-evaluating form. E.g. if
 937   ;;   (INVOKE-EFFECTIVE-METHOD-FUNCTION EMF '(ERROR "gotcha") ...)
 938   ;; then TRACE-EMF-CALL-CALL-INTERNAL might die on a gotcha error.
 939   (setq restp (eval restp))
 940   `(progn
 941      (trace-emf-call ,emf ,restp (list ,@required-args+rest-arg))
 942      (cond ((typep ,emf 'fast-method-call)
 943             (invoke-fast-method-call ,emf ,@required-args+rest-arg))
 944            ;; "What," you may wonder, "do these next two clauses do?"
 945            ;; In that case, you are not a PCL implementor, for they
 946            ;; considered this to be self-documenting.:-| Or CSR, for
 947            ;; that matter, since he can also figure it out by looking
 948            ;; at it without breaking stride. For the rest of us,
 949            ;; though: From what the code is doing with .SLOTS. and
 950            ;; whatnot, evidently it's implementing SLOT-VALUEish and
 951            ;; GET-SLOT-VALUEish things. Then we can reason backwards
 952            ;; and conclude that setting EMF to a FIXNUM is an
 953            ;; optimized way to represent these slot access operations.
 954            ,@(when (and (null restp) (= 1 (length required-args+rest-arg)))
 955                `(((typep ,emf 'fixnum)
 956                   (let* ((.slots. (get-slots-or-nil
 957                                    ,(car required-args+rest-arg)))
 958                          (value (when .slots. (clos-slots-ref .slots. ,emf))))
 959                     (if (eq value +slot-unbound+)
 960                         (slot-unbound-internal ,(car required-args+rest-arg)
 961                                                ,emf)
 962                         value)))))
 963            ,@(when (and (null restp) (= 2 (length required-args+rest-arg)))
 964                `(((typep ,emf 'fixnum)
 965                   (let ((.new-value. ,(car required-args+rest-arg))
 966                         (.slots. (get-slots-or-nil
 967                                   ,(cadr required-args+rest-arg))))
 968                     (when .slots.
 969                       (setf (clos-slots-ref .slots. ,emf) .new-value.))))))
 970            ;; (In cmucl-2.4.8 there was a commented-out third ,@(WHEN
 971            ;; ...) clause here to handle SLOT-BOUNDish stuff. Since
 972            ;; there was no explanation and presumably the code is 10+
 973            ;; years stale, I simply deleted it. -- WHN)
 974            (t
 975             (etypecase ,emf
 976               (method-call
 977                (invoke-method-call ,emf ,restp ,@required-args+rest-arg))
 978               (function
 979                ,(if restp
 980                     `(apply (the function ,emf) ,@required-args+rest-arg)
 981                     `(funcall (the function ,emf)
 982                               ,@required-args+rest-arg))))))))
 983
 984 (defun invoke-emf (emf args)
 985   (trace-emf-call emf t args)
 986   (etypecase emf
 987     (fast-method-call
 988      (let* ((arg-info (fast-method-call-arg-info emf))
 989             (restp (cdr arg-info))
 990             (nreq (car arg-info)))
 991        (if restp
 992            (let* ((rest-args (nthcdr nreq args))
 993                   (req-args (ldiff args rest-args)))
 994              (apply (fast-method-call-function emf)
 995                     (fast-method-call-pv-cell emf)
 996                     (fast-method-call-next-method-call emf)
 997                     (nconc req-args (list rest-args))))
 998            (cond ((null args)
 999                   (if (eql nreq 0)
1000                       (invoke-fast-method-call emf)
1001                       (error "wrong number of args")))
1002                  ((null (cdr args))
1003                   (if (eql nreq 1)
1004                       (invoke-fast-method-call emf (car args))
1005                       (error "wrong number of args")))
1006                  ((null (cddr args))
1007                   (if (eql nreq 2)
1008                       (invoke-fast-method-call emf (car args) (cadr args))
1009                       (error "wrong number of args")))
1010                  (t
1011                   (apply (fast-method-call-function emf)
1012                          (fast-method-call-pv-cell emf)
1013                          (fast-method-call-next-method-call emf)
1014                          args))))))
1015     (method-call
1016      (apply (method-call-function emf)
1017             args
1018             (method-call-call-method-args emf)))
1019     (fixnum
1020      (cond ((null args) (error "1 or 2 args were expected."))
1021            ((null (cdr args))
1022             (let* ((slots (get-slots (car args)))
1023                    (value (clos-slots-ref slots emf)))
1024               (if (eq value +slot-unbound+)
1025                   (slot-unbound-internal (car args) emf)
1026                   value)))
1027            ((null (cddr args))
1028              (setf (clos-slots-ref (get-slots (cadr args)) emf)
1029                    (car args)))
1030            (t (error "1 or 2 args were expected."))))
1031     (fast-instance-boundp
1032      (if (or (null args) (cdr args))
1033          (error "1 arg was expected.")
1034        (let ((slots (get-slots (car args))))
1035          (not (eq (clos-slots-ref slots
1036                                   (fast-instance-boundp-index emf))
1037                   +slot-unbound+)))))
1038     (function
1039      (apply emf args))))
1040 \f
1041 (defmacro bind-fast-lexical-method-macros ((args rest-arg next-method-call)
1042                                            &body body)
1043   (let* ((all-params (append args (when rest-arg (list rest-arg))))
1044          (rebindings (mapcar (lambda (x) (list x x)) all-params)))
1045     `(macrolet ((narrowed-emf (emf)
1046                  ;; INVOKE-EFFECTIVE-METHOD-FUNCTION has code in it to
1047                  ;; dispatch on the possibility that EMF might be of
1048                  ;; type FIXNUM (as an optimized representation of a
1049                  ;; slot accessor). But as far as I (WHN 2002-06-11)
1050                  ;; can tell, it's impossible for such a representation
1051                  ;; to end up as .NEXT-METHOD-CALL. By reassuring
1052                  ;; INVOKE-E-M-F that when called from this context
1053                  ;; it needn't worry about the FIXNUM case, we can
1054                  ;; keep those cases from being compiled, which is
1055                  ;; good both because it saves bytes and because it
1056                  ;; avoids annoying type mismatch compiler warnings.
1057                  ;;
1058                  ;; KLUDGE: In sbcl-0.7.4.29, the compiler's type
1059                  ;; system isn't smart enough about NOT and
1060                  ;; intersection types to benefit from a (NOT FIXNUM)
1061                  ;; declaration here. -- WHN 2002-06-12 (FIXME: maybe
1062                  ;; it is now... -- CSR, 2003-06-07)
1063                  ;;
1064                  ;; FIXME: Might the FUNCTION type be omittable here,
1065                  ;; leaving only METHOD-CALLs? Failing that, could this
1066                  ;; be documented somehow? (It'd be nice if the types
1067                  ;; involved could be understood without solving the
1068                  ;; halting problem.)
1069                  `(the (or function method-call fast-method-call)
1070                    ,emf))
1071                 (call-next-method-bind (&body body)
1072                  `(let () ,@body))
1073                 (call-next-method-body (method-name-declaration cnm-args)
1074                  `(if ,',next-method-call
1075                       ,(locally
1076                         ;; This declaration suppresses a "deleting
1077                         ;; unreachable code" note for the following IF
1078                         ;; when REST-ARG is NIL. It is not nice for
1079                         ;; debugging SBCL itself, but at least it
1080                         ;; keeps us from annoying users.
1081                         (declare (optimize (inhibit-warnings 3)))
1082                         (if (and (null ',rest-arg)
1083                                  (consp cnm-args)
1084                                  (eq (car cnm-args) 'list))
1085                             `(invoke-effective-method-function
1086                               (narrowed-emf ,',next-method-call)
1087                               nil
1088                               ,@(cdr cnm-args))
1089                             (let ((call `(invoke-effective-method-function
1090                                           (narrowed-emf ,',next-method-call)
1091                                           ,',(not (null rest-arg))
1092                                           ,@',args
1093                                           ,@',(when rest-arg `(,rest-arg)))))
1094                               `(if ,cnm-args
1095                                 (bind-args ((,@',args
1096                                              ,@',(when rest-arg
1097                                                        `(&rest ,rest-arg)))
1098                                             ,cnm-args)
1099                                  ,call)
1100                                 ,call))))
1101                       ,(locally
1102                         ;; As above, this declaration suppresses code
1103                         ;; deletion notes.
1104                         (declare (optimize (inhibit-warnings 3)))
1105                         (if (and (null ',rest-arg)
1106                                  (consp cnm-args)
1107                                  (eq (car cnm-args) 'list))
1108                             `(call-no-next-method ',method-name-declaration
1109                               ,@(cdr cnm-args))
1110                             `(call-no-next-method ',method-name-declaration
1111                               ,@',args
1112                               ,@',(when rest-arg
1113                                         `(,rest-arg)))))))
1114                 (next-method-p-body ()
1115                  `(not (null ,',next-method-call)))
1116                 (with-rebound-original-args ((cnm-p) &body body)
1117                   (if cnm-p
1118                       `(let ,',rebindings
1119                         (declare (ignorable ,@',all-params))
1120                         ,@body)
1121                       `(let () ,@body))))
1122       ,@body)))
1123
1124 (defmacro bind-lexical-method-functions
1125     ((&key call-next-method-p next-method-p-p
1126            closurep applyp method-name-declaration)
1127      &body body)
1128   (cond ((and (null call-next-method-p) (null next-method-p-p)
1129               (null closurep) (null applyp))
1130          `(let () ,@body))
1131         (t
1132          `(call-next-method-bind
1133             (flet (,@(and call-next-method-p
1134                           `((call-next-method (&rest cnm-args)
1135                              (call-next-method-body
1136                               ,method-name-declaration
1137                               cnm-args))))
1138                    ,@(and next-method-p-p
1139                           '((next-method-p ()
1140                              (next-method-p-body)))))
1141               (with-rebound-original-args (,call-next-method-p)
1142                 ,@body))))))
1143
1144 (defmacro bind-args ((lambda-list args) &body body)
1145   (let ((args-tail '.args-tail.)
1146         (key '.key.)
1147         (state 'required))
1148     (flet ((process-var (var)
1149              (if (memq var lambda-list-keywords)
1150                  (progn
1151                    (case var
1152                      (&optional       (setq state 'optional))
1153                      (&key            (setq state 'key))
1154                      (&allow-other-keys)
1155                      (&rest           (setq state 'rest))
1156                      (&aux            (setq state 'aux))
1157                      (otherwise
1158                       (error
1159                        "encountered the non-standard lambda list keyword ~S"
1160                        var)))
1161                    nil)
1162                  (case state
1163                    (required `((,var (pop ,args-tail))))
1164                    (optional (cond ((not (consp var))
1165                                     `((,var (when ,args-tail
1166                                               (pop ,args-tail)))))
1167                                    ((null (cddr var))
1168                                     `((,(car var) (if ,args-tail
1169                                                       (pop ,args-tail)
1170                                                       ,(cadr var)))))
1171                                    (t
1172                                     `((,(caddr var) ,args-tail)
1173                                       (,(car var) (if ,args-tail
1174                                                       (pop ,args-tail)
1175                                                       ,(cadr var)))))))
1176                    (rest `((,var ,args-tail)))
1177                    (key (cond ((not (consp var))
1178                                `((,var (car
1179                                         (get-key-arg-tail ,(keywordicate var)
1180                                                           ,args-tail)))))
1181                               ((null (cddr var))
1182                                (multiple-value-bind (keyword variable)
1183                                    (if (consp (car var))
1184                                        (values (caar var)
1185                                                (cadar var))
1186                                        (values (keywordicate (car var))
1187                                                (car var)))
1188                                  `((,key (get-key-arg-tail ',keyword
1189                                                            ,args-tail))
1190                                    (,variable (if ,key
1191                                                   (car ,key)
1192                                                   ,(cadr var))))))
1193                               (t
1194                                (multiple-value-bind (keyword variable)
1195                                    (if (consp (car var))
1196                                        (values (caar var)
1197                                                (cadar var))
1198                                        (values (keywordicate (car var))
1199                                                (car var)))
1200                                  `((,key (get-key-arg-tail ',keyword
1201                                                            ,args-tail))
1202                                    (,(caddr var) ,key)
1203                                    (,variable (if ,key
1204                                                   (car ,key)
1205                                                   ,(cadr var))))))))
1206                    (aux `(,var))))))
1207       (let ((bindings (mapcan #'process-var lambda-list)))
1208         `(let* ((,args-tail ,args)
1209                 ,@bindings
1210                 (.dummy0.
1211                  ,@(when (eq state 'optional)
1212                      `((unless (null ,args-tail)
1213                          (error 'simple-program-error
1214                                 :format-control "surplus arguments: ~S"
1215                                 :format-arguments (list ,args-tail)))))))
1216            (declare (ignorable ,args-tail .dummy0.))
1217            ,@body)))))
1218
1219 (defun get-key-arg-tail (keyword list)
1220   (loop for (key . tail) on list by #'cddr
1221         when (null tail) do
1222           ;; FIXME: Do we want to export this symbol? Or maybe use an
1223           ;; (ERROR 'SIMPLE-PROGRAM-ERROR) form?
1224           (sb-c::%odd-key-args-error)
1225         when (eq key keyword)
1226           return tail))
1227
1228 (defun walk-method-lambda (method-lambda required-parameters env slots calls)
1229   (let ((call-next-method-p nil)   ; flag indicating that CALL-NEXT-METHOD
1230                                    ; should be in the method definition
1231         (closurep nil)             ; flag indicating that #'CALL-NEXT-METHOD
1232                                    ; was seen in the body of a method
1233         (next-method-p-p nil))     ; flag indicating that NEXT-METHOD-P
1234                                    ; should be in the method definition
1235     (flet ((walk-function (form context env)
1236              (cond ((not (eq context :eval)) form)
1237                    ;; FIXME: Jumping to a conclusion from the way it's used
1238                    ;; above, perhaps CONTEXT should be called SITUATION
1239                    ;; (after the term used in the ANSI specification of
1240                    ;; EVAL-WHEN) and given modern ANSI keyword values
1241                    ;; like :LOAD-TOPLEVEL.
1242                    ((not (listp form)) form)
1243                    ((eq (car form) 'call-next-method)
1244                     (setq call-next-method-p t)
1245                     form)
1246                    ((eq (car form) 'next-method-p)
1247                     (setq next-method-p-p t)
1248                     form)
1249                    ((and (eq (car form) 'function)
1250                          (cond ((eq (cadr form) 'call-next-method)
1251                                 (setq call-next-method-p t)
1252                                 (setq closurep t)
1253                                 form)
1254                                ((eq (cadr form) 'next-method-p)
1255                                 (setq next-method-p-p t)
1256                                 (setq closurep t)
1257                                 form)
1258                                (t nil))))
1259                    ((and (memq (car form)
1260                                '(slot-value set-slot-value slot-boundp))
1261                          (constantp (caddr form)))
1262                      (let ((parameter (can-optimize-access form
1263                                                            required-parameters
1264                                                            env)))
1265                       (let ((fun (ecase (car form)
1266                                    (slot-value #'optimize-slot-value)
1267                                    (set-slot-value #'optimize-set-slot-value)
1268                                    (slot-boundp #'optimize-slot-boundp))))
1269                         (funcall fun slots parameter form))))
1270                    ((and (eq (car form) 'apply)
1271                          (consp (cadr form))
1272                          (eq (car (cadr form)) 'function)
1273                          (generic-function-name-p (cadr (cadr form))))
1274                     (optimize-generic-function-call
1275                      form required-parameters env slots calls))
1276                    ((generic-function-name-p (car form))
1277                     (optimize-generic-function-call
1278                      form required-parameters env slots calls))
1279                    (t form))))
1280
1281       (let ((walked-lambda (walk-form method-lambda env #'walk-function)))
1282         (values walked-lambda
1283                 call-next-method-p
1284                 closurep
1285                 next-method-p-p)))))
1286
1287 (defun generic-function-name-p (name)
1288   (and (legal-fun-name-p name)
1289        (gboundp name)
1290        (if (eq *boot-state* 'complete)
1291            (standard-generic-function-p (gdefinition name))
1292            (funcallable-instance-p (gdefinition name)))))
1293 \f
1294 (defvar *method-function-plist* (make-hash-table :test 'eq))
1295 (defvar *mf1* nil)
1296 (defvar *mf1p* nil)
1297 (defvar *mf1cp* nil)
1298 (defvar *mf2* nil)
1299 (defvar *mf2p* nil)
1300 (defvar *mf2cp* nil)
1301
1302 (defun method-function-plist (method-function)
1303   (unless (eq method-function *mf1*)
1304     (rotatef *mf1* *mf2*)
1305     (rotatef *mf1p* *mf2p*)
1306     (rotatef *mf1cp* *mf2cp*))
1307   (unless (or (eq method-function *mf1*) (null *mf1cp*))
1308     (setf (gethash *mf1* *method-function-plist*) *mf1p*))
1309   (unless (eq method-function *mf1*)
1310     (setf *mf1* method-function
1311           *mf1cp* nil
1312           *mf1p* (gethash method-function *method-function-plist*)))
1313   *mf1p*)
1314
1315 (defun (setf method-function-plist)
1316     (val method-function)
1317   (unless (eq method-function *mf1*)
1318     (rotatef *mf1* *mf2*)
1319     (rotatef *mf1cp* *mf2cp*)
1320     (rotatef *mf1p* *mf2p*))
1321   (unless (or (eq method-function *mf1*) (null *mf1cp*))
1322     (setf (gethash *mf1* *method-function-plist*) *mf1p*))
1323   (setf *mf1* method-function
1324         *mf1cp* t
1325         *mf1p* val))
1326
1327 (defun method-function-get (method-function key &optional default)
1328   (getf (method-function-plist method-function) key default))
1329
1330 (defun (setf method-function-get)
1331     (val method-function key)
1332   (setf (getf (method-function-plist method-function) key) val))
1333
1334 (defun method-function-pv-table (method-function)
1335   (method-function-get method-function :pv-table))
1336
1337 (defun method-function-method (method-function)
1338   (method-function-get method-function :method))
1339
1340 (defun method-function-needs-next-methods-p (method-function)
1341   (method-function-get method-function :needs-next-methods-p t))
1342 \f
1343 (defmacro method-function-closure-generator (method-function)
1344   `(method-function-get ,method-function 'closure-generator))
1345
1346 (defun load-defmethod
1347     (class name quals specls ll initargs &optional pv-table-symbol)
1348   (setq initargs (copy-tree initargs))
1349   (let ((method-spec (or (getf initargs :method-spec)
1350                          (make-method-spec name quals specls))))
1351     (setf (getf initargs :method-spec) method-spec)
1352     (load-defmethod-internal class name quals specls
1353                              ll initargs pv-table-symbol)))
1354
1355 (defun load-defmethod-internal
1356     (method-class gf-spec qualifiers specializers lambda-list
1357                   initargs pv-table-symbol)
1358   (when pv-table-symbol
1359     (setf (getf (getf initargs :plist) :pv-table-symbol)
1360           pv-table-symbol))
1361   (when (and (eq *boot-state* 'complete)
1362              (fboundp gf-spec))
1363     (let* ((gf (fdefinition gf-spec))
1364            (method (and (generic-function-p gf)
1365                         (generic-function-methods gf)
1366                         (find-method gf
1367                                      qualifiers
1368                                      (parse-specializers specializers)
1369                                      nil))))
1370       (when method
1371         (style-warn "redefining ~S~{ ~S~} ~S in DEFMETHOD"
1372                     gf-spec qualifiers specializers))))
1373   (let ((method (apply #'add-named-method
1374                        gf-spec qualifiers specializers lambda-list
1375                        :definition-source `((defmethod ,gf-spec
1376                                                 ,@qualifiers
1377                                               ,specializers)
1378                                             ,*load-pathname*)
1379                        initargs)))
1380     (unless (or (eq method-class 'standard-method)
1381                 (eq (find-class method-class nil) (class-of method)))
1382       ;; FIXME: should be STYLE-WARNING?
1383       (format *error-output*
1384               "~&At the time the method with qualifiers ~:S and~%~
1385                specializers ~:S on the generic function ~S~%~
1386                was compiled, the method-class for that generic function was~%~
1387                ~S. But, the method class is now ~S, this~%~
1388                may mean that this method was compiled improperly.~%"
1389               qualifiers specializers gf-spec
1390               method-class (class-name (class-of method))))
1391     method))
1392
1393 (defun make-method-spec (gf-spec qualifiers unparsed-specializers)
1394   `(method ,gf-spec ,@qualifiers ,unparsed-specializers))
1395
1396 (defun initialize-method-function (initargs &optional return-function-p method)
1397   (let* ((mf (getf initargs :function))
1398          (method-spec (getf initargs :method-spec))
1399          (plist (getf initargs :plist))
1400          (pv-table-symbol (getf plist :pv-table-symbol))
1401          (pv-table nil)
1402          (mff (getf initargs :fast-function)))
1403     (flet ((set-mf-property (p v)
1404              (when mf
1405                (setf (method-function-get mf p) v))
1406              (when mff
1407                (setf (method-function-get mff p) v))))
1408       (when method-spec
1409         (when mf
1410           (setq mf (set-fun-name mf method-spec)))
1411         (when mff
1412           (let ((name `(,(or (get (car method-spec) 'fast-sym)
1413                              (setf (get (car method-spec) 'fast-sym)
1414                                    ;; KLUDGE: If we're going to be
1415                                    ;; interning private symbols in our
1416                                    ;; a this way, it would be cleanest
1417                                    ;; to use a separate package
1418                                    ;; %PCL-PRIVATE or something, and
1419                                    ;; failing that, to use a special
1420                                    ;; symbol prefix denoting privateness.
1421                                    ;; -- WHN 19991201
1422                                    (intern (format nil "FAST-~A"
1423                                                    (car method-spec))
1424                                            *pcl-package*)))
1425                          ,@(cdr method-spec))))
1426             (set-fun-name mff name)
1427             (unless mf
1428               (set-mf-property :name name)))))
1429       (when plist
1430         (let ((snl (getf plist :slot-name-lists))
1431               (cl (getf plist :call-list)))
1432           (when (or snl cl)
1433             (setq pv-table (intern-pv-table :slot-name-lists snl
1434                                             :call-list cl))
1435             (when pv-table (set pv-table-symbol pv-table))
1436             (set-mf-property :pv-table pv-table)))
1437         (loop (when (null plist) (return nil))
1438               (set-mf-property (pop plist) (pop plist)))
1439         (when method
1440           (set-mf-property :method method))
1441         (when return-function-p
1442           (or mf (method-function-from-fast-function mff)))))))
1443 \f
1444 (defun analyze-lambda-list (lambda-list)
1445   (flet (;; FIXME: Is this redundant with SB-C::MAKE-KEYWORD-FOR-ARG?
1446          (parse-key-arg (arg)
1447            (if (listp arg)
1448                (if (listp (car arg))
1449                    (caar arg)
1450                    (keywordicate (car arg)))
1451                (keywordicate arg))))
1452     (let ((nrequired 0)
1453           (noptional 0)
1454           (keysp nil)
1455           (restp nil)
1456           (nrest 0)
1457           (allow-other-keys-p nil)
1458           (keywords ())
1459           (keyword-parameters ())
1460           (state 'required))
1461       (dolist (x lambda-list)
1462         (if (memq x lambda-list-keywords)
1463             (case x
1464               (&optional         (setq state 'optional))
1465               (&key              (setq keysp t
1466                                        state 'key))
1467               (&allow-other-keys (setq allow-other-keys-p t))
1468               (&rest             (setq restp t
1469                                        state 'rest))
1470               (&aux           (return t))
1471               (otherwise
1472                 (error "encountered the non-standard lambda list keyword ~S"
1473                        x)))
1474             (ecase state
1475               (required  (incf nrequired))
1476               (optional  (incf noptional))
1477               (key       (push (parse-key-arg x) keywords)
1478                          (push x keyword-parameters))
1479               (rest      (incf nrest)))))
1480       (when (and restp (zerop nrest))
1481         (error "Error in lambda-list:~%~
1482                 After &REST, a DEFGENERIC lambda-list ~
1483                 must be followed by at least one variable."))
1484       (values nrequired noptional keysp restp allow-other-keys-p
1485               (reverse keywords)
1486               (reverse keyword-parameters)))))
1487
1488 (defun keyword-spec-name (x)
1489   (let ((key (if (atom x) x (car x))))
1490     (if (atom key)
1491         (keywordicate key)
1492         (car key))))
1493
1494 (defun ftype-declaration-from-lambda-list (lambda-list name)
1495   (multiple-value-bind (nrequired noptional keysp restp allow-other-keys-p
1496                                   keywords keyword-parameters)
1497       (analyze-lambda-list lambda-list)
1498     (declare (ignore keyword-parameters))
1499     (let* ((old (info :function :type name)) ;FIXME:FDOCUMENTATION instead?
1500            (old-ftype (if (fun-type-p old) old nil))
1501            (old-restp (and old-ftype (fun-type-rest old-ftype)))
1502            (old-keys (and old-ftype
1503                           (mapcar #'key-info-name
1504                                   (fun-type-keywords
1505                                    old-ftype))))
1506            (old-keysp (and old-ftype (fun-type-keyp old-ftype)))
1507            (old-allowp (and old-ftype
1508                             (fun-type-allowp old-ftype)))
1509            (keywords (union old-keys (mapcar #'keyword-spec-name keywords))))
1510       `(function ,(append (make-list nrequired :initial-element t)
1511                           (when (plusp noptional)
1512                             (append '(&optional)
1513                                     (make-list noptional :initial-element t)))
1514                           (when (or restp old-restp)
1515                             '(&rest t))
1516                           (when (or keysp old-keysp)
1517                             (append '(&key)
1518                                     (mapcar (lambda (key)
1519                                               `(,key t))
1520                                             keywords)
1521                                     (when (or allow-other-keys-p old-allowp)
1522                                       '(&allow-other-keys)))))
1523                  *))))
1524
1525 (defun defgeneric-declaration (spec lambda-list)
1526   (when (consp spec)
1527     (setq spec (get-setf-fun-name (cadr spec))))
1528   `(ftype ,(ftype-declaration-from-lambda-list lambda-list spec) ,spec))
1529 \f
1530 ;;;; early generic function support
1531
1532 (defvar *!early-generic-functions* ())
1533
1534 (defun ensure-generic-function (fun-name
1535                                 &rest all-keys
1536                                 &key environment
1537                                 &allow-other-keys)
1538   (declare (ignore environment))
1539   (let ((existing (and (gboundp fun-name)
1540                        (gdefinition fun-name))))
1541     (if (and existing
1542              (eq *boot-state* 'complete)
1543              (null (generic-function-p existing)))
1544         (generic-clobbers-function fun-name)
1545         (apply #'ensure-generic-function-using-class
1546                existing fun-name all-keys))))
1547
1548 (defun generic-clobbers-function (fun-name)
1549   (error 'simple-program-error
1550          :format-control "~S already names an ordinary function or a macro."
1551          :format-arguments (list fun-name)))
1552
1553 (defvar *sgf-wrapper*
1554   (boot-make-wrapper (early-class-size 'standard-generic-function)
1555                      'standard-generic-function))
1556
1557 (defvar *sgf-slots-init*
1558   (mapcar (lambda (canonical-slot)
1559             (if (memq (getf canonical-slot :name) '(arg-info source))
1560                 +slot-unbound+
1561                 (let ((initfunction (getf canonical-slot :initfunction)))
1562                   (if initfunction
1563                       (funcall initfunction)
1564                       +slot-unbound+))))
1565           (early-collect-inheritance 'standard-generic-function)))
1566
1567 (defvar *sgf-method-class-index*
1568   (!bootstrap-slot-index 'standard-generic-function 'method-class))
1569
1570 (defun early-gf-p (x)
1571   (and (fsc-instance-p x)
1572        (eq (clos-slots-ref (get-slots x) *sgf-method-class-index*)
1573            +slot-unbound+)))
1574
1575 (defvar *sgf-methods-index*
1576   (!bootstrap-slot-index 'standard-generic-function 'methods))
1577
1578 (defmacro early-gf-methods (gf)
1579   `(clos-slots-ref (get-slots ,gf) *sgf-methods-index*))
1580
1581 (defvar *sgf-arg-info-index*
1582   (!bootstrap-slot-index 'standard-generic-function 'arg-info))
1583
1584 (defmacro early-gf-arg-info (gf)
1585   `(clos-slots-ref (get-slots ,gf) *sgf-arg-info-index*))
1586
1587 (defvar *sgf-dfun-state-index*
1588   (!bootstrap-slot-index 'standard-generic-function 'dfun-state))
1589
1590 (defstruct (arg-info
1591             (:conc-name nil)
1592             (:constructor make-arg-info ())
1593             (:copier nil))
1594   (arg-info-lambda-list :no-lambda-list)
1595   arg-info-precedence
1596   arg-info-metatypes
1597   arg-info-number-optional
1598   arg-info-key/rest-p
1599   arg-info-keys   ;nil        no &KEY or &REST allowed
1600                   ;(k1 k2 ..) Each method must accept these &KEY arguments.
1601                   ;T          must have &KEY or &REST
1602
1603   gf-info-simple-accessor-type ; nil, reader, writer, boundp
1604   (gf-precompute-dfun-and-emf-p nil) ; set by set-arg-info
1605
1606   gf-info-static-c-a-m-emf
1607   (gf-info-c-a-m-emf-std-p t)
1608   gf-info-fast-mf-p)
1609
1610 #-sb-fluid (declaim (sb-ext:freeze-type arg-info))
1611
1612 (defun arg-info-valid-p (arg-info)
1613   (not (null (arg-info-number-optional arg-info))))
1614
1615 (defun arg-info-applyp (arg-info)
1616   (or (plusp (arg-info-number-optional arg-info))
1617       (arg-info-key/rest-p arg-info)))
1618
1619 (defun arg-info-number-required (arg-info)
1620   (length (arg-info-metatypes arg-info)))
1621
1622 (defun arg-info-nkeys (arg-info)
1623   (count-if (lambda (x) (neq x t)) (arg-info-metatypes arg-info)))
1624
1625 ;;; Keep pages clean by not setting if the value is already the same.
1626 (defmacro esetf (pos val)
1627   (with-unique-names (valsym)
1628     `(let ((,valsym ,val))
1629        (unless (equal ,pos ,valsym)
1630          (setf ,pos ,valsym)))))
1631
1632 (defun set-arg-info (gf &key new-method (lambda-list nil lambda-list-p)
1633                         argument-precedence-order)
1634   (let* ((arg-info (if (eq *boot-state* 'complete)
1635                        (gf-arg-info gf)
1636                        (early-gf-arg-info gf)))
1637          (methods (if (eq *boot-state* 'complete)
1638                       (generic-function-methods gf)
1639                       (early-gf-methods gf)))
1640          (was-valid-p (integerp (arg-info-number-optional arg-info)))
1641          (first-p (and new-method (null (cdr methods)))))
1642     (when (and (not lambda-list-p) methods)
1643       (setq lambda-list (gf-lambda-list gf)))
1644     (when (or lambda-list-p
1645               (and first-p
1646                    (eq (arg-info-lambda-list arg-info) :no-lambda-list)))
1647       (multiple-value-bind (nreq nopt keysp restp allow-other-keys-p keywords)
1648           (analyze-lambda-list lambda-list)
1649         (when (and methods (not first-p))
1650           (let ((gf-nreq (arg-info-number-required arg-info))
1651                 (gf-nopt (arg-info-number-optional arg-info))
1652                 (gf-key/rest-p (arg-info-key/rest-p arg-info)))
1653             (unless (and (= nreq gf-nreq)
1654                          (= nopt gf-nopt)
1655                          (eq (or keysp restp) gf-key/rest-p))
1656               (error "The lambda-list ~S is incompatible with ~
1657                      existing methods of ~S."
1658                      lambda-list gf))))
1659         (when lambda-list-p
1660           (esetf (arg-info-lambda-list arg-info) lambda-list))
1661         (when (or lambda-list-p argument-precedence-order
1662                   (null (arg-info-precedence arg-info)))
1663           (esetf (arg-info-precedence arg-info)
1664                  (compute-precedence lambda-list nreq
1665                                      argument-precedence-order)))
1666         (esetf (arg-info-metatypes arg-info) (make-list nreq))
1667         (esetf (arg-info-number-optional arg-info) nopt)
1668         (esetf (arg-info-key/rest-p arg-info) (not (null (or keysp restp))))
1669         (esetf (arg-info-keys arg-info)
1670                (if lambda-list-p
1671                    (if allow-other-keys-p t keywords)
1672                    (arg-info-key/rest-p arg-info)))))
1673     (when new-method
1674       (check-method-arg-info gf arg-info new-method))
1675     (set-arg-info1 gf arg-info new-method methods was-valid-p first-p)
1676     arg-info))
1677
1678 (defun check-method-arg-info (gf arg-info method)
1679   (multiple-value-bind (nreq nopt keysp restp allow-other-keys-p keywords)
1680       (analyze-lambda-list (if (consp method)
1681                                (early-method-lambda-list method)
1682                                (method-lambda-list method)))
1683     (flet ((lose (string &rest args)
1684              (error 'simple-program-error
1685                     :format-control "~@<attempt to add the method~2I~_~S~I~_~
1686                                      to the generic function~2I~_~S;~I~_~
1687                                      but ~?~:>"
1688                     :format-arguments (list method gf string args)))
1689            (comparison-description (x y)
1690              (if (> x y) "more" "fewer")))
1691       (let ((gf-nreq (arg-info-number-required arg-info))
1692             (gf-nopt (arg-info-number-optional arg-info))
1693             (gf-key/rest-p (arg-info-key/rest-p arg-info))
1694             (gf-keywords (arg-info-keys arg-info)))
1695         (unless (= nreq gf-nreq)
1696           (lose
1697            "the method has ~A required arguments than the generic function."
1698            (comparison-description nreq gf-nreq)))
1699         (unless (= nopt gf-nopt)
1700           (lose
1701            "the method has ~A optional arguments than the generic function."
1702            (comparison-description nopt gf-nopt)))
1703         (unless (eq (or keysp restp) gf-key/rest-p)
1704           (lose
1705            "the method and generic function differ in whether they accept~_~
1706             &REST or &KEY arguments."))
1707         (when (consp gf-keywords)
1708           (unless (or (and restp (not keysp))
1709                       allow-other-keys-p
1710                       (every (lambda (k) (memq k keywords)) gf-keywords))
1711             (lose "the method does not accept each of the &KEY arguments~2I~_~
1712                    ~S."
1713                   gf-keywords)))))))
1714
1715 (defun set-arg-info1 (gf arg-info new-method methods was-valid-p first-p)
1716   (let* ((existing-p (and methods (cdr methods) new-method))
1717          (nreq (length (arg-info-metatypes arg-info)))
1718          (metatypes (if existing-p
1719                         (arg-info-metatypes arg-info)
1720                         (make-list nreq)))
1721          (type (if existing-p
1722                    (gf-info-simple-accessor-type arg-info)
1723                    nil)))
1724     (when (arg-info-valid-p arg-info)
1725       (dolist (method (if new-method (list new-method) methods))
1726         (let* ((specializers (if (or (eq *boot-state* 'complete)
1727                                      (not (consp method)))
1728                                  (method-specializers method)
1729                                  (early-method-specializers method t)))
1730                (class (if (or (eq *boot-state* 'complete) (not (consp method)))
1731                           (class-of method)
1732                           (early-method-class method)))
1733                (new-type (when (and class
1734                                     (or (not (eq *boot-state* 'complete))
1735                                         (eq (generic-function-method-combination gf)
1736                                             *standard-method-combination*)))
1737                            (cond ((eq class *the-class-standard-reader-method*)
1738                                   'reader)
1739                                  ((eq class *the-class-standard-writer-method*)
1740                                   'writer)
1741                                  ((eq class *the-class-standard-boundp-method*)
1742                                   'boundp)))))
1743           (setq metatypes (mapcar #'raise-metatype metatypes specializers))
1744           (setq type (cond ((null type) new-type)
1745                            ((eq type new-type) type)
1746                            (t nil)))))
1747       (esetf (arg-info-metatypes arg-info) metatypes)
1748       (esetf (gf-info-simple-accessor-type arg-info) type)))
1749   (when (or (not was-valid-p) first-p)
1750     (multiple-value-bind (c-a-m-emf std-p)
1751         (if (early-gf-p gf)
1752             (values t t)
1753             (compute-applicable-methods-emf gf))
1754       (esetf (gf-info-static-c-a-m-emf arg-info) c-a-m-emf)
1755       (esetf (gf-info-c-a-m-emf-std-p arg-info) std-p)
1756       (unless (gf-info-c-a-m-emf-std-p arg-info)
1757         (esetf (gf-info-simple-accessor-type arg-info) t))))
1758   (unless was-valid-p
1759     (let ((name (if (eq *boot-state* 'complete)
1760                     (generic-function-name gf)
1761                     (!early-gf-name gf))))
1762       (esetf (gf-precompute-dfun-and-emf-p arg-info)
1763              (cond
1764                ((and (consp name)
1765                      (member (car name)
1766                              *internal-pcl-generalized-fun-name-symbols*))
1767                 nil)
1768                (t (let* ((symbol (fun-name-block-name name))
1769                          (package (symbol-package symbol)))
1770                     (and (or (eq package *pcl-package*)
1771                              (memq package (package-use-list *pcl-package*)))
1772                          ;; FIXME: this test will eventually be
1773                          ;; superseded by the *internal-pcl...* test,
1774                          ;; above.  While we are in a process of
1775                          ;; transition, however, it should probably
1776                          ;; remain.
1777                          (not (find #\Space (symbol-name symbol))))))))))
1778   (esetf (gf-info-fast-mf-p arg-info)
1779          (or (not (eq *boot-state* 'complete))
1780              (let* ((method-class (generic-function-method-class gf))
1781                     (methods (compute-applicable-methods
1782                               #'make-method-lambda
1783                               (list gf (class-prototype method-class)
1784                                     '(lambda) nil))))
1785                (and methods (null (cdr methods))
1786                     (let ((specls (method-specializers (car methods))))
1787                       (and (classp (car specls))
1788                            (eq 'standard-generic-function
1789                                (class-name (car specls)))
1790                            (classp (cadr specls))
1791                            (eq 'standard-method
1792                                (class-name (cadr specls)))))))))
1793   arg-info)
1794
1795 ;;; This is the early definition of ENSURE-GENERIC-FUNCTION-USING-CLASS.
1796 ;;;
1797 ;;; The STATIC-SLOTS field of the funcallable instances used as early
1798 ;;; generic functions is used to store the early methods and early
1799 ;;; discriminator code for the early generic function. The static
1800 ;;; slots field of the fins contains a list whose:
1801 ;;;    CAR    -   a list of the early methods on this early gf
1802 ;;;    CADR   -   the early discriminator code for this method
1803 (defun ensure-generic-function-using-class (existing spec &rest keys
1804                                             &key (lambda-list nil
1805                                                               lambda-list-p)
1806                                             argument-precedence-order
1807                                             &allow-other-keys)
1808   (declare (ignore keys))
1809   (cond ((and existing (early-gf-p existing))
1810          existing)
1811         ((assoc spec *!generic-function-fixups* :test #'equal)
1812          (if existing
1813              (make-early-gf spec lambda-list lambda-list-p existing
1814                             argument-precedence-order)
1815              (error "The function ~S is not already defined." spec)))
1816         (existing
1817          (error "~S should be on the list ~S."
1818                 spec
1819                 '*!generic-function-fixups*))
1820         (t
1821          (pushnew spec *!early-generic-functions* :test #'equal)
1822          (make-early-gf spec lambda-list lambda-list-p nil
1823                         argument-precedence-order))))
1824
1825 (defun make-early-gf (spec &optional lambda-list lambda-list-p
1826                       function argument-precedence-order)
1827   (let ((fin (allocate-funcallable-instance *sgf-wrapper* *sgf-slots-init*)))
1828     (set-funcallable-instance-function
1829      fin
1830      (or function
1831          (if (eq spec 'print-object)
1832              #'(instance-lambda (instance stream)
1833                  (print-unreadable-object (instance stream :identity t)
1834                    (format stream "std-instance")))
1835              #'(instance-lambda (&rest args)
1836                  (declare (ignore args))
1837                  (error "The function of the funcallable-instance ~S~
1838                          has not been set." fin)))))
1839     (setf (gdefinition spec) fin)
1840     (!bootstrap-set-slot 'standard-generic-function fin 'name spec)
1841     (!bootstrap-set-slot 'standard-generic-function
1842                          fin
1843                          'source
1844                          *load-pathname*)
1845     (set-fun-name fin spec)
1846     (let ((arg-info (make-arg-info)))
1847       (setf (early-gf-arg-info fin) arg-info)
1848       (when lambda-list-p
1849         (proclaim (defgeneric-declaration spec lambda-list))
1850         (if argument-precedence-order
1851             (set-arg-info fin
1852                           :lambda-list lambda-list
1853                           :argument-precedence-order argument-precedence-order)
1854             (set-arg-info fin :lambda-list lambda-list))))
1855     fin))
1856
1857 (defun set-dfun (gf &optional dfun cache info)
1858   (when cache
1859     (setf (cache-owner cache) gf))
1860   (let ((new-state (if (and dfun (or cache info))
1861                        (list* dfun cache info)
1862                        dfun)))
1863     (if (eq *boot-state* 'complete)
1864         (setf (gf-dfun-state gf) new-state)
1865         (setf (clos-slots-ref (get-slots gf) *sgf-dfun-state-index*)
1866               new-state)))
1867   dfun)
1868
1869 (defun gf-dfun-cache (gf)
1870   (let ((state (if (eq *boot-state* 'complete)
1871                    (gf-dfun-state gf)
1872                    (clos-slots-ref (get-slots gf) *sgf-dfun-state-index*))))
1873     (typecase state
1874       (function nil)
1875       (cons (cadr state)))))
1876
1877 (defun gf-dfun-info (gf)
1878   (let ((state (if (eq *boot-state* 'complete)
1879                    (gf-dfun-state gf)
1880                    (clos-slots-ref (get-slots gf) *sgf-dfun-state-index*))))
1881     (typecase state
1882       (function nil)
1883       (cons (cddr state)))))
1884
1885 (defvar *sgf-name-index*
1886   (!bootstrap-slot-index 'standard-generic-function 'name))
1887
1888 (defun !early-gf-name (gf)
1889   (clos-slots-ref (get-slots gf) *sgf-name-index*))
1890
1891 (defun gf-lambda-list (gf)
1892   (let ((arg-info (if (eq *boot-state* 'complete)
1893                       (gf-arg-info gf)
1894                       (early-gf-arg-info gf))))
1895     (if (eq :no-lambda-list (arg-info-lambda-list arg-info))
1896         (let ((methods (if (eq *boot-state* 'complete)
1897                            (generic-function-methods gf)
1898                            (early-gf-methods gf))))
1899           (if (null methods)
1900               (progn
1901                 (warn "no way to determine the lambda list for ~S" gf)
1902                 nil)
1903               (let* ((method (car (last methods)))
1904                      (ll (if (consp method)
1905                              (early-method-lambda-list method)
1906                              (method-lambda-list method)))
1907                      (k (member '&key ll)))
1908                 (if k
1909                     (append (ldiff ll (cdr k)) '(&allow-other-keys))
1910                     ll))))
1911         (arg-info-lambda-list arg-info))))
1912
1913 (defmacro real-ensure-gf-internal (gf-class all-keys env)
1914   `(progn
1915      (cond ((symbolp ,gf-class)
1916             (setq ,gf-class (find-class ,gf-class t ,env)))
1917            ((classp ,gf-class))
1918            (t
1919             (error "The :GENERIC-FUNCTION-CLASS argument (~S) was neither a~%~
1920                     class nor a symbol that names a class."
1921                    ,gf-class)))
1922      (remf ,all-keys :generic-function-class)
1923      (remf ,all-keys :environment)
1924      (let ((combin (getf ,all-keys :method-combination '.shes-not-there.)))
1925        (unless (eq combin '.shes-not-there.)
1926          (setf (getf ,all-keys :method-combination)
1927                (find-method-combination (class-prototype ,gf-class)
1928                                         (car combin)
1929                                         (cdr combin)))))
1930     (let ((method-class (getf ,all-keys :method-class '.shes-not-there.)))
1931       (unless (eq method-class '.shes-not-there.)
1932         (setf (getf ,all-keys :method-class)
1933                 (find-class method-class t ,env))))))
1934
1935 (defun real-ensure-gf-using-class--generic-function
1936        (existing
1937         fun-name
1938         &rest all-keys
1939         &key environment (lambda-list nil lambda-list-p)
1940              (generic-function-class 'standard-generic-function gf-class-p)
1941         &allow-other-keys)
1942   (real-ensure-gf-internal generic-function-class all-keys environment)
1943   (unless (or (null gf-class-p)
1944               (eq (class-of existing) generic-function-class))
1945     (change-class existing generic-function-class))
1946   (prog1
1947       (apply #'reinitialize-instance existing all-keys)
1948     (when lambda-list-p
1949       (proclaim (defgeneric-declaration fun-name lambda-list)))))
1950
1951 (defun real-ensure-gf-using-class--null
1952        (existing
1953         fun-name
1954         &rest all-keys
1955         &key environment (lambda-list nil lambda-list-p)
1956              (generic-function-class 'standard-generic-function)
1957         &allow-other-keys)
1958   (declare (ignore existing))
1959   (real-ensure-gf-internal generic-function-class all-keys environment)
1960   (prog1
1961       (setf (gdefinition fun-name)
1962             (apply #'make-instance generic-function-class
1963                    :name fun-name all-keys))
1964     (when lambda-list-p
1965       (proclaim (defgeneric-declaration fun-name lambda-list)))))
1966 \f
1967 (defun get-generic-fun-info (gf)
1968   ;; values   nreq applyp metatypes nkeys arg-info
1969   (multiple-value-bind (applyp metatypes arg-info)
1970       (let* ((arg-info (if (early-gf-p gf)
1971                            (early-gf-arg-info gf)
1972                            (gf-arg-info gf)))
1973              (metatypes (arg-info-metatypes arg-info)))
1974         (values (arg-info-applyp arg-info)
1975                 metatypes
1976                 arg-info))
1977     (values (length metatypes) applyp metatypes
1978             (count-if (lambda (x) (neq x t)) metatypes)
1979             arg-info)))
1980
1981 (defun early-make-a-method (class qualifiers arglist specializers initargs doc
1982                             &optional slot-name)
1983   (initialize-method-function initargs)
1984   (let ((parsed ())
1985         (unparsed ()))
1986     ;; Figure out whether we got class objects or class names as the
1987     ;; specializers and set parsed and unparsed appropriately. If we
1988     ;; got class objects, then we can compute unparsed, but if we got
1989     ;; class names we don't try to compute parsed.
1990     ;;
1991     ;; Note that the use of not symbolp in this call to every should be
1992     ;; read as 'classp' we can't use classp itself because it doesn't
1993     ;; exist yet.
1994     (if (every (lambda (s) (not (symbolp s))) specializers)
1995         (setq parsed specializers
1996               unparsed (mapcar (lambda (s)
1997                                  (if (eq s t) t (class-name s)))
1998                                specializers))
1999         (setq unparsed specializers
2000               parsed ()))
2001     (list :early-method           ;This is an early method dammit!
2002
2003           (getf initargs :function)
2004           (getf initargs :fast-function)
2005
2006           parsed                  ;The parsed specializers. This is used
2007                                   ;by early-method-specializers to cache
2008                                   ;the parse. Note that this only comes
2009                                   ;into play when there is more than one
2010                                   ;early method on an early gf.
2011
2012           (list class        ;A list to which real-make-a-method
2013                 qualifiers      ;can be applied to make a real method
2014                 arglist    ;corresponding to this early one.
2015                 unparsed
2016                 initargs
2017                 doc
2018                 slot-name))))
2019
2020 (defun real-make-a-method
2021        (class qualifiers lambda-list specializers initargs doc
2022         &optional slot-name)
2023   (setq specializers (parse-specializers specializers))
2024   (apply #'make-instance class
2025          :qualifiers qualifiers
2026          :lambda-list lambda-list
2027          :specializers specializers
2028          :documentation doc
2029          :slot-name slot-name
2030          :allow-other-keys t
2031          initargs))
2032
2033 (defun early-method-function (early-method)
2034   (values (cadr early-method) (caddr early-method)))
2035
2036 (defun early-method-class (early-method)
2037   (find-class (car (fifth early-method))))
2038
2039 (defun early-method-standard-accessor-p (early-method)
2040   (let ((class (first (fifth early-method))))
2041     (or (eq class 'standard-reader-method)
2042         (eq class 'standard-writer-method)
2043         (eq class 'standard-boundp-method))))
2044
2045 (defun early-method-standard-accessor-slot-name (early-method)
2046   (seventh (fifth early-method)))
2047
2048 ;;; Fetch the specializers of an early method. This is basically just
2049 ;;; a simple accessor except that when the second argument is t, this
2050 ;;; converts the specializers from symbols into class objects. The
2051 ;;; class objects are cached in the early method, this makes
2052 ;;; bootstrapping faster because the class objects only have to be
2053 ;;; computed once.
2054 ;;;
2055 ;;; NOTE:
2056 ;;;  The second argument should only be passed as T by
2057 ;;;  early-lookup-method. This is to implement the rule that only when
2058 ;;;  there is more than one early method on a generic function is the
2059 ;;;  conversion from class names to class objects done. This
2060 ;;;  corresponds to the fact that we are only allowed to have one
2061 ;;;  method on any generic function up until the time classes exist.
2062 (defun early-method-specializers (early-method &optional objectsp)
2063   (if (and (listp early-method)
2064            (eq (car early-method) :early-method))
2065       (cond ((eq objectsp t)
2066              (or (fourth early-method)
2067                  (setf (fourth early-method)
2068                        (mapcar #'find-class (cadddr (fifth early-method))))))
2069             (t
2070              (cadddr (fifth early-method))))
2071       (error "~S is not an early-method." early-method)))
2072
2073 (defun early-method-qualifiers (early-method)
2074   (cadr (fifth early-method)))
2075
2076 (defun early-method-lambda-list (early-method)
2077   (caddr (fifth early-method)))
2078
2079 (defun early-add-named-method (generic-function-name
2080                                qualifiers
2081                                specializers
2082                                arglist
2083                                &rest initargs)
2084   (let* ((gf (ensure-generic-function generic-function-name))
2085          (existing
2086            (dolist (m (early-gf-methods gf))
2087              (when (and (equal (early-method-specializers m) specializers)
2088                         (equal (early-method-qualifiers m) qualifiers))
2089                (return m))))
2090          (new (make-a-method 'standard-method
2091                              qualifiers
2092                              arglist
2093                              specializers
2094                              initargs
2095                              ())))
2096     (when existing (remove-method gf existing))
2097     (add-method gf new)))
2098
2099 ;;; This is the early version of ADD-METHOD. Later this will become a
2100 ;;; generic function. See !FIX-EARLY-GENERIC-FUNCTIONS which has
2101 ;;; special knowledge about ADD-METHOD.
2102 (defun add-method (generic-function method)
2103   (when (not (fsc-instance-p generic-function))
2104     (error "Early ADD-METHOD didn't get a funcallable instance."))
2105   (when (not (and (listp method) (eq (car method) :early-method)))
2106     (error "Early ADD-METHOD didn't get an early method."))
2107   (push method (early-gf-methods generic-function))
2108   (set-arg-info generic-function :new-method method)
2109   (unless (assoc (!early-gf-name generic-function)
2110                  *!generic-function-fixups*
2111                  :test #'equal)
2112     (update-dfun generic-function)))
2113
2114 ;;; This is the early version of REMOVE-METHOD. See comments on
2115 ;;; the early version of ADD-METHOD.
2116 (defun remove-method (generic-function method)
2117   (when (not (fsc-instance-p generic-function))
2118     (error "An early remove-method didn't get a funcallable instance."))
2119   (when (not (and (listp method) (eq (car method) :early-method)))
2120     (error "An early remove-method didn't get an early method."))
2121   (setf (early-gf-methods generic-function)
2122         (remove method (early-gf-methods generic-function)))
2123   (set-arg-info generic-function)
2124   (unless (assoc (!early-gf-name generic-function)
2125                  *!generic-function-fixups*
2126                  :test #'equal)
2127     (update-dfun generic-function)))
2128
2129 ;;; This is the early version of GET-METHOD. See comments on the early
2130 ;;; version of ADD-METHOD.
2131 (defun get-method (generic-function qualifiers specializers
2132                                     &optional (errorp t))
2133   (if (early-gf-p generic-function)
2134       (or (dolist (m (early-gf-methods generic-function))
2135             (when (and (or (equal (early-method-specializers m nil)
2136                                   specializers)
2137                            (equal (early-method-specializers m t)
2138                                   specializers))
2139                        (equal (early-method-qualifiers m) qualifiers))
2140               (return m)))
2141           (if errorp
2142               (error "can't get early method")
2143               nil))
2144       (real-get-method generic-function qualifiers specializers errorp)))
2145
2146 (defun !fix-early-generic-functions ()
2147   (let ((accessors nil))
2148     ;; Rearrange *!EARLY-GENERIC-FUNCTIONS* to speed up
2149     ;; FIX-EARLY-GENERIC-FUNCTIONS.
2150     (dolist (early-gf-spec *!early-generic-functions*)
2151       (when (every #'early-method-standard-accessor-p
2152                    (early-gf-methods (gdefinition early-gf-spec)))
2153         (push early-gf-spec accessors)))
2154     (dolist (spec (nconc accessors
2155                          '(accessor-method-slot-name
2156                            generic-function-methods
2157                            method-specializers
2158                            specializerp
2159                            specializer-type
2160                            specializer-class
2161                            slot-definition-location
2162                            slot-definition-name
2163                            class-slots
2164                            gf-arg-info
2165                            class-precedence-list
2166                            slot-boundp-using-class
2167                            (setf slot-value-using-class)
2168                            slot-value-using-class
2169                            structure-class-p
2170                            standard-class-p
2171                            funcallable-standard-class-p
2172                            specializerp)))
2173       (/show spec)
2174       (setq *!early-generic-functions*
2175             (cons spec
2176                   (delete spec *!early-generic-functions* :test #'equal))))
2177
2178     (dolist (early-gf-spec *!early-generic-functions*)
2179       (/show early-gf-spec)
2180       (let* ((gf (gdefinition early-gf-spec))
2181              (methods (mapcar (lambda (early-method)
2182                                 (let ((args (copy-list (fifth
2183                                                         early-method))))
2184                                   (setf (fourth args)
2185                                         (early-method-specializers
2186                                          early-method t))
2187                                   (apply #'real-make-a-method args)))
2188                               (early-gf-methods gf))))
2189         (setf (generic-function-method-class gf) *the-class-standard-method*)
2190         (setf (generic-function-method-combination gf)
2191               *standard-method-combination*)
2192         (set-methods gf methods)))
2193
2194     (dolist (fn *!early-functions*)
2195       (/show fn)
2196       (setf (gdefinition (car fn)) (fdefinition (caddr fn))))
2197
2198     (dolist (fixup *!generic-function-fixups*)
2199       (/show fixup)
2200       (let* ((fspec (car fixup))
2201              (gf (gdefinition fspec))
2202              (methods (mapcar (lambda (method)
2203                                 (let* ((lambda-list (first method))
2204                                        (specializers (second method))
2205                                        (method-fn-name (third method))
2206                                        (fn-name (or method-fn-name fspec))
2207                                        (fn (fdefinition fn-name))
2208                                        (initargs
2209                                         (list :function
2210                                               (set-fun-name
2211                                                (lambda (args next-methods)
2212                                                  (declare (ignore
2213                                                            next-methods))
2214                                                  (apply fn args))
2215                                                `(call ,fn-name)))))
2216                                   (declare (type function fn))
2217                                   (make-a-method 'standard-method
2218                                                  ()
2219                                                  lambda-list
2220                                                  specializers
2221                                                  initargs
2222                                                  nil)))
2223                               (cdr fixup))))
2224         (setf (generic-function-method-class gf) *the-class-standard-method*)
2225         (setf (generic-function-method-combination gf)
2226               *standard-method-combination*)
2227         (set-methods gf methods))))
2228   (/show "leaving !FIX-EARLY-GENERIC-FUNCTIONS"))
2229 \f
2230 ;;; PARSE-DEFMETHOD is used by DEFMETHOD to parse the &REST argument
2231 ;;; into the 'real' arguments. This is where the syntax of DEFMETHOD
2232 ;;; is really implemented.
2233 (defun parse-defmethod (cdr-of-form)
2234   (declare (list cdr-of-form))
2235   (let ((name (pop cdr-of-form))
2236         (qualifiers ())
2237         (spec-ll ()))
2238     (loop (if (and (car cdr-of-form) (atom (car cdr-of-form)))
2239               (push (pop cdr-of-form) qualifiers)
2240               (return (setq qualifiers (nreverse qualifiers)))))
2241     (setq spec-ll (pop cdr-of-form))
2242     (values name qualifiers spec-ll cdr-of-form)))
2243
2244 (defun parse-specializers (specializers)
2245   (declare (list specializers))
2246   (flet ((parse (spec)
2247            (let ((result (specializer-from-type spec)))
2248              (if (specializerp result)
2249                  result
2250                  (if (symbolp spec)
2251                      (error "~S was used as a specializer,~%~
2252                              but is not the name of a class."
2253                             spec)
2254                      (error "~S is not a legal specializer." spec))))))
2255     (mapcar #'parse specializers)))
2256
2257 (defun unparse-specializers (specializers-or-method)
2258   (if (listp specializers-or-method)
2259       (flet ((unparse (spec)
2260                (if (specializerp spec)
2261                    (let ((type (specializer-type spec)))
2262                      (if (and (consp type)
2263                               (eq (car type) 'class))
2264                          (let* ((class (cadr type))
2265                                 (class-name (class-name class)))
2266                            (if (eq class (find-class class-name nil))
2267                                class-name
2268                                type))
2269                          type))
2270                    (error "~S is not a legal specializer." spec))))
2271         (mapcar #'unparse specializers-or-method))
2272       (unparse-specializers (method-specializers specializers-or-method))))
2273
2274 (defun parse-method-or-spec (spec &optional (errorp t))
2275   (let (gf method name temp)
2276     (if (method-p spec)
2277         (setq method spec
2278               gf (method-generic-function method)
2279               temp (and gf (generic-function-name gf))
2280               name (if temp
2281                        (intern-fun-name
2282                          (make-method-spec temp
2283                                            (method-qualifiers method)
2284                                            (unparse-specializers
2285                                              (method-specializers method))))
2286                        (make-symbol (format nil "~S" method))))
2287         (multiple-value-bind (gf-spec quals specls)
2288             (parse-defmethod spec)
2289           (and (setq gf (and (or errorp (gboundp gf-spec))
2290                              (gdefinition gf-spec)))
2291                (let ((nreq (compute-discriminating-function-arglist-info gf)))
2292                  (setq specls (append (parse-specializers specls)
2293                                       (make-list (- nreq (length specls))
2294                                                  :initial-element
2295                                                  *the-class-t*)))
2296                  (and
2297                    (setq method (get-method gf quals specls errorp))
2298                    (setq name
2299                          (intern-fun-name (make-method-spec gf-spec
2300                                                             quals
2301                                                             specls))))))))
2302     (values gf method name)))
2303 \f
2304 (defun extract-parameters (specialized-lambda-list)
2305   (multiple-value-bind (parameters ignore1 ignore2)
2306       (parse-specialized-lambda-list specialized-lambda-list)
2307     (declare (ignore ignore1 ignore2))
2308     parameters))
2309
2310 (defun extract-lambda-list (specialized-lambda-list)
2311   (multiple-value-bind (ignore1 lambda-list ignore2)
2312       (parse-specialized-lambda-list specialized-lambda-list)
2313     (declare (ignore ignore1 ignore2))
2314     lambda-list))
2315
2316 (defun extract-specializer-names (specialized-lambda-list)
2317   (multiple-value-bind (ignore1 ignore2 specializers)
2318       (parse-specialized-lambda-list specialized-lambda-list)
2319     (declare (ignore ignore1 ignore2))
2320     specializers))
2321
2322 (defun extract-required-parameters (specialized-lambda-list)
2323   (multiple-value-bind (ignore1 ignore2 ignore3 required-parameters)
2324       (parse-specialized-lambda-list specialized-lambda-list)
2325     (declare (ignore ignore1 ignore2 ignore3))
2326     required-parameters))
2327
2328 (defun parse-specialized-lambda-list
2329     (arglist
2330      &optional supplied-keywords (allowed-keywords '(&optional &rest &key &aux))
2331      &aux (specialized-lambda-list-keywords
2332            '(&optional &rest &key &allow-other-keys &aux)))
2333   (let ((arg (car arglist)))
2334     (cond ((null arglist) (values nil nil nil nil))
2335           ((eq arg '&aux)
2336            (values nil arglist nil nil))
2337           ((memq arg lambda-list-keywords)
2338            ;; Now, since we try to conform to ANSI, non-standard
2339            ;; lambda-list-keywords should be treated as errors.
2340            (unless (memq arg specialized-lambda-list-keywords)
2341              (error 'simple-program-error
2342                     :format-control "unknown specialized-lambda-list ~
2343                                      keyword ~S~%"
2344                     :format-arguments (list arg)))
2345            ;; no multiple &rest x &rest bla specifying
2346            (when (memq arg supplied-keywords)
2347              (error 'simple-program-error
2348                     :format-control "multiple occurrence of ~
2349                                      specialized-lambda-list keyword ~S~%"
2350                     :format-arguments (list arg)))
2351            ;; And no placing &key in front of &optional, either.
2352            (unless (memq arg allowed-keywords)
2353              (error 'simple-program-error
2354                     :format-control "misplaced specialized-lambda-list ~
2355                                      keyword ~S~%"
2356                     :format-arguments (list arg)))
2357            ;; When we are at a lambda-list keyword, the parameters
2358            ;; don't include the lambda-list keyword; the lambda-list
2359            ;; does include the lambda-list keyword; and no
2360            ;; specializers are allowed to follow the lambda-list
2361            ;; keywords (at least for now).
2362            (multiple-value-bind (parameters lambda-list)
2363                (parse-specialized-lambda-list (cdr arglist)
2364                                               (cons arg supplied-keywords)
2365                                               (if (eq arg '&key)
2366                                                   (cons '&allow-other-keys
2367                                                         (cdr (member arg allowed-keywords)))
2368                                                 (cdr (member arg allowed-keywords))))
2369              (when (and (eq arg '&rest)
2370                         (or (null lambda-list)
2371                             (memq (car lambda-list)
2372                                   specialized-lambda-list-keywords)
2373                             (not (or (null (cadr lambda-list))
2374                                      (memq (cadr lambda-list)
2375                                            specialized-lambda-list-keywords)))))
2376                (error 'simple-program-error
2377                       :format-control
2378                       "in a specialized-lambda-list, excactly one ~
2379                        variable must follow &REST.~%"
2380                       :format-arguments nil))
2381              (values parameters
2382                      (cons arg lambda-list)
2383                      ()
2384                      ())))
2385           (supplied-keywords
2386            ;; After a lambda-list keyword there can be no specializers.
2387            (multiple-value-bind (parameters lambda-list)
2388                (parse-specialized-lambda-list (cdr arglist)
2389                                               supplied-keywords
2390                                               allowed-keywords)
2391              (values (cons (if (listp arg) (car arg) arg) parameters)
2392                      (cons arg lambda-list)
2393                      ()
2394                      ())))
2395           (t
2396            (multiple-value-bind (parameters lambda-list specializers required)
2397                (parse-specialized-lambda-list (cdr arglist))
2398              (values (cons (if (listp arg) (car arg) arg) parameters)
2399                      (cons (if (listp arg) (car arg) arg) lambda-list)
2400                      (cons (if (listp arg) (cadr arg) t) specializers)
2401                      (cons (if (listp arg) (car arg) arg) required)))))))
2402 \f
2403 (setq *boot-state* 'early)
2404 \f
2405 ;;; FIXME: In here there was a #-CMU definition of SYMBOL-MACROLET
2406 ;;; which used %WALKER stuff. That suggests to me that maybe the code
2407 ;;; walker stuff was only used for implementing stuff like that; maybe
2408 ;;; it's not needed any more? Hunt down what it was used for and see.
2409
2410 (defmacro with-slots (slots instance &body body)
2411   (let ((in (gensym)))
2412     `(let ((,in ,instance))
2413        (declare (ignorable ,in))
2414        ,@(let ((instance (if (and (consp instance) (eq (car instance) 'the))
2415                              (third instance)
2416                              instance)))
2417            (and (symbolp instance)
2418                 `((declare (%variable-rebinding ,in ,instance)))))
2419        ,in
2420        (symbol-macrolet ,(mapcar (lambda (slot-entry)
2421                                    (let ((var-name
2422                                           (if (symbolp slot-entry)
2423                                               slot-entry
2424                                               (car slot-entry)))
2425                                          (slot-name
2426                                           (if (symbolp slot-entry)
2427                                               slot-entry
2428                                               (cadr slot-entry))))
2429                                      `(,var-name
2430                                        (slot-value ,in ',slot-name))))
2431                                  slots)
2432                         ,@body))))
2433
2434 (defmacro with-accessors (slots instance &body body)
2435   (let ((in (gensym)))
2436     `(let ((,in ,instance))
2437        (declare (ignorable ,in))
2438        ,@(let ((instance (if (and (consp instance) (eq (car instance) 'the))
2439                              (third instance)
2440                              instance)))
2441            (and (symbolp instance)
2442                 `((declare (%variable-rebinding ,in ,instance)))))
2443        ,in
2444        (symbol-macrolet ,(mapcar (lambda (slot-entry)
2445                                    (let ((var-name (car slot-entry))
2446                                          (accessor-name (cadr slot-entry)))
2447                                      `(,var-name (,accessor-name ,in))))
2448                                  slots)
2449           ,@body))))