src/pcl/braid.lisp

   1 ;;;; bootstrapping the meta-braid
   2 ;;;;
   3 ;;;; The code in this file takes the early definitions that have been
   4 ;;;; saved up and actually builds those class objects. This work is
   5 ;;;; largely driven off of those class definitions, but the fact that
   6 ;;;; STANDARD-CLASS is the class of all metaclasses in the braid is
   7 ;;;; built into this code pretty deeply.
   8
   9 ;;;; This software is part of the SBCL system. See the README file for
  10 ;;;; more information.
  11
  12 ;;;; This software is derived from software originally released by Xerox
  13 ;;;; Corporation. Copyright and release statements follow. Later modifications
  14 ;;;; to the software are in the public domain and are provided with
  15 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
  16 ;;;; information.
  17
  18 ;;;; copyright information from original PCL sources:
  19 ;;;;
  20 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  21 ;;;; All rights reserved.
  22 ;;;;
  23 ;;;; Use and copying of this software and preparation of derivative works based
  24 ;;;; upon this software are permitted. Any distribution of this software or
  25 ;;;; derivative works must comply with all applicable United States export
  26 ;;;; control laws.
  27 ;;;;
  28 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  29 ;;;; warranty about the software, its performance or its conformity to any
  30 ;;;; specification.
  31
  32 (in-package "SB-PCL")
  33 \f
  34 (defun allocate-standard-instance (wrapper
  35                                    &optional (slots-init nil slots-init-p))
  36   (let ((instance (%make-standard-instance nil (get-instance-hash-code)))
  37         (no-of-slots (wrapper-no-of-instance-slots wrapper)))
  38     (setf (std-instance-wrapper instance) wrapper)
  39     (setf (std-instance-slots instance)
  40           (cond (slots-init-p
  41                  ;; Inline the slots vector allocation and initialization.
  42                  (let ((slots (make-array no-of-slots :initial-element 0)))
  43                    (do ((rem-slots slots-init (rest rem-slots))
  44                         (i 0 (1+ i)))
  45                        ((>= i no-of-slots)) ;endp rem-slots))
  46                      (declare (list rem-slots)
  47                               (type index i))
  48                      (setf (aref slots i) (first rem-slots)))
  49                    slots))
  50                 (t
  51                  (make-array no-of-slots
  52                              :initial-element +slot-unbound+))))
  53     instance))
  54
  55 (defmacro allocate-funcallable-instance-slots (wrapper &optional
  56                                                        slots-init-p slots-init)
  57   `(let ((no-of-slots (wrapper-no-of-instance-slots ,wrapper)))
  58      ,(if slots-init-p
  59           `(if ,slots-init-p
  60                (make-array no-of-slots :initial-contents ,slots-init)
  61                (make-array no-of-slots :initial-element +slot-unbound+))
  62           `(make-array no-of-slots :initial-element +slot-unbound+))))
  63
  64 (defun allocate-funcallable-instance (wrapper &optional
  65                                               (slots-init nil slots-init-p))
  66   (let ((fin (%make-pcl-funcallable-instance nil nil
  67                                              (get-instance-hash-code))))
  68     (set-funcallable-instance-function
  69      fin
  70      #'(lambda (&rest args)
  71          (declare (ignore args))
  72          (error "The function of the funcallable-instance ~S has not been set."
  73                 fin)))
  74     (setf (fsc-instance-wrapper fin) wrapper
  75           (fsc-instance-slots fin) (allocate-funcallable-instance-slots
  76                                     wrapper slots-init-p slots-init))
  77     fin))
  78
  79 (defun allocate-structure-instance (wrapper &optional
  80                                             (slots-init nil slots-init-p))
  81   (let* ((class (wrapper-class wrapper))
  82          (constructor (class-defstruct-constructor class)))
  83     (if constructor
  84         (let ((instance (funcall constructor))
  85               (slots (class-slots class)))
  86           (when slots-init-p
  87             (dolist (slot slots)
  88               (setf (slot-value-using-class class instance slot)
  89                     (pop slots-init))))
  90           instance)
  91         (error "can't allocate an instance of class ~S" (class-name class)))))
  92 \f
  93 ;;;; BOOTSTRAP-META-BRAID
  94 ;;;;
  95 ;;;; This function builds the base metabraid from the early class definitions.
  96
  97 (defmacro !initial-classes-and-wrappers (&rest classes)
  98   `(progn
  99      ,@(mapcar (lambda (class)
 100                  (let ((wr (format-symbol *pcl-package* "~A-WRAPPER" class)))
 101                    `(setf ,wr ,(if (eq class 'standard-generic-function)
 102                                    '*sgf-wrapper*
 103                                    `(boot-make-wrapper
 104                                      (early-class-size ',class)
 105                                      ',class))
 106                           ,class (allocate-standard-instance
 107                                   ,(if (eq class 'standard-generic-function)
 108                                        'funcallable-standard-class-wrapper
 109                                        'standard-class-wrapper))
 110                           (wrapper-class ,wr) ,class
 111                           (find-class ',class) ,class)))
 112                classes)))
 113
 114 (defun !bootstrap-meta-braid ()
 115   (let* ((*create-classes-from-internal-structure-definitions-p* nil)
 116          standard-class-wrapper standard-class
 117          funcallable-standard-class-wrapper funcallable-standard-class
 118          slot-class-wrapper slot-class
 119          built-in-class-wrapper built-in-class
 120          structure-class-wrapper structure-class
 121          condition-class-wrapper condition-class
 122          standard-direct-slot-definition-wrapper
 123          standard-direct-slot-definition
 124          standard-effective-slot-definition-wrapper
 125          standard-effective-slot-definition
 126          class-eq-specializer-wrapper class-eq-specializer
 127          standard-generic-function-wrapper standard-generic-function)
 128     (!initial-classes-and-wrappers
 129      standard-class funcallable-standard-class
 130      slot-class built-in-class structure-class condition-class
 131      standard-direct-slot-definition standard-effective-slot-definition
 132      class-eq-specializer standard-generic-function)
 133     ;; First, make a class metaobject for each of the early classes. For
 134     ;; each metaobject we also set its wrapper. Except for the class T,
 135     ;; the wrapper is always that of STANDARD-CLASS.
 136     (dolist (definition *early-class-definitions*)
 137       (let* ((name (ecd-class-name definition))
 138              (meta (ecd-metaclass definition))
 139              (wrapper (ecase meta
 140                         (slot-class slot-class-wrapper)
 141                         (standard-class standard-class-wrapper)
 142                         (funcallable-standard-class
 143                          funcallable-standard-class-wrapper)
 144                         (built-in-class built-in-class-wrapper)
 145                         (structure-class structure-class-wrapper)
 146                         (condition-class condition-class-wrapper)))
 147              (class (or (find-class name nil)
 148                         (allocate-standard-instance wrapper))))
 149         (setf (find-class name) class)))
 150     (dolist (definition *early-class-definitions*)
 151       (let ((name (ecd-class-name definition))
 152             (meta (ecd-metaclass definition))
 153             (source (ecd-source-location definition))
 154             (direct-supers (ecd-superclass-names definition))
 155             (direct-slots  (ecd-canonical-slots definition))
 156             (other-initargs (ecd-other-initargs definition)))
 157         (let ((direct-default-initargs
 158                (getf other-initargs :direct-default-initargs)))
 159           (multiple-value-bind (slots cpl default-initargs direct-subclasses)
 160               (early-collect-inheritance name)
 161             (let* ((class (find-class name))
 162                    (wrapper (cond ((eq class slot-class)
 163                                    slot-class-wrapper)
 164                                   ((eq class standard-class)
 165                                    standard-class-wrapper)
 166                                   ((eq class funcallable-standard-class)
 167                                    funcallable-standard-class-wrapper)
 168                                   ((eq class standard-direct-slot-definition)
 169                                    standard-direct-slot-definition-wrapper)
 170                                   ((eq class
 171                                        standard-effective-slot-definition)
 172                                    standard-effective-slot-definition-wrapper)
 173                                   ((eq class built-in-class)
 174                                    built-in-class-wrapper)
 175                                   ((eq class structure-class)
 176                                    structure-class-wrapper)
 177                                   ((eq class condition-class)
 178                                    condition-class-wrapper)
 179                                   ((eq class class-eq-specializer)
 180                                    class-eq-specializer-wrapper)
 181                                   ((eq class standard-generic-function)
 182                                    standard-generic-function-wrapper)
 183                                   (t
 184                                    (boot-make-wrapper (length slots) name))))
 185                    (proto nil))
 186               (when (eq name t) (setq *the-wrapper-of-t* wrapper))
 187               (set (make-class-symbol name) class)
 188               (dolist (slot slots)
 189                 (unless (eq (getf slot :allocation :instance) :instance)
 190                   (error "Slot allocation ~S is not supported in bootstrap."
 191                          (getf slot :allocation))))
 192
 193               (when (typep wrapper 'wrapper)
 194                 (setf (wrapper-instance-slots-layout wrapper)
 195                       (mapcar #'canonical-slot-name slots))
 196                 (setf (wrapper-class-slots wrapper)
 197                       ()))
 198
 199               (setq proto (if (eq meta 'funcallable-standard-class)
 200                               (allocate-funcallable-instance wrapper)
 201                               (allocate-standard-instance wrapper)))
 202
 203               (setq direct-slots
 204                     (!bootstrap-make-slot-definitions
 205                      name class direct-slots
 206                      standard-direct-slot-definition-wrapper nil))
 207               (setq slots
 208                     (!bootstrap-make-slot-definitions
 209                      name class slots
 210                      standard-effective-slot-definition-wrapper t))
 211
 212               (case meta
 213                 ((standard-class funcallable-standard-class)
 214                  (!bootstrap-initialize-class
 215                   meta
 216                   class name class-eq-specializer-wrapper source
 217                   direct-supers direct-subclasses cpl wrapper proto
 218                   direct-slots slots direct-default-initargs default-initargs))
 219                 (built-in-class         ; *the-class-t*
 220                  (!bootstrap-initialize-class
 221                   meta
 222                   class name class-eq-specializer-wrapper source
 223                   direct-supers direct-subclasses cpl wrapper proto))
 224                 (slot-class             ; *the-class-slot-object*
 225                  (!bootstrap-initialize-class
 226                   meta
 227                   class name class-eq-specializer-wrapper source
 228                   direct-supers direct-subclasses cpl wrapper proto))
 229                 (structure-class        ; *the-class-structure-object*
 230                  (!bootstrap-initialize-class
 231                   meta
 232                   class name class-eq-specializer-wrapper source
 233                   direct-supers direct-subclasses cpl wrapper))
 234                 (condition-class
 235                  (!bootstrap-initialize-class
 236                   meta
 237                   class name class-eq-specializer-wrapper source
 238                   direct-supers direct-subclasses cpl wrapper))))))))
 239
 240     (let* ((smc-class (find-class 'standard-method-combination))
 241            (smc-wrapper (!bootstrap-get-slot 'standard-class
 242                                              smc-class
 243                                              'wrapper))
 244            (smc (allocate-standard-instance smc-wrapper)))
 245       (flet ((set-slot (name value)
 246                (!bootstrap-set-slot 'standard-method-combination
 247                                     smc
 248                                     name
 249                                     value)))
 250         (set-slot 'source nil)
 251         (set-slot 'type-name 'standard)
 252         (set-slot '%documentation "The standard method combination.")
 253         (set-slot 'options ()))
 254       (setq *standard-method-combination* smc))))
 255
 256 ;;; Initialize a class metaobject.
 257 (defun !bootstrap-initialize-class
 258        (metaclass-name class name
 259         class-eq-wrapper source direct-supers direct-subclasses cpl wrapper
 260         &optional
 261         (proto nil proto-p)
 262         direct-slots slots direct-default-initargs default-initargs)
 263   (flet ((classes (names) (mapcar #'find-class names))
 264          (set-slot (slot-name value)
 265            (!bootstrap-set-slot metaclass-name class slot-name value)))
 266     (set-slot 'name name)
 267     (set-slot 'finalized-p t)
 268     (set-slot 'source source)
 269     (set-slot '%type (if (eq class (find-class t))
 270                          t
 271                          ;; FIXME: Could this just be CLASS instead
 272                          ;; of `(CLASS ,CLASS)? If not, why not?
 273                          ;; (See also similar expression in
 274                          ;; SHARED-INITIALIZE :BEFORE (CLASS).)
 275                          `(class ,class)))
 276     (set-slot 'class-eq-specializer
 277               (let ((spec (allocate-standard-instance class-eq-wrapper)))
 278                 (!bootstrap-set-slot 'class-eq-specializer spec '%type
 279                                      `(class-eq ,class))
 280                 (!bootstrap-set-slot 'class-eq-specializer spec 'object
 281                                      class)
 282                 spec))
 283     (set-slot '%class-precedence-list (classes cpl))
 284     (set-slot 'cpl-available-p t)
 285     (set-slot 'can-precede-list (classes (cdr cpl)))
 286     (set-slot 'incompatible-superclass-list nil)
 287     (set-slot 'direct-superclasses (classes direct-supers))
 288     (set-slot 'direct-subclasses (classes direct-subclasses))
 289     (set-slot 'direct-methods (cons nil nil))
 290     (set-slot 'wrapper wrapper)
 291     (set-slot '%documentation nil)
 292     (set-slot 'plist
 293               `(,@(and direct-default-initargs
 294                        `(direct-default-initargs ,direct-default-initargs))
 295                 ,@(and default-initargs
 296                        `(default-initargs ,default-initargs))))
 297     (when (memq metaclass-name '(standard-class funcallable-standard-class
 298                                  structure-class condition-class
 299                                  slot-class))
 300       (set-slot 'direct-slots direct-slots)
 301       (set-slot 'slots slots))
 302
 303     ;; For all direct superclasses SUPER of CLASS, make sure CLASS is
 304     ;; a direct subclass of SUPER.  Note that METACLASS-NAME doesn't
 305     ;; matter here for the slot DIRECT-SUBCLASSES, since every class
 306     ;; inherits the slot from class CLASS.
 307     (dolist (super direct-supers)
 308       (let* ((super (find-class super))
 309              (subclasses (!bootstrap-get-slot metaclass-name super
 310                                               'direct-subclasses)))
 311         (cond ((eq +slot-unbound+ subclasses)
 312                (!bootstrap-set-slot metaclass-name super 'direct-subclasses
 313                                     (list class)))
 314               ((not (memq class subclasses))
 315                (!bootstrap-set-slot metaclass-name super 'direct-subclasses
 316                                     (cons class subclasses))))))
 317
 318     (case metaclass-name
 319       (structure-class
 320        (let ((constructor-sym '|STRUCTURE-OBJECT class constructor|))
 321          (set-slot 'defstruct-form
 322                    `(defstruct (structure-object (:constructor
 323                                                   ,constructor-sym)
 324                                                  (:copier nil))))
 325          (set-slot 'defstruct-constructor constructor-sym)
 326          (set-slot 'from-defclass-p t)
 327          (set-slot 'plist nil)
 328          (set-slot 'prototype (funcall constructor-sym))))
 329       (condition-class
 330        (set-slot 'prototype (make-condition name)))
 331       (t
 332        (set-slot 'prototype
 333                  (if proto-p proto (allocate-standard-instance wrapper)))))
 334     class))
 335
 336 (defun !bootstrap-make-slot-definitions (name class slots wrapper effective-p)
 337   (let ((index -1))
 338     (mapcar (lambda (slot)
 339               (incf index)
 340               (!bootstrap-make-slot-definition
 341                name class slot wrapper effective-p index))
 342             slots)))
 343
 344 (defun !bootstrap-make-slot-definition
 345     (name class slot wrapper effective-p index)
 346   (let* ((slotd-class-name (if effective-p
 347                                'standard-effective-slot-definition
 348                                'standard-direct-slot-definition))
 349          (slotd (allocate-standard-instance wrapper))
 350          (slot-name (getf slot :name)))
 351     (flet ((get-val (name) (getf slot name))
 352            (set-val (name val)
 353                     (!bootstrap-set-slot slotd-class-name slotd name val)))
 354       (set-val 'name         slot-name)
 355       (set-val 'initform     (get-val :initform))
 356       (set-val 'initfunction (get-val :initfunction))
 357       (set-val 'initargs     (get-val :initargs))
 358       (set-val 'readers      (get-val :readers))
 359       (set-val 'writers      (get-val :writers))
 360       (set-val 'allocation   :instance)
 361       (set-val '%type        (or (get-val :type) t))
 362       (set-val '%documentation (or (get-val :documentation) ""))
 363       (set-val '%class   class)
 364       (when effective-p
 365         (set-val 'location index)
 366         (let ((fsc-p nil))
 367           (set-val 'reader-function (make-optimized-std-reader-method-function
 368                                      fsc-p nil slot-name index))
 369           (set-val 'writer-function (make-optimized-std-writer-method-function
 370                                      fsc-p nil slot-name index))
 371           (set-val 'boundp-function (make-optimized-std-boundp-method-function
 372                                      fsc-p nil slot-name index)))
 373         (set-val 'accessor-flags 7))
 374       (when (and (eq name 'standard-class)
 375                  (eq slot-name 'slots) effective-p)
 376         (setq *the-eslotd-standard-class-slots* slotd))
 377       (when (and (eq name 'funcallable-standard-class)
 378                  (eq slot-name 'slots) effective-p)
 379         (setq *the-eslotd-funcallable-standard-class-slots* slotd))
 380       slotd)))
 381
 382 (defun !bootstrap-accessor-definitions (early-p)
 383   (let ((*early-p* early-p))
 384     (dolist (definition *early-class-definitions*)
 385       (let ((name (ecd-class-name definition))
 386             (meta (ecd-metaclass definition)))
 387         (unless (eq meta 'built-in-class)
 388           (let ((direct-slots  (ecd-canonical-slots definition)))
 389             (dolist (slotd direct-slots)
 390               (let ((slot-name (getf slotd :name))
 391                     (readers (getf slotd :readers))
 392                     (writers (getf slotd :writers)))
 393                 (!bootstrap-accessor-definitions1
 394                  name
 395                  slot-name
 396                  readers
 397                  writers
 398                  nil)))))))))
 399
 400 (defun !bootstrap-accessor-definition (class-name accessor-name slot-name type)
 401   (multiple-value-bind (accessor-class make-method-function arglist specls doc)
 402       (ecase type
 403         (reader (values 'standard-reader-method
 404                         #'make-std-reader-method-function
 405                         (list class-name)
 406                         (list class-name)
 407                         "automatically generated reader method"))
 408         (writer (values 'standard-writer-method
 409                         #'make-std-writer-method-function
 410                         (list 'new-value class-name)
 411                         (list t class-name)
 412                         "automatically generated writer method"))
 413         (boundp (values 'standard-boundp-method
 414                         #'make-std-boundp-method-function
 415                         (list class-name)
 416                         (list class-name)
 417                         "automatically generated boundp method")))
 418     (let ((gf (ensure-generic-function accessor-name
 419                                        :lambda-list arglist)))
 420       (if (find specls (early-gf-methods gf)
 421                 :key #'early-method-specializers
 422                 :test 'equal)
 423           (unless (assoc accessor-name *!generic-function-fixups*
 424                          :test #'equal)
 425             (update-dfun gf))
 426           (add-method gf
 427                       (make-a-method accessor-class
 428                                      ()
 429                                      arglist specls
 430                                      (funcall make-method-function
 431                                               class-name slot-name)
 432                                      doc
 433                                      :slot-name slot-name
 434                                      :object-class class-name
 435                                      :method-class-function (constantly (find-class accessor-class))))))))
 436
 437 (defun !bootstrap-accessor-definitions1 (class-name
 438                                         slot-name
 439                                         readers
 440                                         writers
 441                                         boundps)
 442   (flet ((do-reader-definition (reader)
 443            (!bootstrap-accessor-definition class-name
 444                                            reader
 445                                            slot-name
 446                                            'reader))
 447          (do-writer-definition (writer)
 448            (!bootstrap-accessor-definition class-name
 449                                            writer
 450                                            slot-name
 451                                            'writer))
 452          (do-boundp-definition (boundp)
 453            (!bootstrap-accessor-definition class-name
 454                                            boundp
 455                                            slot-name
 456                                            'boundp)))
 457     (dolist (reader readers) (do-reader-definition reader))
 458     (dolist (writer writers) (do-writer-definition writer))
 459     (dolist (boundp boundps) (do-boundp-definition boundp))))
 460
 461 ;;; FIXME: find a better name.
 462 (defun !bootstrap-class-predicates (early-p)
 463   (let ((*early-p* early-p))
 464     (dolist (ecp *early-class-predicates*)
 465       (let ((class-name (car ecp))
 466             (predicate-name (cadr ecp)))
 467         (make-class-predicate (find-class class-name) predicate-name)))))
 468
 469 (defun !bootstrap-built-in-classes ()
 470
 471   ;; First make sure that all the supers listed in
 472   ;; *BUILT-IN-CLASS-LATTICE* are themselves defined by
 473   ;; *BUILT-IN-CLASS-LATTICE*. This is just to check for typos and
 474   ;; other sorts of brainos.
 475   (dolist (e *built-in-classes*)
 476     (dolist (super (cadr e))
 477       (unless (or (eq super t)
 478                   (assq super *built-in-classes*))
 479         (error "in *BUILT-IN-CLASSES*: ~S has ~S as a super,~%~
 480                 but ~S is not itself a class in *BUILT-IN-CLASSES*."
 481                (car e) super super))))
 482
 483   ;; In the first pass, we create a skeletal object to be bound to the
 484   ;; class name.
 485   (let* ((built-in-class (find-class 'built-in-class))
 486          (built-in-class-wrapper (class-wrapper built-in-class)))
 487     (dolist (e *built-in-classes*)
 488       (let ((class (allocate-standard-instance built-in-class-wrapper)))
 489         (setf (find-class (car e)) class))))
 490
 491   ;; In the second pass, we initialize the class objects.
 492   (let ((class-eq-wrapper (class-wrapper (find-class 'class-eq-specializer))))
 493     (dolist (e *built-in-classes*)
 494       (destructuring-bind (name supers subs cpl prototype) e
 495         (let* ((class (find-class name))
 496                (lclass (find-classoid name))
 497                (wrapper (classoid-layout lclass)))
 498           (set (get-built-in-class-symbol name) class)
 499           (set (get-built-in-wrapper-symbol name) wrapper)
 500           (setf (classoid-pcl-class lclass) class)
 501
 502           (!bootstrap-initialize-class 'built-in-class class
 503                                        name class-eq-wrapper nil
 504                                        supers subs
 505                                        (cons name cpl)
 506                                        wrapper prototype))))))
 507 \f
 508 (defmacro wrapper-of-macro (x)
 509   `(layout-of ,x))
 510
 511 (defun class-of (x)
 512   (wrapper-class* (wrapper-of-macro x)))
 513
 514 ;;; FIXME: We probably don't need both WRAPPER-OF and WRAPPER-OF-MACRO.
 515 #-sb-fluid (declaim (inline wrapper-of))
 516 (defun wrapper-of (x)
 517   (wrapper-of-macro x))
 518
 519 (defun eval-form (form)
 520   (lambda () (eval form)))
 521
 522 (defun ensure-non-standard-class (name &optional existing-class)
 523   (flet
 524       ((ensure (metaclass &optional (slots nil slotsp))
 525          (let ((supers
 526                 (mapcar #'classoid-name (classoid-direct-superclasses
 527                                          (find-classoid name)))))
 528            (if slotsp
 529                (ensure-class-using-class existing-class name
 530                                          :metaclass metaclass :name name
 531                                          :direct-superclasses supers
 532                                          :direct-slots slots)
 533                (ensure-class-using-class existing-class name
 534                                          :metaclass metaclass :name name
 535                                          :direct-superclasses supers))))
 536        (slot-initargs-from-structure-slotd (slotd)
 537          (let ((accessor (structure-slotd-accessor-symbol slotd)))
 538            `(:name ,(structure-slotd-name slotd)
 539              :defstruct-accessor-symbol ,accessor
 540              ,@(when (fboundp accessor)
 541                  `(:internal-reader-function
 542                    ,(structure-slotd-reader-function slotd)
 543                    :internal-writer-function
 544                    ,(structure-slotd-writer-function name slotd)))
 545              :type ,(or (structure-slotd-type slotd) t)
 546              :initform ,(structure-slotd-init-form slotd)
 547              :initfunction ,(eval-form (structure-slotd-init-form slotd)))))
 548        (slot-initargs-from-condition-slot (slot)
 549          `(:name ,(condition-slot-name slot)
 550            :initargs ,(condition-slot-initargs slot)
 551            :readers ,(condition-slot-readers slot)
 552            :writers ,(condition-slot-writers slot)
 553            ,@(when (condition-slot-initform-p slot)
 554                (let ((form-or-fun (condition-slot-initform slot)))
 555                  (if (functionp form-or-fun)
 556                      `(:initfunction ,form-or-fun)
 557                      `(:initform ,form-or-fun
 558                        :initfunction ,(lambda () form-or-fun)))))
 559            :allocation ,(condition-slot-allocation slot)
 560            :documentation ,(condition-slot-documentation slot))))
 561     (cond ((structure-type-p name)
 562            (ensure 'structure-class
 563                    (mapcar #'slot-initargs-from-structure-slotd
 564                            (structure-type-slot-description-list name))))
 565           ((condition-type-p name)
 566            (ensure 'condition-class
 567                    (mapcar #'slot-initargs-from-condition-slot
 568                            (condition-classoid-slots (find-classoid name)))))
 569           (t
 570            (error "~@<~S is not the name of a class.~@:>" name)))))
 571
 572 (defun ensure-deffoo-class (classoid)
 573   (let ((class (classoid-pcl-class classoid)))
 574     (cond (class
 575            (ensure-non-standard-class (class-name class) class))
 576           ((eq 'complete *boot-state*)
 577            (ensure-non-standard-class (classoid-name classoid))))))
 578
 579 (pushnew 'ensure-deffoo-class sb-kernel::*defstruct-hooks*)
 580 (pushnew 'ensure-deffoo-class sb-kernel::*define-condition-hooks*)
 581 \f
 582 (defun make-class-predicate (class name)
 583   (let* ((gf (ensure-generic-function name :lambda-list '(object)))
 584          (mlist (if (eq *boot-state* 'complete)
 585                     (generic-function-methods gf)
 586                     (early-gf-methods gf))))
 587     (unless mlist
 588       (unless (eq class *the-class-t*)
 589         (let* ((default-method-function #'constantly-nil)
 590                (default-method-initargs (list :function
 591                                               default-method-function))
 592                (default-method (make-a-method
 593                                 'standard-method
 594                                 ()
 595                                 (list 'object)
 596                                 (list *the-class-t*)
 597                                 default-method-initargs
 598                                 "class predicate default method")))
 599           (setf (method-function-get default-method-function :constant-value)
 600                 nil)
 601           (add-method gf default-method)))
 602       (let* ((class-method-function #'constantly-t)
 603              (class-method-initargs (list :function
 604                                           class-method-function))
 605              (class-method (make-a-method 'standard-method
 606                                           ()
 607                                           (list 'object)
 608                                           (list class)
 609                                           class-method-initargs
 610                                           "class predicate class method")))
 611         (setf (method-function-get class-method-function :constant-value) t)
 612         (add-method gf class-method)))
 613     gf))
 614
 615 ;;; Set the inherits from CPL, and register the layout. This actually
 616 ;;; installs the class in the Lisp type system.
 617 (defun update-lisp-class-layout (class layout)
 618   (let ((classoid (layout-classoid layout))
 619         (olayout (class-wrapper class)))
 620     (unless (eq (classoid-layout classoid) layout)
 621       (setf (layout-inherits layout)
 622             (order-layout-inherits
 623              (map 'simple-vector #'class-wrapper
 624                   (reverse (rest (class-precedence-list class))))))
 625       (register-layout layout :invalidate t)
 626
 627       ;; FIXME: I don't think this should be necessary, but without it
 628       ;; we are unable to compile (TYPEP foo '<class-name>) in the
 629       ;; same file as the class is defined.  If we had environments,
 630       ;; then I think the classsoid whould only be associated with the
 631       ;; name in that environment...  Alternatively, fix the compiler
 632       ;; so that TYPEP foo '<class-name> is slow but compileable.
 633       (let ((name (class-name class)))
 634         (when (and name (symbolp name) (eq name (classoid-name classoid)))
 635           (setf (find-classoid name) classoid))))))
 636
 637 (defun set-class-type-translation (class classoid)
 638   (when (not (typep classoid 'classoid))
 639     (setq classoid (find-classoid classoid nil)))
 640   (etypecase classoid
 641     (null)
 642     (built-in-classoid
 643      (let ((translation (built-in-classoid-translation classoid)))
 644        (cond
 645          (translation
 646           (aver (ctype-p translation))
 647           (setf (info :type :translator class)
 648                 (lambda (spec) (declare (ignore spec)) translation)))
 649          (t
 650           (setf (info :type :translator class)
 651                 (lambda (spec) (declare (ignore spec)) classoid))))))
 652     (classoid
 653      (setf (info :type :translator class)
 654            (lambda (spec) (declare (ignore spec)) classoid)))))
 655
 656 (clrhash *find-class*)
 657 (!bootstrap-meta-braid)
 658 (!bootstrap-accessor-definitions t)
 659 (!bootstrap-class-predicates t)
 660 (!bootstrap-accessor-definitions nil)
 661 (!bootstrap-class-predicates nil)
 662 (!bootstrap-built-in-classes)
 663
 664 (dohash (name x *find-class*)
 665         (let* ((class (find-class-from-cell name x))
 666                (layout (class-wrapper class))
 667                (lclass (layout-classoid layout))
 668                (lclass-pcl-class (classoid-pcl-class lclass))
 669                (olclass (find-classoid name nil)))
 670           (if lclass-pcl-class
 671               (aver (eq class lclass-pcl-class))
 672               (setf (classoid-pcl-class lclass) class))
 673
 674           (update-lisp-class-layout class layout)
 675
 676           (cond (olclass
 677                  (aver (eq lclass olclass)))
 678                 (t
 679                  (setf (find-classoid name) lclass)))
 680
 681           (set-class-type-translation class name)))
 682
 683 (setq *boot-state* 'braid)
 684
 685 (defmethod no-applicable-method (generic-function &rest args)
 686   (error "~@<There is no applicable method for the generic function ~2I~_~S~
 687           ~I~_when called with arguments ~2I~_~S.~:>"
 688          generic-function
 689          args))
 690
 691 (defmethod no-next-method ((generic-function standard-generic-function)
 692                            (method standard-method) &rest args)
 693   (error "~@<There is no next method for the generic function ~2I~_~S~
 694           ~I~_when called from method ~2I~_~S~I~_with arguments ~2I~_~S.~:>"
 695          generic-function
 696          method
 697          args))
 698
 699 ;;; An extension to the ANSI standard: in the presence of e.g. a
 700 ;;; :BEFORE method, it would seem that going through
 701 ;;; NO-APPLICABLE-METHOD is prohibited, as in fact there is an
 702 ;;; applicable method.  -- CSR, 2002-11-15
 703 (defmethod no-primary-method (generic-function &rest args)
 704   (error "~@<There is no primary method for the generic function ~2I~_~S~
 705           ~I~_when called with arguments ~2I~_~S.~:>"
 706          generic-function
 707          args))
 708
 709 (defmethod invalid-qualifiers ((gf generic-function)
 710                                combin
 711                                method)
 712   (let ((qualifiers (method-qualifiers method)))
 713     (let ((why (cond
 714                  ((cdr qualifiers) "has too many qualifiers")
 715                  (t (aver (not (member (car qualifiers)
 716                                        '(:around :before :after))))
 717                     "has an invalid qualifier"))))
 718       (invalid-method-error
 719        method
 720        "The method ~S on ~S ~A.~%~
 721         Standard method combination requires all methods to have one~%~
 722         of the single qualifiers :AROUND, :BEFORE and :AFTER or to~%~
 723         have no qualifier at all."
 724        method gf why))))