src/pcl/ctor.lisp

   1 ;;;; This file contains the optimization machinery for make-instance.
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5
   6 ;;;; This software is derived from software originally released by
   7 ;;;; Gerd Moellmann.  Copyright and release statements follow.  Later
   8 ;;;; modifications to the software are in the public domain and are
   9 ;;;; provided with absolutely no warranty.  See the COPYING and
  10 ;;;; CREDITS files for more information.
  11
  12 ;;; Copyright (C) 2002 Gerd Moellmann <gerd.moellmann@t-online.de>
  13 ;;; All rights reserved.
  14 ;;;
  15 ;;; Redistribution and use in source and binary forms, with or without
  16 ;;; modification, are permitted provided that the following conditions
  17 ;;; are met:
  18 ;;;
  19 ;;; 1. Redistributions of source code must retain the above copyright
  20 ;;;    notice, this list of conditions and the following disclaimer.
  21 ;;; 2. Redistributions in binary form must reproduce the above copyright
  22 ;;;    notice, this list of conditions and the following disclaimer in the
  23 ;;;    documentation and/or other materials provided with the distribution.
  24 ;;; 3. The name of the author may not be used to endorse or promote
  25 ;;;    products derived from this software without specific prior written
  26 ;;;    permission.
  27 ;;;
  28 ;;; THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS
  29 ;;; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  30 ;;; WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  31 ;;; ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE
  32 ;;; LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  33 ;;; CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT
  34 ;;; OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR
  35 ;;; BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
  36 ;;; LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  37 ;;; (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE
  38 ;;; USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH
  39 ;;; DAMAGE.
  40
  41 ;;; ***************
  42 ;;; Overview  *****
  43 ;;; ***************
  44 ;;;
  45 ;;; Compiler macro for MAKE-INSTANCE, and load-time generation of
  46 ;;; optimized instance constructor functions.
  47 ;;;
  48 ;;; ********************
  49 ;;; Entry Points  ******
  50 ;;; ********************
  51 ;;;
  52 ;;; UPDATE-CTORS must be called when methods are added/removed,
  53 ;;; classes are changed, etc., which affect instance creation.
  54 ;;;
  55 ;;; PRECOMPILE-CTORS can be called to precompile constructor functions
  56 ;;; for classes whose definitions are known at the time the function
  57 ;;; is called.
  58
  59 (in-package "SB-PCL")
  60
  61 ;;; ******************
  62 ;;; Utilities  *******
  63 ;;; ******************
  64
  65 (defun quote-plist-keys (plist)
  66   (loop for (key . more) on plist by #'cddr
  67         if (null more) do
  68           (error "Not a property list: ~S" plist)
  69         else
  70           collect `(quote ,key)
  71           and collect (car more)))
  72
  73 (defun plist-keys (plist &key test)
  74   (loop for (key . more) on plist by #'cddr
  75         if (null more) do
  76           (error "Not a property list: ~S" plist)
  77         else if (or (null test) (funcall test key))
  78           collect key))
  79
  80 (defun plist-values (plist &key test)
  81   (loop for (key . more) on plist by #'cddr
  82         if (null more) do
  83           (error "Not a property list: ~S" plist)
  84         else if (or (null test) (funcall test (car more)))
  85           collect (car more)))
  86
  87 (defun constant-symbol-p (form)
  88   (and (constantp form)
  89        (let ((constant (eval form)))
  90          (and (symbolp constant)
  91               (not (null (symbol-package constant)))))))
  92
  93 ;;; somewhat akin to DEFAULT-INITARGS (SLOT-CLASS T T), but just
  94 ;;; collecting the defaulted initargs for the call.
  95 (defun ctor-default-initkeys (supplied-initargs class-default-initargs)
  96   (loop for (key) in class-default-initargs
  97         when (eq (getf supplied-initargs key '.not-there.) '.not-there.)
  98         collect key))
  99 \f
 100 ;;; *****************
 101 ;;; CTORS   *********
 102 ;;; *****************
 103 ;;;
 104 ;;; Ctors are funcallable instances whose initial function is a
 105 ;;; function computing an optimized constructor function when called.
 106 ;;; When the optimized function is computed, the function of the
 107 ;;; funcallable instance is set to it.
 108 ;;;
 109 (!defstruct-with-alternate-metaclass ctor
 110   :slot-names (function-name class-name class initargs)
 111   :boa-constructor %make-ctor
 112   :superclass-name pcl-funcallable-instance
 113   :metaclass-name random-pcl-classoid
 114   :metaclass-constructor make-random-pcl-classoid
 115   :dd-type funcallable-structure
 116   :runtime-type-checks-p nil)
 117
 118 ;;; List of all defined ctors.
 119
 120 (defvar *all-ctors* ())
 121
 122 (defun make-ctor-parameter-list (ctor)
 123   (plist-values (ctor-initargs ctor) :test (complement #'constantp)))
 124
 125 ;;; Reset CTOR to use a default function that will compute an
 126 ;;; optimized constructor function when called.
 127 (defun install-initial-constructor (ctor &key force-p)
 128   (when (or force-p (ctor-class ctor))
 129     (setf (ctor-class ctor) nil)
 130     (setf (funcallable-instance-fun ctor)
 131           #'(lambda (&rest args)
 132               (install-optimized-constructor ctor)
 133               (apply ctor args)))
 134     (setf (%funcallable-instance-info ctor 1)
 135           (ctor-function-name ctor))))
 136
 137 (defun make-ctor-function-name (class-name initargs)
 138   (list* 'ctor class-name initargs))
 139
 140 ;;; Keep this a separate function for testing.
 141 (defun ensure-ctor (function-name class-name initargs)
 142   (unless (fboundp function-name)
 143     (make-ctor function-name class-name initargs)))
 144
 145 ;;; Keep this a separate function for testing.
 146 (defun make-ctor (function-name class-name initargs)
 147   (without-package-locks ; for (setf symbol-function)
 148    (let ((ctor (%make-ctor function-name class-name nil initargs)))
 149      (push ctor *all-ctors*)
 150      (setf (fdefinition function-name) ctor)
 151      (install-initial-constructor ctor :force-p t)
 152      ctor)))
 153
 154 \f
 155 ;;; ***********************************************
 156 ;;; Compile-Time Expansion of MAKE-INSTANCE *******
 157 ;;; ***********************************************
 158
 159 (define-compiler-macro make-instance (&whole form &rest args)
 160   (declare (ignore args))
 161   (or (make-instance->constructor-call form)
 162       form))
 163
 164 (defun make-instance->constructor-call (form)
 165   (destructuring-bind (fn class-name &rest args) form
 166     (declare (ignore fn))
 167     (flet (;;
 168            ;; Return the name of parameter number I of a constructor
 169            ;; function.
 170            (parameter-name (i)
 171              (let ((ps #(.p0. .p1. .p2. .p3. .p4. .p5.)))
 172                (if (array-in-bounds-p ps i)
 173                    (aref ps i)
 174                    (format-symbol *pcl-package* ".P~D." i))))
 175            ;; Check if CLASS-NAME is a constant symbol.  Give up if
 176            ;; not.
 177            (check-class ()
 178              (unless (and class-name (constant-symbol-p class-name))
 179                (return-from make-instance->constructor-call nil)))
 180            ;; Check if ARGS are suitable for an optimized constructor.
 181            ;; Return NIL from the outer function if not.
 182            (check-args ()
 183              (loop for (key . more) on args by #'cddr do
 184                      (when (or (null more)
 185                                (not (constant-symbol-p key))
 186                                (eq :allow-other-keys (eval key)))
 187                        (return-from make-instance->constructor-call nil)))))
 188       (check-class)
 189       (check-args)
 190       ;; Collect a plist of initargs and constant values/parameter names
 191       ;; in INITARGS.  Collect non-constant initialization forms in
 192       ;; VALUE-FORMS.
 193       (multiple-value-bind (initargs value-forms)
 194           (loop for (key value) on args by #'cddr and i from 0
 195                 collect (eval key) into initargs
 196                 if (constantp value)
 197                   collect value into initargs
 198                 else
 199                   collect (parameter-name i) into initargs
 200                   and collect value into value-forms
 201                 finally
 202                   (return (values initargs value-forms)))
 203         (let* ((class-name (eval class-name))
 204                (function-name (make-ctor-function-name class-name initargs)))
 205           ;; Prevent compiler warnings for calling the ctor.
 206           (proclaim-as-fun-name function-name)
 207           (note-name-defined function-name :function)
 208           (when (eq (info :function :where-from function-name) :assumed)
 209             (setf (info :function :where-from function-name) :defined)
 210             (when (info :function :assumed-type function-name)
 211               (setf (info :function :assumed-type function-name) nil)))
 212           ;; Return code constructing a ctor at load time, which, when
 213           ;; called, will set its funcallable instance function to an
 214           ;; optimized constructor function.
 215           `(locally
 216                (declare (disable-package-locks ,function-name))
 217             (let ((.x. (load-time-value
 218                         (ensure-ctor ',function-name ',class-name ',initargs))))
 219               (declare (ignore .x.))
 220               ;; ??? check if this is worth it.
 221               (declare
 222                (ftype (or (function ,(make-list (length value-forms)
 223                                                 :initial-element t)
 224                                     t)
 225                           (function (&rest t) t))
 226                       ,function-name))
 227               (funcall (function ,function-name) ,@value-forms))))))))
 228
 229 \f
 230 ;;; **************************************************
 231 ;;; Load-Time Constructor Function Generation  *******
 232 ;;; **************************************************
 233
 234 ;;; The system-supplied primary INITIALIZE-INSTANCE and
 235 ;;; SHARED-INITIALIZE methods.  One cannot initialize these variables
 236 ;;; to the right values here because said functions don't exist yet
 237 ;;; when this file is first loaded.
 238 (defvar *the-system-ii-method* nil)
 239 (defvar *the-system-si-method* nil)
 240
 241 (defun install-optimized-constructor (ctor)
 242   (let ((class (find-class (ctor-class-name ctor))))
 243     (unless (class-finalized-p class)
 244       (finalize-inheritance class))
 245     (setf (ctor-class ctor) class)
 246     (pushnew ctor (plist-value class 'ctors))
 247     (setf (funcallable-instance-fun ctor)
 248           ;; KLUDGE: Gerd here has the equivalent of (COMPILE NIL
 249           ;; (CONSTRUCTOR-FUNCTION-FORM)), but SBCL's COMPILE doesn't
 250           ;; deal with INSTANCE-LAMBDA expressions, only with LAMBDA
 251           ;; expressions.  The below should be equivalent, since we
 252           ;; have a compiler-only implementation.
 253           ;;
 254           ;; (except maybe for optimization qualities? -- CSR,
 255           ;; 2004-07-12)
 256           ;;
 257           ;; FIXME: INSTANCE-LAMBDA is no more.  We could change this.
 258           (multiple-value-bind (form locations names)
 259               (constructor-function-form ctor)
 260             (apply (compile nil `(lambda ,names ,form)) locations)))))
 261
 262 (defun constructor-function-form (ctor)
 263   (let* ((class (ctor-class ctor))
 264          (proto (class-prototype class))
 265          (make-instance-methods
 266           (compute-applicable-methods #'make-instance (list class)))
 267          (allocate-instance-methods
 268           (compute-applicable-methods #'allocate-instance (list class)))
 269          ;; I stared at this in confusion for a while, thinking
 270          ;; carefully about the possibility of the class prototype not
 271          ;; being of sufficient discrimiating power, given the
 272          ;; possibility of EQL-specialized methods on
 273          ;; INITIALIZE-INSTANCE or SHARED-INITIALIZE.  However, given
 274          ;; that this is a constructor optimization, the user doesn't
 275          ;; yet have the instance to create a method with such an EQL
 276          ;; specializer.
 277          ;;
 278          ;; There remains the (theoretical) possibility of someone
 279          ;; coming along with code of the form
 280          ;;
 281          ;; (defmethod initialize-instance :before ((o foo) ...)
 282          ;;   (eval `(defmethod shared-initialize :before ((o foo) ...) ...)))
 283          ;;
 284          ;; but probably we can afford not to worry about this too
 285          ;; much for now.  -- CSR, 2004-07-12
 286          (ii-methods
 287           (compute-applicable-methods #'initialize-instance (list proto)))
 288          (si-methods
 289           (compute-applicable-methods #'shared-initialize (list proto t)))
 290          (setf-svuc-slots-methods
 291           (loop for slot in (class-slots class)
 292                 collect (compute-applicable-methods
 293                          #'(setf slot-value-using-class)
 294                          (list nil class proto slot))))
 295          (sbuc-slots-methods
 296           (loop for slot in (class-slots class)
 297                 collect (compute-applicable-methods
 298                          #'slot-boundp-using-class
 299                          (list class proto slot)))))
 300     ;; Cannot initialize these variables earlier because the generic
 301     ;; functions don't exist when PCL is built.
 302     (when (null *the-system-si-method*)
 303       (setq *the-system-si-method*
 304             (find-method #'shared-initialize
 305                          () (list *the-class-slot-object* *the-class-t*)))
 306       (setq *the-system-ii-method*
 307             (find-method #'initialize-instance
 308                          () (list *the-class-slot-object*))))
 309     ;; Note that when there are user-defined applicable methods on
 310     ;; MAKE-INSTANCE and/or ALLOCATE-INSTANCE, these will show up
 311     ;; together with the system-defined ones in what
 312     ;; COMPUTE-APPLICABLE-METHODS returns.
 313     (if (and (not (structure-class-p class))
 314              (not (condition-class-p class))
 315              (null (cdr make-instance-methods))
 316              (null (cdr allocate-instance-methods))
 317              (every (lambda (x)
 318                       (member (slot-definition-allocation x)
 319                               '(:instance :class)))
 320                     (class-slots class))
 321              (null (check-initargs-1
 322                     class
 323                     (append
 324                      (ctor-default-initkeys
 325                       (ctor-initargs ctor) (class-default-initargs class))
 326                      (plist-keys (ctor-initargs ctor)))
 327                     (append ii-methods si-methods) nil nil))
 328              (not (around-or-nonstandard-primary-method-p
 329                    ii-methods *the-system-ii-method*))
 330              (not (around-or-nonstandard-primary-method-p
 331                    si-methods *the-system-si-method*))
 332              ;; the instance structure protocol goes through
 333              ;; slot-value(-using-class) and friends (actually just
 334              ;; (SETF SLOT-VALUE-USING-CLASS) and
 335              ;; SLOT-BOUNDP-USING-CLASS), so if there are non-standard
 336              ;; applicable methods we can't shortcircuit them.
 337              (every (lambda (x) (= (length x) 1)) setf-svuc-slots-methods)
 338              (every (lambda (x) (= (length x) 1)) sbuc-slots-methods))
 339         (optimizing-generator ctor ii-methods si-methods)
 340         (fallback-generator ctor ii-methods si-methods))))
 341
 342 (defun around-or-nonstandard-primary-method-p
 343     (methods &optional standard-method)
 344   (loop with primary-checked-p = nil
 345         for method in methods
 346         as qualifiers = (method-qualifiers method)
 347         when (or (eq :around (car qualifiers))
 348                  (and (null qualifiers)
 349                       (not primary-checked-p)
 350                       (not (null standard-method))
 351                       (not (eq standard-method method))))
 352           return t
 353         when (null qualifiers) do
 354           (setq primary-checked-p t)))
 355
 356 (defun fallback-generator (ctor ii-methods si-methods)
 357   (declare (ignore ii-methods si-methods))
 358   `(lambda ,(make-ctor-parameter-list ctor)
 359      ;; The CTOR MAKE-INSTANCE optimization only kicks in when the
 360      ;; first argument to MAKE-INSTANCE is a constant symbol: by
 361      ;; calling it with a class, as here, we inhibit the optimization,
 362      ;; so removing the possibility of endless recursion.  -- CSR,
 363      ;; 2004-07-12
 364      (make-instance ,(ctor-class ctor) ,@(ctor-initargs ctor))))
 365
 366 (defun optimizing-generator (ctor ii-methods si-methods)
 367   (multiple-value-bind (locations names body before-method-p)
 368       (fake-initialization-emf ctor ii-methods si-methods)
 369     (values
 370      `(lambda ,(make-ctor-parameter-list ctor)
 371        (declare #.*optimize-speed*)
 372        ,(wrap-in-allocate-forms ctor body before-method-p))
 373      locations
 374      names)))
 375
 376 ;;; Return a form wrapped around BODY that allocates an instance
 377 ;;; constructed by CTOR.  BEFORE-METHOD-P set means we have to run
 378 ;;; before-methods, in which case we initialize instance slots to
 379 ;;; +SLOT-UNBOUND+.  The resulting form binds the local variables
 380 ;;; .INSTANCE. to the instance, and .SLOTS. to the instance's slot
 381 ;;; vector around BODY.
 382 (defun wrap-in-allocate-forms (ctor body before-method-p)
 383   (let* ((class (ctor-class ctor))
 384          (wrapper (class-wrapper class))
 385          (allocation-function (raw-instance-allocator class))
 386          (slots-fetcher (slots-fetcher class)))
 387     (if (eq allocation-function 'allocate-standard-instance)
 388         `(let ((.instance. (%make-standard-instance nil
 389                                                     (get-instance-hash-code)))
 390                (.slots. (make-array
 391                          ,(layout-length wrapper)
 392                          ,@(when before-method-p
 393                              '(:initial-element +slot-unbound+)))))
 394            (setf (std-instance-wrapper .instance.) ,wrapper)
 395            (setf (std-instance-slots .instance.) .slots.)
 396            ,body
 397            .instance.)
 398         `(let* ((.instance. (,allocation-function ,wrapper))
 399                 (.slots. (,slots-fetcher .instance.)))
 400            ,body
 401            .instance.))))
 402
 403 ;;; Return a form for invoking METHOD with arguments from ARGS.  As
 404 ;;; can be seen in METHOD-FUNCTION-FROM-FAST-FUNCTION, method
 405 ;;; functions look like (LAMBDA (ARGS NEXT-METHODS) ...).  We could
 406 ;;; call fast method functions directly here, but benchmarks show that
 407 ;;; there's no speed to gain, so lets avoid the hair here.
 408 (defmacro invoke-method (method args)
 409   `(funcall ,(method-function method) ,args ()))
 410
 411 ;;; Return a form that is sort of an effective method comprising all
 412 ;;; calls to INITIALIZE-INSTANCE and SHARED-INITIALIZE that would
 413 ;;; normally have taken place when calling MAKE-INSTANCE.
 414 (defun fake-initialization-emf (ctor ii-methods si-methods)
 415   (multiple-value-bind (ii-around ii-before ii-primary ii-after)
 416       (standard-sort-methods ii-methods)
 417     (declare (ignore ii-primary))
 418     (multiple-value-bind (si-around si-before si-primary si-after)
 419         (standard-sort-methods si-methods)
 420       (declare (ignore si-primary))
 421       (aver (and (null ii-around) (null si-around)))
 422       (let ((initargs (ctor-initargs ctor)))
 423         (multiple-value-bind (locations names bindings vars defaulting-initargs body)
 424             (slot-init-forms ctor (or ii-before si-before))
 425         (values
 426          locations
 427          names
 428          `(let ,bindings
 429            (declare (ignorable ,@vars))
 430            (let (,@(when (or ii-before ii-after)
 431                      `((.ii-args.
 432                         (list .instance. ,@(quote-plist-keys initargs) ,@defaulting-initargs))))
 433                  ,@(when (or si-before si-after)
 434                      `((.si-args.
 435                         (list .instance. t ,@(quote-plist-keys initargs) ,@defaulting-initargs)))))
 436             ,@(loop for method in ii-before
 437                     collect `(invoke-method ,method .ii-args.))
 438             ,@(loop for method in si-before
 439                     collect `(invoke-method ,method .si-args.))
 440             ,@body
 441             ,@(loop for method in si-after
 442                     collect `(invoke-method ,method .si-args.))
 443             ,@(loop for method in ii-after
 444                     collect `(invoke-method ,method .ii-args.))))
 445          (or ii-before si-before)))))))
 446
 447 ;;; Return four values from APPLICABLE-METHODS: around methods, before
 448 ;;; methods, the applicable primary method, and applicable after
 449 ;;; methods.  Before and after methods are sorted in the order they
 450 ;;; must be called.
 451 (defun standard-sort-methods (applicable-methods)
 452   (loop for method in applicable-methods
 453         as qualifiers = (method-qualifiers method)
 454         if (null qualifiers)
 455           collect method into primary
 456         else if (eq :around (car qualifiers))
 457           collect method into around
 458         else if (eq :after (car qualifiers))
 459           collect method into after
 460         else if (eq :before (car qualifiers))
 461           collect method into before
 462         finally
 463           (return (values around before (first primary) (reverse after)))))
 464
 465 ;;; Return as multiple values bindings for default initialization
 466 ;;; arguments, variable names, defaulting initargs and a body for
 467 ;;; initializing instance and class slots of an object costructed by
 468 ;;; CTOR.  The variable .SLOTS. is assumed to bound to the instance's
 469 ;;; slot vector.  BEFORE-METHOD-P T means before-methods will be
 470 ;;; called, which means that 1) other code will initialize instance
 471 ;;; slots to +SLOT-UNBOUND+ before the before-methods are run, and
 472 ;;; that we have to check if these before-methods have set slots.
 473 (defun slot-init-forms (ctor before-method-p)
 474   (let* ((class (ctor-class ctor))
 475          (initargs (ctor-initargs ctor))
 476          (initkeys (plist-keys initargs))
 477          (slot-vector
 478           (make-array (layout-length (class-wrapper class))
 479                       :initial-element nil))
 480          (class-inits ())
 481          (default-inits ())
 482          (defaulting-initargs ())
 483          (default-initargs (class-default-initargs class))
 484          (initarg-locations
 485           (compute-initarg-locations
 486            class (append initkeys (mapcar #'car default-initargs)))))
 487     (labels ((initarg-locations (initarg)
 488                (cdr (assoc initarg initarg-locations :test #'eq)))
 489              (initializedp (location)
 490                (cond
 491                  ((consp location)
 492                   (assoc location class-inits :test #'eq))
 493                  ((integerp location)
 494                   (not (null (aref slot-vector location))))
 495                  (t (bug "Weird location in ~S" 'slot-init-forms))))
 496              (class-init (location type val)
 497                (aver (consp location))
 498                (unless (initializedp location)
 499                  (push (list location type val) class-inits)))
 500              (instance-init (location type val)
 501                (aver (integerp location))
 502                (unless (initializedp location)
 503                  (setf (aref slot-vector location) (list type val))))
 504              (default-init-var-name (i)
 505                (let ((ps #(.d0. .d1. .d2. .d3. .d4. .d5.)))
 506                  (if (array-in-bounds-p ps i)
 507                      (aref ps i)
 508                      (format-symbol *pcl-package* ".D~D." i))))
 509              (location-var-name (i)
 510                (let ((ls #(.l0. .l1. .l2. .l3. .l4. .l5.)))
 511                  (if (array-in-bounds-p ls i)
 512                      (aref ls i)
 513                      (format-symbol *pcl-package* ".L~D." i)))))
 514       ;; Loop over supplied initargs and values and record which
 515       ;; instance and class slots they initialize.
 516       (loop for (key value) on initargs by #'cddr
 517             as locations = (initarg-locations key) do
 518               (if (constantp value)
 519                   (dolist (location locations)
 520                     (if (consp location)
 521                         (class-init location 'constant value)
 522                         (instance-init location 'constant value)))
 523                   (dolist (location locations)
 524                       (if (consp location)
 525                           (class-init location 'param value)
 526                           (instance-init location 'param value)))))
 527       ;; Loop over default initargs of the class, recording
 528       ;; initializations of slots that have not been initialized
 529       ;; above.  Default initargs which are not in the supplied
 530       ;; initargs are treated as if they were appended to supplied
 531       ;; initargs, that is, their values must be evaluated even
 532       ;; if not actually used for initializing a slot.
 533       (loop for (key initform initfn) in default-initargs and i from 0
 534             unless (member key initkeys :test #'eq) do
 535             (let* ((type (if (constantp initform) 'constant 'var))
 536                    (init (if (eq type 'var) initfn initform)))
 537               (ecase type
 538                 (constant
 539                  (push key defaulting-initargs)
 540                  (push initform defaulting-initargs))
 541                 (var
 542                  (push key defaulting-initargs)
 543                  (push (default-init-var-name i) defaulting-initargs)))
 544               (when (eq type 'var)
 545                 (let ((init-var (default-init-var-name i)))
 546                   (setq init init-var)
 547                   (push (cons init-var initfn) default-inits)))
 548               (dolist (location (initarg-locations key))
 549                 (if (consp location)
 550                     (class-init location type init)
 551                     (instance-init location type init)))))
 552       ;; Loop over all slots of the class, filling in the rest from
 553       ;; slot initforms.
 554       (loop for slotd in (class-slots class)
 555             as location = (slot-definition-location slotd)
 556             as allocation = (slot-definition-allocation slotd)
 557             as initfn = (slot-definition-initfunction slotd)
 558             as initform = (slot-definition-initform slotd) do
 559               (unless (or (eq allocation :class)
 560                           (null initfn)
 561                           (initializedp location))
 562                 (if (constantp initform)
 563                     (instance-init location 'initform initform)
 564                     (instance-init location 'initform/initfn initfn))))
 565       ;; Generate the forms for initializing instance and class slots.
 566       (let ((instance-init-forms
 567              (loop for slot-entry across slot-vector and i from 0
 568                    as (type value) = slot-entry collect
 569                      (ecase type
 570                        ((nil)
 571                         (unless before-method-p
 572                           `(setf (clos-slots-ref .slots. ,i) +slot-unbound+)))
 573                        ((param var)
 574                         `(setf (clos-slots-ref .slots. ,i) ,value))
 575                        (initfn
 576                         `(setf (clos-slots-ref .slots. ,i) (funcall ,value)))
 577                        (initform/initfn
 578                         (if before-method-p
 579                             `(when (eq (clos-slots-ref .slots. ,i)
 580                                        +slot-unbound+)
 581                                (setf (clos-slots-ref .slots. ,i)
 582                                      (funcall ,value)))
 583                             `(setf (clos-slots-ref .slots. ,i)
 584                                    (funcall ,value))))
 585                        (initform
 586                         (if before-method-p
 587                             `(when (eq (clos-slots-ref .slots. ,i)
 588                                        +slot-unbound+)
 589                                (setf (clos-slots-ref .slots. ,i)
 590                                      ',(eval value)))
 591                             `(setf (clos-slots-ref .slots. ,i)
 592                                    ',(eval value))))
 593                        (constant
 594                         `(setf (clos-slots-ref .slots. ,i) ',(eval value)))))))
 595         ;; we are not allowed to modify QUOTEd locations, so we can't
 596         ;; generate code like (setf (cdr ',location) arg).  Instead,
 597         ;; we have to do (setf (cdr .L0.) arg) and arrange for .L0. to
 598         ;; be bound to the location.
 599         (multiple-value-bind (names locations class-init-forms)
 600             (loop for (location type value) in class-inits
 601                   for i upfrom 0
 602                   for name = (location-var-name i)
 603                   collect name into names
 604                   collect location into locations
 605                   collect `(setf (cdr ,name)
 606                                  ,(case type
 607                                     (constant `',(eval value))
 608                                     ((param var) `,value)
 609                                     (initfn `(funcall ,value))))
 610                   into class-init-forms
 611                   finally (return (values names locations class-init-forms)))
 612           (multiple-value-bind (vars bindings)
 613               (loop for (var . initfn) in (nreverse default-inits)
 614                     collect var into vars
 615                     collect `(,var (funcall ,initfn)) into bindings
 616                     finally (return (values vars bindings)))
 617             (values locations names
 618                     bindings vars
 619                     (nreverse defaulting-initargs)
 620                     `(,@(delete nil instance-init-forms)
 621                       ,@class-init-forms))))))))
 622
 623 ;;; Return an alist of lists (KEY LOCATION ...) telling, for each
 624 ;;; key in INITKEYS, which locations the initarg initializes.
 625 ;;; CLASS is the class of the instance being initialized.
 626 (defun compute-initarg-locations (class initkeys)
 627   (loop with slots = (class-slots class)
 628         for key in initkeys collect
 629           (loop for slot in slots
 630                 if (memq key (slot-definition-initargs slot))
 631                   collect (slot-definition-location slot) into locations
 632                 else
 633                   collect slot into remaining-slots
 634                 finally
 635                   (setq slots remaining-slots)
 636                   (return (cons key locations)))))
 637
 638 \f
 639 ;;; *******************************
 640 ;;; External Entry Points  ********
 641 ;;; *******************************
 642
 643 (defun update-ctors (reason &key class name generic-function method)
 644   (labels ((reset (class &optional ri-cache-p (ctorsp t))
 645              (when ctorsp
 646                (dolist (ctor (plist-value class 'ctors))
 647                  (install-initial-constructor ctor)))
 648              (when ri-cache-p
 649                (setf (plist-value class 'ri-initargs) ()))
 650              (dolist (subclass (class-direct-subclasses class))
 651                (reset subclass ri-cache-p ctorsp))))
 652     (ecase reason
 653       ;; CLASS must have been specified.
 654       (finalize-inheritance
 655        (reset class t))
 656       ;; NAME must have been specified.
 657       (setf-find-class
 658        (loop for ctor in *all-ctors*
 659              when (eq (ctor-class-name ctor) name) do
 660              (when (ctor-class ctor)
 661                (reset (ctor-class ctor)))
 662              (loop-finish)))
 663       ;; GENERIC-FUNCTION and METHOD must have been specified.
 664       ((add-method remove-method)
 665        (flet ((class-of-1st-method-param (method)
 666                 (type-class (first (method-specializers method)))))
 667          (case (generic-function-name generic-function)
 668            ((make-instance allocate-instance
 669              initialize-instance shared-initialize)
 670             (reset (class-of-1st-method-param method) t t))
 671            ((reinitialize-instance)
 672             (reset (class-of-1st-method-param method) t nil))
 673            (t (when (or (eq (generic-function-name generic-function)
 674                             'slot-boundp-using-class)
 675                         (equal (generic-function-name generic-function)
 676                                '(setf slot-value-using-class)))
 677                 ;; this looks awfully expensive, but given that one
 678                 ;; can specialize on the SLOTD argument, nothing is
 679                 ;; safe.  -- CSR, 2004-07-12
 680                 (reset (find-class 'standard-object))))))))))
 681
 682 (defun precompile-ctors ()
 683   (dolist (ctor *all-ctors*)
 684     (when (null (ctor-class ctor))
 685       (let ((class (find-class (ctor-class-name ctor) nil)))
 686         (when (and class (class-finalized-p class))
 687           (install-optimized-constructor ctor))))))
 688
 689 (defun check-ri-initargs (instance initargs)
 690   (let* ((class (class-of instance))
 691          (keys (plist-keys initargs))
 692          (cached (assoc keys (plist-value class 'ri-initargs)
 693                         :test #'equal))
 694          (invalid-keys
 695           (if (consp cached)
 696               (cdr cached)
 697               (let ((invalid
 698                      ;; FIXME: give CHECK-INITARGS-1 and friends a
 699                      ;; more mnemonic name and (possibly) a nicer,
 700                      ;; more orthogonal interface.
 701                      (check-initargs-1
 702                       class initargs
 703                       (list (list* 'reinitialize-instance instance initargs)
 704                             (list* 'shared-initialize instance nil initargs))
 705                       t nil)))
 706                 (setf (plist-value class 'ri-initargs)
 707                       (acons keys invalid cached))
 708                 invalid))))
 709     (when invalid-keys
 710       (error 'initarg-error :class class :initargs invalid-keys))))
 711
 712 ;;; end of ctor.lisp