src/pcl/cache.lisp

   1 ;;;; the basics of the PCL wrapper cache mechanism
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5
   6 ;;;; This software is derived from software originally released by Xerox
   7 ;;;; Corporation. Copyright and release statements follow. Later modifications
   8 ;;;; to the software are in the public domain and are provided with
   9 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
  10 ;;;; information.
  11
  12 ;;;; copyright information from original PCL sources:
  13 ;;;;
  14 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  15 ;;;; All rights reserved.
  16 ;;;;
  17 ;;;; Use and copying of this software and preparation of derivative works based
  18 ;;;; upon this software are permitted. Any distribution of this software or
  19 ;;;; derivative works must comply with all applicable United States export
  20 ;;;; control laws.
  21 ;;;;
  22 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  23 ;;;; warranty about the software, its performance or its conformity to any
  24 ;;;; specification.
  25
  26 ;;;; Note: as of SBCL 1.0.6.3 it is questionable if cache.lisp can
  27 ;;;; anymore be considered to be "derived from software originally
  28 ;;;; released by Xerox Corporation", as at that time the whole cache
  29 ;;;; implementation was essentially redone from scratch.
  30
  31 (in-package "SB-PCL")
  32
  33 ;;;; Public API:
  34 ;;;;
  35 ;;;;   fill-cache
  36 ;;;;   probe-cache
  37 ;;;;   make-cache
  38 ;;;;   map-cache
  39 ;;;;   emit-cache-lookup
  40 ;;;;   copy-cache
  41 ;;;;   hash-table-to-cache
  42 ;;;;
  43 ;;;; This is a thread and interrupt safe reimplementation loosely
  44 ;;;; based on the original PCL cache by Kickzales and Rodrigues,
  45 ;;;; as described in "Efficient Method Dispatch in PCL".
  46 ;;;;
  47 ;;;; * Writes to cache are made atomic using compare-and-swap on
  48 ;;;;   wrappers. Wrappers are never moved or deleted after they have
  49 ;;;;   been written: to clean them out the cache need to be copied.
  50 ;;;;
  51 ;;;; * Copying or expanding the cache drops out incomplete and invalid
  52 ;;;;   lines.
  53 ;;;;
  54 ;;;; * Since the cache is used for memoization only we don't need to
  55 ;;;;   worry about which of simultaneous replacements (when expanding
  56 ;;;;   the cache) takes place: the loosing one will have its work
  57 ;;;;   redone later. This also allows us to drop entries when the
  58 ;;;;   cache is about to grow insanely huge.
  59 ;;;;
  60 ;;;; The cache is essentially a specialized hash-table for layouts, used
  61 ;;;; for memoization of effective methods, slot locations, and constant
  62 ;;;; return values.
  63 ;;;;
  64 ;;;; Subsequences of the cache vector are called cache lines.
  65 ;;;;
  66 ;;;; The cache vector uses the symbol SB-PCL::..EMPTY.. as a sentinel
  67 ;;;; value, to allow storing NILs in the vector as well.
  68
  69 (defstruct (cache (:constructor %make-cache)
  70                   (:copier %copy-cache))
  71   ;; Number of keys the cache uses.
  72   (key-count 1 :type (integer 1 (#.call-arguments-limit)))
  73   ;; True if we store values in the cache.
  74   (value)
  75   ;; Number of vector elements a single cache line uses in the vector.
  76   ;; This is always a power of two, so that the vector length can be both
  77   ;; an exact multiple of this and a power of two.
  78   (line-size 1 :type (integer 1 #.most-positive-fixnum))
  79   ;; Cache vector, its length is always both a multiple of line-size
  80   ;; and a power of two. This is so that we can calculate
  81   ;;   (mod index (length vector))
  82   ;; using a bitmask.
  83   (vector #() :type simple-vector)
  84   ;; The bitmask used to calculate
  85   ;;   (mod (* line-size line-hash) (length vector))).
  86   (mask 0 :type fixnum)
  87   ;; Current probe-depth needed in the cache.
  88   (depth 0 :type index)
  89   ;; Maximum allowed probe-depth before the cache needs to expand.
  90   (limit 0 :type index))
  91
  92 (defun compute-cache-mask (vector-length line-size)
  93   ;; Since both vector-length and line-size are powers of two, we
  94   ;; can compute a bitmask such that
  95   ;;
  96   ;;  (logand <mask> <combined-layout-hash>)
  97   ;;
  98   ;; is "morally equal" to
  99   ;;
 100   ;;  (mod (* <line-size> <combined-layout-hash>) <vector-length>)
 101   ;;
 102   ;; This is it: (1- vector-length) is #b111... of the approriate size
 103   ;; to get the MOD, and (- line-size) gives right the number of zero
 104   ;; bits at the low end.
 105   (logand (1- vector-length) (- line-size)))
 106
 107 ;;; The smallest power of two that is equal to or greater then X.
 108 (declaim (inline power-of-two-ceiling))
 109 (defun power-of-two-ceiling (x)
 110   (ash 1 (integer-length (1- x))))
 111
 112 (defun cache-statistics (cache)
 113   (let* ((vector (cache-vector cache))
 114          (size (length vector))
 115          (line-size (cache-line-size cache))
 116          (total-lines (/ size line-size))
 117          (free-lines (loop for i from 0 by line-size below size
 118                            unless (eq (svref vector i) '..empty..)
 119                            count t)))
 120     (values (- total-lines free-lines) total-lines
 121             (cache-depth cache) (cache-limit cache))))
 122
 123 ;;; Don't allocate insanely huge caches: this is 4096 lines for a
 124 ;;; value cache with 8-15 keys -- probably "big enough for anyone",
 125 ;;; and 16384 lines for a commonplace 2-key value cache.
 126 (defconstant +cache-vector-max-length+ (expt 2 16))
 127
 128 ;;; Compute the maximum allowed probe depth as a function of cache size.
 129 ;;; Cache size refers to number of cache lines, not the length of the
 130 ;;; cache vector.
 131 ;;;
 132 ;;; FIXME: It would be nice to take the generic function optimization
 133 ;;; policy into account here (speed vs. space.)
 134 (declaim (inline compute-limit))
 135 (defun compute-limit (size)
 136   (ceiling (sqrt (sqrt size))))
 137
 138 ;;; Returns VALUE if it is not ..EMPTY.., otherwise executes ELSE:
 139 (defmacro non-empty-or (value else)
 140   (with-unique-names (n-value)
 141     `(let ((,n-value ,value))
 142        (if (eq ,n-value '..empty..)
 143            ,else
 144            ,n-value))))
 145
 146 ;;; Fast way to check if a thing found at the position of a cache key is one:
 147 ;;; it is always either a wrapper, or the ..EMPTY.. symbol.
 148 (declaim (inline cache-key-p))
 149 (defun cache-key-p (thing)
 150   (not (symbolp thing)))
 151
 152 (eval-when (:compile-toplevel :load-toplevel :execute)
 153   (sb-kernel:define-structure-slot-compare-and-swap compare-and-swap-cache-depth
 154       :structure cache
 155       :slot depth))
 156
 157 ;;; Utility macro for atomic updates without locking... doesn't
 158 ;;; do much right now, and it would be nice to make this more magical.
 159 (defmacro compare-and-swap (place old new)
 160   (unless (consp place)
 161     (error "Don't know how to compare and swap ~S." place))
 162   (ecase (car place)
 163     (svref
 164      `(simple-vector-compare-and-swap ,@(cdr place) ,old ,new))
 165     (cache-depth
 166      `(compare-and-swap-cache-depth ,@(cdr place) ,old ,new))))
 167
 168 ;;; Atomically update the current probe depth of a cache.
 169 (defun note-cache-depth (cache depth)
 170   (loop for old = (cache-depth cache)
 171         while (and (< old depth)
 172                    (not (eq old (compare-and-swap (cache-depth cache)
 173                                                   old depth))))))
 174
 175 ;;; Compute the starting index of the next cache line in the cache vector.
 176 (declaim (inline next-cache-index))
 177 (defun next-cache-index (mask index line-size)
 178   (logand mask (+ index line-size)))
 179
 180 ;;; Returns the hash-value for layout, or executes ELSE if the layout
 181 ;;; is invalid.
 182 (defmacro hash-layout-or (layout else)
 183   (with-unique-names (n-hash)
 184     `(let ((,n-hash (layout-clos-hash ,layout)))
 185        (if (zerop ,n-hash)
 186            ,else
 187            ,n-hash))))
 188
 189 ;;; Compute cache index for the cache and a list of layouts.
 190 (declaim (inline compute-cache-index))
 191 (defun compute-cache-index (cache layouts)
 192   (let ((index (hash-layout-or (car layouts)
 193                                (return-from compute-cache-index nil))))
 194     (declare (fixnum index))
 195     (dolist (layout (cdr layouts))
 196       (mixf index (hash-layout-or layout (return-from compute-cache-index nil))))
 197     ;; align with cache lines
 198     (logand index (cache-mask cache))))
 199
 200 ;;; Emit code that does lookup in cache bound to CACHE-VAR using
 201 ;;; layouts bound to LAYOUT-VARS. Go to MISS-TAG on event of a miss or
 202 ;;; invalid layout. Otherwise, if VALUE-VAR is non-nil, set it to the
 203 ;;; value found. (VALUE-VAR is non-nil only when CACHE-VALUE is true.)
 204 ;;;
 205 ;;; In other words, produces inlined code for COMPUTE-CACHE-INDEX when
 206 ;;; number of keys and presence of values in the cache is known
 207 ;;; beforehand.
 208 (defun emit-cache-lookup (cache-var layout-vars miss-tag value-var)
 209   (let ((line-size (power-of-two-ceiling (+ (length layout-vars)
 210                                             (if value-var 1 0)))))
 211     (with-unique-names (n-index n-vector n-depth n-pointer n-mask
 212                        MATCH-WRAPPERS EXIT-WITH-HIT)
 213       `(let* ((,n-index (hash-layout-or ,(car layout-vars) (go ,miss-tag)))
 214               (,n-vector (cache-vector ,cache-var))
 215               (,n-mask (cache-mask ,cache-var)))
 216          (declare (index ,n-index))
 217          ,@(mapcar (lambda (layout-var)
 218                      `(mixf ,n-index (hash-layout-or ,layout-var (go ,miss-tag))))
 219                    (cdr layout-vars))
 220          ;; align with cache lines
 221          (setf ,n-index (logand ,n-index ,n-mask))
 222          (let ((,n-depth (cache-depth ,cache-var))
 223                (,n-pointer ,n-index))
 224            (declare (index ,n-depth ,n-pointer))
 225            (tagbody
 226             ,MATCH-WRAPPERS
 227               (when (and ,@(mapcar
 228                             (lambda (layout-var)
 229                               `(prog1
 230                                    (eq ,layout-var (svref ,n-vector ,n-pointer))
 231                                  (incf ,n-pointer)))
 232                             layout-vars))
 233                 ,@(when value-var
 234                     `((setf ,value-var (non-empty-or (svref ,n-vector ,n-pointer)
 235                                                      (go ,miss-tag)))))
 236                 (go ,EXIT-WITH-HIT))
 237               (if (zerop ,n-depth)
 238                   (go ,miss-tag)
 239                   (decf ,n-depth))
 240               (setf ,n-index (next-cache-index ,n-mask ,n-index ,line-size)
 241                     ,n-pointer ,n-index)
 242               (go ,MATCH-WRAPPERS)
 243             ,EXIT-WITH-HIT))))))
 244
 245 ;;; Probes CACHE for LAYOUTS.
 246 ;;;
 247 ;;; Returns two values: a boolean indicating a hit or a miss, and a secondary
 248 ;;; value that is the value that was stored in the cache if any.
 249 (defun probe-cache (cache layouts)
 250   (unless (consp layouts)
 251     (setf layouts (list layouts)))
 252   (let ((vector (cache-vector cache))
 253         (key-count (cache-key-count cache))
 254         (line-size (cache-line-size cache))
 255         (mask (cache-mask cache)))
 256     (flet ((probe-line (base)
 257              (tagbody
 258                 (loop for offset from 0 below key-count
 259                       for layout in layouts do
 260                       (unless (eq layout (svref vector (+ base offset)))
 261                         ;; missed
 262                         (go :miss)))
 263                 ;; all layouts match!
 264                 (let ((value (when (cache-value cache)
 265                                (non-empty-or (svref vector (+ base key-count))
 266                                              (go :miss)))))
 267                   (return-from probe-cache (values t value)))
 268               :miss
 269                 (return-from probe-line (next-cache-index mask base line-size)))))
 270       (let ((index (compute-cache-index cache layouts)))
 271         (when index
 272           (loop repeat (1+ (cache-depth cache)) do
 273                 (setf index (probe-line index)))))))
 274   (values nil nil))
 275
 276 ;;; Tries to write LAYOUTS and VALUE at the cache line starting at
 277 ;;; the index BASE. Returns true on success, and false on failure.
 278 (defun try-update-cache-line (cache base layouts value)
 279   (declare (index base))
 280   (let ((vector (cache-vector cache))
 281         (new (pop layouts)))
 282     ;; If we unwind from here, we will be left with an incomplete
 283     ;; cache line, but that is OK: next write using the same layouts
 284     ;; will fill it, and reads will treat an incomplete line as a
 285     ;; miss -- causing it to be filled.
 286     (loop for old = (compare-and-swap (svref vector base) '..empty.. new)  do
 287           (when (and (cache-key-p old) (not (eq old new)))
 288             ;; The place was already taken, and doesn't match our key.
 289             (return-from try-update-cache-line nil))
 290           (unless layouts
 291             ;; All keys match or succesfully saved, save our value --
 292             ;; just smash it in. Until the first time it is written
 293             ;; there is ..EMPTY.. here, which probes look for, so we
 294             ;; don't get bogus hits. This is necessary because we want
 295             ;; to be able store arbitrary values here for use with
 296             ;; constant-value dispatch functions.
 297             (when (cache-value cache)
 298               (setf (svref vector (1+ base)) value))
 299             (return-from try-update-cache-line t))
 300           (setf new (pop layouts))
 301           (incf base))))
 302
 303 ;;; Tries to write LAYOUTS and VALUE somewhere in the cache. Returns
 304 ;;; true on success and false on failure, meaning the cache is too
 305 ;;; full.
 306 (defun try-update-cache (cache layouts value)
 307   (let ((vector (cache-vector cache))
 308         (index (or (compute-cache-index cache layouts)
 309                    ;; At least one of the layouts was invalid: just
 310                    ;; pretend we updated the cache, and let the next
 311                    ;; read pick up the mess.
 312                    (return-from try-update-cache t)))
 313         (line-size (cache-line-size cache))
 314         (mask (cache-mask cache)))
 315     (declare (index index))
 316     (loop for depth from 0 upto (cache-limit cache) do
 317           (when (try-update-cache-line cache index layouts value)
 318             (note-cache-depth cache depth)
 319             (return-from try-update-cache t))
 320           (setf index (next-cache-index mask index line-size)))))
 321
 322 ;;; Constructs a new cache.
 323 (defun make-cache (&key (key-count (missing-arg)) (value (missing-arg))
 324                    (size 1))
 325   (let* ((line-size (power-of-two-ceiling (+ key-count (if value 1 0))))
 326          (adjusted-size (power-of-two-ceiling size))
 327          (length (* adjusted-size line-size)))
 328     (if (<= length +cache-vector-max-length+)
 329         (%make-cache :key-count key-count
 330                      :line-size line-size
 331                      :vector (make-array length :initial-element '..empty..)
 332                      :value value
 333                      :mask (compute-cache-mask length line-size)
 334                      :limit (compute-limit adjusted-size))
 335         ;; Make a smaller one, then
 336         (make-cache :key-count key-count :value value :size (ceiling size 2)))))
 337
 338 ;;;; Copies and expands the cache, dropping any invalidated or
 339 ;;;; incomplete lines.
 340 (defun copy-and-expand-cache (cache)
 341   (let ((copy (%copy-cache cache))
 342         (length (length (cache-vector cache))))
 343     (when (< length +cache-vector-max-length+)
 344       (setf length (* 2 length)))
 345     (tagbody
 346      :again
 347        ;; Blow way the old vector first, so a GC potentially triggered by
 348        ;; MAKE-ARRAY can collect it.
 349        (setf (cache-vector copy) #()
 350              (cache-vector copy) (make-array length :initial-element '..empty..)
 351              (cache-depth copy) 0
 352              (cache-mask copy) (compute-cache-mask length (cache-line-size cache))
 353              (cache-limit copy) (compute-limit (/ length (cache-line-size cache))))
 354        (map-cache (lambda (layouts value)
 355                     (unless (try-update-cache copy layouts value)
 356                       ;; If the cache would grow too much we drop the
 357                       ;; remaining the entries that don't fit. FIXME:
 358                       ;; It would be better to drop random entries to
 359                       ;; avoid getting into a rut here (best done by
 360                       ;; making MAP-CACHE map in a random order?), and
 361                       ;; possibly to downsize the cache more
 362                       ;; aggressively (on the assumption that most
 363                       ;; entries aren't getting used at the moment.)
 364                       (when (< length +cache-vector-max-length+)
 365                         (setf length (* 2 length))
 366                         (go :again))))
 367                   cache))
 368     copy))
 369
 370 (defun cache-has-invalid-entries-p (cache)
 371   (let ((vector (cache-vector cache))
 372         (line-size (cache-line-size cache))
 373         (key-count (cache-key-count cache))
 374         (mask (cache-mask cache))
 375         (index 0))
 376     (loop
 377       ;; Check if the line is in use, and check validity of the keys.
 378       (let ((key1 (svref vector index)))
 379         (when (cache-key-p key1)
 380           (if (zerop (layout-clos-hash key1))
 381               ;; First key invalid.
 382               (return-from cache-has-invalid-entries-p t)
 383               ;; Line is in use and the first key is valid: check the rest.
 384               (loop for offset from 1 below key-count
 385                     do (let ((thing (svref vector (+ index offset))))
 386                          (when (or (not (cache-key-p thing))
 387                                    (zerop (layout-clos-hash thing)))
 388                            ;; Incomplete line or invalid layout.
 389                            (return-from cache-has-invalid-entries-p t)))))))
 390       ;; Line empty of valid, onwards.
 391       (setf index (next-cache-index mask index line-size))
 392       (when (zerop index)
 393         ;; wrapped around
 394         (return-from cache-has-invalid-entries-p nil)))))
 395
 396 (defun hash-table-to-cache (table &key value key-count)
 397   (let ((cache (make-cache :key-count key-count :value value
 398                            :size (hash-table-count table))))
 399     (maphash (lambda (class value)
 400                (setq cache (fill-cache cache (class-wrapper class) value)))
 401              table)
 402     cache))
 403
 404 ;;; Inserts VALUE to CACHE keyd by LAYOUTS. Expands the cache if
 405 ;;; necessary, and returns the new cache.
 406 (defun fill-cache (cache layouts value)
 407   (labels
 408       ((%fill-cache (cache layouts value)
 409          (cond ((try-update-cache cache layouts value)
 410                 cache)
 411                ((cache-has-invalid-entries-p cache)
 412                 ;; Don't expand yet: maybe there will be enough space if
 413                 ;; we just drop the invalid entries.
 414                 (%fill-cache (copy-cache cache) layouts value))
 415                (t
 416                 (%fill-cache (copy-and-expand-cache cache) layouts value)))))
 417     (if (listp layouts)
 418         (%fill-cache cache layouts value)
 419         (%fill-cache cache (list layouts) value))))
 420
 421 ;;; Calls FUNCTION with all layouts and values in cache.
 422 (defun map-cache (function cache)
 423   (let* ((vector (cache-vector cache))
 424          (key-count (cache-key-count cache))
 425          (valuep (cache-value cache))
 426          (line-size (cache-line-size cache))
 427          (mask (cache-mask cache))
 428          (fun (if (functionp function)
 429                   function
 430                   (fdefinition function)))
 431          (index 0)
 432          (key nil))
 433     (tagbody
 434      :map
 435        (let ((layouts
 436               (loop for offset from 0 below key-count
 437                     collect (non-empty-or (svref vector (+ offset index))
 438                                           (go :next)))))
 439          (let ((value (when valuep
 440                         (non-empty-or (svref vector (+ index key-count))
 441                                       (go :next)))))
 442            ;; Let the callee worry about invalid layouts
 443            (funcall fun layouts value)))
 444      :next
 445        (setf index (next-cache-index mask index line-size))
 446        (unless (zerop index)
 447          (go :map))))
 448   cache)
 449
 450 ;;; Copying a cache without expanding it is very much like mapping it:
 451 ;;; we need to be carefull because there may be updates while we are
 452 ;;; copying it, and we don't want to copy incomplete entries or invalid
 453 ;;; ones.
 454 (defun copy-cache (cache)
 455   (let* ((vector (cache-vector cache))
 456          (copy (make-array (length vector) :initial-element '..empty..))
 457          (line-size (cache-line-size cache))
 458          (key-count (cache-key-count cache))
 459          (valuep (cache-value cache))
 460          (mask (cache-mask cache))
 461          (size (/ (length vector) line-size))
 462          (index 0)
 463          (elt nil)
 464          (depth 0))
 465     (tagbody
 466      :copy
 467        (let ((layouts (loop for offset from 0 below key-count
 468                             collect (non-empty-or (svref vector (+ index offset))
 469                                                   (go :next)))))
 470          ;; Check validity & compute primary index.
 471          (let ((primary (or (compute-cache-index cache layouts)
 472                             (go :next))))
 473            ;; Check & copy value.
 474            (when valuep
 475              (setf (svref copy (+ index key-count))
 476                    (non-empty-or (svref vector (+ index key-count))
 477                                  (go :next))))
 478            ;; Copy layouts.
 479            (loop for offset from 0 below key-count do
 480                  (setf (svref copy (+ index offset)) (pop layouts)))
 481            ;; Update probe depth.
 482            (let ((distance (/ (- index primary) line-size)))
 483              (setf depth (max depth (if (minusp distance)
 484                                         ;; account for wrap-around
 485                                         (+ distance size)
 486                                         distance))))))
 487      :next
 488        (setf index (next-cache-index mask index line-size))
 489        (unless (zerop index)
 490          (go :copy)))
 491     (%make-cache :vector copy
 492                  :depth depth
 493                  :key-count (cache-key-count cache)
 494                  :line-size line-size
 495                  :value valuep
 496                  :mask mask
 497                  :limit (cache-limit cache))))
 498
 499 ;;;; For debugging & collecting statistics.
 500
 501 (defun map-all-caches (function)
 502   (dolist (p (list-all-packages))
 503     (do-symbols (s p)
 504       (when (eq p (symbol-package s))
 505         (dolist (name (list s
 506                             `(setf ,s)
 507                             (slot-reader-name s)
 508                             (slot-writer-name s)
 509                             (slot-boundp-name s)))
 510           (when (fboundp name)
 511             (let ((fun (fdefinition name)))
 512               (when (typep fun 'generic-function)
 513                 (let ((cache (gf-dfun-cache fun)))
 514                   (when cache
 515                     (funcall function name cache)))))))))))
 516
 517 (defun check-cache-consistency (cache)
 518   (let ((table (make-hash-table :test 'equal)))
 519     (map-cache (lambda (layouts value)
 520                  (declare (ignore value))
 521                  (if (gethash layouts table)
 522                      (cerror "Check futher."
 523                              "Multiple appearances of ~S." layouts)
 524                      (setf (gethash layouts table) t)))
 525                cache)))