src/pcl/cpl.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 ;;;; COMPUTE-CLASS-PRECEDENCE-LIST and friends
  27
  28 ;;; Knuth section 2.2.3 has some interesting notes on this.
  29 ;;;
  30 ;;; What appears here is basically the algorithm presented there.
  31 ;;;
  32 ;;; The key idea is that we use class-precedence-description (CPD) structures
  33 ;;; to store the precedence information as we proceed. The CPD structure for
  34 ;;; a class stores two critical pieces of information:
  35 ;;;
  36 ;;;  - a count of the number of "reasons" why the class can't go
  37 ;;;    into the class precedence list yet.
  38 ;;;
  39 ;;;  - a list of the "reasons" this class prevents others from
  40 ;;;    going in until after it
  41 ;;
  42 ;;; A "reason" is essentially a single local precedence constraint. If a
  43 ;;; constraint between two classes arises more than once it generates more
  44 ;;; than one reason. This makes things simpler, linear, and isn't a problem
  45 ;;; as long as we make sure to keep track of each instance of a "reason".
  46 ;;;
  47 ;;; This code is divided into three phases.
  48 ;;;
  49 ;;;  - the first phase simply generates the CPD's for each of the class
  50 ;;;    and its superclasses. The remainder of the code will manipulate
  51 ;;;    these CPDs rather than the class objects themselves. At the end
  52 ;;;    of this pass, the CPD-SUPERS field of a CPD is a list of the CPDs
  53 ;;;    of the direct superclasses of the class.
  54 ;;;
  55 ;;;  - the second phase folds all the local constraints into the CPD
  56 ;;;    structure. The CPD-COUNT of each CPD is built up, and the
  57 ;;;    CPD-AFTER fields are augmented to include precedence constraints
  58 ;;;    from the CPD-SUPERS field and from the order of classes in other
  59 ;;;    CPD-SUPERS fields.
  60 ;;;
  61 ;;;    After this phase, the CPD-AFTER field of a class includes all the
  62 ;;;    direct superclasses of the class plus any class that immediately
  63 ;;;    follows the class in the direct superclasses of another. There
  64 ;;;    can be duplicates in this list. The CPD-COUNT field is equal to
  65 ;;;    the number of times this class appears in the CPD-AFTER field of
  66 ;;;    all the other CPDs.
  67 ;;;
  68 ;;;  - In the third phase, classes are put into the precedence list one
  69 ;;;    at a time, with only those classes with a CPD-COUNT of 0 being
  70 ;;;    candidates for insertion. When a class is inserted , every CPD
  71 ;;;    in its CPD-AFTER field has its count decremented.
  72 ;;;
  73 ;;;    In the usual case, there is only one candidate for insertion at
  74 ;;;    any point. If there is more than one, the specified tiebreaker
  75 ;;;    rule is used to choose among them.
  76
  77 (defmethod compute-class-precedence-list ((root slot-class))
  78   (compute-std-cpl root (class-direct-superclasses root)))
  79
  80 (defstruct (class-precedence-description
  81             (:conc-name nil)
  82             (:print-object (lambda (obj str)
  83                              (print-unreadable-object (obj str :type t)
  84                                (format str "~D" (cpd-count obj)))))
  85             (:constructor make-cpd ())
  86             (:copier nil))
  87   (cpd-class  nil)
  88   (cpd-supers ())
  89   (cpd-after  ())
  90   (cpd-count  0))
  91
  92 (defun compute-std-cpl (class supers)
  93   (cond ((null supers)                          ;First two branches of COND
  94          (list class))                          ;are implementing the single
  95         ((null (cdr supers))                    ;inheritance optimization.
  96          (cons class
  97                (compute-std-cpl (car supers)
  98                                 (class-direct-superclasses (car supers)))))
  99         (t
 100          (multiple-value-bind (all-cpds nclasses)
 101              (compute-std-cpl-phase-1 class supers)
 102            (compute-std-cpl-phase-2 all-cpds)
 103            (compute-std-cpl-phase-3 class all-cpds nclasses)))))
 104
 105 (defvar *compute-std-cpl-class->entry-table-size* 60)
 106
 107 (defun compute-std-cpl-phase-1 (class supers)
 108   (let ((nclasses 0)
 109         (all-cpds ())
 110         (table (make-hash-table :size *compute-std-cpl-class->entry-table-size*
 111                                 :test #'eq)))
 112     (declare (fixnum nclasses))
 113     (labels ((get-cpd (c)
 114                (or (gethash c table)
 115                    (setf (gethash c table) (make-cpd))))
 116              (walk (c supers)
 117                (if (forward-referenced-class-p c)
 118                    (cpl-forward-referenced-class-error class c)
 119                    (let ((cpd (get-cpd c)))
 120                      (unless (cpd-class cpd)    ;If we have already done this
 121                                                 ;class before, we can quit.
 122                        (setf (cpd-class cpd) c)
 123                        (incf nclasses)
 124                        (push cpd all-cpds)
 125                        (setf (cpd-supers cpd) (mapcar #'get-cpd supers))
 126                        (dolist (super supers)
 127                          (walk super (class-direct-superclasses super))))))))
 128       (walk class supers)
 129       (values all-cpds nclasses))))
 130
 131 (defun compute-std-cpl-phase-2 (all-cpds)
 132   (dolist (cpd all-cpds)
 133     (let ((supers (cpd-supers cpd)))
 134       (when supers
 135         (setf (cpd-after cpd) (nconc (cpd-after cpd) supers))
 136         (incf (cpd-count (car supers)) 1)
 137         (do* ((t1 supers t2)
 138               (t2 (cdr t1) (cdr t1)))
 139              ((null t2))
 140           (incf (cpd-count (car t2)) 2)
 141           (push (car t2) (cpd-after (car t1))))))))
 142
 143 (defun compute-std-cpl-phase-3 (class all-cpds nclasses)
 144   (let ((candidates ())
 145         (next-cpd nil)
 146         (rcpl ()))
 147
 148     ;; We have to bootstrap the collection of those CPD's that
 149     ;; have a zero count. Once we get going, we will maintain
 150     ;; this list incrementally.
 151     (dolist (cpd all-cpds)
 152       (when (zerop (cpd-count cpd)) (push cpd candidates)))
 153
 154     (loop
 155       (when (null candidates)
 156
 157         ;; If there are no candidates, and enough classes have been put
 158         ;; into the precedence list, then we are all done. Otherwise
 159         ;; it means there is a consistency problem.
 160         (if (zerop nclasses)
 161             (return (reverse rcpl))
 162             (cpl-inconsistent-error class all-cpds)))
 163
 164       ;; Try to find the next class to put in from among the candidates.
 165       ;; If there is only one, its easy, otherwise we have to use the
 166       ;; famous RPG tiebreaker rule. There is some hair here to avoid
 167       ;; having to call DELETE on the list of candidates. I dunno if
 168       ;; its worth it but what the hell.
 169       (setq next-cpd
 170             (if (null (cdr candidates))
 171                 (prog1 (car candidates)
 172                        (setq candidates ()))
 173                 (block tie-breaker
 174                   (dolist (c rcpl)
 175                     (let ((supers (class-direct-superclasses c)))
 176                       (if (memq (cpd-class (car candidates)) supers)
 177                           (return-from tie-breaker (pop candidates))
 178                           (do ((loc candidates (cdr loc)))
 179                               ((null (cdr loc)))
 180                             (let ((cpd (cadr loc)))
 181                               (when (memq (cpd-class cpd) supers)
 182                                 (setf (cdr loc) (cddr loc))
 183                                 (return-from tie-breaker cpd))))))))))
 184       (decf nclasses)
 185       (push (cpd-class next-cpd) rcpl)
 186       (dolist (after (cpd-after next-cpd))
 187         (when (zerop (decf (cpd-count after)))
 188           (push after candidates))))))
 189 \f
 190 ;;;; support code for signalling nice error messages
 191
 192 (defun cpl-error (class format-string &rest format-args)
 193   (error "While computing the class precedence list of the class ~A.~%~A"
 194           (if (class-name class)
 195               (format nil "named ~S" (class-name class))
 196               class)
 197           (apply #'format nil format-string format-args)))
 198
 199 (defun cpl-forward-referenced-class-error (class forward-class)
 200   (flet ((class-or-name (class)
 201            (if (class-name class)
 202                (format nil "named ~S" (class-name class))
 203                class)))
 204     (let ((names (mapcar #'class-or-name
 205                          (cdr (find-superclass-chain class forward-class)))))
 206       (cpl-error class
 207                  "The class ~A is a forward referenced class.~@
 208                   The class ~A is ~A."
 209                  (class-or-name forward-class)
 210                  (class-or-name forward-class)
 211                  (if (null (cdr names))
 212                      (format nil
 213                              "a direct superclass of the class ~A"
 214                              (class-or-name class))
 215                      (format nil
 216                              "reached from the class ~A by following~@
 217                               the direct superclass chain through: ~A~
 218                               ~%  ending at the class ~A"
 219                              (class-or-name class)
 220                              (format nil
 221                                      "~{~%  the class ~A,~}"
 222                                      (butlast names))
 223                              (car (last names))))))))
 224
 225 (defun find-superclass-chain (bottom top)
 226   (labels ((walk (c chain)
 227              (if (eq c top)
 228                  (return-from find-superclass-chain (nreverse chain))
 229                  (dolist (super (class-direct-superclasses c))
 230                    (walk super (cons super chain))))))
 231     (walk bottom (list bottom))))
 232
 233 (defun cpl-inconsistent-error (class all-cpds)
 234   (let ((reasons (find-cycle-reasons all-cpds)))
 235     (cpl-error class
 236       "It is not possible to compute the class precedence list because~@
 237        there ~A in the local precedence relations.~@
 238        ~A because:~{~%  ~A~}."
 239       (if (cdr reasons) "are circularities" "is a circularity")
 240       (if (cdr reasons) "These arise" "This arises")
 241       (format-cycle-reasons (apply #'append reasons)))))
 242
 243 (defun format-cycle-reasons (reasons)
 244   (flet ((class-or-name (cpd)
 245            (let ((class (cpd-class cpd)))
 246              (if (class-name class)
 247                  (format nil "named ~S" (class-name class))
 248                  class))))
 249     (mapcar
 250       (lambda (reason)
 251         (ecase (caddr reason)
 252           (:super
 253            (format
 254             nil
 255             "The class ~A appears in the supers of the class ~A."
 256             (class-or-name (cadr reason))
 257             (class-or-name (car reason))))
 258           (:in-supers
 259            (format
 260             nil
 261             "The class ~A follows the class ~A in the supers of the class ~A."
 262             (class-or-name (cadr reason))
 263             (class-or-name (car reason))
 264             (class-or-name (cadddr reason))))))
 265       reasons)))
 266
 267 (defun find-cycle-reasons (all-cpds)
 268   (let ((been-here ())     ; list of classes we have visited
 269         (cycle-reasons ()))
 270
 271     (labels ((chase (path)
 272                (if (memq (car path) (cdr path))
 273                    (record-cycle (memq (car path) (nreverse path)))
 274                    (unless (memq (car path) been-here)
 275                      (push (car path) been-here)
 276                      (dolist (after (cpd-after (car path)))
 277                        (chase (cons after path))))))
 278              (record-cycle (cycle)
 279                (let ((reasons ()))
 280                  (do* ((t1 cycle t2)
 281                        (t2 (cdr t1) (cdr t1)))
 282                       ((null t2))
 283                    (let ((c1 (car t1))
 284                          (c2 (car t2)))
 285                      (if (memq c2 (cpd-supers c1))
 286                          (push (list c1 c2 :super) reasons)
 287                          (dolist (cpd all-cpds)
 288                            (when (memq c2 (memq c1 (cpd-supers cpd)))
 289                              (return
 290                                (push (list c1 c2 :in-supers cpd) reasons)))))))
 291                  (push (nreverse reasons) cycle-reasons))))
 292
 293       (dolist (cpd all-cpds)
 294         (unless (zerop (cpd-count cpd))
 295           (chase (list cpd))))
 296
 297       cycle-reasons)))
 298