src/pcl/braid.lisp

   1 ;;;; bootstrapping the meta-braid
   2 ;;;;
   3 ;;;; The code in this file takes the early definitions that have been
   4 ;;;; saved up and actually builds those class objects. This work is
   5 ;;;; largely driven off of those class definitions, but the fact that
   6 ;;;; STANDARD-CLASS is the class of all metaclasses in the braid is
   7 ;;;; built into this code pretty deeply.
   8
   9 ;;;; This software is part of the SBCL system. See the README file for
  10 ;;;; more information.
  11
  12 ;;;; This software is derived from software originally released by Xerox
  13 ;;;; Corporation. Copyright and release statements follow. Later modifications
  14 ;;;; to the software are in the public domain and are provided with
  15 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
  16 ;;;; information.
  17
  18 ;;;; copyright information from original PCL sources:
  19 ;;;;
  20 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  21 ;;;; All rights reserved.
  22 ;;;;
  23 ;;;; Use and copying of this software and preparation of derivative works based
  24 ;;;; upon this software are permitted. Any distribution of this software or
  25 ;;;; derivative works must comply with all applicable United States export
  26 ;;;; control laws.
  27 ;;;;
  28 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  29 ;;;; warranty about the software, its performance or its conformity to any
  30 ;;;; specification.
  31
  32 (in-package "SB-PCL")
  33 \f
  34 (defun allocate-standard-instance (wrapper
  35                                    &optional (slots-init nil slots-init-p))
  36   (let ((instance (%make-standard-instance nil (get-instance-hash-code)))
  37         (no-of-slots (wrapper-no-of-instance-slots wrapper)))
  38     (setf (std-instance-wrapper instance) wrapper)
  39     (setf (std-instance-slots instance)
  40           (cond (slots-init-p
  41                  ;; Inline the slots vector allocation and initialization.
  42                  (let ((slots (make-array no-of-slots :initial-element 0)))
  43                    (do ((rem-slots slots-init (rest rem-slots))
  44                         (i 0 (1+ i)))
  45                        ((>= i no-of-slots)) ;endp rem-slots))
  46                      (declare (list rem-slots)
  47                               (type index i))
  48                      (setf (aref slots i) (first rem-slots)))
  49                    slots))
  50                 (t
  51                  (make-array no-of-slots
  52                              :initial-element +slot-unbound+))))
  53     instance))
  54
  55 (defmacro allocate-funcallable-instance-slots (wrapper &optional
  56                                                        slots-init-p slots-init)
  57   `(let ((no-of-slots (wrapper-no-of-instance-slots ,wrapper)))
  58      ,(if slots-init-p
  59           `(if ,slots-init-p
  60                (make-array no-of-slots :initial-contents ,slots-init)
  61                (make-array no-of-slots :initial-element +slot-unbound+))
  62           `(make-array no-of-slots :initial-element +slot-unbound+))))
  63
  64 (defun allocate-funcallable-instance (wrapper &optional
  65                                               (slots-init nil slots-init-p))
  66   (let ((fin (%make-pcl-funcallable-instance nil nil
  67                                              (get-instance-hash-code))))
  68     (set-funcallable-instance-function
  69      fin
  70      #'(instance-lambda (&rest args)
  71          (declare (ignore args))
  72          (error "The function of the funcallable-instance ~S has not been set."
  73                 fin)))
  74     (setf (fsc-instance-wrapper fin) wrapper
  75           (fsc-instance-slots fin) (allocate-funcallable-instance-slots
  76                                     wrapper slots-init-p slots-init))
  77     fin))
  78
  79 (defun allocate-structure-instance (wrapper &optional
  80                                             (slots-init nil slots-init-p))
  81   (let* ((class (wrapper-class wrapper))
  82          (constructor (class-defstruct-constructor class)))
  83     (if constructor
  84         (let ((instance (funcall constructor))
  85               (slots (class-slots class)))
  86           (when slots-init-p
  87             (dolist (slot slots)
  88               (setf (slot-value-using-class class instance slot)
  89                     (pop slots-init))))
  90           instance)
  91         (error "can't allocate an instance of class ~S" (class-name class)))))
  92 \f
  93 ;;;; BOOTSTRAP-META-BRAID
  94 ;;;;
  95 ;;;; This function builds the base metabraid from the early class definitions.
  96
  97 (defmacro !initial-classes-and-wrappers (&rest classes)
  98   `(progn
  99      ,@(mapcar (lambda (class)
 100                  (let ((wr (intern (format nil "~A-WRAPPER" class)
 101                                    *pcl-package*)))
 102                    `(setf ,wr ,(if (eq class 'standard-generic-function)
 103                                    '*sgf-wrapper*
 104                                    `(boot-make-wrapper
 105                                      (early-class-size ',class)
 106                                      ',class))
 107                           ,class (allocate-standard-instance
 108                                   ,(if (eq class 'standard-generic-function)
 109                                        'funcallable-standard-class-wrapper
 110                                        'standard-class-wrapper))
 111                           (wrapper-class ,wr) ,class
 112                           (find-class ',class) ,class)))
 113                classes)))
 114
 115 (defun !bootstrap-meta-braid ()
 116   (let* ((*create-classes-from-internal-structure-definitions-p* nil)
 117          std-class-wrapper std-class
 118          standard-class-wrapper standard-class
 119          funcallable-standard-class-wrapper funcallable-standard-class
 120          slot-class-wrapper slot-class
 121          built-in-class-wrapper built-in-class
 122          structure-class-wrapper structure-class
 123          standard-direct-slot-definition-wrapper
 124          standard-direct-slot-definition
 125          standard-effective-slot-definition-wrapper
 126          standard-effective-slot-definition
 127          class-eq-specializer-wrapper class-eq-specializer
 128          standard-generic-function-wrapper standard-generic-function)
 129     (!initial-classes-and-wrappers
 130      standard-class funcallable-standard-class
 131      slot-class built-in-class structure-class std-class
 132      standard-direct-slot-definition standard-effective-slot-definition
 133      class-eq-specializer standard-generic-function)
 134     ;; First, make a class metaobject for each of the early classes. For
 135     ;; each metaobject we also set its wrapper. Except for the class T,
 136     ;; the wrapper is always that of STANDARD-CLASS.
 137     (dolist (definition *early-class-definitions*)
 138       (let* ((name (ecd-class-name definition))
 139              (meta (ecd-metaclass definition))
 140              (wrapper (ecase meta
 141                         (slot-class slot-class-wrapper)
 142                         (std-class std-class-wrapper)
 143                         (standard-class standard-class-wrapper)
 144                         (funcallable-standard-class
 145                          funcallable-standard-class-wrapper)
 146                         (built-in-class built-in-class-wrapper)
 147                         (structure-class structure-class-wrapper)))
 148              (class (or (find-class name nil)
 149                         (allocate-standard-instance wrapper))))
 150         (setf (find-class name) class)))
 151     (dolist (definition *early-class-definitions*)
 152       (let ((name (ecd-class-name definition))
 153             (meta (ecd-metaclass definition))
 154             (source (ecd-source definition))
 155             (direct-supers (ecd-superclass-names definition))
 156             (direct-slots  (ecd-canonical-slots definition))
 157             (other-initargs (ecd-other-initargs definition)))
 158         (let ((direct-default-initargs
 159                (getf other-initargs :direct-default-initargs)))
 160           (multiple-value-bind (slots cpl default-initargs direct-subclasses)
 161               (early-collect-inheritance name)
 162             (let* ((class (find-class name))
 163                    (wrapper (cond ((eq class slot-class)
 164                                    slot-class-wrapper)
 165                                   ((eq class std-class)
 166                                    std-class-wrapper)
 167                                   ((eq class standard-class)
 168                                    standard-class-wrapper)
 169                                   ((eq class funcallable-standard-class)
 170                                    funcallable-standard-class-wrapper)
 171                                   ((eq class standard-direct-slot-definition)
 172                                    standard-direct-slot-definition-wrapper)
 173                                   ((eq class
 174                                        standard-effective-slot-definition)
 175                                    standard-effective-slot-definition-wrapper)
 176                                   ((eq class built-in-class)
 177                                    built-in-class-wrapper)
 178                                   ((eq class structure-class)
 179                                    structure-class-wrapper)
 180                                   ((eq class class-eq-specializer)
 181                                    class-eq-specializer-wrapper)
 182                                   ((eq class standard-generic-function)
 183                                    standard-generic-function-wrapper)
 184                                   (t
 185                                    (boot-make-wrapper (length slots) name))))
 186                    (proto nil))
 187               (when (eq name t) (setq *the-wrapper-of-t* wrapper))
 188               (set (intern (format nil "*THE-CLASS-~A*" (symbol-name name))
 189                            *pcl-package*)
 190                    class)
 191               (dolist (slot slots)
 192                 (unless (eq (getf slot :allocation :instance) :instance)
 193                   (error "Slot allocation ~S is not supported in bootstrap.")))
 194
 195               (when (typep wrapper 'wrapper)
 196                 (setf (wrapper-instance-slots-layout wrapper)
 197                       (mapcar #'canonical-slot-name slots))
 198                 (setf (wrapper-class-slots wrapper)
 199                       ()))
 200
 201               (setq proto (if (eq meta 'funcallable-standard-class)
 202                               (allocate-funcallable-instance wrapper)
 203                               (allocate-standard-instance wrapper)))
 204
 205               (setq direct-slots
 206                     (!bootstrap-make-slot-definitions
 207                      name class direct-slots
 208                      standard-direct-slot-definition-wrapper nil))
 209               (setq slots
 210                     (!bootstrap-make-slot-definitions
 211                      name class slots
 212                      standard-effective-slot-definition-wrapper t))
 213
 214               (case meta
 215                 ((std-class standard-class funcallable-standard-class)
 216                  (!bootstrap-initialize-class
 217                   meta
 218                   class name class-eq-specializer-wrapper source
 219                   direct-supers direct-subclasses cpl wrapper proto
 220                   direct-slots slots direct-default-initargs default-initargs))
 221                 (built-in-class         ; *the-class-t*
 222                  (!bootstrap-initialize-class
 223                   meta
 224                   class name class-eq-specializer-wrapper source
 225                   direct-supers direct-subclasses cpl wrapper proto))
 226                 (slot-class             ; *the-class-slot-object*
 227                  (!bootstrap-initialize-class
 228                   meta
 229                   class name class-eq-specializer-wrapper source
 230                   direct-supers direct-subclasses cpl wrapper proto))
 231                 (structure-class        ; *the-class-structure-object*
 232                  (!bootstrap-initialize-class
 233                   meta
 234                   class name class-eq-specializer-wrapper source
 235                   direct-supers direct-subclasses cpl wrapper))))))))
 236
 237     (let* ((smc-class (find-class 'standard-method-combination))
 238            (smc-wrapper (!bootstrap-get-slot 'standard-class
 239                                              smc-class
 240                                              'wrapper))
 241            (smc (allocate-standard-instance smc-wrapper)))
 242       (flet ((set-slot (name value)
 243                (!bootstrap-set-slot 'standard-method-combination
 244                                     smc
 245                                     name
 246                                     value)))
 247         (set-slot 'source *load-pathname*)
 248         (set-slot 'type 'standard)
 249         (set-slot 'documentation "The standard method combination.")
 250         (set-slot 'options ()))
 251       (setq *standard-method-combination* smc))))
 252
 253 ;;; Initialize a class metaobject.
 254 (defun !bootstrap-initialize-class
 255        (metaclass-name class name
 256         class-eq-wrapper source direct-supers direct-subclasses cpl wrapper
 257         &optional
 258         (proto nil proto-p)
 259         direct-slots slots direct-default-initargs default-initargs)
 260   (flet ((classes (names) (mapcar #'find-class names))
 261          (set-slot (slot-name value)
 262            (!bootstrap-set-slot metaclass-name class slot-name value)))
 263     (set-slot 'name name)
 264     (set-slot 'finalized-p t)
 265     (set-slot 'source source)
 266     (set-slot 'type (if (eq class (find-class t))
 267                         t
 268                         ;; FIXME: Could this just be CLASS instead
 269                         ;; of `(CLASS ,CLASS)? If not, why not?
 270                         ;; (See also similar expression in
 271                         ;; SHARED-INITIALIZE :BEFORE (CLASS).)
 272                         `(class ,class)))
 273     (set-slot 'class-eq-specializer
 274               (let ((spec (allocate-standard-instance class-eq-wrapper)))
 275                 (!bootstrap-set-slot 'class-eq-specializer spec 'type
 276                                      `(class-eq ,class))
 277                 (!bootstrap-set-slot 'class-eq-specializer spec 'object
 278                                      class)
 279                 spec))
 280     (set-slot 'class-precedence-list (classes cpl))
 281     (set-slot 'can-precede-list (classes (cdr cpl)))
 282     (set-slot 'incompatible-superclass-list nil)
 283     (set-slot 'direct-superclasses (classes direct-supers))
 284     (set-slot 'direct-subclasses (classes direct-subclasses))
 285     (set-slot 'direct-methods (cons nil nil))
 286     (set-slot 'wrapper wrapper)
 287     (set-slot 'predicate-name (or (cadr (assoc name *early-class-predicates*))
 288                                   (make-class-predicate-name name)))
 289     (set-slot 'plist
 290               `(,@(and direct-default-initargs
 291                        `(direct-default-initargs ,direct-default-initargs))
 292                 ,@(and default-initargs
 293                        `(default-initargs ,default-initargs))))
 294     (when (memq metaclass-name '(standard-class funcallable-standard-class
 295                                  structure-class slot-class std-class))
 296       (set-slot 'direct-slots direct-slots)
 297       (set-slot 'slots slots)
 298       (set-slot 'initialize-info nil))
 299
 300     ;; For all direct superclasses SUPER of CLASS, make sure CLASS is
 301     ;; a direct subclass of SUPER.  Note that METACLASS-NAME doesn't
 302     ;; matter here for the slot DIRECT-SUBCLASSES, since every class
 303     ;; inherits the slot from class CLASS.
 304     (dolist (super direct-supers)
 305       (let* ((super (find-class super))
 306              (subclasses (!bootstrap-get-slot metaclass-name super
 307                                               'direct-subclasses)))
 308         (cond ((eq +slot-unbound+ subclasses)
 309                (!bootstrap-set-slot metaclass-name super 'direct-subclasses
 310                                     (list class)))
 311               ((not (memq class subclasses))
 312                (!bootstrap-set-slot metaclass-name super 'direct-subclasses
 313                                     (cons class subclasses))))))
 314
 315     (if (eq metaclass-name 'structure-class)
 316         (let ((constructor-sym '|STRUCTURE-OBJECT class constructor|))
 317           (set-slot 'predicate-name (or (cadr (assoc name
 318                                                      *early-class-predicates*))
 319                                         (make-class-predicate-name name)))
 320           (set-slot 'defstruct-form
 321                     `(defstruct (structure-object (:constructor
 322                                                    ,constructor-sym)
 323                                                   (:copier nil))))
 324           (set-slot 'defstruct-constructor constructor-sym)
 325           (set-slot 'from-defclass-p t)
 326           (set-slot 'plist nil)
 327           (set-slot 'prototype (funcall constructor-sym)))
 328         (set-slot 'prototype
 329                   (if proto-p proto (allocate-standard-instance wrapper))))
 330     class))
 331
 332 (defun !bootstrap-make-slot-definitions (name class slots wrapper effective-p)
 333   (let ((index -1))
 334     (mapcar (lambda (slot)
 335               (incf index)
 336               (!bootstrap-make-slot-definition
 337                name class slot wrapper effective-p index))
 338             slots)))
 339
 340 (defun !bootstrap-make-slot-definition
 341     (name class slot wrapper effective-p index)
 342   (let* ((slotd-class-name (if effective-p
 343                                'standard-effective-slot-definition
 344                                'standard-direct-slot-definition))
 345          (slotd (allocate-standard-instance wrapper))
 346          (slot-name (getf slot :name)))
 347     (flet ((get-val (name) (getf slot name))
 348            (set-val (name val)
 349                     (!bootstrap-set-slot slotd-class-name slotd name val)))
 350       (set-val 'name         slot-name)
 351       (set-val 'initform     (get-val :initform))
 352       (set-val 'initfunction (get-val :initfunction))
 353       (set-val 'initargs     (get-val :initargs))
 354       (set-val 'readers      (get-val :readers))
 355       (set-val 'writers      (get-val :writers))
 356       (set-val 'allocation   :instance)
 357       (set-val 'type         (or (get-val :type) t))
 358       (set-val 'documentation (or (get-val :documentation) ""))
 359       (set-val 'class   class)
 360       (when effective-p
 361         (set-val 'location index)
 362         (let ((fsc-p nil))
 363           (set-val 'reader-function (make-optimized-std-reader-method-function
 364                                      fsc-p slot-name index))
 365           (set-val 'writer-function (make-optimized-std-writer-method-function
 366                                      fsc-p slot-name index))
 367           (set-val 'boundp-function (make-optimized-std-boundp-method-function
 368                                      fsc-p slot-name index)))
 369         (set-val 'accessor-flags 7)
 370         (let ((table (or (gethash slot-name *name->class->slotd-table*)
 371                          (setf (gethash slot-name *name->class->slotd-table*)
 372                                (make-hash-table :test 'eq :size 5)))))
 373           (setf (gethash class table) slotd)))
 374       (when (and (eq name 'standard-class)
 375                  (eq slot-name 'slots) effective-p)
 376         (setq *the-eslotd-standard-class-slots* slotd))
 377       (when (and (eq name 'funcallable-standard-class)
 378                  (eq slot-name 'slots) effective-p)
 379         (setq *the-eslotd-funcallable-standard-class-slots* slotd))
 380       slotd)))
 381
 382 (defun !bootstrap-accessor-definitions (early-p)
 383   (let ((*early-p* early-p))
 384     (dolist (definition *early-class-definitions*)
 385       (let ((name (ecd-class-name definition))
 386             (meta (ecd-metaclass definition)))
 387         (unless (eq meta 'built-in-class)
 388           (let ((direct-slots  (ecd-canonical-slots definition)))
 389             (dolist (slotd direct-slots)
 390               (let ((slot-name (getf slotd :name))
 391                     (readers (getf slotd :readers))
 392                     (writers (getf slotd :writers)))
 393                 (!bootstrap-accessor-definitions1
 394                  name
 395                  slot-name
 396                  readers
 397                  writers
 398                  nil)
 399                 (!bootstrap-accessor-definitions1
 400                  'slot-object
 401                  slot-name
 402                  (list (slot-reader-name slot-name))
 403                  (list (slot-writer-name slot-name))
 404                  (list (slot-boundp-name slot-name)))))))))))
 405
 406 (defun !bootstrap-accessor-definition (class-name accessor-name slot-name type)
 407   (multiple-value-bind (accessor-class make-method-function arglist specls doc)
 408       (ecase type
 409         (reader (values 'standard-reader-method
 410                         #'make-std-reader-method-function
 411                         (list class-name)
 412                         (list class-name)
 413                         "automatically generated reader method"))
 414         (writer (values 'standard-writer-method
 415                         #'make-std-writer-method-function
 416                         (list 'new-value class-name)
 417                         (list t class-name)
 418                         "automatically generated writer method"))
 419         (boundp (values 'standard-boundp-method
 420                         #'make-std-boundp-method-function
 421                         (list class-name)
 422                         (list class-name)
 423                         "automatically generated boundp method")))
 424     (let ((gf (ensure-generic-function accessor-name)))
 425       (if (find specls (early-gf-methods gf)
 426                 :key #'early-method-specializers
 427                 :test 'equal)
 428           (unless (assoc accessor-name *!generic-function-fixups*
 429                          :test #'equal)
 430             (update-dfun gf))
 431           (add-method gf
 432                       (make-a-method accessor-class
 433                                      ()
 434                                      arglist specls
 435                                      (funcall make-method-function
 436                                               class-name slot-name)
 437                                      doc
 438                                      slot-name))))))
 439
 440 (defun !bootstrap-accessor-definitions1 (class-name
 441                                         slot-name
 442                                         readers
 443                                         writers
 444                                         boundps)
 445   (flet ((do-reader-definition (reader)
 446            (!bootstrap-accessor-definition class-name
 447                                            reader
 448                                            slot-name
 449                                            'reader))
 450          (do-writer-definition (writer)
 451            (!bootstrap-accessor-definition class-name
 452                                            writer
 453                                            slot-name
 454                                            'writer))
 455          (do-boundp-definition (boundp)
 456            (!bootstrap-accessor-definition class-name
 457                                            boundp
 458                                            slot-name
 459                                            'boundp)))
 460     (dolist (reader readers) (do-reader-definition reader))
 461     (dolist (writer writers) (do-writer-definition writer))
 462     (dolist (boundp boundps) (do-boundp-definition boundp))))
 463
 464 (defun !bootstrap-class-predicates (early-p)
 465   (let ((*early-p* early-p))
 466     (dolist (definition *early-class-definitions*)
 467       (let* ((name (ecd-class-name definition))
 468              (class (find-class name)))
 469         (setf (find-class-predicate name)
 470               (make-class-predicate class (class-predicate-name class)))))))
 471
 472 (defun !bootstrap-built-in-classes ()
 473
 474   ;; First make sure that all the supers listed in
 475   ;; *BUILT-IN-CLASS-LATTICE* are themselves defined by
 476   ;; *BUILT-IN-CLASS-LATTICE*. This is just to check for typos and
 477   ;; other sorts of brainos.
 478   (dolist (e *built-in-classes*)
 479     (dolist (super (cadr e))
 480       (unless (or (eq super t)
 481                   (assq super *built-in-classes*))
 482         (error "in *BUILT-IN-CLASSES*: ~S has ~S as a super,~%~
 483                 but ~S is not itself a class in *BUILT-IN-CLASSES*."
 484                (car e) super super))))
 485
 486   ;; In the first pass, we create a skeletal object to be bound to the
 487   ;; class name.
 488   (let* ((built-in-class (find-class 'built-in-class))
 489          (built-in-class-wrapper (class-wrapper built-in-class)))
 490     (dolist (e *built-in-classes*)
 491       (let ((class (allocate-standard-instance built-in-class-wrapper)))
 492         (setf (find-class (car e)) class))))
 493
 494   ;; In the second pass, we initialize the class objects.
 495   (let ((class-eq-wrapper (class-wrapper (find-class 'class-eq-specializer))))
 496     (dolist (e *built-in-classes*)
 497       (destructuring-bind (name supers subs cpl prototype) e
 498         (let* ((class (find-class name))
 499                (lclass (find-classoid name))
 500                (wrapper (classoid-layout lclass)))
 501           (set (get-built-in-class-symbol name) class)
 502           (set (get-built-in-wrapper-symbol name) wrapper)
 503           (setf (classoid-pcl-class lclass) class)
 504
 505           (!bootstrap-initialize-class 'built-in-class class
 506                                        name class-eq-wrapper nil
 507                                        supers subs
 508                                        (cons name cpl)
 509                                        wrapper prototype)))))
 510
 511   (dolist (e *built-in-classes*)
 512     (let* ((name (car e))
 513            (class (find-class name)))
 514       (setf (find-class-predicate name)
 515             (make-class-predicate class (class-predicate-name class))))))
 516 \f
 517 (defmacro wrapper-of-macro (x)
 518   `(layout-of ,x))
 519
 520 (defun class-of (x)
 521   (wrapper-class* (wrapper-of-macro x)))
 522
 523 ;;; FIXME: We probably don't need both WRAPPER-OF and WRAPPER-OF-MACRO.
 524 #-sb-fluid (declaim (inline wrapper-of))
 525 (defun wrapper-of (x)
 526   (wrapper-of-macro x))
 527
 528 (defun eval-form (form)
 529   (lambda () (eval form)))
 530
 531 (defun ensure-non-standard-class (name &optional existing-class)
 532   (flet
 533       ((ensure (metaclass &optional (slots nil slotsp))
 534          (let ((supers
 535                 (mapcar #'classoid-name (classoid-direct-superclasses
 536                                          (find-classoid name)))))
 537            (if slotsp
 538                (ensure-class-using-class existing-class name
 539                                          :metaclass metaclass :name name
 540                                          :direct-superclasses supers
 541                                          :direct-slots slots)
 542                (ensure-class-using-class existing-class name
 543                                          :metaclass metaclass :name name
 544                                          :direct-superclasses supers))))
 545        (slot-initargs-from-structure-slotd (slotd)
 546          (let ((accessor (structure-slotd-accessor-symbol slotd)))
 547            `(:name ,(structure-slotd-name slotd)
 548              :defstruct-accessor-symbol ,accessor
 549              ,@(when (fboundp accessor)
 550                  `(:internal-reader-function
 551                    ,(structure-slotd-reader-function slotd)
 552                    :internal-writer-function
 553                    ,(structure-slotd-writer-function slotd)))
 554              :type ,(or (structure-slotd-type slotd) t)
 555              :initform ,(structure-slotd-init-form slotd)
 556              :initfunction ,(eval-form (structure-slotd-init-form slotd))))))
 557     (cond ((structure-type-p name)
 558            (ensure 'structure-class
 559                    (mapcar #'slot-initargs-from-structure-slotd
 560                            (structure-type-slot-description-list name))))
 561           ((condition-type-p name)
 562            (ensure 'condition-class))
 563           (t
 564            (error "~@<~S is not the name of a class.~@:>" name)))))
 565
 566 (defun maybe-reinitialize-structure-class (classoid)
 567   (let ((class (classoid-pcl-class classoid)))
 568     (when class
 569       (ensure-non-standard-class (class-name class) class))))
 570
 571 (pushnew 'maybe-reinitialize-structure-class sb-kernel::*defstruct-hooks*)
 572 \f
 573 (defun make-class-predicate (class name)
 574   (let* ((gf (ensure-generic-function name))
 575          (mlist (if (eq *boot-state* 'complete)
 576                     (generic-function-methods gf)
 577                     (early-gf-methods gf))))
 578     (unless mlist
 579       (unless (eq class *the-class-t*)
 580         (let* ((default-method-function #'constantly-nil)
 581                (default-method-initargs (list :function
 582                                               default-method-function))
 583                (default-method (make-a-method
 584                                 'standard-method
 585                                 ()
 586                                 (list 'object)
 587                                 (list *the-class-t*)
 588                                 default-method-initargs
 589                                 "class predicate default method")))
 590           (setf (method-function-get default-method-function :constant-value)
 591                 nil)
 592           (add-method gf default-method)))
 593       (let* ((class-method-function #'constantly-t)
 594              (class-method-initargs (list :function
 595                                           class-method-function))
 596              (class-method (make-a-method 'standard-method
 597                                           ()
 598                                           (list 'object)
 599                                           (list class)
 600                                           class-method-initargs
 601                                           "class predicate class method")))
 602         (setf (method-function-get class-method-function :constant-value) t)
 603         (add-method gf class-method)))
 604     gf))
 605
 606 ;;; Set the inherits from CPL, and register the layout. This actually
 607 ;;; installs the class in the Lisp type system.
 608 (defun update-lisp-class-layout (class layout)
 609   (let ((lclass (layout-classoid layout)))
 610     (unless (eq (classoid-layout lclass) layout)
 611       (setf (layout-inherits layout)
 612               (order-layout-inherits
 613                (map 'simple-vector #'class-wrapper
 614                     (reverse (rest (class-precedence-list class))))))
 615       (register-layout layout :invalidate t)
 616
 617       ;; Subclasses of formerly forward-referenced-class may be
 618       ;; unknown to CL:FIND-CLASS and also anonymous. This
 619       ;; functionality moved here from (SETF FIND-CLASS).
 620       (let ((name (class-name class)))
 621         (setf (find-classoid name) lclass
 622               (classoid-name lclass) name)))))
 623
 624 (defun set-class-type-translation (class name)
 625   (let ((classoid (find-classoid name nil)))
 626     (etypecase classoid
 627       (null)
 628       (built-in-classoid
 629        (let ((translation (built-in-classoid-translation classoid)))
 630          (cond
 631            (translation
 632             (aver (ctype-p translation))
 633             (setf (info :type :translator class)
 634                   (lambda (spec) (declare (ignore spec)) translation)))
 635            (t
 636             (setf (info :type :translator class)
 637                   (lambda (spec) (declare (ignore spec)) classoid))))))
 638       (classoid
 639        (setf (info :type :translator class)
 640              (lambda (spec) (declare (ignore spec)) classoid))))))
 641
 642 (clrhash *find-class*)
 643 (!bootstrap-meta-braid)
 644 (!bootstrap-accessor-definitions t)
 645 (!bootstrap-class-predicates t)
 646 (!bootstrap-accessor-definitions nil)
 647 (!bootstrap-class-predicates nil)
 648 (!bootstrap-built-in-classes)
 649
 650 (dohash (name x *find-class*)
 651         (let* ((class (find-class-from-cell name x))
 652                (layout (class-wrapper class))
 653                (lclass (layout-classoid layout))
 654                (lclass-pcl-class (classoid-pcl-class lclass))
 655                (olclass (find-classoid name nil)))
 656           (if lclass-pcl-class
 657               (aver (eq class lclass-pcl-class))
 658               (setf (classoid-pcl-class lclass) class))
 659
 660           (update-lisp-class-layout class layout)
 661
 662           (cond (olclass
 663                  (aver (eq lclass olclass)))
 664                 (t
 665                  (setf (find-classoid name) lclass)))
 666
 667           (set-class-type-translation class name)))
 668
 669 (setq *boot-state* 'braid)
 670
 671 (defmethod no-applicable-method (generic-function &rest args)
 672   (error "~@<There is no matching method for the generic function ~2I~_~S~
 673           ~I~_when called with arguments ~2I~_~S.~:>"
 674          generic-function
 675          args))
 676
 677 (defmethod no-next-method ((generic-function standard-generic-function)
 678                            (method standard-method) &rest args)
 679   (error "~@<There is no next method for the generic function ~2I~_~S~
 680           ~I~_when called from method ~2I~_~S~I~_with arguments ~2I~_~S.~:>"
 681          generic-function
 682          method
 683          args))
 684
 685 ;;; An extension to the ANSI standard: in the presence of e.g. a
 686 ;;; :BEFORE method, it would seem that going through
 687 ;;; NO-APPLICABLE-METHOD is prohibited, as in fact there is an
 688 ;;; applicable method.  -- CSR, 2002-11-15
 689 (defmethod no-primary-method (generic-function &rest args)
 690   (error "~@<There is no primary method for the generic function ~2I~_~S~
 691           ~I~_when called with arguments ~2I~_~S.~:>"
 692          generic-function
 693          args))