src/pcl/defclass.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 ;;;; DEFCLASS macro and close personal friends
  27
  28 ;;; state for the current DEFCLASS expansion
  29 (defvar *initfunctions-for-this-defclass*)
  30 (defvar *readers-for-this-defclass*)
  31 (defvar *writers-for-this-defclass*)
  32 (defvar *slot-names-for-this-defclass*)
  33
  34 ;;; Like the DEFMETHOD macro, the expansion of the DEFCLASS macro is
  35 ;;; fixed. DEFCLASS always expands into a call to LOAD-DEFCLASS. Until
  36 ;;; the meta-braid is set up, LOAD-DEFCLASS has a special definition
  37 ;;; which simply collects all class definitions up, when the metabraid
  38 ;;; is initialized it is done from those class definitions.
  39 ;;;
  40 ;;; After the metabraid has been setup, and the protocol for defining
  41 ;;; classes has been defined, the real definition of LOAD-DEFCLASS is
  42 ;;; installed by the file std-class.lisp
  43 (defmacro defclass (&environment env name direct-superclasses direct-slots &rest options)
  44   (let (*initfunctions-for-this-defclass*
  45         *readers-for-this-defclass* ;Truly a crock, but we got
  46         *writers-for-this-defclass* ;to have it to live nicely.
  47         *slot-names-for-this-defclass*)
  48     ;; FIXME: It would be nice to collect all errors from the
  49     ;; expansion of a defclass and signal them in a single go.
  50     (multiple-value-bind (metaclass canonical-options)
  51         (canonize-defclass-options name options)
  52     (let ((canonical-slots (canonize-defclass-slots name direct-slots env))
  53           ;; DEFSTRUCT-P should be true if the class is defined
  54           ;; with a metaclass STRUCTURE-CLASS, so that a DEFSTRUCT
  55           ;; is compiled for the class.
  56           (defstruct-p (and (eq *boot-state* 'complete)
  57                             (let ((mclass (find-class metaclass nil)))
  58                               (and mclass
  59                                    (*subtypep
  60                                     mclass
  61                                     *the-class-structure-class*))))))
  62       (let* ((defclass-form
  63               `(let ,(mapcar #'cdr *initfunctions-for-this-defclass*)
  64                  (load-defclass ',name
  65                                 ',metaclass
  66                                 ',direct-superclasses
  67                                 (list ,@canonical-slots)
  68                                 (list ,@(apply #'append
  69                                                (when defstruct-p
  70                                                  '(:from-defclass-p t))
  71                                                 canonical-options))
  72                                 ',*readers-for-this-defclass*
  73                                 ',*writers-for-this-defclass*
  74                                 ',*slot-names-for-this-defclass*
  75                                 (sb-c:source-location)))))
  76         (if defstruct-p
  77             (progn
  78               ;; FIXME: (YUK!) Why do we do this? Because in order
  79               ;; to make the defstruct form, we need to know what
  80               ;; the accessors for the slots are, so we need already
  81               ;; to have hooked into the CLOS machinery.
  82               ;;
  83               ;; There may be a better way to do this: it would
  84               ;; involve knowing enough about PCL to ask "what will
  85               ;; my slot names and accessors be"; failing this, we
  86               ;; currently just evaluate the whole kaboodle, and
  87               ;; then use CLASS-DIRECT-SLOTS. -- CSR, 2002-06-07
  88               (eval defclass-form)
  89               (let* ((include (or (and direct-superclasses
  90                                        (fix-super (car direct-superclasses)))
  91                                   (and (not (eq name 'structure-object))
  92                                        *the-class-structure-object*)))
  93                      (defstruct-form (make-structure-class-defstruct-form
  94                                       name (class-direct-slots (find-class name))
  95                                       include)))
  96                 `(progn
  97                    (eval-when (:compile-toplevel :load-toplevel :execute)
  98                      ,defstruct-form) ; really compile the defstruct-form
  99                    (eval-when (:compile-toplevel :load-toplevel :execute)
 100                      ,defclass-form))))
 101             `(progn
 102                ;; By telling the type system at compile time about
 103                ;; the existence of a class named NAME, we can avoid
 104                ;; various bogus warnings about "type isn't defined yet"
 105                ;; for code elsewhere in the same file which uses
 106                ;; the name of the type.
 107                ;;
 108                ;; We only need to do this at compile time, because
 109                ;; at load and execute time we write the actual
 110                ;; full-blown class, so the "a class of this name is
 111                ;; coming" note we write here would be irrelevant.
 112                (eval-when (:compile-toplevel)
 113                  (%compiler-defclass ',name
 114                                      ',*readers-for-this-defclass*
 115                                      ',*writers-for-this-defclass*
 116                                      ',*slot-names-for-this-defclass*))
 117                (eval-when (:load-toplevel :execute)
 118                  ,defclass-form))))))))
 119
 120 (defun canonize-defclass-options (class-name options)
 121   (maplist (lambda (sublist)
 122              (let ((option-name (first (pop sublist))))
 123                (when (member option-name sublist :key #'first)
 124                  (error "Multiple ~S options in DEFCLASS ~S."
 125                         option-name class-name))))
 126            options)
 127   (let (metaclass
 128         default-initargs
 129         documentation
 130         canonized-options)
 131       (dolist (option options)
 132         (unless (listp option)
 133           (error "~S is not a legal defclass option." option))
 134         (case (first option)
 135           (:metaclass
 136            (let ((maybe-metaclass (second option)))
 137              (unless (and maybe-metaclass (legal-class-name-p maybe-metaclass))
 138                (error "~@<The value of the :metaclass option (~S) ~
 139                          is not a legal class name.~:@>"
 140                       maybe-metaclass))
 141              (setf metaclass maybe-metaclass)))
 142           (:default-initargs
 143            (let (initargs arg-names)
 144              (doplist (key val) (cdr option)
 145                (when (member key arg-names)
 146                  (error 'simple-program-error
 147                         :format-control "~@<Duplicate initialization argument ~
 148                                            name ~S in :DEFAULT-INITARGS of ~
 149                                            DEFCLASS ~S.~:>"
 150                         :format-arguments (list key class-name)))
 151                (push key arg-names)
 152                (push ``(,',key ,',val ,,(make-initfunction val)) initargs))
 153              (setf default-initargs t)
 154              (push `(:direct-default-initargs (list ,@(nreverse initargs)))
 155                    canonized-options)))
 156           (:documentation
 157            (unless (stringp (second option))
 158              (error "~S is not a legal :documentation value" (second option)))
 159            (setf documentation t)
 160            (push `(:documentation ,(second option)) canonized-options))
 161           (otherwise
 162            (push `(',(car option) ',(cdr option)) canonized-options))))
 163       (values (or metaclass 'standard-class) (nreverse canonized-options))))
 164
 165 (defun canonize-defclass-slots (class-name slots env)
 166   (let (canonized-specs)
 167     (dolist (spec slots)
 168       (when (atom spec)
 169         (setf spec (list spec)))
 170       (when (and (cdr spec) (null (cddr spec)))
 171         (error 'simple-program-error
 172                :format-control "~@<in DEFCLASS ~S, the slot specification ~S ~
 173                                 is invalid; the probable intended meaning may ~
 174                                 be achieved by specifiying ~S instead.~:>"
 175                :format-arguments (list class-name spec
 176                                        `(,(car spec) :initform ,(cadr spec)))))
 177       (let* ((name (car spec))
 178              (plist (cdr spec))
 179              (readers ())
 180              (writers ())
 181              (initargs ())
 182              (others ())
 183              (unsupplied (list nil))
 184              (initform unsupplied))
 185         (check-slot-name-for-defclass name class-name env)
 186         (push name *slot-names-for-this-defclass*)
 187         (flet ((note-reader (x)
 188                  (unless (symbolp x)
 189                    (error 'simple-program-error
 190                           :format-control "Slot reader name ~S for slot ~S in ~
 191                                            DEFCLASS ~S is not a symbol."
 192                           :format-arguments (list x name class-name)))
 193                  (push x readers)
 194                  (push x *readers-for-this-defclass*))
 195                (note-writer (x)
 196                  (push x writers)
 197                  (push x *writers-for-this-defclass*)))
 198           (doplist (key val) plist
 199             (case key
 200               (:accessor (note-reader val) (note-writer `(setf ,val)))
 201               (:reader   (note-reader val))
 202               (:writer   (note-writer val))
 203               (:initarg
 204                (unless (symbolp val)
 205                  (error 'simple-program-error
 206                         :format-control "Slot initarg name ~S for slot ~S in ~
 207                                          DEFCLASS ~S is not a symbol."
 208                         :format-arguments (list val name class-name)))
 209                (push val initargs))
 210               (otherwise
 211                (when (member key '(:initform :allocation :type :documentation))
 212                  (when (eq key :initform)
 213                    (setf initform val))
 214                  (when (get-properties others (list key))
 215                    (error 'simple-program-error
 216                           :format-control "Duplicate slot option ~S for slot ~
 217                                            ~S in DEFCLASS ~S."
 218                           :format-arguments (list key name class-name))))
 219                ;; For non-standard options multiple entries go in a list
 220                (push val (getf others key))))))
 221         ;; Unwrap singleton lists (AMOP 5.4.2)
 222         (do ((head others (cddr head)))
 223             ((null head))
 224           (unless (cdr (second head))
 225             (setf (second head) (car (second head)))))
 226         (let ((canon `(:name ',name :readers ',readers :writers ',writers
 227                              :initargs ',initargs ',others)))
 228           (push (if (eq initform unsupplied)
 229                     `(list* ,@canon)
 230                     `(list* :initfunction ,(make-initfunction initform)
 231                             ,@canon))
 232                 canonized-specs))))
 233     (nreverse canonized-specs)))
 234
 235
 236 (defun check-slot-name-for-defclass (name class-name env)
 237   (flet ((slot-name-illegal (reason)
 238            (error 'simple-program-error
 239                   :format-control
 240                   (format nil "~~@<In DEFCLASS ~~S, the slot name ~~S ~
 241                                is ~A.~~@:>" reason)
 242                   :format-arguments (list class-name name))))
 243     (cond ((not (symbolp name))
 244            (slot-name-illegal "not a symbol"))
 245           ((keywordp name)
 246            (slot-name-illegal "a keyword"))
 247           ((constantp name env)
 248            (slot-name-illegal "a constant"))
 249           ((member name *slot-names-for-this-defclass*)
 250            (error 'simple-program-error
 251                   :format-control "Multiple slots named ~S in DEFCLASS ~S."
 252                   :format-arguments (list name class-name))))))
 253
 254 (defun make-initfunction (initform)
 255   (cond ((or (eq initform t)
 256              (equal initform ''t))
 257          '(function constantly-t))
 258         ((or (eq initform nil)
 259              (equal initform ''nil))
 260          '(function constantly-nil))
 261         ((or (eql initform 0)
 262              (equal initform ''0))
 263          '(function constantly-0))
 264         (t
 265          (let ((entry (assoc initform *initfunctions-for-this-defclass*
 266                              :test #'equal)))
 267            (unless entry
 268              (setq entry (list initform
 269                                (gensym)
 270                                `(function (lambda () ,initform))))
 271              (push entry *initfunctions-for-this-defclass*))
 272            (cadr entry)))))
 273
 274 (defun %compiler-defclass (name readers writers slots)
 275   ;; ANSI says (Macro DEFCLASS, section 7.7) that DEFCLASS, if it
 276   ;; "appears as a top level form, the compiler must make the class
 277   ;; name be recognized as a valid type name in subsequent
 278   ;; declarations (as for deftype) and be recognized as a valid class
 279   ;; name for defmethod parameter specializers and for use as the
 280   ;; :metaclass option of a subsequent defclass."
 281   (preinform-compiler-about-class-type name)
 282   (preinform-compiler-about-accessors readers writers slots))
 283
 284 (defun preinform-compiler-about-class-type (name)
 285   ;; Unless the type system already has an actual type attached to
 286   ;; NAME (in which case (1) writing a placeholder value over that
 287   ;; actual type as a compile-time side-effect would probably be a bad
 288   ;; idea and (2) anyway we don't need to modify it in order to make
 289   ;; NAME be recognized as a valid type name)
 290   (unless (info :type :kind name)
 291     ;; Tell the compiler to expect a class with the given NAME, by
 292     ;; writing a kind of minimal placeholder type information. This
 293     ;; placeholder will be overwritten later when the class is defined.
 294     (setf (info :type :kind name) :forthcoming-defclass-type))
 295   (values))
 296
 297 (defun preinform-compiler-about-accessors (readers writers slots)
 298   (flet ((inform (name type)
 299            ;; FIXME: This matches what PROCLAIM FTYPE does, except
 300            ;; that :WHERE-FROM is :DEFINED, not :DECLARED, and should
 301            ;; probably be factored into a common function -- eg.
 302            ;; (%proclaim-ftype name declared-or-defined).
 303            (when (eq (info :function :where-from name) :assumed)
 304              (proclaim-as-fun-name name)
 305              (note-name-defined name :function)
 306              (setf (info :function :where-from name) :defined
 307                    (info :function :type name) type))))
 308     (let ((rtype (specifier-type '(function (t) t)))
 309           (wtype (specifier-type '(function (t t) t))))
 310       (dolist (reader readers)
 311         (inform reader rtype))
 312       (dolist (writer writers)
 313         (inform writer wtype))
 314       (dolist (slot slots)
 315         (inform (slot-reader-name slot) rtype)
 316         (inform (slot-boundp-name slot) rtype)
 317         (inform (slot-writer-name slot) wtype)))))
 318 \f
 319 ;;; This is the early definition of LOAD-DEFCLASS. It just collects up
 320 ;;; all the class definitions in a list. Later, in braid1.lisp, these
 321 ;;; are actually defined.
 322
 323 ;;; Each entry in *EARLY-CLASS-DEFINITIONS* is an EARLY-CLASS-DEFINITION.
 324 (defparameter *early-class-definitions* ())
 325
 326 (defun early-class-definition (class-name)
 327   (or (find class-name *early-class-definitions* :key #'ecd-class-name)
 328       (error "~S is not a class in *early-class-definitions*." class-name)))
 329
 330 (defun make-early-class-definition
 331        (name source-location metaclass
 332         superclass-names canonical-slots other-initargs)
 333   (list 'early-class-definition
 334         name source-location metaclass
 335         superclass-names canonical-slots other-initargs))
 336
 337 (defun ecd-class-name        (ecd) (nth 1 ecd))
 338 (defun ecd-source-location   (ecd) (nth 2 ecd))
 339 (defun ecd-metaclass         (ecd) (nth 3 ecd))
 340 (defun ecd-superclass-names  (ecd) (nth 4 ecd))
 341 (defun ecd-canonical-slots   (ecd) (nth 5 ecd))
 342 (defun ecd-other-initargs    (ecd) (nth 6 ecd))
 343
 344 (defvar *early-class-slots* nil)
 345
 346 (defun canonical-slot-name (canonical-slot)
 347   (getf canonical-slot :name))
 348
 349 (defun early-class-slots (class-name)
 350   (cdr (or (assoc class-name *early-class-slots*)
 351            (let ((a (cons class-name
 352                           (mapcar #'canonical-slot-name
 353                                   (early-collect-inheritance class-name)))))
 354              (push a *early-class-slots*)
 355              a))))
 356
 357 (defun early-class-size (class-name)
 358   (length (early-class-slots class-name)))
 359
 360 (defun early-collect-inheritance (class-name)
 361   ;;(declare (values slots cpl default-initargs direct-subclasses))
 362   (let ((cpl (early-collect-cpl class-name)))
 363     (values (early-collect-slots cpl)
 364             cpl
 365             (early-collect-default-initargs cpl)
 366             (let (collect)
 367               (dolist (definition *early-class-definitions*)
 368                 (when (memq class-name (ecd-superclass-names definition))
 369                   (push (ecd-class-name definition) collect)))
 370               (nreverse collect)))))
 371
 372 (defun early-collect-slots (cpl)
 373   (let* ((definitions (mapcar #'early-class-definition cpl))
 374          (super-slots (mapcar #'ecd-canonical-slots definitions))
 375          (slots (apply #'append (reverse super-slots))))
 376     (dolist (s1 slots)
 377       (let ((name1 (canonical-slot-name s1)))
 378         (dolist (s2 (cdr (memq s1 slots)))
 379           (when (eq name1 (canonical-slot-name s2))
 380             (error "More than one early class defines a slot with the~%~
 381                     name ~S. This can't work because the bootstrap~%~
 382                     object system doesn't know how to compute effective~%~
 383                     slots."
 384                    name1)))))
 385     slots))
 386
 387 (defun early-collect-cpl (class-name)
 388   (labels ((walk (c)
 389              (let* ((definition (early-class-definition c))
 390                     (supers (ecd-superclass-names definition)))
 391                (cons c
 392                      (apply #'append (mapcar #'early-collect-cpl supers))))))
 393     (remove-duplicates (walk class-name) :from-end nil :test #'eq)))
 394
 395 (defun early-collect-default-initargs (cpl)
 396   (let ((default-initargs ()))
 397     (dolist (class-name cpl)
 398       (let* ((definition (early-class-definition class-name))
 399              (others (ecd-other-initargs definition)))
 400         (loop (when (null others) (return nil))
 401               (let ((initarg (pop others)))
 402                 (unless (eq initarg :direct-default-initargs)
 403                  (error "~@<The defclass option ~S is not supported by ~
 404                         the bootstrap object system.~:@>"
 405                         initarg)))
 406               (setq default-initargs
 407                     (nconc default-initargs (reverse (pop others)))))))
 408     (reverse default-initargs)))
 409
 410 (defun !bootstrap-slot-index (class-name slot-name)
 411   (or (position slot-name (early-class-slots class-name))
 412       (error "~S not found" slot-name)))
 413
 414 ;;; !BOOTSTRAP-GET-SLOT and !BOOTSTRAP-SET-SLOT are used to access and
 415 ;;; change the values of slots during bootstrapping. During
 416 ;;; bootstrapping, there are only two kinds of objects whose slots we
 417 ;;; need to access, CLASSes and SLOT-DEFINITIONs. The first argument
 418 ;;; to these functions tells whether the object is a CLASS or a
 419 ;;; SLOT-DEFINITION.
 420 ;;;
 421 ;;; Note that the way this works it stores the slot in the same place
 422 ;;; in memory that the full object system will expect to find it
 423 ;;; later. This is critical to the bootstrapping process, the whole
 424 ;;; changeover to the full object system is predicated on this.
 425 ;;;
 426 ;;; One important point is that the layout of standard classes and
 427 ;;; standard slots must be computed the same way in this file as it is
 428 ;;; by the full object system later.
 429 (defmacro !bootstrap-get-slot (type object slot-name)
 430   `(clos-slots-ref (get-slots ,object)
 431                    (!bootstrap-slot-index ,type ,slot-name)))
 432 (defun !bootstrap-set-slot (type object slot-name new-value)
 433   (setf (!bootstrap-get-slot type object slot-name) new-value))
 434
 435 (defun early-class-name (class)
 436   (!bootstrap-get-slot 'class class 'name))
 437
 438 (defun early-class-precedence-list (class)
 439   (!bootstrap-get-slot 'pcl-class class '%class-precedence-list))
 440
 441 (defun early-class-name-of (instance)
 442   (early-class-name (class-of instance)))
 443
 444 (defun early-class-slotds (class)
 445   (!bootstrap-get-slot 'slot-class class 'slots))
 446
 447 (defun early-slot-definition-name (slotd)
 448   (!bootstrap-get-slot 'standard-effective-slot-definition slotd 'name))
 449
 450 (defun early-slot-definition-location (slotd)
 451   (!bootstrap-get-slot 'standard-effective-slot-definition slotd 'location))
 452
 453 (defun early-accessor-method-slot-name (method)
 454   (!bootstrap-get-slot 'standard-accessor-method method 'slot-name))
 455
 456 (unless (fboundp 'class-name-of)
 457   (setf (symbol-function 'class-name-of)
 458         (symbol-function 'early-class-name-of)))
 459 (unintern 'early-class-name-of)
 460
 461 (defun early-class-direct-subclasses (class)
 462   (!bootstrap-get-slot 'class class 'direct-subclasses))
 463
 464 (declaim (notinline load-defclass))
 465 (defun load-defclass (name metaclass supers canonical-slots canonical-options
 466                       readers writers slot-names source-location)
 467   (%compiler-defclass name readers writers slot-names)
 468   (setq supers  (copy-tree supers)
 469         canonical-slots   (copy-tree canonical-slots)
 470         canonical-options (copy-tree canonical-options))
 471   (let ((ecd
 472           (make-early-class-definition name
 473                                        source-location
 474                                        metaclass
 475                                        supers
 476                                        canonical-slots
 477                                        canonical-options))
 478         (existing
 479           (find name *early-class-definitions* :key #'ecd-class-name)))
 480     (setq *early-class-definitions*
 481           (cons ecd (remove existing *early-class-definitions*)))
 482     ecd))