src/pcl/braid.lisp

   1 ;;;; bootstrapping the meta-braid
   2 ;;;;
   3 ;;;; The code in this file takes the early definitions that have been
   4 ;;;; saved up and actually builds those class objects. This work is
   5 ;;;; largely driven off of those class definitions, but the fact that
   6 ;;;; STANDARD-CLASS is the class of all metaclasses in the braid is
   7 ;;;; built into this code pretty deeply.
   8
   9 ;;;; This software is part of the SBCL system. See the README file for
  10 ;;;; more information.
  11
  12 ;;;; This software is derived from software originally released by Xerox
  13 ;;;; Corporation. Copyright and release statements follow. Later modifications
  14 ;;;; to the software are in the public domain and are provided with
  15 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
  16 ;;;; information.
  17
  18 ;;;; copyright information from original PCL sources:
  19 ;;;;
  20 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  21 ;;;; All rights reserved.
  22 ;;;;
  23 ;;;; Use and copying of this software and preparation of derivative works based
  24 ;;;; upon this software are permitted. Any distribution of this software or
  25 ;;;; derivative works must comply with all applicable United States export
  26 ;;;; control laws.
  27 ;;;;
  28 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  29 ;;;; warranty about the software, its performance or its conformity to any
  30 ;;;; specification.
  31
  32 (in-package "SB-PCL")
  33 \f
  34 (defun allocate-standard-instance (wrapper
  35                                    &optional (slots-init nil slots-init-p))
  36   (let ((instance (%make-standard-instance nil (get-instance-hash-code)))
  37         (no-of-slots (wrapper-no-of-instance-slots wrapper)))
  38     (setf (std-instance-wrapper instance) wrapper)
  39     (setf (std-instance-slots instance)
  40           (cond (slots-init-p
  41                  ;; Inline the slots vector allocation and initialization.
  42                  (let ((slots (make-array no-of-slots :initial-element 0)))
  43                    (do ((rem-slots slots-init (rest rem-slots))
  44                         (i 0 (1+ i)))
  45                        ((>= i no-of-slots)) ;endp rem-slots))
  46                      (declare (list rem-slots)
  47                               (type index i))
  48                      (setf (aref slots i) (first rem-slots)))
  49                    slots))
  50                 (t
  51                  (make-array no-of-slots
  52                              :initial-element +slot-unbound+))))
  53     instance))
  54
  55 (defmacro allocate-standard-funcallable-instance-slots
  56     (wrapper &optional slots-init-p slots-init)
  57   `(let ((no-of-slots (wrapper-no-of-instance-slots ,wrapper)))
  58     ,(if slots-init-p
  59          `(if ,slots-init-p
  60            (make-array no-of-slots :initial-contents ,slots-init)
  61            (make-array no-of-slots :initial-element +slot-unbound+))
  62          `(make-array no-of-slots :initial-element +slot-unbound+))))
  63
  64 (define-condition unset-funcallable-instance-function
  65     (reference-condition simple-error)
  66   ()
  67   (:default-initargs
  68    :references (list '(:amop :generic-function allocate-instance)
  69                      '(:amop :function set-funcallable-instance-function))))
  70
  71 (defun allocate-standard-funcallable-instance
  72     (wrapper &optional (slots-init nil slots-init-p))
  73   (let ((fin (%make-standard-funcallable-instance
  74               nil nil (get-instance-hash-code))))
  75     (set-funcallable-instance-function
  76      fin
  77      #'(lambda (&rest args)
  78          (declare (ignore args))
  79          (error 'unset-funcallable-instance-function
  80                 :format-control "~@<The function of funcallable instance ~
  81                                  ~S has not been set.~@:>"
  82                 :format-arguments (list fin))))
  83     (setf (fsc-instance-wrapper fin) wrapper
  84           (fsc-instance-slots fin)
  85           (allocate-standard-funcallable-instance-slots
  86            wrapper slots-init-p slots-init))
  87     fin))
  88
  89 (defun allocate-structure-instance (wrapper &optional
  90                                             (slots-init nil slots-init-p))
  91   (let* ((class (wrapper-class wrapper))
  92          (constructor (class-defstruct-constructor class)))
  93     (if constructor
  94         (let ((instance (funcall constructor))
  95               (slots (class-slots class)))
  96           (when slots-init-p
  97             (dolist (slot slots)
  98               (setf (slot-value-using-class class instance slot)
  99                     (pop slots-init))))
 100           instance)
 101         (error "can't allocate an instance of class ~S" (class-name class)))))
 102 \f
 103 ;;;; BOOTSTRAP-META-BRAID
 104 ;;;;
 105 ;;;; This function builds the base metabraid from the early class definitions.
 106
 107 (defmacro !initial-classes-and-wrappers (&rest classes)
 108   `(progn
 109      ,@(mapcar (lambda (class)
 110                  (let ((wr (format-symbol *pcl-package* "~A-WRAPPER" class)))
 111                    `(setf ,wr ,(if (eq class 'standard-generic-function)
 112                                    '*sgf-wrapper*
 113                                    `(boot-make-wrapper
 114                                      (early-class-size ',class)
 115                                      ',class))
 116                           ,class (allocate-standard-instance
 117                                   ,(if (eq class 'standard-generic-function)
 118                                        'funcallable-standard-class-wrapper
 119                                        'standard-class-wrapper))
 120                           (wrapper-class ,wr) ,class
 121                           (find-class ',class) ,class)))
 122                classes)))
 123
 124 (defun !bootstrap-meta-braid ()
 125   (let* ((*create-classes-from-internal-structure-definitions-p* nil)
 126          standard-class-wrapper standard-class
 127          funcallable-standard-class-wrapper funcallable-standard-class
 128          slot-class-wrapper slot-class
 129          built-in-class-wrapper built-in-class
 130          structure-class-wrapper structure-class
 131          condition-class-wrapper condition-class
 132          standard-direct-slot-definition-wrapper
 133          standard-direct-slot-definition
 134          standard-effective-slot-definition-wrapper
 135          standard-effective-slot-definition
 136          class-eq-specializer-wrapper class-eq-specializer
 137          standard-generic-function-wrapper standard-generic-function)
 138     (!initial-classes-and-wrappers
 139      standard-class funcallable-standard-class
 140      slot-class built-in-class structure-class condition-class
 141      standard-direct-slot-definition standard-effective-slot-definition
 142      class-eq-specializer standard-generic-function)
 143     ;; First, make a class metaobject for each of the early classes. For
 144     ;; each metaobject we also set its wrapper. Except for the class T,
 145     ;; the wrapper is always that of STANDARD-CLASS.
 146     (dolist (definition *early-class-definitions*)
 147       (let* ((name (ecd-class-name definition))
 148              (meta (ecd-metaclass definition))
 149              (wrapper (ecase meta
 150                         (slot-class slot-class-wrapper)
 151                         (standard-class standard-class-wrapper)
 152                         (funcallable-standard-class
 153                          funcallable-standard-class-wrapper)
 154                         (built-in-class built-in-class-wrapper)
 155                         (structure-class structure-class-wrapper)
 156                         (condition-class condition-class-wrapper)))
 157              (class (or (find-class name nil)
 158                         (allocate-standard-instance wrapper))))
 159         (setf (find-class name) class)))
 160     (dolist (definition *early-class-definitions*)
 161       (let ((name (ecd-class-name definition))
 162             (meta (ecd-metaclass definition))
 163             (source (ecd-source-location definition))
 164             (direct-supers (ecd-superclass-names definition))
 165             (direct-slots  (ecd-canonical-slots definition))
 166             (other-initargs (ecd-other-initargs definition)))
 167         (let ((direct-default-initargs
 168                (getf other-initargs :direct-default-initargs)))
 169           (multiple-value-bind (slots cpl default-initargs direct-subclasses)
 170               (early-collect-inheritance name)
 171             (let* ((class (find-class name))
 172                    (wrapper (cond ((eq class slot-class)
 173                                    slot-class-wrapper)
 174                                   ((eq class standard-class)
 175                                    standard-class-wrapper)
 176                                   ((eq class funcallable-standard-class)
 177                                    funcallable-standard-class-wrapper)
 178                                   ((eq class standard-direct-slot-definition)
 179                                    standard-direct-slot-definition-wrapper)
 180                                   ((eq class
 181                                        standard-effective-slot-definition)
 182                                    standard-effective-slot-definition-wrapper)
 183                                   ((eq class built-in-class)
 184                                    built-in-class-wrapper)
 185                                   ((eq class structure-class)
 186                                    structure-class-wrapper)
 187                                   ((eq class condition-class)
 188                                    condition-class-wrapper)
 189                                   ((eq class class-eq-specializer)
 190                                    class-eq-specializer-wrapper)
 191                                   ((eq class standard-generic-function)
 192                                    standard-generic-function-wrapper)
 193                                   (t
 194                                    (boot-make-wrapper (length slots) name))))
 195                    (proto nil))
 196               (when (eq name t) (setq *the-wrapper-of-t* wrapper))
 197               (set (make-class-symbol name) class)
 198               (dolist (slot slots)
 199                 (unless (eq (getf slot :allocation :instance) :instance)
 200                   (error "Slot allocation ~S is not supported in bootstrap."
 201                          (getf slot :allocation))))
 202
 203               (when (typep wrapper 'wrapper)
 204                 (setf (wrapper-instance-slots-layout wrapper)
 205                       (mapcar #'canonical-slot-name slots))
 206                 (setf (wrapper-class-slots wrapper)
 207                       ()))
 208
 209               (setq proto (if (eq meta 'funcallable-standard-class)
 210                               (allocate-standard-funcallable-instance wrapper)
 211                               (allocate-standard-instance wrapper)))
 212
 213               (setq direct-slots
 214                     (!bootstrap-make-slot-definitions
 215                      name class direct-slots
 216                      standard-direct-slot-definition-wrapper nil))
 217               (setq slots
 218                     (!bootstrap-make-slot-definitions
 219                      name class slots
 220                      standard-effective-slot-definition-wrapper t))
 221
 222               (setf (layout-slot-table wrapper) (make-slot-table class slots t))
 223
 224               (case meta
 225                 ((standard-class funcallable-standard-class)
 226                  (!bootstrap-initialize-class
 227                   meta
 228                   class name class-eq-specializer-wrapper source
 229                   direct-supers direct-subclasses cpl wrapper proto
 230                   direct-slots slots direct-default-initargs default-initargs))
 231                 (built-in-class         ; *the-class-t*
 232                  (!bootstrap-initialize-class
 233                   meta
 234                   class name class-eq-specializer-wrapper source
 235                   direct-supers direct-subclasses cpl wrapper proto))
 236                 (slot-class             ; *the-class-slot-object*
 237                  (!bootstrap-initialize-class
 238                   meta
 239                   class name class-eq-specializer-wrapper source
 240                   direct-supers direct-subclasses cpl wrapper proto))
 241                 (structure-class        ; *the-class-structure-object*
 242                  (!bootstrap-initialize-class
 243                   meta
 244                   class name class-eq-specializer-wrapper source
 245                   direct-supers direct-subclasses cpl wrapper))
 246                 (condition-class
 247                  (!bootstrap-initialize-class
 248                   meta
 249                   class name class-eq-specializer-wrapper source
 250                   direct-supers direct-subclasses cpl wrapper))))))))
 251
 252     (let* ((smc-class (find-class 'standard-method-combination))
 253            (smc-wrapper (!bootstrap-get-slot 'standard-class
 254                                              smc-class
 255                                              'wrapper))
 256            (smc (allocate-standard-instance smc-wrapper)))
 257       (flet ((set-slot (name value)
 258                (!bootstrap-set-slot 'standard-method-combination
 259                                     smc
 260                                     name
 261                                     value)))
 262         (set-slot 'source nil)
 263         (set-slot 'type-name 'standard)
 264         (set-slot '%documentation "The standard method combination.")
 265         (set-slot 'options ()))
 266       (setq *standard-method-combination* smc))))
 267
 268 ;;; Initialize a class metaobject.
 269 (defun !bootstrap-initialize-class
 270        (metaclass-name class name
 271         class-eq-wrapper source direct-supers direct-subclasses cpl wrapper
 272         &optional
 273         (proto nil proto-p)
 274         direct-slots slots direct-default-initargs default-initargs)
 275   (flet ((classes (names) (mapcar #'find-class names))
 276          (set-slot (slot-name value)
 277            (!bootstrap-set-slot metaclass-name class slot-name value)))
 278     (set-slot 'name name)
 279     (set-slot 'finalized-p t)
 280     (set-slot 'source source)
 281     (set-slot 'safe-p nil)
 282     (set-slot '%type (if (eq class (find-class t))
 283                          t
 284                          ;; FIXME: Could this just be CLASS instead
 285                          ;; of `(CLASS ,CLASS)? If not, why not?
 286                          ;; (See also similar expression in
 287                          ;; SHARED-INITIALIZE :BEFORE (CLASS).)
 288                          `(class ,class)))
 289     (set-slot 'class-eq-specializer
 290               (let ((spec (allocate-standard-instance class-eq-wrapper)))
 291                 (!bootstrap-set-slot 'class-eq-specializer spec '%type
 292                                      `(class-eq ,class))
 293                 (!bootstrap-set-slot 'class-eq-specializer spec 'object
 294                                      class)
 295                 spec))
 296     (set-slot '%class-precedence-list (classes cpl))
 297     (set-slot 'cpl-available-p t)
 298     (set-slot 'can-precede-list (classes (cdr cpl)))
 299     (set-slot 'incompatible-superclass-list nil)
 300     (set-slot 'direct-superclasses (classes direct-supers))
 301     (set-slot 'direct-subclasses (classes direct-subclasses))
 302     (set-slot 'direct-methods (cons nil nil))
 303     (set-slot 'wrapper wrapper)
 304     (set-slot '%documentation nil)
 305     (set-slot 'plist
 306               `(,@(and direct-default-initargs
 307                        `(direct-default-initargs ,direct-default-initargs))
 308                 ,@(and default-initargs
 309                        `(default-initargs ,default-initargs))))
 310     (when (memq metaclass-name '(standard-class funcallable-standard-class
 311                                  structure-class condition-class
 312                                  slot-class))
 313       (set-slot 'direct-slots direct-slots)
 314       (set-slot 'slots slots)
 315       (setf (layout-slot-table wrapper)
 316             (make-slot-table class slots
 317                              (member metaclass-name
 318                                      '(standard-class funcallable-standard-class)))))
 319
 320     ;; For all direct superclasses SUPER of CLASS, make sure CLASS is
 321     ;; a direct subclass of SUPER.  Note that METACLASS-NAME doesn't
 322     ;; matter here for the slot DIRECT-SUBCLASSES, since every class
 323     ;; inherits the slot from class CLASS.
 324     (dolist (super direct-supers)
 325       (let* ((super (find-class super))
 326              (subclasses (!bootstrap-get-slot metaclass-name super
 327                                               'direct-subclasses)))
 328         (cond ((eq +slot-unbound+ subclasses)
 329                (!bootstrap-set-slot metaclass-name super 'direct-subclasses
 330                                     (list class)))
 331               ((not (memq class subclasses))
 332                (!bootstrap-set-slot metaclass-name super 'direct-subclasses
 333                                     (cons class subclasses))))))
 334
 335     (case metaclass-name
 336       (structure-class
 337        (let ((constructor-sym '|STRUCTURE-OBJECT class constructor|))
 338          (set-slot 'defstruct-form
 339                    `(defstruct (structure-object (:constructor
 340                                                   ,constructor-sym)
 341                                                  (:copier nil))))
 342          (set-slot 'defstruct-constructor constructor-sym)
 343          (set-slot 'from-defclass-p t)
 344          (set-slot 'plist nil)
 345          (set-slot 'prototype (funcall constructor-sym))))
 346       (condition-class
 347        (set-slot 'prototype (make-condition name)))
 348       (t
 349        (set-slot 'prototype
 350                  (if proto-p proto (allocate-standard-instance wrapper)))))
 351     class))
 352
 353 (defun !bootstrap-make-slot-definitions (name class slots wrapper effective-p)
 354   (let ((index -1))
 355     (mapcar (lambda (slot)
 356               (incf index)
 357               (!bootstrap-make-slot-definition
 358                name class slot wrapper effective-p index))
 359             slots)))
 360
 361 (defun !bootstrap-make-slot-definition
 362     (name class slot wrapper effective-p index)
 363   (let* ((slotd-class-name (if effective-p
 364                                'standard-effective-slot-definition
 365                                'standard-direct-slot-definition))
 366          (slotd (allocate-standard-instance wrapper))
 367          (slot-name (getf slot :name)))
 368     (flet ((get-val (name) (getf slot name))
 369            (set-val (name val)
 370                     (!bootstrap-set-slot slotd-class-name slotd name val)))
 371       (set-val 'name         slot-name)
 372       (set-val 'initform     (get-val :initform))
 373       (set-val 'initfunction (get-val :initfunction))
 374       (set-val 'initargs     (get-val :initargs))
 375       (set-val 'readers      (get-val :readers))
 376       (set-val 'writers      (get-val :writers))
 377       (set-val 'allocation   :instance)
 378       (set-val '%type        (or (get-val :type) t))
 379       (set-val '%type-check-function (get-val 'type-check-function))
 380       (set-val '%documentation (or (get-val :documentation) ""))
 381       (set-val '%class   class)
 382       (when effective-p
 383         (set-val 'location index)
 384         (let ((fsc-p nil))
 385           (set-val 'reader-function (make-optimized-std-reader-method-function
 386                                      fsc-p nil slot-name index))
 387           (set-val 'writer-function (make-optimized-std-writer-method-function
 388                                      fsc-p nil slot-name index))
 389           (set-val 'boundp-function (make-optimized-std-boundp-method-function
 390                                      fsc-p nil slot-name index)))
 391         (set-val 'accessor-flags 7))
 392       (when (and (eq name 'standard-class)
 393                  (eq slot-name 'slots) effective-p)
 394         (setq *the-eslotd-standard-class-slots* slotd))
 395       (when (and (eq name 'funcallable-standard-class)
 396                  (eq slot-name 'slots) effective-p)
 397         (setq *the-eslotd-funcallable-standard-class-slots* slotd))
 398       slotd)))
 399
 400 (defun !bootstrap-accessor-definitions (early-p)
 401   (let ((*early-p* early-p))
 402     (dolist (definition *early-class-definitions*)
 403       (let ((name (ecd-class-name definition))
 404             (meta (ecd-metaclass definition)))
 405         (unless (eq meta 'built-in-class)
 406           (let ((direct-slots  (ecd-canonical-slots definition)))
 407             (dolist (slotd direct-slots)
 408               (let ((slot-name (getf slotd :name))
 409                     (readers (getf slotd :readers))
 410                     (writers (getf slotd :writers)))
 411                 (!bootstrap-accessor-definitions1
 412                  name
 413                  slot-name
 414                  readers
 415                  writers
 416                  nil)))))))))
 417
 418 (defun !bootstrap-accessor-definition (class-name accessor-name slot-name type)
 419   (multiple-value-bind (accessor-class make-method-function arglist specls doc)
 420       (ecase type
 421         (reader (values 'standard-reader-method
 422                         #'make-std-reader-method-function
 423                         (list class-name)
 424                         (list class-name)
 425                         "automatically generated reader method"))
 426         (writer (values 'standard-writer-method
 427                         #'make-std-writer-method-function
 428                         (list 'new-value class-name)
 429                         (list t class-name)
 430                         "automatically generated writer method"))
 431         (boundp (values 'standard-boundp-method
 432                         #'make-std-boundp-method-function
 433                         (list class-name)
 434                         (list class-name)
 435                         "automatically generated boundp method")))
 436     (let ((gf (ensure-generic-function accessor-name :lambda-list arglist)))
 437       (if (find specls (early-gf-methods gf)
 438                 :key #'early-method-specializers
 439                 :test 'equal)
 440           (unless (assoc accessor-name *!generic-function-fixups*
 441                          :test #'equal)
 442             (update-dfun gf))
 443           (add-method gf
 444                       (make-a-method accessor-class
 445                                      ()
 446                                      arglist specls
 447                                      (funcall make-method-function
 448                                               class-name slot-name)
 449                                      doc
 450                                      :slot-name slot-name
 451                                      :object-class class-name
 452                                      :method-class-function (constantly (find-class accessor-class))))))))
 453
 454 (defun !bootstrap-accessor-definitions1 (class-name
 455                                         slot-name
 456                                         readers
 457                                         writers
 458                                         boundps)
 459   (flet ((do-reader-definition (reader)
 460            (!bootstrap-accessor-definition class-name
 461                                            reader
 462                                            slot-name
 463                                            'reader))
 464          (do-writer-definition (writer)
 465            (!bootstrap-accessor-definition class-name
 466                                            writer
 467                                            slot-name
 468                                            'writer))
 469          (do-boundp-definition (boundp)
 470            (!bootstrap-accessor-definition class-name
 471                                            boundp
 472                                            slot-name
 473                                            'boundp)))
 474     (dolist (reader readers) (do-reader-definition reader))
 475     (dolist (writer writers) (do-writer-definition writer))
 476     (dolist (boundp boundps) (do-boundp-definition boundp))))
 477
 478 ;;; FIXME: find a better name.
 479 (defun !bootstrap-class-predicates (early-p)
 480   (let ((*early-p* early-p))
 481     (dolist (ecp *early-class-predicates*)
 482       (let ((class-name (car ecp))
 483             (predicate-name (cadr ecp)))
 484         (make-class-predicate (find-class class-name) predicate-name)))))
 485
 486 (defun !bootstrap-built-in-classes ()
 487
 488   ;; First make sure that all the supers listed in
 489   ;; *BUILT-IN-CLASS-LATTICE* are themselves defined by
 490   ;; *BUILT-IN-CLASS-LATTICE*. This is just to check for typos and
 491   ;; other sorts of brainos.
 492   (dolist (e *built-in-classes*)
 493     (dolist (super (cadr e))
 494       (unless (or (eq super t)
 495                   (assq super *built-in-classes*))
 496         (error "in *BUILT-IN-CLASSES*: ~S has ~S as a super,~%~
 497                 but ~S is not itself a class in *BUILT-IN-CLASSES*."
 498                (car e) super super))))
 499
 500   ;; In the first pass, we create a skeletal object to be bound to the
 501   ;; class name.
 502   (let* ((built-in-class (find-class 'built-in-class))
 503          (built-in-class-wrapper (class-wrapper built-in-class)))
 504     (dolist (e *built-in-classes*)
 505       (let ((class (allocate-standard-instance built-in-class-wrapper)))
 506         (setf (find-class (car e)) class))))
 507
 508   ;; In the second pass, we initialize the class objects.
 509   (let ((class-eq-wrapper (class-wrapper (find-class 'class-eq-specializer))))
 510     (dolist (e *built-in-classes*)
 511       (destructuring-bind (name supers subs cpl prototype) e
 512         (let* ((class (find-class name))
 513                (lclass (find-classoid name))
 514                (wrapper (classoid-layout lclass)))
 515           (set (get-built-in-class-symbol name) class)
 516           (set (get-built-in-wrapper-symbol name) wrapper)
 517           (setf (classoid-pcl-class lclass) class)
 518
 519           (!bootstrap-initialize-class 'built-in-class class
 520                                        name class-eq-wrapper nil
 521                                        supers subs
 522                                        (cons name cpl)
 523                                        wrapper prototype))))))
 524 \f
 525 #-sb-fluid (declaim (inline wrapper-of))
 526 (defun wrapper-of (x)
 527   (layout-of x))
 528
 529 (defun class-of (x)
 530   (wrapper-class* (wrapper-of x)))
 531
 532 (defun eval-form (form)
 533   (lambda () (eval form)))
 534
 535 (defun ensure-non-standard-class (name &optional existing-class)
 536   (flet
 537       ((ensure (metaclass &optional (slots nil slotsp))
 538          (let ((supers
 539                 (mapcar #'classoid-name (classoid-direct-superclasses
 540                                          (find-classoid name)))))
 541            (if slotsp
 542                (ensure-class-using-class existing-class name
 543                                          :metaclass metaclass :name name
 544                                          :direct-superclasses supers
 545                                          :direct-slots slots)
 546                (ensure-class-using-class existing-class name
 547                                          :metaclass metaclass :name name
 548                                          :direct-superclasses supers))))
 549        (slot-initargs-from-structure-slotd (slotd)
 550          (let ((accessor (structure-slotd-accessor-symbol slotd)))
 551            `(:name ,(structure-slotd-name slotd)
 552              :defstruct-accessor-symbol ,accessor
 553              ,@(when (fboundp accessor)
 554                  `(:internal-reader-function
 555                    ,(structure-slotd-reader-function slotd)
 556                    :internal-writer-function
 557                    ,(structure-slotd-writer-function name slotd)))
 558              :type ,(or (structure-slotd-type slotd) t)
 559              :initform ,(structure-slotd-init-form slotd)
 560              :initfunction ,(eval-form (structure-slotd-init-form slotd)))))
 561        (slot-initargs-from-condition-slot (slot)
 562          `(:name ,(condition-slot-name slot)
 563            :initargs ,(condition-slot-initargs slot)
 564            :readers ,(condition-slot-readers slot)
 565            :writers ,(condition-slot-writers slot)
 566            ,@(when (condition-slot-initform-p slot)
 567                (let ((form-or-fun (condition-slot-initform slot)))
 568                  (if (functionp form-or-fun)
 569                      `(:initfunction ,form-or-fun)
 570                      `(:initform ,form-or-fun
 571                        :initfunction ,(lambda () form-or-fun)))))
 572            :allocation ,(condition-slot-allocation slot)
 573            :documentation ,(condition-slot-documentation slot))))
 574     (cond ((structure-type-p name)
 575            (ensure 'structure-class
 576                    (mapcar #'slot-initargs-from-structure-slotd
 577                            (structure-type-slot-description-list name))))
 578           ((condition-type-p name)
 579            (ensure 'condition-class
 580                    (mapcar #'slot-initargs-from-condition-slot
 581                            (condition-classoid-slots (find-classoid name)))))
 582           (t
 583            (error "~@<~S is not the name of a class.~@:>" name)))))
 584
 585 (defun ensure-deffoo-class (classoid)
 586   (let ((class (classoid-pcl-class classoid)))
 587     (cond (class
 588            (ensure-non-standard-class (class-name class) class))
 589           ((eq 'complete *boot-state*)
 590            (ensure-non-standard-class (classoid-name classoid))))))
 591
 592 (pushnew 'ensure-deffoo-class sb-kernel::*defstruct-hooks*)
 593 (pushnew 'ensure-deffoo-class sb-kernel::*define-condition-hooks*)
 594 \f
 595 ;;; FIXME: only needed during bootstrap
 596 (defun make-class-predicate (class name)
 597   (let* ((gf (ensure-generic-function name :lambda-list '(object)))
 598          (mlist (if (eq *boot-state* 'complete)
 599                     (generic-function-methods gf)
 600                     (early-gf-methods gf))))
 601     (unless mlist
 602       (unless (eq class *the-class-t*)
 603         (let* ((default-method-function #'constantly-nil)
 604                (default-method-initargs (list :function default-method-function
 605                                               'plist '(:constant-value nil)))
 606                (default-method (make-a-method
 607                                 'standard-method
 608                                 ()
 609                                 (list 'object)
 610                                 (list *the-class-t*)
 611                                 default-method-initargs
 612                                 "class predicate default method")))
 613           (add-method gf default-method)))
 614       (let* ((class-method-function #'constantly-t)
 615              (class-method-initargs (list :function class-method-function
 616                                           'plist '(:constant-value t)))
 617              (class-method (make-a-method 'standard-method
 618                                           ()
 619                                           (list 'object)
 620                                           (list class)
 621                                           class-method-initargs
 622                                           "class predicate class method")))
 623         (add-method gf class-method)))
 624     gf))
 625
 626 ;;; Set the inherits from CPL, and register the layout. This actually
 627 ;;; installs the class in the Lisp type system.
 628 (defun update-lisp-class-layout (class layout)
 629   (let ((classoid (layout-classoid layout))
 630         (olayout (class-wrapper class)))
 631     (unless (eq (classoid-layout classoid) layout)
 632       (setf (layout-inherits layout)
 633             (order-layout-inherits
 634              (map 'simple-vector #'class-wrapper
 635                   (reverse (rest (class-precedence-list class))))))
 636       (register-layout layout :invalidate t)
 637
 638       ;; FIXME: I don't think this should be necessary, but without it
 639       ;; we are unable to compile (TYPEP foo '<class-name>) in the
 640       ;; same file as the class is defined.  If we had environments,
 641       ;; then I think the classsoid whould only be associated with the
 642       ;; name in that environment...  Alternatively, fix the compiler
 643       ;; so that TYPEP foo '<class-name> is slow but compileable.
 644       (let ((name (class-name class)))
 645         (when (and name (symbolp name) (eq name (classoid-name classoid)))
 646           (setf (find-classoid name) classoid))))))
 647
 648 (defun set-class-type-translation (class classoid)
 649   (when (not (typep classoid 'classoid))
 650     (setq classoid (find-classoid classoid nil)))
 651   (etypecase classoid
 652     (null)
 653     (built-in-classoid
 654      (let ((translation (built-in-classoid-translation classoid)))
 655        (cond
 656          (translation
 657           (aver (ctype-p translation))
 658           (setf (info :type :translator class)
 659                 (lambda (spec) (declare (ignore spec)) translation)))
 660          (t
 661           (setf (info :type :translator class)
 662                 (lambda (spec) (declare (ignore spec)) classoid))))))
 663     (classoid
 664      (setf (info :type :translator class)
 665            (lambda (spec) (declare (ignore spec)) classoid)))))
 666
 667 (clrhash *find-class*)
 668 (!bootstrap-meta-braid)
 669 (!bootstrap-accessor-definitions t)
 670 (!bootstrap-class-predicates t)
 671 (!bootstrap-accessor-definitions nil)
 672 (!bootstrap-class-predicates nil)
 673 (!bootstrap-built-in-classes)
 674
 675 (dohash ((name x) *find-class*)
 676   (let* ((class (find-class-from-cell name x))
 677          (layout (class-wrapper class))
 678          (lclass (layout-classoid layout))
 679          (lclass-pcl-class (classoid-pcl-class lclass))
 680          (olclass (find-classoid name nil)))
 681     (if lclass-pcl-class
 682         (aver (eq class lclass-pcl-class))
 683         (setf (classoid-pcl-class lclass) class))
 684
 685     (update-lisp-class-layout class layout)
 686
 687     (cond (olclass
 688            (aver (eq lclass olclass)))
 689           (t
 690            (setf (find-classoid name) lclass)))
 691
 692     (set-class-type-translation class name)))
 693
 694 (setq *boot-state* 'braid)
 695
 696 (defmethod no-applicable-method (generic-function &rest args)
 697   (error "~@<There is no applicable method for the generic function ~2I~_~S~
 698           ~I~_when called with arguments ~2I~_~S.~:>"
 699          generic-function
 700          args))
 701
 702 (defmethod no-next-method ((generic-function standard-generic-function)
 703                            (method standard-method) &rest args)
 704   (error "~@<There is no next method for the generic function ~2I~_~S~
 705           ~I~_when called from method ~2I~_~S~I~_with arguments ~2I~_~S.~:>"
 706          generic-function
 707          method
 708          args))
 709
 710 ;;; An extension to the ANSI standard: in the presence of e.g. a
 711 ;;; :BEFORE method, it would seem that going through
 712 ;;; NO-APPLICABLE-METHOD is prohibited, as in fact there is an
 713 ;;; applicable method.  -- CSR, 2002-11-15
 714 (define-condition no-primary-method (reference-condition error)
 715   ((generic-function :initarg :generic-function :reader no-primary-method-generic-function)
 716    (args :initarg :args :reader no-primary-method-args))
 717   (:report
 718    (lambda (c s)
 719      (format s "~@<There is no primary method for the generic function ~2I~_~S~
 720                 ~I~_when called with arguments ~2I~_~S.~:>"
 721              (no-primary-method-generic-function c)
 722              (no-primary-method-args c))))
 723   (:default-initargs :references (list '(:ansi-cl :section (7 6 6 2)))))
 724 (defmethod no-primary-method (generic-function &rest args)
 725   (error 'no-primary-method :generic-function generic-function :args args))
 726
 727 (defmethod invalid-qualifiers ((gf generic-function)
 728                                combin
 729                                method)
 730   (let ((qualifiers (method-qualifiers method)))
 731     (let ((why (cond
 732                  ((cdr qualifiers) "has too many qualifiers")
 733                  (t (aver (not (member (car qualifiers)
 734                                        '(:around :before :after))))
 735                     "has an invalid qualifier"))))
 736       (invalid-method-error
 737        method
 738        "The method ~S on ~S ~A.~%~
 739         Standard method combination requires all methods to have one~%~
 740         of the single qualifiers :AROUND, :BEFORE and :AFTER or to~%~
 741         have no qualifier at all."
 742        method gf why))))