src/pcl/ctor.lisp

   1 ;;;; This file contains the optimization machinery for make-instance.
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5
   6 ;;;; This software is derived from software originally released by
   7 ;;;; Gerd Moellmann.  Copyright and release statements follow.  Later
   8 ;;;; modifications to the software are in the public domain and are
   9 ;;;; provided with absolutely no warranty.  See the COPYING and
  10 ;;;; CREDITS files for more information.
  11
  12 ;;; Copyright (C) 2002 Gerd Moellmann <gerd.moellmann@t-online.de>
  13 ;;; All rights reserved.
  14 ;;;
  15 ;;; Redistribution and use in source and binary forms, with or without
  16 ;;; modification, are permitted provided that the following conditions
  17 ;;; are met:
  18 ;;;
  19 ;;; 1. Redistributions of source code must retain the above copyright
  20 ;;;    notice, this list of conditions and the following disclaimer.
  21 ;;; 2. Redistributions in binary form must reproduce the above copyright
  22 ;;;    notice, this list of conditions and the following disclaimer in the
  23 ;;;    documentation and/or other materials provided with the distribution.
  24 ;;; 3. The name of the author may not be used to endorse or promote
  25 ;;;    products derived from this software without specific prior written
  26 ;;;    permission.
  27 ;;;
  28 ;;; THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS
  29 ;;; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  30 ;;; WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  31 ;;; ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE
  32 ;;; LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  33 ;;; CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT
  34 ;;; OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR
  35 ;;; BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
  36 ;;; LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  37 ;;; (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE
  38 ;;; USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH
  39 ;;; DAMAGE.
  40
  41 ;;; ***************
  42 ;;; Overview  *****
  43 ;;; ***************
  44 ;;;
  45 ;;; Compiler macro for MAKE-INSTANCE, and load-time generation of
  46 ;;; optimized instance constructor functions.
  47 ;;;
  48 ;;; ********************
  49 ;;; Entry Points  ******
  50 ;;; ********************
  51 ;;;
  52 ;;; UPDATE-CTORS must be called when methods are added/removed,
  53 ;;; classes are changed, etc., which affect instance creation.
  54 ;;;
  55 ;;; PRECOMPILE-CTORS can be called to precompile constructor functions
  56 ;;; for classes whose definitions are known at the time the function
  57 ;;; is called.
  58
  59 (in-package "SB-PCL")
  60
  61 ;;; ******************
  62 ;;; Utilities  *******
  63 ;;; ******************
  64
  65 (defun quote-plist-keys (plist)
  66   (loop for (key . more) on plist by #'cddr
  67         if (null more) do
  68           (error "Not a property list: ~S" plist)
  69         else
  70           collect `(quote ,key)
  71           and collect (car more)))
  72
  73 (defun plist-keys (plist &key test)
  74   (loop for (key . more) on plist by #'cddr
  75         if (null more) do
  76           (error "Not a property list: ~S" plist)
  77         else if (or (null test) (funcall test key))
  78           collect key))
  79
  80 (defun plist-values (plist &key test)
  81   (loop for (key . more) on plist by #'cddr
  82         if (null more) do
  83           (error "Not a property list: ~S" plist)
  84         else if (or (null test) (funcall test (car more)))
  85           collect (car more)))
  86
  87 (defun constant-symbol-p (form)
  88   (and (constantp form)
  89        (let ((constant (constant-form-value form)))
  90          (and (symbolp constant)
  91               (not (null (symbol-package constant)))))))
  92
  93 ;;; somewhat akin to DEFAULT-INITARGS (SLOT-CLASS T T), but just
  94 ;;; collecting the defaulted initargs for the call.
  95 (defun ctor-default-initkeys (supplied-initargs class-default-initargs)
  96   (loop for (key) in class-default-initargs
  97         when (eq (getf supplied-initargs key '.not-there.) '.not-there.)
  98         collect key))
  99 \f
 100 ;;; *****************
 101 ;;; CTORS   *********
 102 ;;; *****************
 103 ;;;
 104 ;;; Ctors are funcallable instances whose initial function is a
 105 ;;; function computing an optimized constructor function when called.
 106 ;;; When the optimized function is computed, the function of the
 107 ;;; funcallable instance is set to it.
 108 ;;;
 109 (!defstruct-with-alternate-metaclass ctor
 110   :slot-names (function-name class-name class initargs safe-p)
 111   :boa-constructor %make-ctor
 112   :superclass-name function
 113   :metaclass-name static-classoid
 114   :metaclass-constructor make-static-classoid
 115   :dd-type funcallable-structure
 116   :runtime-type-checks-p nil)
 117
 118 ;;; List of all defined ctors.
 119
 120 (defvar *all-ctors* ())
 121
 122 (defun make-ctor-parameter-list (ctor)
 123   (plist-values (ctor-initargs ctor) :test (complement #'constantp)))
 124
 125 ;;; Reset CTOR to use a default function that will compute an
 126 ;;; optimized constructor function when called.
 127 (defun install-initial-constructor (ctor &key force-p)
 128   (when (or force-p (ctor-class ctor))
 129     (setf (ctor-class ctor) nil)
 130     (setf (funcallable-instance-fun ctor)
 131           #'(lambda (&rest args)
 132               (install-optimized-constructor ctor)
 133               (apply ctor args)))
 134     (setf (%funcallable-instance-info ctor 1)
 135           (ctor-function-name ctor))))
 136
 137 (defun make-ctor-function-name (class-name initargs safe-code-p)
 138   (list* 'ctor class-name safe-code-p initargs))
 139
 140 ;;; Keep this a separate function for testing.
 141 (defun ensure-ctor (function-name class-name initargs safe-code-p)
 142   (unless (fboundp function-name)
 143     (make-ctor function-name class-name initargs safe-code-p)))
 144
 145 ;;; Keep this a separate function for testing.
 146 (defun make-ctor (function-name class-name initargs safe-p)
 147   (without-package-locks ; for (setf symbol-function)
 148    (let ((ctor (%make-ctor function-name class-name nil initargs safe-p)))
 149      (push ctor *all-ctors*)
 150      (setf (fdefinition function-name) ctor)
 151      (install-initial-constructor ctor :force-p t)
 152      ctor)))
 153
 154 \f
 155 ;;; ***********************************************
 156 ;;; Compile-Time Expansion of MAKE-INSTANCE *******
 157 ;;; ***********************************************
 158
 159 (define-compiler-macro make-instance (&whole form &rest args &environment env)
 160   (declare (ignore args))
 161   (or (make-instance->constructor-call form (safe-code-p env))
 162       form))
 163
 164 (defun make-instance->constructor-call (form safe-code-p)
 165   (destructuring-bind (fn class-name &rest args) form
 166     (declare (ignore fn))
 167     (flet (;;
 168            ;; Return the name of parameter number I of a constructor
 169            ;; function.
 170            (parameter-name (i)
 171              (let ((ps #(.p0. .p1. .p2. .p3. .p4. .p5.)))
 172                (if (array-in-bounds-p ps i)
 173                    (aref ps i)
 174                    (format-symbol *pcl-package* ".P~D." i))))
 175            ;; Check if CLASS-NAME is a constant symbol.  Give up if
 176            ;; not.
 177            (check-class ()
 178              (unless (and class-name (constant-symbol-p class-name))
 179                (return-from make-instance->constructor-call nil)))
 180            ;; Check if ARGS are suitable for an optimized constructor.
 181            ;; Return NIL from the outer function if not.
 182            (check-args ()
 183              (loop for (key . more) on args by #'cddr do
 184                      (when (or (null more)
 185                                (not (constant-symbol-p key))
 186                                (eq :allow-other-keys (constant-form-value key)))
 187                        (return-from make-instance->constructor-call nil)))))
 188       (check-class)
 189       (check-args)
 190       ;; Collect a plist of initargs and constant values/parameter names
 191       ;; in INITARGS.  Collect non-constant initialization forms in
 192       ;; VALUE-FORMS.
 193       (multiple-value-bind (initargs value-forms)
 194           (loop for (key value) on args by #'cddr and i from 0
 195                 collect (constant-form-value key) into initargs
 196                 if (constantp value)
 197                   collect value into initargs
 198                 else
 199                   collect (parameter-name i) into initargs
 200                   and collect value into value-forms
 201                 finally
 202                   (return (values initargs value-forms)))
 203         (let* ((class-name (constant-form-value class-name))
 204                (function-name (make-ctor-function-name class-name initargs
 205                                                        safe-code-p)))
 206           ;; Prevent compiler warnings for calling the ctor.
 207           (proclaim-as-fun-name function-name)
 208           (note-name-defined function-name :function)
 209           (when (eq (info :function :where-from function-name) :assumed)
 210             (setf (info :function :where-from function-name) :defined)
 211             (when (info :function :assumed-type function-name)
 212               (setf (info :function :assumed-type function-name) nil)))
 213           ;; Return code constructing a ctor at load time, which, when
 214           ;; called, will set its funcallable instance function to an
 215           ;; optimized constructor function.
 216           `(locally
 217                (declare (disable-package-locks ,function-name))
 218             (let ((.x. (load-time-value
 219                         (ensure-ctor ',function-name ',class-name ',initargs
 220                                      ',safe-code-p))))
 221               (declare (ignore .x.))
 222               ;; ??? check if this is worth it.
 223               (declare
 224                (ftype (or (function ,(make-list (length value-forms)
 225                                                 :initial-element t)
 226                                     t)
 227                           (function (&rest t) t))
 228                       ,function-name))
 229               (funcall (function ,function-name) ,@value-forms))))))))
 230
 231 \f
 232 ;;; **************************************************
 233 ;;; Load-Time Constructor Function Generation  *******
 234 ;;; **************************************************
 235
 236 ;;; The system-supplied primary INITIALIZE-INSTANCE and
 237 ;;; SHARED-INITIALIZE methods.  One cannot initialize these variables
 238 ;;; to the right values here because said functions don't exist yet
 239 ;;; when this file is first loaded.
 240 (defvar *the-system-ii-method* nil)
 241 (defvar *the-system-si-method* nil)
 242
 243 (defun install-optimized-constructor (ctor)
 244   (let ((class (find-class (ctor-class-name ctor))))
 245     (unless (class-finalized-p class)
 246       (finalize-inheritance class))
 247     ;; We can have a class with an invalid layout here.  Such a class
 248     ;; cannot have a LAYOUT-INVALID of (:FLUSH ...) or (:OBSOLETE
 249     ;; ...), because part of the deal is that those only happen from
 250     ;; FORCE-CACHE-FLUSHES, which create a new valid wrapper for the
 251     ;; class.  An invalid layout of T needs to be flushed, however.
 252     (when (eq (layout-invalid (class-wrapper class)) t)
 253       (force-cache-flushes class))
 254     (setf (ctor-class ctor) class)
 255     (pushnew ctor (plist-value class 'ctors) :test #'eq)
 256     (setf (funcallable-instance-fun ctor)
 257           (multiple-value-bind (form locations names)
 258               (constructor-function-form ctor)
 259             (apply (compile nil `(lambda ,names ,form)) locations)))))
 260
 261 (defun constructor-function-form (ctor)
 262   (let* ((class (ctor-class ctor))
 263          (proto (class-prototype class))
 264          (make-instance-methods
 265           (compute-applicable-methods #'make-instance (list class)))
 266          (allocate-instance-methods
 267           (compute-applicable-methods #'allocate-instance (list class)))
 268          ;; I stared at this in confusion for a while, thinking
 269          ;; carefully about the possibility of the class prototype not
 270          ;; being of sufficient discrimiating power, given the
 271          ;; possibility of EQL-specialized methods on
 272          ;; INITIALIZE-INSTANCE or SHARED-INITIALIZE.  However, given
 273          ;; that this is a constructor optimization, the user doesn't
 274          ;; yet have the instance to create a method with such an EQL
 275          ;; specializer.
 276          ;;
 277          ;; There remains the (theoretical) possibility of someone
 278          ;; coming along with code of the form
 279          ;;
 280          ;; (defmethod initialize-instance :before ((o foo) ...)
 281          ;;   (eval `(defmethod shared-initialize :before ((o foo) ...) ...)))
 282          ;;
 283          ;; but probably we can afford not to worry about this too
 284          ;; much for now.  -- CSR, 2004-07-12
 285          (ii-methods
 286           (compute-applicable-methods #'initialize-instance (list proto)))
 287          (si-methods
 288           (compute-applicable-methods #'shared-initialize (list proto t)))
 289          (setf-svuc-slots-methods
 290           (loop for slot in (class-slots class)
 291                 collect (compute-applicable-methods
 292                          #'(setf slot-value-using-class)
 293                          (list nil class proto slot))))
 294          (sbuc-slots-methods
 295           (loop for slot in (class-slots class)
 296                 collect (compute-applicable-methods
 297                          #'slot-boundp-using-class
 298                          (list class proto slot)))))
 299     ;; Cannot initialize these variables earlier because the generic
 300     ;; functions don't exist when PCL is built.
 301     (when (null *the-system-si-method*)
 302       (setq *the-system-si-method*
 303             (find-method #'shared-initialize
 304                          () (list *the-class-slot-object* *the-class-t*)))
 305       (setq *the-system-ii-method*
 306             (find-method #'initialize-instance
 307                          () (list *the-class-slot-object*))))
 308     ;; Note that when there are user-defined applicable methods on
 309     ;; MAKE-INSTANCE and/or ALLOCATE-INSTANCE, these will show up
 310     ;; together with the system-defined ones in what
 311     ;; COMPUTE-APPLICABLE-METHODS returns.
 312     (if (and (not (structure-class-p class))
 313              (not (condition-class-p class))
 314              (null (cdr make-instance-methods))
 315              (null (cdr allocate-instance-methods))
 316              (every (lambda (x)
 317                       (member (slot-definition-allocation x)
 318                               '(:instance :class)))
 319                     (class-slots class))
 320              (null (check-initargs-1
 321                     class
 322                     (append
 323                      (ctor-default-initkeys
 324                       (ctor-initargs ctor) (class-default-initargs class))
 325                      (plist-keys (ctor-initargs ctor)))
 326                     (append ii-methods si-methods) nil nil))
 327              (not (around-or-nonstandard-primary-method-p
 328                    ii-methods *the-system-ii-method*))
 329              (not (around-or-nonstandard-primary-method-p
 330                    si-methods *the-system-si-method*))
 331              ;; the instance structure protocol goes through
 332              ;; slot-value(-using-class) and friends (actually just
 333              ;; (SETF SLOT-VALUE-USING-CLASS) and
 334              ;; SLOT-BOUNDP-USING-CLASS), so if there are non-standard
 335              ;; applicable methods we can't shortcircuit them.
 336              (every (lambda (x) (= (length x) 1)) setf-svuc-slots-methods)
 337              (every (lambda (x) (= (length x) 1)) sbuc-slots-methods))
 338         (optimizing-generator ctor ii-methods si-methods)
 339         (fallback-generator ctor ii-methods si-methods))))
 340
 341 (defun around-or-nonstandard-primary-method-p
 342     (methods &optional standard-method)
 343   (loop with primary-checked-p = nil
 344         for method in methods
 345         as qualifiers = (method-qualifiers method)
 346         when (or (eq :around (car qualifiers))
 347                  (and (null qualifiers)
 348                       (not primary-checked-p)
 349                       (not (null standard-method))
 350                       (not (eq standard-method method))))
 351           return t
 352         when (null qualifiers) do
 353           (setq primary-checked-p t)))
 354
 355 (defun fallback-generator (ctor ii-methods si-methods)
 356   (declare (ignore ii-methods si-methods))
 357   `(lambda ,(make-ctor-parameter-list ctor)
 358      ;; The CTOR MAKE-INSTANCE optimization only kicks in when the
 359      ;; first argument to MAKE-INSTANCE is a constant symbol: by
 360      ;; calling it with a class, as here, we inhibit the optimization,
 361      ;; so removing the possibility of endless recursion.  -- CSR,
 362      ;; 2004-07-12
 363      (make-instance ,(ctor-class ctor)
 364       ,@(quote-plist-keys (ctor-initargs ctor)))))
 365
 366 (defun optimizing-generator (ctor ii-methods si-methods)
 367   (multiple-value-bind (locations names body before-method-p)
 368       (fake-initialization-emf ctor ii-methods si-methods)
 369     (let ((wrapper (class-wrapper (ctor-class ctor))))
 370       (values
 371        `(lambda ,(make-ctor-parameter-list ctor)
 372          (declare #.*optimize-speed*)
 373          (block nil
 374            (when (layout-invalid ,wrapper)
 375              (install-initial-constructor ,ctor)
 376              (return (funcall ,ctor ,@(make-ctor-parameter-list ctor))))
 377            ,(wrap-in-allocate-forms ctor body before-method-p)))
 378        locations
 379        names))))
 380
 381 ;;; Return a form wrapped around BODY that allocates an instance
 382 ;;; constructed by CTOR.  BEFORE-METHOD-P set means we have to run
 383 ;;; before-methods, in which case we initialize instance slots to
 384 ;;; +SLOT-UNBOUND+.  The resulting form binds the local variables
 385 ;;; .INSTANCE. to the instance, and .SLOTS. to the instance's slot
 386 ;;; vector around BODY.
 387 (defun wrap-in-allocate-forms (ctor body before-method-p)
 388   (let* ((class (ctor-class ctor))
 389          (wrapper (class-wrapper class))
 390          (allocation-function (raw-instance-allocator class))
 391          (slots-fetcher (slots-fetcher class)))
 392     (if (eq allocation-function 'allocate-standard-instance)
 393         `(let ((.instance. (%make-standard-instance nil
 394                                                     (get-instance-hash-code)))
 395                (.slots. (make-array
 396                          ,(layout-length wrapper)
 397                          ,@(when before-method-p
 398                              '(:initial-element +slot-unbound+)))))
 399            (setf (std-instance-wrapper .instance.) ,wrapper)
 400            (setf (std-instance-slots .instance.) .slots.)
 401            ,body
 402            .instance.)
 403         `(let* ((.instance. (,allocation-function ,wrapper))
 404                 (.slots. (,slots-fetcher .instance.)))
 405            (declare (ignorable .slots.))
 406            ,body
 407            .instance.))))
 408
 409 ;;; Return a form for invoking METHOD with arguments from ARGS.  As
 410 ;;; can be seen in METHOD-FUNCTION-FROM-FAST-FUNCTION, method
 411 ;;; functions look like (LAMBDA (ARGS NEXT-METHODS) ...).  We could
 412 ;;; call fast method functions directly here, but benchmarks show that
 413 ;;; there's no speed to gain, so lets avoid the hair here.
 414 (defmacro invoke-method (method args)
 415   `(funcall ,(method-function method) ,args ()))
 416
 417 ;;; Return a form that is sort of an effective method comprising all
 418 ;;; calls to INITIALIZE-INSTANCE and SHARED-INITIALIZE that would
 419 ;;; normally have taken place when calling MAKE-INSTANCE.
 420 (defun fake-initialization-emf (ctor ii-methods si-methods)
 421   (multiple-value-bind (ii-around ii-before ii-primary ii-after)
 422       (standard-sort-methods ii-methods)
 423     (declare (ignore ii-primary))
 424     (multiple-value-bind (si-around si-before si-primary si-after)
 425         (standard-sort-methods si-methods)
 426       (declare (ignore si-primary))
 427       (aver (and (null ii-around) (null si-around)))
 428       (let ((initargs (ctor-initargs ctor)))
 429         (multiple-value-bind (locations names bindings vars defaulting-initargs body)
 430             (slot-init-forms ctor (or ii-before si-before))
 431         (values
 432          locations
 433          names
 434          `(let ,bindings
 435            (declare (ignorable ,@vars))
 436            (let (,@(when (or ii-before ii-after)
 437                      `((.ii-args.
 438                         (list .instance. ,@(quote-plist-keys initargs) ,@defaulting-initargs))))
 439                  ,@(when (or si-before si-after)
 440                      `((.si-args.
 441                         (list .instance. t ,@(quote-plist-keys initargs) ,@defaulting-initargs)))))
 442             ,@(loop for method in ii-before
 443                     collect `(invoke-method ,method .ii-args.))
 444             ,@(loop for method in si-before
 445                     collect `(invoke-method ,method .si-args.))
 446             ,@body
 447             ,@(loop for method in si-after
 448                     collect `(invoke-method ,method .si-args.))
 449             ,@(loop for method in ii-after
 450                     collect `(invoke-method ,method .ii-args.))))
 451          (or ii-before si-before)))))))
 452
 453 ;;; Return four values from APPLICABLE-METHODS: around methods, before
 454 ;;; methods, the applicable primary method, and applicable after
 455 ;;; methods.  Before and after methods are sorted in the order they
 456 ;;; must be called.
 457 (defun standard-sort-methods (applicable-methods)
 458   (loop for method in applicable-methods
 459         as qualifiers = (method-qualifiers method)
 460         if (null qualifiers)
 461           collect method into primary
 462         else if (eq :around (car qualifiers))
 463           collect method into around
 464         else if (eq :after (car qualifiers))
 465           collect method into after
 466         else if (eq :before (car qualifiers))
 467           collect method into before
 468         finally
 469           (return (values around before (first primary) (reverse after)))))
 470
 471 (defmacro with-type-checked ((type safe-p) &body body)
 472   (if safe-p
 473       ;; To handle FUNCTION types reasonable, we use SAFETY 3 and
 474       ;; THE instead of e.g. CHECK-TYPE.
 475       `(locally
 476            (declare (optimize (safety 3)))
 477          (the ,type (progn ,@body)))
 478       `(progn ,@body)))
 479
 480 ;;; Return as multiple values bindings for default initialization
 481 ;;; arguments, variable names, defaulting initargs and a body for
 482 ;;; initializing instance and class slots of an object costructed by
 483 ;;; CTOR.  The variable .SLOTS. is assumed to bound to the instance's
 484 ;;; slot vector.  BEFORE-METHOD-P T means before-methods will be
 485 ;;; called, which means that 1) other code will initialize instance
 486 ;;; slots to +SLOT-UNBOUND+ before the before-methods are run, and
 487 ;;; that we have to check if these before-methods have set slots.
 488 (defun slot-init-forms (ctor before-method-p)
 489   (let* ((class (ctor-class ctor))
 490          (initargs (ctor-initargs ctor))
 491          (initkeys (plist-keys initargs))
 492          (safe-p (ctor-safe-p ctor))
 493          (slot-vector
 494           (make-array (layout-length (class-wrapper class))
 495                       :initial-element nil))
 496          (class-inits ())
 497          (default-inits ())
 498          (defaulting-initargs ())
 499          (default-initargs (class-default-initargs class))
 500          (initarg-locations
 501           (compute-initarg-locations
 502            class (append initkeys (mapcar #'car default-initargs)))))
 503     (labels ((initarg-locations (initarg)
 504                (cdr (assoc initarg initarg-locations :test #'eq)))
 505              (initializedp (location)
 506                (cond
 507                  ((consp location)
 508                   (assoc location class-inits :test #'eq))
 509                  ((integerp location)
 510                   (not (null (aref slot-vector location))))
 511                  (t (bug "Weird location in ~S" 'slot-init-forms))))
 512              (class-init (location kind val type)
 513                (aver (consp location))
 514                (unless (initializedp location)
 515                  (push (list location kind val type) class-inits)))
 516              (instance-init (location kind val type)
 517                (aver (integerp location))
 518                (unless (initializedp location)
 519                  (setf (aref slot-vector location) (list kind val type))))
 520              (default-init-var-name (i)
 521                (let ((ps #(.d0. .d1. .d2. .d3. .d4. .d5.)))
 522                  (if (array-in-bounds-p ps i)
 523                      (aref ps i)
 524                      (format-symbol *pcl-package* ".D~D." i))))
 525              (location-var-name (i)
 526                (let ((ls #(.l0. .l1. .l2. .l3. .l4. .l5.)))
 527                  (if (array-in-bounds-p ls i)
 528                      (aref ls i)
 529                      (format-symbol *pcl-package* ".L~D." i)))))
 530       ;; Loop over supplied initargs and values and record which
 531       ;; instance and class slots they initialize.
 532       (loop for (key value) on initargs by #'cddr
 533             as kind = (if (constantp value) 'constant 'param)
 534             as locations = (initarg-locations key)
 535             do (loop for (location . type) in locations
 536                      do (if (consp location)
 537                             (class-init location kind value type)
 538                             (instance-init location kind value type))))
 539       ;; Loop over default initargs of the class, recording
 540       ;; initializations of slots that have not been initialized
 541       ;; above.  Default initargs which are not in the supplied
 542       ;; initargs are treated as if they were appended to supplied
 543       ;; initargs, that is, their values must be evaluated even
 544       ;; if not actually used for initializing a slot.
 545       (loop for (key initform initfn) in default-initargs and i from 0
 546             unless (member key initkeys :test #'eq)
 547             do (let* ((kind (if (constantp initform) 'constant 'var))
 548                       (init (if (eq kind 'var) initfn initform)))
 549                  (ecase kind
 550                    (constant
 551                     (push (list 'quote key) defaulting-initargs)
 552                     (push initform defaulting-initargs))
 553                    (var
 554                     (push (list 'quote key) defaulting-initargs)
 555                     (push (default-init-var-name i) defaulting-initargs)))
 556               (when (eq kind 'var)
 557                 (let ((init-var (default-init-var-name i)))
 558                   (setq init init-var)
 559                   (push (cons init-var initfn) default-inits)))
 560               (loop for (location . type) in (initarg-locations key)
 561                     do (if (consp location)
 562                            (class-init location kind init type)
 563                            (instance-init location kind init type)))))
 564       ;; Loop over all slots of the class, filling in the rest from
 565       ;; slot initforms.
 566       (loop for slotd in (class-slots class)
 567             as location = (slot-definition-location slotd)
 568             as type = (slot-definition-type slotd)
 569             as allocation = (slot-definition-allocation slotd)
 570             as initfn = (slot-definition-initfunction slotd)
 571             as initform = (slot-definition-initform slotd) do
 572               (unless (or (eq allocation :class)
 573                           (null initfn)
 574                           (initializedp location))
 575                 (if (constantp initform)
 576                     (instance-init location 'initform initform type)
 577                     (instance-init location 'initform/initfn initfn type))))
 578       ;; Generate the forms for initializing instance and class slots.
 579       (let ((instance-init-forms
 580              (loop for slot-entry across slot-vector and i from 0
 581                    as (kind value type) = slot-entry collect
 582                      (ecase kind
 583                        ((nil)
 584                         (unless before-method-p
 585                           `(setf (clos-slots-ref .slots. ,i) +slot-unbound+)))
 586                        ((param var)
 587                         `(setf (clos-slots-ref .slots. ,i)
 588                                (with-type-checked (,type ,safe-p)
 589                                    ,value)))
 590                        (initfn
 591                         `(setf (clos-slots-ref .slots. ,i)
 592                                (with-type-checked (,type ,safe-p)
 593                                  (funcall ,value))))
 594                        (initform/initfn
 595                         (if before-method-p
 596                             `(when (eq (clos-slots-ref .slots. ,i)
 597                                        +slot-unbound+)
 598                                (setf (clos-slots-ref .slots. ,i)
 599                                      (with-type-checked (,type ,safe-p)
 600                                        (funcall ,value))))
 601                             `(setf (clos-slots-ref .slots. ,i)
 602                                    (with-type-checked (,type ,safe-p)
 603                                      (funcall ,value)))))
 604                        (initform
 605                         (if before-method-p
 606                             `(when (eq (clos-slots-ref .slots. ,i)
 607                                        +slot-unbound+)
 608                                (setf (clos-slots-ref .slots. ,i)
 609                                      (with-type-checked (,type ,safe-p)
 610                                        ',(constant-form-value value))))
 611                             `(setf (clos-slots-ref .slots. ,i)
 612                                    (with-type-checked (,type ,safe-p)
 613                                      ',(constant-form-value value)))))
 614                        (constant
 615                         `(setf (clos-slots-ref .slots. ,i)
 616                                (with-type-checked (,type ,safe-p)
 617                                  ',(constant-form-value value))))))))
 618         ;; we are not allowed to modify QUOTEd locations, so we can't
 619         ;; generate code like (setf (cdr ',location) arg).  Instead,
 620         ;; we have to do (setf (cdr .L0.) arg) and arrange for .L0. to
 621         ;; be bound to the location.
 622         (multiple-value-bind (names locations class-init-forms)
 623             (loop for (location kind value type) in class-inits
 624                   for i upfrom 0
 625                   for name = (location-var-name i)
 626                   collect name into names
 627                   collect location into locations
 628                   collect `(setf (cdr ,name)
 629                                  (with-type-checked (,type ,safe-p)
 630                                    ,(case kind
 631                                           (constant `',(constant-form-value value))
 632                                           ((param var) `,value)
 633                                           (initfn `(funcall ,value)))))
 634                   into class-init-forms
 635                   finally (return (values names locations class-init-forms)))
 636           (multiple-value-bind (vars bindings)
 637               (loop for (var . initfn) in (nreverse default-inits)
 638                     collect var into vars
 639                     collect `(,var (funcall ,initfn)) into bindings
 640                     finally (return (values vars bindings)))
 641             (values locations names
 642                     bindings vars
 643                     (nreverse defaulting-initargs)
 644                     `(,@(delete nil instance-init-forms)
 645                       ,@class-init-forms))))))))
 646
 647 ;;; Return an alist of lists (KEY (LOCATION . TYPE-SPECIFIER) ...)
 648 ;;; telling, for each key in INITKEYS, which locations the initarg
 649 ;;; initializes and the associated type with the location.  CLASS is
 650 ;;; the class of the instance being initialized.
 651 (defun compute-initarg-locations (class initkeys)
 652   (loop with slots = (class-slots class)
 653         for key in initkeys collect
 654           (loop for slot in slots
 655                 if (memq key (slot-definition-initargs slot))
 656                   collect (cons (slot-definition-location slot)
 657                                 (slot-definition-type slot))
 658                           into locations
 659                 else
 660                   collect slot into remaining-slots
 661                 finally
 662                   (setq slots remaining-slots)
 663                   (return (cons key locations)))))
 664
 665 \f
 666 ;;; *******************************
 667 ;;; External Entry Points  ********
 668 ;;; *******************************
 669
 670 (defun update-ctors (reason &key class name generic-function method)
 671   (labels ((reset (class &optional ri-cache-p (ctorsp t))
 672              (when ctorsp
 673                (dolist (ctor (plist-value class 'ctors))
 674                  (install-initial-constructor ctor)))
 675              (when ri-cache-p
 676                (setf (plist-value class 'ri-initargs) ()))
 677              (dolist (subclass (class-direct-subclasses class))
 678                (reset subclass ri-cache-p ctorsp))))
 679     (ecase reason
 680       ;; CLASS must have been specified.
 681       (finalize-inheritance
 682        (reset class t))
 683       ;; NAME must have been specified.
 684       (setf-find-class
 685        (loop for ctor in *all-ctors*
 686              when (eq (ctor-class-name ctor) name) do
 687              (when (ctor-class ctor)
 688                (reset (ctor-class ctor)))
 689              (loop-finish)))
 690       ;; GENERIC-FUNCTION and METHOD must have been specified.
 691       ((add-method remove-method)
 692        (flet ((class-of-1st-method-param (method)
 693                 (type-class (first (method-specializers method)))))
 694          (case (generic-function-name generic-function)
 695            ((make-instance allocate-instance
 696              initialize-instance shared-initialize)
 697             (reset (class-of-1st-method-param method) t t))
 698            ((reinitialize-instance)
 699             (reset (class-of-1st-method-param method) t nil))
 700            (t (when (or (eq (generic-function-name generic-function)
 701                             'slot-boundp-using-class)
 702                         (equal (generic-function-name generic-function)
 703                                '(setf slot-value-using-class)))
 704                 ;; this looks awfully expensive, but given that one
 705                 ;; can specialize on the SLOTD argument, nothing is
 706                 ;; safe.  -- CSR, 2004-07-12
 707                 (reset (find-class 'standard-object))))))))))
 708
 709 (defun precompile-ctors ()
 710   (dolist (ctor *all-ctors*)
 711     (when (null (ctor-class ctor))
 712       (let ((class (find-class (ctor-class-name ctor) nil)))
 713         (when (and class (class-finalized-p class))
 714           (install-optimized-constructor ctor))))))
 715
 716 (defun check-ri-initargs (instance initargs)
 717   (let* ((class (class-of instance))
 718          (keys (plist-keys initargs))
 719          (cached (assoc keys (plist-value class 'ri-initargs)
 720                         :test #'equal))
 721          (invalid-keys
 722           (if (consp cached)
 723               (cdr cached)
 724               (let ((invalid
 725                      ;; FIXME: give CHECK-INITARGS-1 and friends a
 726                      ;; more mnemonic name and (possibly) a nicer,
 727                      ;; more orthogonal interface.
 728                      (check-initargs-1
 729                       class initargs
 730                       (list (list* 'reinitialize-instance instance initargs)
 731                             (list* 'shared-initialize instance nil initargs))
 732                       t nil)))
 733                 (setf (plist-value class 'ri-initargs)
 734                       (acons keys invalid cached))
 735                 invalid))))
 736     (when invalid-keys
 737       (error 'initarg-error :class class :initargs invalid-keys))))
 738
 739 ;;; end of ctor.lisp