src/pcl/defclass.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 ;;;; DEFCLASS macro and close personal friends
  27
  28 ;;; ANSI says (Macro DEFCLASS, section 7.7) that DEFCLASS, if it
  29 ;;; "appears as a top level form, the compiler must make the class
  30 ;;; name be recognized as a valid type name in subsequent declarations
  31 ;;; (as for deftype) and be recognized as a valid class name for
  32 ;;; defmethod parameter specializers and for use as the :metaclass
  33 ;;; option of a subsequent defclass."
  34 (defun preinform-compiler-about-class-type (name)
  35   ;; Unless the type system already has an actual type attached to
  36   ;; NAME (in which case (1) writing a placeholder value over that
  37   ;; actual type as a compile-time side-effect would probably be a bad
  38   ;; idea and (2) anyway we don't need to modify it in order to make
  39   ;; NAME be recognized as a valid type name)
  40   (unless (info :type :kind name)
  41     ;; Tell the compiler to expect a class with the given NAME, by
  42     ;; writing a kind of minimal placeholder type information. This
  43     ;; placeholder will be overwritten later when the class is defined.
  44     (setf (info :type :kind name) :forthcoming-defclass-type))
  45   (values))
  46
  47 ;;; state for the current DEFCLASS expansion
  48 (defvar *initfunctions-for-this-defclass*)
  49 (defvar *readers-for-this-defclass*)
  50 (defvar *writers-for-this-defclass*)
  51 (defvar *slot-names-for-this-defclass*)
  52
  53 ;;; Like the DEFMETHOD macro, the expansion of the DEFCLASS macro is
  54 ;;; fixed. DEFCLASS always expands into a call to LOAD-DEFCLASS. Until
  55 ;;; the meta-braid is set up, LOAD-DEFCLASS has a special definition
  56 ;;; which simply collects all class definitions up, when the metabraid
  57 ;;; is initialized it is done from those class definitions.
  58 ;;;
  59 ;;; After the metabraid has been setup, and the protocol for defining
  60 ;;; classes has been defined, the real definition of LOAD-DEFCLASS is
  61 ;;; installed by the file std-class.lisp
  62 (defmacro defclass (&environment env name %direct-superclasses %direct-slots &rest %options)
  63   (let ((supers  (copy-tree %direct-superclasses))
  64         (slots   (copy-tree %direct-slots))
  65         (options (copy-tree %options)))
  66     (let ((metaclass 'standard-class))
  67       (dolist (option options)
  68         (if (not (listp option))
  69           (error "~S is not a legal defclass option." option)
  70           (when (eq (car option) :metaclass)
  71             (unless (legal-class-name-p (cadr option))
  72               (error "The value of the :metaclass option (~S) is not a~%~
  73                       legal class name."
  74                      (cadr option)))
  75             (setq metaclass (cadr option))
  76             (setf options (remove option options))
  77             (return t))))
  78
  79       (let ((*initfunctions-for-this-defclass* ())
  80             (*readers-for-this-defclass* ()) ;Truly a crock, but we got
  81             (*writers-for-this-defclass* ()) ;to have it to live nicely.
  82             (*slot-names-for-this-defclass* ()))
  83         (let ((canonical-slots
  84                 (mapcar (lambda (spec)
  85                           (canonicalize-slot-specification name spec env))
  86                         slots))
  87               (other-initargs
  88                 (mapcar (lambda (option)
  89                           (canonicalize-defclass-option name option))
  90                         options))
  91               ;; DEFSTRUCT-P should be true if the class is defined
  92               ;; with a metaclass STRUCTURE-CLASS, so that a DEFSTRUCT
  93               ;; is compiled for the class.
  94               (defstruct-p (and (eq *boot-state* 'complete)
  95                                 (let ((mclass (find-class metaclass nil)))
  96                                   (and mclass
  97                                        (*subtypep
  98                                         mclass
  99                                         *the-class-structure-class*))))))
 100           (let ((defclass-form
 101                     `(progn
 102                       (let ,(mapcar #'cdr *initfunctions-for-this-defclass*)
 103                         (%compiler-defclass ',name
 104                                             ',*readers-for-this-defclass*
 105                                             ',*writers-for-this-defclass*
 106                                             ',*slot-names-for-this-defclass*)
 107                         (load-defclass ',name
 108                                        ',metaclass
 109                                        ',supers
 110                                        (list ,@canonical-slots)
 111                                        (list ,@(apply #'append
 112                                                       (when defstruct-p
 113                                                         '(:from-defclass-p t))
 114                                                       other-initargs)))))))
 115             (if defstruct-p
 116                 (progn
 117                   ;; FIXME: (YUK!) Why do we do this? Because in order
 118                   ;; to make the defstruct form, we need to know what
 119                   ;; the accessors for the slots are, so we need
 120                   ;; already to have hooked into the CLOS machinery.
 121                   ;;
 122                   ;; There may be a better way to do this: it would
 123                   ;; involve knowing enough about PCL to ask "what
 124                   ;; will my slot names and accessors be"; failing
 125                   ;; this, we currently just evaluate the whole
 126                   ;; kaboodle, and then use CLASS-DIRECT-SLOTS. --
 127                   ;; CSR, 2002-06-07
 128                   (eval defclass-form)
 129                   (let* ((include (or (and supers
 130                                            (fix-super (car supers)))
 131                                       (and (not (eq name 'structure-object))
 132                                            *the-class-structure-object*)))
 133                          (defstruct-form (make-structure-class-defstruct-form
 134                                           name (class-direct-slots (find-class name))
 135                                           include)))
 136                     `(progn
 137                       (eval-when (:compile-toplevel :load-toplevel :execute)
 138                         ,defstruct-form) ; really compile the defstruct-form
 139                       (eval-when (:compile-toplevel :load-toplevel :execute)
 140                         ,defclass-form))))
 141                 `(progn
 142                    ;; By telling the type system at compile time about
 143                    ;; the existence of a class named NAME, we can avoid
 144                    ;; various bogus warnings about "type isn't defined yet"
 145                    ;; for code elsewhere in the same file which uses
 146                    ;; the name of the type.
 147                    ;;
 148                    ;; We only need to do this at compile time, because
 149                    ;; at load and execute time we write the actual
 150                    ;; full-blown class, so the "a class of this name is
 151                    ;; coming" note we write here would be irrelevant.
 152                    (eval-when (:compile-toplevel)
 153                      (%compiler-defclass ',name
 154                                          ',*readers-for-this-defclass*
 155                                          ',*writers-for-this-defclass*
 156                                          ',*slot-names-for-this-defclass*))
 157                    (eval-when (:load-toplevel :execute)
 158                      ,defclass-form)))))))))
 159
 160 (defun %compiler-defclass (name readers writers slot-names)
 161   (with-single-package-locked-error (:symbol name "defining ~A as a class")
 162     (preinform-compiler-about-class-type name)
 163     (proclaim `(ftype (function (t) t)
 164                 ,@readers
 165                 ,@(mapcar #'slot-reader-name slot-names)
 166                 ,@(mapcar #'slot-boundp-name slot-names)))
 167     (proclaim `(ftype (function (t t) t)
 168                 ,@writers ,@(mapcar #'slot-writer-name slot-names)))))
 169
 170 (defun make-initfunction (initform)
 171   (cond ((or (eq initform t)
 172              (equal initform ''t))
 173          '(function constantly-t))
 174         ((or (eq initform nil)
 175              (equal initform ''nil))
 176          '(function constantly-nil))
 177         ((or (eql initform 0)
 178              (equal initform ''0))
 179          '(function constantly-0))
 180         (t
 181          (let ((entry (assoc initform *initfunctions-for-this-defclass*
 182                              :test #'equal)))
 183            (unless entry
 184              (setq entry (list initform
 185                                (gensym)
 186                                `(function (lambda () ,initform))))
 187              (push entry *initfunctions-for-this-defclass*))
 188            (cadr entry)))))
 189
 190 (defun canonicalize-slot-specification (class-name spec env)
 191   (labels ((slot-name-illegal (reason)
 192              (error 'simple-program-error
 193                     :format-control
 194                     (format nil "~~@<in DEFCLASS ~~S, the slot name in the ~
 195                                  specification ~~S is ~A.~~@:>" reason)
 196                     :format-arguments (list class-name spec)))
 197            (check-slot-name-legality (name)
 198              (cond
 199                ((not (symbolp name))
 200                 (slot-name-illegal "not a symbol"))
 201                ((keywordp name)
 202                 (slot-name-illegal "a keyword"))
 203                ((constantp name env)
 204                 (slot-name-illegal "a constant")))))
 205     (cond ((atom spec)
 206            (check-slot-name-legality spec)
 207            (push spec *slot-names-for-this-defclass*)
 208            `'(:name ,spec))
 209           ((null (cdr spec))
 210            (check-slot-name-legality (car spec))
 211            (push (car spec) *slot-names-for-this-defclass*)
 212          `'(:name ,(car spec)))
 213           ((null (cddr spec))
 214            (error 'simple-program-error
 215                   :format-control
 216                   "~@<in DEFCLASS ~S, the slot specification ~S is invalid; ~
 217                    the probable intended meaning may be achieved by ~
 218                    specifiying ~S instead.~>"
 219                   :format-arguments
 220                   (list class-name spec
 221                         `(,(car spec) :initform ,(cadr spec)))))
 222           (t
 223            (let* ((name (car spec))
 224                   (spec (cdr spec))
 225                   (readers ())
 226                   (writers ())
 227                   (initargs ())
 228                   (unsupplied (list nil))
 229                   (initform (getf spec :initform unsupplied)))
 230              (check-slot-name-legality name)
 231              (push name *slot-names-for-this-defclass*)
 232              (doplist (key val) spec
 233                (case key
 234                  (:accessor (push val readers)
 235                             (push `(setf ,val) writers))
 236                  (:reader   (push val readers))
 237                  (:writer   (push val writers))
 238                  (:initarg  (push val initargs))))
 239              (loop (unless (remf spec :accessor) (return)))
 240              (loop (unless (remf spec :reader)   (return)))
 241              (loop (unless (remf spec :writer)   (return)))
 242              (loop (unless (remf spec :initarg)  (return)))
 243              (setq *writers-for-this-defclass*
 244                    (append writers *writers-for-this-defclass*))
 245              (setq *readers-for-this-defclass*
 246                    (append readers *readers-for-this-defclass*))
 247              (setq spec `(:name     ',name
 248                           :readers  ',readers
 249                           :writers  ',writers
 250                           :initargs ',initargs
 251                           ',spec))
 252              (if (eq initform unsupplied)
 253                  `(list* ,@spec)
 254                  `(list* :initfunction ,(make-initfunction initform)
 255                          ,@spec)))))))
 256
 257 (defun canonicalize-defclass-option (class-name option)
 258   (declare (ignore class-name))
 259   (case (car option)
 260     (:default-initargs
 261       (let ((canonical ()))
 262         (let (key val (tail (cdr option)))
 263           (loop (when (null tail) (return nil))
 264                 (setq key (pop tail)
 265                       val (pop tail))
 266                 (push ``(,',key ,,(make-initfunction val) ,',val) canonical))
 267           `(:direct-default-initargs (list ,@(nreverse canonical))))))
 268     (:documentation
 269       `(',(car option) ',(cadr option)))
 270     (otherwise
 271      `(',(car option) ',(cdr option)))))
 272 \f
 273 ;;; This is the early definition of LOAD-DEFCLASS. It just collects up
 274 ;;; all the class definitions in a list. Later, in braid1.lisp, these
 275 ;;; are actually defined.
 276
 277 ;;; Each entry in *EARLY-CLASS-DEFINITIONS* is an EARLY-CLASS-DEFINITION.
 278 (defparameter *early-class-definitions* ())
 279
 280 (defun early-class-definition (class-name)
 281   (or (find class-name *early-class-definitions* :key #'ecd-class-name)
 282       (error "~S is not a class in *early-class-definitions*." class-name)))
 283
 284 (defun make-early-class-definition
 285        (name source metaclass
 286         superclass-names canonical-slots other-initargs)
 287   (list 'early-class-definition
 288         name source metaclass
 289         superclass-names canonical-slots other-initargs))
 290
 291 (defun ecd-class-name        (ecd) (nth 1 ecd))
 292 (defun ecd-source            (ecd) (nth 2 ecd))
 293 (defun ecd-metaclass         (ecd) (nth 3 ecd))
 294 (defun ecd-superclass-names  (ecd) (nth 4 ecd))
 295 (defun ecd-canonical-slots   (ecd) (nth 5 ecd))
 296 (defun ecd-other-initargs    (ecd) (nth 6 ecd))
 297
 298 (defvar *early-class-slots* nil)
 299
 300 (defun canonical-slot-name (canonical-slot)
 301   (getf canonical-slot :name))
 302
 303 (defun early-class-slots (class-name)
 304   (cdr (or (assoc class-name *early-class-slots*)
 305            (let ((a (cons class-name
 306                           (mapcar #'canonical-slot-name
 307                                   (early-collect-inheritance class-name)))))
 308              (push a *early-class-slots*)
 309              a))))
 310
 311 (defun early-class-size (class-name)
 312   (length (early-class-slots class-name)))
 313
 314 (defun early-collect-inheritance (class-name)
 315   ;;(declare (values slots cpl default-initargs direct-subclasses))
 316   (let ((cpl (early-collect-cpl class-name)))
 317     (values (early-collect-slots cpl)
 318             cpl
 319             (early-collect-default-initargs cpl)
 320             (let (collect)
 321               (dolist (definition *early-class-definitions*)
 322                 (when (memq class-name (ecd-superclass-names definition))
 323                   (push (ecd-class-name definition) collect)))
 324               (nreverse collect)))))
 325
 326 (defun early-collect-slots (cpl)
 327   (let* ((definitions (mapcar #'early-class-definition cpl))
 328          (super-slots (mapcar #'ecd-canonical-slots definitions))
 329          (slots (apply #'append (reverse super-slots))))
 330     (dolist (s1 slots)
 331       (let ((name1 (canonical-slot-name s1)))
 332         (dolist (s2 (cdr (memq s1 slots)))
 333           (when (eq name1 (canonical-slot-name s2))
 334             (error "More than one early class defines a slot with the~%~
 335                     name ~S. This can't work because the bootstrap~%~
 336                     object system doesn't know how to compute effective~%~
 337                     slots."
 338                    name1)))))
 339     slots))
 340
 341 (defun early-collect-cpl (class-name)
 342   (labels ((walk (c)
 343              (let* ((definition (early-class-definition c))
 344                     (supers (ecd-superclass-names definition)))
 345                (cons c
 346                      (apply #'append (mapcar #'early-collect-cpl supers))))))
 347     (remove-duplicates (walk class-name) :from-end nil :test #'eq)))
 348
 349 (defun early-collect-default-initargs (cpl)
 350   (let ((default-initargs ()))
 351     (dolist (class-name cpl)
 352       (let* ((definition (early-class-definition class-name))
 353              (others (ecd-other-initargs definition)))
 354         (loop (when (null others) (return nil))
 355               (let ((initarg (pop others)))
 356                 (unless (eq initarg :direct-default-initargs)
 357                  (error "~@<The defclass option ~S is not supported by ~
 358                         the bootstrap object system.~:@>"
 359                         initarg)))
 360               (setq default-initargs
 361                     (nconc default-initargs (reverse (pop others)))))))
 362     (reverse default-initargs)))
 363
 364 (defun !bootstrap-slot-index (class-name slot-name)
 365   (or (position slot-name (early-class-slots class-name))
 366       (error "~S not found" slot-name)))
 367
 368 ;;; !BOOTSTRAP-GET-SLOT and !BOOTSTRAP-SET-SLOT are used to access and
 369 ;;; change the values of slots during bootstrapping. During
 370 ;;; bootstrapping, there are only two kinds of objects whose slots we
 371 ;;; need to access, CLASSes and SLOT-DEFINITIONs. The first argument
 372 ;;; to these functions tells whether the object is a CLASS or a
 373 ;;; SLOT-DEFINITION.
 374 ;;;
 375 ;;; Note that the way this works it stores the slot in the same place
 376 ;;; in memory that the full object system will expect to find it
 377 ;;; later. This is critical to the bootstrapping process, the whole
 378 ;;; changeover to the full object system is predicated on this.
 379 ;;;
 380 ;;; One important point is that the layout of standard classes and
 381 ;;; standard slots must be computed the same way in this file as it is
 382 ;;; by the full object system later.
 383 (defmacro !bootstrap-get-slot (type object slot-name)
 384   `(clos-slots-ref (get-slots ,object)
 385                    (!bootstrap-slot-index ,type ,slot-name)))
 386 (defun !bootstrap-set-slot (type object slot-name new-value)
 387   (setf (!bootstrap-get-slot type object slot-name) new-value))
 388
 389 (defun early-class-name (class)
 390   (!bootstrap-get-slot 'class class 'name))
 391
 392 (defun early-class-precedence-list (class)
 393   (!bootstrap-get-slot 'pcl-class class 'class-precedence-list))
 394
 395 (defun early-class-name-of (instance)
 396   (early-class-name (class-of instance)))
 397
 398 (defun early-class-slotds (class)
 399   (!bootstrap-get-slot 'slot-class class 'slots))
 400
 401 (defun early-slot-definition-name (slotd)
 402   (!bootstrap-get-slot 'standard-effective-slot-definition slotd 'name))
 403
 404 (defun early-slot-definition-location (slotd)
 405   (!bootstrap-get-slot 'standard-effective-slot-definition slotd 'location))
 406
 407 (defun early-accessor-method-slot-name (method)
 408   (!bootstrap-get-slot 'standard-accessor-method method 'slot-name))
 409
 410 (unless (fboundp 'class-name-of)
 411   (setf (symbol-function 'class-name-of)
 412         (symbol-function 'early-class-name-of)))
 413 (unintern 'early-class-name-of)
 414
 415 (defun early-class-direct-subclasses (class)
 416   (!bootstrap-get-slot 'class class 'direct-subclasses))
 417
 418 (declaim (notinline load-defclass))
 419 (defun load-defclass (name metaclass supers canonical-slots canonical-options)
 420   (setq supers  (copy-tree supers)
 421         canonical-slots   (copy-tree canonical-slots)
 422         canonical-options (copy-tree canonical-options))
 423   (let ((ecd
 424           (make-early-class-definition name
 425                                        *load-pathname*
 426                                        metaclass
 427                                        supers
 428                                        canonical-slots
 429                                        canonical-options))
 430         (existing
 431           (find name *early-class-definitions* :key #'ecd-class-name)))
 432     (setq *early-class-definitions*
 433           (cons ecd (remove existing *early-class-definitions*)))
 434     ecd))
 435