src/pcl/combin.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 (defun get-method-function (method &optional method-alist wrappers)
  27   (let ((fn (cadr (assoc method method-alist))))
  28     (if fn
  29         (values fn nil nil nil)
  30         (multiple-value-bind (mf fmf)
  31             (if (listp method)
  32                 (early-method-function method)
  33                 (values nil (safe-method-fast-function method)))
  34           (let* ((pv-table (and fmf (method-plist-value method :pv-table))))
  35             (if (and fmf (or (null pv-table) wrappers))
  36                 (let* ((pv-wrappers (when pv-table
  37                                       (pv-wrappers-from-all-wrappers
  38                                        pv-table wrappers)))
  39                        (pv (when (and pv-table pv-wrappers)
  40                              (pv-table-lookup pv-table pv-wrappers))))
  41                   (values mf t fmf pv))
  42                 (values
  43                  (or mf (if (listp method)
  44                             (bug "early method with no method-function")
  45                             (method-function method)))
  46                  t nil nil)))))))
  47
  48 (defun make-effective-method-function (generic-function form &optional
  49                                        method-alist wrappers)
  50   (funcall (make-effective-method-function1 generic-function form
  51                                             (not (null method-alist))
  52                                             (not (null wrappers)))
  53            method-alist wrappers))
  54
  55 (defun make-effective-method-function1 (generic-function form
  56                                         method-alist-p wrappers-p)
  57   (if (and (listp form)
  58            (eq (car form) 'call-method))
  59       (make-effective-method-function-simple generic-function form)
  60       ;; We have some sort of `real' effective method. Go off and get a
  61       ;; compiled function for it. Most of the real hair here is done by
  62       ;; the GET-FUN mechanism.
  63       (make-effective-method-function-internal generic-function form
  64                                                method-alist-p wrappers-p)))
  65
  66 (defun make-effective-method-fun-type (generic-function
  67                                        form
  68                                        method-alist-p
  69                                        wrappers-p)
  70   (if (and (listp form)
  71            (eq (car form) 'call-method))
  72       (let* ((cm-args (cdr form))
  73              (method (car cm-args)))
  74         (when method
  75           (if (if (listp method)
  76                   (eq (car method) :early-method)
  77                   (method-p method))
  78               (if method-alist-p
  79                   t
  80                   (multiple-value-bind (mf fmf)
  81                       (if (listp method)
  82                           (early-method-function method)
  83                           (values nil (safe-method-fast-function method)))
  84                     (declare (ignore mf))
  85                     (let* ((pv-table (and fmf (method-plist-value method :pv-table))))
  86                       (if (and fmf (or (null pv-table) wrappers-p))
  87                           'fast-method-call
  88                           'method-call))))
  89               (if (and (consp method) (eq (car method) 'make-method))
  90                   (make-effective-method-fun-type
  91                    generic-function (cadr method) method-alist-p wrappers-p)
  92                   (type-of method)))))
  93       'fast-method-call))
  94
  95 (defun make-effective-method-function-simple
  96     (generic-function form &optional no-fmf-p)
  97   ;; The effective method is just a call to CALL-METHOD. This opens up
  98   ;; the possibility of just using the method function of the method as
  99   ;; the effective method function.
 100   ;;
 101   ;; But we have to be careful. If that method function will ask for
 102   ;; the next methods we have to provide them. We do not look to see
 103   ;; if there are next methods, we look at whether the method function
 104   ;; asks about them. If it does, we must tell it whether there are
 105   ;; or aren't to prevent the leaky next methods bug.
 106   (let* ((cm-args (cdr form))
 107          (fmf-p (and (null no-fmf-p)
 108                      (or (not (eq **boot-state** 'complete))
 109                          (gf-fast-method-function-p generic-function))
 110                      (null (cddr cm-args))))
 111          (method (car cm-args))
 112          (cm-args1 (cdr cm-args)))
 113     (lambda (method-alist wrappers)
 114       (make-effective-method-function-simple1 generic-function
 115                                               method
 116                                               cm-args1
 117                                               fmf-p
 118                                               method-alist
 119                                               wrappers))))
 120
 121 (defun make-emf-from-method
 122     (method cm-args &optional gf fmf-p method-alist wrappers)
 123   (multiple-value-bind (mf real-mf-p fmf pv)
 124       (get-method-function method method-alist wrappers)
 125     (if fmf
 126         (let* ((next-methods (car cm-args))
 127                (next (make-effective-method-function-simple1
 128                       gf (car next-methods)
 129                       (list* (cdr next-methods) (cdr cm-args))
 130                       fmf-p method-alist wrappers))
 131                (arg-info (method-plist-value method :arg-info))
 132                (default (cons nil nil))
 133                (value (method-plist-value method :constant-value default)))
 134           (if (eq value default)
 135               (make-fast-method-call :function fmf :pv pv
 136                                      :next-method-call next :arg-info arg-info)
 137               (make-constant-fast-method-call
 138                :function fmf :pv pv :next-method-call next
 139                :arg-info arg-info :value value)))
 140         (if real-mf-p
 141             (flet ((frob-cm-arg (arg)
 142                      (if (if (listp arg)
 143                              (eq (car arg) :early-method)
 144                              (method-p arg))
 145                          arg
 146                          (if (and (consp arg) (eq (car arg) 'make-method))
 147                              (let ((emf (make-effective-method-function
 148                                          gf (cadr arg) method-alist wrappers)))
 149                                (etypecase emf
 150                                  (method-call
 151                                   (make-instance 'standard-method
 152                                                  :specializers nil ; XXX
 153                                                  :qualifiers nil ; XXX
 154                                                  :function (method-call-function emf)))
 155                                  (fast-method-call
 156                                   (let* ((fmf (fast-method-call-function emf))
 157                                          (fun (method-function-from-fast-method-call emf))
 158                                          (mf (%make-method-function fmf nil)))
 159                                     (set-funcallable-instance-function mf fun)
 160                                     (make-instance 'standard-method
 161                                                    :specializers nil ; XXX
 162                                                    :qualifiers nil
 163                                                    :function mf)))))
 164                              arg))))
 165               (let* ((default (cons nil nil))
 166                      (value
 167                       (method-plist-value method :constant-value default))
 168                      ;; FIXME: this is wrong.  Very wrong.  It assumes
 169                      ;; that the only place that can have make-method
 170                      ;; calls is in the list structure of the second
 171                      ;; argument to CALL-METHOD, but AMOP says that
 172                      ;; CALL-METHOD can be more complicated if
 173                      ;; COMPUTE-EFFECTIVE-METHOD (and presumably
 174                      ;; MAKE-METHOD-LAMBDA) is adjusted to match.
 175                      ;;
 176                      ;; On the other hand, it's a start, because
 177                      ;; without this calls to MAKE-METHOD in method
 178                      ;; combination where one of the methods is of a
 179                      ;; user-defined class don't work at all.  -- CSR,
 180                      ;; 2006-08-05
 181                      (args (cons (mapcar #'frob-cm-arg (car cm-args))
 182                                  (cdr cm-args))))
 183                 (if (eq value default)
 184                     (make-method-call :function mf :call-method-args args)
 185                     (make-constant-method-call :function mf :value value
 186                                                :call-method-args args))))
 187             mf))))
 188
 189 (defun make-effective-method-function-simple1
 190     (gf method cm-args fmf-p &optional method-alist wrappers)
 191   (when method
 192     (if (if (listp method)
 193             (eq (car method) :early-method)
 194             (method-p method))
 195         (make-emf-from-method method cm-args gf fmf-p method-alist wrappers)
 196         (if (and (consp method) (eq (car method) 'make-method))
 197             (make-effective-method-function gf
 198                                             (cadr method)
 199                                             method-alist wrappers)
 200             method))))
 201
 202 (defvar *global-effective-method-gensyms* ())
 203 (defvar *rebound-effective-method-gensyms*)
 204
 205 (defun get-effective-method-gensym ()
 206   (or (pop *rebound-effective-method-gensyms*)
 207       (let ((new (format-symbol *pcl-package*
 208                                 "EFFECTIVE-METHOD-GENSYM-~D"
 209                                 (length *global-effective-method-gensyms*))))
 210         (setq *global-effective-method-gensyms*
 211               (append *global-effective-method-gensyms* (list new)))
 212         new)))
 213
 214 (let ((*rebound-effective-method-gensyms* ()))
 215   (dotimes-fixnum (i 10) (get-effective-method-gensym)))
 216
 217 (defun expand-effective-method-function (gf effective-method &optional env)
 218   (declare (ignore env))
 219   (multiple-value-bind (nreq applyp)
 220       (get-generic-fun-info gf)
 221     (let ((ll (make-fast-method-call-lambda-list nreq applyp))
 222           (check-applicable-keywords
 223            (when (and applyp (gf-requires-emf-keyword-checks gf))
 224              '((check-applicable-keywords))))
 225           (error-p (or (eq (first effective-method) '%no-primary-method)
 226                        (eq (first effective-method) '%invalid-qualifiers)))
 227           (mc-args-p
 228            (when (eq **boot-state** 'complete)
 229              ;; Otherwise the METHOD-COMBINATION slot is not bound.
 230              (let ((combin (generic-function-method-combination gf)))
 231                (and (long-method-combination-p combin)
 232                     (long-method-combination-args-lambda-list combin))))))
 233       (cond
 234         (error-p
 235          `(lambda (.pv. .next-method-call. &rest .args.)
 236            (declare (ignore .pv. .next-method-call.))
 237            (declare (ignorable .args.))
 238            (flet ((%no-primary-method (gf args)
 239                     (call-no-primary-method gf args))
 240                   (%invalid-qualifiers (gf combin method)
 241                     (invalid-qualifiers gf combin method)))
 242              (declare (ignorable #'%no-primary-method #'%invalid-qualifiers))
 243              ,effective-method)))
 244         (mc-args-p
 245          (let* ((required (make-dfun-required-args nreq))
 246                 (gf-args (if applyp
 247                              `(list* ,@required
 248                                      (sb-c::%listify-rest-args
 249                                       .dfun-more-context.
 250                                       (the (and unsigned-byte fixnum)
 251                                         .dfun-more-count.)))
 252                              `(list ,@required))))
 253            `(lambda ,ll
 254              (declare (ignore .pv. .next-method-call.))
 255              (let ((.gf-args. ,gf-args))
 256                (declare (ignorable .gf-args.))
 257                ,@check-applicable-keywords
 258                ,effective-method))))
 259         (t
 260          `(lambda ,ll
 261            (declare (ignore ,@(if error-p ll '(.pv. .next-method-call.))))
 262            ,@check-applicable-keywords
 263            ,effective-method))))))
 264
 265 (defun expand-emf-call-method (gf form metatypes applyp env)
 266   (declare (ignore gf metatypes applyp env))
 267   `(call-method ,(cdr form)))
 268
 269 (defmacro call-method (&rest args)
 270   (declare (ignore args))
 271   ;; the PROGN is here to defend against premature macroexpansion by
 272   ;; RESTART-CASE.
 273   `(progn (error "~S outside of a effective method form" 'call-method)))
 274
 275 (defun make-effective-method-list-fun-type
 276     (generic-function form method-alist-p wrappers-p)
 277   (if (every (lambda (form)
 278                (eq 'fast-method-call
 279                    (make-effective-method-fun-type
 280                     generic-function form method-alist-p wrappers-p)))
 281              (cdr form))
 282       'fast-method-call
 283       t))
 284
 285 (defun memf-test-converter (form generic-function method-alist-p wrappers-p)
 286   (case (and (consp form) (car form))
 287     (call-method
 288      (case (make-effective-method-fun-type
 289             generic-function form method-alist-p wrappers-p)
 290        (fast-method-call '.fast-call-method.)
 291        (t '.call-method.)))
 292     (call-method-list
 293      (case (make-effective-method-list-fun-type
 294             generic-function form method-alist-p wrappers-p)
 295        (fast-method-call '.fast-call-method-list.)
 296        (t '.call-method-list.)))
 297     (check-applicable-keywords 'check-applicable-keywords)
 298     (t (default-test-converter form))))
 299
 300 ;;; CMUCL comment (2003-10-15):
 301 ;;;
 302 ;;;   This function is called via the GET-FUNCTION mechanism on forms
 303 ;;;   of an emf lambda.  First value returned replaces FORM in the emf
 304 ;;;   lambda.  Second value is a list of variable names that become
 305 ;;;   closure variables.
 306 (defun memf-code-converter
 307     (form generic-function metatypes applyp method-alist-p wrappers-p)
 308   (case (and (consp form) (car form))
 309     (call-method
 310      (let ((gensym (get-effective-method-gensym)))
 311        (values (make-emf-call
 312                 (length metatypes) applyp gensym
 313                 (make-effective-method-fun-type
 314                  generic-function form method-alist-p wrappers-p))
 315                (list gensym))))
 316     (call-method-list
 317      (let ((gensym (get-effective-method-gensym))
 318            (type (make-effective-method-list-fun-type
 319                   generic-function form method-alist-p wrappers-p)))
 320        (values `(dolist (emf ,gensym nil)
 321                  ,(make-emf-call (length metatypes) applyp 'emf type))
 322                (list gensym))))
 323     (check-applicable-keywords
 324      (values `(check-applicable-keywords .keyargs-start.
 325                                          .valid-keys.
 326                                          .dfun-more-context.
 327                                          .dfun-more-count.)
 328              '(.keyargs-start. .valid-keys.)))
 329     (t
 330      (default-code-converter form))))
 331
 332 (defun memf-constant-converter (form generic-function)
 333   (case (and (consp form) (car form))
 334     (call-method
 335      (list (cons '.meth.
 336                  (make-effective-method-function-simple
 337                   generic-function form))))
 338     (call-method-list
 339      (list (cons '.meth-list.
 340                  (mapcar (lambda (form)
 341                            (make-effective-method-function-simple
 342                             generic-function form))
 343                          (cdr form)))))
 344     (check-applicable-keywords
 345      '(.keyargs-start. .valid-keys.))
 346     (t
 347      (default-constant-converter form))))
 348
 349 (defvar *applicable-methods*)
 350 (defun make-effective-method-function-internal
 351     (generic-function effective-method method-alist-p wrappers-p)
 352   (multiple-value-bind (nreq applyp metatypes nkeys arg-info)
 353       (get-generic-fun-info generic-function)
 354     (declare (ignore nkeys arg-info))
 355     (let* ((*rebound-effective-method-gensyms*
 356             *global-effective-method-gensyms*)
 357            (name (if (early-gf-p generic-function)
 358                      (!early-gf-name generic-function)
 359                      (generic-function-name generic-function)))
 360            (arg-info (cons nreq applyp))
 361            (effective-method-lambda (expand-effective-method-function
 362                                      generic-function effective-method)))
 363       (multiple-value-bind (cfunction constants)
 364           (get-fun1 effective-method-lambda
 365                     (lambda (form)
 366                       (memf-test-converter form generic-function
 367                                            method-alist-p wrappers-p))
 368                     (lambda (form)
 369                       (memf-code-converter form generic-function
 370                                            metatypes applyp
 371                                            method-alist-p wrappers-p))
 372                     (lambda (form)
 373                       (memf-constant-converter form generic-function)))
 374         (lambda (method-alist wrappers)
 375           (multiple-value-bind (valid-keys keyargs-start)
 376               (when (memq '.valid-keys. constants)
 377                 (compute-applicable-keywords
 378                  generic-function *applicable-methods*))
 379             (flet ((compute-constant (constant)
 380                      (if (consp constant)
 381                          (case (car constant)
 382                            (.meth.
 383                             (funcall (cdr constant) method-alist wrappers))
 384                            (.meth-list.
 385                             (mapcar (lambda (fn)
 386                                       (funcall fn method-alist wrappers))
 387                                     (cdr constant)))
 388                            (t constant))
 389                          (case constant
 390                            (.keyargs-start. keyargs-start)
 391                            (.valid-keys. valid-keys)
 392                            (t constant)))))
 393               (let ((fun (apply cfunction
 394                                 (mapcar #'compute-constant constants))))
 395                 (set-fun-name fun `(combined-method ,name))
 396                 (make-fast-method-call :function fun
 397                                        :arg-info arg-info)))))))))
 398
 399 (defmacro call-method-list (&rest calls)
 400   `(progn ,@calls))
 401
 402 (defun make-call-methods (methods)
 403   `(call-method-list
 404     ,@(mapcar (lambda (method) `(call-method ,method ())) methods)))
 405
 406 (defun gf-requires-emf-keyword-checks (generic-function)
 407   (member '&key (gf-lambda-list generic-function)))
 408
 409 (defun standard-compute-effective-method
 410     (generic-function combin applicable-methods)
 411   (collect ((before) (primary) (after) (around))
 412     (flet ((invalid (gf combin m) (invalid-qualifiers gf combin m)))
 413       (dolist (m applicable-methods)
 414         (let ((qualifiers (if (listp m)
 415                               (early-method-qualifiers m)
 416                               (safe-method-qualifiers m))))
 417           (cond
 418             ((null qualifiers) (primary m))
 419             ((cdr qualifiers) (invalid generic-function combin m))
 420             ((eq (car qualifiers) :around) (around m))
 421             ((eq (car qualifiers) :before) (before m))
 422             ((eq (car qualifiers) :after) (after m))
 423             (t (invalid generic-function combin m))))))
 424     (cond ((null (primary))
 425            `(%no-primary-method ',generic-function .args.))
 426           ((and (null (before)) (null (after)) (null (around)))
 427            ;; By returning a single call-method `form' here we enable
 428            ;; an important implementation-specific optimization; that
 429            ;; is, we can use the fast method function directly as the
 430            ;; effective method function.
 431            ;;
 432            ;; However, the requirement by ANSI (CLHS 7.6.5) on generic
 433            ;; function argument checking inhibits this, as we don't
 434            ;; perform this checking in fast-method-functions given
 435            ;; that they are not solely used for effective method
 436            ;; functions, but also in combination, when they should not
 437            ;; perform argument checks.
 438            (let ((call-method
 439                   `(call-method ,(first (primary)) ,(rest (primary)))))
 440              (if (gf-requires-emf-keyword-checks generic-function)
 441                  ;; the PROGN inhibits the above optimization
 442                  `(progn ,call-method)
 443                  call-method)))
 444           (t
 445            (let ((main-effective-method
 446                    (if (or (before) (after))
 447                        `(multiple-value-prog1
 448                           (progn
 449                             ,(make-call-methods (before))
 450                             (call-method ,(first (primary))
 451                                          ,(rest (primary))))
 452                           ,(make-call-methods (reverse (after))))
 453                        `(call-method ,(first (primary)) ,(rest (primary))))))
 454              (if (around)
 455                  `(call-method ,(first (around))
 456                                (,@(rest (around))
 457                                   (make-method ,main-effective-method)))
 458                  main-effective-method))))))
 459 \f
 460 ;;; helper code for checking keywords in generic function calls.
 461 (defun compute-applicable-keywords (gf methods)
 462   (let ((any-keyp nil))
 463     (flet ((analyze (lambda-list)
 464              (multiple-value-bind (nreq nopt keyp restp allowp keys)
 465                  (analyze-lambda-list lambda-list)
 466                (declare (ignore nreq restp))
 467                (when keyp
 468                  (setq any-keyp t))
 469                (values nopt allowp keys))))
 470       (multiple-value-bind (nopt allowp keys)
 471           (analyze (generic-function-lambda-list gf))
 472         (dolist (method methods)
 473           (let ((ll (if (consp method)
 474                         (early-method-lambda-list method)
 475                         (method-lambda-list method))))
 476             (multiple-value-bind (n allowp method-keys)
 477                 (analyze ll)
 478               (declare (ignore n))
 479               (when allowp
 480                 (return-from compute-applicable-keywords (values t nopt)))
 481               (setq keys (union method-keys keys)))))
 482         (aver any-keyp)
 483         (values (if allowp t keys) nopt)))))
 484
 485 (defun check-applicable-keywords (start valid-keys more-context more-count)
 486   (let ((allow-other-keys-seen nil)
 487         (allow-other-keys nil)
 488         (i start))
 489     (declare (type index i more-count)
 490              (optimize speed))
 491     (flet ((current-value ()
 492              (sb-c::%more-arg more-context i)))
 493       (declare (inline current-value))
 494       (collect ((invalid))
 495         (loop
 496            (when (>= i more-count)
 497              (when (and (invalid) (not allow-other-keys))
 498                (error 'simple-program-error
 499                       :format-control "~@<invalid keyword argument~P: ~
 500                                    ~{~S~^, ~} (valid keys are ~{~S~^, ~}).~@:>"
 501                       :format-arguments (list (length (invalid)) (invalid) valid-keys)))
 502              (return))
 503            (let ((key (current-value)))
 504              (incf i)
 505              (cond
 506                ((not (symbolp key))
 507                 (error 'simple-program-error
 508                        :format-control "~@<keyword argument not a symbol: ~S.~@:>"
 509                        :format-arguments (list key)))
 510                ((= i more-count)
 511                 (sb-c::%odd-key-args-error))
 512                ((eq key :allow-other-keys)
 513                 ;; only the leftmost :ALLOW-OTHER-KEYS has any effect
 514                 (unless allow-other-keys-seen
 515                   (setq allow-other-keys-seen t
 516                         allow-other-keys (current-value))))
 517                ((eq t valid-keys))
 518                ((not (memq key valid-keys)) (invalid key))))
 519            (incf i))))))
 520 \f
 521 ;;;; the STANDARD method combination type. This is coded by hand
 522 ;;;; (rather than with DEFINE-METHOD-COMBINATION) for bootstrapping
 523 ;;;; and efficiency reasons. Note that the definition of the
 524 ;;;; FIND-METHOD-COMBINATION-METHOD appears in the file
 525 ;;;; defcombin.lisp. This is because EQL methods can't appear in the
 526 ;;;; bootstrap.
 527 ;;;;
 528 ;;;; The DEFCLASS for the METHOD-COMBINATION and
 529 ;;;; STANDARD-METHOD-COMBINATION classes has to appear here for this
 530 ;;;; reason. This code must conform to the code in the file
 531 ;;;; defcombin.lisp, look there for more details.
 532
 533 (defun compute-effective-method (generic-function combin applicable-methods)
 534   (standard-compute-effective-method generic-function
 535                                      combin
 536                                      applicable-methods))
 537
 538 (defun invalid-method-error (method format-control &rest format-arguments)
 539   (let ((sb-debug:*stack-top-hint* (nth-value 1 (find-caller-name-and-frame))))
 540     (error "~@<invalid method error for ~2I~_~S ~I~_method: ~2I~_~?~:>"
 541            method
 542            format-control
 543            format-arguments)))
 544
 545 (defun method-combination-error (format-control &rest format-arguments)
 546   (let ((sb-debug:*stack-top-hint* (nth-value 1 (find-caller-name-and-frame))))
 547     (error "~@<method combination error in CLOS dispatch: ~2I~_~?~:>"
 548            format-control
 549            format-arguments)))