src/pcl/braid.lisp

   1 ;;;; bootstrapping the meta-braid
   2 ;;;;
   3 ;;;; The code in this file takes the early definitions that have been
   4 ;;;; saved up and actually builds those class objects. This work is
   5 ;;;; largely driven off of those class definitions, but the fact that
   6 ;;;; STANDARD-CLASS is the class of all metaclasses in the braid is
   7 ;;;; built into this code pretty deeply.
   8
   9 ;;;; This software is part of the SBCL system. See the README file for
  10 ;;;; more information.
  11
  12 ;;;; This software is derived from software originally released by Xerox
  13 ;;;; Corporation. Copyright and release statements follow. Later modifications
  14 ;;;; to the software are in the public domain and are provided with
  15 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
  16 ;;;; information.
  17
  18 ;;;; copyright information from original PCL sources:
  19 ;;;;
  20 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  21 ;;;; All rights reserved.
  22 ;;;;
  23 ;;;; Use and copying of this software and preparation of derivative works based
  24 ;;;; upon this software are permitted. Any distribution of this software or
  25 ;;;; derivative works must comply with all applicable United States export
  26 ;;;; control laws.
  27 ;;;;
  28 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  29 ;;;; warranty about the software, its performance or its conformity to any
  30 ;;;; specification.
  31
  32 (in-package "SB-PCL")
  33 \f
  34 (defun allocate-standard-instance (wrapper
  35                                    &optional (slots-init nil slots-init-p))
  36   (let ((instance (%%allocate-instance--class))
  37         (no-of-slots (wrapper-no-of-instance-slots wrapper)))
  38     (setf (std-instance-wrapper instance) wrapper)
  39     (setf (std-instance-slots instance)
  40           (cond (slots-init-p
  41                  ;; Inline the slots vector allocation and initialization.
  42                  (let ((slots (make-array no-of-slots :initial-element 0)))
  43                    (do ((rem-slots slots-init (rest rem-slots))
  44                         (i 0 (1+ i)))
  45                        ((>= i no-of-slots)) ;endp rem-slots))
  46                      (declare (list rem-slots)
  47                               (type index i))
  48                      (setf (aref slots i) (first rem-slots)))
  49                    slots))
  50                 (t
  51                  (make-array no-of-slots
  52                              :initial-element +slot-unbound+))))
  53     instance))
  54
  55 (defmacro allocate-funcallable-instance-slots (wrapper &optional
  56                                                        slots-init-p slots-init)
  57   `(let ((no-of-slots (wrapper-no-of-instance-slots ,wrapper)))
  58      ,(if slots-init-p
  59           `(if ,slots-init-p
  60                (make-array no-of-slots :initial-contents ,slots-init)
  61                (make-array no-of-slots :initial-element +slot-unbound+))
  62           `(make-array no-of-slots :initial-element +slot-unbound+))))
  63
  64 (defun allocate-funcallable-instance (wrapper &optional
  65                                               (slots-init nil slots-init-p))
  66   (let ((fin (allocate-funcallable-instance-1)))
  67     (set-funcallable-instance-function
  68      fin
  69      #'(sb-kernel:instance-lambda (&rest args)
  70          (declare (ignore args))
  71          (error "The function of the funcallable-instance ~S has not been set."
  72                 fin)))
  73     (setf (fsc-instance-wrapper fin) wrapper
  74           (fsc-instance-slots fin) (allocate-funcallable-instance-slots
  75                                     wrapper slots-init-p slots-init))
  76     fin))
  77
  78 (defun allocate-structure-instance (wrapper &optional
  79                                             (slots-init nil slots-init-p))
  80   (let* ((class (wrapper-class wrapper))
  81          (constructor (class-defstruct-constructor class)))
  82     (if constructor
  83         (let ((instance (funcall constructor))
  84               (slots (class-slots class)))
  85           (when slots-init-p
  86             (dolist (slot slots)
  87               (setf (slot-value-using-class class instance slot)
  88                     (pop slots-init))))
  89           instance)
  90         (error "can't allocate an instance of class ~S" (class-name class)))))
  91 \f
  92 ;;;; BOOTSTRAP-META-BRAID
  93 ;;;;
  94 ;;;; This function builds the base metabraid from the early class definitions.
  95 ;;;;
  96 ;;;; FIXME: This, like lotso the other stuff in PCL, is not needed in target
  97 ;;;; Lisp, only at bootstrap time. Perhaps we should do something kludgy like
  98 ;;;; putting a special character (#\$, perhaps) at the beginning of each
  99 ;;;; needed-only-at-bootstrap-time symbol and then UNINTERN them all once we're
 100 ;;;; done bootstrapping?
 101
 102 (defmacro initial-classes-and-wrappers (&rest classes)
 103   `(progn
 104      ,@(mapcar #'(lambda (class)
 105                    (let ((wr (intern (format nil "~A-WRAPPER" class)
 106                                      *pcl-package*)))
 107                      `(setf ,wr ,(if (eq class 'standard-generic-function)
 108                                      '*sgf-wrapper*
 109                                      `(boot-make-wrapper
 110                                        (early-class-size ',class)
 111                                        ',class))
 112                             ,class (allocate-standard-instance
 113                                     ,(if (eq class 'standard-generic-function)
 114                                          'funcallable-standard-class-wrapper
 115                                          'standard-class-wrapper))
 116                             (wrapper-class ,wr) ,class
 117                             (find-class ',class) ,class)))
 118               classes)))
 119
 120 (defun !bootstrap-meta-braid ()
 121   (let* ((name 'class)
 122          (predicate-name (make-type-predicate-name name)))
 123     (setf (gdefinition predicate-name)
 124           #'(lambda (x) (declare (ignore x)) t))
 125     (do-satisfies-deftype name predicate-name))
 126   (let* ((*create-classes-from-internal-structure-definitions-p* nil)
 127          std-class-wrapper std-class
 128          standard-class-wrapper standard-class
 129          funcallable-standard-class-wrapper funcallable-standard-class
 130          slot-class-wrapper slot-class
 131          built-in-class-wrapper built-in-class
 132          structure-class-wrapper structure-class
 133          standard-direct-slot-definition-wrapper
 134          standard-direct-slot-definition
 135          standard-effective-slot-definition-wrapper
 136          standard-effective-slot-definition
 137          class-eq-specializer-wrapper class-eq-specializer
 138          standard-generic-function-wrapper standard-generic-function)
 139     (initial-classes-and-wrappers
 140      standard-class funcallable-standard-class
 141      slot-class built-in-class structure-class std-class
 142      standard-direct-slot-definition standard-effective-slot-definition
 143      class-eq-specializer standard-generic-function)
 144     ;; First, make a class metaobject for each of the early classes. For
 145     ;; each metaobject we also set its wrapper. Except for the class T,
 146     ;; the wrapper is always that of STANDARD-CLASS.
 147     (dolist (definition *early-class-definitions*)
 148       (let* ((name (ecd-class-name definition))
 149              (meta (ecd-metaclass definition))
 150              (wrapper (ecase meta
 151                         (slot-class slot-class-wrapper)
 152                         (std-class std-class-wrapper)
 153                         (standard-class standard-class-wrapper)
 154                         (funcallable-standard-class
 155                          funcallable-standard-class-wrapper)
 156                         (built-in-class built-in-class-wrapper)
 157                         (structure-class structure-class-wrapper)))
 158              (class (or (find-class name nil)
 159                         (allocate-standard-instance wrapper))))
 160         (when (or (eq meta 'standard-class)
 161                   (eq meta 'funcallable-standard-class))
 162           (inform-type-system-about-std-class name))
 163         (setf (find-class name) class)))
 164     (dolist (definition *early-class-definitions*)
 165       (let ((name (ecd-class-name definition))
 166             (meta (ecd-metaclass definition))
 167             (source (ecd-source definition))
 168             (direct-supers (ecd-superclass-names definition))
 169             (direct-slots  (ecd-canonical-slots definition))
 170             (other-initargs (ecd-other-initargs definition)))
 171         (let ((direct-default-initargs
 172                (getf other-initargs :direct-default-initargs)))
 173           (multiple-value-bind (slots cpl default-initargs direct-subclasses)
 174               (early-collect-inheritance name)
 175             (let* ((class (find-class name))
 176                    (wrapper (cond ((eq class slot-class)
 177                                    slot-class-wrapper)
 178                                   ((eq class std-class)
 179                                    std-class-wrapper)
 180                                   ((eq class standard-class)
 181                                    standard-class-wrapper)
 182                                   ((eq class funcallable-standard-class)
 183                                    funcallable-standard-class-wrapper)
 184                                   ((eq class standard-direct-slot-definition)
 185                                    standard-direct-slot-definition-wrapper)
 186                                   ((eq class
 187                                        standard-effective-slot-definition)
 188                                    standard-effective-slot-definition-wrapper)
 189                                   ((eq class built-in-class)
 190                                    built-in-class-wrapper)
 191                                   ((eq class structure-class)
 192                                    structure-class-wrapper)
 193                                   ((eq class class-eq-specializer)
 194                                    class-eq-specializer-wrapper)
 195                                   ((eq class standard-generic-function)
 196                                    standard-generic-function-wrapper)
 197                                   (t
 198                                    (boot-make-wrapper (length slots) name))))
 199                    (proto nil))
 200               (when (eq name t) (setq *the-wrapper-of-t* wrapper))
 201               (set (intern (format nil "*THE-CLASS-~A*" (symbol-name name))
 202                            *pcl-package*)
 203                    class)
 204               (dolist (slot slots)
 205                 (unless (eq (getf slot :allocation :instance) :instance)
 206                   (error "Slot allocation ~S is not supported in bootstrap.")))
 207
 208               (when (typep wrapper 'wrapper)
 209                 (setf (wrapper-instance-slots-layout wrapper)
 210                       (mapcar #'canonical-slot-name slots))
 211                 (setf (wrapper-class-slots wrapper)
 212                       ()))
 213
 214               (setq proto (if (eq meta 'funcallable-standard-class)
 215                               (allocate-funcallable-instance wrapper)
 216                               (allocate-standard-instance wrapper)))
 217
 218               (setq direct-slots
 219                     (!bootstrap-make-slot-definitions
 220                      name class direct-slots
 221                      standard-direct-slot-definition-wrapper nil))
 222               (setq slots
 223                     (!bootstrap-make-slot-definitions
 224                      name class slots
 225                      standard-effective-slot-definition-wrapper t))
 226
 227               (case meta
 228                 ((std-class standard-class funcallable-standard-class)
 229                  (!bootstrap-initialize-class
 230                   meta
 231                   class name class-eq-specializer-wrapper source
 232                   direct-supers direct-subclasses cpl wrapper proto
 233                   direct-slots slots direct-default-initargs default-initargs))
 234                 (built-in-class         ; *the-class-t*
 235                  (!bootstrap-initialize-class
 236                   meta
 237                   class name class-eq-specializer-wrapper source
 238                   direct-supers direct-subclasses cpl wrapper proto))
 239                 (slot-class             ; *the-class-slot-object*
 240                  (!bootstrap-initialize-class
 241                   meta
 242                   class name class-eq-specializer-wrapper source
 243                   direct-supers direct-subclasses cpl wrapper proto))
 244                 (structure-class        ; *the-class-structure-object*
 245                  (!bootstrap-initialize-class
 246                   meta
 247                   class name class-eq-specializer-wrapper source
 248                   direct-supers direct-subclasses cpl wrapper))))))))
 249
 250     (let* ((smc-class (find-class 'standard-method-combination))
 251            (smc-wrapper (!bootstrap-get-slot 'standard-class
 252                                              smc-class
 253                                              'wrapper))
 254            (smc (allocate-standard-instance smc-wrapper)))
 255       (flet ((set-slot (name value)
 256                (!bootstrap-set-slot 'standard-method-combination
 257                                     smc
 258                                     name
 259                                     value)))
 260         (set-slot 'source *load-truename*)
 261         (set-slot 'type 'standard)
 262         (set-slot 'documentation "The standard method combination.")
 263         (set-slot 'options ()))
 264       (setq *standard-method-combination* smc))))
 265
 266 ;;; Initialize a class metaobject.
 267 (defun !bootstrap-initialize-class
 268        (metaclass-name class name
 269         class-eq-wrapper source direct-supers direct-subclasses cpl wrapper
 270         &optional
 271         proto direct-slots slots direct-default-initargs default-initargs)
 272   (flet ((classes (names) (mapcar #'find-class names))
 273          (set-slot (slot-name value)
 274            (!bootstrap-set-slot metaclass-name class slot-name value)))
 275     (set-slot 'name name)
 276     (set-slot 'source source)
 277     (set-slot 'type (if (eq class (find-class t))
 278                         t
 279                         ;; FIXME: Could this just be CLASS instead
 280                         ;; of `(CLASS ,CLASS)? If not, why not?
 281                         ;; (See also similar expression in
 282                         ;; SHARED-INITIALIZE :BEFORE (CLASS).)
 283                         `(class ,class)))
 284     (set-slot 'class-eq-specializer
 285               (let ((spec (allocate-standard-instance class-eq-wrapper)))
 286                 (!bootstrap-set-slot 'class-eq-specializer spec 'type
 287                                      `(class-eq ,class))
 288                 (!bootstrap-set-slot 'class-eq-specializer spec 'object
 289                                      class)
 290                 spec))
 291     (set-slot 'class-precedence-list (classes cpl))
 292     (set-slot 'can-precede-list (classes (cdr cpl)))
 293     (set-slot 'incompatible-superclass-list nil)
 294     (set-slot 'direct-superclasses (classes direct-supers))
 295     (set-slot 'direct-subclasses (classes direct-subclasses))
 296     (set-slot 'direct-methods (cons nil nil))
 297     (set-slot 'wrapper wrapper)
 298     (set-slot 'predicate-name (or (cadr (assoc name *early-class-predicates*))
 299                                   (make-class-predicate-name name)))
 300     (set-slot 'plist
 301               `(,@(and direct-default-initargs
 302                        `(direct-default-initargs ,direct-default-initargs))
 303                 ,@(and default-initargs
 304                        `(default-initargs ,default-initargs))))
 305     (when (memq metaclass-name '(standard-class funcallable-standard-class
 306                                  structure-class slot-class std-class))
 307       (set-slot 'direct-slots direct-slots)
 308       (set-slot 'slots slots)
 309       (set-slot 'initialize-info nil))
 310     (if (eq metaclass-name 'structure-class)
 311         (let ((constructor-sym '|STRUCTURE-OBJECT class constructor|))
 312           (set-slot 'predicate-name (or (cadr (assoc name
 313                                                      *early-class-predicates*))
 314                                         (make-class-predicate-name name)))
 315           (set-slot 'defstruct-form
 316                     `(defstruct (structure-object (:constructor
 317                                                    ,constructor-sym)
 318                                                   (:copier nil))))
 319           (set-slot 'defstruct-constructor constructor-sym)
 320           (set-slot 'from-defclass-p t)
 321           (set-slot 'plist nil)
 322           (set-slot 'prototype (funcall constructor-sym)))
 323         (set-slot 'prototype (or proto (allocate-standard-instance wrapper))))
 324     class))
 325
 326 (defun !bootstrap-make-slot-definitions (name class slots wrapper effective-p)
 327   (let ((index -1))
 328     (mapcar (lambda (slot)
 329               (incf index)
 330               (!bootstrap-make-slot-definition
 331                name class slot wrapper effective-p index))
 332             slots)))
 333
 334 (defun !bootstrap-make-slot-definition
 335     (name class slot wrapper effective-p index)
 336   (let* ((slotd-class-name (if effective-p
 337                                'standard-effective-slot-definition
 338                                'standard-direct-slot-definition))
 339          (slotd (allocate-standard-instance wrapper))
 340          (slot-name (getf slot :name)))
 341     (flet ((get-val (name) (getf slot name))
 342            (set-val (name val)
 343                     (!bootstrap-set-slot slotd-class-name slotd name val)))
 344       (set-val 'name         slot-name)
 345       (set-val 'initform     (get-val :initform))
 346       (set-val 'initfunction (get-val :initfunction))
 347       (set-val 'initargs     (get-val :initargs))
 348       (set-val 'readers      (get-val :readers))
 349       (set-val 'writers      (get-val :writers))
 350       (set-val 'allocation   :instance)
 351       (set-val 'type         (or (get-val :type) t))
 352       (set-val 'documentation (or (get-val :documentation) ""))
 353       (set-val 'class   class)
 354       (when effective-p
 355         (set-val 'location index)
 356         (let ((fsc-p nil))
 357           (set-val 'reader-function (make-optimized-std-reader-method-function
 358                                      fsc-p slot-name index))
 359           (set-val 'writer-function (make-optimized-std-writer-method-function
 360                                      fsc-p slot-name index))
 361           (set-val 'boundp-function (make-optimized-std-boundp-method-function
 362                                      fsc-p slot-name index)))
 363         (set-val 'accessor-flags 7)
 364         (let ((table (or (gethash slot-name *name->class->slotd-table*)
 365                          (setf (gethash slot-name *name->class->slotd-table*)
 366                                (make-hash-table :test 'eq :size 5)))))
 367           (setf (gethash class table) slotd)))
 368       (when (and (eq name 'standard-class)
 369                  (eq slot-name 'slots) effective-p)
 370         (setq *the-eslotd-standard-class-slots* slotd))
 371       (when (and (eq name 'funcallable-standard-class)
 372                  (eq slot-name 'slots) effective-p)
 373         (setq *the-eslotd-funcallable-standard-class-slots* slotd))
 374       slotd)))
 375
 376 (defun !bootstrap-accessor-definitions (early-p)
 377   (let ((*early-p* early-p))
 378     (dolist (definition *early-class-definitions*)
 379       (let ((name (ecd-class-name definition))
 380             (meta (ecd-metaclass definition)))
 381         (unless (eq meta 'built-in-class)
 382           (let ((direct-slots  (ecd-canonical-slots definition)))
 383             (dolist (slotd direct-slots)
 384               (let ((slot-name (getf slotd :name))
 385                     (readers (getf slotd :readers))
 386                     (writers (getf slotd :writers)))
 387                 (!bootstrap-accessor-definitions1
 388                  name
 389                  slot-name
 390                  readers
 391                  writers
 392                  nil)
 393                 (!bootstrap-accessor-definitions1
 394                  'slot-object
 395                  slot-name
 396                  (list (slot-reader-symbol slot-name))
 397                  (list (slot-writer-symbol slot-name))
 398                  (list (slot-boundp-symbol slot-name)))))))))))
 399
 400 (defun !bootstrap-accessor-definition (class-name accessor-name slot-name type)
 401   (multiple-value-bind (accessor-class make-method-function arglist specls doc)
 402       (ecase type
 403         (reader (values 'standard-reader-method
 404                         #'make-std-reader-method-function
 405                         (list class-name)
 406                         (list class-name)
 407                         "automatically generated reader method"))
 408         (writer (values 'standard-writer-method
 409                         #'make-std-writer-method-function
 410                         (list 'new-value class-name)
 411                         (list t class-name)
 412                         "automatically generated writer method"))
 413         (boundp (values 'standard-boundp-method
 414                         #'make-std-boundp-method-function
 415                         (list class-name)
 416                         (list class-name)
 417                         "automatically generated boundp method")))
 418     (let ((gf (ensure-generic-function accessor-name)))
 419       (if (find specls (early-gf-methods gf)
 420                 :key #'early-method-specializers
 421                 :test 'equal)
 422           (unless (assoc accessor-name *!generic-function-fixups*
 423                          :test #'equal)
 424             (update-dfun gf))
 425           (add-method gf
 426                       (make-a-method accessor-class
 427                                      ()
 428                                      arglist specls
 429                                      (funcall make-method-function
 430                                               class-name slot-name)
 431                                      doc
 432                                      slot-name))))))
 433
 434 (defun !bootstrap-accessor-definitions1 (class-name
 435                                         slot-name
 436                                         readers
 437                                         writers
 438                                         boundps)
 439   (flet ((do-reader-definition (reader)
 440            (!bootstrap-accessor-definition class-name
 441                                            reader
 442                                            slot-name
 443                                            'reader))
 444          (do-writer-definition (writer)
 445            (!bootstrap-accessor-definition class-name
 446                                            writer
 447                                            slot-name
 448                                            'writer))
 449          (do-boundp-definition (boundp)
 450            (!bootstrap-accessor-definition class-name
 451                                            boundp
 452                                            slot-name
 453                                            'boundp)))
 454     (dolist (reader readers) (do-reader-definition reader))
 455     (dolist (writer writers) (do-writer-definition writer))
 456     (dolist (boundp boundps) (do-boundp-definition boundp))))
 457
 458 (defun !bootstrap-class-predicates (early-p)
 459   (let ((*early-p* early-p))
 460     (dolist (definition *early-class-definitions*)
 461       (let* ((name (ecd-class-name definition))
 462              (class (find-class name)))
 463         (setf (find-class-predicate name)
 464               (make-class-predicate class (class-predicate-name class)))))))
 465
 466 (defun !bootstrap-built-in-classes ()
 467
 468   ;; First make sure that all the supers listed in
 469   ;; *BUILT-IN-CLASS-LATTICE* are themselves defined by
 470   ;; *BUILT-IN-CLASS-LATTICE*. This is just to check for typos and
 471   ;; other sorts of brainos.
 472   (dolist (e *built-in-classes*)
 473     (dolist (super (cadr e))
 474       (unless (or (eq super t)
 475                   (assq super *built-in-classes*))
 476         (error "in *BUILT-IN-CLASSES*: ~S has ~S as a super,~%~
 477                 but ~S is not itself a class in *BUILT-IN-CLASSES*."
 478                (car e) super super))))
 479
 480   ;; In the first pass, we create a skeletal object to be bound to the
 481   ;; class name.
 482   (let* ((built-in-class (find-class 'built-in-class))
 483          (built-in-class-wrapper (class-wrapper built-in-class)))
 484     (dolist (e *built-in-classes*)
 485       (let ((class (allocate-standard-instance built-in-class-wrapper)))
 486         (setf (find-class (car e)) class))))
 487
 488   ;; In the second pass, we initialize the class objects.
 489   (let ((class-eq-wrapper (class-wrapper (find-class 'class-eq-specializer))))
 490     (dolist (e *built-in-classes*)
 491       (destructuring-bind (name supers subs cpl prototype) e
 492         (let* ((class (find-class name))
 493                (lclass (cl:find-class name))
 494                (wrapper (sb-kernel:class-layout lclass)))
 495           (set (get-built-in-class-symbol name) class)
 496           (set (get-built-in-wrapper-symbol name) wrapper)
 497           (setf (sb-kernel:class-pcl-class lclass) class)
 498
 499           (!bootstrap-initialize-class 'built-in-class class
 500                                        name class-eq-wrapper nil
 501                                        supers subs
 502                                        (cons name cpl)
 503                                        wrapper prototype)))))
 504
 505   (dolist (e *built-in-classes*)
 506     (let* ((name (car e))
 507            (class (find-class name)))
 508       (setf (find-class-predicate name)
 509             (make-class-predicate class (class-predicate-name class))))))
 510 \f
 511 (defmacro wrapper-of-macro (x)
 512   `(sb-kernel:layout-of ,x))
 513
 514 (defun class-of (x)
 515   (wrapper-class* (wrapper-of-macro x)))
 516
 517 ;;; FIXME: We probably don't need both WRAPPER-OF and WRAPPER-OF-MACRO.
 518 #-sb-fluid (declaim (inline wrapper-of))
 519 (defun wrapper-of (x)
 520   (wrapper-of-macro x))
 521
 522 (defvar *find-structure-class* nil)
 523
 524 (defun eval-form (form)
 525   #'(lambda () (eval form)))
 526
 527 (defun slot-initargs-from-structure-slotd (slotd)
 528   `(:name ,(structure-slotd-name slotd)
 529     :defstruct-accessor-symbol ,(structure-slotd-accessor-symbol slotd)
 530     :internal-reader-function ,(structure-slotd-reader-function slotd)
 531     :internal-writer-function ,(structure-slotd-writer-function slotd)
 532     :type ,(or (structure-slotd-type slotd) t)
 533     :initform ,(structure-slotd-init-form slotd)
 534     :initfunction ,(eval-form (structure-slotd-init-form slotd))))
 535
 536 (defun find-structure-class (symbol)
 537   (if (structure-type-p symbol)
 538       (unless (eq *find-structure-class* symbol)
 539         (let ((*find-structure-class* symbol))
 540           (ensure-class symbol
 541                         :metaclass 'structure-class
 542                         :name symbol
 543                         :direct-superclasses
 544                         (cond ;; Handle our CMU-CL-ish structure-based
 545                               ;; conditions.
 546                               ((cl:subtypep symbol 'condition)
 547                                (mapcar #'cl:class-name
 548                                        (sb-kernel:class-direct-superclasses
 549                                         (cl:find-class symbol))))
 550                               ;; a hack to add the STREAM class as a
 551                               ;; mixin to the LISP-STREAM class.
 552                               ((eq symbol 'sb-kernel:lisp-stream)
 553                                '(structure-object stream))
 554                               ((structure-type-included-type-name symbol)
 555                                (list (structure-type-included-type-name
 556                                       symbol))))
 557                         :direct-slots
 558                         (mapcar #'slot-initargs-from-structure-slotd
 559                                 (structure-type-slot-description-list
 560                                  symbol)))))
 561       (error "~S is not a legal structure class name." symbol)))
 562 \f
 563 (defun make-class-predicate (class name)
 564   (let* ((gf (ensure-generic-function name))
 565          (mlist (if (eq *boot-state* 'complete)
 566                     (generic-function-methods gf)
 567                     (early-gf-methods gf))))
 568     (unless mlist
 569       (unless (eq class *the-class-t*)
 570         (let* ((default-method-function #'constantly-nil)
 571                (default-method-initargs (list :function
 572                                               default-method-function))
 573                (default-method (make-a-method 'standard-method
 574                                               ()
 575                                               (list 'object)
 576                                               (list *the-class-t*)
 577                                               default-method-initargs
 578                                               "class predicate default method")))
 579           (setf (method-function-get default-method-function :constant-value)
 580                 nil)
 581           (add-method gf default-method)))
 582       (let* ((class-method-function #'constantly-t)
 583              (class-method-initargs (list :function
 584                                           class-method-function))
 585              (class-method (make-a-method 'standard-method
 586                                           ()
 587                                           (list 'object)
 588                                           (list class)
 589                                           class-method-initargs
 590                                           "class predicate class method")))
 591         (setf (method-function-get class-method-function :constant-value) t)
 592         (add-method gf class-method)))
 593     gf))
 594
 595 ;;; Set the inherits from CPL, and register the layout. This actually
 596 ;;; installs the class in the Lisp type system.
 597 (defun update-lisp-class-layout (class layout)
 598   (let ((lclass (sb-kernel:layout-class layout)))
 599     (unless (eq (sb-kernel:class-layout lclass) layout)
 600       (setf (sb-kernel:layout-inherits layout)
 601             (map 'vector #'class-wrapper
 602                  (reverse (rest (class-precedence-list class)))))
 603       (sb-kernel:register-layout layout :invalidate nil)
 604
 605       ;; Subclasses of formerly forward-referenced-class may be
 606       ;; unknown to CL:FIND-CLASS and also anonymous. This
 607       ;; functionality moved here from (SETF FIND-CLASS).
 608       (let ((name (class-name class)))
 609         (setf (cl:find-class name) lclass
 610               ;; FIXME: It's nasty to use double colons. Perhaps the
 611               ;; best way to fix this is not to export CLASS-%NAME
 612               ;; from SB-KERNEL, but instead to move the whole
 613               ;; UPDATE-LISP-CLASS-LAYOUT function to SB-KERNEL, and
 614               ;; export it. (since it's also nasty for us to be
 615               ;; reaching into %KERNEL implementation details my
 616               ;; messing with raw CLASS-%NAME)
 617               (sb-kernel::class-%name lclass) name)))))
 618
 619 (clrhash *find-class*)
 620 (!bootstrap-meta-braid)
 621 (!bootstrap-accessor-definitions t)
 622 (!bootstrap-class-predicates t)
 623 (!bootstrap-accessor-definitions nil)
 624 (!bootstrap-class-predicates nil)
 625 (!bootstrap-built-in-classes)
 626
 627 (dohash (name x *find-class*)
 628         (let* ((class (find-class-from-cell name x))
 629                (layout (class-wrapper class))
 630                (lclass (sb-kernel:layout-class layout))
 631                (lclass-pcl-class (sb-kernel:class-pcl-class lclass))
 632                (olclass (cl:find-class name nil)))
 633           (if lclass-pcl-class
 634               (aver (eq class lclass-pcl-class))
 635               (setf (sb-kernel:class-pcl-class lclass) class))
 636
 637           (update-lisp-class-layout class layout)
 638
 639           (cond (olclass
 640                  (aver (eq lclass olclass)))
 641                 (t
 642                  (setf (cl:find-class name) lclass)))))
 643
 644 (setq *boot-state* 'braid)
 645
 646 (defmethod no-applicable-method (generic-function &rest args)
 647   (error "~@<There is no matching method for the generic function ~2I~_~S~
 648           ~I~_when called with arguments ~2I~_~S.~:>"
 649          generic-function
 650          args))