src/pcl/boot.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 #|
  27
  28 The CommonLoops evaluator is meta-circular.
  29
  30 Most of the code in PCL is methods on generic functions, including
  31 most of the code that actually implements generic functions and method
  32 lookup.
  33
  34 So, we have a classic bootstrapping problem. The solution to this is
  35 to first get a cheap implementation of generic functions running,
  36 these are called early generic functions. These early generic
  37 functions and the corresponding early methods and early method lookup
  38 are used to get enough of the system running that it is possible to
  39 create real generic functions and methods and implement real method
  40 lookup. At that point (done in the file FIXUP) the function
  41 !FIX-EARLY-GENERIC-FUNCTIONS is called to convert all the early generic
  42 functions to real generic functions.
  43
  44 The cheap generic functions are built using the same
  45 FUNCALLABLE-INSTANCE objects that real generic functions are made out of.
  46 This means that as PCL is being bootstrapped, the cheap generic
  47 function objects which are being created are the same objects which
  48 will later be real generic functions. This is good because:
  49   - we don't cons garbage structure, and
  50   - we can keep pointers to the cheap generic function objects
  51     during booting because those pointers will still point to
  52     the right object after the generic functions are all fixed up.
  53
  54 This file defines the DEFMETHOD macro and the mechanism used to expand
  55 it. This includes the mechanism for processing the body of a method.
  56 DEFMETHOD basically expands into a call to LOAD-DEFMETHOD, which
  57 basically calls ADD-METHOD to add the method to the generic function.
  58 These expansions can be loaded either during bootstrapping or when PCL
  59 is fully up and running.
  60
  61 An important effect of this arrangement is it means we can compile
  62 files with DEFMETHOD forms in them in a completely running PCL, but
  63 then load those files back in during bootstrapping. This makes
  64 development easier. It also means there is only one set of code for
  65 processing DEFMETHOD. Bootstrapping works by being sure to have
  66 LOAD-METHOD be careful to call only primitives which work during
  67 bootstrapping.
  68
  69 |#
  70
  71 (declaim (notinline make-a-method
  72                     add-named-method
  73                     ensure-generic-function-using-class
  74                     add-method
  75                     remove-method))
  76
  77 (defvar *!early-functions*
  78         '((make-a-method early-make-a-method
  79                          real-make-a-method)
  80           (add-named-method early-add-named-method
  81                             real-add-named-method)
  82           ))
  83
  84 ;;; For each of the early functions, arrange to have it point to its
  85 ;;; early definition. Do this in a way that makes sure that if we
  86 ;;; redefine one of the early definitions the redefinition will take
  87 ;;; effect. This makes development easier.
  88 (dolist (fns *!early-functions*)
  89   (let ((name (car fns))
  90         (early-name (cadr fns)))
  91     (setf (gdefinition name)
  92             (set-fun-name
  93              (lambda (&rest args)
  94                (apply (fdefinition early-name) args))
  95              name))))
  96
  97 ;;; *!GENERIC-FUNCTION-FIXUPS* is used by !FIX-EARLY-GENERIC-FUNCTIONS
  98 ;;; to convert the few functions in the bootstrap which are supposed
  99 ;;; to be generic functions but can't be early on.
 100 (defvar *!generic-function-fixups*
 101   '((add-method
 102      ((generic-function method)  ;lambda-list
 103       (standard-generic-function method) ;specializers
 104       real-add-method))          ;method-function
 105     (remove-method
 106      ((generic-function method)
 107       (standard-generic-function method)
 108       real-remove-method))
 109     (get-method
 110      ((generic-function qualifiers specializers &optional (errorp t))
 111       (standard-generic-function t t)
 112       real-get-method))
 113     (ensure-generic-function-using-class
 114      ((generic-function fun-name
 115                         &key generic-function-class environment
 116                         &allow-other-keys)
 117       (generic-function t)
 118       real-ensure-gf-using-class--generic-function)
 119      ((generic-function fun-name
 120                         &key generic-function-class environment
 121                         &allow-other-keys)
 122       (null t)
 123       real-ensure-gf-using-class--null))
 124     (make-method-lambda
 125      ((proto-generic-function proto-method lambda-expression environment)
 126       (standard-generic-function standard-method t t)
 127       real-make-method-lambda))
 128     (make-method-initargs-form
 129      ((proto-generic-function proto-method
 130                               lambda-expression
 131                               lambda-list environment)
 132       (standard-generic-function standard-method t t t)
 133       real-make-method-initargs-form))
 134     (compute-effective-method
 135      ((generic-function combin applicable-methods)
 136       (generic-function standard-method-combination t)
 137       standard-compute-effective-method))))
 138 \f
 139 (defmacro defgeneric (fun-name lambda-list &body options)
 140   (declare (type list lambda-list))
 141   (unless (legal-fun-name-p fun-name)
 142     (error 'simple-program-error
 143            :format-control "illegal generic function name ~S"
 144            :format-arguments (list fun-name)))
 145   (check-gf-lambda-list lambda-list)
 146   (let ((initargs ())
 147         (methods ()))
 148     (flet ((duplicate-option (name)
 149              (error 'simple-program-error
 150                     :format-control "The option ~S appears more than once."
 151                     :format-arguments (list name)))
 152            (expand-method-definition (qab) ; QAB = qualifiers, arglist, body
 153              (let* ((arglist-pos (position-if #'listp qab))
 154                     (arglist (elt qab arglist-pos))
 155                     (qualifiers (subseq qab 0 arglist-pos))
 156                     (body (nthcdr (1+ arglist-pos) qab)))
 157                `(push (defmethod ,fun-name ,@qualifiers ,arglist ,@body)
 158                       (generic-function-initial-methods (fdefinition ',fun-name))))))
 159       (macrolet ((initarg (key) `(getf initargs ,key)))
 160         (dolist (option options)
 161           (let ((car-option (car option)))
 162             (case car-option
 163               (declare
 164                (when (and
 165                       (consp (cadr option))
 166                       (member (first (cadr option))
 167                               ;; FIXME: this list is slightly weird.
 168                               ;; ANSI (on the DEFGENERIC page) in one
 169                               ;; place allows only OPTIMIZE; in
 170                               ;; another place gives this list of
 171                               ;; disallowed declaration specifiers.
 172                               ;; This seems to be the only place where
 173                               ;; the FUNCTION declaration is
 174                               ;; mentioned; TYPE seems to be missing.
 175                               ;; Very strange.  -- CSR, 2002-10-21
 176                               '(declaration ftype function
 177                                 inline notinline special)))
 178                  (error 'simple-program-error
 179                         :format-control "The declaration specifier ~S ~
 180                                          is not allowed inside DEFGENERIC."
 181                         :format-arguments (list (cadr option))))
 182                (push (cadr option) (initarg :declarations)))
 183               (:method-combination
 184                (when (initarg car-option)
 185                  (duplicate-option car-option))
 186                (unless (symbolp (cadr option))
 187                  (error 'simple-program-error
 188                         :format-control "METHOD-COMBINATION name not a ~
 189                                          symbol: ~S"
 190                         :format-arguments (list (cadr option))))
 191                (setf (initarg car-option)
 192                      `',(cdr option)))
 193               (:argument-precedence-order
 194                (let* ((required (parse-lambda-list lambda-list))
 195                       (supplied (cdr option)))
 196                  (unless (= (length required) (length supplied))
 197                    (error 'simple-program-error
 198                           :format-control "argument count discrepancy in ~
 199                                            :ARGUMENT-PRECEDENCE-ORDER clause."
 200                           :format-arguments nil))
 201                  (when (set-difference required supplied)
 202                    (error 'simple-program-error
 203                           :format-control "unequal sets for ~
 204                                            :ARGUMENT-PRECEDENCE-ORDER clause: ~
 205                                            ~S and ~S"
 206                           :format-arguments (list required supplied)))
 207                  (setf (initarg car-option)
 208                        `',(cdr option))))
 209               ((:documentation :generic-function-class :method-class)
 210                (unless (proper-list-of-length-p option 2)
 211                  (error "bad list length for ~S" option))
 212                (if (initarg car-option)
 213                    (duplicate-option car-option)
 214                    (setf (initarg car-option) `',(cadr option))))
 215               (:method
 216                (push (cdr option) methods))
 217               (t
 218                ;; ANSI requires that unsupported things must get a
 219                ;; PROGRAM-ERROR.
 220                (error 'simple-program-error
 221                       :format-control "unsupported option ~S"
 222                       :format-arguments (list option))))))
 223
 224         (when (initarg :declarations)
 225           (setf (initarg :declarations)
 226                 `',(initarg :declarations))))
 227       `(progn
 228          (eval-when (:compile-toplevel :load-toplevel :execute)
 229            (compile-or-load-defgeneric ',fun-name))
 230          (load-defgeneric ',fun-name ',lambda-list
 231                           (sb-c:source-location) ,@initargs)
 232         ,@(mapcar #'expand-method-definition methods)
 233         (fdefinition ',fun-name)))))
 234
 235 (defun compile-or-load-defgeneric (fun-name)
 236   (proclaim-as-fun-name fun-name)
 237   (note-name-defined fun-name :function)
 238   (unless (eq (info :function :where-from fun-name) :declared)
 239     (setf (info :function :where-from fun-name) :defined)
 240     (setf (info :function :type fun-name)
 241           (specifier-type 'function))))
 242
 243 (defun load-defgeneric (fun-name lambda-list source-location &rest initargs)
 244   (when (fboundp fun-name)
 245     (style-warn "redefining ~S in DEFGENERIC" fun-name)
 246     (let ((fun (fdefinition fun-name)))
 247       (when (generic-function-p fun)
 248         (loop for method in (generic-function-initial-methods fun)
 249               do (remove-method fun method))
 250         (setf (generic-function-initial-methods fun) '()))))
 251   (apply #'ensure-generic-function
 252          fun-name
 253          :lambda-list lambda-list
 254          :definition-source source-location
 255          initargs))
 256
 257 (define-condition generic-function-lambda-list-error
 258     (reference-condition simple-program-error)
 259   ()
 260   (:default-initargs :references (list '(:ansi-cl :section (3 4 2)))))
 261
 262 (defun check-gf-lambda-list (lambda-list)
 263   (flet ((ensure (arg ok)
 264            (unless ok
 265              (error 'generic-function-lambda-list-error
 266                     :format-control
 267                     "~@<invalid ~S ~_in the generic function lambda list ~S~:>"
 268                     :format-arguments (list arg lambda-list)))))
 269     (multiple-value-bind (required optional restp rest keyp keys allowp
 270                           auxp aux morep more-context more-count)
 271         (parse-lambda-list lambda-list)
 272       (declare (ignore required)) ; since they're no different in a gf ll
 273       (declare (ignore restp rest)) ; since they're no different in a gf ll
 274       (declare (ignore allowp)) ; since &ALLOW-OTHER-KEYS is fine either way
 275       (declare (ignore aux)) ; since we require AUXP=NIL
 276       (declare (ignore more-context more-count)) ; safely ignored unless MOREP
 277       ;; no defaults allowed for &OPTIONAL arguments
 278       (dolist (i optional)
 279         (ensure i (or (symbolp i)
 280                       (and (consp i) (symbolp (car i)) (null (cdr i))))))
 281       ;; no defaults allowed for &KEY arguments
 282       (when keyp
 283         (dolist (i keys)
 284           (ensure i (or (symbolp i)
 285                         (and (consp i)
 286                              (or (symbolp (car i))
 287                                  (and (consp (car i))
 288                                       (symbolp (caar i))
 289                                       (symbolp (cadar i))
 290                                       (null (cddar i))))
 291                              (null (cdr i)))))))
 292       ;; no &AUX allowed
 293       (when auxp
 294         (error "&AUX is not allowed in a generic function lambda list: ~S"
 295                lambda-list))
 296       ;; Oh, *puhlease*... not specifically as per section 3.4.2 of
 297       ;; the ANSI spec, but the CMU CL &MORE extension does not
 298       ;; belong here!
 299       (aver (not morep)))))
 300 \f
 301 (defmacro defmethod (&rest args &environment env)
 302   (multiple-value-bind (name qualifiers lambda-list body)
 303       (parse-defmethod args)
 304     (multiple-value-bind (proto-gf proto-method)
 305         (prototypes-for-make-method-lambda name)
 306       (expand-defmethod name
 307                         proto-gf
 308                         proto-method
 309                         qualifiers
 310                         lambda-list
 311                         body
 312                         env))))
 313
 314 (defun prototypes-for-make-method-lambda (name)
 315   (if (not (eq *boot-state* 'complete))
 316       (values nil nil)
 317       (let ((gf? (and (fboundp name)
 318                       (gdefinition name))))
 319         (if (or (null gf?)
 320                 (not (generic-function-p gf?)))
 321             (values (class-prototype (find-class 'standard-generic-function))
 322                     (class-prototype (find-class 'standard-method)))
 323             (values gf?
 324                     (class-prototype (or (generic-function-method-class gf?)
 325                                          (find-class 'standard-method))))))))
 326
 327 ;;; Take a name which is either a generic function name or a list specifying
 328 ;;; a SETF generic function (like: (SETF <generic-function-name>)). Return
 329 ;;; the prototype instance of the method-class for that generic function.
 330 ;;;
 331 ;;; If there is no generic function by that name, this returns the
 332 ;;; default value, the prototype instance of the class
 333 ;;; STANDARD-METHOD. This default value is also returned if the spec
 334 ;;; names an ordinary function or even a macro. In effect, this leaves
 335 ;;; the signalling of the appropriate error until load time.
 336 ;;;
 337 ;;; Note: During bootstrapping, this function is allowed to return NIL.
 338 (defun method-prototype-for-gf (name)
 339   (let ((gf? (and (fboundp name)
 340                   (gdefinition name))))
 341     (cond ((neq *boot-state* 'complete) nil)
 342           ((or (null gf?)
 343                (not (generic-function-p gf?)))          ; Someone else MIGHT
 344                                                         ; error at load time.
 345            (class-prototype (find-class 'standard-method)))
 346           (t
 347             (class-prototype (or (generic-function-method-class gf?)
 348                                  (find-class 'standard-method)))))))
 349 \f
 350 (defun expand-defmethod (name
 351                          proto-gf
 352                          proto-method
 353                          qualifiers
 354                          lambda-list
 355                          body
 356                          env)
 357   (multiple-value-bind (method-lambda unspecialized-lambda-list specializers)
 358       (add-method-declarations name qualifiers lambda-list body env)
 359     (multiple-value-bind (method-function-lambda initargs)
 360         (make-method-lambda proto-gf proto-method method-lambda env)
 361       (let ((initargs-form (make-method-initargs-form proto-gf
 362                                                       proto-method
 363                                                       method-function-lambda
 364                                                       initargs
 365                                                       env)))
 366         `(progn
 367           ;; Note: We could DECLAIM the ftype of the generic function
 368           ;; here, since ANSI specifies that we create it if it does
 369           ;; not exist. However, I chose not to, because I think it's
 370           ;; more useful to support a style of programming where every
 371           ;; generic function has an explicit DEFGENERIC and any typos
 372           ;; in DEFMETHODs are warned about. Otherwise
 373           ;;
 374           ;;   (DEFGENERIC FOO-BAR-BLETCH ((X T)))
 375           ;;   (DEFMETHOD FOO-BAR-BLETCH ((X HASH-TABLE)) ..)
 376           ;;   (DEFMETHOD FOO-BRA-BLETCH ((X SIMPLE-VECTOR)) ..)
 377           ;;   (DEFMETHOD FOO-BAR-BLETCH ((X VECTOR)) ..)
 378           ;;   (DEFMETHOD FOO-BAR-BLETCH ((X ARRAY)) ..)
 379           ;;   (DEFMETHOD FOO-BAR-BLETCH ((X LIST)) ..)
 380           ;;
 381           ;; compiles without raising an error and runs without
 382           ;; raising an error (since SIMPLE-VECTOR cases fall through
 383           ;; to VECTOR) but still doesn't do what was intended. I hate
 384           ;; that kind of bug (code which silently gives the wrong
 385           ;; answer), so we don't do a DECLAIM here. -- WHN 20000229
 386           ,(make-defmethod-form name qualifiers specializers
 387                                 unspecialized-lambda-list
 388                                 (if proto-method
 389                                     (class-name (class-of proto-method))
 390                                     'standard-method)
 391                                 initargs-form))))))
 392
 393 (defun interned-symbol-p (x)
 394   (and (symbolp x) (symbol-package x)))
 395
 396 (defun make-defmethod-form
 397     (name qualifiers specializers unspecialized-lambda-list
 398      method-class-name initargs-form)
 399   (let (fn
 400         fn-lambda)
 401     (if (and (interned-symbol-p (fun-name-block-name name))
 402              (every #'interned-symbol-p qualifiers)
 403              (every (lambda (s)
 404                       (if (consp s)
 405                           (and (eq (car s) 'eql)
 406                                (constantp (cadr s))
 407                                (let ((sv (constant-form-value (cadr s))))
 408                                  (or (interned-symbol-p sv)
 409                                      (integerp sv)
 410                                      (and (characterp sv)
 411                                           (standard-char-p sv)))))
 412                           (interned-symbol-p s)))
 413                     specializers)
 414              (consp initargs-form)
 415              (eq (car initargs-form) 'list*)
 416              (memq (cadr initargs-form) '(:function))
 417              (consp (setq fn (caddr initargs-form)))
 418              (eq (car fn) 'function)
 419              (consp (setq fn-lambda (cadr fn)))
 420              (eq (car fn-lambda) 'lambda))
 421         (let* ((specls (mapcar (lambda (specl)
 422                                  (if (consp specl)
 423                                      `(,(car specl) ,(eval (cadr specl)))
 424                                    specl))
 425                                specializers))
 426                (mname `(,(if (eq (cadr initargs-form) :function)
 427                              'slow-method 'fast-method)
 428                         ,name ,@qualifiers ,specls)))
 429           `(progn
 430              (defun ,mname ,(cadr fn-lambda)
 431                ,@(cddr fn-lambda))
 432              ,(make-defmethod-form-internal
 433                name qualifiers `',specls
 434                unspecialized-lambda-list method-class-name
 435                `(list* ,(cadr initargs-form)
 436                        #',mname
 437                        ,@(cdddr initargs-form)))))
 438         (make-defmethod-form-internal
 439          name qualifiers
 440          `(list ,@(mapcar (lambda (specializer)
 441                             (if (consp specializer)
 442                                 ``(,',(car specializer)
 443                                       ,,(cadr specializer))
 444                                 `',specializer))
 445                           specializers))
 446          unspecialized-lambda-list
 447          method-class-name
 448          initargs-form))))
 449
 450 (defun make-defmethod-form-internal
 451     (name qualifiers specializers-form unspecialized-lambda-list
 452      method-class-name initargs-form)
 453   `(load-defmethod
 454     ',method-class-name
 455     ',name
 456     ',qualifiers
 457     ,specializers-form
 458     ',unspecialized-lambda-list
 459     ,initargs-form
 460     (sb-c:source-location)))
 461
 462 (defmacro make-method-function (method-lambda &environment env)
 463   (make-method-function-internal method-lambda env))
 464
 465 (defun make-method-function-internal (method-lambda &optional env)
 466   (multiple-value-bind (proto-gf proto-method)
 467       (prototypes-for-make-method-lambda nil)
 468     (multiple-value-bind (method-function-lambda initargs)
 469         (make-method-lambda proto-gf proto-method method-lambda env)
 470       (make-method-initargs-form proto-gf
 471                                  proto-method
 472                                  method-function-lambda
 473                                  initargs
 474                                  env))))
 475
 476 (defun add-method-declarations (name qualifiers lambda-list body env)
 477   (declare (ignore env))
 478   (multiple-value-bind (parameters unspecialized-lambda-list specializers)
 479       (parse-specialized-lambda-list lambda-list)
 480     (multiple-value-bind (real-body declarations documentation)
 481         (parse-body body)
 482       (values `(lambda ,unspecialized-lambda-list
 483                  ,@(when documentation `(,documentation))
 484                  ;; (Old PCL code used a somewhat different style of
 485                  ;; list for %METHOD-NAME values. Our names use
 486                  ;; ,@QUALIFIERS instead of ,QUALIFIERS so that the
 487                  ;; method names look more like what you see in a
 488                  ;; DEFMETHOD form.)
 489                  ;;
 490                  ;; FIXME: As of sbcl-0.7.0.6, code elsewhere, at
 491                  ;; least the code to set up named BLOCKs around the
 492                  ;; bodies of methods, depends on the function's base
 493                  ;; name being the first element of the %METHOD-NAME
 494                  ;; list. It would be good to remove this dependency,
 495                  ;; perhaps by building the BLOCK here, or by using
 496                  ;; another declaration (e.g. %BLOCK-NAME), so that
 497                  ;; our method debug names are free to have any format,
 498                  ;; e.g. (:METHOD PRINT-OBJECT :AROUND (CLOWN T)).
 499                  ;;
 500                  ;; Further, as of sbcl-0.7.9.10, the code to
 501                  ;; implement NO-NEXT-METHOD is coupled to the form of
 502                  ;; this declaration; see the definition of
 503                  ;; CALL-NO-NEXT-METHOD (and the passing of
 504                  ;; METHOD-NAME-DECLARATION arguments around the
 505                  ;; various CALL-NEXT-METHOD logic).
 506                  (declare (%method-name (,name
 507                                          ,@qualifiers
 508                                          ,specializers)))
 509                  (declare (%method-lambda-list ,@lambda-list))
 510                  ,@declarations
 511                  ,@real-body)
 512               unspecialized-lambda-list specializers))))
 513
 514 (defun real-make-method-initargs-form (proto-gf proto-method
 515                                        method-lambda initargs env)
 516   (declare (ignore proto-gf proto-method))
 517   (unless (and (consp method-lambda)
 518                (eq (car method-lambda) 'lambda))
 519     (error "The METHOD-LAMBDA argument to MAKE-METHOD-FUNCTION, ~S, ~
 520             is not a lambda form."
 521            method-lambda))
 522   (make-method-initargs-form-internal method-lambda initargs env))
 523
 524 (unless (fboundp 'make-method-initargs-form)
 525   (setf (gdefinition 'make-method-initargs-form)
 526         (symbol-function 'real-make-method-initargs-form)))
 527
 528 (defun real-make-method-lambda (proto-gf proto-method method-lambda env)
 529   (declare (ignore proto-gf proto-method))
 530   (make-method-lambda-internal method-lambda env))
 531
 532 ;;; a helper function for creating Python-friendly type declarations
 533 ;;; in DEFMETHOD forms
 534 (defun parameter-specializer-declaration-in-defmethod (parameter specializer)
 535   (cond ((and (consp specializer)
 536               (eq (car specializer) 'eql))
 537          ;; KLUDGE: ANSI, in its wisdom, says that
 538          ;; EQL-SPECIALIZER-FORMs in EQL specializers are evaluated at
 539          ;; DEFMETHOD expansion time. Thus, although one might think
 540          ;; that in
 541          ;;   (DEFMETHOD FOO ((X PACKAGE)
 542          ;;                   (Y (EQL 12))
 543          ;;      ..))
 544          ;; the PACKAGE and (EQL 12) forms are both parallel type
 545          ;; names, they're not, as is made clear when you do
 546          ;;   (DEFMETHOD FOO ((X PACKAGE)
 547          ;;                   (Y (EQL 'BAR)))
 548          ;;     ..)
 549          ;; where Y needs to be a symbol named "BAR", not some cons
 550          ;; made by (CONS 'QUOTE 'BAR). I.e. when the
 551          ;; EQL-SPECIALIZER-FORM is (EQL 'X), it requires an argument
 552          ;; to be of type (EQL X). It'd be easy to transform one to
 553          ;; the other, but it'd be somewhat messier to do so while
 554          ;; ensuring that the EQL-SPECIALIZER-FORM is only EVAL'd
 555          ;; once. (The new code wouldn't be messy, but it'd require a
 556          ;; big transformation of the old code.) So instead we punt.
 557          ;; -- WHN 20000610
 558          '(ignorable))
 559         ((member specializer
 560                  ;; KLUDGE: For some low-level implementation
 561                  ;; classes, perhaps because of some problems related
 562                  ;; to the incomplete integration of PCL into SBCL's
 563                  ;; type system, some specializer classes can't be
 564                  ;; declared as argument types. E.g.
 565                  ;;   (DEFMETHOD FOO ((X SLOT-OBJECT))
 566                  ;;     (DECLARE (TYPE SLOT-OBJECT X))
 567                  ;;     ..)
 568                  ;; loses when
 569                  ;;   (DEFSTRUCT BAR A B)
 570                  ;;   (FOO (MAKE-BAR))
 571                  ;; perhaps because of the way that STRUCTURE-OBJECT
 572                  ;; inherits both from SLOT-OBJECT and from
 573                  ;; SB-KERNEL:INSTANCE. In an effort to sweep such
 574                  ;; problems under the rug, we exclude these problem
 575                  ;; cases by blacklisting them here. -- WHN 2001-01-19
 576                  (list 'slot-object #+nil (find-class 'slot-object)))
 577          '(ignorable))
 578         ((not (eq *boot-state* 'complete))
 579          ;; KLUDGE: PCL, in its wisdom, sometimes calls methods with
 580          ;; types which don't match their specializers. (Specifically,
 581          ;; it calls ENSURE-CLASS-USING-CLASS (T NULL) with a non-NULL
 582          ;; second argument.) Hopefully it only does this kind of
 583          ;; weirdness when bootstrapping.. -- WHN 20000610
 584          '(ignorable))
 585         ((typep specializer 'eql-specializer)
 586          `(type (eql ,(eql-specializer-object specializer)) ,parameter))
 587         ((var-globally-special-p parameter)
 588          ;; KLUDGE: Don't declare types for global special variables
 589          ;; -- our rebinding magic for SETQ cases don't work right
 590          ;; there.
 591          ;;
 592          ;; FIXME: It would be better to detect the SETQ earlier and
 593          ;; skip declarations for specials only when needed, not
 594          ;; always.
 595          ;;
 596          ;; --NS 2004-10-14
 597          '(ignorable))
 598         (t
 599          ;; Otherwise, we can usually make Python very happy.
 600          ;;
 601          ;; KLUDGE: Since INFO doesn't work right for class objects here,
 602          ;; and they are valid specializers, see if the specializer is
 603          ;; a named class, and use the name in that case -- otherwise
 604          ;; the class instance is ok, since info will just return NIL, NIL.
 605          ;;
 606          ;; We still need to deal with the class case too, but at
 607          ;; least #.(find-class 'integer) and integer as equivalent
 608          ;; specializers with this.
 609          (let* ((specializer (if (and (typep specializer 'class)
 610                                       (let ((name (class-name specializer)))
 611                                         (and name (symbolp name)
 612                                              (eq specializer (find-class name nil)))))
 613                                  (class-name specializer)
 614                                  specializer))
 615                 (kind (info :type :kind specializer)))
 616
 617            (flet ((specializer-class ()
 618                     (if (typep specializer 'class)
 619                         specializer
 620                         (find-class specializer nil))))
 621              (ecase kind
 622                ((:primitive) `(type ,specializer ,parameter))
 623                ((:defined)
 624                 (let ((class (specializer-class)))
 625                   ;; CLASS can be null here if the user has erroneously
 626                  ;; tried to use a defined type as a specializer; it
 627                  ;; can be a non-BUILT-IN-CLASS if the user defines a
 628                  ;; type and calls (SETF FIND-CLASS) in a consistent
 629                  ;; way.
 630                  (when (and class (typep class 'built-in-class))
 631                    `(type ,specializer ,parameter))))
 632               ((:instance nil)
 633                (let ((class (specializer-class)))
 634                  (cond
 635                    (class
 636                     (if (typep class '(or built-in-class structure-class))
 637                         `(type ,specializer ,parameter)
 638                         ;; don't declare CLOS classes as parameters;
 639                         ;; it's too expensive.
 640                         '(ignorable)))
 641                    (t
 642                     ;; we can get here, and still not have a failure
 643                     ;; case, by doing MOP programming like (PROGN
 644                     ;; (ENSURE-CLASS 'FOO) (DEFMETHOD BAR ((X FOO))
 645                     ;; ...)).  Best to let the user know we haven't
 646                     ;; been able to extract enough information:
 647                     (style-warn
 648                      "~@<can't find type for presumed class ~S in ~S.~@:>"
 649                      specializer
 650                      'parameter-specializer-declaration-in-defmethod)
 651                     '(ignorable)))))
 652               ((:forthcoming-defclass-type)
 653                '(ignorable))))))))
 654
 655 ;;; For passing a list (groveled by the walker) of the required
 656 ;;; parameters whose bindings are modified in the method body to the
 657 ;;; optimized-slot-value* macros.
 658 (define-symbol-macro %parameter-binding-modified ())
 659
 660 (defun make-method-lambda-internal (method-lambda &optional env)
 661   (unless (and (consp method-lambda) (eq (car method-lambda) 'lambda))
 662     (error "The METHOD-LAMBDA argument to MAKE-METHOD-LAMBDA, ~S, ~
 663             is not a lambda form."
 664            method-lambda))
 665   (multiple-value-bind (real-body declarations documentation)
 666       (parse-body (cddr method-lambda))
 667     (let* ((name-decl (get-declaration '%method-name declarations))
 668            (sll-decl (get-declaration '%method-lambda-list declarations))
 669            (method-name (when (consp name-decl) (car name-decl)))
 670            (generic-function-name (when method-name (car method-name)))
 671            (specialized-lambda-list (or sll-decl (cadr method-lambda))))
 672       (multiple-value-bind (parameters lambda-list specializers)
 673           (parse-specialized-lambda-list specialized-lambda-list)
 674         (let* ((required-parameters
 675                 (mapcar (lambda (r s) (declare (ignore s)) r)
 676                         parameters
 677                         specializers))
 678                (slots (mapcar #'list required-parameters))
 679                (calls (list nil))
 680                (class-declarations
 681                 `(declare
 682                   ;; These declarations seem to be used by PCL to pass
 683                   ;; information to itself; when I tried to delete 'em
 684                   ;; ca. 0.6.10 it didn't work. I'm not sure how
 685                   ;; they work, but note the (VAR-DECLARATION '%CLASS ..)
 686                   ;; expression in CAN-OPTIMIZE-ACCESS1. -- WHN 2000-12-30
 687                   ,@(remove nil
 688                             (mapcar (lambda (a s) (and (symbolp s)
 689                                                        (neq s t)
 690                                                        `(%class ,a ,s)))
 691                                     parameters
 692                                     specializers))
 693                   ;; These TYPE declarations weren't in the original
 694                   ;; PCL code, but the Python compiler likes them a
 695                   ;; lot. (We're telling the compiler about our
 696                   ;; knowledge of specialized argument types so that
 697                   ;; it can avoid run-time type dispatch overhead,
 698                   ;; which can be a huge win for Python.)
 699                   ;;
 700                   ;; KLUDGE: when I tried moving these to
 701                   ;; ADD-METHOD-DECLARATIONS, things broke.  No idea
 702                   ;; why.  -- CSR, 2004-06-16
 703                   ,@(mapcar #'parameter-specializer-declaration-in-defmethod
 704                             parameters
 705                             specializers)))
 706                (method-lambda
 707                 ;; Remove the documentation string and insert the
 708                 ;; appropriate class declarations. The documentation
 709                 ;; string is removed to make it easy for us to insert
 710                 ;; new declarations later, they will just go after the
 711                 ;; CADR of the method lambda. The class declarations
 712                 ;; are inserted to communicate the class of the method's
 713                 ;; arguments to the code walk.
 714                 `(lambda ,lambda-list
 715                    ;; The default ignorability of method parameters
 716                    ;; doesn't seem to be specified by ANSI. PCL had
 717                    ;; them basically ignorable but was a little
 718                    ;; inconsistent. E.g. even though the two
 719                    ;; method definitions
 720                    ;;   (DEFMETHOD FOO ((X T) (Y T)) "Z")
 721                    ;;   (DEFMETHOD FOO ((X T) Y) "Z")
 722                    ;; are otherwise equivalent, PCL treated Y as
 723                    ;; ignorable in the first definition but not in the
 724                    ;; second definition. We make all required
 725                    ;; parameters ignorable as a way of systematizing
 726                    ;; the old PCL behavior. -- WHN 2000-11-24
 727                    (declare (ignorable ,@required-parameters))
 728                    ,class-declarations
 729                    ,@declarations
 730                    (block ,(fun-name-block-name generic-function-name)
 731                      ,@real-body)))
 732                (constant-value-p (and (null (cdr real-body))
 733                                       (constantp (car real-body))))
 734                (constant-value (and constant-value-p
 735                                     (constant-form-value (car real-body))))
 736                (plist (and constant-value-p
 737                            (or (typep constant-value
 738                                       '(or number character))
 739                                (and (symbolp constant-value)
 740                                     (symbol-package constant-value)))
 741                            (list :constant-value constant-value)))
 742                (applyp (dolist (p lambda-list nil)
 743                          (cond ((memq p '(&optional &rest &key))
 744                                 (return t))
 745                                ((eq p '&aux)
 746                                 (return nil))))))
 747           (multiple-value-bind
 748                 (walked-lambda call-next-method-p closurep
 749                                next-method-p-p setq-p
 750                                parameters-setqd)
 751               (walk-method-lambda method-lambda
 752                                   required-parameters
 753                                   env
 754                                   slots
 755                                   calls)
 756             (multiple-value-bind (walked-lambda-body
 757                                   walked-declarations
 758                                   walked-documentation)
 759                 (parse-body (cddr walked-lambda))
 760               (declare (ignore walked-documentation))
 761               (when (some #'cdr slots)
 762                 (multiple-value-bind (slot-name-lists call-list)
 763                     (slot-name-lists-from-slots slots calls)
 764                   (setq plist
 765                         `(,@(when slot-name-lists
 766                                   `(:slot-name-lists ,slot-name-lists))
 767                             ,@(when call-list
 768                                     `(:call-list ,call-list))
 769                             ,@plist))
 770                   (setq walked-lambda-body
 771                         `((pv-binding (,required-parameters
 772                                        ,slot-name-lists
 773                                        (load-time-value
 774                                         (intern-pv-table
 775                                          :slot-name-lists ',slot-name-lists
 776                                          :call-list ',call-list)))
 777                             ,@walked-lambda-body)))))
 778               (when (and (memq '&key lambda-list)
 779                          (not (memq '&allow-other-keys lambda-list)))
 780                 (let ((aux (memq '&aux lambda-list)))
 781                   (setq lambda-list (nconc (ldiff lambda-list aux)
 782                                            (list '&allow-other-keys)
 783                                            aux))))
 784               (values `(lambda (.method-args. .next-methods.)
 785                          (simple-lexical-method-functions
 786                              (,lambda-list .method-args. .next-methods.
 787                                            :call-next-method-p
 788                                            ,call-next-method-p
 789                                            :next-method-p-p ,next-method-p-p
 790                                            :setq-p ,setq-p
 791                                            ;; we need to pass this along
 792                                            ;; so that NO-NEXT-METHOD can
 793                                            ;; be given a suitable METHOD
 794                                            ;; argument; we need the
 795                                            ;; QUALIFIERS and SPECIALIZERS
 796                                            ;; inside the declaration to
 797                                            ;; give to FIND-METHOD.
 798                                            :method-name-declaration ,name-decl
 799                                            :closurep ,closurep
 800                                            :applyp ,applyp)
 801                            ,@walked-declarations
 802                            (locally
 803                                (declare (disable-package-locks
 804                                          %parameter-binding-modified))
 805                              (symbol-macrolet ((%parameter-binding-modified
 806                                                 ',@parameters-setqd))
 807                                (declare (enable-package-locks
 808                                          %parameter-binding-modified))
 809                                ,@walked-lambda-body))))
 810                       `(,@(when plist
 811                                 `(plist ,plist))
 812                           ,@(when documentation
 813                                   `(:documentation ,documentation)))))))))))
 814
 815 (unless (fboundp 'make-method-lambda)
 816   (setf (gdefinition 'make-method-lambda)
 817         (symbol-function 'real-make-method-lambda)))
 818
 819 (defmacro simple-lexical-method-functions ((lambda-list
 820                                             method-args
 821                                             next-methods
 822                                             &rest lmf-options)
 823                                            &body body)
 824   `(progn
 825      ,method-args ,next-methods
 826      (bind-simple-lexical-method-functions (,method-args ,next-methods
 827                                                          ,lmf-options)
 828          (bind-args (,lambda-list ,method-args)
 829            ,@body))))
 830
 831 (defmacro fast-lexical-method-functions ((lambda-list
 832                                           next-method-call
 833                                           args
 834                                           rest-arg
 835                                           &rest lmf-options)
 836                                          &body body)
 837   `(bind-fast-lexical-method-functions (,args ,rest-arg ,next-method-call ,lmf-options)
 838      (bind-args (,(nthcdr (length args) lambda-list) ,rest-arg)
 839        ,@body)))
 840
 841 (defmacro bind-simple-lexical-method-functions
 842     ((method-args next-methods (&key call-next-method-p next-method-p-p setq-p
 843                                      closurep applyp method-name-declaration))
 844      &body body
 845      &environment env)
 846   (if (not (or call-next-method-p setq-p closurep next-method-p-p applyp))
 847       `(locally
 848            ,@body)
 849       `(let ((.next-method. (car ,next-methods))
 850              (,next-methods (cdr ,next-methods)))
 851          (declare (ignorable .next-method. ,next-methods))
 852          (flet (,@(and call-next-method-p
 853                        `((call-next-method
 854                           (&rest cnm-args)
 855                           ,@(if (safe-code-p env)
 856                                 `((%check-cnm-args cnm-args
 857                                                    ,method-args
 858                                                    ',method-name-declaration))
 859                                 nil)
 860                           (if .next-method.
 861                               (funcall (if (std-instance-p .next-method.)
 862                                            (method-function .next-method.)
 863                                            .next-method.) ; for early methods
 864                                        (or cnm-args ,method-args)
 865                                        ,next-methods)
 866                               (apply #'call-no-next-method
 867                                      ',method-name-declaration
 868                                      (or cnm-args ,method-args))))))
 869                 ,@(and next-method-p-p
 870                        '((next-method-p ()
 871                           (not (null .next-method.))))))
 872            ,@body))))
 873
 874 (defun call-no-next-method (method-name-declaration &rest args)
 875   (destructuring-bind (name) method-name-declaration
 876     (destructuring-bind (name &rest qualifiers-and-specializers) name
 877       ;; KLUDGE: inefficient traversal, but hey.  This should only
 878       ;; happen on the slow error path anyway.
 879       (let* ((qualifiers (butlast qualifiers-and-specializers))
 880              (specializers (car (last qualifiers-and-specializers)))
 881              (method (find-method (gdefinition name) qualifiers specializers)))
 882         (apply #'no-next-method
 883                (method-generic-function method)
 884                method
 885                args)))))
 886
 887 (defstruct (method-call (:copier nil))
 888   (function #'identity :type function)
 889   call-method-args)
 890 (defstruct (constant-method-call (:copier nil) (:include method-call))
 891   value)
 892
 893 #-sb-fluid (declaim (sb-ext:freeze-type method-call))
 894
 895 (defmacro invoke-method-call1 (function args cm-args)
 896   `(let ((.function. ,function)
 897          (.args. ,args)
 898          (.cm-args. ,cm-args))
 899      (if (and .cm-args. (null (cdr .cm-args.)))
 900          (funcall .function. .args. (car .cm-args.))
 901          (apply .function. .args. .cm-args.))))
 902
 903 (defmacro invoke-method-call (method-call restp &rest required-args+rest-arg)
 904   `(invoke-method-call1 (method-call-function ,method-call)
 905                         ,(if restp
 906                              `(list* ,@required-args+rest-arg)
 907                              `(list ,@required-args+rest-arg))
 908                         (method-call-call-method-args ,method-call)))
 909
 910 (defstruct (fast-method-call (:copier nil))
 911   (function #'identity :type function)
 912   pv-cell
 913   next-method-call
 914   arg-info)
 915 (defstruct (constant-fast-method-call
 916              (:copier nil) (:include fast-method-call))
 917   value)
 918
 919 #-sb-fluid (declaim (sb-ext:freeze-type fast-method-call))
 920
 921 (defmacro fmc-funcall (fn pv-cell next-method-call &rest args)
 922   `(funcall ,fn ,pv-cell ,next-method-call ,@args))
 923
 924 (defmacro invoke-fast-method-call (method-call &rest required-args+rest-arg)
 925   `(fmc-funcall (fast-method-call-function ,method-call)
 926                 (fast-method-call-pv-cell ,method-call)
 927                 (fast-method-call-next-method-call ,method-call)
 928                 ,@required-args+rest-arg))
 929
 930 (defstruct (fast-instance-boundp (:copier nil))
 931   (index 0 :type fixnum))
 932
 933 #-sb-fluid (declaim (sb-ext:freeze-type fast-instance-boundp))
 934
 935 (eval-when (:compile-toplevel :load-toplevel :execute)
 936   (defvar *allow-emf-call-tracing-p* nil)
 937   (defvar *enable-emf-call-tracing-p* #-sb-show nil #+sb-show t))
 938 \f
 939 ;;;; effective method functions
 940
 941 (defvar *emf-call-trace-size* 200)
 942 (defvar *emf-call-trace* nil)
 943 (defvar *emf-call-trace-index* 0)
 944
 945 ;;; This function was in the CMU CL version of PCL (ca Debian 2.4.8)
 946 ;;; without explanation. It appears to be intended for debugging, so
 947 ;;; it might be useful someday, so I haven't deleted it.
 948 ;;; But it isn't documented and isn't used for anything now, so
 949 ;;; I've conditionalized it out of the base system. -- WHN 19991213
 950 #+sb-show
 951 (defun show-emf-call-trace ()
 952   (when *emf-call-trace*
 953     (let ((j *emf-call-trace-index*)
 954           (*enable-emf-call-tracing-p* nil))
 955       (format t "~&(The oldest entries are printed first)~%")
 956       (dotimes-fixnum (i *emf-call-trace-size*)
 957         (let ((ct (aref *emf-call-trace* j)))
 958           (when ct (print ct)))
 959         (incf j)
 960         (when (= j *emf-call-trace-size*)
 961           (setq j 0))))))
 962
 963 (defun trace-emf-call-internal (emf format args)
 964   (unless *emf-call-trace*
 965     (setq *emf-call-trace* (make-array *emf-call-trace-size*)))
 966   (setf (aref *emf-call-trace* *emf-call-trace-index*)
 967         (list* emf format args))
 968   (incf *emf-call-trace-index*)
 969   (when (= *emf-call-trace-index* *emf-call-trace-size*)
 970     (setq *emf-call-trace-index* 0)))
 971
 972 (defmacro trace-emf-call (emf format args)
 973   (when *allow-emf-call-tracing-p*
 974     `(when *enable-emf-call-tracing-p*
 975        (trace-emf-call-internal ,emf ,format ,args))))
 976
 977 (defmacro invoke-effective-method-function-fast
 978     (emf restp &rest required-args+rest-arg)
 979   `(progn
 980      (trace-emf-call ,emf ,restp (list ,@required-args+rest-arg))
 981      (invoke-fast-method-call ,emf ,@required-args+rest-arg)))
 982
 983 (defun effective-method-optimized-slot-access-clause
 984     (emf restp required-args+rest-arg)
 985   ;; "What," you may wonder, "do these next two clauses do?" In that
 986   ;; case, you are not a PCL implementor, for they considered this to
 987   ;; be self-documenting.:-| Or CSR, for that matter, since he can
 988   ;; also figure it out by looking at it without breaking stride. For
 989   ;; the rest of us, though: From what the code is doing with .SLOTS.
 990   ;; and whatnot, evidently it's implementing SLOT-VALUEish and
 991   ;; GET-SLOT-VALUEish things. Then we can reason backwards and
 992   ;; conclude that setting EMF to a FIXNUM is an optimized way to
 993   ;; represent these slot access operations.
 994   (when (not restp)
 995     (let ((length (length required-args+rest-arg)))
 996       (cond ((= 1 length)
 997              `((fixnum
 998                 (let* ((.slots. (get-slots-or-nil
 999                                  ,(car required-args+rest-arg)))
1000                        (value (when .slots. (clos-slots-ref .slots. ,emf))))
1001                   (if (eq value +slot-unbound+)
1002                       (slot-unbound-internal ,(car required-args+rest-arg)
1003                                              ,emf)
1004                       value)))))
1005             ((= 2 length)
1006              `((fixnum
1007                 (let ((.new-value. ,(car required-args+rest-arg))
1008                       (.slots. (get-slots-or-nil
1009                                 ,(cadr required-args+rest-arg))))
1010                   (when .slots.
1011                     (setf (clos-slots-ref .slots. ,emf) .new-value.)))))))
1012       ;; (In cmucl-2.4.8 there was a commented-out third ,@(WHEN
1013       ;; ...) clause here to handle SLOT-BOUNDish stuff. Since
1014       ;; there was no explanation and presumably the code is 10+
1015       ;; years stale, I simply deleted it. -- WHN)
1016       )))
1017
1018 ;;; Before SBCL 0.9.16.7 instead of
1019 ;;; INVOKE-NARROW-EFFECTIVE-METHOD-FUNCTION we passed a (THE (OR
1020 ;;; FUNCTION METHOD-CALL FAST-METHOD-CALL) EMF) form as the EMF. Now,
1021 ;;; to make less work for the compiler we take a path that doesn't
1022 ;;; involve the slot-accessor clause (where EMF is a FIXNUM) at all.
1023 (macrolet ((def (name &optional narrow)
1024              `(defmacro ,name (emf restp &rest required-args+rest-arg)
1025                 (unless (constantp restp)
1026                   (error "The RESTP argument is not constant."))
1027                 (setq restp (constant-form-value restp))
1028                 (with-unique-names (emf-n)
1029                   `(locally
1030                        (declare (optimize (sb-c:insert-step-conditions 0)))
1031                      (let ((,emf-n ,emf))
1032                        (trace-emf-call ,emf-n ,restp (list ,@required-args+rest-arg))
1033                        (etypecase ,emf-n
1034                          (fast-method-call
1035                           (invoke-fast-method-call ,emf-n ,@required-args+rest-arg))
1036                          ,@,(unless narrow
1037                               `(effective-method-optimized-slot-access-clause
1038                                 emf-n restp required-args+rest-arg))
1039                          (method-call
1040                           (invoke-method-call ,emf-n ,restp ,@required-args+rest-arg))
1041                          (function
1042                           ,(if restp
1043                                `(apply ,emf-n ,@required-args+rest-arg)
1044                             `(funcall ,emf-n ,@required-args+rest-arg))))))))))
1045   (def invoke-effective-method-function nil)
1046   (def invoke-narrow-effective-method-function t))
1047
1048 (defun invoke-emf (emf args)
1049   (trace-emf-call emf t args)
1050   (etypecase emf
1051     (fast-method-call
1052      (let* ((arg-info (fast-method-call-arg-info emf))
1053             (restp (cdr arg-info))
1054             (nreq (car arg-info)))
1055        (if restp
1056            (let* ((rest-args (nthcdr nreq args))
1057                   (req-args (ldiff args rest-args)))
1058              (apply (fast-method-call-function emf)
1059                     (fast-method-call-pv-cell emf)
1060                     (fast-method-call-next-method-call emf)
1061                     (nconc req-args (list rest-args))))
1062            (cond ((null args)
1063                   (if (eql nreq 0)
1064                       (invoke-fast-method-call emf)
1065                       (error 'simple-program-error
1066                              :format-control "invalid number of arguments: 0"
1067                              :format-arguments nil)))
1068                  ((null (cdr args))
1069                   (if (eql nreq 1)
1070                       (invoke-fast-method-call emf (car args))
1071                       (error 'simple-program-error
1072                              :format-control "invalid number of arguments: 1"
1073                              :format-arguments nil)))
1074                  ((null (cddr args))
1075                   (if (eql nreq 2)
1076                       (invoke-fast-method-call emf (car args) (cadr args))
1077                       (error 'simple-program-error
1078                              :format-control "invalid number of arguments: 2"
1079                              :format-arguments nil)))
1080                  (t
1081                   (apply (fast-method-call-function emf)
1082                          (fast-method-call-pv-cell emf)
1083                          (fast-method-call-next-method-call emf)
1084                          args))))))
1085     (method-call
1086      (apply (method-call-function emf)
1087             args
1088             (method-call-call-method-args emf)))
1089     (fixnum
1090      (cond ((null args)
1091             (error 'simple-program-error
1092                    :format-control "invalid number of arguments: 0"
1093                    :format-arguments nil))
1094            ((null (cdr args))
1095             (let* ((slots (get-slots (car args)))
1096                    (value (clos-slots-ref slots emf)))
1097               (if (eq value +slot-unbound+)
1098                   (slot-unbound-internal (car args) emf)
1099                   value)))
1100            ((null (cddr args))
1101             (setf (clos-slots-ref (get-slots (cadr args)) emf)
1102                   (car args)))
1103            (t (error 'simple-program-error
1104                      :format-control "invalid number of arguments"
1105                      :format-arguments nil))))
1106     (fast-instance-boundp
1107      (if (or (null args) (cdr args))
1108          (error 'simple-program-error
1109                 :format-control "invalid number of arguments"
1110                 :format-arguments nil)
1111          (let ((slots (get-slots (car args))))
1112            (not (eq (clos-slots-ref slots (fast-instance-boundp-index emf))
1113                     +slot-unbound+)))))
1114     (function
1115      (apply emf args))))
1116 \f
1117
1118 (defmacro fast-call-next-method-body ((args next-method-call rest-arg)
1119                                       method-name-declaration
1120                                       cnm-args)
1121   `(if ,next-method-call
1122        ,(let ((call `(invoke-narrow-effective-method-function
1123                       ,next-method-call
1124                       ,(not (null rest-arg))
1125                       ,@args
1126                       ,@(when rest-arg `(,rest-arg)))))
1127              `(if ,cnm-args
1128                   (bind-args ((,@args
1129                                ,@(when rest-arg
1130                                        `(&rest ,rest-arg)))
1131                               ,cnm-args)
1132                     ,call)
1133                   ,call))
1134        (call-no-next-method ',method-name-declaration
1135                             ,@args
1136                             ,@(when rest-arg
1137                                     `(,rest-arg)))))
1138
1139 (defmacro bind-fast-lexical-method-functions
1140     ((args rest-arg next-method-call (&key
1141                                       call-next-method-p
1142                                       setq-p
1143                                       method-name-declaration
1144                                       next-method-p-p
1145                                       closurep
1146                                       applyp))
1147      &body body
1148      &environment env)
1149   (let* ((all-params (append args (when rest-arg (list rest-arg))))
1150          (rebindings (when (or setq-p call-next-method-p)
1151                        (mapcar (lambda (x) (list x x)) all-params))))
1152     (if (not (or call-next-method-p setq-p closurep next-method-p-p applyp))
1153         `(locally
1154              ,@body)
1155         `(flet (,@(when call-next-method-p
1156                         `((call-next-method (&rest cnm-args)
1157                             (declare (muffle-conditions code-deletion-note)
1158                                      (optimize (sb-c:insert-step-conditions 0)))
1159                            ,@(if (safe-code-p env)
1160                                  `((%check-cnm-args cnm-args (list ,@args)
1161                                                     ',method-name-declaration))
1162                                  nil)
1163                            (fast-call-next-method-body (,args
1164                                                         ,next-method-call
1165                                                         ,rest-arg)
1166                                                         ,method-name-declaration
1167                                                        cnm-args))))
1168                 ,@(when next-method-p-p
1169                         `((next-method-p ()
1170                            (declare (optimize (sb-c:insert-step-conditions 0)))
1171                            (not (null ,next-method-call))))))
1172            (let ,rebindings
1173              ,@(when rebindings `((declare (ignorable ,@all-params))))
1174              ,@body)))))
1175
1176 ;;; CMUCL comment (Gerd Moellmann):
1177 ;;;
1178 ;;; The standard says it's an error if CALL-NEXT-METHOD is called with
1179 ;;; arguments, and the set of methods applicable to those arguments is
1180 ;;; different from the set of methods applicable to the original
1181 ;;; method arguments.  (According to Barry Margolin, this rule was
1182 ;;; probably added to ensure that before and around methods are always
1183 ;;; run before primary methods.)
1184 ;;;
1185 ;;; This could be optimized for the case that the generic function
1186 ;;; doesn't have hairy methods, does have standard method combination,
1187 ;;; is a standard generic function, there are no methods defined on it
1188 ;;; for COMPUTE-APPLICABLE-METHODS and probably a lot more of such
1189 ;;; preconditions.  That looks hairy and is probably not worth it,
1190 ;;; because this check will never be fast.
1191 (defun %check-cnm-args (cnm-args orig-args method-name-declaration)
1192   (when cnm-args
1193     (let* ((gf (fdefinition (caar method-name-declaration)))
1194            (omethods (compute-applicable-methods gf orig-args))
1195            (nmethods (compute-applicable-methods gf cnm-args)))
1196       (unless (equal omethods nmethods)
1197         (error "~@<The set of methods ~S applicable to argument~P ~
1198                 ~{~S~^, ~} to call-next-method is different from ~
1199                 the set of methods ~S applicable to the original ~
1200                 method argument~P ~{~S~^, ~}.~@:>"
1201                nmethods (length cnm-args) cnm-args omethods
1202                (length orig-args) orig-args)))))
1203
1204 (defmacro bind-args ((lambda-list args) &body body)
1205   (let ((args-tail '.args-tail.)
1206         (key '.key.)
1207         (state 'required))
1208     (flet ((process-var (var)
1209              (if (memq var lambda-list-keywords)
1210                  (progn
1211                    (case var
1212                      (&optional       (setq state 'optional))
1213                      (&key            (setq state 'key))
1214                      (&allow-other-keys)
1215                      (&rest           (setq state 'rest))
1216                      (&aux            (setq state 'aux))
1217                      (otherwise
1218                       (error
1219                        "encountered the non-standard lambda list keyword ~S"
1220                        var)))
1221                    nil)
1222                  (case state
1223                    (required `((,var (pop ,args-tail))))
1224                    (optional (cond ((not (consp var))
1225                                     `((,var (when ,args-tail
1226                                               (pop ,args-tail)))))
1227                                    ((null (cddr var))
1228                                     `((,(car var) (if ,args-tail
1229                                                       (pop ,args-tail)
1230                                                       ,(cadr var)))))
1231                                    (t
1232                                     `((,(caddr var) ,args-tail)
1233                                       (,(car var) (if ,args-tail
1234                                                       (pop ,args-tail)
1235                                                       ,(cadr var)))))))
1236                    (rest `((,var ,args-tail)))
1237                    (key (cond ((not (consp var))
1238                                `((,var (car
1239                                         (get-key-arg-tail ,(keywordicate var)
1240                                                           ,args-tail)))))
1241                               ((null (cddr var))
1242                                (multiple-value-bind (keyword variable)
1243                                    (if (consp (car var))
1244                                        (values (caar var)
1245                                                (cadar var))
1246                                        (values (keywordicate (car var))
1247                                                (car var)))
1248                                  `((,key (get-key-arg-tail ',keyword
1249                                                            ,args-tail))
1250                                    (,variable (if ,key
1251                                                   (car ,key)
1252                                                   ,(cadr var))))))
1253                               (t
1254                                (multiple-value-bind (keyword variable)
1255                                    (if (consp (car var))
1256                                        (values (caar var)
1257                                                (cadar var))
1258                                        (values (keywordicate (car var))
1259                                                (car var)))
1260                                  `((,key (get-key-arg-tail ',keyword
1261                                                            ,args-tail))
1262                                    (,(caddr var) ,key)
1263                                    (,variable (if ,key
1264                                                   (car ,key)
1265                                                   ,(cadr var))))))))
1266                    (aux `(,var))))))
1267       (let ((bindings (mapcan #'process-var lambda-list)))
1268         `(let* ((,args-tail ,args)
1269                 ,@bindings
1270                 (.dummy0.
1271                  ,@(when (eq state 'optional)
1272                      `((unless (null ,args-tail)
1273                          (error 'simple-program-error
1274                                 :format-control "surplus arguments: ~S"
1275                                 :format-arguments (list ,args-tail)))))))
1276            (declare (ignorable ,args-tail .dummy0.))
1277            ,@body)))))
1278
1279 (defun get-key-arg-tail (keyword list)
1280   (loop for (key . tail) on list by #'cddr
1281         when (null tail) do
1282           ;; FIXME: Do we want to export this symbol? Or maybe use an
1283           ;; (ERROR 'SIMPLE-PROGRAM-ERROR) form?
1284           (sb-c::%odd-key-args-error)
1285         when (eq key keyword)
1286           return tail))
1287
1288 (defun walk-method-lambda (method-lambda required-parameters env slots calls)
1289   (let (;; flag indicating that CALL-NEXT-METHOD should be in the
1290         ;; method definition
1291         (call-next-method-p nil)
1292         ;; flag indicating that #'CALL-NEXT-METHOD was seen in the
1293         ;; body of a method
1294         (closurep nil)
1295         ;; flag indicating that NEXT-METHOD-P should be in the method
1296         ;; definition
1297         (next-method-p-p nil)
1298         ;; a list of all required parameters whose bindings might be
1299         ;; modified in the method body.
1300         (parameters-setqd nil))
1301     (flet ((walk-function (form context env)
1302              (cond ((not (eq context :eval)) form)
1303                    ;; FIXME: Jumping to a conclusion from the way it's used
1304                    ;; above, perhaps CONTEXT should be called SITUATION
1305                    ;; (after the term used in the ANSI specification of
1306                    ;; EVAL-WHEN) and given modern ANSI keyword values
1307                    ;; like :LOAD-TOPLEVEL.
1308                    ((not (listp form)) form)
1309                    ((eq (car form) 'call-next-method)
1310                     (setq call-next-method-p t)
1311                     form)
1312                    ((eq (car form) 'next-method-p)
1313                     (setq next-method-p-p t)
1314                     form)
1315                    ((memq (car form) '(setq multiple-value-setq))
1316                     ;; FIXME: this is possibly a little strong as
1317                     ;; conditions go.  Ideally we would want to detect
1318                     ;; which, if any, of the method parameters are
1319                     ;; being set, and communicate that information to
1320                     ;; e.g. SPLIT-DECLARATIONS.  However, the brute
1321                     ;; force method doesn't really cost much; a little
1322                     ;; loss of discrimination over IGNORED variables
1323                     ;; should be all.  -- CSR, 2004-07-01
1324                     ;;
1325                     ;; As of 2006-09-18 modified parameter bindings
1326                     ;; are now tracked with more granularity than just
1327                     ;; one SETQ-P flag, in order to disable SLOT-VALUE
1328                     ;; optimizations for parameters that are SETQd.
1329                     ;; The old binary SETQ-P flag is still used for
1330                     ;; all other purposes, since as noted above, the
1331                     ;; extra cost is minimal. -- JES, 2006-09-18
1332                     ;;
1333                     ;; The walker will split (SETQ A 1 B 2) to
1334                     ;; separate (SETQ A 1) and (SETQ B 2) forms, so we
1335                     ;; only need to handle the simple case of SETQ
1336                     ;; here.
1337                     (let ((vars (if (eq (car form) 'setq)
1338                                     (list (second form))
1339                                     (second form))))
1340                       (dolist (var vars)
1341                         ;; Note that we don't need to check for
1342                         ;; %VARIABLE-REBINDING declarations like is
1343                         ;; done in CAN-OPTIMIZE-ACCESS1, since the
1344                         ;; bindings that will have that declation will
1345                         ;; never be SETQd.
1346                         (when (var-declaration '%class var env)
1347                           ;; If a parameter binding is shadowed by
1348                           ;; another binding it won't have a %CLASS
1349                           ;; declaration anymore, and this won't get
1350                           ;; executed.
1351                           (pushnew var parameters-setqd))))
1352                     form)
1353                    ((and (eq (car form) 'function)
1354                          (cond ((eq (cadr form) 'call-next-method)
1355                                 (setq call-next-method-p t)
1356                                 (setq closurep t)
1357                                 form)
1358                                ((eq (cadr form) 'next-method-p)
1359                                 (setq next-method-p-p t)
1360                                 (setq closurep t)
1361                                 form)
1362                                (t nil))))
1363                    ((and (memq (car form)
1364                                '(slot-value set-slot-value slot-boundp))
1365                          (constantp (caddr form)))
1366                     (let ((parameter (can-optimize-access form
1367                                                           required-parameters
1368                                                           env)))
1369                       (let ((fun (ecase (car form)
1370                                    (slot-value #'optimize-slot-value)
1371                                    (set-slot-value #'optimize-set-slot-value)
1372                                    (slot-boundp #'optimize-slot-boundp))))
1373                         (funcall fun slots parameter form))))
1374                    (t form))))
1375
1376       (let ((walked-lambda (walk-form method-lambda env #'walk-function)))
1377         (values walked-lambda
1378                 call-next-method-p
1379                 closurep
1380                 next-method-p-p
1381                 (not (null parameters-setqd))
1382                 parameters-setqd)))))
1383
1384 (defun generic-function-name-p (name)
1385   (and (legal-fun-name-p name)
1386        (fboundp name)
1387        (if (eq *boot-state* 'complete)
1388            (standard-generic-function-p (gdefinition name))
1389            (funcallable-instance-p (gdefinition name)))))
1390 \f
1391 (defun method-plist-value (method key &optional default)
1392   (let ((plist (if (consp method)
1393                    (getf (early-method-initargs method) 'plist)
1394                    (object-plist method))))
1395     (getf plist key default)))
1396
1397 (defun (setf method-plist-value) (new-value method key &optional default)
1398   (if (consp method)
1399       (setf (getf (getf (early-method-initargs method) 'plist) key default)
1400             new-value)
1401       (setf (getf (object-plist method) key default) new-value)))
1402 \f
1403 (defun load-defmethod
1404     (class name quals specls ll initargs source-location)
1405   (setq initargs (copy-tree initargs))
1406   (setf (getf (getf initargs 'plist) :name)
1407         (make-method-spec name quals specls))
1408   (load-defmethod-internal class name quals specls
1409                            ll initargs source-location))
1410
1411 (defun load-defmethod-internal
1412     (method-class gf-spec qualifiers specializers lambda-list
1413                   initargs source-location)
1414   (when (and (eq *boot-state* 'complete)
1415              (fboundp gf-spec))
1416     (let* ((gf (fdefinition gf-spec))
1417            (method (and (generic-function-p gf)
1418                         (generic-function-methods gf)
1419                         (find-method gf
1420                                      qualifiers
1421                                      (parse-specializers specializers)
1422                                      nil))))
1423       (when method
1424         (style-warn "redefining ~S~{ ~S~} ~S in DEFMETHOD"
1425                     gf-spec qualifiers specializers))))
1426   (let ((method (apply #'add-named-method
1427                        gf-spec qualifiers specializers lambda-list
1428                        :definition-source source-location
1429                        initargs)))
1430     (unless (or (eq method-class 'standard-method)
1431                 (eq (find-class method-class nil) (class-of method)))
1432       ;; FIXME: should be STYLE-WARNING?
1433       (format *error-output*
1434               "~&At the time the method with qualifiers ~:S and~%~
1435                specializers ~:S on the generic function ~S~%~
1436                was compiled, the method-class for that generic function was~%~
1437                ~S. But, the method class is now ~S, this~%~
1438                may mean that this method was compiled improperly.~%"
1439               qualifiers specializers gf-spec
1440               method-class (class-name (class-of method))))
1441     method))
1442
1443 (defun make-method-spec (gf-spec qualifiers unparsed-specializers)
1444   `(slow-method ,gf-spec ,@qualifiers ,unparsed-specializers))
1445
1446 (defun initialize-method-function (initargs method)
1447   (let* ((mf (getf initargs :function))
1448          (mff (and (typep mf '%method-function)
1449                    (%method-function-fast-function mf)))
1450          (plist (getf initargs 'plist))
1451          (name (getf plist :name)))
1452     (when name
1453       (when mf
1454         (setq mf (set-fun-name mf name)))
1455       (when (and mff (consp name) (eq (car name) 'slow-method))
1456         (let ((fast-name `(fast-method ,@(cdr name))))
1457           (set-fun-name mff fast-name))))
1458     (when plist
1459       (let ((plist plist))
1460         (let ((snl (getf plist :slot-name-lists))
1461               (cl (getf plist :call-list)))
1462           (when (or snl cl)
1463             (setf (method-plist-value method :pv-table)
1464                   (intern-pv-table :slot-name-lists snl :call-list cl))))))))
1465 \f
1466 (defun analyze-lambda-list (lambda-list)
1467   (flet (;; FIXME: Is this redundant with SB-C::MAKE-KEYWORD-FOR-ARG?
1468          (parse-key-arg (arg)
1469            (if (listp arg)
1470                (if (listp (car arg))
1471                    (caar arg)
1472                    (keywordicate (car arg)))
1473                (keywordicate arg))))
1474     (let ((nrequired 0)
1475           (noptional 0)
1476           (keysp nil)
1477           (restp nil)
1478           (nrest 0)
1479           (allow-other-keys-p nil)
1480           (keywords ())
1481           (keyword-parameters ())
1482           (state 'required))
1483       (dolist (x lambda-list)
1484         (if (memq x lambda-list-keywords)
1485             (case x
1486               (&optional         (setq state 'optional))
1487               (&key              (setq keysp t
1488                                        state 'key))
1489               (&allow-other-keys (setq allow-other-keys-p t))
1490               (&rest             (setq restp t
1491                                        state 'rest))
1492               (&aux           (return t))
1493               (otherwise
1494                 (error "encountered the non-standard lambda list keyword ~S"
1495                        x)))
1496             (ecase state
1497               (required  (incf nrequired))
1498               (optional  (incf noptional))
1499               (key       (push (parse-key-arg x) keywords)
1500                          (push x keyword-parameters))
1501               (rest      (incf nrest)))))
1502       (when (and restp (zerop nrest))
1503         (error "Error in lambda-list:~%~
1504                 After &REST, a DEFGENERIC lambda-list ~
1505                 must be followed by at least one variable."))
1506       (values nrequired noptional keysp restp allow-other-keys-p
1507               (reverse keywords)
1508               (reverse keyword-parameters)))))
1509
1510 (defun keyword-spec-name (x)
1511   (let ((key (if (atom x) x (car x))))
1512     (if (atom key)
1513         (keywordicate key)
1514         (car key))))
1515
1516 (defun ftype-declaration-from-lambda-list (lambda-list name)
1517   (multiple-value-bind (nrequired noptional keysp restp allow-other-keys-p
1518                                   keywords keyword-parameters)
1519       (analyze-lambda-list lambda-list)
1520     (declare (ignore keyword-parameters))
1521     (let* ((old (info :function :type name)) ;FIXME:FDOCUMENTATION instead?
1522            (old-ftype (if (fun-type-p old) old nil))
1523            (old-restp (and old-ftype (fun-type-rest old-ftype)))
1524            (old-keys (and old-ftype
1525                           (mapcar #'key-info-name
1526                                   (fun-type-keywords
1527                                    old-ftype))))
1528            (old-keysp (and old-ftype (fun-type-keyp old-ftype)))
1529            (old-allowp (and old-ftype
1530                             (fun-type-allowp old-ftype)))
1531            (keywords (union old-keys (mapcar #'keyword-spec-name keywords))))
1532       `(function ,(append (make-list nrequired :initial-element t)
1533                           (when (plusp noptional)
1534                             (append '(&optional)
1535                                     (make-list noptional :initial-element t)))
1536                           (when (or restp old-restp)
1537                             '(&rest t))
1538                           (when (or keysp old-keysp)
1539                             (append '(&key)
1540                                     (mapcar (lambda (key)
1541                                               `(,key t))
1542                                             keywords)
1543                                     (when (or allow-other-keys-p old-allowp)
1544                                       '(&allow-other-keys)))))
1545                  *))))
1546
1547 (defun defgeneric-declaration (spec lambda-list)
1548   `(ftype ,(ftype-declaration-from-lambda-list lambda-list spec) ,spec))
1549 \f
1550 ;;;; early generic function support
1551
1552 (defvar *!early-generic-functions* ())
1553
1554 (defun ensure-generic-function (fun-name
1555                                 &rest all-keys
1556                                 &key environment source-location
1557                                 &allow-other-keys)
1558   (declare (ignore environment))
1559   (let ((existing (and (fboundp fun-name)
1560                        (gdefinition fun-name))))
1561     (if (and existing
1562              (eq *boot-state* 'complete)
1563              (null (generic-function-p existing)))
1564         (generic-clobbers-function fun-name)
1565         (apply #'ensure-generic-function-using-class
1566                existing fun-name all-keys))))
1567
1568 (defun generic-clobbers-function (fun-name)
1569   (error 'simple-program-error
1570          :format-control "~S already names an ordinary function or a macro."
1571          :format-arguments (list fun-name)))
1572
1573 (defvar *sgf-wrapper*
1574   (boot-make-wrapper (early-class-size 'standard-generic-function)
1575                      'standard-generic-function))
1576
1577 (defvar *sgf-slots-init*
1578   (mapcar (lambda (canonical-slot)
1579             (if (memq (getf canonical-slot :name) '(arg-info source))
1580                 +slot-unbound+
1581                 (let ((initfunction (getf canonical-slot :initfunction)))
1582                   (if initfunction
1583                       (funcall initfunction)
1584                       +slot-unbound+))))
1585           (early-collect-inheritance 'standard-generic-function)))
1586
1587 (defvar *sgf-method-class-index*
1588   (!bootstrap-slot-index 'standard-generic-function 'method-class))
1589
1590 (defun early-gf-p (x)
1591   (and (fsc-instance-p x)
1592        (eq (clos-slots-ref (get-slots x) *sgf-method-class-index*)
1593            +slot-unbound+)))
1594
1595 (defvar *sgf-methods-index*
1596   (!bootstrap-slot-index 'standard-generic-function 'methods))
1597
1598 (defmacro early-gf-methods (gf)
1599   `(clos-slots-ref (get-slots ,gf) *sgf-methods-index*))
1600
1601 (defun safe-generic-function-methods (generic-function)
1602   (if (eq (class-of generic-function) *the-class-standard-generic-function*)
1603       (clos-slots-ref (get-slots generic-function) *sgf-methods-index*)
1604       (generic-function-methods generic-function)))
1605
1606 (defvar *sgf-arg-info-index*
1607   (!bootstrap-slot-index 'standard-generic-function 'arg-info))
1608
1609 (defmacro early-gf-arg-info (gf)
1610   `(clos-slots-ref (get-slots ,gf) *sgf-arg-info-index*))
1611
1612 (defvar *sgf-dfun-state-index*
1613   (!bootstrap-slot-index 'standard-generic-function 'dfun-state))
1614
1615 (defstruct (arg-info
1616             (:conc-name nil)
1617             (:constructor make-arg-info ())
1618             (:copier nil))
1619   (arg-info-lambda-list :no-lambda-list)
1620   arg-info-precedence
1621   arg-info-metatypes
1622   arg-info-number-optional
1623   arg-info-key/rest-p
1624   arg-info-keys   ;nil        no &KEY or &REST allowed
1625                   ;(k1 k2 ..) Each method must accept these &KEY arguments.
1626                   ;T          must have &KEY or &REST
1627
1628   gf-info-simple-accessor-type ; nil, reader, writer, boundp
1629   (gf-precompute-dfun-and-emf-p nil) ; set by set-arg-info
1630
1631   gf-info-static-c-a-m-emf
1632   (gf-info-c-a-m-emf-std-p t)
1633   gf-info-fast-mf-p)
1634
1635 #-sb-fluid (declaim (sb-ext:freeze-type arg-info))
1636
1637 (defun arg-info-valid-p (arg-info)
1638   (not (null (arg-info-number-optional arg-info))))
1639
1640 (defun arg-info-applyp (arg-info)
1641   (or (plusp (arg-info-number-optional arg-info))
1642       (arg-info-key/rest-p arg-info)))
1643
1644 (defun arg-info-number-required (arg-info)
1645   (length (arg-info-metatypes arg-info)))
1646
1647 (defun arg-info-nkeys (arg-info)
1648   (count-if (lambda (x) (neq x t)) (arg-info-metatypes arg-info)))
1649
1650 (defun create-gf-lambda-list (lambda-list)
1651   ;;; Create a gf lambda list from a method lambda list
1652   (loop for x in lambda-list
1653         collect (if (consp x) (list (car x)) x)
1654         if (eq x '&key) do (loop-finish)))
1655
1656 (defun set-arg-info (gf &key new-method (lambda-list nil lambda-list-p)
1657                         argument-precedence-order)
1658   (let* ((arg-info (if (eq *boot-state* 'complete)
1659                        (gf-arg-info gf)
1660                        (early-gf-arg-info gf)))
1661          (methods (if (eq *boot-state* 'complete)
1662                       (generic-function-methods gf)
1663                       (early-gf-methods gf)))
1664          (was-valid-p (integerp (arg-info-number-optional arg-info)))
1665          (first-p (and new-method (null (cdr methods)))))
1666     (when (and (not lambda-list-p) methods)
1667       (setq lambda-list (gf-lambda-list gf)))
1668     (when (or lambda-list-p
1669               (and first-p
1670                    (eq (arg-info-lambda-list arg-info) :no-lambda-list)))
1671       (multiple-value-bind (nreq nopt keysp restp allow-other-keys-p keywords)
1672           (analyze-lambda-list lambda-list)
1673         (when (and methods (not first-p))
1674           (let ((gf-nreq (arg-info-number-required arg-info))
1675                 (gf-nopt (arg-info-number-optional arg-info))
1676                 (gf-key/rest-p (arg-info-key/rest-p arg-info)))
1677             (unless (and (= nreq gf-nreq)
1678                          (= nopt gf-nopt)
1679                          (eq (or keysp restp) gf-key/rest-p))
1680               (error "The lambda-list ~S is incompatible with ~
1681                      existing methods of ~S."
1682                      lambda-list gf))))
1683         (setf (arg-info-lambda-list arg-info)
1684               (if lambda-list-p
1685                   lambda-list
1686                    (create-gf-lambda-list lambda-list)))
1687         (when (or lambda-list-p argument-precedence-order
1688                   (null (arg-info-precedence arg-info)))
1689           (setf (arg-info-precedence arg-info)
1690                 (compute-precedence lambda-list nreq argument-precedence-order)))
1691         (setf (arg-info-metatypes arg-info) (make-list nreq))
1692         (setf (arg-info-number-optional arg-info) nopt)
1693         (setf (arg-info-key/rest-p arg-info) (not (null (or keysp restp))))
1694         (setf (arg-info-keys arg-info)
1695               (if lambda-list-p
1696                   (if allow-other-keys-p t keywords)
1697                   (arg-info-key/rest-p arg-info)))))
1698     (when new-method
1699       (check-method-arg-info gf arg-info new-method))
1700     (set-arg-info1 gf arg-info new-method methods was-valid-p first-p)
1701     arg-info))
1702
1703 (defun check-method-arg-info (gf arg-info method)
1704   (multiple-value-bind (nreq nopt keysp restp allow-other-keys-p keywords)
1705       (analyze-lambda-list (if (consp method)
1706                                (early-method-lambda-list method)
1707                                (method-lambda-list method)))
1708     (flet ((lose (string &rest args)
1709              (error 'simple-program-error
1710                     :format-control "~@<attempt to add the method~2I~_~S~I~_~
1711                                      to the generic function~2I~_~S;~I~_~
1712                                      but ~?~:>"
1713                     :format-arguments (list method gf string args)))
1714            (comparison-description (x y)
1715              (if (> x y) "more" "fewer")))
1716       (let ((gf-nreq (arg-info-number-required arg-info))
1717             (gf-nopt (arg-info-number-optional arg-info))
1718             (gf-key/rest-p (arg-info-key/rest-p arg-info))
1719             (gf-keywords (arg-info-keys arg-info)))
1720         (unless (= nreq gf-nreq)
1721           (lose
1722            "the method has ~A required arguments than the generic function."
1723            (comparison-description nreq gf-nreq)))
1724         (unless (= nopt gf-nopt)
1725           (lose
1726            "the method has ~A optional arguments than the generic function."
1727            (comparison-description nopt gf-nopt)))
1728         (unless (eq (or keysp restp) gf-key/rest-p)
1729           (lose
1730            "the method and generic function differ in whether they accept~_~
1731             &REST or &KEY arguments."))
1732         (when (consp gf-keywords)
1733           (unless (or (and restp (not keysp))
1734                       allow-other-keys-p
1735                       (every (lambda (k) (memq k keywords)) gf-keywords))
1736             (lose "the method does not accept each of the &KEY arguments~2I~_~
1737                    ~S."
1738                   gf-keywords)))))))
1739
1740 (defvar *sm-specializers-index*
1741   (!bootstrap-slot-index 'standard-method 'specializers))
1742 (defvar *sm-%function-index*
1743   (!bootstrap-slot-index 'standard-method '%function))
1744 (defvar *sm-qualifiers-index*
1745   (!bootstrap-slot-index 'standard-method 'qualifiers))
1746 (defvar *sm-plist-index*
1747   (!bootstrap-slot-index 'standard-method 'plist))
1748
1749 ;;; FIXME: we don't actually need this; we could test for the exact
1750 ;;; class and deal with it as appropriate.  In fact we probably don't
1751 ;;; need it anyway because we only use this for METHOD-SPECIALIZERS on
1752 ;;; the standard reader method for METHOD-SPECIALIZERS.  Probably.
1753 (dolist (s '(specializers %function plist))
1754   (aver (= (symbol-value (intern (format nil "*SM-~A-INDEX*" s)))
1755            (!bootstrap-slot-index 'standard-reader-method s)
1756            (!bootstrap-slot-index 'standard-writer-method s)
1757            (!bootstrap-slot-index 'standard-boundp-method s))))
1758
1759 (defun safe-method-specializers (method)
1760   (let ((standard-method-classes
1761          (list *the-class-standard-method*
1762                *the-class-standard-reader-method*
1763                *the-class-standard-writer-method*
1764                *the-class-standard-boundp-method*))
1765         (class (class-of method)))
1766     (if (member class standard-method-classes)
1767         (clos-slots-ref (get-slots method) *sm-specializers-index*)
1768         (method-specializers method))))
1769 (defun safe-method-fast-function (method)
1770   (let ((mf (safe-method-function method)))
1771     (and (typep mf '%method-function)
1772          (%method-function-fast-function mf))))
1773 (defun safe-method-function (method)
1774   (let ((standard-method-classes
1775          (list *the-class-standard-method*
1776                *the-class-standard-reader-method*
1777                *the-class-standard-writer-method*
1778                *the-class-standard-boundp-method*))
1779         (class (class-of method)))
1780     (if (member class standard-method-classes)
1781         (clos-slots-ref (get-slots method) *sm-%function-index*)
1782         (method-function method))))
1783 (defun safe-method-qualifiers (method)
1784   (let ((standard-method-classes
1785          (list *the-class-standard-method*
1786                *the-class-standard-reader-method*
1787                *the-class-standard-writer-method*
1788                *the-class-standard-boundp-method*))
1789         (class (class-of method)))
1790     (if (member class standard-method-classes)
1791         (clos-slots-ref (get-slots method) *sm-qualifiers-index*)
1792         (method-qualifiers method))))
1793
1794 (defun set-arg-info1 (gf arg-info new-method methods was-valid-p first-p)
1795   (let* ((existing-p (and methods (cdr methods) new-method))
1796          (nreq (length (arg-info-metatypes arg-info)))
1797          (metatypes (if existing-p
1798                         (arg-info-metatypes arg-info)
1799                         (make-list nreq)))
1800          (type (if existing-p
1801                    (gf-info-simple-accessor-type arg-info)
1802                    nil)))
1803     (when (arg-info-valid-p arg-info)
1804       (dolist (method (if new-method (list new-method) methods))
1805         (let* ((specializers (if (or (eq *boot-state* 'complete)
1806                                      (not (consp method)))
1807                                  (safe-method-specializers method)
1808                                  (early-method-specializers method t)))
1809                (class (if (or (eq *boot-state* 'complete) (not (consp method)))
1810                           (class-of method)
1811                           (early-method-class method)))
1812                (new-type
1813                 (when (and class
1814                            (or (not (eq *boot-state* 'complete))
1815                                (eq (generic-function-method-combination gf)
1816                                    *standard-method-combination*)))
1817                   (cond ((or (eq class *the-class-standard-reader-method*)
1818                              (eq class *the-class-global-reader-method*))
1819                          'reader)
1820                         ((or (eq class *the-class-standard-writer-method*)
1821                              (eq class *the-class-global-writer-method*))
1822                          'writer)
1823                         ((or (eq class *the-class-standard-boundp-method*)
1824                              (eq class *the-class-global-boundp-method*))
1825                          'boundp)))))
1826           (setq metatypes (mapcar #'raise-metatype metatypes specializers))
1827           (setq type (cond ((null type) new-type)
1828                            ((eq type new-type) type)
1829                            (t nil)))))
1830       (setf (arg-info-metatypes arg-info) metatypes)
1831       (setf (gf-info-simple-accessor-type arg-info) type)))
1832   (when (or (not was-valid-p) first-p)
1833     (multiple-value-bind (c-a-m-emf std-p)
1834         (if (early-gf-p gf)
1835             (values t t)
1836             (compute-applicable-methods-emf gf))
1837       (setf (gf-info-static-c-a-m-emf arg-info) c-a-m-emf)
1838       (setf (gf-info-c-a-m-emf-std-p arg-info) std-p)
1839       (unless (gf-info-c-a-m-emf-std-p arg-info)
1840         (setf (gf-info-simple-accessor-type arg-info) t))))
1841   (unless was-valid-p
1842     (let ((name (if (eq *boot-state* 'complete)
1843                     (generic-function-name gf)
1844                     (!early-gf-name gf))))
1845       (setf (gf-precompute-dfun-and-emf-p arg-info)
1846             (cond
1847               ((and (consp name)
1848                     (member (car name)
1849                             *internal-pcl-generalized-fun-name-symbols*))
1850                 nil)
1851               (t (let* ((symbol (fun-name-block-name name))
1852                         (package (symbol-package symbol)))
1853                    (and (or (eq package *pcl-package*)
1854                             (memq package (package-use-list *pcl-package*)))
1855                         ;; FIXME: this test will eventually be
1856                         ;; superseded by the *internal-pcl...* test,
1857                         ;; above.  While we are in a process of
1858                         ;; transition, however, it should probably
1859                         ;; remain.
1860                         (not (find #\Space (symbol-name symbol))))))))))
1861   (setf (gf-info-fast-mf-p arg-info)
1862         (or (not (eq *boot-state* 'complete))
1863             (let* ((method-class (generic-function-method-class gf))
1864                    (methods (compute-applicable-methods
1865                              #'make-method-lambda
1866                              (list gf (class-prototype method-class)
1867                                    '(lambda) nil))))
1868               (and methods (null (cdr methods))
1869                    (let ((specls (method-specializers (car methods))))
1870                      (and (classp (car specls))
1871                           (eq 'standard-generic-function
1872                               (class-name (car specls)))
1873                           (classp (cadr specls))
1874                           (eq 'standard-method
1875                               (class-name (cadr specls)))))))))
1876   arg-info)
1877
1878 ;;; This is the early definition of ENSURE-GENERIC-FUNCTION-USING-CLASS.
1879 ;;;
1880 ;;; The STATIC-SLOTS field of the funcallable instances used as early
1881 ;;; generic functions is used to store the early methods and early
1882 ;;; discriminator code for the early generic function. The static
1883 ;;; slots field of the fins contains a list whose:
1884 ;;;    CAR    -   a list of the early methods on this early gf
1885 ;;;    CADR   -   the early discriminator code for this method
1886 (defun ensure-generic-function-using-class (existing spec &rest keys
1887                                             &key (lambda-list nil
1888                                                               lambda-list-p)
1889                                             argument-precedence-order
1890                                             source-location
1891                                             &allow-other-keys)
1892   (declare (ignore keys))
1893   (cond ((and existing (early-gf-p existing))
1894          (when lambda-list-p
1895            (set-arg-info existing :lambda-list lambda-list))
1896          existing)
1897         ((assoc spec *!generic-function-fixups* :test #'equal)
1898          (if existing
1899              (make-early-gf spec lambda-list lambda-list-p existing
1900                             argument-precedence-order source-location)
1901              (error "The function ~S is not already defined." spec)))
1902         (existing
1903          (error "~S should be on the list ~S."
1904                 spec
1905                 '*!generic-function-fixups*))
1906         (t
1907          (pushnew spec *!early-generic-functions* :test #'equal)
1908          (make-early-gf spec lambda-list lambda-list-p nil
1909                         argument-precedence-order source-location))))
1910
1911 (defun make-early-gf (spec &optional lambda-list lambda-list-p
1912                       function argument-precedence-order source-location)
1913   (let ((fin (allocate-standard-funcallable-instance
1914               *sgf-wrapper* *sgf-slots-init*)))
1915     (set-funcallable-instance-function
1916      fin
1917      (or function
1918          (if (eq spec 'print-object)
1919              #'(lambda (instance stream)
1920                  (print-unreadable-object (instance stream :identity t)
1921                    (format stream "std-instance")))
1922              #'(lambda (&rest args)
1923                  (declare (ignore args))
1924                  (error "The function of the funcallable-instance ~S~
1925                          has not been set." fin)))))
1926     (setf (gdefinition spec) fin)
1927     (!bootstrap-set-slot 'standard-generic-function fin 'name spec)
1928     (!bootstrap-set-slot 'standard-generic-function
1929                          fin
1930                          'source
1931                          source-location)
1932     (set-fun-name fin spec)
1933     (let ((arg-info (make-arg-info)))
1934       (setf (early-gf-arg-info fin) arg-info)
1935       (when lambda-list-p
1936         (proclaim (defgeneric-declaration spec lambda-list))
1937         (if argument-precedence-order
1938             (set-arg-info fin
1939                           :lambda-list lambda-list
1940                           :argument-precedence-order argument-precedence-order)
1941             (set-arg-info fin :lambda-list lambda-list))))
1942     fin))
1943
1944 (defun safe-gf-dfun-state (generic-function)
1945   (if (eq (class-of generic-function) *the-class-standard-generic-function*)
1946       (clos-slots-ref (get-slots generic-function) *sgf-dfun-state-index*)
1947       (gf-dfun-state generic-function)))
1948 (defun (setf safe-gf-dfun-state) (new-value generic-function)
1949   (if (eq (class-of generic-function) *the-class-standard-generic-function*)
1950       (setf (clos-slots-ref (get-slots generic-function)
1951                             *sgf-dfun-state-index*)
1952             new-value)
1953       (setf (gf-dfun-state generic-function) new-value)))
1954
1955 (defun set-dfun (gf &optional dfun cache info)
1956   (when cache
1957     (setf (cache-owner cache) gf))
1958   (let ((new-state (if (and dfun (or cache info))
1959                        (list* dfun cache info)
1960                        dfun)))
1961     (if (eq *boot-state* 'complete)
1962         (setf (safe-gf-dfun-state gf) new-state)
1963         (setf (clos-slots-ref (get-slots gf) *sgf-dfun-state-index*)
1964               new-state)))
1965   dfun)
1966
1967 (defun gf-dfun-cache (gf)
1968   (let ((state (if (eq *boot-state* 'complete)
1969                    (safe-gf-dfun-state gf)
1970                    (clos-slots-ref (get-slots gf) *sgf-dfun-state-index*))))
1971     (typecase state
1972       (function nil)
1973       (cons (cadr state)))))
1974
1975 (defun gf-dfun-info (gf)
1976   (let ((state (if (eq *boot-state* 'complete)
1977                    (safe-gf-dfun-state gf)
1978                    (clos-slots-ref (get-slots gf) *sgf-dfun-state-index*))))
1979     (typecase state
1980       (function nil)
1981       (cons (cddr state)))))
1982
1983 (defvar *sgf-name-index*
1984   (!bootstrap-slot-index 'standard-generic-function 'name))
1985
1986 (defun !early-gf-name (gf)
1987   (clos-slots-ref (get-slots gf) *sgf-name-index*))
1988
1989 (defun gf-lambda-list (gf)
1990   (let ((arg-info (if (eq *boot-state* 'complete)
1991                       (gf-arg-info gf)
1992                       (early-gf-arg-info gf))))
1993     (if (eq :no-lambda-list (arg-info-lambda-list arg-info))
1994         (let ((methods (if (eq *boot-state* 'complete)
1995                            (generic-function-methods gf)
1996                            (early-gf-methods gf))))
1997           (if (null methods)
1998               (progn
1999                 (warn "no way to determine the lambda list for ~S" gf)
2000                 nil)
2001               (let* ((method (car (last methods)))
2002                      (ll (if (consp method)
2003                              (early-method-lambda-list method)
2004                              (method-lambda-list method))))
2005                 (create-gf-lambda-list ll))))
2006         (arg-info-lambda-list arg-info))))
2007
2008 (defmacro real-ensure-gf-internal (gf-class all-keys env)
2009   `(progn
2010      (cond ((symbolp ,gf-class)
2011             (setq ,gf-class (find-class ,gf-class t ,env)))
2012            ((classp ,gf-class))
2013            (t
2014             (error "The :GENERIC-FUNCTION-CLASS argument (~S) was neither a~%~
2015                     class nor a symbol that names a class."
2016                    ,gf-class)))
2017      (unless (class-finalized-p ,gf-class)
2018        (if (class-has-a-forward-referenced-superclass-p ,gf-class)
2019            ;; FIXME: reference MOP documentation -- this is an
2020            ;; additional requirement on our users
2021            (error "The generic function class ~S is not finalizeable" ,gf-class)
2022            (finalize-inheritance ,gf-class)))
2023      (remf ,all-keys :generic-function-class)
2024      (remf ,all-keys :environment)
2025      (let ((combin (getf ,all-keys :method-combination '.shes-not-there.)))
2026        (unless (eq combin '.shes-not-there.)
2027          (setf (getf ,all-keys :method-combination)
2028                (find-method-combination (class-prototype ,gf-class)
2029                                         (car combin)
2030                                         (cdr combin)))))
2031     (let ((method-class (getf ,all-keys :method-class '.shes-not-there.)))
2032       (unless (eq method-class '.shes-not-there.)
2033         (setf (getf ,all-keys :method-class)
2034               (cond ((classp method-class)
2035                      method-class)
2036                     (t (find-class method-class t ,env))))))))
2037
2038 (defun real-ensure-gf-using-class--generic-function
2039        (existing
2040         fun-name
2041         &rest all-keys
2042         &key environment (lambda-list nil lambda-list-p)
2043         (generic-function-class 'standard-generic-function)
2044         &allow-other-keys)
2045   (real-ensure-gf-internal generic-function-class all-keys environment)
2046   ;; KLUDGE: the above macro does SETQ on GENERIC-FUNCTION-CLASS,
2047   ;; which is what makes the next line work
2048   (unless (eq (class-of existing) generic-function-class)
2049     (change-class existing generic-function-class))
2050   (prog1
2051       (apply #'reinitialize-instance existing all-keys)
2052     (when lambda-list-p
2053       (proclaim (defgeneric-declaration fun-name lambda-list)))))
2054
2055 (defun real-ensure-gf-using-class--null
2056        (existing
2057         fun-name
2058         &rest all-keys
2059         &key environment (lambda-list nil lambda-list-p)
2060              (generic-function-class 'standard-generic-function)
2061         &allow-other-keys)
2062   (declare (ignore existing))
2063   (real-ensure-gf-internal generic-function-class all-keys environment)
2064   (prog1
2065       (setf (gdefinition fun-name)
2066             (apply #'make-instance generic-function-class
2067                    :name fun-name all-keys))
2068     (when lambda-list-p
2069       (proclaim (defgeneric-declaration fun-name lambda-list)))))
2070 \f
2071 (defun safe-gf-arg-info (generic-function)
2072   (if (eq (class-of generic-function) *the-class-standard-generic-function*)
2073       (clos-slots-ref (fsc-instance-slots generic-function)
2074                       *sgf-arg-info-index*)
2075       (gf-arg-info generic-function)))
2076
2077 ;;; FIXME: this function took on a slightly greater role than it
2078 ;;; previously had around 2005-11-02, when CSR fixed the bug whereby
2079 ;;; having more than one subclass of standard-generic-function caused
2080 ;;; the whole system to die horribly through a metacircle in
2081 ;;; GF-ARG-INFO.  The fix is to be slightly more disciplined about
2082 ;;; calling accessor methods -- we call GET-GENERIC-FUN-INFO when
2083 ;;; computing discriminating functions, so we need to be careful about
2084 ;;; having a base case for the recursion, and we provide that with the
2085 ;;; STANDARD-GENERIC-FUNCTION case below.  However, we are not (yet)
2086 ;;; as disciplined as CLISP's CLOS/MOP, and it would be nice to get to
2087 ;;; that stage, where all potentially dangerous cases are enumerated
2088 ;;; and stopped.  -- CSR, 2005-11-02.
2089 (defun get-generic-fun-info (gf)
2090   ;; values   nreq applyp metatypes nkeys arg-info
2091   (multiple-value-bind (applyp metatypes arg-info)
2092       (let* ((arg-info (if (early-gf-p gf)
2093                            (early-gf-arg-info gf)
2094                            (safe-gf-arg-info gf)))
2095              (metatypes (arg-info-metatypes arg-info)))
2096         (values (arg-info-applyp arg-info)
2097                 metatypes
2098                 arg-info))
2099     (values (length metatypes) applyp metatypes
2100             (count-if (lambda (x) (neq x t)) metatypes)
2101             arg-info)))
2102
2103 (defun early-make-a-method (class qualifiers arglist specializers initargs doc
2104                             &key slot-name object-class method-class-function)
2105   (let ((parsed ())
2106         (unparsed ()))
2107     ;; Figure out whether we got class objects or class names as the
2108     ;; specializers and set parsed and unparsed appropriately. If we
2109     ;; got class objects, then we can compute unparsed, but if we got
2110     ;; class names we don't try to compute parsed.
2111     ;;
2112     ;; Note that the use of not symbolp in this call to every should be
2113     ;; read as 'classp' we can't use classp itself because it doesn't
2114     ;; exist yet.
2115     (if (every (lambda (s) (not (symbolp s))) specializers)
2116         (setq parsed specializers
2117               unparsed (mapcar (lambda (s)
2118                                  (if (eq s t) t (class-name s)))
2119                                specializers))
2120         (setq unparsed specializers
2121               parsed ()))
2122     (let ((result
2123            (list :early-method
2124
2125                  (getf initargs :function)
2126                  (let ((mf (getf initargs :function)))
2127                    (aver mf)
2128                    (and (typep mf '%method-function)
2129                         (%method-function-fast-function mf)))
2130
2131                  ;; the parsed specializers. This is used by
2132                  ;; EARLY-METHOD-SPECIALIZERS to cache the parse.
2133                  ;; Note that this only comes into play when there is
2134                  ;; more than one early method on an early gf.
2135                  parsed
2136
2137                  ;; A list to which REAL-MAKE-A-METHOD can be applied
2138                  ;; to make a real method corresponding to this early
2139                  ;; one.
2140                  (append
2141                   (list class qualifiers arglist unparsed
2142                         initargs doc)
2143                   (when slot-name
2144                     (list :slot-name slot-name :object-class object-class
2145                           :method-class-function method-class-function))))))
2146       (initialize-method-function initargs result)
2147       result)))
2148
2149 (defun real-make-a-method
2150        (class qualifiers lambda-list specializers initargs doc
2151         &rest args &key slot-name object-class method-class-function)
2152   (setq specializers (parse-specializers specializers))
2153   (if method-class-function
2154       (let* ((object-class (if (classp object-class) object-class
2155                                (find-class object-class)))
2156              (slots (class-direct-slots object-class))
2157              (slot-definition (find slot-name slots
2158                                     :key #'slot-definition-name)))
2159         (aver slot-name)
2160         (aver slot-definition)
2161         (let ((initargs (list* :qualifiers qualifiers :lambda-list lambda-list
2162                                :specializers specializers :documentation doc
2163                                :slot-definition slot-definition
2164                                :slot-name slot-name initargs)))
2165           (apply #'make-instance
2166                  (apply method-class-function object-class slot-definition
2167                         initargs)
2168                  initargs)))
2169       (apply #'make-instance class :qualifiers qualifiers
2170              :lambda-list lambda-list :specializers specializers
2171              :documentation doc (append args initargs))))
2172
2173 (defun early-method-function (early-method)
2174   (values (cadr early-method) (caddr early-method)))
2175
2176 (defun early-method-class (early-method)
2177   (find-class (car (fifth early-method))))
2178
2179 (defun early-method-standard-accessor-p (early-method)
2180   (let ((class (first (fifth early-method))))
2181     (or (eq class 'standard-reader-method)
2182         (eq class 'standard-writer-method)
2183         (eq class 'standard-boundp-method))))
2184
2185 (defun early-method-standard-accessor-slot-name (early-method)
2186   (eighth (fifth early-method)))
2187
2188 ;;; Fetch the specializers of an early method. This is basically just
2189 ;;; a simple accessor except that when the second argument is t, this
2190 ;;; converts the specializers from symbols into class objects. The
2191 ;;; class objects are cached in the early method, this makes
2192 ;;; bootstrapping faster because the class objects only have to be
2193 ;;; computed once.
2194 ;;;
2195 ;;; NOTE:
2196 ;;;  The second argument should only be passed as T by
2197 ;;;  early-lookup-method. This is to implement the rule that only when
2198 ;;;  there is more than one early method on a generic function is the
2199 ;;;  conversion from class names to class objects done. This
2200 ;;;  corresponds to the fact that we are only allowed to have one
2201 ;;;  method on any generic function up until the time classes exist.
2202 (defun early-method-specializers (early-method &optional objectsp)
2203   (if (and (listp early-method)
2204            (eq (car early-method) :early-method))
2205       (cond ((eq objectsp t)
2206              (or (fourth early-method)
2207                  (setf (fourth early-method)
2208                        (mapcar #'find-class (cadddr (fifth early-method))))))
2209             (t
2210              (fourth (fifth early-method))))
2211       (error "~S is not an early-method." early-method)))
2212
2213 (defun early-method-qualifiers (early-method)
2214   (second (fifth early-method)))
2215
2216 (defun early-method-lambda-list (early-method)
2217   (third (fifth early-method)))
2218
2219 (defun early-method-initargs (early-method)
2220   (fifth (fifth early-method)))
2221
2222 (defun (setf early-method-initargs) (new-value early-method)
2223   (setf (fifth (fifth early-method)) new-value))
2224
2225 (defun early-add-named-method (generic-function-name
2226                                qualifiers
2227                                specializers
2228                                arglist
2229                                &rest initargs)
2230   (let* (;; we don't need to deal with the :generic-function-class
2231          ;; argument here because the default,
2232          ;; STANDARD-GENERIC-FUNCTION, is right for all early generic
2233          ;; functions.  (See REAL-ADD-NAMED-METHOD)
2234          (gf (ensure-generic-function generic-function-name))
2235          (existing
2236            (dolist (m (early-gf-methods gf))
2237              (when (and (equal (early-method-specializers m) specializers)
2238                         (equal (early-method-qualifiers m) qualifiers))
2239                (return m))))
2240          (new (make-a-method 'standard-method
2241                              qualifiers
2242                              arglist
2243                              specializers
2244                              initargs
2245                              ())))
2246     (when existing (remove-method gf existing))
2247     (add-method gf new)))
2248
2249 ;;; This is the early version of ADD-METHOD. Later this will become a
2250 ;;; generic function. See !FIX-EARLY-GENERIC-FUNCTIONS which has
2251 ;;; special knowledge about ADD-METHOD.
2252 (defun add-method (generic-function method)
2253   (when (not (fsc-instance-p generic-function))
2254     (error "Early ADD-METHOD didn't get a funcallable instance."))
2255   (when (not (and (listp method) (eq (car method) :early-method)))
2256     (error "Early ADD-METHOD didn't get an early method."))
2257   (push method (early-gf-methods generic-function))
2258   (set-arg-info generic-function :new-method method)
2259   (unless (assoc (!early-gf-name generic-function)
2260                  *!generic-function-fixups*
2261                  :test #'equal)
2262     (update-dfun generic-function)))
2263
2264 ;;; This is the early version of REMOVE-METHOD. See comments on
2265 ;;; the early version of ADD-METHOD.
2266 (defun remove-method (generic-function method)
2267   (when (not (fsc-instance-p generic-function))
2268     (error "An early remove-method didn't get a funcallable instance."))
2269   (when (not (and (listp method) (eq (car method) :early-method)))
2270     (error "An early remove-method didn't get an early method."))
2271   (setf (early-gf-methods generic-function)
2272         (remove method (early-gf-methods generic-function)))
2273   (set-arg-info generic-function)
2274   (unless (assoc (!early-gf-name generic-function)
2275                  *!generic-function-fixups*
2276                  :test #'equal)
2277     (update-dfun generic-function)))
2278
2279 ;;; This is the early version of GET-METHOD. See comments on the early
2280 ;;; version of ADD-METHOD.
2281 (defun get-method (generic-function qualifiers specializers
2282                                     &optional (errorp t))
2283   (if (early-gf-p generic-function)
2284       (or (dolist (m (early-gf-methods generic-function))
2285             (when (and (or (equal (early-method-specializers m nil)
2286                                   specializers)
2287                            (equal (early-method-specializers m t)
2288                                   specializers))
2289                        (equal (early-method-qualifiers m) qualifiers))
2290               (return m)))
2291           (if errorp
2292               (error "can't get early method")
2293               nil))
2294       (real-get-method generic-function qualifiers specializers errorp)))
2295
2296 (defun !fix-early-generic-functions ()
2297   (let ((accessors nil))
2298     ;; Rearrange *!EARLY-GENERIC-FUNCTIONS* to speed up
2299     ;; FIX-EARLY-GENERIC-FUNCTIONS.
2300     (dolist (early-gf-spec *!early-generic-functions*)
2301       (when (every #'early-method-standard-accessor-p
2302                    (early-gf-methods (gdefinition early-gf-spec)))
2303         (push early-gf-spec accessors)))
2304     (dolist (spec (nconc accessors
2305                          '(accessor-method-slot-name
2306                            generic-function-methods
2307                            method-specializers
2308                            specializerp
2309                            specializer-type
2310                            specializer-class
2311                            slot-definition-location
2312                            slot-definition-name
2313                            class-slots
2314                            gf-arg-info
2315                            class-precedence-list
2316                            slot-boundp-using-class
2317                            (setf slot-value-using-class)
2318                            slot-value-using-class
2319                            structure-class-p
2320                            standard-class-p
2321                            funcallable-standard-class-p
2322                            specializerp)))
2323       (/show spec)
2324       (setq *!early-generic-functions*
2325             (cons spec
2326                   (delete spec *!early-generic-functions* :test #'equal))))
2327
2328     (dolist (early-gf-spec *!early-generic-functions*)
2329       (/show early-gf-spec)
2330       (let* ((gf (gdefinition early-gf-spec))
2331              (methods (mapcar (lambda (early-method)
2332                                 (let ((args (copy-list (fifth
2333                                                         early-method))))
2334                                   (setf (fourth args)
2335                                         (early-method-specializers
2336                                          early-method t))
2337                                   (apply #'real-make-a-method args)))
2338                               (early-gf-methods gf))))
2339         (setf (generic-function-method-class gf) *the-class-standard-method*)
2340         (setf (generic-function-method-combination gf)
2341               *standard-method-combination*)
2342         (set-methods gf methods)))
2343
2344     (dolist (fn *!early-functions*)
2345       (/show fn)
2346       (setf (gdefinition (car fn)) (fdefinition (caddr fn))))
2347
2348     (dolist (fixup *!generic-function-fixups*)
2349       (/show fixup)
2350       (let* ((fspec (car fixup))
2351              (gf (gdefinition fspec))
2352              (methods (mapcar (lambda (method)
2353                                 (let* ((lambda-list (first method))
2354                                        (specializers (second method))
2355                                        (method-fn-name (third method))
2356                                        (fn-name (or method-fn-name fspec))
2357                                        (fn (fdefinition fn-name))
2358                                        (initargs
2359                                         (list :function
2360                                               (set-fun-name
2361                                                (lambda (args next-methods)
2362                                                  (declare (ignore
2363                                                            next-methods))
2364                                                  (apply fn args))
2365                                                `(call ,fn-name)))))
2366                                   (declare (type function fn))
2367                                   (make-a-method 'standard-method
2368                                                  ()
2369                                                  lambda-list
2370                                                  specializers
2371                                                  initargs
2372                                                  nil)))
2373                               (cdr fixup))))
2374         (setf (generic-function-method-class gf) *the-class-standard-method*)
2375         (setf (generic-function-method-combination gf)
2376               *standard-method-combination*)
2377         (set-methods gf methods))))
2378   (/show "leaving !FIX-EARLY-GENERIC-FUNCTIONS"))
2379 \f
2380 ;;; PARSE-DEFMETHOD is used by DEFMETHOD to parse the &REST argument
2381 ;;; into the 'real' arguments. This is where the syntax of DEFMETHOD
2382 ;;; is really implemented.
2383 (defun parse-defmethod (cdr-of-form)
2384   (declare (list cdr-of-form))
2385   (let ((name (pop cdr-of-form))
2386         (qualifiers ())
2387         (spec-ll ()))
2388     (loop (if (and (car cdr-of-form) (atom (car cdr-of-form)))
2389               (push (pop cdr-of-form) qualifiers)
2390               (return (setq qualifiers (nreverse qualifiers)))))
2391     (setq spec-ll (pop cdr-of-form))
2392     (values name qualifiers spec-ll cdr-of-form)))
2393
2394 (defun parse-specializers (specializers)
2395   (declare (list specializers))
2396   (flet ((parse (spec)
2397            (let ((result (specializer-from-type spec)))
2398              (if (specializerp result)
2399                  result
2400                  (if (symbolp spec)
2401                      (error "~S was used as a specializer,~%~
2402                              but is not the name of a class."
2403                             spec)
2404                      (error "~S is not a legal specializer." spec))))))
2405     (mapcar #'parse specializers)))
2406
2407 (defun unparse-specializers (specializers-or-method)
2408   (if (listp specializers-or-method)
2409       (flet ((unparse (spec)
2410                (if (specializerp spec)
2411                    (let ((type (specializer-type spec)))
2412                      (if (and (consp type)
2413                               (eq (car type) 'class))
2414                          (let* ((class (cadr type))
2415                                 (class-name (class-name class)))
2416                            (if (eq class (find-class class-name nil))
2417                                class-name
2418                                type))
2419                          type))
2420                    (error "~S is not a legal specializer." spec))))
2421         (mapcar #'unparse specializers-or-method))
2422       (unparse-specializers (method-specializers specializers-or-method))))
2423
2424 (defun parse-method-or-spec (spec &optional (errorp t))
2425   (let (gf method name temp)
2426     (if (method-p spec)
2427         (setq method spec
2428               gf (method-generic-function method)
2429               temp (and gf (generic-function-name gf))
2430               name (if temp
2431                        (make-method-spec temp
2432                                          (method-qualifiers method)
2433                                          (unparse-specializers
2434                                           (method-specializers method)))
2435                        (make-symbol (format nil "~S" method))))
2436         (multiple-value-bind (gf-spec quals specls)
2437             (parse-defmethod spec)
2438           (and (setq gf (and (or errorp (fboundp gf-spec))
2439                              (gdefinition gf-spec)))
2440                (let ((nreq (compute-discriminating-function-arglist-info gf)))
2441                  (setq specls (append (parse-specializers specls)
2442                                       (make-list (- nreq (length specls))
2443                                                  :initial-element
2444                                                  *the-class-t*)))
2445                  (and
2446                    (setq method (get-method gf quals specls errorp))
2447                    (setq name
2448                          (make-method-spec
2449                           gf-spec quals (unparse-specializers specls))))))))
2450     (values gf method name)))
2451 \f
2452 (defun extract-parameters (specialized-lambda-list)
2453   (multiple-value-bind (parameters ignore1 ignore2)
2454       (parse-specialized-lambda-list specialized-lambda-list)
2455     (declare (ignore ignore1 ignore2))
2456     parameters))
2457
2458 (defun extract-lambda-list (specialized-lambda-list)
2459   (multiple-value-bind (ignore1 lambda-list ignore2)
2460       (parse-specialized-lambda-list specialized-lambda-list)
2461     (declare (ignore ignore1 ignore2))
2462     lambda-list))
2463
2464 (defun extract-specializer-names (specialized-lambda-list)
2465   (multiple-value-bind (ignore1 ignore2 specializers)
2466       (parse-specialized-lambda-list specialized-lambda-list)
2467     (declare (ignore ignore1 ignore2))
2468     specializers))
2469
2470 (defun extract-required-parameters (specialized-lambda-list)
2471   (multiple-value-bind (ignore1 ignore2 ignore3 required-parameters)
2472       (parse-specialized-lambda-list specialized-lambda-list)
2473     (declare (ignore ignore1 ignore2 ignore3))
2474     required-parameters))
2475
2476 (define-condition specialized-lambda-list-error
2477     (reference-condition simple-program-error)
2478   ()
2479   (:default-initargs :references (list '(:ansi-cl :section (3 4 3)))))
2480
2481 (defun parse-specialized-lambda-list
2482     (arglist
2483      &optional supplied-keywords (allowed-keywords '(&optional &rest &key &aux))
2484      &aux (specialized-lambda-list-keywords
2485            '(&optional &rest &key &allow-other-keys &aux)))
2486   (let ((arg (car arglist)))
2487     (cond ((null arglist) (values nil nil nil nil))
2488           ((eq arg '&aux)
2489            (values nil arglist nil nil))
2490           ((memq arg lambda-list-keywords)
2491            ;; non-standard lambda-list-keywords are errors.
2492            (unless (memq arg specialized-lambda-list-keywords)
2493              (error 'specialized-lambda-list-error
2494                     :format-control "unknown specialized-lambda-list ~
2495                                      keyword ~S~%"
2496                     :format-arguments (list arg)))
2497            ;; no multiple &rest x &rest bla specifying
2498            (when (memq arg supplied-keywords)
2499              (error 'specialized-lambda-list-error
2500                     :format-control "multiple occurrence of ~
2501                                      specialized-lambda-list keyword ~S~%"
2502                     :format-arguments (list arg)))
2503            ;; And no placing &key in front of &optional, either.
2504            (unless (memq arg allowed-keywords)
2505              (error 'specialized-lambda-list-error
2506                     :format-control "misplaced specialized-lambda-list ~
2507                                      keyword ~S~%"
2508                     :format-arguments (list arg)))
2509            ;; When we are at a lambda-list keyword, the parameters
2510            ;; don't include the lambda-list keyword; the lambda-list
2511            ;; does include the lambda-list keyword; and no
2512            ;; specializers are allowed to follow the lambda-list
2513            ;; keywords (at least for now).
2514            (multiple-value-bind (parameters lambda-list)
2515                (parse-specialized-lambda-list (cdr arglist)
2516                                               (cons arg supplied-keywords)
2517                                               (if (eq arg '&key)
2518                                                   (cons '&allow-other-keys
2519                                                         (cdr (member arg allowed-keywords)))
2520                                                 (cdr (member arg allowed-keywords))))
2521              (when (and (eq arg '&rest)
2522                         (or (null lambda-list)
2523                             (memq (car lambda-list)
2524                                   specialized-lambda-list-keywords)
2525                             (not (or (null (cadr lambda-list))
2526                                      (memq (cadr lambda-list)
2527                                            specialized-lambda-list-keywords)))))
2528                (error 'specialized-lambda-list-error
2529                       :format-control
2530                       "in a specialized-lambda-list, excactly one ~
2531                        variable must follow &REST.~%"
2532                       :format-arguments nil))
2533              (values parameters
2534                      (cons arg lambda-list)
2535                      ()
2536                      ())))
2537           (supplied-keywords
2538            ;; After a lambda-list keyword there can be no specializers.
2539            (multiple-value-bind (parameters lambda-list)
2540                (parse-specialized-lambda-list (cdr arglist)
2541                                               supplied-keywords
2542                                               allowed-keywords)
2543              (values (cons (if (listp arg) (car arg) arg) parameters)
2544                      (cons arg lambda-list)
2545                      ()
2546                      ())))
2547           (t
2548            (multiple-value-bind (parameters lambda-list specializers required)
2549                (parse-specialized-lambda-list (cdr arglist))
2550              (values (cons (if (listp arg) (car arg) arg) parameters)
2551                      (cons (if (listp arg) (car arg) arg) lambda-list)
2552                      (cons (if (listp arg) (cadr arg) t) specializers)
2553                      (cons (if (listp arg) (car arg) arg) required)))))))
2554 \f
2555 (setq *boot-state* 'early)
2556 \f
2557 ;;; FIXME: In here there was a #-CMU definition of SYMBOL-MACROLET
2558 ;;; which used %WALKER stuff. That suggests to me that maybe the code
2559 ;;; walker stuff was only used for implementing stuff like that; maybe
2560 ;;; it's not needed any more? Hunt down what it was used for and see.
2561
2562 (defmacro with-slots (slots instance &body body)
2563   (let ((in (gensym)))
2564     `(let ((,in ,instance))
2565        (declare (ignorable ,in))
2566        ,@(let ((instance (if (and (consp instance) (eq (car instance) 'the))
2567                              (third instance)
2568                              instance)))
2569            (and (symbolp instance)
2570                 `((declare (%variable-rebinding ,in ,instance)))))
2571        ,in
2572        (symbol-macrolet ,(mapcar (lambda (slot-entry)
2573                                    (let ((var-name
2574                                           (if (symbolp slot-entry)
2575                                               slot-entry
2576                                               (car slot-entry)))
2577                                          (slot-name
2578                                           (if (symbolp slot-entry)
2579                                               slot-entry
2580                                               (cadr slot-entry))))
2581                                      `(,var-name
2582                                        (slot-value ,in ',slot-name))))
2583                                  slots)
2584                         ,@body))))
2585
2586 (defmacro with-accessors (slots instance &body body)
2587   (let ((in (gensym)))
2588     `(let ((,in ,instance))
2589        (declare (ignorable ,in))
2590        ,@(let ((instance (if (and (consp instance) (eq (car instance) 'the))
2591                              (third instance)
2592                              instance)))
2593            (and (symbolp instance)
2594                 `((declare (%variable-rebinding ,in ,instance)))))
2595        ,in
2596        (symbol-macrolet ,(mapcar (lambda (slot-entry)
2597                                    (let ((var-name (car slot-entry))
2598                                          (accessor-name (cadr slot-entry)))
2599                                      `(,var-name (,accessor-name ,in))))
2600                                  slots)
2601           ,@body))))