src/pcl/braid.lisp

   1 ;;;; bootstrapping the meta-braid
   2 ;;;;
   3 ;;;; The code in this file takes the early definitions that have been
   4 ;;;; saved up and actually builds those class objects. This work is
   5 ;;;; largely driven off of those class definitions, but the fact that
   6 ;;;; STANDARD-CLASS is the class of all metaclasses in the braid is
   7 ;;;; built into this code pretty deeply.
   8
   9 ;;;; This software is part of the SBCL system. See the README file for
  10 ;;;; more information.
  11
  12 ;;;; This software is derived from software originally released by Xerox
  13 ;;;; Corporation. Copyright and release statements follow. Later modifications
  14 ;;;; to the software are in the public domain and are provided with
  15 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
  16 ;;;; information.
  17
  18 ;;;; copyright information from original PCL sources:
  19 ;;;;
  20 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  21 ;;;; All rights reserved.
  22 ;;;;
  23 ;;;; Use and copying of this software and preparation of derivative works based
  24 ;;;; upon this software are permitted. Any distribution of this software or
  25 ;;;; derivative works must comply with all applicable United States export
  26 ;;;; control laws.
  27 ;;;;
  28 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  29 ;;;; warranty about the software, its performance or its conformity to any
  30 ;;;; specification.
  31
  32 (in-package "SB-PCL")
  33 \f
  34 (defun allocate-standard-instance (wrapper
  35                                    &optional (slots-init nil slots-init-p))
  36   (let ((instance (%make-standard-instance nil (get-instance-hash-code)))
  37         (no-of-slots (wrapper-no-of-instance-slots wrapper)))
  38     (setf (std-instance-wrapper instance) wrapper)
  39     (setf (std-instance-slots instance)
  40           (cond (slots-init-p
  41                  ;; Inline the slots vector allocation and initialization.
  42                  (let ((slots (make-array no-of-slots :initial-element 0)))
  43                    (do ((rem-slots slots-init (rest rem-slots))
  44                         (i 0 (1+ i)))
  45                        ((>= i no-of-slots)) ;endp rem-slots))
  46                      (declare (list rem-slots)
  47                               (type index i))
  48                      (setf (aref slots i) (first rem-slots)))
  49                    slots))
  50                 (t
  51                  (make-array no-of-slots
  52                              :initial-element +slot-unbound+))))
  53     instance))
  54
  55 (defmacro allocate-funcallable-instance-slots (wrapper &optional
  56                                                        slots-init-p slots-init)
  57   `(let ((no-of-slots (wrapper-no-of-instance-slots ,wrapper)))
  58      ,(if slots-init-p
  59           `(if ,slots-init-p
  60                (make-array no-of-slots :initial-contents ,slots-init)
  61                (make-array no-of-slots :initial-element +slot-unbound+))
  62           `(make-array no-of-slots :initial-element +slot-unbound+))))
  63
  64 (defun allocate-funcallable-instance (wrapper &optional
  65                                               (slots-init nil slots-init-p))
  66   (let ((fin (%make-pcl-funcallable-instance nil nil
  67                                              (get-instance-hash-code))))
  68     (set-funcallable-instance-fun
  69      fin
  70      #'(sb-kernel:instance-lambda (&rest args)
  71          (declare (ignore args))
  72          (error "The function of the funcallable-instance ~S has not been set."
  73                 fin)))
  74     (setf (fsc-instance-wrapper fin) wrapper
  75           (fsc-instance-slots fin) (allocate-funcallable-instance-slots
  76                                     wrapper slots-init-p slots-init))
  77     fin))
  78
  79 (defun allocate-structure-instance (wrapper &optional
  80                                             (slots-init nil slots-init-p))
  81   (let* ((class (wrapper-class wrapper))
  82          (constructor (class-defstruct-constructor class)))
  83     (if constructor
  84         (let ((instance (funcall constructor))
  85               (slots (class-slots class)))
  86           (when slots-init-p
  87             (dolist (slot slots)
  88               (setf (slot-value-using-class class instance slot)
  89                     (pop slots-init))))
  90           instance)
  91         (error "can't allocate an instance of class ~S" (class-name class)))))
  92 \f
  93 ;;;; BOOTSTRAP-META-BRAID
  94 ;;;;
  95 ;;;; This function builds the base metabraid from the early class definitions.
  96
  97 (defmacro !initial-classes-and-wrappers (&rest classes)
  98   `(progn
  99      ,@(mapcar (lambda (class)
 100                  (let ((wr (intern (format nil "~A-WRAPPER" class)
 101                                    *pcl-package*)))
 102                    `(setf ,wr ,(if (eq class 'standard-generic-function)
 103                                    '*sgf-wrapper*
 104                                    `(boot-make-wrapper
 105                                      (early-class-size ',class)
 106                                      ',class))
 107                           ,class (allocate-standard-instance
 108                                   ,(if (eq class 'standard-generic-function)
 109                                        'funcallable-standard-class-wrapper
 110                                        'standard-class-wrapper))
 111                           (wrapper-class ,wr) ,class
 112                           (find-class ',class) ,class)))
 113                classes)))
 114
 115 (defun !bootstrap-meta-braid ()
 116   (let* ((*create-classes-from-internal-structure-definitions-p* nil)
 117          std-class-wrapper std-class
 118          standard-class-wrapper standard-class
 119          funcallable-standard-class-wrapper funcallable-standard-class
 120          slot-class-wrapper slot-class
 121          built-in-class-wrapper built-in-class
 122          structure-class-wrapper structure-class
 123          standard-direct-slot-definition-wrapper
 124          standard-direct-slot-definition
 125          standard-effective-slot-definition-wrapper
 126          standard-effective-slot-definition
 127          class-eq-specializer-wrapper class-eq-specializer
 128          standard-generic-function-wrapper standard-generic-function)
 129     (!initial-classes-and-wrappers
 130      standard-class funcallable-standard-class
 131      slot-class built-in-class structure-class std-class
 132      standard-direct-slot-definition standard-effective-slot-definition
 133      class-eq-specializer standard-generic-function)
 134     ;; First, make a class metaobject for each of the early classes. For
 135     ;; each metaobject we also set its wrapper. Except for the class T,
 136     ;; the wrapper is always that of STANDARD-CLASS.
 137     (dolist (definition *early-class-definitions*)
 138       (let* ((name (ecd-class-name definition))
 139              (meta (ecd-metaclass definition))
 140              (wrapper (ecase meta
 141                         (slot-class slot-class-wrapper)
 142                         (std-class std-class-wrapper)
 143                         (standard-class standard-class-wrapper)
 144                         (funcallable-standard-class
 145                          funcallable-standard-class-wrapper)
 146                         (built-in-class built-in-class-wrapper)
 147                         (structure-class structure-class-wrapper)))
 148              (class (or (find-class name nil)
 149                         (allocate-standard-instance wrapper))))
 150         (setf (find-class name) class)))
 151     (dolist (definition *early-class-definitions*)
 152       (let ((name (ecd-class-name definition))
 153             (meta (ecd-metaclass definition))
 154             (source (ecd-source definition))
 155             (direct-supers (ecd-superclass-names definition))
 156             (direct-slots  (ecd-canonical-slots definition))
 157             (other-initargs (ecd-other-initargs definition)))
 158         (let ((direct-default-initargs
 159                (getf other-initargs :direct-default-initargs)))
 160           (multiple-value-bind (slots cpl default-initargs direct-subclasses)
 161               (early-collect-inheritance name)
 162             (let* ((class (find-class name))
 163                    (wrapper (cond ((eq class slot-class)
 164                                    slot-class-wrapper)
 165                                   ((eq class std-class)
 166                                    std-class-wrapper)
 167                                   ((eq class standard-class)
 168                                    standard-class-wrapper)
 169                                   ((eq class funcallable-standard-class)
 170                                    funcallable-standard-class-wrapper)
 171                                   ((eq class standard-direct-slot-definition)
 172                                    standard-direct-slot-definition-wrapper)
 173                                   ((eq class
 174                                        standard-effective-slot-definition)
 175                                    standard-effective-slot-definition-wrapper)
 176                                   ((eq class built-in-class)
 177                                    built-in-class-wrapper)
 178                                   ((eq class structure-class)
 179                                    structure-class-wrapper)
 180                                   ((eq class class-eq-specializer)
 181                                    class-eq-specializer-wrapper)
 182                                   ((eq class standard-generic-function)
 183                                    standard-generic-function-wrapper)
 184                                   (t
 185                                    (boot-make-wrapper (length slots) name))))
 186                    (proto nil))
 187               (when (eq name t) (setq *the-wrapper-of-t* wrapper))
 188               (set (intern (format nil "*THE-CLASS-~A*" (symbol-name name))
 189                            *pcl-package*)
 190                    class)
 191               (dolist (slot slots)
 192                 (unless (eq (getf slot :allocation :instance) :instance)
 193                   (error "Slot allocation ~S is not supported in bootstrap.")))
 194
 195               (when (typep wrapper 'wrapper)
 196                 (setf (wrapper-instance-slots-layout wrapper)
 197                       (mapcar #'canonical-slot-name slots))
 198                 (setf (wrapper-class-slots wrapper)
 199                       ()))
 200
 201               (setq proto (if (eq meta 'funcallable-standard-class)
 202                               (allocate-funcallable-instance wrapper)
 203                               (allocate-standard-instance wrapper)))
 204
 205               (setq direct-slots
 206                     (!bootstrap-make-slot-definitions
 207                      name class direct-slots
 208                      standard-direct-slot-definition-wrapper nil))
 209               (setq slots
 210                     (!bootstrap-make-slot-definitions
 211                      name class slots
 212                      standard-effective-slot-definition-wrapper t))
 213
 214               (case meta
 215                 ((std-class standard-class funcallable-standard-class)
 216                  (!bootstrap-initialize-class
 217                   meta
 218                   class name class-eq-specializer-wrapper source
 219                   direct-supers direct-subclasses cpl wrapper proto
 220                   direct-slots slots direct-default-initargs default-initargs))
 221                 (built-in-class         ; *the-class-t*
 222                  (!bootstrap-initialize-class
 223                   meta
 224                   class name class-eq-specializer-wrapper source
 225                   direct-supers direct-subclasses cpl wrapper proto))
 226                 (slot-class             ; *the-class-slot-object*
 227                  (!bootstrap-initialize-class
 228                   meta
 229                   class name class-eq-specializer-wrapper source
 230                   direct-supers direct-subclasses cpl wrapper proto))
 231                 (structure-class        ; *the-class-structure-object*
 232                  (!bootstrap-initialize-class
 233                   meta
 234                   class name class-eq-specializer-wrapper source
 235                   direct-supers direct-subclasses cpl wrapper))))))))
 236
 237     (let* ((smc-class (find-class 'standard-method-combination))
 238            (smc-wrapper (!bootstrap-get-slot 'standard-class
 239                                              smc-class
 240                                              'wrapper))
 241            (smc (allocate-standard-instance smc-wrapper)))
 242       (flet ((set-slot (name value)
 243                (!bootstrap-set-slot 'standard-method-combination
 244                                     smc
 245                                     name
 246                                     value)))
 247         (set-slot 'source *load-pathname*)
 248         (set-slot 'type 'standard)
 249         (set-slot 'documentation "The standard method combination.")
 250         (set-slot 'options ()))
 251       (setq *standard-method-combination* smc))))
 252
 253 ;;; Initialize a class metaobject.
 254 (defun !bootstrap-initialize-class
 255        (metaclass-name class name
 256         class-eq-wrapper source direct-supers direct-subclasses cpl wrapper
 257         &optional
 258         proto direct-slots slots direct-default-initargs default-initargs)
 259   (flet ((classes (names) (mapcar #'find-class names))
 260          (set-slot (slot-name value)
 261            (!bootstrap-set-slot metaclass-name class slot-name value)))
 262     (set-slot 'name name)
 263     (set-slot 'source source)
 264     (set-slot 'type (if (eq class (find-class t))
 265                         t
 266                         ;; FIXME: Could this just be CLASS instead
 267                         ;; of `(CLASS ,CLASS)? If not, why not?
 268                         ;; (See also similar expression in
 269                         ;; SHARED-INITIALIZE :BEFORE (CLASS).)
 270                         `(class ,class)))
 271     (set-slot 'class-eq-specializer
 272               (let ((spec (allocate-standard-instance class-eq-wrapper)))
 273                 (!bootstrap-set-slot 'class-eq-specializer spec 'type
 274                                      `(class-eq ,class))
 275                 (!bootstrap-set-slot 'class-eq-specializer spec 'object
 276                                      class)
 277                 spec))
 278     (set-slot 'class-precedence-list (classes cpl))
 279     (set-slot 'can-precede-list (classes (cdr cpl)))
 280     (set-slot 'incompatible-superclass-list nil)
 281     (set-slot 'direct-superclasses (classes direct-supers))
 282     (set-slot 'direct-subclasses (classes direct-subclasses))
 283     (set-slot 'direct-methods (cons nil nil))
 284     (set-slot 'wrapper wrapper)
 285     (set-slot 'predicate-name (or (cadr (assoc name *early-class-predicates*))
 286                                   (make-class-predicate-name name)))
 287     (set-slot 'plist
 288               `(,@(and direct-default-initargs
 289                        `(direct-default-initargs ,direct-default-initargs))
 290                 ,@(and default-initargs
 291                        `(default-initargs ,default-initargs))))
 292     (when (memq metaclass-name '(standard-class funcallable-standard-class
 293                                  structure-class slot-class std-class))
 294       (set-slot 'direct-slots direct-slots)
 295       (set-slot 'slots slots)
 296       (set-slot 'initialize-info nil))
 297     (if (eq metaclass-name 'structure-class)
 298         (let ((constructor-sym '|STRUCTURE-OBJECT class constructor|))
 299           (set-slot 'predicate-name (or (cadr (assoc name
 300                                                      *early-class-predicates*))
 301                                         (make-class-predicate-name name)))
 302           (set-slot 'defstruct-form
 303                     `(defstruct (structure-object (:constructor
 304                                                    ,constructor-sym)
 305                                                   (:copier nil))))
 306           (set-slot 'defstruct-constructor constructor-sym)
 307           (set-slot 'from-defclass-p t)
 308           (set-slot 'plist nil)
 309           (set-slot 'prototype (funcall constructor-sym)))
 310         (set-slot 'prototype (or proto (allocate-standard-instance wrapper))))
 311     class))
 312
 313 (defun !bootstrap-make-slot-definitions (name class slots wrapper effective-p)
 314   (let ((index -1))
 315     (mapcar (lambda (slot)
 316               (incf index)
 317               (!bootstrap-make-slot-definition
 318                name class slot wrapper effective-p index))
 319             slots)))
 320
 321 (defun !bootstrap-make-slot-definition
 322     (name class slot wrapper effective-p index)
 323   (let* ((slotd-class-name (if effective-p
 324                                'standard-effective-slot-definition
 325                                'standard-direct-slot-definition))
 326          (slotd (allocate-standard-instance wrapper))
 327          (slot-name (getf slot :name)))
 328     (flet ((get-val (name) (getf slot name))
 329            (set-val (name val)
 330                     (!bootstrap-set-slot slotd-class-name slotd name val)))
 331       (set-val 'name         slot-name)
 332       (set-val 'initform     (get-val :initform))
 333       (set-val 'initfunction (get-val :initfunction))
 334       (set-val 'initargs     (get-val :initargs))
 335       (set-val 'readers      (get-val :readers))
 336       (set-val 'writers      (get-val :writers))
 337       (set-val 'allocation   :instance)
 338       (set-val 'type         (or (get-val :type) t))
 339       (set-val 'documentation (or (get-val :documentation) ""))
 340       (set-val 'class   class)
 341       (when effective-p
 342         (set-val 'location index)
 343         (let ((fsc-p nil))
 344           (set-val 'reader-function (make-optimized-std-reader-method-function
 345                                      fsc-p slot-name index))
 346           (set-val 'writer-function (make-optimized-std-writer-method-function
 347                                      fsc-p slot-name index))
 348           (set-val 'boundp-function (make-optimized-std-boundp-method-function
 349                                      fsc-p slot-name index)))
 350         (set-val 'accessor-flags 7)
 351         (let ((table (or (gethash slot-name *name->class->slotd-table*)
 352                          (setf (gethash slot-name *name->class->slotd-table*)
 353                                (make-hash-table :test 'eq :size 5)))))
 354           (setf (gethash class table) slotd)))
 355       (when (and (eq name 'standard-class)
 356                  (eq slot-name 'slots) effective-p)
 357         (setq *the-eslotd-standard-class-slots* slotd))
 358       (when (and (eq name 'funcallable-standard-class)
 359                  (eq slot-name 'slots) effective-p)
 360         (setq *the-eslotd-funcallable-standard-class-slots* slotd))
 361       slotd)))
 362
 363 (defun !bootstrap-accessor-definitions (early-p)
 364   (let ((*early-p* early-p))
 365     (dolist (definition *early-class-definitions*)
 366       (let ((name (ecd-class-name definition))
 367             (meta (ecd-metaclass definition)))
 368         (unless (eq meta 'built-in-class)
 369           (let ((direct-slots  (ecd-canonical-slots definition)))
 370             (dolist (slotd direct-slots)
 371               (let ((slot-name (getf slotd :name))
 372                     (readers (getf slotd :readers))
 373                     (writers (getf slotd :writers)))
 374                 (!bootstrap-accessor-definitions1
 375                  name
 376                  slot-name
 377                  readers
 378                  writers
 379                  nil)
 380                 (!bootstrap-accessor-definitions1
 381                  'slot-object
 382                  slot-name
 383                  (list (slot-reader-symbol slot-name))
 384                  (list (slot-writer-symbol slot-name))
 385                  (list (slot-boundp-symbol slot-name)))))))))))
 386
 387 (defun !bootstrap-accessor-definition (class-name accessor-name slot-name type)
 388   (multiple-value-bind (accessor-class make-method-function arglist specls doc)
 389       (ecase type
 390         (reader (values 'standard-reader-method
 391                         #'make-std-reader-method-function
 392                         (list class-name)
 393                         (list class-name)
 394                         "automatically generated reader method"))
 395         (writer (values 'standard-writer-method
 396                         #'make-std-writer-method-function
 397                         (list 'new-value class-name)
 398                         (list t class-name)
 399                         "automatically generated writer method"))
 400         (boundp (values 'standard-boundp-method
 401                         #'make-std-boundp-method-function
 402                         (list class-name)
 403                         (list class-name)
 404                         "automatically generated boundp method")))
 405     (let ((gf (ensure-generic-function accessor-name)))
 406       (if (find specls (early-gf-methods gf)
 407                 :key #'early-method-specializers
 408                 :test 'equal)
 409           (unless (assoc accessor-name *!generic-function-fixups*
 410                          :test #'equal)
 411             (update-dfun gf))
 412           (add-method gf
 413                       (make-a-method accessor-class
 414                                      ()
 415                                      arglist specls
 416                                      (funcall make-method-function
 417                                               class-name slot-name)
 418                                      doc
 419                                      slot-name))))))
 420
 421 (defun !bootstrap-accessor-definitions1 (class-name
 422                                         slot-name
 423                                         readers
 424                                         writers
 425                                         boundps)
 426   (flet ((do-reader-definition (reader)
 427            (!bootstrap-accessor-definition class-name
 428                                            reader
 429                                            slot-name
 430                                            'reader))
 431          (do-writer-definition (writer)
 432            (!bootstrap-accessor-definition class-name
 433                                            writer
 434                                            slot-name
 435                                            'writer))
 436          (do-boundp-definition (boundp)
 437            (!bootstrap-accessor-definition class-name
 438                                            boundp
 439                                            slot-name
 440                                            'boundp)))
 441     (dolist (reader readers) (do-reader-definition reader))
 442     (dolist (writer writers) (do-writer-definition writer))
 443     (dolist (boundp boundps) (do-boundp-definition boundp))))
 444
 445 (defun !bootstrap-class-predicates (early-p)
 446   (let ((*early-p* early-p))
 447     (dolist (definition *early-class-definitions*)
 448       (let* ((name (ecd-class-name definition))
 449              (class (find-class name)))
 450         (setf (find-class-predicate name)
 451               (make-class-predicate class (class-predicate-name class)))))))
 452
 453 (defun !bootstrap-built-in-classes ()
 454
 455   ;; First make sure that all the supers listed in
 456   ;; *BUILT-IN-CLASS-LATTICE* are themselves defined by
 457   ;; *BUILT-IN-CLASS-LATTICE*. This is just to check for typos and
 458   ;; other sorts of brainos.
 459   (dolist (e *built-in-classes*)
 460     (dolist (super (cadr e))
 461       (unless (or (eq super t)
 462                   (assq super *built-in-classes*))
 463         (error "in *BUILT-IN-CLASSES*: ~S has ~S as a super,~%~
 464                 but ~S is not itself a class in *BUILT-IN-CLASSES*."
 465                (car e) super super))))
 466
 467   ;; In the first pass, we create a skeletal object to be bound to the
 468   ;; class name.
 469   (let* ((built-in-class (find-class 'built-in-class))
 470          (built-in-class-wrapper (class-wrapper built-in-class)))
 471     (dolist (e *built-in-classes*)
 472       (let ((class (allocate-standard-instance built-in-class-wrapper)))
 473         (setf (find-class (car e)) class))))
 474
 475   ;; In the second pass, we initialize the class objects.
 476   (let ((class-eq-wrapper (class-wrapper (find-class 'class-eq-specializer))))
 477     (dolist (e *built-in-classes*)
 478       (destructuring-bind (name supers subs cpl prototype) e
 479         (let* ((class (find-class name))
 480                (lclass (cl:find-class name))
 481                (wrapper (sb-kernel:class-layout lclass)))
 482           (set (get-built-in-class-symbol name) class)
 483           (set (get-built-in-wrapper-symbol name) wrapper)
 484           (setf (sb-kernel:class-pcl-class lclass) class)
 485
 486           (!bootstrap-initialize-class 'built-in-class class
 487                                        name class-eq-wrapper nil
 488                                        supers subs
 489                                        (cons name cpl)
 490                                        wrapper prototype)))))
 491
 492   (dolist (e *built-in-classes*)
 493     (let* ((name (car e))
 494            (class (find-class name)))
 495       (setf (find-class-predicate name)
 496             (make-class-predicate class (class-predicate-name class))))))
 497 \f
 498 (defmacro wrapper-of-macro (x)
 499   `(sb-kernel:layout-of ,x))
 500
 501 (defun class-of (x)
 502   (wrapper-class* (wrapper-of-macro x)))
 503
 504 ;;; FIXME: We probably don't need both WRAPPER-OF and WRAPPER-OF-MACRO.
 505 #-sb-fluid (declaim (inline wrapper-of))
 506 (defun wrapper-of (x)
 507   (wrapper-of-macro x))
 508
 509 (defvar *find-structure-class* nil)
 510
 511 (defun eval-form (form)
 512   (lambda () (eval form)))
 513
 514 (defun slot-initargs-from-structure-slotd (slotd)
 515   `(:name ,(structure-slotd-name slotd)
 516     :defstruct-accessor-symbol ,(structure-slotd-accessor-symbol slotd)
 517     :internal-reader-function ,(structure-slotd-reader-function slotd)
 518     :internal-writer-function ,(structure-slotd-writer-function slotd)
 519     :type ,(or (structure-slotd-type slotd) t)
 520     :initform ,(structure-slotd-init-form slotd)
 521     :initfunction ,(eval-form (structure-slotd-init-form slotd))))
 522
 523 (defun find-structure-class (symbol)
 524   (if (structure-type-p symbol)
 525       (unless (eq *find-structure-class* symbol)
 526         (let ((*find-structure-class* symbol))
 527           (ensure-class symbol
 528                         :metaclass 'structure-class
 529                         :name symbol
 530                         :direct-superclasses
 531                         (mapcar #'cl:class-name
 532                                 (sb-kernel:class-direct-superclasses
 533                                  (cl:find-class symbol)))
 534                         :direct-slots
 535                         (mapcar #'slot-initargs-from-structure-slotd
 536                                 (structure-type-slot-description-list
 537                                  symbol)))))
 538       (error "~S is not a legal structure class name." symbol)))
 539 \f
 540 (defun make-class-predicate (class name)
 541   (let* ((gf (ensure-generic-function name))
 542          (mlist (if (eq *boot-state* 'complete)
 543                     (generic-function-methods gf)
 544                     (early-gf-methods gf))))
 545     (unless mlist
 546       (unless (eq class *the-class-t*)
 547         (let* ((default-method-function #'constantly-nil)
 548                (default-method-initargs (list :function
 549                                               default-method-function))
 550                (default-method (make-a-method
 551                                 'standard-method
 552                                 ()
 553                                 (list 'object)
 554                                 (list *the-class-t*)
 555                                 default-method-initargs
 556                                 "class predicate default method")))
 557           (setf (method-function-get default-method-function :constant-value)
 558                 nil)
 559           (add-method gf default-method)))
 560       (let* ((class-method-function #'constantly-t)
 561              (class-method-initargs (list :function
 562                                           class-method-function))
 563              (class-method (make-a-method 'standard-method
 564                                           ()
 565                                           (list 'object)
 566                                           (list class)
 567                                           class-method-initargs
 568                                           "class predicate class method")))
 569         (setf (method-function-get class-method-function :constant-value) t)
 570         (add-method gf class-method)))
 571     gf))
 572
 573 ;;; Set the inherits from CPL, and register the layout. This actually
 574 ;;; installs the class in the Lisp type system.
 575 (defun update-lisp-class-layout (class layout)
 576   (let ((lclass (sb-kernel:layout-class layout)))
 577     (unless (eq (sb-kernel:class-layout lclass) layout)
 578       (setf (sb-kernel:layout-inherits layout)
 579               (sb-kernel:order-layout-inherits
 580                (map 'simple-vector #'class-wrapper
 581                     (reverse (rest (class-precedence-list class))))))
 582       (sb-kernel:register-layout layout :invalidate t)
 583
 584       ;; Subclasses of formerly forward-referenced-class may be
 585       ;; unknown to CL:FIND-CLASS and also anonymous. This
 586       ;; functionality moved here from (SETF FIND-CLASS).
 587       (let ((name (class-name class)))
 588         (setf (cl:find-class name) lclass
 589               ;; FIXME: It's nasty to use double colons. Perhaps the
 590               ;; best way to fix this is not to export CLASS-%NAME
 591               ;; from SB-KERNEL, but instead to move the whole
 592               ;; UPDATE-LISP-CLASS-LAYOUT function to SB-KERNEL, and
 593               ;; export it. (since it's also nasty for us to be
 594               ;; reaching into %KERNEL implementation details my
 595               ;; messing with raw CLASS-%NAME)
 596               (sb-kernel::class-%name lclass) name)))))
 597
 598 (clrhash *find-class*)
 599 (!bootstrap-meta-braid)
 600 (!bootstrap-accessor-definitions t)
 601 (!bootstrap-class-predicates t)
 602 (!bootstrap-accessor-definitions nil)
 603 (!bootstrap-class-predicates nil)
 604 (!bootstrap-built-in-classes)
 605
 606 (dohash (name x *find-class*)
 607         (let* ((class (find-class-from-cell name x))
 608                (layout (class-wrapper class))
 609                (lclass (sb-kernel:layout-class layout))
 610                (lclass-pcl-class (sb-kernel:class-pcl-class lclass))
 611                (olclass (cl:find-class name nil)))
 612           (if lclass-pcl-class
 613               (aver (eq class lclass-pcl-class))
 614               (setf (sb-kernel:class-pcl-class lclass) class))
 615
 616           (update-lisp-class-layout class layout)
 617
 618           (cond (olclass
 619                  (aver (eq lclass olclass)))
 620                 (t
 621                  (setf (cl:find-class name) lclass)))))
 622
 623 (setq *boot-state* 'braid)
 624
 625 (defmethod no-applicable-method (generic-function &rest args)
 626   (error "~@<There is no matching method for the generic function ~2I~_~S~
 627           ~I~_when called with arguments ~2I~_~S.~:>"
 628          generic-function
 629          args))
 630
 631 (defmethod no-next-method ((generic-function standard-generic-function)
 632                            (method standard-method) &rest args)
 633   (error "~@<There is no next method for the generic function ~2I~_~S~
 634           ~I~_when called from method ~2I~_~S~I~_with arguments ~2I~_~S.~:>"
 635          generic-function
 636          method
 637          args))