src/pcl/ctor.lisp

   1 ;;;; This file contains the optimization machinery for make-instance.
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5
   6 ;;;; This software is derived from software originally released by
   7 ;;;; Gerd Moellmann.  Copyright and release statements follow.  Later
   8 ;;;; modifications to the software are in the public domain and are
   9 ;;;; provided with absolutely no warranty.  See the COPYING and
  10 ;;;; CREDITS files for more information.
  11
  12 ;;; Copyright (C) 2002 Gerd Moellmann <gerd.moellmann@t-online.de>
  13 ;;; All rights reserved.
  14 ;;;
  15 ;;; Redistribution and use in source and binary forms, with or without
  16 ;;; modification, are permitted provided that the following conditions
  17 ;;; are met:
  18 ;;;
  19 ;;; 1. Redistributions of source code must retain the above copyright
  20 ;;;    notice, this list of conditions and the following disclaimer.
  21 ;;; 2. Redistributions in binary form must reproduce the above copyright
  22 ;;;    notice, this list of conditions and the following disclaimer in the
  23 ;;;    documentation and/or other materials provided with the distribution.
  24 ;;; 3. The name of the author may not be used to endorse or promote
  25 ;;;    products derived from this software without specific prior written
  26 ;;;    permission.
  27 ;;;
  28 ;;; THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS
  29 ;;; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  30 ;;; WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  31 ;;; ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE
  32 ;;; LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  33 ;;; CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT
  34 ;;; OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR
  35 ;;; BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
  36 ;;; LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  37 ;;; (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE
  38 ;;; USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH
  39 ;;; DAMAGE.
  40
  41 ;;; ***************
  42 ;;; Overview  *****
  43 ;;; ***************
  44 ;;;
  45 ;;; Compiler macro for MAKE-INSTANCE, and load-time generation of
  46 ;;; optimized instance constructor functions.
  47 ;;;
  48 ;;; ********************
  49 ;;; Entry Points  ******
  50 ;;; ********************
  51 ;;;
  52 ;;; UPDATE-CTORS must be called when methods are added/removed,
  53 ;;; classes are changed, etc., which affect instance creation.
  54 ;;;
  55 ;;; PRECOMPILE-CTORS can be called to precompile constructor functions
  56 ;;; for classes whose definitions are known at the time the function
  57 ;;; is called.
  58
  59 (in-package "SB-PCL")
  60
  61 ;;; ******************
  62 ;;; Utilities  *******
  63 ;;; ******************
  64
  65 (defun quote-plist-keys (plist)
  66   (loop for (key . more) on plist by #'cddr
  67         if (null more) do
  68           (error "Not a property list: ~S" plist)
  69         else
  70           collect `(quote ,key)
  71           and collect (car more)))
  72
  73 (defun plist-keys (plist &key test)
  74   (loop for (key . more) on plist by #'cddr
  75         if (null more) do
  76           (error "Not a property list: ~S" plist)
  77         else if (or (null test) (funcall test key))
  78           collect key))
  79
  80 (defun plist-values (plist &key test)
  81   (loop for (key . more) on plist by #'cddr
  82         if (null more) do
  83           (error "Not a property list: ~S" plist)
  84         else if (or (null test) (funcall test (car more)))
  85           collect (car more)))
  86
  87 (defun constant-symbol-p (form)
  88   (and (constantp form)
  89        (let ((constant (constant-form-value form)))
  90          (and (symbolp constant)
  91               (not (null (symbol-package constant)))))))
  92
  93 ;;; somewhat akin to DEFAULT-INITARGS (SLOT-CLASS T T), but just
  94 ;;; collecting the defaulted initargs for the call.
  95 (defun ctor-default-initkeys (supplied-initargs class-default-initargs)
  96   (loop for (key) in class-default-initargs
  97         when (eq (getf supplied-initargs key '.not-there.) '.not-there.)
  98         collect key))
  99 \f
 100 ;;; *****************
 101 ;;; CTORS   *********
 102 ;;; *****************
 103 ;;;
 104 ;;; Ctors are funcallable instances whose initial function is a
 105 ;;; function computing an optimized constructor function when called.
 106 ;;; When the optimized function is computed, the function of the
 107 ;;; funcallable instance is set to it.
 108 ;;;
 109 (!defstruct-with-alternate-metaclass ctor
 110   :slot-names (function-name class-name class initargs)
 111   :boa-constructor %make-ctor
 112   :superclass-name function
 113   :metaclass-name static-classoid
 114   :metaclass-constructor make-static-classoid
 115   :dd-type funcallable-structure
 116   :runtime-type-checks-p nil)
 117
 118 ;;; List of all defined ctors.
 119
 120 (defvar *all-ctors* ())
 121
 122 (defun make-ctor-parameter-list (ctor)
 123   (plist-values (ctor-initargs ctor) :test (complement #'constantp)))
 124
 125 ;;; Reset CTOR to use a default function that will compute an
 126 ;;; optimized constructor function when called.
 127 (defun install-initial-constructor (ctor &key force-p)
 128   (when (or force-p (ctor-class ctor))
 129     (setf (ctor-class ctor) nil)
 130     (setf (funcallable-instance-fun ctor)
 131           #'(lambda (&rest args)
 132               (install-optimized-constructor ctor)
 133               (apply ctor args)))
 134     (setf (%funcallable-instance-info ctor 1)
 135           (ctor-function-name ctor))))
 136
 137 (defun make-ctor-function-name (class-name initargs)
 138   (list* 'ctor class-name initargs))
 139
 140 ;;; Keep this a separate function for testing.
 141 (defun ensure-ctor (function-name class-name initargs)
 142   (unless (fboundp function-name)
 143     (make-ctor function-name class-name initargs)))
 144
 145 ;;; Keep this a separate function for testing.
 146 (defun make-ctor (function-name class-name initargs)
 147   (without-package-locks ; for (setf symbol-function)
 148    (let ((ctor (%make-ctor function-name class-name nil initargs)))
 149      (push ctor *all-ctors*)
 150      (setf (fdefinition function-name) ctor)
 151      (install-initial-constructor ctor :force-p t)
 152      ctor)))
 153
 154 \f
 155 ;;; ***********************************************
 156 ;;; Compile-Time Expansion of MAKE-INSTANCE *******
 157 ;;; ***********************************************
 158
 159 (define-compiler-macro make-instance (&whole form &rest args)
 160   (declare (ignore args))
 161   (or (make-instance->constructor-call form)
 162       form))
 163
 164 (defun make-instance->constructor-call (form)
 165   (destructuring-bind (fn class-name &rest args) form
 166     (declare (ignore fn))
 167     (flet (;;
 168            ;; Return the name of parameter number I of a constructor
 169            ;; function.
 170            (parameter-name (i)
 171              (let ((ps #(.p0. .p1. .p2. .p3. .p4. .p5.)))
 172                (if (array-in-bounds-p ps i)
 173                    (aref ps i)
 174                    (format-symbol *pcl-package* ".P~D." i))))
 175            ;; Check if CLASS-NAME is a constant symbol.  Give up if
 176            ;; not.
 177            (check-class ()
 178              (unless (and class-name (constant-symbol-p class-name))
 179                (return-from make-instance->constructor-call nil)))
 180            ;; Check if ARGS are suitable for an optimized constructor.
 181            ;; Return NIL from the outer function if not.
 182            (check-args ()
 183              (loop for (key . more) on args by #'cddr do
 184                      (when (or (null more)
 185                                (not (constant-symbol-p key))
 186                                (eq :allow-other-keys (constant-form-value key)))
 187                        (return-from make-instance->constructor-call nil)))))
 188       (check-class)
 189       (check-args)
 190       ;; Collect a plist of initargs and constant values/parameter names
 191       ;; in INITARGS.  Collect non-constant initialization forms in
 192       ;; VALUE-FORMS.
 193       (multiple-value-bind (initargs value-forms)
 194           (loop for (key value) on args by #'cddr and i from 0
 195                 collect (constant-form-value key) into initargs
 196                 if (constantp value)
 197                   collect value into initargs
 198                 else
 199                   collect (parameter-name i) into initargs
 200                   and collect value into value-forms
 201                 finally
 202                   (return (values initargs value-forms)))
 203         (let* ((class-name (constant-form-value class-name))
 204                (function-name (make-ctor-function-name class-name initargs)))
 205           ;; Prevent compiler warnings for calling the ctor.
 206           (proclaim-as-fun-name function-name)
 207           (note-name-defined function-name :function)
 208           (when (eq (info :function :where-from function-name) :assumed)
 209             (setf (info :function :where-from function-name) :defined)
 210             (when (info :function :assumed-type function-name)
 211               (setf (info :function :assumed-type function-name) nil)))
 212           ;; Return code constructing a ctor at load time, which, when
 213           ;; called, will set its funcallable instance function to an
 214           ;; optimized constructor function.
 215           `(locally
 216                (declare (disable-package-locks ,function-name))
 217             (let ((.x. (load-time-value
 218                         (ensure-ctor ',function-name ',class-name ',initargs))))
 219               (declare (ignore .x.))
 220               ;; ??? check if this is worth it.
 221               (declare
 222                (ftype (or (function ,(make-list (length value-forms)
 223                                                 :initial-element t)
 224                                     t)
 225                           (function (&rest t) t))
 226                       ,function-name))
 227               (funcall (function ,function-name) ,@value-forms))))))))
 228
 229 \f
 230 ;;; **************************************************
 231 ;;; Load-Time Constructor Function Generation  *******
 232 ;;; **************************************************
 233
 234 ;;; The system-supplied primary INITIALIZE-INSTANCE and
 235 ;;; SHARED-INITIALIZE methods.  One cannot initialize these variables
 236 ;;; to the right values here because said functions don't exist yet
 237 ;;; when this file is first loaded.
 238 (defvar *the-system-ii-method* nil)
 239 (defvar *the-system-si-method* nil)
 240
 241 (defun install-optimized-constructor (ctor)
 242   (let ((class (find-class (ctor-class-name ctor))))
 243     (unless (class-finalized-p class)
 244       (finalize-inheritance class))
 245     (setf (ctor-class ctor) class)
 246     (pushnew ctor (plist-value class 'ctors))
 247     (setf (funcallable-instance-fun ctor)
 248           (multiple-value-bind (form locations names)
 249               (constructor-function-form ctor)
 250             (apply (compile nil `(lambda ,names ,form)) locations)))))
 251
 252 (defun constructor-function-form (ctor)
 253   (let* ((class (ctor-class ctor))
 254          (proto (class-prototype class))
 255          (make-instance-methods
 256           (compute-applicable-methods #'make-instance (list class)))
 257          (allocate-instance-methods
 258           (compute-applicable-methods #'allocate-instance (list class)))
 259          ;; I stared at this in confusion for a while, thinking
 260          ;; carefully about the possibility of the class prototype not
 261          ;; being of sufficient discrimiating power, given the
 262          ;; possibility of EQL-specialized methods on
 263          ;; INITIALIZE-INSTANCE or SHARED-INITIALIZE.  However, given
 264          ;; that this is a constructor optimization, the user doesn't
 265          ;; yet have the instance to create a method with such an EQL
 266          ;; specializer.
 267          ;;
 268          ;; There remains the (theoretical) possibility of someone
 269          ;; coming along with code of the form
 270          ;;
 271          ;; (defmethod initialize-instance :before ((o foo) ...)
 272          ;;   (eval `(defmethod shared-initialize :before ((o foo) ...) ...)))
 273          ;;
 274          ;; but probably we can afford not to worry about this too
 275          ;; much for now.  -- CSR, 2004-07-12
 276          (ii-methods
 277           (compute-applicable-methods #'initialize-instance (list proto)))
 278          (si-methods
 279           (compute-applicable-methods #'shared-initialize (list proto t)))
 280          (setf-svuc-slots-methods
 281           (loop for slot in (class-slots class)
 282                 collect (compute-applicable-methods
 283                          #'(setf slot-value-using-class)
 284                          (list nil class proto slot))))
 285          (sbuc-slots-methods
 286           (loop for slot in (class-slots class)
 287                 collect (compute-applicable-methods
 288                          #'slot-boundp-using-class
 289                          (list class proto slot)))))
 290     ;; Cannot initialize these variables earlier because the generic
 291     ;; functions don't exist when PCL is built.
 292     (when (null *the-system-si-method*)
 293       (setq *the-system-si-method*
 294             (find-method #'shared-initialize
 295                          () (list *the-class-slot-object* *the-class-t*)))
 296       (setq *the-system-ii-method*
 297             (find-method #'initialize-instance
 298                          () (list *the-class-slot-object*))))
 299     ;; Note that when there are user-defined applicable methods on
 300     ;; MAKE-INSTANCE and/or ALLOCATE-INSTANCE, these will show up
 301     ;; together with the system-defined ones in what
 302     ;; COMPUTE-APPLICABLE-METHODS returns.
 303     (if (and (not (structure-class-p class))
 304              (not (condition-class-p class))
 305              (null (cdr make-instance-methods))
 306              (null (cdr allocate-instance-methods))
 307              (every (lambda (x)
 308                       (member (slot-definition-allocation x)
 309                               '(:instance :class)))
 310                     (class-slots class))
 311              (null (check-initargs-1
 312                     class
 313                     (append
 314                      (ctor-default-initkeys
 315                       (ctor-initargs ctor) (class-default-initargs class))
 316                      (plist-keys (ctor-initargs ctor)))
 317                     (append ii-methods si-methods) nil nil))
 318              (not (around-or-nonstandard-primary-method-p
 319                    ii-methods *the-system-ii-method*))
 320              (not (around-or-nonstandard-primary-method-p
 321                    si-methods *the-system-si-method*))
 322              ;; the instance structure protocol goes through
 323              ;; slot-value(-using-class) and friends (actually just
 324              ;; (SETF SLOT-VALUE-USING-CLASS) and
 325              ;; SLOT-BOUNDP-USING-CLASS), so if there are non-standard
 326              ;; applicable methods we can't shortcircuit them.
 327              (every (lambda (x) (= (length x) 1)) setf-svuc-slots-methods)
 328              (every (lambda (x) (= (length x) 1)) sbuc-slots-methods))
 329         (optimizing-generator ctor ii-methods si-methods)
 330         (fallback-generator ctor ii-methods si-methods))))
 331
 332 (defun around-or-nonstandard-primary-method-p
 333     (methods &optional standard-method)
 334   (loop with primary-checked-p = nil
 335         for method in methods
 336         as qualifiers = (method-qualifiers method)
 337         when (or (eq :around (car qualifiers))
 338                  (and (null qualifiers)
 339                       (not primary-checked-p)
 340                       (not (null standard-method))
 341                       (not (eq standard-method method))))
 342           return t
 343         when (null qualifiers) do
 344           (setq primary-checked-p t)))
 345
 346 (defun fallback-generator (ctor ii-methods si-methods)
 347   (declare (ignore ii-methods si-methods))
 348   `(lambda ,(make-ctor-parameter-list ctor)
 349      ;; The CTOR MAKE-INSTANCE optimization only kicks in when the
 350      ;; first argument to MAKE-INSTANCE is a constant symbol: by
 351      ;; calling it with a class, as here, we inhibit the optimization,
 352      ;; so removing the possibility of endless recursion.  -- CSR,
 353      ;; 2004-07-12
 354      (make-instance ,(ctor-class ctor)
 355       ,@(quote-plist-keys (ctor-initargs ctor)))))
 356
 357 (defun optimizing-generator (ctor ii-methods si-methods)
 358   (multiple-value-bind (locations names body before-method-p)
 359       (fake-initialization-emf ctor ii-methods si-methods)
 360     (values
 361      `(lambda ,(make-ctor-parameter-list ctor)
 362        (declare #.*optimize-speed*)
 363        ,(wrap-in-allocate-forms ctor body before-method-p))
 364      locations
 365      names)))
 366
 367 ;;; Return a form wrapped around BODY that allocates an instance
 368 ;;; constructed by CTOR.  BEFORE-METHOD-P set means we have to run
 369 ;;; before-methods, in which case we initialize instance slots to
 370 ;;; +SLOT-UNBOUND+.  The resulting form binds the local variables
 371 ;;; .INSTANCE. to the instance, and .SLOTS. to the instance's slot
 372 ;;; vector around BODY.
 373 (defun wrap-in-allocate-forms (ctor body before-method-p)
 374   (let* ((class (ctor-class ctor))
 375          (wrapper (class-wrapper class))
 376          (allocation-function (raw-instance-allocator class))
 377          (slots-fetcher (slots-fetcher class)))
 378     (if (eq allocation-function 'allocate-standard-instance)
 379         `(let ((.instance. (%make-standard-instance nil
 380                                                     (get-instance-hash-code)))
 381                (.slots. (make-array
 382                          ,(layout-length wrapper)
 383                          ,@(when before-method-p
 384                              '(:initial-element +slot-unbound+)))))
 385            (setf (std-instance-wrapper .instance.) ,wrapper)
 386            (setf (std-instance-slots .instance.) .slots.)
 387            ,body
 388            .instance.)
 389         `(let* ((.instance. (,allocation-function ,wrapper))
 390                 (.slots. (,slots-fetcher .instance.)))
 391            ,body
 392            .instance.))))
 393
 394 ;;; Return a form for invoking METHOD with arguments from ARGS.  As
 395 ;;; can be seen in METHOD-FUNCTION-FROM-FAST-FUNCTION, method
 396 ;;; functions look like (LAMBDA (ARGS NEXT-METHODS) ...).  We could
 397 ;;; call fast method functions directly here, but benchmarks show that
 398 ;;; there's no speed to gain, so lets avoid the hair here.
 399 (defmacro invoke-method (method args)
 400   `(funcall ,(method-function method) ,args ()))
 401
 402 ;;; Return a form that is sort of an effective method comprising all
 403 ;;; calls to INITIALIZE-INSTANCE and SHARED-INITIALIZE that would
 404 ;;; normally have taken place when calling MAKE-INSTANCE.
 405 (defun fake-initialization-emf (ctor ii-methods si-methods)
 406   (multiple-value-bind (ii-around ii-before ii-primary ii-after)
 407       (standard-sort-methods ii-methods)
 408     (declare (ignore ii-primary))
 409     (multiple-value-bind (si-around si-before si-primary si-after)
 410         (standard-sort-methods si-methods)
 411       (declare (ignore si-primary))
 412       (aver (and (null ii-around) (null si-around)))
 413       (let ((initargs (ctor-initargs ctor)))
 414         (multiple-value-bind (locations names bindings vars defaulting-initargs body)
 415             (slot-init-forms ctor (or ii-before si-before))
 416         (values
 417          locations
 418          names
 419          `(let ,bindings
 420            (declare (ignorable ,@vars))
 421            (let (,@(when (or ii-before ii-after)
 422                      `((.ii-args.
 423                         (list .instance. ,@(quote-plist-keys initargs) ,@defaulting-initargs))))
 424                  ,@(when (or si-before si-after)
 425                      `((.si-args.
 426                         (list .instance. t ,@(quote-plist-keys initargs) ,@defaulting-initargs)))))
 427             ,@(loop for method in ii-before
 428                     collect `(invoke-method ,method .ii-args.))
 429             ,@(loop for method in si-before
 430                     collect `(invoke-method ,method .si-args.))
 431             ,@body
 432             ,@(loop for method in si-after
 433                     collect `(invoke-method ,method .si-args.))
 434             ,@(loop for method in ii-after
 435                     collect `(invoke-method ,method .ii-args.))))
 436          (or ii-before si-before)))))))
 437
 438 ;;; Return four values from APPLICABLE-METHODS: around methods, before
 439 ;;; methods, the applicable primary method, and applicable after
 440 ;;; methods.  Before and after methods are sorted in the order they
 441 ;;; must be called.
 442 (defun standard-sort-methods (applicable-methods)
 443   (loop for method in applicable-methods
 444         as qualifiers = (method-qualifiers method)
 445         if (null qualifiers)
 446           collect method into primary
 447         else if (eq :around (car qualifiers))
 448           collect method into around
 449         else if (eq :after (car qualifiers))
 450           collect method into after
 451         else if (eq :before (car qualifiers))
 452           collect method into before
 453         finally
 454           (return (values around before (first primary) (reverse after)))))
 455
 456 ;;; Return as multiple values bindings for default initialization
 457 ;;; arguments, variable names, defaulting initargs and a body for
 458 ;;; initializing instance and class slots of an object costructed by
 459 ;;; CTOR.  The variable .SLOTS. is assumed to bound to the instance's
 460 ;;; slot vector.  BEFORE-METHOD-P T means before-methods will be
 461 ;;; called, which means that 1) other code will initialize instance
 462 ;;; slots to +SLOT-UNBOUND+ before the before-methods are run, and
 463 ;;; that we have to check if these before-methods have set slots.
 464 (defun slot-init-forms (ctor before-method-p)
 465   (let* ((class (ctor-class ctor))
 466          (initargs (ctor-initargs ctor))
 467          (initkeys (plist-keys initargs))
 468          (slot-vector
 469           (make-array (layout-length (class-wrapper class))
 470                       :initial-element nil))
 471          (class-inits ())
 472          (default-inits ())
 473          (defaulting-initargs ())
 474          (default-initargs (class-default-initargs class))
 475          (initarg-locations
 476           (compute-initarg-locations
 477            class (append initkeys (mapcar #'car default-initargs)))))
 478     (labels ((initarg-locations (initarg)
 479                (cdr (assoc initarg initarg-locations :test #'eq)))
 480              (initializedp (location)
 481                (cond
 482                  ((consp location)
 483                   (assoc location class-inits :test #'eq))
 484                  ((integerp location)
 485                   (not (null (aref slot-vector location))))
 486                  (t (bug "Weird location in ~S" 'slot-init-forms))))
 487              (class-init (location type val)
 488                (aver (consp location))
 489                (unless (initializedp location)
 490                  (push (list location type val) class-inits)))
 491              (instance-init (location type val)
 492                (aver (integerp location))
 493                (unless (initializedp location)
 494                  (setf (aref slot-vector location) (list type val))))
 495              (default-init-var-name (i)
 496                (let ((ps #(.d0. .d1. .d2. .d3. .d4. .d5.)))
 497                  (if (array-in-bounds-p ps i)
 498                      (aref ps i)
 499                      (format-symbol *pcl-package* ".D~D." i))))
 500              (location-var-name (i)
 501                (let ((ls #(.l0. .l1. .l2. .l3. .l4. .l5.)))
 502                  (if (array-in-bounds-p ls i)
 503                      (aref ls i)
 504                      (format-symbol *pcl-package* ".L~D." i)))))
 505       ;; Loop over supplied initargs and values and record which
 506       ;; instance and class slots they initialize.
 507       (loop for (key value) on initargs by #'cddr
 508             as locations = (initarg-locations key) do
 509               (if (constantp value)
 510                   (dolist (location locations)
 511                     (if (consp location)
 512                         (class-init location 'constant value)
 513                         (instance-init location 'constant value)))
 514                   (dolist (location locations)
 515                       (if (consp location)
 516                           (class-init location 'param value)
 517                           (instance-init location 'param value)))))
 518       ;; Loop over default initargs of the class, recording
 519       ;; initializations of slots that have not been initialized
 520       ;; above.  Default initargs which are not in the supplied
 521       ;; initargs are treated as if they were appended to supplied
 522       ;; initargs, that is, their values must be evaluated even
 523       ;; if not actually used for initializing a slot.
 524       (loop for (key initform initfn) in default-initargs and i from 0
 525             unless (member key initkeys :test #'eq) do
 526             (let* ((type (if (constantp initform) 'constant 'var))
 527                    (init (if (eq type 'var) initfn initform)))
 528               (ecase type
 529                 (constant
 530                  (push key defaulting-initargs)
 531                  (push initform defaulting-initargs))
 532                 (var
 533                  (push key defaulting-initargs)
 534                  (push (default-init-var-name i) defaulting-initargs)))
 535               (when (eq type 'var)
 536                 (let ((init-var (default-init-var-name i)))
 537                   (setq init init-var)
 538                   (push (cons init-var initfn) default-inits)))
 539               (dolist (location (initarg-locations key))
 540                 (if (consp location)
 541                     (class-init location type init)
 542                     (instance-init location type init)))))
 543       ;; Loop over all slots of the class, filling in the rest from
 544       ;; slot initforms.
 545       (loop for slotd in (class-slots class)
 546             as location = (slot-definition-location slotd)
 547             as allocation = (slot-definition-allocation slotd)
 548             as initfn = (slot-definition-initfunction slotd)
 549             as initform = (slot-definition-initform slotd) do
 550               (unless (or (eq allocation :class)
 551                           (null initfn)
 552                           (initializedp location))
 553                 (if (constantp initform)
 554                     (instance-init location 'initform initform)
 555                     (instance-init location 'initform/initfn initfn))))
 556       ;; Generate the forms for initializing instance and class slots.
 557       (let ((instance-init-forms
 558              (loop for slot-entry across slot-vector and i from 0
 559                    as (type value) = slot-entry collect
 560                      (ecase type
 561                        ((nil)
 562                         (unless before-method-p
 563                           `(setf (clos-slots-ref .slots. ,i) +slot-unbound+)))
 564                        ((param var)
 565                         `(setf (clos-slots-ref .slots. ,i) ,value))
 566                        (initfn
 567                         `(setf (clos-slots-ref .slots. ,i) (funcall ,value)))
 568                        (initform/initfn
 569                         (if before-method-p
 570                             `(when (eq (clos-slots-ref .slots. ,i)
 571                                        +slot-unbound+)
 572                                (setf (clos-slots-ref .slots. ,i)
 573                                      (funcall ,value)))
 574                             `(setf (clos-slots-ref .slots. ,i)
 575                                    (funcall ,value))))
 576                        (initform
 577                         (if before-method-p
 578                             `(when (eq (clos-slots-ref .slots. ,i)
 579                                        +slot-unbound+)
 580                                (setf (clos-slots-ref .slots. ,i)
 581                                      ',(constant-form-value value)))
 582                             `(setf (clos-slots-ref .slots. ,i)
 583                                    ',(constant-form-value value))))
 584                        (constant
 585                         `(setf (clos-slots-ref .slots. ,i)
 586                                ',(constant-form-value value)))))))
 587         ;; we are not allowed to modify QUOTEd locations, so we can't
 588         ;; generate code like (setf (cdr ',location) arg).  Instead,
 589         ;; we have to do (setf (cdr .L0.) arg) and arrange for .L0. to
 590         ;; be bound to the location.
 591         (multiple-value-bind (names locations class-init-forms)
 592             (loop for (location type value) in class-inits
 593                   for i upfrom 0
 594                   for name = (location-var-name i)
 595                   collect name into names
 596                   collect location into locations
 597                   collect `(setf (cdr ,name)
 598                                  ,(case type
 599                                     (constant `',(constant-form-value value))
 600                                     ((param var) `,value)
 601                                     (initfn `(funcall ,value))))
 602                   into class-init-forms
 603                   finally (return (values names locations class-init-forms)))
 604           (multiple-value-bind (vars bindings)
 605               (loop for (var . initfn) in (nreverse default-inits)
 606                     collect var into vars
 607                     collect `(,var (funcall ,initfn)) into bindings
 608                     finally (return (values vars bindings)))
 609             (values locations names
 610                     bindings vars
 611                     (nreverse defaulting-initargs)
 612                     `(,@(delete nil instance-init-forms)
 613                       ,@class-init-forms))))))))
 614
 615 ;;; Return an alist of lists (KEY LOCATION ...) telling, for each
 616 ;;; key in INITKEYS, which locations the initarg initializes.
 617 ;;; CLASS is the class of the instance being initialized.
 618 (defun compute-initarg-locations (class initkeys)
 619   (loop with slots = (class-slots class)
 620         for key in initkeys collect
 621           (loop for slot in slots
 622                 if (memq key (slot-definition-initargs slot))
 623                   collect (slot-definition-location slot) into locations
 624                 else
 625                   collect slot into remaining-slots
 626                 finally
 627                   (setq slots remaining-slots)
 628                   (return (cons key locations)))))
 629
 630 \f
 631 ;;; *******************************
 632 ;;; External Entry Points  ********
 633 ;;; *******************************
 634
 635 (defun update-ctors (reason &key class name generic-function method)
 636   (labels ((reset (class &optional ri-cache-p (ctorsp t))
 637              (when ctorsp
 638                (dolist (ctor (plist-value class 'ctors))
 639                  (install-initial-constructor ctor)))
 640              (when ri-cache-p
 641                (setf (plist-value class 'ri-initargs) ()))
 642              (dolist (subclass (class-direct-subclasses class))
 643                (reset subclass ri-cache-p ctorsp))))
 644     (ecase reason
 645       ;; CLASS must have been specified.
 646       (finalize-inheritance
 647        (reset class t))
 648       ;; NAME must have been specified.
 649       (setf-find-class
 650        (loop for ctor in *all-ctors*
 651              when (eq (ctor-class-name ctor) name) do
 652              (when (ctor-class ctor)
 653                (reset (ctor-class ctor)))
 654              (loop-finish)))
 655       ;; GENERIC-FUNCTION and METHOD must have been specified.
 656       ((add-method remove-method)
 657        (flet ((class-of-1st-method-param (method)
 658                 (type-class (first (method-specializers method)))))
 659          (case (generic-function-name generic-function)
 660            ((make-instance allocate-instance
 661              initialize-instance shared-initialize)
 662             (reset (class-of-1st-method-param method) t t))
 663            ((reinitialize-instance)
 664             (reset (class-of-1st-method-param method) t nil))
 665            (t (when (or (eq (generic-function-name generic-function)
 666                             'slot-boundp-using-class)
 667                         (equal (generic-function-name generic-function)
 668                                '(setf slot-value-using-class)))
 669                 ;; this looks awfully expensive, but given that one
 670                 ;; can specialize on the SLOTD argument, nothing is
 671                 ;; safe.  -- CSR, 2004-07-12
 672                 (reset (find-class 'standard-object))))))))))
 673
 674 (defun precompile-ctors ()
 675   (dolist (ctor *all-ctors*)
 676     (when (null (ctor-class ctor))
 677       (let ((class (find-class (ctor-class-name ctor) nil)))
 678         (when (and class (class-finalized-p class))
 679           (install-optimized-constructor ctor))))))
 680
 681 (defun check-ri-initargs (instance initargs)
 682   (let* ((class (class-of instance))
 683          (keys (plist-keys initargs))
 684          (cached (assoc keys (plist-value class 'ri-initargs)
 685                         :test #'equal))
 686          (invalid-keys
 687           (if (consp cached)
 688               (cdr cached)
 689               (let ((invalid
 690                      ;; FIXME: give CHECK-INITARGS-1 and friends a
 691                      ;; more mnemonic name and (possibly) a nicer,
 692                      ;; more orthogonal interface.
 693                      (check-initargs-1
 694                       class initargs
 695                       (list (list* 'reinitialize-instance instance initargs)
 696                             (list* 'shared-initialize instance nil initargs))
 697                       t nil)))
 698                 (setf (plist-value class 'ri-initargs)
 699                       (acons keys invalid cached))
 700                 invalid))))
 701     (when invalid-keys
 702       (error 'initarg-error :class class :initargs invalid-keys))))
 703
 704 ;;; end of ctor.lisp