src/pcl/braid.lisp

   1 ;;;; bootstrapping the meta-braid
   2 ;;;;
   3 ;;;; The code in this file takes the early definitions that have been
   4 ;;;; saved up and actually builds those class objects. This work is
   5 ;;;; largely driven off of those class definitions, but the fact that
   6 ;;;; STANDARD-CLASS is the class of all metaclasses in the braid is
   7 ;;;; built into this code pretty deeply.
   8
   9 ;;;; This software is part of the SBCL system. See the README file for
  10 ;;;; more information.
  11
  12 ;;;; This software is derived from software originally released by Xerox
  13 ;;;; Corporation. Copyright and release statements follow. Later modifications
  14 ;;;; to the software are in the public domain and are provided with
  15 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
  16 ;;;; information.
  17
  18 ;;;; copyright information from original PCL sources:
  19 ;;;;
  20 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  21 ;;;; All rights reserved.
  22 ;;;;
  23 ;;;; Use and copying of this software and preparation of derivative works based
  24 ;;;; upon this software are permitted. Any distribution of this software or
  25 ;;;; derivative works must comply with all applicable United States export
  26 ;;;; control laws.
  27 ;;;;
  28 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  29 ;;;; warranty about the software, its performance or its conformity to any
  30 ;;;; specification.
  31
  32 (in-package "SB-PCL")
  33 \f
  34 (defun allocate-standard-instance (wrapper
  35                                    &optional (slots-init nil slots-init-p))
  36   (let ((instance (%make-standard-instance nil (get-instance-hash-code)))
  37         (no-of-slots (wrapper-no-of-instance-slots wrapper)))
  38     (setf (std-instance-wrapper instance) wrapper)
  39     (setf (std-instance-slots instance)
  40           (cond (slots-init-p
  41                  ;; Inline the slots vector allocation and initialization.
  42                  (let ((slots (make-array no-of-slots :initial-element 0)))
  43                    (do ((rem-slots slots-init (rest rem-slots))
  44                         (i 0 (1+ i)))
  45                        ((>= i no-of-slots)) ;endp rem-slots))
  46                      (declare (list rem-slots)
  47                               (type index i))
  48                      (setf (aref slots i) (first rem-slots)))
  49                    slots))
  50                 (t
  51                  (make-array no-of-slots
  52                              :initial-element +slot-unbound+))))
  53     instance))
  54
  55 (defmacro allocate-standard-funcallable-instance-slots
  56     (wrapper &optional slots-init-p slots-init)
  57   `(let ((no-of-slots (wrapper-no-of-instance-slots ,wrapper)))
  58     ,(if slots-init-p
  59          `(if ,slots-init-p
  60            (make-array no-of-slots :initial-contents ,slots-init)
  61            (make-array no-of-slots :initial-element +slot-unbound+))
  62          `(make-array no-of-slots :initial-element +slot-unbound+))))
  63
  64 (define-condition unset-funcallable-instance-function
  65     (reference-condition simple-error)
  66   ()
  67   (:default-initargs
  68    :references (list '(:amop :generic-function allocate-instance)
  69                      '(:amop :function set-funcallable-instance-function))))
  70
  71 (defun allocate-standard-funcallable-instance
  72     (wrapper &optional (slots-init nil slots-init-p))
  73   (let ((fin (%make-standard-funcallable-instance
  74               nil nil (get-instance-hash-code))))
  75     (set-funcallable-instance-function
  76      fin
  77      #'(lambda (&rest args)
  78          (declare (ignore args))
  79          (error 'unset-funcallable-instance-function
  80                 :format-control "~@<The function of funcallable instance ~
  81                                  ~S has not been set.~@:>"
  82                 :format-arguments (list fin))))
  83     (setf (fsc-instance-wrapper fin) wrapper
  84           (fsc-instance-slots fin)
  85           (allocate-standard-funcallable-instance-slots
  86            wrapper slots-init-p slots-init))
  87     fin))
  88
  89 (defun allocate-structure-instance (wrapper &optional
  90                                             (slots-init nil slots-init-p))
  91   (let* ((class (wrapper-class wrapper))
  92          (constructor (class-defstruct-constructor class)))
  93     (if constructor
  94         (let ((instance (funcall constructor))
  95               (slots (class-slots class)))
  96           (when slots-init-p
  97             (dolist (slot slots)
  98               (setf (slot-value-using-class class instance slot)
  99                     (pop slots-init))))
 100           instance)
 101         (error "can't allocate an instance of class ~S" (class-name class)))))
 102 \f
 103 ;;;; BOOTSTRAP-META-BRAID
 104 ;;;;
 105 ;;;; This function builds the base metabraid from the early class definitions.
 106
 107 (defmacro !initial-classes-and-wrappers (&rest classes)
 108   `(progn
 109      ,@(mapcar (lambda (class)
 110                  (let ((wr (format-symbol *pcl-package* "~A-WRAPPER" class)))
 111                    `(setf ,wr ,(if (eq class 'standard-generic-function)
 112                                    '*sgf-wrapper*
 113                                    `(boot-make-wrapper
 114                                      (early-class-size ',class)
 115                                      ',class))
 116                           ,class (allocate-standard-instance
 117                                   ,(if (eq class 'standard-generic-function)
 118                                        'funcallable-standard-class-wrapper
 119                                        'standard-class-wrapper))
 120                           (wrapper-class ,wr) ,class
 121                           (find-class ',class) ,class)))
 122                classes)))
 123
 124 (defun !bootstrap-meta-braid ()
 125   (let* ((*create-classes-from-internal-structure-definitions-p* nil)
 126          standard-class-wrapper standard-class
 127          funcallable-standard-class-wrapper funcallable-standard-class
 128          slot-class-wrapper slot-class
 129          built-in-class-wrapper built-in-class
 130          structure-class-wrapper structure-class
 131          condition-class-wrapper condition-class
 132          standard-direct-slot-definition-wrapper
 133          standard-direct-slot-definition
 134          standard-effective-slot-definition-wrapper
 135          standard-effective-slot-definition
 136          class-eq-specializer-wrapper class-eq-specializer
 137          standard-generic-function-wrapper standard-generic-function)
 138     (!initial-classes-and-wrappers
 139      standard-class funcallable-standard-class
 140      slot-class built-in-class structure-class condition-class
 141      standard-direct-slot-definition standard-effective-slot-definition
 142      class-eq-specializer standard-generic-function)
 143     ;; First, make a class metaobject for each of the early classes. For
 144     ;; each metaobject we also set its wrapper. Except for the class T,
 145     ;; the wrapper is always that of STANDARD-CLASS.
 146     (dolist (definition *early-class-definitions*)
 147       (let* ((name (ecd-class-name definition))
 148              (meta (ecd-metaclass definition))
 149              (wrapper (ecase meta
 150                         (slot-class slot-class-wrapper)
 151                         (standard-class standard-class-wrapper)
 152                         (funcallable-standard-class
 153                          funcallable-standard-class-wrapper)
 154                         (built-in-class built-in-class-wrapper)
 155                         (structure-class structure-class-wrapper)
 156                         (condition-class condition-class-wrapper)))
 157              (class (or (find-class name nil)
 158                         (allocate-standard-instance wrapper))))
 159         (setf (find-class name) class)))
 160     (dolist (definition *early-class-definitions*)
 161       (let ((name (ecd-class-name definition))
 162             (meta (ecd-metaclass definition))
 163             (source (ecd-source-location definition))
 164             (direct-supers (ecd-superclass-names definition))
 165             (direct-slots  (ecd-canonical-slots definition))
 166             (other-initargs (ecd-other-initargs definition)))
 167         (let ((direct-default-initargs
 168                (getf other-initargs :direct-default-initargs)))
 169           (multiple-value-bind (slots cpl default-initargs direct-subclasses)
 170               (early-collect-inheritance name)
 171             (let* ((class (find-class name))
 172                    (wrapper (cond ((eq class slot-class)
 173                                    slot-class-wrapper)
 174                                   ((eq class standard-class)
 175                                    standard-class-wrapper)
 176                                   ((eq class funcallable-standard-class)
 177                                    funcallable-standard-class-wrapper)
 178                                   ((eq class standard-direct-slot-definition)
 179                                    standard-direct-slot-definition-wrapper)
 180                                   ((eq class
 181                                        standard-effective-slot-definition)
 182                                    standard-effective-slot-definition-wrapper)
 183                                   ((eq class built-in-class)
 184                                    built-in-class-wrapper)
 185                                   ((eq class structure-class)
 186                                    structure-class-wrapper)
 187                                   ((eq class condition-class)
 188                                    condition-class-wrapper)
 189                                   ((eq class class-eq-specializer)
 190                                    class-eq-specializer-wrapper)
 191                                   ((eq class standard-generic-function)
 192                                    standard-generic-function-wrapper)
 193                                   (t
 194                                    (boot-make-wrapper (length slots) name))))
 195                    (proto nil))
 196               (when (eq name t) (setq *the-wrapper-of-t* wrapper))
 197               (set (make-class-symbol name) class)
 198               (dolist (slot slots)
 199                 (unless (eq (getf slot :allocation :instance) :instance)
 200                   (error "Slot allocation ~S is not supported in bootstrap."
 201                          (getf slot :allocation))))
 202
 203               (when (typep wrapper 'wrapper)
 204                 (setf (wrapper-instance-slots-layout wrapper)
 205                       (mapcar #'canonical-slot-name slots))
 206                 (setf (wrapper-class-slots wrapper)
 207                       ()))
 208
 209               (setq proto (if (eq meta 'funcallable-standard-class)
 210                               (allocate-standard-funcallable-instance wrapper)
 211                               (allocate-standard-instance wrapper)))
 212
 213               (setq direct-slots
 214                     (!bootstrap-make-slot-definitions
 215                      name class direct-slots
 216                      standard-direct-slot-definition-wrapper nil))
 217               (setq slots
 218                     (!bootstrap-make-slot-definitions
 219                      name class slots
 220                      standard-effective-slot-definition-wrapper t))
 221
 222               (case meta
 223                 ((standard-class funcallable-standard-class)
 224                  (!bootstrap-initialize-class
 225                   meta
 226                   class name class-eq-specializer-wrapper source
 227                   direct-supers direct-subclasses cpl wrapper proto
 228                   direct-slots slots direct-default-initargs default-initargs))
 229                 (built-in-class         ; *the-class-t*
 230                  (!bootstrap-initialize-class
 231                   meta
 232                   class name class-eq-specializer-wrapper source
 233                   direct-supers direct-subclasses cpl wrapper proto))
 234                 (slot-class             ; *the-class-slot-object*
 235                  (!bootstrap-initialize-class
 236                   meta
 237                   class name class-eq-specializer-wrapper source
 238                   direct-supers direct-subclasses cpl wrapper proto))
 239                 (structure-class        ; *the-class-structure-object*
 240                  (!bootstrap-initialize-class
 241                   meta
 242                   class name class-eq-specializer-wrapper source
 243                   direct-supers direct-subclasses cpl wrapper))
 244                 (condition-class
 245                  (!bootstrap-initialize-class
 246                   meta
 247                   class name class-eq-specializer-wrapper source
 248                   direct-supers direct-subclasses cpl wrapper))))))))
 249
 250     (let* ((smc-class (find-class 'standard-method-combination))
 251            (smc-wrapper (!bootstrap-get-slot 'standard-class
 252                                              smc-class
 253                                              'wrapper))
 254            (smc (allocate-standard-instance smc-wrapper)))
 255       (flet ((set-slot (name value)
 256                (!bootstrap-set-slot 'standard-method-combination
 257                                     smc
 258                                     name
 259                                     value)))
 260         (set-slot 'source nil)
 261         (set-slot 'type-name 'standard)
 262         (set-slot '%documentation "The standard method combination.")
 263         (set-slot 'options ()))
 264       (setq *standard-method-combination* smc))))
 265
 266 ;;; Initialize a class metaobject.
 267 (defun !bootstrap-initialize-class
 268        (metaclass-name class name
 269         class-eq-wrapper source direct-supers direct-subclasses cpl wrapper
 270         &optional
 271         (proto nil proto-p)
 272         direct-slots slots direct-default-initargs default-initargs)
 273   (flet ((classes (names) (mapcar #'find-class names))
 274          (set-slot (slot-name value)
 275            (!bootstrap-set-slot metaclass-name class slot-name value)))
 276     (set-slot 'name name)
 277     (set-slot 'finalized-p t)
 278     (set-slot 'source source)
 279     (set-slot 'safe-p nil)
 280     (set-slot '%type (if (eq class (find-class t))
 281                          t
 282                          ;; FIXME: Could this just be CLASS instead
 283                          ;; of `(CLASS ,CLASS)? If not, why not?
 284                          ;; (See also similar expression in
 285                          ;; SHARED-INITIALIZE :BEFORE (CLASS).)
 286                          `(class ,class)))
 287     (set-slot 'class-eq-specializer
 288               (let ((spec (allocate-standard-instance class-eq-wrapper)))
 289                 (!bootstrap-set-slot 'class-eq-specializer spec '%type
 290                                      `(class-eq ,class))
 291                 (!bootstrap-set-slot 'class-eq-specializer spec 'object
 292                                      class)
 293                 spec))
 294     (set-slot '%class-precedence-list (classes cpl))
 295     (set-slot 'cpl-available-p t)
 296     (set-slot 'can-precede-list (classes (cdr cpl)))
 297     (set-slot 'incompatible-superclass-list nil)
 298     (set-slot 'direct-superclasses (classes direct-supers))
 299     (set-slot 'direct-subclasses (classes direct-subclasses))
 300     (set-slot 'direct-methods (cons nil nil))
 301     (set-slot 'wrapper wrapper)
 302     (set-slot '%documentation nil)
 303     (set-slot 'plist
 304               `(,@(and direct-default-initargs
 305                        `(direct-default-initargs ,direct-default-initargs))
 306                 ,@(and default-initargs
 307                        `(default-initargs ,default-initargs))))
 308     (when (memq metaclass-name '(standard-class funcallable-standard-class
 309                                  structure-class condition-class
 310                                  slot-class))
 311       (set-slot 'direct-slots direct-slots)
 312       (set-slot 'slots slots))
 313
 314     ;; For all direct superclasses SUPER of CLASS, make sure CLASS is
 315     ;; a direct subclass of SUPER.  Note that METACLASS-NAME doesn't
 316     ;; matter here for the slot DIRECT-SUBCLASSES, since every class
 317     ;; inherits the slot from class CLASS.
 318     (dolist (super direct-supers)
 319       (let* ((super (find-class super))
 320              (subclasses (!bootstrap-get-slot metaclass-name super
 321                                               'direct-subclasses)))
 322         (cond ((eq +slot-unbound+ subclasses)
 323                (!bootstrap-set-slot metaclass-name super 'direct-subclasses
 324                                     (list class)))
 325               ((not (memq class subclasses))
 326                (!bootstrap-set-slot metaclass-name super 'direct-subclasses
 327                                     (cons class subclasses))))))
 328
 329     (case metaclass-name
 330       (structure-class
 331        (let ((constructor-sym '|STRUCTURE-OBJECT class constructor|))
 332          (set-slot 'defstruct-form
 333                    `(defstruct (structure-object (:constructor
 334                                                   ,constructor-sym)
 335                                                  (:copier nil))))
 336          (set-slot 'defstruct-constructor constructor-sym)
 337          (set-slot 'from-defclass-p t)
 338          (set-slot 'plist nil)
 339          (set-slot 'prototype (funcall constructor-sym))))
 340       (condition-class
 341        (set-slot 'prototype (make-condition name)))
 342       (t
 343        (set-slot 'prototype
 344                  (if proto-p proto (allocate-standard-instance wrapper)))))
 345     class))
 346
 347 (defun !bootstrap-make-slot-definitions (name class slots wrapper effective-p)
 348   (let ((index -1))
 349     (mapcar (lambda (slot)
 350               (incf index)
 351               (!bootstrap-make-slot-definition
 352                name class slot wrapper effective-p index))
 353             slots)))
 354
 355 (defun !bootstrap-make-slot-definition
 356     (name class slot wrapper effective-p index)
 357   (let* ((slotd-class-name (if effective-p
 358                                'standard-effective-slot-definition
 359                                'standard-direct-slot-definition))
 360          (slotd (allocate-standard-instance wrapper))
 361          (slot-name (getf slot :name)))
 362     (flet ((get-val (name) (getf slot name))
 363            (set-val (name val)
 364                     (!bootstrap-set-slot slotd-class-name slotd name val)))
 365       (set-val 'name         slot-name)
 366       (set-val 'initform     (get-val :initform))
 367       (set-val 'initfunction (get-val :initfunction))
 368       (set-val 'initargs     (get-val :initargs))
 369       (set-val 'readers      (get-val :readers))
 370       (set-val 'writers      (get-val :writers))
 371       (set-val 'allocation   :instance)
 372       (set-val '%type        (or (get-val :type) t))
 373       (set-val '%type-check-function (get-val 'type-check-function))
 374       (set-val '%documentation (or (get-val :documentation) ""))
 375       (set-val '%class   class)
 376       (when effective-p
 377         (set-val 'location index)
 378         (let ((fsc-p nil))
 379           (set-val 'reader-function (make-optimized-std-reader-method-function
 380                                      fsc-p nil slot-name index))
 381           (set-val 'writer-function (make-optimized-std-writer-method-function
 382                                      fsc-p nil slot-name index))
 383           (set-val 'boundp-function (make-optimized-std-boundp-method-function
 384                                      fsc-p nil slot-name index)))
 385         (set-val 'accessor-flags 7))
 386       (when (and (eq name 'standard-class)
 387                  (eq slot-name 'slots) effective-p)
 388         (setq *the-eslotd-standard-class-slots* slotd))
 389       (when (and (eq name 'funcallable-standard-class)
 390                  (eq slot-name 'slots) effective-p)
 391         (setq *the-eslotd-funcallable-standard-class-slots* slotd))
 392       slotd)))
 393
 394 (defun !bootstrap-accessor-definitions (early-p)
 395   (let ((*early-p* early-p))
 396     (dolist (definition *early-class-definitions*)
 397       (let ((name (ecd-class-name definition))
 398             (meta (ecd-metaclass definition)))
 399         (unless (eq meta 'built-in-class)
 400           (let ((direct-slots  (ecd-canonical-slots definition)))
 401             (dolist (slotd direct-slots)
 402               (let ((slot-name (getf slotd :name))
 403                     (readers (getf slotd :readers))
 404                     (writers (getf slotd :writers)))
 405                 (!bootstrap-accessor-definitions1
 406                  name
 407                  slot-name
 408                  readers
 409                  writers
 410                  nil)))))))))
 411
 412 (defun !bootstrap-accessor-definition (class-name accessor-name slot-name type)
 413   (multiple-value-bind (accessor-class make-method-function arglist specls doc)
 414       (ecase type
 415         (reader (values 'standard-reader-method
 416                         #'make-std-reader-method-function
 417                         (list class-name)
 418                         (list class-name)
 419                         "automatically generated reader method"))
 420         (writer (values 'standard-writer-method
 421                         #'make-std-writer-method-function
 422                         (list 'new-value class-name)
 423                         (list t class-name)
 424                         "automatically generated writer method"))
 425         (boundp (values 'standard-boundp-method
 426                         #'make-std-boundp-method-function
 427                         (list class-name)
 428                         (list class-name)
 429                         "automatically generated boundp method")))
 430     (let ((gf (ensure-generic-function accessor-name :lambda-list arglist)))
 431       (if (find specls (early-gf-methods gf)
 432                 :key #'early-method-specializers
 433                 :test 'equal)
 434           (unless (assoc accessor-name *!generic-function-fixups*
 435                          :test #'equal)
 436             (update-dfun gf))
 437           (add-method gf
 438                       (make-a-method accessor-class
 439                                      ()
 440                                      arglist specls
 441                                      (funcall make-method-function
 442                                               class-name slot-name)
 443                                      doc
 444                                      :slot-name slot-name
 445                                      :object-class class-name
 446                                      :method-class-function (constantly (find-class accessor-class))))))))
 447
 448 (defun !bootstrap-accessor-definitions1 (class-name
 449                                         slot-name
 450                                         readers
 451                                         writers
 452                                         boundps)
 453   (flet ((do-reader-definition (reader)
 454            (!bootstrap-accessor-definition class-name
 455                                            reader
 456                                            slot-name
 457                                            'reader))
 458          (do-writer-definition (writer)
 459            (!bootstrap-accessor-definition class-name
 460                                            writer
 461                                            slot-name
 462                                            'writer))
 463          (do-boundp-definition (boundp)
 464            (!bootstrap-accessor-definition class-name
 465                                            boundp
 466                                            slot-name
 467                                            'boundp)))
 468     (dolist (reader readers) (do-reader-definition reader))
 469     (dolist (writer writers) (do-writer-definition writer))
 470     (dolist (boundp boundps) (do-boundp-definition boundp))))
 471
 472 ;;; FIXME: find a better name.
 473 (defun !bootstrap-class-predicates (early-p)
 474   (let ((*early-p* early-p))
 475     (dolist (ecp *early-class-predicates*)
 476       (let ((class-name (car ecp))
 477             (predicate-name (cadr ecp)))
 478         (make-class-predicate (find-class class-name) predicate-name)))))
 479
 480 (defun !bootstrap-built-in-classes ()
 481
 482   ;; First make sure that all the supers listed in
 483   ;; *BUILT-IN-CLASS-LATTICE* are themselves defined by
 484   ;; *BUILT-IN-CLASS-LATTICE*. This is just to check for typos and
 485   ;; other sorts of brainos.
 486   (dolist (e *built-in-classes*)
 487     (dolist (super (cadr e))
 488       (unless (or (eq super t)
 489                   (assq super *built-in-classes*))
 490         (error "in *BUILT-IN-CLASSES*: ~S has ~S as a super,~%~
 491                 but ~S is not itself a class in *BUILT-IN-CLASSES*."
 492                (car e) super super))))
 493
 494   ;; In the first pass, we create a skeletal object to be bound to the
 495   ;; class name.
 496   (let* ((built-in-class (find-class 'built-in-class))
 497          (built-in-class-wrapper (class-wrapper built-in-class)))
 498     (dolist (e *built-in-classes*)
 499       (let ((class (allocate-standard-instance built-in-class-wrapper)))
 500         (setf (find-class (car e)) class))))
 501
 502   ;; In the second pass, we initialize the class objects.
 503   (let ((class-eq-wrapper (class-wrapper (find-class 'class-eq-specializer))))
 504     (dolist (e *built-in-classes*)
 505       (destructuring-bind (name supers subs cpl prototype) e
 506         (let* ((class (find-class name))
 507                (lclass (find-classoid name))
 508                (wrapper (classoid-layout lclass)))
 509           (set (get-built-in-class-symbol name) class)
 510           (set (get-built-in-wrapper-symbol name) wrapper)
 511           (setf (classoid-pcl-class lclass) class)
 512
 513           (!bootstrap-initialize-class 'built-in-class class
 514                                        name class-eq-wrapper nil
 515                                        supers subs
 516                                        (cons name cpl)
 517                                        wrapper prototype))))))
 518 \f
 519 #-sb-fluid (declaim (inline wrapper-of))
 520 (defun wrapper-of (x)
 521   (layout-of x))
 522
 523 (defun class-of (x)
 524   (wrapper-class* (wrapper-of x)))
 525
 526 (defun eval-form (form)
 527   (lambda () (eval form)))
 528
 529 (defun ensure-non-standard-class (name &optional existing-class)
 530   (flet
 531       ((ensure (metaclass &optional (slots nil slotsp))
 532          (let ((supers
 533                 (mapcar #'classoid-name (classoid-direct-superclasses
 534                                          (find-classoid name)))))
 535            (if slotsp
 536                (ensure-class-using-class existing-class name
 537                                          :metaclass metaclass :name name
 538                                          :direct-superclasses supers
 539                                          :direct-slots slots)
 540                (ensure-class-using-class existing-class name
 541                                          :metaclass metaclass :name name
 542                                          :direct-superclasses supers))))
 543        (slot-initargs-from-structure-slotd (slotd)
 544          (let ((accessor (structure-slotd-accessor-symbol slotd)))
 545            `(:name ,(structure-slotd-name slotd)
 546              :defstruct-accessor-symbol ,accessor
 547              ,@(when (fboundp accessor)
 548                  `(:internal-reader-function
 549                    ,(structure-slotd-reader-function slotd)
 550                    :internal-writer-function
 551                    ,(structure-slotd-writer-function name slotd)))
 552              :type ,(or (structure-slotd-type slotd) t)
 553              :initform ,(structure-slotd-init-form slotd)
 554              :initfunction ,(eval-form (structure-slotd-init-form slotd)))))
 555        (slot-initargs-from-condition-slot (slot)
 556          `(:name ,(condition-slot-name slot)
 557            :initargs ,(condition-slot-initargs slot)
 558            :readers ,(condition-slot-readers slot)
 559            :writers ,(condition-slot-writers slot)
 560            ,@(when (condition-slot-initform-p slot)
 561                (let ((form-or-fun (condition-slot-initform slot)))
 562                  (if (functionp form-or-fun)
 563                      `(:initfunction ,form-or-fun)
 564                      `(:initform ,form-or-fun
 565                        :initfunction ,(lambda () form-or-fun)))))
 566            :allocation ,(condition-slot-allocation slot)
 567            :documentation ,(condition-slot-documentation slot))))
 568     (cond ((structure-type-p name)
 569            (ensure 'structure-class
 570                    (mapcar #'slot-initargs-from-structure-slotd
 571                            (structure-type-slot-description-list name))))
 572           ((condition-type-p name)
 573            (ensure 'condition-class
 574                    (mapcar #'slot-initargs-from-condition-slot
 575                            (condition-classoid-slots (find-classoid name)))))
 576           (t
 577            (error "~@<~S is not the name of a class.~@:>" name)))))
 578
 579 (defun ensure-deffoo-class (classoid)
 580   (let ((class (classoid-pcl-class classoid)))
 581     (cond (class
 582            (ensure-non-standard-class (class-name class) class))
 583           ((eq 'complete *boot-state*)
 584            (ensure-non-standard-class (classoid-name classoid))))))
 585
 586 (pushnew 'ensure-deffoo-class sb-kernel::*defstruct-hooks*)
 587 (pushnew 'ensure-deffoo-class sb-kernel::*define-condition-hooks*)
 588 \f
 589 ;;; FIXME: only needed during bootstrap
 590 (defun make-class-predicate (class name)
 591   (let* ((gf (ensure-generic-function name :lambda-list '(object)))
 592          (mlist (if (eq *boot-state* 'complete)
 593                     (generic-function-methods gf)
 594                     (early-gf-methods gf))))
 595     (unless mlist
 596       (unless (eq class *the-class-t*)
 597         (let* ((default-method-function #'constantly-nil)
 598                (default-method-initargs (list :function default-method-function
 599                                               'plist '(:constant-value nil)))
 600                (default-method (make-a-method
 601                                 'standard-method
 602                                 ()
 603                                 (list 'object)
 604                                 (list *the-class-t*)
 605                                 default-method-initargs
 606                                 "class predicate default method")))
 607           (add-method gf default-method)))
 608       (let* ((class-method-function #'constantly-t)
 609              (class-method-initargs (list :function class-method-function
 610                                           'plist '(:constant-value t)))
 611              (class-method (make-a-method 'standard-method
 612                                           ()
 613                                           (list 'object)
 614                                           (list class)
 615                                           class-method-initargs
 616                                           "class predicate class method")))
 617         (add-method gf class-method)))
 618     gf))
 619
 620 ;;; Set the inherits from CPL, and register the layout. This actually
 621 ;;; installs the class in the Lisp type system.
 622 (defun update-lisp-class-layout (class layout)
 623   (let ((classoid (layout-classoid layout))
 624         (olayout (class-wrapper class)))
 625     (unless (eq (classoid-layout classoid) layout)
 626       (setf (layout-inherits layout)
 627             (order-layout-inherits
 628              (map 'simple-vector #'class-wrapper
 629                   (reverse (rest (class-precedence-list class))))))
 630       (register-layout layout :invalidate t)
 631
 632       ;; FIXME: I don't think this should be necessary, but without it
 633       ;; we are unable to compile (TYPEP foo '<class-name>) in the
 634       ;; same file as the class is defined.  If we had environments,
 635       ;; then I think the classsoid whould only be associated with the
 636       ;; name in that environment...  Alternatively, fix the compiler
 637       ;; so that TYPEP foo '<class-name> is slow but compileable.
 638       (let ((name (class-name class)))
 639         (when (and name (symbolp name) (eq name (classoid-name classoid)))
 640           (setf (find-classoid name) classoid))))))
 641
 642 (defun set-class-type-translation (class classoid)
 643   (when (not (typep classoid 'classoid))
 644     (setq classoid (find-classoid classoid nil)))
 645   (etypecase classoid
 646     (null)
 647     (built-in-classoid
 648      (let ((translation (built-in-classoid-translation classoid)))
 649        (cond
 650          (translation
 651           (aver (ctype-p translation))
 652           (setf (info :type :translator class)
 653                 (lambda (spec) (declare (ignore spec)) translation)))
 654          (t
 655           (setf (info :type :translator class)
 656                 (lambda (spec) (declare (ignore spec)) classoid))))))
 657     (classoid
 658      (setf (info :type :translator class)
 659            (lambda (spec) (declare (ignore spec)) classoid)))))
 660
 661 (clrhash *find-class*)
 662 (!bootstrap-meta-braid)
 663 (!bootstrap-accessor-definitions t)
 664 (!bootstrap-class-predicates t)
 665 (!bootstrap-accessor-definitions nil)
 666 (!bootstrap-class-predicates nil)
 667 (!bootstrap-built-in-classes)
 668
 669 (dohash (name x *find-class*)
 670         (let* ((class (find-class-from-cell name x))
 671                (layout (class-wrapper class))
 672                (lclass (layout-classoid layout))
 673                (lclass-pcl-class (classoid-pcl-class lclass))
 674                (olclass (find-classoid name nil)))
 675           (if lclass-pcl-class
 676               (aver (eq class lclass-pcl-class))
 677               (setf (classoid-pcl-class lclass) class))
 678
 679           (update-lisp-class-layout class layout)
 680
 681           (cond (olclass
 682                  (aver (eq lclass olclass)))
 683                 (t
 684                  (setf (find-classoid name) lclass)))
 685
 686           (set-class-type-translation class name)))
 687
 688 (setq *boot-state* 'braid)
 689
 690 (defmethod no-applicable-method (generic-function &rest args)
 691   (error "~@<There is no applicable method for the generic function ~2I~_~S~
 692           ~I~_when called with arguments ~2I~_~S.~:>"
 693          generic-function
 694          args))
 695
 696 (defmethod no-next-method ((generic-function standard-generic-function)
 697                            (method standard-method) &rest args)
 698   (error "~@<There is no next method for the generic function ~2I~_~S~
 699           ~I~_when called from method ~2I~_~S~I~_with arguments ~2I~_~S.~:>"
 700          generic-function
 701          method
 702          args))
 703
 704 ;;; An extension to the ANSI standard: in the presence of e.g. a
 705 ;;; :BEFORE method, it would seem that going through
 706 ;;; NO-APPLICABLE-METHOD is prohibited, as in fact there is an
 707 ;;; applicable method.  -- CSR, 2002-11-15
 708 (defmethod no-primary-method (generic-function &rest args)
 709   (error "~@<There is no primary method for the generic function ~2I~_~S~
 710           ~I~_when called with arguments ~2I~_~S.~:>"
 711          generic-function
 712          args))
 713
 714 (defmethod invalid-qualifiers ((gf generic-function)
 715                                combin
 716                                method)
 717   (let ((qualifiers (method-qualifiers method)))
 718     (let ((why (cond
 719                  ((cdr qualifiers) "has too many qualifiers")
 720                  (t (aver (not (member (car qualifiers)
 721                                        '(:around :before :after))))
 722                     "has an invalid qualifier"))))
 723       (invalid-method-error
 724        method
 725        "The method ~S on ~S ~A.~%~
 726         Standard method combination requires all methods to have one~%~
 727         of the single qualifiers :AROUND, :BEFORE and :AFTER or to~%~
 728         have no qualifier at all."
 729        method gf why))))