src/pcl/braid.lisp

   1 ;;;; bootstrapping the meta-braid
   2 ;;;;
   3 ;;;; The code in this file takes the early definitions that have been
   4 ;;;; saved up and actually builds those class objects. This work is
   5 ;;;; largely driven off of those class definitions, but the fact that
   6 ;;;; STANDARD-CLASS is the class of all metaclasses in the braid is
   7 ;;;; built into this code pretty deeply.
   8
   9 ;;;; This software is part of the SBCL system. See the README file for
  10 ;;;; more information.
  11
  12 ;;;; This software is derived from software originally released by Xerox
  13 ;;;; Corporation. Copyright and release statements follow. Later modifications
  14 ;;;; to the software are in the public domain and are provided with
  15 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
  16 ;;;; information.
  17
  18 ;;;; copyright information from original PCL sources:
  19 ;;;;
  20 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  21 ;;;; All rights reserved.
  22 ;;;;
  23 ;;;; Use and copying of this software and preparation of derivative works based
  24 ;;;; upon this software are permitted. Any distribution of this software or
  25 ;;;; derivative works must comply with all applicable United States export
  26 ;;;; control laws.
  27 ;;;;
  28 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  29 ;;;; warranty about the software, its performance or its conformity to any
  30 ;;;; specification.
  31
  32 (in-package "SB-PCL")
  33 \f
  34 (defun allocate-standard-instance (wrapper
  35                                    &optional (slots-init nil slots-init-p))
  36   (let ((instance (%make-standard-instance nil (get-instance-hash-code)))
  37         (no-of-slots (wrapper-no-of-instance-slots wrapper)))
  38     (setf (std-instance-wrapper instance) wrapper)
  39     (setf (std-instance-slots instance)
  40           (cond (slots-init-p
  41                  ;; Inline the slots vector allocation and initialization.
  42                  (let ((slots (make-array no-of-slots :initial-element 0)))
  43                    (do ((rem-slots slots-init (rest rem-slots))
  44                         (i 0 (1+ i)))
  45                        ((>= i no-of-slots)) ;endp rem-slots))
  46                      (declare (list rem-slots)
  47                               (type index i))
  48                      (setf (aref slots i) (first rem-slots)))
  49                    slots))
  50                 (t
  51                  (make-array no-of-slots
  52                              :initial-element +slot-unbound+))))
  53     instance))
  54
  55 (defmacro allocate-standard-funcallable-instance-slots
  56     (wrapper &optional slots-init-p slots-init)
  57   `(let ((no-of-slots (wrapper-no-of-instance-slots ,wrapper)))
  58     ,(if slots-init-p
  59          `(if ,slots-init-p
  60            (make-array no-of-slots :initial-contents ,slots-init)
  61            (make-array no-of-slots :initial-element +slot-unbound+))
  62          `(make-array no-of-slots :initial-element +slot-unbound+))))
  63
  64 (define-condition unset-funcallable-instance-function
  65     (reference-condition simple-error)
  66   ()
  67   (:default-initargs
  68    :references (list '(:amop :generic-function allocate-instance)
  69                      '(:amop :function set-funcallable-instance-function))))
  70
  71 (defun allocate-standard-funcallable-instance
  72     (wrapper &optional (slots-init nil slots-init-p))
  73   (let ((fin (%make-standard-funcallable-instance
  74               nil nil (get-instance-hash-code))))
  75     (set-funcallable-instance-function
  76      fin
  77      #'(lambda (&rest args)
  78          (declare (ignore args))
  79          (error 'unset-funcallable-instance-function
  80                 :format-control "~@<The function of funcallable instance ~
  81                                  ~S has not been set.~@:>"
  82                 :format-arguments (list fin))))
  83     (setf (fsc-instance-wrapper fin) wrapper
  84           (fsc-instance-slots fin)
  85           (allocate-standard-funcallable-instance-slots
  86            wrapper slots-init-p slots-init))
  87     fin))
  88 \f
  89 ;;;; BOOTSTRAP-META-BRAID
  90 ;;;;
  91 ;;;; This function builds the base metabraid from the early class definitions.
  92
  93 (defmacro !initial-classes-and-wrappers (&rest classes)
  94   `(progn
  95      ,@(mapcar (lambda (class)
  96                  (let ((wr (format-symbol *pcl-package* "~A-WRAPPER" class)))
  97                    `(setf ,wr ,(if (eq class 'standard-generic-function)
  98                                    '*sgf-wrapper*
  99                                    `(boot-make-wrapper
 100                                      (early-class-size ',class)
 101                                      ',class))
 102                           ,class (allocate-standard-instance
 103                                   ,(if (eq class 'standard-generic-function)
 104                                        'funcallable-standard-class-wrapper
 105                                        'standard-class-wrapper))
 106                           (wrapper-class ,wr) ,class
 107                           (find-class ',class) ,class)))
 108                classes)))
 109
 110 (defun !bootstrap-meta-braid ()
 111   (let* ((*create-classes-from-internal-structure-definitions-p* nil)
 112          standard-class-wrapper standard-class
 113          funcallable-standard-class-wrapper funcallable-standard-class
 114          slot-class-wrapper slot-class
 115          built-in-class-wrapper built-in-class
 116          structure-class-wrapper structure-class
 117          condition-class-wrapper condition-class
 118          standard-direct-slot-definition-wrapper
 119          standard-direct-slot-definition
 120          standard-effective-slot-definition-wrapper
 121          standard-effective-slot-definition
 122          class-eq-specializer-wrapper class-eq-specializer
 123          standard-generic-function-wrapper standard-generic-function)
 124     (!initial-classes-and-wrappers
 125      standard-class funcallable-standard-class
 126      slot-class built-in-class structure-class condition-class
 127      standard-direct-slot-definition standard-effective-slot-definition
 128      class-eq-specializer standard-generic-function)
 129     ;; First, make a class metaobject for each of the early classes. For
 130     ;; each metaobject we also set its wrapper. Except for the class T,
 131     ;; the wrapper is always that of STANDARD-CLASS.
 132     (dolist (definition *early-class-definitions*)
 133       (let* ((name (ecd-class-name definition))
 134              (meta (ecd-metaclass definition))
 135              (wrapper (ecase meta
 136                         (slot-class slot-class-wrapper)
 137                         (standard-class standard-class-wrapper)
 138                         (funcallable-standard-class
 139                          funcallable-standard-class-wrapper)
 140                         (built-in-class built-in-class-wrapper)
 141                         (structure-class structure-class-wrapper)
 142                         (condition-class condition-class-wrapper)))
 143              (class (or (find-class name nil)
 144                         (allocate-standard-instance wrapper))))
 145         (setf (find-class name) class)))
 146     (dolist (definition *early-class-definitions*)
 147       (let ((name (ecd-class-name definition))
 148             (meta (ecd-metaclass definition))
 149             (source (ecd-source-location definition))
 150             (direct-supers (ecd-superclass-names definition))
 151             (direct-slots  (ecd-canonical-slots definition))
 152             (other-initargs (ecd-other-initargs definition)))
 153         (let ((direct-default-initargs
 154                (getf other-initargs :direct-default-initargs)))
 155           (multiple-value-bind (slots cpl default-initargs direct-subclasses)
 156               (early-collect-inheritance name)
 157             (let* ((class (find-class name))
 158                    (wrapper (cond ((eq class slot-class)
 159                                    slot-class-wrapper)
 160                                   ((eq class standard-class)
 161                                    standard-class-wrapper)
 162                                   ((eq class funcallable-standard-class)
 163                                    funcallable-standard-class-wrapper)
 164                                   ((eq class standard-direct-slot-definition)
 165                                    standard-direct-slot-definition-wrapper)
 166                                   ((eq class
 167                                        standard-effective-slot-definition)
 168                                    standard-effective-slot-definition-wrapper)
 169                                   ((eq class built-in-class)
 170                                    built-in-class-wrapper)
 171                                   ((eq class structure-class)
 172                                    structure-class-wrapper)
 173                                   ((eq class condition-class)
 174                                    condition-class-wrapper)
 175                                   ((eq class class-eq-specializer)
 176                                    class-eq-specializer-wrapper)
 177                                   ((eq class standard-generic-function)
 178                                    standard-generic-function-wrapper)
 179                                   (t
 180                                    (boot-make-wrapper (length slots) name))))
 181                    (proto nil))
 182               (when (eq name t) (setq *the-wrapper-of-t* wrapper))
 183               (set (make-class-symbol name) class)
 184               (dolist (slot slots)
 185                 (unless (eq (getf slot :allocation :instance) :instance)
 186                   (error "Slot allocation ~S is not supported in bootstrap."
 187                          (getf slot :allocation))))
 188
 189               (when (typep wrapper 'wrapper)
 190                 (setf (wrapper-instance-slots-layout wrapper)
 191                       (mapcar #'canonical-slot-name slots))
 192                 (setf (wrapper-class-slots wrapper)
 193                       ()))
 194
 195               (setq proto (if (eq meta 'funcallable-standard-class)
 196                               (allocate-standard-funcallable-instance wrapper)
 197                               (allocate-standard-instance wrapper)))
 198
 199               (setq direct-slots
 200                     (!bootstrap-make-slot-definitions
 201                      name class direct-slots
 202                      standard-direct-slot-definition-wrapper nil))
 203               (setq slots
 204                     (!bootstrap-make-slot-definitions
 205                      name class slots
 206                      standard-effective-slot-definition-wrapper t))
 207
 208               (setf (layout-slot-table wrapper) (make-slot-table class slots t))
 209
 210               (case meta
 211                 ((standard-class funcallable-standard-class)
 212                  (!bootstrap-initialize-class
 213                   meta
 214                   class name class-eq-specializer-wrapper source
 215                   direct-supers direct-subclasses cpl wrapper proto
 216                   direct-slots slots direct-default-initargs default-initargs))
 217                 (built-in-class         ; *the-class-t*
 218                  (!bootstrap-initialize-class
 219                   meta
 220                   class name class-eq-specializer-wrapper source
 221                   direct-supers direct-subclasses cpl wrapper proto))
 222                 (slot-class             ; *the-class-slot-object*
 223                  (!bootstrap-initialize-class
 224                   meta
 225                   class name class-eq-specializer-wrapper source
 226                   direct-supers direct-subclasses cpl wrapper proto))
 227                 (structure-class        ; *the-class-structure-object*
 228                  (!bootstrap-initialize-class
 229                   meta
 230                   class name class-eq-specializer-wrapper source
 231                   direct-supers direct-subclasses cpl wrapper))
 232                 (condition-class
 233                  (!bootstrap-initialize-class
 234                   meta
 235                   class name class-eq-specializer-wrapper source
 236                   direct-supers direct-subclasses cpl wrapper))))))))
 237
 238     (let* ((smc-class (find-class 'standard-method-combination))
 239            (smc-wrapper (!bootstrap-get-slot 'standard-class
 240                                              smc-class
 241                                              'wrapper))
 242            (smc (allocate-standard-instance smc-wrapper)))
 243       (flet ((set-slot (name value)
 244                (!bootstrap-set-slot 'standard-method-combination
 245                                     smc
 246                                     name
 247                                     value)))
 248         (set-slot 'source nil)
 249         (set-slot 'type-name 'standard)
 250         (set-slot '%documentation "The standard method combination.")
 251         (set-slot 'options ()))
 252       (setq *standard-method-combination* smc))))
 253
 254 ;;; Initialize a class metaobject.
 255 (defun !bootstrap-initialize-class
 256        (metaclass-name class name
 257         class-eq-wrapper source direct-supers direct-subclasses cpl wrapper
 258         &optional
 259         (proto nil proto-p)
 260         direct-slots slots direct-default-initargs default-initargs)
 261   (flet ((classes (names) (mapcar #'find-class names))
 262          (set-slot (slot-name value)
 263            (!bootstrap-set-slot metaclass-name class slot-name value)))
 264     (set-slot 'name name)
 265     (set-slot 'finalized-p t)
 266     (set-slot 'source source)
 267     (set-slot 'safe-p nil)
 268     (set-slot '%type (if (eq class (find-class t))
 269                          t
 270                          ;; FIXME: Could this just be CLASS instead
 271                          ;; of `(CLASS ,CLASS)? If not, why not?
 272                          ;; (See also similar expression in
 273                          ;; SHARED-INITIALIZE :BEFORE (CLASS).)
 274                          `(class ,class)))
 275     (set-slot 'class-eq-specializer
 276               (let ((spec (allocate-standard-instance class-eq-wrapper)))
 277                 (!bootstrap-set-slot 'class-eq-specializer spec '%type
 278                                      `(class-eq ,class))
 279                 (!bootstrap-set-slot 'class-eq-specializer spec 'object
 280                                      class)
 281                 spec))
 282     (set-slot '%class-precedence-list (classes cpl))
 283     (set-slot 'cpl-available-p t)
 284     (set-slot 'can-precede-list (classes (cdr cpl)))
 285     (set-slot 'incompatible-superclass-list nil)
 286     (set-slot 'direct-superclasses (classes direct-supers))
 287     (set-slot 'direct-subclasses (classes direct-subclasses))
 288     (set-slot 'direct-methods (cons nil nil))
 289     (set-slot 'wrapper wrapper)
 290     (set-slot '%documentation nil)
 291     (set-slot 'plist
 292               `(,@(and direct-default-initargs
 293                        `(direct-default-initargs ,direct-default-initargs))
 294                 ,@(and default-initargs
 295                        `(default-initargs ,default-initargs))))
 296     (when (memq metaclass-name '(standard-class funcallable-standard-class
 297                                  structure-class condition-class
 298                                  slot-class))
 299       (set-slot 'direct-slots direct-slots)
 300       (set-slot 'slots slots)
 301       (setf (layout-slot-table wrapper)
 302             (make-slot-table class slots
 303                              (member metaclass-name
 304                                      '(standard-class funcallable-standard-class)))))
 305
 306     ;; For all direct superclasses SUPER of CLASS, make sure CLASS is
 307     ;; a direct subclass of SUPER.  Note that METACLASS-NAME doesn't
 308     ;; matter here for the slot DIRECT-SUBCLASSES, since every class
 309     ;; inherits the slot from class CLASS.
 310     (dolist (super direct-supers)
 311       (let* ((super (find-class super))
 312              (subclasses (!bootstrap-get-slot metaclass-name super
 313                                               'direct-subclasses)))
 314         (cond ((eq +slot-unbound+ subclasses)
 315                (!bootstrap-set-slot metaclass-name super 'direct-subclasses
 316                                     (list class)))
 317               ((not (memq class subclasses))
 318                (!bootstrap-set-slot metaclass-name super 'direct-subclasses
 319                                     (cons class subclasses))))))
 320
 321     (case metaclass-name
 322       (structure-class
 323        (let ((constructor-sym '|STRUCTURE-OBJECT class constructor|))
 324          (set-slot 'defstruct-form
 325                    `(defstruct (structure-object (:constructor
 326                                                   ,constructor-sym)
 327                                                  (:copier nil))))
 328          (set-slot 'defstruct-constructor constructor-sym)
 329          (set-slot 'from-defclass-p t)
 330          (set-slot 'plist nil)
 331          (set-slot 'prototype (funcall constructor-sym))))
 332       (condition-class
 333        (set-slot 'prototype (make-condition name)))
 334       (t
 335        (set-slot 'prototype
 336                  (if proto-p proto (allocate-standard-instance wrapper)))))
 337     class))
 338
 339 (defun !bootstrap-make-slot-definitions (name class slots wrapper effective-p)
 340   (let ((index -1))
 341     (mapcar (lambda (slot)
 342               (incf index)
 343               (!bootstrap-make-slot-definition
 344                name class slot wrapper effective-p index))
 345             slots)))
 346
 347 (defun !bootstrap-make-slot-definition
 348     (name class slot wrapper effective-p index)
 349   (let* ((slotd-class-name (if effective-p
 350                                'standard-effective-slot-definition
 351                                'standard-direct-slot-definition))
 352          (slotd (allocate-standard-instance wrapper))
 353          (slot-name (getf slot :name)))
 354     (flet ((get-val (name) (getf slot name))
 355            (set-val (name val)
 356                     (!bootstrap-set-slot slotd-class-name slotd name val)))
 357       (set-val 'name         slot-name)
 358       (set-val 'initform     (get-val :initform))
 359       (set-val 'initfunction (get-val :initfunction))
 360       (set-val 'initargs     (get-val :initargs))
 361       (set-val 'readers      (get-val :readers))
 362       (set-val 'writers      (get-val :writers))
 363       (set-val 'allocation   :instance)
 364       (set-val '%type        (or (get-val :type) t))
 365       (set-val '%type-check-function (get-val 'type-check-function))
 366       (set-val '%documentation (or (get-val :documentation) ""))
 367       (set-val '%class   class)
 368       (when effective-p
 369         (set-val 'location index)
 370         (let ((fsc-p nil))
 371           (set-val 'reader-function (make-optimized-std-reader-method-function
 372                                      fsc-p nil slot-name index))
 373           (set-val 'writer-function (make-optimized-std-writer-method-function
 374                                      fsc-p nil slot-name index))
 375           (set-val 'boundp-function (make-optimized-std-boundp-method-function
 376                                      fsc-p nil slot-name index)))
 377         (set-val 'accessor-flags 7))
 378       (when (and (eq name 'standard-class)
 379                  (eq slot-name 'slots) effective-p)
 380         (setq *the-eslotd-standard-class-slots* slotd))
 381       (when (and (eq name 'funcallable-standard-class)
 382                  (eq slot-name 'slots) effective-p)
 383         (setq *the-eslotd-funcallable-standard-class-slots* slotd))
 384       slotd)))
 385
 386 (defun !bootstrap-accessor-definitions (early-p)
 387   (let ((*early-p* early-p))
 388     (dolist (definition *early-class-definitions*)
 389       (let ((name (ecd-class-name definition))
 390             (meta (ecd-metaclass definition)))
 391         (unless (eq meta 'built-in-class)
 392           (let ((direct-slots  (ecd-canonical-slots definition)))
 393             (dolist (slotd direct-slots)
 394               (let ((slot-name (getf slotd :name))
 395                     (readers (getf slotd :readers))
 396                     (writers (getf slotd :writers)))
 397                 (!bootstrap-accessor-definitions1
 398                  name
 399                  slot-name
 400                  readers
 401                  writers
 402                  nil
 403                  (ecd-source-location definition))))))))))
 404
 405 (defun !bootstrap-accessor-definition (class-name accessor-name slot-name type source-location)
 406   (multiple-value-bind (accessor-class make-method-function arglist specls doc)
 407       (ecase type
 408         (reader (values 'standard-reader-method
 409                         #'make-std-reader-method-function
 410                         (list class-name)
 411                         (list class-name)
 412                         "automatically generated reader method"))
 413         (writer (values 'standard-writer-method
 414                         #'make-std-writer-method-function
 415                         (list 'new-value class-name)
 416                         (list t class-name)
 417                         "automatically generated writer method"))
 418         (boundp (values 'standard-boundp-method
 419                         #'make-std-boundp-method-function
 420                         (list class-name)
 421                         (list class-name)
 422                         "automatically generated boundp method")))
 423     (let ((gf (ensure-generic-function accessor-name :lambda-list arglist)))
 424       (if (find specls (early-gf-methods gf)
 425                 :key #'early-method-specializers
 426                 :test 'equal)
 427           (unless (assoc accessor-name *!generic-function-fixups*
 428                          :test #'equal)
 429             (update-dfun gf))
 430           (add-method gf
 431                       (make-a-method accessor-class
 432                                      ()
 433                                      arglist specls
 434                                      (funcall make-method-function
 435                                               class-name slot-name)
 436                                      doc
 437                                      :slot-name slot-name
 438                                      :object-class class-name
 439                                      :method-class-function (constantly (find-class accessor-class))
 440                                      :definition-source source-location))))))
 441
 442 (defun !bootstrap-accessor-definitions1 (class-name
 443                                          slot-name
 444                                          readers
 445                                          writers
 446                                          boundps
 447                                          source-location)
 448   (flet ((do-reader-definition (reader)
 449            (!bootstrap-accessor-definition class-name
 450                                            reader
 451                                            slot-name
 452                                            'reader
 453                                            source-location))
 454          (do-writer-definition (writer)
 455            (!bootstrap-accessor-definition class-name
 456                                            writer
 457                                            slot-name
 458                                            'writer
 459                                            source-location))
 460          (do-boundp-definition (boundp)
 461            (!bootstrap-accessor-definition class-name
 462                                            boundp
 463                                            slot-name
 464                                            'boundp
 465                                            source-location)))
 466     (dolist (reader readers) (do-reader-definition reader))
 467     (dolist (writer writers) (do-writer-definition writer))
 468     (dolist (boundp boundps) (do-boundp-definition boundp))))
 469
 470 ;;; FIXME: find a better name.
 471 (defun !bootstrap-class-predicates (early-p)
 472   (let ((*early-p* early-p))
 473     (dolist (ecp *early-class-predicates*)
 474       (let ((class-name (car ecp))
 475             (predicate-name (cadr ecp)))
 476         (make-class-predicate (find-class class-name) predicate-name)))))
 477
 478 (defun !bootstrap-built-in-classes ()
 479
 480   ;; First make sure that all the supers listed in
 481   ;; *BUILT-IN-CLASS-LATTICE* are themselves defined by
 482   ;; *BUILT-IN-CLASS-LATTICE*. This is just to check for typos and
 483   ;; other sorts of brainos.
 484   (dolist (e *built-in-classes*)
 485     (dolist (super (cadr e))
 486       (unless (or (eq super t)
 487                   (assq super *built-in-classes*))
 488         (error "in *BUILT-IN-CLASSES*: ~S has ~S as a super,~%~
 489                 but ~S is not itself a class in *BUILT-IN-CLASSES*."
 490                (car e) super super))))
 491
 492   ;; In the first pass, we create a skeletal object to be bound to the
 493   ;; class name.
 494   (let* ((built-in-class (find-class 'built-in-class))
 495          (built-in-class-wrapper (class-wrapper built-in-class)))
 496     (dolist (e *built-in-classes*)
 497       (let ((class (allocate-standard-instance built-in-class-wrapper)))
 498         (setf (find-class (car e)) class))))
 499
 500   ;; In the second pass, we initialize the class objects.
 501   (let ((class-eq-wrapper (class-wrapper (find-class 'class-eq-specializer))))
 502     (dolist (e *built-in-classes*)
 503       (destructuring-bind (name supers subs cpl prototype) e
 504         (let* ((class (find-class name))
 505                (lclass (find-classoid name))
 506                (wrapper (classoid-layout lclass)))
 507           (set (get-built-in-class-symbol name) class)
 508           (set (get-built-in-wrapper-symbol name) wrapper)
 509           (setf (classoid-pcl-class lclass) class)
 510
 511           (!bootstrap-initialize-class 'built-in-class class
 512                                        name class-eq-wrapper nil
 513                                        supers subs
 514                                        (cons name cpl)
 515                                        wrapper prototype))))))
 516 \f
 517 #-sb-fluid (declaim (inline wrapper-of))
 518 (defun wrapper-of (x)
 519   (layout-of x))
 520
 521 (defun class-of (x)
 522   (wrapper-class* (wrapper-of x)))
 523
 524 (defun eval-form (form)
 525   (lambda () (eval form)))
 526
 527 (defun ensure-non-standard-class (name classoid &optional existing-class)
 528   (flet
 529       ((ensure (metaclass &optional (slots nil slotsp))
 530          (let ((supers (mapcar #'classoid-name (classoid-direct-superclasses classoid))))
 531            (if slotsp
 532                (ensure-class-using-class existing-class name
 533                                          :metaclass metaclass :name name
 534                                          :direct-superclasses supers
 535                                          :direct-slots slots)
 536                (ensure-class-using-class existing-class name
 537                                          :metaclass metaclass :name name
 538                                          :direct-superclasses supers))))
 539        (slot-initargs-from-structure-slotd (slotd)
 540          (let ((accessor (structure-slotd-accessor-symbol slotd)))
 541            `(:name ,(structure-slotd-name slotd)
 542              :defstruct-accessor-symbol ,accessor
 543              ,@(when (fboundp accessor)
 544                  `(:internal-reader-function
 545                    ,(structure-slotd-reader-function slotd)
 546                    :internal-writer-function
 547                    ,(structure-slotd-writer-function name slotd)))
 548              :type ,(or (structure-slotd-type slotd) t)
 549              :initform ,(structure-slotd-init-form slotd)
 550              :initfunction ,(eval-form (structure-slotd-init-form slotd)))))
 551        (slot-initargs-from-condition-slot (slot)
 552          `(:name ,(condition-slot-name slot)
 553            :initargs ,(condition-slot-initargs slot)
 554            :readers ,(condition-slot-readers slot)
 555            :writers ,(condition-slot-writers slot)
 556            ,@(when (condition-slot-initform-p slot)
 557                (let ((form-or-fun (condition-slot-initform slot)))
 558                  (if (functionp form-or-fun)
 559                      `(:initfunction ,form-or-fun)
 560                      `(:initform ,form-or-fun
 561                        :initfunction ,(lambda () form-or-fun)))))
 562            :allocation ,(condition-slot-allocation slot)
 563            :documentation ,(condition-slot-documentation slot))))
 564     (cond ((structure-type-p name)
 565            (ensure 'structure-class
 566                    (mapcar #'slot-initargs-from-structure-slotd
 567                            (structure-type-slot-description-list name))))
 568           ((condition-type-p name)
 569            (ensure 'condition-class
 570                    (mapcar #'slot-initargs-from-condition-slot
 571                            (condition-classoid-slots classoid))))
 572           (t
 573            (error "~@<~S is not the name of a class.~@:>" name)))))
 574
 575 (defun ensure-deffoo-class (classoid)
 576   (let ((class (classoid-pcl-class classoid)))
 577     (cond (class
 578            (ensure-non-standard-class (class-name class) classoid class))
 579           ((eq 'complete *boot-state*)
 580            (ensure-non-standard-class (classoid-name classoid) classoid)))))
 581
 582 (pushnew 'ensure-deffoo-class sb-kernel::*defstruct-hooks*)
 583 (pushnew 'ensure-deffoo-class sb-kernel::*define-condition-hooks*)
 584 \f
 585 ;;; FIXME: only needed during bootstrap
 586 (defun make-class-predicate (class name)
 587   (let* ((gf (ensure-generic-function name :lambda-list '(object)))
 588          (mlist (if (eq *boot-state* 'complete)
 589                     (early-gf-methods gf)
 590                     (generic-function-methods gf))))
 591     (unless mlist
 592       (unless (eq class *the-class-t*)
 593         (let* ((default-method-function #'constantly-nil)
 594                (default-method-initargs (list :function default-method-function
 595                                               'plist '(:constant-value nil)))
 596                (default-method (make-a-method
 597                                 'standard-method
 598                                 ()
 599                                 (list 'object)
 600                                 (list *the-class-t*)
 601                                 default-method-initargs
 602                                 "class predicate default method")))
 603           (add-method gf default-method)))
 604       (let* ((class-method-function #'constantly-t)
 605              (class-method-initargs (list :function class-method-function
 606                                           'plist '(:constant-value t)))
 607              (class-method (make-a-method 'standard-method
 608                                           ()
 609                                           (list 'object)
 610                                           (list class)
 611                                           class-method-initargs
 612                                           "class predicate class method")))
 613         (add-method gf class-method)))
 614     gf))
 615
 616 ;;; Set the inherits from CPL, and register the layout. This actually
 617 ;;; installs the class in the Lisp type system.
 618 (defun %update-lisp-class-layout (class layout)
 619   ;; Protected by *world-lock* in callers.
 620   (let ((classoid (layout-classoid layout))
 621         (olayout (class-wrapper class)))
 622     (unless (eq (classoid-layout classoid) layout)
 623       (setf (layout-inherits layout)
 624             (order-layout-inherits
 625              (map 'simple-vector #'class-wrapper
 626                   (reverse (rest (class-precedence-list class))))))
 627       (register-layout layout :invalidate t)
 628
 629       ;; FIXME: I don't think this should be necessary, but without it
 630       ;; we are unable to compile (TYPEP foo '<class-name>) in the
 631       ;; same file as the class is defined.  If we had environments,
 632       ;; then I think the classsoid whould only be associated with the
 633       ;; name in that environment...  Alternatively, fix the compiler
 634       ;; so that TYPEP foo '<class-name> is slow but compileable.
 635       (let ((name (class-name class)))
 636         (when (and name (symbolp name) (eq name (classoid-name classoid)))
 637           (setf (find-classoid name) classoid))))))
 638
 639 (defun %set-class-type-translation (class classoid)
 640   (when (not (typep classoid 'classoid))
 641     (setq classoid (find-classoid classoid nil)))
 642   (etypecase classoid
 643     (null)
 644     (built-in-classoid
 645      (let ((translation (built-in-classoid-translation classoid)))
 646        (cond
 647          (translation
 648           (aver (ctype-p translation))
 649           (setf (info :type :translator class)
 650                 (lambda (spec) (declare (ignore spec)) translation)))
 651          (t
 652           (setf (info :type :translator class)
 653                 (lambda (spec) (declare (ignore spec)) classoid))))))
 654     (classoid
 655      (setf (info :type :translator class)
 656            (lambda (spec) (declare (ignore spec)) classoid)))))
 657
 658 (!bootstrap-meta-braid)
 659 (!bootstrap-accessor-definitions t)
 660 (!bootstrap-class-predicates t)
 661 (!bootstrap-accessor-definitions nil)
 662 (!bootstrap-class-predicates nil)
 663 (!bootstrap-built-in-classes)
 664
 665 (dohash ((name x) sb-kernel::*classoid-cells*)
 666   (when (classoid-cell-pcl-class x)
 667     (let* ((class (find-class-from-cell name x))
 668            (layout (class-wrapper class))
 669            (lclass (layout-classoid layout))
 670            (lclass-pcl-class (classoid-pcl-class lclass))
 671            (olclass (find-classoid name nil)))
 672       (if lclass-pcl-class
 673           (aver (eq class lclass-pcl-class))
 674           (setf (classoid-pcl-class lclass) class))
 675
 676       (%update-lisp-class-layout class layout)
 677
 678       (cond (olclass
 679              (aver (eq lclass olclass)))
 680             (t
 681              (setf (find-classoid name) lclass)))
 682
 683       (%set-class-type-translation class name))))
 684
 685 (setq *boot-state* 'braid)
 686
 687 (defmethod no-applicable-method (generic-function &rest args)
 688   (error "~@<There is no applicable method for the generic function ~2I~_~S~
 689           ~I~_when called with arguments ~2I~_~S.~:>"
 690          generic-function
 691          args))
 692
 693 (defmethod no-next-method ((generic-function standard-generic-function)
 694                            (method standard-method) &rest args)
 695   (error "~@<There is no next method for the generic function ~2I~_~S~
 696           ~I~_when called from method ~2I~_~S~I~_with arguments ~2I~_~S.~:>"
 697          generic-function
 698          method
 699          args))
 700
 701 ;;; An extension to the ANSI standard: in the presence of e.g. a
 702 ;;; :BEFORE method, it would seem that going through
 703 ;;; NO-APPLICABLE-METHOD is prohibited, as in fact there is an
 704 ;;; applicable method.  -- CSR, 2002-11-15
 705 (define-condition no-primary-method (reference-condition error)
 706   ((generic-function :initarg :generic-function :reader no-primary-method-generic-function)
 707    (args :initarg :args :reader no-primary-method-args))
 708   (:report
 709    (lambda (c s)
 710      (format s "~@<There is no primary method for the generic function ~2I~_~S~
 711                 ~I~_when called with arguments ~2I~_~S.~:>"
 712              (no-primary-method-generic-function c)
 713              (no-primary-method-args c))))
 714   (:default-initargs :references (list '(:ansi-cl :section (7 6 6 2)))))
 715 (defmethod no-primary-method (generic-function &rest args)
 716   (error 'no-primary-method :generic-function generic-function :args args))
 717
 718 (defmethod invalid-qualifiers ((gf generic-function)
 719                                combin
 720                                method)
 721   (let ((qualifiers (method-qualifiers method)))
 722     (let ((why (cond
 723                  ((cdr qualifiers) "has too many qualifiers")
 724                  (t (aver (not (member (car qualifiers)
 725                                        '(:around :before :after))))
 726                     "has an invalid qualifier"))))
 727       (invalid-method-error
 728        method
 729        "The method ~S on ~S ~A.~%~
 730         Standard method combination requires all methods to have one~%~
 731         of the single qualifiers :AROUND, :BEFORE and :AFTER or to~%~
 732         have no qualifier at all."
 733        method gf why))))