src/pcl/boot.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 #|
  27
  28 The CommonLoops evaluator is meta-circular.
  29
  30 Most of the code in PCL is methods on generic functions, including
  31 most of the code that actually implements generic functions and method
  32 lookup.
  33
  34 So, we have a classic bootstrapping problem. The solution to this is
  35 to first get a cheap implementation of generic functions running,
  36 these are called early generic functions. These early generic
  37 functions and the corresponding early methods and early method lookup
  38 are used to get enough of the system running that it is possible to
  39 create real generic functions and methods and implement real method
  40 lookup. At that point (done in the file FIXUP) the function
  41 !FIX-EARLY-GENERIC-FUNCTIONS is called to convert all the early generic
  42 functions to real generic functions.
  43
  44 The cheap generic functions are built using the same
  45 FUNCALLABLE-INSTANCE objects that real generic functions are made out of.
  46 This means that as PCL is being bootstrapped, the cheap generic
  47 function objects which are being created are the same objects which
  48 will later be real generic functions. This is good because:
  49   - we don't cons garbage structure, and
  50   - we can keep pointers to the cheap generic function objects
  51     during booting because those pointers will still point to
  52     the right object after the generic functions are all fixed up.
  53
  54 This file defines the DEFMETHOD macro and the mechanism used to expand
  55 it. This includes the mechanism for processing the body of a method.
  56 DEFMETHOD basically expands into a call to LOAD-DEFMETHOD, which
  57 basically calls ADD-METHOD to add the method to the generic function.
  58 These expansions can be loaded either during bootstrapping or when PCL
  59 is fully up and running.
  60
  61 An important effect of this arrangement is it means we can compile
  62 files with DEFMETHOD forms in them in a completely running PCL, but
  63 then load those files back in during bootstrapping. This makes
  64 development easier. It also means there is only one set of code for
  65 processing DEFMETHOD. Bootstrapping works by being sure to have
  66 LOAD-METHOD be careful to call only primitives which work during
  67 bootstrapping.
  68
  69 |#
  70
  71 (declaim (notinline make-a-method
  72                     add-named-method
  73                     ensure-generic-function-using-class
  74                     add-method
  75                     remove-method))
  76
  77 (defvar *!early-functions*
  78         '((make-a-method early-make-a-method
  79                          real-make-a-method)
  80           (add-named-method early-add-named-method
  81                             real-add-named-method)
  82           ))
  83
  84 ;;; For each of the early functions, arrange to have it point to its
  85 ;;; early definition. Do this in a way that makes sure that if we
  86 ;;; redefine one of the early definitions the redefinition will take
  87 ;;; effect. This makes development easier.
  88 (dolist (fns *!early-functions*)
  89   (let ((name (car fns))
  90         (early-name (cadr fns)))
  91     (setf (gdefinition name)
  92             (set-fun-name
  93              (lambda (&rest args)
  94                (apply (fdefinition early-name) args))
  95              name))))
  96
  97 ;;; *!GENERIC-FUNCTION-FIXUPS* is used by !FIX-EARLY-GENERIC-FUNCTIONS
  98 ;;; to convert the few functions in the bootstrap which are supposed
  99 ;;; to be generic functions but can't be early on.
 100 (defvar *!generic-function-fixups*
 101   '((add-method
 102      ((generic-function method)  ;lambda-list
 103       (standard-generic-function method) ;specializers
 104       real-add-method))          ;method-function
 105     (remove-method
 106      ((generic-function method)
 107       (standard-generic-function method)
 108       real-remove-method))
 109     (get-method
 110      ((generic-function qualifiers specializers &optional (errorp t))
 111       (standard-generic-function t t)
 112       real-get-method))
 113     (ensure-generic-function-using-class
 114      ((generic-function fun-name
 115                         &key generic-function-class environment
 116                         &allow-other-keys)
 117       (generic-function t)
 118       real-ensure-gf-using-class--generic-function)
 119      ((generic-function fun-name
 120                         &key generic-function-class environment
 121                         &allow-other-keys)
 122       (null t)
 123       real-ensure-gf-using-class--null))
 124     (make-method-lambda
 125      ((proto-generic-function proto-method lambda-expression environment)
 126       (standard-generic-function standard-method t t)
 127       real-make-method-lambda))
 128     (make-method-initargs-form
 129      ((proto-generic-function proto-method
 130                               lambda-expression
 131                               lambda-list environment)
 132       (standard-generic-function standard-method t t t)
 133       real-make-method-initargs-form))
 134     (compute-effective-method
 135      ((generic-function combin applicable-methods)
 136       (generic-function standard-method-combination t)
 137       standard-compute-effective-method))))
 138 \f
 139 (defmacro defgeneric (fun-name lambda-list &body options)
 140   (declare (type list lambda-list))
 141   (unless (legal-fun-name-p fun-name)
 142     (error 'simple-program-error
 143            :format-control "illegal generic function name ~S"
 144            :format-arguments (list fun-name)))
 145   (check-gf-lambda-list lambda-list)
 146   (let ((initargs ())
 147         (methods ()))
 148     (flet ((duplicate-option (name)
 149              (error 'simple-program-error
 150                     :format-control "The option ~S appears more than once."
 151                     :format-arguments (list name)))
 152            (expand-method-definition (qab) ; QAB = qualifiers, arglist, body
 153              (let* ((arglist-pos (position-if #'listp qab))
 154                     (arglist (elt qab arglist-pos))
 155                     (qualifiers (subseq qab 0 arglist-pos))
 156                     (body (nthcdr (1+ arglist-pos) qab)))
 157                `(push (defmethod ,fun-name ,@qualifiers ,arglist ,@body)
 158                       (generic-function-initial-methods (fdefinition ',fun-name))))))
 159       (macrolet ((initarg (key) `(getf initargs ,key)))
 160         (dolist (option options)
 161           (let ((car-option (car option)))
 162             (case car-option
 163               (declare
 164                (when (and
 165                       (consp (cadr option))
 166                       (member (first (cadr option))
 167                               ;; FIXME: this list is slightly weird.
 168                               ;; ANSI (on the DEFGENERIC page) in one
 169                               ;; place allows only OPTIMIZE; in
 170                               ;; another place gives this list of
 171                               ;; disallowed declaration specifiers.
 172                               ;; This seems to be the only place where
 173                               ;; the FUNCTION declaration is
 174                               ;; mentioned; TYPE seems to be missing.
 175                               ;; Very strange.  -- CSR, 2002-10-21
 176                               '(declaration ftype function
 177                                 inline notinline special)))
 178                  (error 'simple-program-error
 179                         :format-control "The declaration specifier ~S ~
 180                                          is not allowed inside DEFGENERIC."
 181                         :format-arguments (list (cadr option))))
 182                (push (cadr option) (initarg :declarations)))
 183               (:method-combination
 184                (when (initarg car-option)
 185                  (duplicate-option car-option))
 186                (unless (symbolp (cadr option))
 187                  (error 'simple-program-error
 188                         :format-control "METHOD-COMBINATION name not a ~
 189                                          symbol: ~S"
 190                         :format-arguments (list (cadr option))))
 191                (setf (initarg car-option)
 192                      `',(cdr option)))
 193               (:argument-precedence-order
 194                (let* ((required (parse-lambda-list lambda-list))
 195                       (supplied (cdr option)))
 196                  (unless (= (length required) (length supplied))
 197                    (error 'simple-program-error
 198                           :format-control "argument count discrepancy in ~
 199                                            :ARGUMENT-PRECEDENCE-ORDER clause."
 200                           :format-arguments nil))
 201                  (when (set-difference required supplied)
 202                    (error 'simple-program-error
 203                           :format-control "unequal sets for ~
 204                                            :ARGUMENT-PRECEDENCE-ORDER clause: ~
 205                                            ~S and ~S"
 206                           :format-arguments (list required supplied)))
 207                  (setf (initarg car-option)
 208                        `',(cdr option))))
 209               ((:documentation :generic-function-class :method-class)
 210                (unless (proper-list-of-length-p option 2)
 211                  (error "bad list length for ~S" option))
 212                (if (initarg car-option)
 213                    (duplicate-option car-option)
 214                    (setf (initarg car-option) `',(cadr option))))
 215               (:method
 216                (push (cdr option) methods))
 217               (t
 218                ;; ANSI requires that unsupported things must get a
 219                ;; PROGRAM-ERROR.
 220                (error 'simple-program-error
 221                       :format-control "unsupported option ~S"
 222                       :format-arguments (list option))))))
 223
 224         (when (initarg :declarations)
 225           (setf (initarg :declarations)
 226                 `',(initarg :declarations))))
 227       `(progn
 228          (eval-when (:compile-toplevel :load-toplevel :execute)
 229            (compile-or-load-defgeneric ',fun-name))
 230          (load-defgeneric ',fun-name ',lambda-list
 231                           (sb-c:source-location) ,@initargs)
 232         ,@(mapcar #'expand-method-definition methods)
 233         (fdefinition ',fun-name)))))
 234
 235 (defun compile-or-load-defgeneric (fun-name)
 236   (proclaim-as-fun-name fun-name)
 237   (note-name-defined fun-name :function)
 238   (unless (eq (info :function :where-from fun-name) :declared)
 239     (setf (info :function :where-from fun-name) :defined)
 240     (setf (info :function :type fun-name)
 241           (specifier-type 'function))))
 242
 243 (defun load-defgeneric (fun-name lambda-list source-location &rest initargs)
 244   (when (fboundp fun-name)
 245     (style-warn "redefining ~S in DEFGENERIC" fun-name)
 246     (let ((fun (fdefinition fun-name)))
 247       (when (generic-function-p fun)
 248         (loop for method in (generic-function-initial-methods fun)
 249               do (remove-method fun method))
 250         (setf (generic-function-initial-methods fun) '()))))
 251   (apply #'ensure-generic-function
 252          fun-name
 253          :lambda-list lambda-list
 254          :definition-source source-location
 255          initargs))
 256
 257 (define-condition generic-function-lambda-list-error
 258     (reference-condition simple-program-error)
 259   ()
 260   (:default-initargs :references (list '(:ansi-cl :section (3 4 2)))))
 261
 262 (defun check-gf-lambda-list (lambda-list)
 263   (flet ((ensure (arg ok)
 264            (unless ok
 265              (error 'generic-function-lambda-list-error
 266                     :format-control
 267                     "~@<invalid ~S ~_in the generic function lambda list ~S~:>"
 268                     :format-arguments (list arg lambda-list)))))
 269     (multiple-value-bind (required optional restp rest keyp keys allowp
 270                           auxp aux morep more-context more-count)
 271         (parse-lambda-list lambda-list)
 272       (declare (ignore required)) ; since they're no different in a gf ll
 273       (declare (ignore restp rest)) ; since they're no different in a gf ll
 274       (declare (ignore allowp)) ; since &ALLOW-OTHER-KEYS is fine either way
 275       (declare (ignore aux)) ; since we require AUXP=NIL
 276       (declare (ignore more-context more-count)) ; safely ignored unless MOREP
 277       ;; no defaults allowed for &OPTIONAL arguments
 278       (dolist (i optional)
 279         (ensure i (or (symbolp i)
 280                       (and (consp i) (symbolp (car i)) (null (cdr i))))))
 281       ;; no defaults allowed for &KEY arguments
 282       (when keyp
 283         (dolist (i keys)
 284           (ensure i (or (symbolp i)
 285                         (and (consp i)
 286                              (or (symbolp (car i))
 287                                  (and (consp (car i))
 288                                       (symbolp (caar i))
 289                                       (symbolp (cadar i))
 290                                       (null (cddar i))))
 291                              (null (cdr i)))))))
 292       ;; no &AUX allowed
 293       (when auxp
 294         (error "&AUX is not allowed in a generic function lambda list: ~S"
 295                lambda-list))
 296       ;; Oh, *puhlease*... not specifically as per section 3.4.2 of
 297       ;; the ANSI spec, but the CMU CL &MORE extension does not
 298       ;; belong here!
 299       (aver (not morep)))))
 300 \f
 301 (defmacro defmethod (&rest args &environment env)
 302   (multiple-value-bind (name qualifiers lambda-list body)
 303       (parse-defmethod args)
 304     (multiple-value-bind (proto-gf proto-method)
 305         (prototypes-for-make-method-lambda name)
 306       (expand-defmethod name
 307                         proto-gf
 308                         proto-method
 309                         qualifiers
 310                         lambda-list
 311                         body
 312                         env))))
 313
 314 (defun prototypes-for-make-method-lambda (name)
 315   (if (not (eq *boot-state* 'complete))
 316       (values nil nil)
 317       (let ((gf? (and (fboundp name)
 318                       (gdefinition name))))
 319         (if (or (null gf?)
 320                 (not (generic-function-p gf?)))
 321             (values (class-prototype (find-class 'standard-generic-function))
 322                     (class-prototype (find-class 'standard-method)))
 323             (values gf?
 324                     (class-prototype (or (generic-function-method-class gf?)
 325                                          (find-class 'standard-method))))))))
 326
 327 ;;; Take a name which is either a generic function name or a list specifying
 328 ;;; a SETF generic function (like: (SETF <generic-function-name>)). Return
 329 ;;; the prototype instance of the method-class for that generic function.
 330 ;;;
 331 ;;; If there is no generic function by that name, this returns the
 332 ;;; default value, the prototype instance of the class
 333 ;;; STANDARD-METHOD. This default value is also returned if the spec
 334 ;;; names an ordinary function or even a macro. In effect, this leaves
 335 ;;; the signalling of the appropriate error until load time.
 336 ;;;
 337 ;;; Note: During bootstrapping, this function is allowed to return NIL.
 338 (defun method-prototype-for-gf (name)
 339   (let ((gf? (and (fboundp name)
 340                   (gdefinition name))))
 341     (cond ((neq *boot-state* 'complete) nil)
 342           ((or (null gf?)
 343                (not (generic-function-p gf?)))          ; Someone else MIGHT
 344                                                         ; error at load time.
 345            (class-prototype (find-class 'standard-method)))
 346           (t
 347             (class-prototype (or (generic-function-method-class gf?)
 348                                  (find-class 'standard-method)))))))
 349 \f
 350 (defun expand-defmethod (name
 351                          proto-gf
 352                          proto-method
 353                          qualifiers
 354                          lambda-list
 355                          body
 356                          env)
 357   (multiple-value-bind (method-lambda unspecialized-lambda-list specializers)
 358       (add-method-declarations name qualifiers lambda-list body env)
 359     (multiple-value-bind (method-function-lambda initargs)
 360         (make-method-lambda proto-gf proto-method method-lambda env)
 361       (let ((initargs-form (make-method-initargs-form proto-gf
 362                                                       proto-method
 363                                                       method-function-lambda
 364                                                       initargs
 365                                                       env)))
 366         `(progn
 367           ;; Note: We could DECLAIM the ftype of the generic function
 368           ;; here, since ANSI specifies that we create it if it does
 369           ;; not exist. However, I chose not to, because I think it's
 370           ;; more useful to support a style of programming where every
 371           ;; generic function has an explicit DEFGENERIC and any typos
 372           ;; in DEFMETHODs are warned about. Otherwise
 373           ;;
 374           ;;   (DEFGENERIC FOO-BAR-BLETCH ((X T)))
 375           ;;   (DEFMETHOD FOO-BAR-BLETCH ((X HASH-TABLE)) ..)
 376           ;;   (DEFMETHOD FOO-BRA-BLETCH ((X SIMPLE-VECTOR)) ..)
 377           ;;   (DEFMETHOD FOO-BAR-BLETCH ((X VECTOR)) ..)
 378           ;;   (DEFMETHOD FOO-BAR-BLETCH ((X ARRAY)) ..)
 379           ;;   (DEFMETHOD FOO-BAR-BLETCH ((X LIST)) ..)
 380           ;;
 381           ;; compiles without raising an error and runs without
 382           ;; raising an error (since SIMPLE-VECTOR cases fall through
 383           ;; to VECTOR) but still doesn't do what was intended. I hate
 384           ;; that kind of bug (code which silently gives the wrong
 385           ;; answer), so we don't do a DECLAIM here. -- WHN 20000229
 386           ,(make-defmethod-form name qualifiers specializers
 387                                 unspecialized-lambda-list
 388                                 (if proto-method
 389                                     (class-name (class-of proto-method))
 390                                     'standard-method)
 391                                 initargs-form))))))
 392
 393 (defun interned-symbol-p (x)
 394   (and (symbolp x) (symbol-package x)))
 395
 396 (defun make-defmethod-form
 397     (name qualifiers specializers unspecialized-lambda-list
 398      method-class-name initargs-form)
 399   (let (fn
 400         fn-lambda)
 401     (if (and (interned-symbol-p (fun-name-block-name name))
 402              (every #'interned-symbol-p qualifiers)
 403              (every (lambda (s)
 404                       (if (consp s)
 405                           (and (eq (car s) 'eql)
 406                                (constantp (cadr s))
 407                                (let ((sv (constant-form-value (cadr s))))
 408                                  (or (interned-symbol-p sv)
 409                                      (integerp sv)
 410                                      (and (characterp sv)
 411                                           (standard-char-p sv)))))
 412                           (interned-symbol-p s)))
 413                     specializers)
 414              (consp initargs-form)
 415              (eq (car initargs-form) 'list*)
 416              (memq (cadr initargs-form) '(:function))
 417              (consp (setq fn (caddr initargs-form)))
 418              (eq (car fn) 'function)
 419              (consp (setq fn-lambda (cadr fn)))
 420              (eq (car fn-lambda) 'lambda))
 421         (let* ((specls (mapcar (lambda (specl)
 422                                  (if (consp specl)
 423                                      `(,(car specl) ,(eval (cadr specl)))
 424                                    specl))
 425                                specializers))
 426                (mname `(,(if (eq (cadr initargs-form) :function)
 427                              'slow-method 'fast-method)
 428                         ,name ,@qualifiers ,specls)))
 429           `(progn
 430              (defun ,mname ,(cadr fn-lambda)
 431                ,@(cddr fn-lambda))
 432              ,(make-defmethod-form-internal
 433                name qualifiers `',specls
 434                unspecialized-lambda-list method-class-name
 435                `(list* ,(cadr initargs-form)
 436                        #',mname
 437                        ,@(cdddr initargs-form)))))
 438         (make-defmethod-form-internal
 439          name qualifiers
 440          `(list ,@(mapcar (lambda (specializer)
 441                             (if (consp specializer)
 442                                 ``(,',(car specializer)
 443                                       ,,(cadr specializer))
 444                                 `',specializer))
 445                           specializers))
 446          unspecialized-lambda-list
 447          method-class-name
 448          initargs-form))))
 449
 450 (defun make-defmethod-form-internal
 451     (name qualifiers specializers-form unspecialized-lambda-list
 452      method-class-name initargs-form)
 453   `(load-defmethod
 454     ',method-class-name
 455     ',name
 456     ',qualifiers
 457     ,specializers-form
 458     ',unspecialized-lambda-list
 459     ,initargs-form
 460     (sb-c:source-location)))
 461
 462 (defmacro make-method-function (method-lambda &environment env)
 463   (make-method-function-internal method-lambda env))
 464
 465 (defun make-method-function-internal (method-lambda &optional env)
 466   (multiple-value-bind (proto-gf proto-method)
 467       (prototypes-for-make-method-lambda nil)
 468     (multiple-value-bind (method-function-lambda initargs)
 469         (make-method-lambda proto-gf proto-method method-lambda env)
 470       (make-method-initargs-form proto-gf
 471                                  proto-method
 472                                  method-function-lambda
 473                                  initargs
 474                                  env))))
 475
 476 (defun add-method-declarations (name qualifiers lambda-list body env)
 477   (declare (ignore env))
 478   (multiple-value-bind (parameters unspecialized-lambda-list specializers)
 479       (parse-specialized-lambda-list lambda-list)
 480     (multiple-value-bind (real-body declarations documentation)
 481         (parse-body body)
 482       (values `(lambda ,unspecialized-lambda-list
 483                  ,@(when documentation `(,documentation))
 484                  ;; (Old PCL code used a somewhat different style of
 485                  ;; list for %METHOD-NAME values. Our names use
 486                  ;; ,@QUALIFIERS instead of ,QUALIFIERS so that the
 487                  ;; method names look more like what you see in a
 488                  ;; DEFMETHOD form.)
 489                  ;;
 490                  ;; FIXME: As of sbcl-0.7.0.6, code elsewhere, at
 491                  ;; least the code to set up named BLOCKs around the
 492                  ;; bodies of methods, depends on the function's base
 493                  ;; name being the first element of the %METHOD-NAME
 494                  ;; list. It would be good to remove this dependency,
 495                  ;; perhaps by building the BLOCK here, or by using
 496                  ;; another declaration (e.g. %BLOCK-NAME), so that
 497                  ;; our method debug names are free to have any format,
 498                  ;; e.g. (:METHOD PRINT-OBJECT :AROUND (CLOWN T)).
 499                  ;;
 500                  ;; Further, as of sbcl-0.7.9.10, the code to
 501                  ;; implement NO-NEXT-METHOD is coupled to the form of
 502                  ;; this declaration; see the definition of
 503                  ;; CALL-NO-NEXT-METHOD (and the passing of
 504                  ;; METHOD-NAME-DECLARATION arguments around the
 505                  ;; various CALL-NEXT-METHOD logic).
 506                  (declare (%method-name (,name
 507                                          ,@qualifiers
 508                                          ,specializers)))
 509                  (declare (%method-lambda-list ,@lambda-list))
 510                  ,@declarations
 511                  ,@real-body)
 512               unspecialized-lambda-list specializers))))
 513
 514 (defun real-make-method-initargs-form (proto-gf proto-method
 515                                        method-lambda initargs env)
 516   (declare (ignore proto-gf proto-method))
 517   (unless (and (consp method-lambda)
 518                (eq (car method-lambda) 'lambda))
 519     (error "The METHOD-LAMBDA argument to MAKE-METHOD-FUNCTION, ~S, ~
 520             is not a lambda form."
 521            method-lambda))
 522   (make-method-initargs-form-internal method-lambda initargs env))
 523
 524 (unless (fboundp 'make-method-initargs-form)
 525   (setf (gdefinition 'make-method-initargs-form)
 526         (symbol-function 'real-make-method-initargs-form)))
 527
 528 (defun real-make-method-lambda (proto-gf proto-method method-lambda env)
 529   (declare (ignore proto-gf proto-method))
 530   (make-method-lambda-internal method-lambda env))
 531
 532 ;;; a helper function for creating Python-friendly type declarations
 533 ;;; in DEFMETHOD forms
 534 (defun parameter-specializer-declaration-in-defmethod (parameter specializer)
 535   (cond ((and (consp specializer)
 536               (eq (car specializer) 'eql))
 537          ;; KLUDGE: ANSI, in its wisdom, says that
 538          ;; EQL-SPECIALIZER-FORMs in EQL specializers are evaluated at
 539          ;; DEFMETHOD expansion time. Thus, although one might think
 540          ;; that in
 541          ;;   (DEFMETHOD FOO ((X PACKAGE)
 542          ;;                   (Y (EQL 12))
 543          ;;      ..))
 544          ;; the PACKAGE and (EQL 12) forms are both parallel type
 545          ;; names, they're not, as is made clear when you do
 546          ;;   (DEFMETHOD FOO ((X PACKAGE)
 547          ;;                   (Y (EQL 'BAR)))
 548          ;;     ..)
 549          ;; where Y needs to be a symbol named "BAR", not some cons
 550          ;; made by (CONS 'QUOTE 'BAR). I.e. when the
 551          ;; EQL-SPECIALIZER-FORM is (EQL 'X), it requires an argument
 552          ;; to be of type (EQL X). It'd be easy to transform one to
 553          ;; the other, but it'd be somewhat messier to do so while
 554          ;; ensuring that the EQL-SPECIALIZER-FORM is only EVAL'd
 555          ;; once. (The new code wouldn't be messy, but it'd require a
 556          ;; big transformation of the old code.) So instead we punt.
 557          ;; -- WHN 20000610
 558          '(ignorable))
 559         ((member specializer
 560                  ;; KLUDGE: For some low-level implementation
 561                  ;; classes, perhaps because of some problems related
 562                  ;; to the incomplete integration of PCL into SBCL's
 563                  ;; type system, some specializer classes can't be
 564                  ;; declared as argument types. E.g.
 565                  ;;   (DEFMETHOD FOO ((X SLOT-OBJECT))
 566                  ;;     (DECLARE (TYPE SLOT-OBJECT X))
 567                  ;;     ..)
 568                  ;; loses when
 569                  ;;   (DEFSTRUCT BAR A B)
 570                  ;;   (FOO (MAKE-BAR))
 571                  ;; perhaps because of the way that STRUCTURE-OBJECT
 572                  ;; inherits both from SLOT-OBJECT and from
 573                  ;; SB-KERNEL:INSTANCE. In an effort to sweep such
 574                  ;; problems under the rug, we exclude these problem
 575                  ;; cases by blacklisting them here. -- WHN 2001-01-19
 576                  (list 'slot-object #+nil (find-class 'slot-object)))
 577          '(ignorable))
 578         ((not (eq *boot-state* 'complete))
 579          ;; KLUDGE: PCL, in its wisdom, sometimes calls methods with
 580          ;; types which don't match their specializers. (Specifically,
 581          ;; it calls ENSURE-CLASS-USING-CLASS (T NULL) with a non-NULL
 582          ;; second argument.) Hopefully it only does this kind of
 583          ;; weirdness when bootstrapping.. -- WHN 20000610
 584          '(ignorable))
 585         ((typep specializer 'eql-specializer)
 586          `(type (eql ,(eql-specializer-object specializer)) ,parameter))
 587         ((var-globally-special-p parameter)
 588          ;; KLUDGE: Don't declare types for global special variables
 589          ;; -- our rebinding magic for SETQ cases don't work right
 590          ;; there.
 591          ;;
 592          ;; FIXME: It would be better to detect the SETQ earlier and
 593          ;; skip declarations for specials only when needed, not
 594          ;; always.
 595          ;;
 596          ;; --NS 2004-10-14
 597          '(ignorable))
 598         (t
 599          ;; Otherwise, we can usually make Python very happy.
 600          ;;
 601          ;; KLUDGE: Since INFO doesn't work right for class objects here,
 602          ;; and they are valid specializers, see if the specializer is
 603          ;; a named class, and use the name in that case -- otherwise
 604          ;; the class instance is ok, since info will just return NIL, NIL.
 605          ;;
 606          ;; We still need to deal with the class case too, but at
 607          ;; least #.(find-class 'integer) and integer as equivalent
 608          ;; specializers with this.
 609          (let* ((specializer (if (and (typep specializer 'class)
 610                                       (let ((name (class-name specializer)))
 611                                         (and name (symbolp name)
 612                                              (eq specializer (find-class name nil)))))
 613                                  (class-name specializer)
 614                                  specializer))
 615                 (kind (info :type :kind specializer)))
 616
 617            (flet ((specializer-class ()
 618                     (if (typep specializer 'class)
 619                         specializer
 620                         (find-class specializer nil))))
 621              (ecase kind
 622                ((:primitive) `(type ,specializer ,parameter))
 623                ((:defined)
 624                 (let ((class (specializer-class)))
 625                   ;; CLASS can be null here if the user has erroneously
 626                  ;; tried to use a defined type as a specializer; it
 627                  ;; can be a non-BUILT-IN-CLASS if the user defines a
 628                  ;; type and calls (SETF FIND-CLASS) in a consistent
 629                  ;; way.
 630                  (when (and class (typep class 'built-in-class))
 631                    `(type ,specializer ,parameter))))
 632               ((:instance nil)
 633                (let ((class (specializer-class)))
 634                  (cond
 635                    (class
 636                     (if (typep class '(or built-in-class structure-class))
 637                         `(type ,specializer ,parameter)
 638                         ;; don't declare CLOS classes as parameters;
 639                         ;; it's too expensive.
 640                         '(ignorable)))
 641                    (t
 642                     ;; we can get here, and still not have a failure
 643                     ;; case, by doing MOP programming like (PROGN
 644                     ;; (ENSURE-CLASS 'FOO) (DEFMETHOD BAR ((X FOO))
 645                     ;; ...)).  Best to let the user know we haven't
 646                     ;; been able to extract enough information:
 647                     (style-warn
 648                      "~@<can't find type for presumed class ~S in ~S.~@:>"
 649                      specializer
 650                      'parameter-specializer-declaration-in-defmethod)
 651                     '(ignorable)))))
 652               ((:forthcoming-defclass-type)
 653                '(ignorable))))))))
 654
 655 (defun make-method-lambda-internal (method-lambda &optional env)
 656   (unless (and (consp method-lambda) (eq (car method-lambda) 'lambda))
 657     (error "The METHOD-LAMBDA argument to MAKE-METHOD-LAMBDA, ~S, ~
 658             is not a lambda form."
 659            method-lambda))
 660   (multiple-value-bind (real-body declarations documentation)
 661       (parse-body (cddr method-lambda))
 662     (let* ((name-decl (get-declaration '%method-name declarations))
 663            (sll-decl (get-declaration '%method-lambda-list declarations))
 664            (method-name (when (consp name-decl) (car name-decl)))
 665            (generic-function-name (when method-name (car method-name)))
 666            (specialized-lambda-list (or sll-decl (cadr method-lambda))))
 667       (multiple-value-bind (parameters lambda-list specializers)
 668           (parse-specialized-lambda-list specialized-lambda-list)
 669         (let* ((required-parameters
 670                 (mapcar (lambda (r s) (declare (ignore s)) r)
 671                         parameters
 672                         specializers))
 673                (slots (mapcar #'list required-parameters))
 674                (calls (list nil))
 675                (class-declarations
 676                 `(declare
 677                   ;; These declarations seem to be used by PCL to pass
 678                   ;; information to itself; when I tried to delete 'em
 679                   ;; ca. 0.6.10 it didn't work. I'm not sure how
 680                   ;; they work, but note the (VAR-DECLARATION '%CLASS ..)
 681                   ;; expression in CAN-OPTIMIZE-ACCESS1. -- WHN 2000-12-30
 682                   ,@(remove nil
 683                             (mapcar (lambda (a s) (and (symbolp s)
 684                                                        (neq s t)
 685                                                        `(%class ,a ,s)))
 686                                     parameters
 687                                     specializers))
 688                   ;; These TYPE declarations weren't in the original
 689                   ;; PCL code, but the Python compiler likes them a
 690                   ;; lot. (We're telling the compiler about our
 691                   ;; knowledge of specialized argument types so that
 692                   ;; it can avoid run-time type dispatch overhead,
 693                   ;; which can be a huge win for Python.)
 694                   ;;
 695                   ;; KLUDGE: when I tried moving these to
 696                   ;; ADD-METHOD-DECLARATIONS, things broke.  No idea
 697                   ;; why.  -- CSR, 2004-06-16
 698                   ,@(mapcar #'parameter-specializer-declaration-in-defmethod
 699                             parameters
 700                             specializers)))
 701                (method-lambda
 702                 ;; Remove the documentation string and insert the
 703                 ;; appropriate class declarations. The documentation
 704                 ;; string is removed to make it easy for us to insert
 705                 ;; new declarations later, they will just go after the
 706                 ;; CADR of the method lambda. The class declarations
 707                 ;; are inserted to communicate the class of the method's
 708                 ;; arguments to the code walk.
 709                 `(lambda ,lambda-list
 710                    ;; The default ignorability of method parameters
 711                    ;; doesn't seem to be specified by ANSI. PCL had
 712                    ;; them basically ignorable but was a little
 713                    ;; inconsistent. E.g. even though the two
 714                    ;; method definitions
 715                    ;;   (DEFMETHOD FOO ((X T) (Y T)) "Z")
 716                    ;;   (DEFMETHOD FOO ((X T) Y) "Z")
 717                    ;; are otherwise equivalent, PCL treated Y as
 718                    ;; ignorable in the first definition but not in the
 719                    ;; second definition. We make all required
 720                    ;; parameters ignorable as a way of systematizing
 721                    ;; the old PCL behavior. -- WHN 2000-11-24
 722                    (declare (ignorable ,@required-parameters))
 723                    ,class-declarations
 724                    ,@declarations
 725                    (block ,(fun-name-block-name generic-function-name)
 726                      ,@real-body)))
 727                (constant-value-p (and (null (cdr real-body))
 728                                       (constantp (car real-body))))
 729                (constant-value (and constant-value-p
 730                                     (constant-form-value (car real-body))))
 731                (plist (and constant-value-p
 732                            (or (typep constant-value
 733                                       '(or number character))
 734                                (and (symbolp constant-value)
 735                                     (symbol-package constant-value)))
 736                            (list :constant-value constant-value)))
 737                (applyp (dolist (p lambda-list nil)
 738                          (cond ((memq p '(&optional &rest &key))
 739                                 (return t))
 740                                ((eq p '&aux)
 741                                 (return nil))))))
 742           (multiple-value-bind
 743                 (walked-lambda call-next-method-p closurep
 744                                next-method-p-p setq-p)
 745               (walk-method-lambda method-lambda
 746                                   required-parameters
 747                                   env
 748                                   slots
 749                                   calls)
 750             (multiple-value-bind (walked-lambda-body
 751                                   walked-declarations
 752                                   walked-documentation)
 753                 (parse-body (cddr walked-lambda))
 754               (declare (ignore walked-documentation))
 755               (when (some #'cdr slots)
 756                 (multiple-value-bind (slot-name-lists call-list)
 757                     (slot-name-lists-from-slots slots calls)
 758                   (setq plist
 759                         `(,@(when slot-name-lists
 760                                   `(:slot-name-lists ,slot-name-lists))
 761                           ,@(when call-list
 762                                   `(:call-list ,call-list))
 763                           ,@plist))
 764                   (setq walked-lambda-body
 765                         `((pv-binding (,required-parameters
 766                                        ,slot-name-lists
 767                                        (load-time-value
 768                                         (intern-pv-table
 769                                          :slot-name-lists ',slot-name-lists
 770                                          :call-list ',call-list)))
 771                            ,@walked-lambda-body)))))
 772               (when (and (memq '&key lambda-list)
 773                          (not (memq '&allow-other-keys lambda-list)))
 774                 (let ((aux (memq '&aux lambda-list)))
 775                   (setq lambda-list (nconc (ldiff lambda-list aux)
 776                                            (list '&allow-other-keys)
 777                                            aux))))
 778               (values `(lambda (.method-args. .next-methods.)
 779                          (simple-lexical-method-functions
 780                              (,lambda-list .method-args. .next-methods.
 781                                            :call-next-method-p
 782                                            ,call-next-method-p
 783                                            :next-method-p-p ,next-method-p-p
 784                                            :setq-p ,setq-p
 785                                            ;; we need to pass this along
 786                                            ;; so that NO-NEXT-METHOD can
 787                                            ;; be given a suitable METHOD
 788                                            ;; argument; we need the
 789                                            ;; QUALIFIERS and SPECIALIZERS
 790                                            ;; inside the declaration to
 791                                            ;; give to FIND-METHOD.
 792                                            :method-name-declaration ,name-decl
 793                                            :closurep ,closurep
 794                                            :applyp ,applyp)
 795                            ,@walked-declarations
 796                            ,@walked-lambda-body))
 797                       `(,@(when plist
 798                                 `(plist ,plist))
 799                           ,@(when documentation
 800                                   `(:documentation ,documentation)))))))))))
 801
 802 (unless (fboundp 'make-method-lambda)
 803   (setf (gdefinition 'make-method-lambda)
 804         (symbol-function 'real-make-method-lambda)))
 805
 806 (defmacro simple-lexical-method-functions ((lambda-list
 807                                             method-args
 808                                             next-methods
 809                                             &rest lmf-options)
 810                                            &body body)
 811   `(progn
 812      ,method-args ,next-methods
 813      (bind-simple-lexical-method-functions (,method-args ,next-methods
 814                                                          ,lmf-options)
 815          (bind-args (,lambda-list ,method-args)
 816            ,@body))))
 817
 818 (defmacro fast-lexical-method-functions ((lambda-list
 819                                           next-method-call
 820                                           args
 821                                           rest-arg
 822                                           &rest lmf-options)
 823                                          &body body)
 824   `(bind-fast-lexical-method-functions (,args ,rest-arg ,next-method-call ,lmf-options)
 825      (bind-args (,(nthcdr (length args) lambda-list) ,rest-arg)
 826        ,@body)))
 827
 828 (defmacro bind-simple-lexical-method-functions
 829     ((method-args next-methods (&key call-next-method-p next-method-p-p setq-p
 830                                      closurep applyp method-name-declaration))
 831      &body body
 832      &environment env)
 833   (if (not (or call-next-method-p setq-p closurep next-method-p-p applyp))
 834       `(locally
 835            ,@body)
 836       `(let ((.next-method. (car ,next-methods))
 837              (,next-methods (cdr ,next-methods)))
 838          (declare (ignorable .next-method. ,next-methods))
 839          (flet (,@(and call-next-method-p
 840                        `((call-next-method
 841                           (&rest cnm-args)
 842                           ,@(if (safe-code-p env)
 843                                 `((%check-cnm-args cnm-args
 844                                                    ,method-args
 845                                                    ',method-name-declaration))
 846                                 nil)
 847                           (if .next-method.
 848                               (funcall (if (std-instance-p .next-method.)
 849                                            (method-function .next-method.)
 850                                            .next-method.) ; for early methods
 851                                        (or cnm-args ,method-args)
 852                                        ,next-methods)
 853                               (apply #'call-no-next-method
 854                                      ',method-name-declaration
 855                                      (or cnm-args ,method-args))))))
 856                 ,@(and next-method-p-p
 857                        '((next-method-p ()
 858                           (not (null .next-method.))))))
 859            ,@body))))
 860
 861 (defun call-no-next-method (method-name-declaration &rest args)
 862   (destructuring-bind (name) method-name-declaration
 863     (destructuring-bind (name &rest qualifiers-and-specializers) name
 864       ;; KLUDGE: inefficient traversal, but hey.  This should only
 865       ;; happen on the slow error path anyway.
 866       (let* ((qualifiers (butlast qualifiers-and-specializers))
 867              (specializers (car (last qualifiers-and-specializers)))
 868              (method (find-method (gdefinition name) qualifiers specializers)))
 869         (apply #'no-next-method
 870                (method-generic-function method)
 871                method
 872                args)))))
 873
 874 (defstruct (method-call (:copier nil))
 875   (function #'identity :type function)
 876   call-method-args)
 877 (defstruct (constant-method-call (:copier nil) (:include method-call))
 878   value)
 879
 880 #-sb-fluid (declaim (sb-ext:freeze-type method-call))
 881
 882 (defmacro invoke-method-call1 (function args cm-args)
 883   `(let ((.function. ,function)
 884          (.args. ,args)
 885          (.cm-args. ,cm-args))
 886      (if (and .cm-args. (null (cdr .cm-args.)))
 887          (funcall .function. .args. (car .cm-args.))
 888          (apply .function. .args. .cm-args.))))
 889
 890 (defmacro invoke-method-call (method-call restp &rest required-args+rest-arg)
 891   `(invoke-method-call1 (method-call-function ,method-call)
 892                         ,(if restp
 893                              `(list* ,@required-args+rest-arg)
 894                              `(list ,@required-args+rest-arg))
 895                         (method-call-call-method-args ,method-call)))
 896
 897 (defstruct (fast-method-call (:copier nil))
 898   (function #'identity :type function)
 899   pv-cell
 900   next-method-call
 901   arg-info)
 902 (defstruct (constant-fast-method-call
 903              (:copier nil) (:include fast-method-call))
 904   value)
 905
 906 #-sb-fluid (declaim (sb-ext:freeze-type fast-method-call))
 907
 908 (defmacro fmc-funcall (fn pv-cell next-method-call &rest args)
 909   `(funcall ,fn ,pv-cell ,next-method-call ,@args))
 910
 911 (defmacro invoke-fast-method-call (method-call &rest required-args+rest-arg)
 912   `(fmc-funcall (fast-method-call-function ,method-call)
 913                 (fast-method-call-pv-cell ,method-call)
 914                 (fast-method-call-next-method-call ,method-call)
 915                 ,@required-args+rest-arg))
 916
 917 (defstruct (fast-instance-boundp (:copier nil))
 918   (index 0 :type fixnum))
 919
 920 #-sb-fluid (declaim (sb-ext:freeze-type fast-instance-boundp))
 921
 922 (eval-when (:compile-toplevel :load-toplevel :execute)
 923   (defvar *allow-emf-call-tracing-p* nil)
 924   (defvar *enable-emf-call-tracing-p* #-sb-show nil #+sb-show t))
 925 \f
 926 ;;;; effective method functions
 927
 928 (defvar *emf-call-trace-size* 200)
 929 (defvar *emf-call-trace* nil)
 930 (defvar *emf-call-trace-index* 0)
 931
 932 ;;; This function was in the CMU CL version of PCL (ca Debian 2.4.8)
 933 ;;; without explanation. It appears to be intended for debugging, so
 934 ;;; it might be useful someday, so I haven't deleted it.
 935 ;;; But it isn't documented and isn't used for anything now, so
 936 ;;; I've conditionalized it out of the base system. -- WHN 19991213
 937 #+sb-show
 938 (defun show-emf-call-trace ()
 939   (when *emf-call-trace*
 940     (let ((j *emf-call-trace-index*)
 941           (*enable-emf-call-tracing-p* nil))
 942       (format t "~&(The oldest entries are printed first)~%")
 943       (dotimes-fixnum (i *emf-call-trace-size*)
 944         (let ((ct (aref *emf-call-trace* j)))
 945           (when ct (print ct)))
 946         (incf j)
 947         (when (= j *emf-call-trace-size*)
 948           (setq j 0))))))
 949
 950 (defun trace-emf-call-internal (emf format args)
 951   (unless *emf-call-trace*
 952     (setq *emf-call-trace* (make-array *emf-call-trace-size*)))
 953   (setf (aref *emf-call-trace* *emf-call-trace-index*)
 954         (list* emf format args))
 955   (incf *emf-call-trace-index*)
 956   (when (= *emf-call-trace-index* *emf-call-trace-size*)
 957     (setq *emf-call-trace-index* 0)))
 958
 959 (defmacro trace-emf-call (emf format args)
 960   (when *allow-emf-call-tracing-p*
 961     `(when *enable-emf-call-tracing-p*
 962        (trace-emf-call-internal ,emf ,format ,args))))
 963
 964 (defmacro invoke-effective-method-function-fast
 965     (emf restp &rest required-args+rest-arg)
 966   `(progn
 967      (trace-emf-call ,emf ,restp (list ,@required-args+rest-arg))
 968      (invoke-fast-method-call ,emf ,@required-args+rest-arg)))
 969
 970 (defmacro invoke-effective-method-function (emf-form restp
 971                                             &rest required-args+rest-arg)
 972   (unless (constantp restp)
 973     (error "The RESTP argument is not constant."))
 974   ;; FIXME: The RESTP handling here is confusing and maybe slightly
 975   ;; broken if RESTP evaluates to a non-self-evaluating form. E.g. if
 976   ;;   (INVOKE-EFFECTIVE-METHOD-FUNCTION EMF '(ERROR "gotcha") ...)
 977   ;; then TRACE-EMF-CALL-CALL-INTERNAL might die on a gotcha error.
 978   (setq restp (constant-form-value restp))
 979   (with-unique-names (emf)
 980     `(let ((,emf ,emf-form))
 981       (trace-emf-call ,emf ,restp (list ,@required-args+rest-arg))
 982       (cond ((typep ,emf 'fast-method-call)
 983              (invoke-fast-method-call ,emf ,@required-args+rest-arg))
 984             ;; "What," you may wonder, "do these next two clauses do?"
 985             ;; In that case, you are not a PCL implementor, for they
 986             ;; considered this to be self-documenting.:-| Or CSR, for
 987             ;; that matter, since he can also figure it out by looking
 988             ;; at it without breaking stride. For the rest of us,
 989             ;; though: From what the code is doing with .SLOTS. and
 990             ;; whatnot, evidently it's implementing SLOT-VALUEish and
 991             ;; GET-SLOT-VALUEish things. Then we can reason backwards
 992             ;; and conclude that setting EMF to a FIXNUM is an
 993             ;; optimized way to represent these slot access operations.
 994             ,@(when (and (null restp) (= 1 (length required-args+rest-arg)))
 995                     `(((typep ,emf 'fixnum)
 996                        (let* ((.slots. (get-slots-or-nil
 997                                         ,(car required-args+rest-arg)))
 998                               (value (when .slots. (clos-slots-ref .slots. ,emf))))
 999                          (if (eq value +slot-unbound+)
1000                              (slot-unbound-internal ,(car required-args+rest-arg)
1001                                                     ,emf)
1002                              value)))))
1003             ,@(when (and (null restp) (= 2 (length required-args+rest-arg)))
1004                     `(((typep ,emf 'fixnum)
1005                        (let ((.new-value. ,(car required-args+rest-arg))
1006                              (.slots. (get-slots-or-nil
1007                                        ,(cadr required-args+rest-arg))))
1008                          (when .slots.
1009                            (setf (clos-slots-ref .slots. ,emf) .new-value.))))))
1010             ;; (In cmucl-2.4.8 there was a commented-out third ,@(WHEN
1011             ;; ...) clause here to handle SLOT-BOUNDish stuff. Since
1012             ;; there was no explanation and presumably the code is 10+
1013             ;; years stale, I simply deleted it. -- WHN)
1014             (t
1015              (etypecase ,emf
1016                (method-call
1017                 (invoke-method-call ,emf ,restp ,@required-args+rest-arg))
1018                (function
1019                 ,(if restp
1020                      `(apply (the function ,emf) ,@required-args+rest-arg)
1021                      `(funcall (the function ,emf)
1022                                ,@required-args+rest-arg)))))))))
1023
1024 (defun invoke-emf (emf args)
1025   (trace-emf-call emf t args)
1026   (etypecase emf
1027     (fast-method-call
1028      (let* ((arg-info (fast-method-call-arg-info emf))
1029             (restp (cdr arg-info))
1030             (nreq (car arg-info)))
1031        (if restp
1032            (let* ((rest-args (nthcdr nreq args))
1033                   (req-args (ldiff args rest-args)))
1034              (apply (fast-method-call-function emf)
1035                     (fast-method-call-pv-cell emf)
1036                     (fast-method-call-next-method-call emf)
1037                     (nconc req-args (list rest-args))))
1038            (cond ((null args)
1039                   (if (eql nreq 0)
1040                       (invoke-fast-method-call emf)
1041                       (error 'simple-program-error
1042                              :format-control "invalid number of arguments: 0"
1043                              :format-arguments nil)))
1044                  ((null (cdr args))
1045                   (if (eql nreq 1)
1046                       (invoke-fast-method-call emf (car args))
1047                       (error 'simple-program-error
1048                              :format-control "invalid number of arguments: 1"
1049                              :format-arguments nil)))
1050                  ((null (cddr args))
1051                   (if (eql nreq 2)
1052                       (invoke-fast-method-call emf (car args) (cadr args))
1053                       (error 'simple-program-error
1054                              :format-control "invalid number of arguments: 2"
1055                              :format-arguments nil)))
1056                  (t
1057                   (apply (fast-method-call-function emf)
1058                          (fast-method-call-pv-cell emf)
1059                          (fast-method-call-next-method-call emf)
1060                          args))))))
1061     (method-call
1062      (apply (method-call-function emf)
1063             args
1064             (method-call-call-method-args emf)))
1065     (fixnum
1066      (cond ((null args)
1067             (error 'simple-program-error
1068                    :format-control "invalid number of arguments: 0"
1069                    :format-arguments nil))
1070            ((null (cdr args))
1071             (let* ((slots (get-slots (car args)))
1072                    (value (clos-slots-ref slots emf)))
1073               (if (eq value +slot-unbound+)
1074                   (slot-unbound-internal (car args) emf)
1075                   value)))
1076            ((null (cddr args))
1077             (setf (clos-slots-ref (get-slots (cadr args)) emf)
1078                   (car args)))
1079            (t (error 'simple-program-error
1080                      :format-control "invalid number of arguments"
1081                      :format-arguments nil))))
1082     (fast-instance-boundp
1083      (if (or (null args) (cdr args))
1084          (error 'simple-program-error
1085                 :format-control "invalid number of arguments"
1086                 :format-arguments nil)
1087          (let ((slots (get-slots (car args))))
1088            (not (eq (clos-slots-ref slots (fast-instance-boundp-index emf))
1089                     +slot-unbound+)))))
1090     (function
1091      (apply emf args))))
1092 \f
1093
1094 (defmacro fast-narrowed-emf (emf)
1095   ;; INVOKE-EFFECTIVE-METHOD-FUNCTION has code in it to dispatch on
1096   ;; the possibility that EMF might be of type FIXNUM (as an optimized
1097   ;; representation of a slot accessor). But as far as I (WHN
1098   ;; 2002-06-11) can tell, it's impossible for such a representation
1099   ;; to end up as .NEXT-METHOD-CALL. By reassuring INVOKE-E-M-F that
1100   ;; when called from this context it needn't worry about the FIXNUM
1101   ;; case, we can keep those cases from being compiled, which is good
1102   ;; both because it saves bytes and because it avoids annoying type
1103   ;; mismatch compiler warnings.
1104   ;;
1105   ;; KLUDGE: In sbcl-0.7.4.29, the compiler's type system isn't smart
1106   ;; enough about NOT and intersection types to benefit from a (NOT
1107   ;; FIXNUM) declaration here. -- WHN 2002-06-12 (FIXME: maybe it is
1108   ;; now... -- CSR, 2003-06-07)
1109   ;;
1110   ;; FIXME: Might the FUNCTION type be omittable here, leaving only
1111   ;; METHOD-CALLs? Failing that, could this be documented somehow?
1112   ;; (It'd be nice if the types involved could be understood without
1113   ;; solving the halting problem.)
1114   `(the (or function method-call fast-method-call)
1115      ,emf))
1116
1117 (defmacro fast-call-next-method-body ((args next-method-call rest-arg)
1118                                       method-name-declaration
1119                                       cnm-args)
1120   `(if ,next-method-call
1121        ,(let ((call `(invoke-effective-method-function
1122                       (fast-narrowed-emf ,next-method-call)
1123                       ,(not (null rest-arg))
1124                       ,@args
1125                       ,@(when rest-arg `(,rest-arg)))))
1126              `(if ,cnm-args
1127                   (bind-args ((,@args
1128                                ,@(when rest-arg
1129                                        `(&rest ,rest-arg)))
1130                               ,cnm-args)
1131                     ,call)
1132                   ,call))
1133        (call-no-next-method ',method-name-declaration
1134                             ,@args
1135                             ,@(when rest-arg
1136                                     `(,rest-arg)))))
1137
1138 (defmacro bind-fast-lexical-method-functions
1139     ((args rest-arg next-method-call (&key
1140                                       call-next-method-p
1141                                       setq-p
1142                                       method-name-declaration
1143                                       next-method-p-p
1144                                       closurep
1145                                       applyp))
1146      &body body
1147      &environment env)
1148   (let* ((all-params (append args (when rest-arg (list rest-arg))))
1149          (rebindings (when (or setq-p call-next-method-p)
1150                        (mapcar (lambda (x) (list x x)) all-params))))
1151     (if (not (or call-next-method-p setq-p closurep next-method-p-p applyp))
1152         `(locally
1153              ,@body)
1154         `(flet (,@(when call-next-method-p
1155                         `((call-next-method (&rest cnm-args)
1156                            (declare (muffle-conditions code-deletion-note))
1157                            ,@(if (safe-code-p env)
1158                                  `((%check-cnm-args cnm-args (list ,@args)
1159                                                     ',method-name-declaration))
1160                                  nil)
1161                            (fast-call-next-method-body (,args
1162                                                         ,next-method-call
1163                                                         ,rest-arg)
1164                                                         ,method-name-declaration
1165                                                        cnm-args))))
1166                 ,@(when next-method-p-p
1167                         `((next-method-p
1168                            ()
1169                            (not (null ,next-method-call))))))
1170            (let ,rebindings
1171              ,@(when rebindings `((declare (ignorable ,@all-params))))
1172              ,@body)))))
1173
1174 ;;; CMUCL comment (Gerd Moellmann):
1175 ;;;
1176 ;;; The standard says it's an error if CALL-NEXT-METHOD is called with
1177 ;;; arguments, and the set of methods applicable to those arguments is
1178 ;;; different from the set of methods applicable to the original
1179 ;;; method arguments.  (According to Barry Margolin, this rule was
1180 ;;; probably added to ensure that before and around methods are always
1181 ;;; run before primary methods.)
1182 ;;;
1183 ;;; This could be optimized for the case that the generic function
1184 ;;; doesn't have hairy methods, does have standard method combination,
1185 ;;; is a standard generic function, there are no methods defined on it
1186 ;;; for COMPUTE-APPLICABLE-METHODS and probably a lot more of such
1187 ;;; preconditions.  That looks hairy and is probably not worth it,
1188 ;;; because this check will never be fast.
1189 (defun %check-cnm-args (cnm-args orig-args method-name-declaration)
1190   (when cnm-args
1191     (let* ((gf (fdefinition (caar method-name-declaration)))
1192            (omethods (compute-applicable-methods gf orig-args))
1193            (nmethods (compute-applicable-methods gf cnm-args)))
1194       (unless (equal omethods nmethods)
1195         (error "~@<The set of methods ~S applicable to argument~P ~
1196                 ~{~S~^, ~} to call-next-method is different from ~
1197                 the set of methods ~S applicable to the original ~
1198                 method argument~P ~{~S~^, ~}.~@:>"
1199                nmethods (length cnm-args) cnm-args omethods
1200                (length orig-args) orig-args)))))
1201
1202 (defmacro bind-args ((lambda-list args) &body body)
1203   (let ((args-tail '.args-tail.)
1204         (key '.key.)
1205         (state 'required))
1206     (flet ((process-var (var)
1207              (if (memq var lambda-list-keywords)
1208                  (progn
1209                    (case var
1210                      (&optional       (setq state 'optional))
1211                      (&key            (setq state 'key))
1212                      (&allow-other-keys)
1213                      (&rest           (setq state 'rest))
1214                      (&aux            (setq state 'aux))
1215                      (otherwise
1216                       (error
1217                        "encountered the non-standard lambda list keyword ~S"
1218                        var)))
1219                    nil)
1220                  (case state
1221                    (required `((,var (pop ,args-tail))))
1222                    (optional (cond ((not (consp var))
1223                                     `((,var (when ,args-tail
1224                                               (pop ,args-tail)))))
1225                                    ((null (cddr var))
1226                                     `((,(car var) (if ,args-tail
1227                                                       (pop ,args-tail)
1228                                                       ,(cadr var)))))
1229                                    (t
1230                                     `((,(caddr var) ,args-tail)
1231                                       (,(car var) (if ,args-tail
1232                                                       (pop ,args-tail)
1233                                                       ,(cadr var)))))))
1234                    (rest `((,var ,args-tail)))
1235                    (key (cond ((not (consp var))
1236                                `((,var (car
1237                                         (get-key-arg-tail ,(keywordicate var)
1238                                                           ,args-tail)))))
1239                               ((null (cddr var))
1240                                (multiple-value-bind (keyword variable)
1241                                    (if (consp (car var))
1242                                        (values (caar var)
1243                                                (cadar var))
1244                                        (values (keywordicate (car var))
1245                                                (car var)))
1246                                  `((,key (get-key-arg-tail ',keyword
1247                                                            ,args-tail))
1248                                    (,variable (if ,key
1249                                                   (car ,key)
1250                                                   ,(cadr var))))))
1251                               (t
1252                                (multiple-value-bind (keyword variable)
1253                                    (if (consp (car var))
1254                                        (values (caar var)
1255                                                (cadar var))
1256                                        (values (keywordicate (car var))
1257                                                (car var)))
1258                                  `((,key (get-key-arg-tail ',keyword
1259                                                            ,args-tail))
1260                                    (,(caddr var) ,key)
1261                                    (,variable (if ,key
1262                                                   (car ,key)
1263                                                   ,(cadr var))))))))
1264                    (aux `(,var))))))
1265       (let ((bindings (mapcan #'process-var lambda-list)))
1266         `(let* ((,args-tail ,args)
1267                 ,@bindings
1268                 (.dummy0.
1269                  ,@(when (eq state 'optional)
1270                      `((unless (null ,args-tail)
1271                          (error 'simple-program-error
1272                                 :format-control "surplus arguments: ~S"
1273                                 :format-arguments (list ,args-tail)))))))
1274            (declare (ignorable ,args-tail .dummy0.))
1275            ,@body)))))
1276
1277 (defun get-key-arg-tail (keyword list)
1278   (loop for (key . tail) on list by #'cddr
1279         when (null tail) do
1280           ;; FIXME: Do we want to export this symbol? Or maybe use an
1281           ;; (ERROR 'SIMPLE-PROGRAM-ERROR) form?
1282           (sb-c::%odd-key-args-error)
1283         when (eq key keyword)
1284           return tail))
1285
1286 (defun walk-method-lambda (method-lambda required-parameters env slots calls)
1287   (let ((call-next-method-p nil)   ; flag indicating that CALL-NEXT-METHOD
1288                                    ; should be in the method definition
1289         (closurep nil)             ; flag indicating that #'CALL-NEXT-METHOD
1290                                    ; was seen in the body of a method
1291         (next-method-p-p nil)      ; flag indicating that NEXT-METHOD-P
1292                                    ; should be in the method definition
1293         (setq-p nil))
1294     (flet ((walk-function (form context env)
1295              (cond ((not (eq context :eval)) form)
1296                    ;; FIXME: Jumping to a conclusion from the way it's used
1297                    ;; above, perhaps CONTEXT should be called SITUATION
1298                    ;; (after the term used in the ANSI specification of
1299                    ;; EVAL-WHEN) and given modern ANSI keyword values
1300                    ;; like :LOAD-TOPLEVEL.
1301                    ((not (listp form)) form)
1302                    ((eq (car form) 'call-next-method)
1303                     (setq call-next-method-p t)
1304                     form)
1305                    ((eq (car form) 'next-method-p)
1306                     (setq next-method-p-p t)
1307                     form)
1308                    ((memq (car form) '(setq multiple-value-setq))
1309                     ;; FIXME: this is possibly a little strong as
1310                     ;; conditions go.  Ideally we would want to detect
1311                     ;; which, if any, of the method parameters are
1312                     ;; being set, and communicate that information to
1313                     ;; e.g. SPLIT-DECLARATIONS.  However, the brute
1314                     ;; force method doesn't really cost much; a little
1315                     ;; loss of discrimination over IGNORED variables
1316                     ;; should be all.  -- CSR, 2004-07-01
1317                     (setq setq-p t)
1318                     form)
1319                    ((and (eq (car form) 'function)
1320                          (cond ((eq (cadr form) 'call-next-method)
1321                                 (setq call-next-method-p t)
1322                                 (setq closurep t)
1323                                 form)
1324                                ((eq (cadr form) 'next-method-p)
1325                                 (setq next-method-p-p t)
1326                                 (setq closurep t)
1327                                 form)
1328                                (t nil))))
1329                    ((and (memq (car form)
1330                                '(slot-value set-slot-value slot-boundp))
1331                          (constantp (caddr form)))
1332                      (let ((parameter (can-optimize-access form
1333                                                            required-parameters
1334                                                            env)))
1335                       (let ((fun (ecase (car form)
1336                                    (slot-value #'optimize-slot-value)
1337                                    (set-slot-value #'optimize-set-slot-value)
1338                                    (slot-boundp #'optimize-slot-boundp))))
1339                         (funcall fun slots parameter form))))
1340                    ((and (eq (car form) 'apply)
1341                          (consp (cadr form))
1342                          (eq (car (cadr form)) 'function)
1343                          (generic-function-name-p (cadr (cadr form))))
1344                     (optimize-generic-function-call
1345                      form required-parameters env slots calls))
1346                    ((generic-function-name-p (car form))
1347                     (optimize-generic-function-call
1348                      form required-parameters env slots calls))
1349                    (t form))))
1350
1351       (let ((walked-lambda (walk-form method-lambda env #'walk-function)))
1352         (values walked-lambda
1353                 call-next-method-p
1354                 closurep
1355                 next-method-p-p
1356                 setq-p)))))
1357
1358 (defun generic-function-name-p (name)
1359   (and (legal-fun-name-p name)
1360        (fboundp name)
1361        (if (eq *boot-state* 'complete)
1362            (standard-generic-function-p (gdefinition name))
1363            (funcallable-instance-p (gdefinition name)))))
1364 \f
1365 (defun method-plist-value (method key &optional default)
1366   (let ((plist (if (consp method)
1367                    (getf (early-method-initargs method) 'plist)
1368                    (object-plist method))))
1369     (getf plist key default)))
1370
1371 (defun (setf method-plist-value) (new-value method key &optional default)
1372   (if (consp method)
1373       (setf (getf (getf (early-method-initargs method) 'plist) key default)
1374             new-value)
1375       (setf (getf (object-plist method) key default) new-value)))
1376 \f
1377 (defun load-defmethod
1378     (class name quals specls ll initargs source-location)
1379   (setq initargs (copy-tree initargs))
1380   (setf (getf (getf initargs 'plist) :name)
1381         (make-method-spec name quals specls))
1382   (load-defmethod-internal class name quals specls
1383                            ll initargs source-location))
1384
1385 (defun load-defmethod-internal
1386     (method-class gf-spec qualifiers specializers lambda-list
1387                   initargs source-location)
1388   (when (and (eq *boot-state* 'complete)
1389              (fboundp gf-spec))
1390     (let* ((gf (fdefinition gf-spec))
1391            (method (and (generic-function-p gf)
1392                         (generic-function-methods gf)
1393                         (find-method gf
1394                                      qualifiers
1395                                      (parse-specializers specializers)
1396                                      nil))))
1397       (when method
1398         (style-warn "redefining ~S~{ ~S~} ~S in DEFMETHOD"
1399                     gf-spec qualifiers specializers))))
1400   (let ((method (apply #'add-named-method
1401                        gf-spec qualifiers specializers lambda-list
1402                        :definition-source source-location
1403                        initargs)))
1404     (unless (or (eq method-class 'standard-method)
1405                 (eq (find-class method-class nil) (class-of method)))
1406       ;; FIXME: should be STYLE-WARNING?
1407       (format *error-output*
1408               "~&At the time the method with qualifiers ~:S and~%~
1409                specializers ~:S on the generic function ~S~%~
1410                was compiled, the method-class for that generic function was~%~
1411                ~S. But, the method class is now ~S, this~%~
1412                may mean that this method was compiled improperly.~%"
1413               qualifiers specializers gf-spec
1414               method-class (class-name (class-of method))))
1415     method))
1416
1417 (defun make-method-spec (gf-spec qualifiers unparsed-specializers)
1418   `(slow-method ,gf-spec ,@qualifiers ,unparsed-specializers))
1419
1420 (defun initialize-method-function (initargs method)
1421   (let* ((mf (getf initargs :function))
1422          (mff (and (typep mf '%method-function)
1423                    (%method-function-fast-function mf)))
1424          (plist (getf initargs 'plist))
1425          (name (getf plist :name)))
1426     (when name
1427       (when mf
1428         (setq mf (set-fun-name mf name)))
1429       (when (and mff (consp name) (eq (car name) 'slow-method))
1430         (let ((fast-name `(fast-method ,@(cdr name))))
1431           (set-fun-name mff fast-name))))
1432     (when plist
1433       (let ((plist plist))
1434         (let ((snl (getf plist :slot-name-lists))
1435               (cl (getf plist :call-list)))
1436           (when (or snl cl)
1437             (setf (method-plist-value method :pv-table)
1438                   (intern-pv-table :slot-name-lists snl :call-list cl))))))))
1439 \f
1440 (defun analyze-lambda-list (lambda-list)
1441   (flet (;; FIXME: Is this redundant with SB-C::MAKE-KEYWORD-FOR-ARG?
1442          (parse-key-arg (arg)
1443            (if (listp arg)
1444                (if (listp (car arg))
1445                    (caar arg)
1446                    (keywordicate (car arg)))
1447                (keywordicate arg))))
1448     (let ((nrequired 0)
1449           (noptional 0)
1450           (keysp nil)
1451           (restp nil)
1452           (nrest 0)
1453           (allow-other-keys-p nil)
1454           (keywords ())
1455           (keyword-parameters ())
1456           (state 'required))
1457       (dolist (x lambda-list)
1458         (if (memq x lambda-list-keywords)
1459             (case x
1460               (&optional         (setq state 'optional))
1461               (&key              (setq keysp t
1462                                        state 'key))
1463               (&allow-other-keys (setq allow-other-keys-p t))
1464               (&rest             (setq restp t
1465                                        state 'rest))
1466               (&aux           (return t))
1467               (otherwise
1468                 (error "encountered the non-standard lambda list keyword ~S"
1469                        x)))
1470             (ecase state
1471               (required  (incf nrequired))
1472               (optional  (incf noptional))
1473               (key       (push (parse-key-arg x) keywords)
1474                          (push x keyword-parameters))
1475               (rest      (incf nrest)))))
1476       (when (and restp (zerop nrest))
1477         (error "Error in lambda-list:~%~
1478                 After &REST, a DEFGENERIC lambda-list ~
1479                 must be followed by at least one variable."))
1480       (values nrequired noptional keysp restp allow-other-keys-p
1481               (reverse keywords)
1482               (reverse keyword-parameters)))))
1483
1484 (defun keyword-spec-name (x)
1485   (let ((key (if (atom x) x (car x))))
1486     (if (atom key)
1487         (keywordicate key)
1488         (car key))))
1489
1490 (defun ftype-declaration-from-lambda-list (lambda-list name)
1491   (multiple-value-bind (nrequired noptional keysp restp allow-other-keys-p
1492                                   keywords keyword-parameters)
1493       (analyze-lambda-list lambda-list)
1494     (declare (ignore keyword-parameters))
1495     (let* ((old (info :function :type name)) ;FIXME:FDOCUMENTATION instead?
1496            (old-ftype (if (fun-type-p old) old nil))
1497            (old-restp (and old-ftype (fun-type-rest old-ftype)))
1498            (old-keys (and old-ftype
1499                           (mapcar #'key-info-name
1500                                   (fun-type-keywords
1501                                    old-ftype))))
1502            (old-keysp (and old-ftype (fun-type-keyp old-ftype)))
1503            (old-allowp (and old-ftype
1504                             (fun-type-allowp old-ftype)))
1505            (keywords (union old-keys (mapcar #'keyword-spec-name keywords))))
1506       `(function ,(append (make-list nrequired :initial-element t)
1507                           (when (plusp noptional)
1508                             (append '(&optional)
1509                                     (make-list noptional :initial-element t)))
1510                           (when (or restp old-restp)
1511                             '(&rest t))
1512                           (when (or keysp old-keysp)
1513                             (append '(&key)
1514                                     (mapcar (lambda (key)
1515                                               `(,key t))
1516                                             keywords)
1517                                     (when (or allow-other-keys-p old-allowp)
1518                                       '(&allow-other-keys)))))
1519                  *))))
1520
1521 (defun defgeneric-declaration (spec lambda-list)
1522   `(ftype ,(ftype-declaration-from-lambda-list lambda-list spec) ,spec))
1523 \f
1524 ;;;; early generic function support
1525
1526 (defvar *!early-generic-functions* ())
1527
1528 (defun ensure-generic-function (fun-name
1529                                 &rest all-keys
1530                                 &key environment source-location
1531                                 &allow-other-keys)
1532   (declare (ignore environment))
1533   (let ((existing (and (fboundp fun-name)
1534                        (gdefinition fun-name))))
1535     (if (and existing
1536              (eq *boot-state* 'complete)
1537              (null (generic-function-p existing)))
1538         (generic-clobbers-function fun-name)
1539         (apply #'ensure-generic-function-using-class
1540                existing fun-name all-keys))))
1541
1542 (defun generic-clobbers-function (fun-name)
1543   (error 'simple-program-error
1544          :format-control "~S already names an ordinary function or a macro."
1545          :format-arguments (list fun-name)))
1546
1547 (defvar *sgf-wrapper*
1548   (boot-make-wrapper (early-class-size 'standard-generic-function)
1549                      'standard-generic-function))
1550
1551 (defvar *sgf-slots-init*
1552   (mapcar (lambda (canonical-slot)
1553             (if (memq (getf canonical-slot :name) '(arg-info source))
1554                 +slot-unbound+
1555                 (let ((initfunction (getf canonical-slot :initfunction)))
1556                   (if initfunction
1557                       (funcall initfunction)
1558                       +slot-unbound+))))
1559           (early-collect-inheritance 'standard-generic-function)))
1560
1561 (defvar *sgf-method-class-index*
1562   (!bootstrap-slot-index 'standard-generic-function 'method-class))
1563
1564 (defun early-gf-p (x)
1565   (and (fsc-instance-p x)
1566        (eq (clos-slots-ref (get-slots x) *sgf-method-class-index*)
1567            +slot-unbound+)))
1568
1569 (defvar *sgf-methods-index*
1570   (!bootstrap-slot-index 'standard-generic-function 'methods))
1571
1572 (defmacro early-gf-methods (gf)
1573   `(clos-slots-ref (get-slots ,gf) *sgf-methods-index*))
1574
1575 (defun safe-generic-function-methods (generic-function)
1576   (if (eq (class-of generic-function) *the-class-standard-generic-function*)
1577       (clos-slots-ref (get-slots generic-function) *sgf-methods-index*)
1578       (generic-function-methods generic-function)))
1579
1580 (defvar *sgf-arg-info-index*
1581   (!bootstrap-slot-index 'standard-generic-function 'arg-info))
1582
1583 (defmacro early-gf-arg-info (gf)
1584   `(clos-slots-ref (get-slots ,gf) *sgf-arg-info-index*))
1585
1586 (defvar *sgf-dfun-state-index*
1587   (!bootstrap-slot-index 'standard-generic-function 'dfun-state))
1588
1589 (defstruct (arg-info
1590             (:conc-name nil)
1591             (:constructor make-arg-info ())
1592             (:copier nil))
1593   (arg-info-lambda-list :no-lambda-list)
1594   arg-info-precedence
1595   arg-info-metatypes
1596   arg-info-number-optional
1597   arg-info-key/rest-p
1598   arg-info-keys   ;nil        no &KEY or &REST allowed
1599                   ;(k1 k2 ..) Each method must accept these &KEY arguments.
1600                   ;T          must have &KEY or &REST
1601
1602   gf-info-simple-accessor-type ; nil, reader, writer, boundp
1603   (gf-precompute-dfun-and-emf-p nil) ; set by set-arg-info
1604
1605   gf-info-static-c-a-m-emf
1606   (gf-info-c-a-m-emf-std-p t)
1607   gf-info-fast-mf-p)
1608
1609 #-sb-fluid (declaim (sb-ext:freeze-type arg-info))
1610
1611 (defun arg-info-valid-p (arg-info)
1612   (not (null (arg-info-number-optional arg-info))))
1613
1614 (defun arg-info-applyp (arg-info)
1615   (or (plusp (arg-info-number-optional arg-info))
1616       (arg-info-key/rest-p arg-info)))
1617
1618 (defun arg-info-number-required (arg-info)
1619   (length (arg-info-metatypes arg-info)))
1620
1621 (defun arg-info-nkeys (arg-info)
1622   (count-if (lambda (x) (neq x t)) (arg-info-metatypes arg-info)))
1623
1624 (defun create-gf-lambda-list (lambda-list)
1625   ;;; Create a gf lambda list from a method lambda list
1626   (loop for x in lambda-list
1627         collect (if (consp x) (list (car x)) x)
1628         if (eq x '&key) do (loop-finish)))
1629
1630 (defun set-arg-info (gf &key new-method (lambda-list nil lambda-list-p)
1631                         argument-precedence-order)
1632   (let* ((arg-info (if (eq *boot-state* 'complete)
1633                        (gf-arg-info gf)
1634                        (early-gf-arg-info gf)))
1635          (methods (if (eq *boot-state* 'complete)
1636                       (generic-function-methods gf)
1637                       (early-gf-methods gf)))
1638          (was-valid-p (integerp (arg-info-number-optional arg-info)))
1639          (first-p (and new-method (null (cdr methods)))))
1640     (when (and (not lambda-list-p) methods)
1641       (setq lambda-list (gf-lambda-list gf)))
1642     (when (or lambda-list-p
1643               (and first-p
1644                    (eq (arg-info-lambda-list arg-info) :no-lambda-list)))
1645       (multiple-value-bind (nreq nopt keysp restp allow-other-keys-p keywords)
1646           (analyze-lambda-list lambda-list)
1647         (when (and methods (not first-p))
1648           (let ((gf-nreq (arg-info-number-required arg-info))
1649                 (gf-nopt (arg-info-number-optional arg-info))
1650                 (gf-key/rest-p (arg-info-key/rest-p arg-info)))
1651             (unless (and (= nreq gf-nreq)
1652                          (= nopt gf-nopt)
1653                          (eq (or keysp restp) gf-key/rest-p))
1654               (error "The lambda-list ~S is incompatible with ~
1655                      existing methods of ~S."
1656                      lambda-list gf))))
1657         (setf (arg-info-lambda-list arg-info)
1658               (if lambda-list-p
1659                   lambda-list
1660                    (create-gf-lambda-list lambda-list)))
1661         (when (or lambda-list-p argument-precedence-order
1662                   (null (arg-info-precedence arg-info)))
1663           (setf (arg-info-precedence arg-info)
1664                 (compute-precedence lambda-list nreq argument-precedence-order)))
1665         (setf (arg-info-metatypes arg-info) (make-list nreq))
1666         (setf (arg-info-number-optional arg-info) nopt)
1667         (setf (arg-info-key/rest-p arg-info) (not (null (or keysp restp))))
1668         (setf (arg-info-keys arg-info)
1669               (if lambda-list-p
1670                   (if allow-other-keys-p t keywords)
1671                   (arg-info-key/rest-p arg-info)))))
1672     (when new-method
1673       (check-method-arg-info gf arg-info new-method))
1674     (set-arg-info1 gf arg-info new-method methods was-valid-p first-p)
1675     arg-info))
1676
1677 (defun check-method-arg-info (gf arg-info method)
1678   (multiple-value-bind (nreq nopt keysp restp allow-other-keys-p keywords)
1679       (analyze-lambda-list (if (consp method)
1680                                (early-method-lambda-list method)
1681                                (method-lambda-list method)))
1682     (flet ((lose (string &rest args)
1683              (error 'simple-program-error
1684                     :format-control "~@<attempt to add the method~2I~_~S~I~_~
1685                                      to the generic function~2I~_~S;~I~_~
1686                                      but ~?~:>"
1687                     :format-arguments (list method gf string args)))
1688            (comparison-description (x y)
1689              (if (> x y) "more" "fewer")))
1690       (let ((gf-nreq (arg-info-number-required arg-info))
1691             (gf-nopt (arg-info-number-optional arg-info))
1692             (gf-key/rest-p (arg-info-key/rest-p arg-info))
1693             (gf-keywords (arg-info-keys arg-info)))
1694         (unless (= nreq gf-nreq)
1695           (lose
1696            "the method has ~A required arguments than the generic function."
1697            (comparison-description nreq gf-nreq)))
1698         (unless (= nopt gf-nopt)
1699           (lose
1700            "the method has ~A optional arguments than the generic function."
1701            (comparison-description nopt gf-nopt)))
1702         (unless (eq (or keysp restp) gf-key/rest-p)
1703           (lose
1704            "the method and generic function differ in whether they accept~_~
1705             &REST or &KEY arguments."))
1706         (when (consp gf-keywords)
1707           (unless (or (and restp (not keysp))
1708                       allow-other-keys-p
1709                       (every (lambda (k) (memq k keywords)) gf-keywords))
1710             (lose "the method does not accept each of the &KEY arguments~2I~_~
1711                    ~S."
1712                   gf-keywords)))))))
1713
1714 (defvar *sm-specializers-index*
1715   (!bootstrap-slot-index 'standard-method 'specializers))
1716 (defvar *sm-%function-index*
1717   (!bootstrap-slot-index 'standard-method '%function))
1718 (defvar *sm-qualifiers-index*
1719   (!bootstrap-slot-index 'standard-method 'qualifiers))
1720 (defvar *sm-plist-index*
1721   (!bootstrap-slot-index 'standard-method 'plist))
1722
1723 ;;; FIXME: we don't actually need this; we could test for the exact
1724 ;;; class and deal with it as appropriate.  In fact we probably don't
1725 ;;; need it anyway because we only use this for METHOD-SPECIALIZERS on
1726 ;;; the standard reader method for METHOD-SPECIALIZERS.  Probably.
1727 (dolist (s '(specializers %function plist))
1728   (aver (= (symbol-value (intern (format nil "*SM-~A-INDEX*" s)))
1729            (!bootstrap-slot-index 'standard-reader-method s)
1730            (!bootstrap-slot-index 'standard-writer-method s)
1731            (!bootstrap-slot-index 'standard-boundp-method s))))
1732
1733 (defun safe-method-specializers (method)
1734   (let ((standard-method-classes
1735          (list *the-class-standard-method*
1736                *the-class-standard-reader-method*
1737                *the-class-standard-writer-method*
1738                *the-class-standard-boundp-method*))
1739         (class (class-of method)))
1740     (if (member class standard-method-classes)
1741         (clos-slots-ref (get-slots method) *sm-specializers-index*)
1742         (method-specializers method))))
1743 (defun safe-method-fast-function (method)
1744   (let ((mf (safe-method-function method)))
1745     (and (typep mf '%method-function)
1746          (%method-function-fast-function mf))))
1747 (defun safe-method-function (method)
1748   (let ((standard-method-classes
1749          (list *the-class-standard-method*
1750                *the-class-standard-reader-method*
1751                *the-class-standard-writer-method*
1752                *the-class-standard-boundp-method*))
1753         (class (class-of method)))
1754     (if (member class standard-method-classes)
1755         (clos-slots-ref (get-slots method) *sm-%function-index*)
1756         (method-function method))))
1757 (defun safe-method-qualifiers (method)
1758   (let ((standard-method-classes
1759          (list *the-class-standard-method*
1760                *the-class-standard-reader-method*
1761                *the-class-standard-writer-method*
1762                *the-class-standard-boundp-method*))
1763         (class (class-of method)))
1764     (if (member class standard-method-classes)
1765         (clos-slots-ref (get-slots method) *sm-qualifiers-index*)
1766         (method-qualifiers method))))
1767
1768 (defun set-arg-info1 (gf arg-info new-method methods was-valid-p first-p)
1769   (let* ((existing-p (and methods (cdr methods) new-method))
1770          (nreq (length (arg-info-metatypes arg-info)))
1771          (metatypes (if existing-p
1772                         (arg-info-metatypes arg-info)
1773                         (make-list nreq)))
1774          (type (if existing-p
1775                    (gf-info-simple-accessor-type arg-info)
1776                    nil)))
1777     (when (arg-info-valid-p arg-info)
1778       (dolist (method (if new-method (list new-method) methods))
1779         (let* ((specializers (if (or (eq *boot-state* 'complete)
1780                                      (not (consp method)))
1781                                  (safe-method-specializers method)
1782                                  (early-method-specializers method t)))
1783                (class (if (or (eq *boot-state* 'complete) (not (consp method)))
1784                           (class-of method)
1785                           (early-method-class method)))
1786                (new-type
1787                 (when (and class
1788                            (or (not (eq *boot-state* 'complete))
1789                                (eq (generic-function-method-combination gf)
1790                                    *standard-method-combination*)))
1791                   (cond ((or (eq class *the-class-standard-reader-method*)
1792                              (eq class *the-class-global-reader-method*))
1793                          'reader)
1794                         ((or (eq class *the-class-standard-writer-method*)
1795                              (eq class *the-class-global-writer-method*))
1796                          'writer)
1797                         ((or (eq class *the-class-standard-boundp-method*)
1798                              (eq class *the-class-global-boundp-method*))
1799                          'boundp)))))
1800           (setq metatypes (mapcar #'raise-metatype metatypes specializers))
1801           (setq type (cond ((null type) new-type)
1802                            ((eq type new-type) type)
1803                            (t nil)))))
1804       (setf (arg-info-metatypes arg-info) metatypes)
1805       (setf (gf-info-simple-accessor-type arg-info) type)))
1806   (when (or (not was-valid-p) first-p)
1807     (multiple-value-bind (c-a-m-emf std-p)
1808         (if (early-gf-p gf)
1809             (values t t)
1810             (compute-applicable-methods-emf gf))
1811       (setf (gf-info-static-c-a-m-emf arg-info) c-a-m-emf)
1812       (setf (gf-info-c-a-m-emf-std-p arg-info) std-p)
1813       (unless (gf-info-c-a-m-emf-std-p arg-info)
1814         (setf (gf-info-simple-accessor-type arg-info) t))))
1815   (unless was-valid-p
1816     (let ((name (if (eq *boot-state* 'complete)
1817                     (generic-function-name gf)
1818                     (!early-gf-name gf))))
1819       (setf (gf-precompute-dfun-and-emf-p arg-info)
1820             (cond
1821               ((and (consp name)
1822                     (member (car name)
1823                             *internal-pcl-generalized-fun-name-symbols*))
1824                 nil)
1825               (t (let* ((symbol (fun-name-block-name name))
1826                         (package (symbol-package symbol)))
1827                    (and (or (eq package *pcl-package*)
1828                             (memq package (package-use-list *pcl-package*)))
1829                         ;; FIXME: this test will eventually be
1830                         ;; superseded by the *internal-pcl...* test,
1831                         ;; above.  While we are in a process of
1832                         ;; transition, however, it should probably
1833                         ;; remain.
1834                         (not (find #\Space (symbol-name symbol))))))))))
1835   (setf (gf-info-fast-mf-p arg-info)
1836         (or (not (eq *boot-state* 'complete))
1837             (let* ((method-class (generic-function-method-class gf))
1838                    (methods (compute-applicable-methods
1839                              #'make-method-lambda
1840                              (list gf (class-prototype method-class)
1841                                    '(lambda) nil))))
1842               (and methods (null (cdr methods))
1843                    (let ((specls (method-specializers (car methods))))
1844                      (and (classp (car specls))
1845                           (eq 'standard-generic-function
1846                               (class-name (car specls)))
1847                           (classp (cadr specls))
1848                           (eq 'standard-method
1849                               (class-name (cadr specls)))))))))
1850   arg-info)
1851
1852 ;;; This is the early definition of ENSURE-GENERIC-FUNCTION-USING-CLASS.
1853 ;;;
1854 ;;; The STATIC-SLOTS field of the funcallable instances used as early
1855 ;;; generic functions is used to store the early methods and early
1856 ;;; discriminator code for the early generic function. The static
1857 ;;; slots field of the fins contains a list whose:
1858 ;;;    CAR    -   a list of the early methods on this early gf
1859 ;;;    CADR   -   the early discriminator code for this method
1860 (defun ensure-generic-function-using-class (existing spec &rest keys
1861                                             &key (lambda-list nil
1862                                                               lambda-list-p)
1863                                             argument-precedence-order
1864                                             source-location
1865                                             &allow-other-keys)
1866   (declare (ignore keys))
1867   (cond ((and existing (early-gf-p existing))
1868          (when lambda-list-p
1869            (set-arg-info existing :lambda-list lambda-list))
1870          existing)
1871         ((assoc spec *!generic-function-fixups* :test #'equal)
1872          (if existing
1873              (make-early-gf spec lambda-list lambda-list-p existing
1874                             argument-precedence-order source-location)
1875              (error "The function ~S is not already defined." spec)))
1876         (existing
1877          (error "~S should be on the list ~S."
1878                 spec
1879                 '*!generic-function-fixups*))
1880         (t
1881          (pushnew spec *!early-generic-functions* :test #'equal)
1882          (make-early-gf spec lambda-list lambda-list-p nil
1883                         argument-precedence-order source-location))))
1884
1885 (defun make-early-gf (spec &optional lambda-list lambda-list-p
1886                       function argument-precedence-order source-location)
1887   (let ((fin (allocate-standard-funcallable-instance
1888               *sgf-wrapper* *sgf-slots-init*)))
1889     (set-funcallable-instance-function
1890      fin
1891      (or function
1892          (if (eq spec 'print-object)
1893              #'(lambda (instance stream)
1894                  (print-unreadable-object (instance stream :identity t)
1895                    (format stream "std-instance")))
1896              #'(lambda (&rest args)
1897                  (declare (ignore args))
1898                  (error "The function of the funcallable-instance ~S~
1899                          has not been set." fin)))))
1900     (setf (gdefinition spec) fin)
1901     (!bootstrap-set-slot 'standard-generic-function fin 'name spec)
1902     (!bootstrap-set-slot 'standard-generic-function
1903                          fin
1904                          'source
1905                          source-location)
1906     (set-fun-name fin spec)
1907     (let ((arg-info (make-arg-info)))
1908       (setf (early-gf-arg-info fin) arg-info)
1909       (when lambda-list-p
1910         (proclaim (defgeneric-declaration spec lambda-list))
1911         (if argument-precedence-order
1912             (set-arg-info fin
1913                           :lambda-list lambda-list
1914                           :argument-precedence-order argument-precedence-order)
1915             (set-arg-info fin :lambda-list lambda-list))))
1916     fin))
1917
1918 (defun safe-gf-dfun-state (generic-function)
1919   (if (eq (class-of generic-function) *the-class-standard-generic-function*)
1920       (clos-slots-ref (get-slots generic-function) *sgf-dfun-state-index*)
1921       (gf-dfun-state generic-function)))
1922 (defun (setf safe-gf-dfun-state) (new-value generic-function)
1923   (if (eq (class-of generic-function) *the-class-standard-generic-function*)
1924       (setf (clos-slots-ref (get-slots generic-function)
1925                             *sgf-dfun-state-index*)
1926             new-value)
1927       (setf (gf-dfun-state generic-function) new-value)))
1928
1929 (defun set-dfun (gf &optional dfun cache info)
1930   (when cache
1931     (setf (cache-owner cache) gf))
1932   (let ((new-state (if (and dfun (or cache info))
1933                        (list* dfun cache info)
1934                        dfun)))
1935     (if (eq *boot-state* 'complete)
1936         (setf (safe-gf-dfun-state gf) new-state)
1937         (setf (clos-slots-ref (get-slots gf) *sgf-dfun-state-index*)
1938               new-state)))
1939   dfun)
1940
1941 (defun gf-dfun-cache (gf)
1942   (let ((state (if (eq *boot-state* 'complete)
1943                    (safe-gf-dfun-state gf)
1944                    (clos-slots-ref (get-slots gf) *sgf-dfun-state-index*))))
1945     (typecase state
1946       (function nil)
1947       (cons (cadr state)))))
1948
1949 (defun gf-dfun-info (gf)
1950   (let ((state (if (eq *boot-state* 'complete)
1951                    (safe-gf-dfun-state gf)
1952                    (clos-slots-ref (get-slots gf) *sgf-dfun-state-index*))))
1953     (typecase state
1954       (function nil)
1955       (cons (cddr state)))))
1956
1957 (defvar *sgf-name-index*
1958   (!bootstrap-slot-index 'standard-generic-function 'name))
1959
1960 (defun !early-gf-name (gf)
1961   (clos-slots-ref (get-slots gf) *sgf-name-index*))
1962
1963 (defun gf-lambda-list (gf)
1964   (let ((arg-info (if (eq *boot-state* 'complete)
1965                       (gf-arg-info gf)
1966                       (early-gf-arg-info gf))))
1967     (if (eq :no-lambda-list (arg-info-lambda-list arg-info))
1968         (let ((methods (if (eq *boot-state* 'complete)
1969                            (generic-function-methods gf)
1970                            (early-gf-methods gf))))
1971           (if (null methods)
1972               (progn
1973                 (warn "no way to determine the lambda list for ~S" gf)
1974                 nil)
1975               (let* ((method (car (last methods)))
1976                      (ll (if (consp method)
1977                              (early-method-lambda-list method)
1978                              (method-lambda-list method))))
1979                 (create-gf-lambda-list ll))))
1980         (arg-info-lambda-list arg-info))))
1981
1982 (defmacro real-ensure-gf-internal (gf-class all-keys env)
1983   `(progn
1984      (cond ((symbolp ,gf-class)
1985             (setq ,gf-class (find-class ,gf-class t ,env)))
1986            ((classp ,gf-class))
1987            (t
1988             (error "The :GENERIC-FUNCTION-CLASS argument (~S) was neither a~%~
1989                     class nor a symbol that names a class."
1990                    ,gf-class)))
1991      (unless (class-finalized-p ,gf-class)
1992        (if (class-has-a-forward-referenced-superclass-p ,gf-class)
1993            ;; FIXME: reference MOP documentation -- this is an
1994            ;; additional requirement on our users
1995            (error "The generic function class ~S is not finalizeable" ,gf-class)
1996            (finalize-inheritance ,gf-class)))
1997      (remf ,all-keys :generic-function-class)
1998      (remf ,all-keys :environment)
1999      (let ((combin (getf ,all-keys :method-combination '.shes-not-there.)))
2000        (unless (eq combin '.shes-not-there.)
2001          (setf (getf ,all-keys :method-combination)
2002                (find-method-combination (class-prototype ,gf-class)
2003                                         (car combin)
2004                                         (cdr combin)))))
2005     (let ((method-class (getf ,all-keys :method-class '.shes-not-there.)))
2006       (unless (eq method-class '.shes-not-there.)
2007         (setf (getf ,all-keys :method-class)
2008               (cond ((classp method-class)
2009                      method-class)
2010                     (t (find-class method-class t ,env))))))))
2011
2012 (defun real-ensure-gf-using-class--generic-function
2013        (existing
2014         fun-name
2015         &rest all-keys
2016         &key environment (lambda-list nil lambda-list-p)
2017              (generic-function-class 'standard-generic-function gf-class-p)
2018         &allow-other-keys)
2019   (real-ensure-gf-internal generic-function-class all-keys environment)
2020   (unless (or (null gf-class-p)
2021               (eq (class-of existing) generic-function-class))
2022     (change-class existing generic-function-class))
2023   (prog1
2024       (apply #'reinitialize-instance existing all-keys)
2025     (when lambda-list-p
2026       (proclaim (defgeneric-declaration fun-name lambda-list)))))
2027
2028 (defun real-ensure-gf-using-class--null
2029        (existing
2030         fun-name
2031         &rest all-keys
2032         &key environment (lambda-list nil lambda-list-p)
2033              (generic-function-class 'standard-generic-function)
2034         &allow-other-keys)
2035   (declare (ignore existing))
2036   (real-ensure-gf-internal generic-function-class all-keys environment)
2037   (prog1
2038       (setf (gdefinition fun-name)
2039             (apply #'make-instance generic-function-class
2040                    :name fun-name all-keys))
2041     (when lambda-list-p
2042       (proclaim (defgeneric-declaration fun-name lambda-list)))))
2043 \f
2044 (defun safe-gf-arg-info (generic-function)
2045   (if (eq (class-of generic-function) *the-class-standard-generic-function*)
2046       (clos-slots-ref (fsc-instance-slots generic-function)
2047                       *sgf-arg-info-index*)
2048       (gf-arg-info generic-function)))
2049
2050 ;;; FIXME: this function took on a slightly greater role than it
2051 ;;; previously had around 2005-11-02, when CSR fixed the bug whereby
2052 ;;; having more than one subclass of standard-generic-function caused
2053 ;;; the whole system to die horribly through a metacircle in
2054 ;;; GF-ARG-INFO.  The fix is to be slightly more disciplined about
2055 ;;; calling accessor methods -- we call GET-GENERIC-FUN-INFO when
2056 ;;; computing discriminating functions, so we need to be careful about
2057 ;;; having a base case for the recursion, and we provide that with the
2058 ;;; STANDARD-GENERIC-FUNCTION case below.  However, we are not (yet)
2059 ;;; as disciplined as CLISP's CLOS/MOP, and it would be nice to get to
2060 ;;; that stage, where all potentially dangerous cases are enumerated
2061 ;;; and stopped.  -- CSR, 2005-11-02.
2062 (defun get-generic-fun-info (gf)
2063   ;; values   nreq applyp metatypes nkeys arg-info
2064   (multiple-value-bind (applyp metatypes arg-info)
2065       (let* ((arg-info (if (early-gf-p gf)
2066                            (early-gf-arg-info gf)
2067                            (safe-gf-arg-info gf)))
2068              (metatypes (arg-info-metatypes arg-info)))
2069         (values (arg-info-applyp arg-info)
2070                 metatypes
2071                 arg-info))
2072     (values (length metatypes) applyp metatypes
2073             (count-if (lambda (x) (neq x t)) metatypes)
2074             arg-info)))
2075
2076 (defun early-make-a-method (class qualifiers arglist specializers initargs doc
2077                             &key slot-name object-class method-class-function)
2078   (let ((parsed ())
2079         (unparsed ()))
2080     ;; Figure out whether we got class objects or class names as the
2081     ;; specializers and set parsed and unparsed appropriately. If we
2082     ;; got class objects, then we can compute unparsed, but if we got
2083     ;; class names we don't try to compute parsed.
2084     ;;
2085     ;; Note that the use of not symbolp in this call to every should be
2086     ;; read as 'classp' we can't use classp itself because it doesn't
2087     ;; exist yet.
2088     (if (every (lambda (s) (not (symbolp s))) specializers)
2089         (setq parsed specializers
2090               unparsed (mapcar (lambda (s)
2091                                  (if (eq s t) t (class-name s)))
2092                                specializers))
2093         (setq unparsed specializers
2094               parsed ()))
2095     (let ((result
2096            (list :early-method
2097
2098                  (getf initargs :function)
2099                  (let ((mf (getf initargs :function)))
2100                    (aver mf)
2101                    (and (typep mf '%method-function)
2102                         (%method-function-fast-function mf)))
2103
2104                  ;; the parsed specializers. This is used by
2105                  ;; EARLY-METHOD-SPECIALIZERS to cache the parse.
2106                  ;; Note that this only comes into play when there is
2107                  ;; more than one early method on an early gf.
2108                  parsed
2109
2110                  ;; A list to which REAL-MAKE-A-METHOD can be applied
2111                  ;; to make a real method corresponding to this early
2112                  ;; one.
2113                  (append
2114                   (list class qualifiers arglist unparsed
2115                         initargs doc)
2116                   (when slot-name
2117                     (list :slot-name slot-name :object-class object-class
2118                           :method-class-function method-class-function))))))
2119       (initialize-method-function initargs result)
2120       result)))
2121
2122 (defun real-make-a-method
2123        (class qualifiers lambda-list specializers initargs doc
2124         &rest args &key slot-name object-class method-class-function)
2125   (setq specializers (parse-specializers specializers))
2126   (if method-class-function
2127       (let* ((object-class (if (classp object-class) object-class
2128                                (find-class object-class)))
2129              (slots (class-direct-slots object-class))
2130              (slot-definition (find slot-name slots
2131                                     :key #'slot-definition-name)))
2132         (aver slot-name)
2133         (aver slot-definition)
2134         (let ((initargs (list* :qualifiers qualifiers :lambda-list lambda-list
2135                                :specializers specializers :documentation doc
2136                                :slot-definition slot-definition
2137                                :slot-name slot-name initargs)))
2138           (apply #'make-instance
2139                  (apply method-class-function object-class slot-definition
2140                         initargs)
2141                  initargs)))
2142       (apply #'make-instance class :qualifiers qualifiers
2143              :lambda-list lambda-list :specializers specializers
2144              :documentation doc (append args initargs))))
2145
2146 (defun early-method-function (early-method)
2147   (values (cadr early-method) (caddr early-method)))
2148
2149 (defun early-method-class (early-method)
2150   (find-class (car (fifth early-method))))
2151
2152 (defun early-method-standard-accessor-p (early-method)
2153   (let ((class (first (fifth early-method))))
2154     (or (eq class 'standard-reader-method)
2155         (eq class 'standard-writer-method)
2156         (eq class 'standard-boundp-method))))
2157
2158 (defun early-method-standard-accessor-slot-name (early-method)
2159   (eighth (fifth early-method)))
2160
2161 ;;; Fetch the specializers of an early method. This is basically just
2162 ;;; a simple accessor except that when the second argument is t, this
2163 ;;; converts the specializers from symbols into class objects. The
2164 ;;; class objects are cached in the early method, this makes
2165 ;;; bootstrapping faster because the class objects only have to be
2166 ;;; computed once.
2167 ;;;
2168 ;;; NOTE:
2169 ;;;  The second argument should only be passed as T by
2170 ;;;  early-lookup-method. This is to implement the rule that only when
2171 ;;;  there is more than one early method on a generic function is the
2172 ;;;  conversion from class names to class objects done. This
2173 ;;;  corresponds to the fact that we are only allowed to have one
2174 ;;;  method on any generic function up until the time classes exist.
2175 (defun early-method-specializers (early-method &optional objectsp)
2176   (if (and (listp early-method)
2177            (eq (car early-method) :early-method))
2178       (cond ((eq objectsp t)
2179              (or (fourth early-method)
2180                  (setf (fourth early-method)
2181                        (mapcar #'find-class (cadddr (fifth early-method))))))
2182             (t
2183              (fourth (fifth early-method))))
2184       (error "~S is not an early-method." early-method)))
2185
2186 (defun early-method-qualifiers (early-method)
2187   (second (fifth early-method)))
2188
2189 (defun early-method-lambda-list (early-method)
2190   (third (fifth early-method)))
2191
2192 (defun early-method-initargs (early-method)
2193   (fifth (fifth early-method)))
2194
2195 (defun (setf early-method-initargs) (new-value early-method)
2196   (setf (fifth (fifth early-method)) new-value))
2197
2198 (defun early-add-named-method (generic-function-name
2199                                qualifiers
2200                                specializers
2201                                arglist
2202                                &rest initargs)
2203   (let* ((gf (ensure-generic-function generic-function-name))
2204          (existing
2205            (dolist (m (early-gf-methods gf))
2206              (when (and (equal (early-method-specializers m) specializers)
2207                         (equal (early-method-qualifiers m) qualifiers))
2208                (return m))))
2209          (new (make-a-method 'standard-method
2210                              qualifiers
2211                              arglist
2212                              specializers
2213                              initargs
2214                              ())))
2215     (when existing (remove-method gf existing))
2216     (add-method gf new)))
2217
2218 ;;; This is the early version of ADD-METHOD. Later this will become a
2219 ;;; generic function. See !FIX-EARLY-GENERIC-FUNCTIONS which has
2220 ;;; special knowledge about ADD-METHOD.
2221 (defun add-method (generic-function method)
2222   (when (not (fsc-instance-p generic-function))
2223     (error "Early ADD-METHOD didn't get a funcallable instance."))
2224   (when (not (and (listp method) (eq (car method) :early-method)))
2225     (error "Early ADD-METHOD didn't get an early method."))
2226   (push method (early-gf-methods generic-function))
2227   (set-arg-info generic-function :new-method method)
2228   (unless (assoc (!early-gf-name generic-function)
2229                  *!generic-function-fixups*
2230                  :test #'equal)
2231     (update-dfun generic-function)))
2232
2233 ;;; This is the early version of REMOVE-METHOD. See comments on
2234 ;;; the early version of ADD-METHOD.
2235 (defun remove-method (generic-function method)
2236   (when (not (fsc-instance-p generic-function))
2237     (error "An early remove-method didn't get a funcallable instance."))
2238   (when (not (and (listp method) (eq (car method) :early-method)))
2239     (error "An early remove-method didn't get an early method."))
2240   (setf (early-gf-methods generic-function)
2241         (remove method (early-gf-methods generic-function)))
2242   (set-arg-info generic-function)
2243   (unless (assoc (!early-gf-name generic-function)
2244                  *!generic-function-fixups*
2245                  :test #'equal)
2246     (update-dfun generic-function)))
2247
2248 ;;; This is the early version of GET-METHOD. See comments on the early
2249 ;;; version of ADD-METHOD.
2250 (defun get-method (generic-function qualifiers specializers
2251                                     &optional (errorp t))
2252   (if (early-gf-p generic-function)
2253       (or (dolist (m (early-gf-methods generic-function))
2254             (when (and (or (equal (early-method-specializers m nil)
2255                                   specializers)
2256                            (equal (early-method-specializers m t)
2257                                   specializers))
2258                        (equal (early-method-qualifiers m) qualifiers))
2259               (return m)))
2260           (if errorp
2261               (error "can't get early method")
2262               nil))
2263       (real-get-method generic-function qualifiers specializers errorp)))
2264
2265 (defun !fix-early-generic-functions ()
2266   (let ((accessors nil))
2267     ;; Rearrange *!EARLY-GENERIC-FUNCTIONS* to speed up
2268     ;; FIX-EARLY-GENERIC-FUNCTIONS.
2269     (dolist (early-gf-spec *!early-generic-functions*)
2270       (when (every #'early-method-standard-accessor-p
2271                    (early-gf-methods (gdefinition early-gf-spec)))
2272         (push early-gf-spec accessors)))
2273     (dolist (spec (nconc accessors
2274                          '(accessor-method-slot-name
2275                            generic-function-methods
2276                            method-specializers
2277                            specializerp
2278                            specializer-type
2279                            specializer-class
2280                            slot-definition-location
2281                            slot-definition-name
2282                            class-slots
2283                            gf-arg-info
2284                            class-precedence-list
2285                            slot-boundp-using-class
2286                            (setf slot-value-using-class)
2287                            slot-value-using-class
2288                            structure-class-p
2289                            standard-class-p
2290                            funcallable-standard-class-p
2291                            specializerp)))
2292       (/show spec)
2293       (setq *!early-generic-functions*
2294             (cons spec
2295                   (delete spec *!early-generic-functions* :test #'equal))))
2296
2297     (dolist (early-gf-spec *!early-generic-functions*)
2298       (/show early-gf-spec)
2299       (let* ((gf (gdefinition early-gf-spec))
2300              (methods (mapcar (lambda (early-method)
2301                                 (let ((args (copy-list (fifth
2302                                                         early-method))))
2303                                   (setf (fourth args)
2304                                         (early-method-specializers
2305                                          early-method t))
2306                                   (apply #'real-make-a-method args)))
2307                               (early-gf-methods gf))))
2308         (setf (generic-function-method-class gf) *the-class-standard-method*)
2309         (setf (generic-function-method-combination gf)
2310               *standard-method-combination*)
2311         (set-methods gf methods)))
2312
2313     (dolist (fn *!early-functions*)
2314       (/show fn)
2315       (setf (gdefinition (car fn)) (fdefinition (caddr fn))))
2316
2317     (dolist (fixup *!generic-function-fixups*)
2318       (/show fixup)
2319       (let* ((fspec (car fixup))
2320              (gf (gdefinition fspec))
2321              (methods (mapcar (lambda (method)
2322                                 (let* ((lambda-list (first method))
2323                                        (specializers (second method))
2324                                        (method-fn-name (third method))
2325                                        (fn-name (or method-fn-name fspec))
2326                                        (fn (fdefinition fn-name))
2327                                        (initargs
2328                                         (list :function
2329                                               (set-fun-name
2330                                                (lambda (args next-methods)
2331                                                  (declare (ignore
2332                                                            next-methods))
2333                                                  (apply fn args))
2334                                                `(call ,fn-name)))))
2335                                   (declare (type function fn))
2336                                   (make-a-method 'standard-method
2337                                                  ()
2338                                                  lambda-list
2339                                                  specializers
2340                                                  initargs
2341                                                  nil)))
2342                               (cdr fixup))))
2343         (setf (generic-function-method-class gf) *the-class-standard-method*)
2344         (setf (generic-function-method-combination gf)
2345               *standard-method-combination*)
2346         (set-methods gf methods))))
2347   (/show "leaving !FIX-EARLY-GENERIC-FUNCTIONS"))
2348 \f
2349 ;;; PARSE-DEFMETHOD is used by DEFMETHOD to parse the &REST argument
2350 ;;; into the 'real' arguments. This is where the syntax of DEFMETHOD
2351 ;;; is really implemented.
2352 (defun parse-defmethod (cdr-of-form)
2353   (declare (list cdr-of-form))
2354   (let ((name (pop cdr-of-form))
2355         (qualifiers ())
2356         (spec-ll ()))
2357     (loop (if (and (car cdr-of-form) (atom (car cdr-of-form)))
2358               (push (pop cdr-of-form) qualifiers)
2359               (return (setq qualifiers (nreverse qualifiers)))))
2360     (setq spec-ll (pop cdr-of-form))
2361     (values name qualifiers spec-ll cdr-of-form)))
2362
2363 (defun parse-specializers (specializers)
2364   (declare (list specializers))
2365   (flet ((parse (spec)
2366            (let ((result (specializer-from-type spec)))
2367              (if (specializerp result)
2368                  result
2369                  (if (symbolp spec)
2370                      (error "~S was used as a specializer,~%~
2371                              but is not the name of a class."
2372                             spec)
2373                      (error "~S is not a legal specializer." spec))))))
2374     (mapcar #'parse specializers)))
2375
2376 (defun unparse-specializers (specializers-or-method)
2377   (if (listp specializers-or-method)
2378       (flet ((unparse (spec)
2379                (if (specializerp spec)
2380                    (let ((type (specializer-type spec)))
2381                      (if (and (consp type)
2382                               (eq (car type) 'class))
2383                          (let* ((class (cadr type))
2384                                 (class-name (class-name class)))
2385                            (if (eq class (find-class class-name nil))
2386                                class-name
2387                                type))
2388                          type))
2389                    (error "~S is not a legal specializer." spec))))
2390         (mapcar #'unparse specializers-or-method))
2391       (unparse-specializers (method-specializers specializers-or-method))))
2392
2393 (defun parse-method-or-spec (spec &optional (errorp t))
2394   (let (gf method name temp)
2395     (if (method-p spec)
2396         (setq method spec
2397               gf (method-generic-function method)
2398               temp (and gf (generic-function-name gf))
2399               name (if temp
2400                        (make-method-spec temp
2401                                          (method-qualifiers method)
2402                                          (unparse-specializers
2403                                           (method-specializers method)))
2404                        (make-symbol (format nil "~S" method))))
2405         (multiple-value-bind (gf-spec quals specls)
2406             (parse-defmethod spec)
2407           (and (setq gf (and (or errorp (fboundp gf-spec))
2408                              (gdefinition gf-spec)))
2409                (let ((nreq (compute-discriminating-function-arglist-info gf)))
2410                  (setq specls (append (parse-specializers specls)
2411                                       (make-list (- nreq (length specls))
2412                                                  :initial-element
2413                                                  *the-class-t*)))
2414                  (and
2415                    (setq method (get-method gf quals specls errorp))
2416                    (setq name
2417                          (make-method-spec
2418                           gf-spec quals (unparse-specializers specls))))))))
2419     (values gf method name)))
2420 \f
2421 (defun extract-parameters (specialized-lambda-list)
2422   (multiple-value-bind (parameters ignore1 ignore2)
2423       (parse-specialized-lambda-list specialized-lambda-list)
2424     (declare (ignore ignore1 ignore2))
2425     parameters))
2426
2427 (defun extract-lambda-list (specialized-lambda-list)
2428   (multiple-value-bind (ignore1 lambda-list ignore2)
2429       (parse-specialized-lambda-list specialized-lambda-list)
2430     (declare (ignore ignore1 ignore2))
2431     lambda-list))
2432
2433 (defun extract-specializer-names (specialized-lambda-list)
2434   (multiple-value-bind (ignore1 ignore2 specializers)
2435       (parse-specialized-lambda-list specialized-lambda-list)
2436     (declare (ignore ignore1 ignore2))
2437     specializers))
2438
2439 (defun extract-required-parameters (specialized-lambda-list)
2440   (multiple-value-bind (ignore1 ignore2 ignore3 required-parameters)
2441       (parse-specialized-lambda-list specialized-lambda-list)
2442     (declare (ignore ignore1 ignore2 ignore3))
2443     required-parameters))
2444
2445 (define-condition specialized-lambda-list-error
2446     (reference-condition simple-program-error)
2447   ()
2448   (:default-initargs :references (list '(:ansi-cl :section (3 4 3)))))
2449
2450 (defun parse-specialized-lambda-list
2451     (arglist
2452      &optional supplied-keywords (allowed-keywords '(&optional &rest &key &aux))
2453      &aux (specialized-lambda-list-keywords
2454            '(&optional &rest &key &allow-other-keys &aux)))
2455   (let ((arg (car arglist)))
2456     (cond ((null arglist) (values nil nil nil nil))
2457           ((eq arg '&aux)
2458            (values nil arglist nil nil))
2459           ((memq arg lambda-list-keywords)
2460            ;; non-standard lambda-list-keywords are errors.
2461            (unless (memq arg specialized-lambda-list-keywords)
2462              (error 'specialized-lambda-list-error
2463                     :format-control "unknown specialized-lambda-list ~
2464                                      keyword ~S~%"
2465                     :format-arguments (list arg)))
2466            ;; no multiple &rest x &rest bla specifying
2467            (when (memq arg supplied-keywords)
2468              (error 'specialized-lambda-list-error
2469                     :format-control "multiple occurrence of ~
2470                                      specialized-lambda-list keyword ~S~%"
2471                     :format-arguments (list arg)))
2472            ;; And no placing &key in front of &optional, either.
2473            (unless (memq arg allowed-keywords)
2474              (error 'specialized-lambda-list-error
2475                     :format-control "misplaced specialized-lambda-list ~
2476                                      keyword ~S~%"
2477                     :format-arguments (list arg)))
2478            ;; When we are at a lambda-list keyword, the parameters
2479            ;; don't include the lambda-list keyword; the lambda-list
2480            ;; does include the lambda-list keyword; and no
2481            ;; specializers are allowed to follow the lambda-list
2482            ;; keywords (at least for now).
2483            (multiple-value-bind (parameters lambda-list)
2484                (parse-specialized-lambda-list (cdr arglist)
2485                                               (cons arg supplied-keywords)
2486                                               (if (eq arg '&key)
2487                                                   (cons '&allow-other-keys
2488                                                         (cdr (member arg allowed-keywords)))
2489                                                 (cdr (member arg allowed-keywords))))
2490              (when (and (eq arg '&rest)
2491                         (or (null lambda-list)
2492                             (memq (car lambda-list)
2493                                   specialized-lambda-list-keywords)
2494                             (not (or (null (cadr lambda-list))
2495                                      (memq (cadr lambda-list)
2496                                            specialized-lambda-list-keywords)))))
2497                (error 'specialized-lambda-list-error
2498                       :format-control
2499                       "in a specialized-lambda-list, excactly one ~
2500                        variable must follow &REST.~%"
2501                       :format-arguments nil))
2502              (values parameters
2503                      (cons arg lambda-list)
2504                      ()
2505                      ())))
2506           (supplied-keywords
2507            ;; After a lambda-list keyword there can be no specializers.
2508            (multiple-value-bind (parameters lambda-list)
2509                (parse-specialized-lambda-list (cdr arglist)
2510                                               supplied-keywords
2511                                               allowed-keywords)
2512              (values (cons (if (listp arg) (car arg) arg) parameters)
2513                      (cons arg lambda-list)
2514                      ()
2515                      ())))
2516           (t
2517            (multiple-value-bind (parameters lambda-list specializers required)
2518                (parse-specialized-lambda-list (cdr arglist))
2519              (values (cons (if (listp arg) (car arg) arg) parameters)
2520                      (cons (if (listp arg) (car arg) arg) lambda-list)
2521                      (cons (if (listp arg) (cadr arg) t) specializers)
2522                      (cons (if (listp arg) (car arg) arg) required)))))))
2523 \f
2524 (setq *boot-state* 'early)
2525 \f
2526 ;;; FIXME: In here there was a #-CMU definition of SYMBOL-MACROLET
2527 ;;; which used %WALKER stuff. That suggests to me that maybe the code
2528 ;;; walker stuff was only used for implementing stuff like that; maybe
2529 ;;; it's not needed any more? Hunt down what it was used for and see.
2530
2531 (defmacro with-slots (slots instance &body body)
2532   (let ((in (gensym)))
2533     `(let ((,in ,instance))
2534        (declare (ignorable ,in))
2535        ,@(let ((instance (if (and (consp instance) (eq (car instance) 'the))
2536                              (third instance)
2537                              instance)))
2538            (and (symbolp instance)
2539                 `((declare (%variable-rebinding ,in ,instance)))))
2540        ,in
2541        (symbol-macrolet ,(mapcar (lambda (slot-entry)
2542                                    (let ((var-name
2543                                           (if (symbolp slot-entry)
2544                                               slot-entry
2545                                               (car slot-entry)))
2546                                          (slot-name
2547                                           (if (symbolp slot-entry)
2548                                               slot-entry
2549                                               (cadr slot-entry))))
2550                                      `(,var-name
2551                                        (slot-value ,in ',slot-name))))
2552                                  slots)
2553                         ,@body))))
2554
2555 (defmacro with-accessors (slots instance &body body)
2556   (let ((in (gensym)))
2557     `(let ((,in ,instance))
2558        (declare (ignorable ,in))
2559        ,@(let ((instance (if (and (consp instance) (eq (car instance) 'the))
2560                              (third instance)
2561                              instance)))
2562            (and (symbolp instance)
2563                 `((declare (%variable-rebinding ,in ,instance)))))
2564        ,in
2565        (symbol-macrolet ,(mapcar (lambda (slot-entry)
2566                                    (let ((var-name (car slot-entry))
2567                                          (accessor-name (cadr slot-entry)))
2568                                      `(,var-name (,accessor-name ,in))))
2569                                  slots)
2570           ,@body))))