src/pcl/defclass.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 ;;;; DEFCLASS macro and close personal friends
  27
  28 ;;; ANSI says (Macro DEFCLASS, section 7.7) that DEFCLASS, if it
  29 ;;; "appears as a top level form, the compiler must make the class
  30 ;;; name be recognized as a valid type name in subsequent declarations
  31 ;;; (as for deftype) and be recognized as a valid class name for
  32 ;;; defmethod parameter specializers and for use as the :metaclass
  33 ;;; option of a subsequent defclass."
  34 (defun preinform-compiler-about-class-type (name)
  35   ;; Unless the type system already has an actual type attached to
  36   ;; NAME (in which case (1) writing a placeholder value over that
  37   ;; actual type as a compile-time side-effect would probably be a bad
  38   ;; idea and (2) anyway we don't need to modify it in order to make
  39   ;; NAME be recognized as a valid type name)
  40   (unless (info :type :kind name)
  41     ;; Tell the compiler to expect a class with the given NAME, by
  42     ;; writing a kind of minimal placeholder type information. This
  43     ;; placeholder will be overwritten later when the class is defined.
  44     (setf (info :type :kind name) :forthcoming-defclass-type))
  45   (values))
  46
  47 ;;; state for the current DEFCLASS expansion
  48 (defvar *initfunctions-for-this-defclass*)
  49 (defvar *readers-for-this-defclass*)
  50 (defvar *writers-for-this-defclass*)
  51 (defvar *slot-names-for-this-defclass*)
  52
  53 ;;; Like the DEFMETHOD macro, the expansion of the DEFCLASS macro is
  54 ;;; fixed. DEFCLASS always expands into a call to LOAD-DEFCLASS. Until
  55 ;;; the meta-braid is set up, LOAD-DEFCLASS has a special definition
  56 ;;; which simply collects all class definitions up, when the metabraid
  57 ;;; is initialized it is done from those class definitions.
  58 ;;;
  59 ;;; After the metabraid has been setup, and the protocol for defining
  60 ;;; classes has been defined, the real definition of LOAD-DEFCLASS is
  61 ;;; installed by the file std-class.lisp
  62 (defmacro defclass (name %direct-superclasses %direct-slots &rest %options)
  63   (let ((supers  (copy-tree %direct-superclasses))
  64         (slots   (copy-tree %direct-slots))
  65         (options (copy-tree %options)))
  66     (let ((metaclass 'standard-class))
  67       (dolist (option options)
  68         (if (not (listp option))
  69           (error "~S is not a legal defclass option." option)
  70           (when (eq (car option) :metaclass)
  71             (unless (legal-class-name-p (cadr option))
  72               (error "The value of the :metaclass option (~S) is not a~%~
  73                       legal class name."
  74                      (cadr option)))
  75             (setq metaclass (cadr option))
  76             (setf options (remove option options))
  77             (return t))))
  78
  79       (let ((*initfunctions-for-this-defclass* ())
  80             (*readers-for-this-defclass* ()) ;Truly a crock, but we got
  81             (*writers-for-this-defclass* ()) ;to have it to live nicely.
  82             (*slot-names-for-this-defclass* ()))
  83         (let ((canonical-slots
  84                 (mapcar (lambda (spec)
  85                           (canonicalize-slot-specification name spec))
  86                         slots))
  87               (other-initargs
  88                 (mapcar (lambda (option)
  89                           (canonicalize-defclass-option name option))
  90                         options))
  91               ;; DEFSTRUCT-P should be true if the class is defined
  92               ;; with a metaclass STRUCTURE-CLASS, so that a DEFSTRUCT
  93               ;; is compiled for the class.
  94               (defstruct-p (and (eq *boot-state* 'complete)
  95                                 (let ((mclass (find-class metaclass nil)))
  96                                   (and mclass
  97                                        (*subtypep
  98                                         mclass
  99                                         *the-class-structure-class*))))))
 100           (let ((defclass-form
 101                   `(progn
 102                      ,@(mapcar (lambda (x)
 103                                  `(declaim (ftype (function (t) t) ,x)))
 104                                *readers-for-this-defclass*)
 105                      ,@(mapcar (lambda (x)
 106                                  `(declaim (ftype (function (t t) t) ,x)))
 107                                *writers-for-this-defclass*)
 108                      ,@(mapcar (lambda (x)
 109                                  `(declaim (ftype (function (t) t)
 110                                                   ,(slot-reader-name x)
 111                                                   ,(slot-boundp-name x))
 112                                            (ftype (function (t t) t)
 113                                                   ,(slot-writer-name x))))
 114                                *slot-names-for-this-defclass*)
 115                      (let ,(mapcar #'cdr *initfunctions-for-this-defclass*)
 116                        (load-defclass ',name
 117                                       ',metaclass
 118                                       ',supers
 119                                       (list ,@canonical-slots)
 120                                       (list ,@(apply #'append
 121                                                      (when defstruct-p
 122                                                        '(:from-defclass-p t))
 123                                                      other-initargs)))))))
 124             (if defstruct-p
 125                 (progn
 126                   ;; FIXME: (YUK!) Why do we do this? Because in order
 127                   ;; to make the defstruct form, we need to know what
 128                   ;; the accessors for the slots are, so we need
 129                   ;; already to have hooked into the CLOS machinery.
 130                   ;;
 131                   ;; There may be a better way to do this: it would
 132                   ;; involve knowing enough about PCL to ask "what
 133                   ;; will my slot names and accessors be"; failing
 134                   ;; this, we currently just evaluate the whole
 135                   ;; kaboodle, and then use CLASS-DIRECT-SLOTS. --
 136                   ;; CSR, 2002-06-07
 137                   (eval defclass-form)
 138                   (let* ((include (or (and supers
 139                                            (fix-super (car supers)))
 140                                       (and (not (eq name 'structure-object))
 141                                            *the-class-structure-object*)))
 142                          (defstruct-form (make-structure-class-defstruct-form
 143                                           name (class-direct-slots (find-class name)) include)))
 144                     `(progn
 145                       (eval-when (:compile-toplevel :load-toplevel :execute)
 146                         ,defstruct-form) ; really compile the defstruct-form
 147                       (eval-when (:compile-toplevel :load-toplevel :execute)
 148                         ,defclass-form))))
 149                 `(progn
 150                    ;; By telling the type system at compile time about
 151                    ;; the existence of a class named NAME, we can avoid
 152                    ;; various bogus warnings about "type isn't defined yet"
 153                    ;; for code elsewhere in the same file which uses
 154                    ;; the name of the type.
 155                    ;;
 156                    ;; We only need to do this at compile time, because
 157                    ;; at load and execute time we write the actual
 158                    ;; full-blown class, so the "a class of this name is
 159                    ;; coming" note we write here would be irrelevant.
 160                    (eval-when (:compile-toplevel)
 161                      (preinform-compiler-about-class-type ',name))
 162                    ,defclass-form))))))))
 163
 164 (defun make-initfunction (initform)
 165   (cond ((or (eq initform t)
 166              (equal initform ''t))
 167          '(function constantly-t))
 168         ((or (eq initform nil)
 169              (equal initform ''nil))
 170          '(function constantly-nil))
 171         ((or (eql initform 0)
 172              (equal initform ''0))
 173          '(function constantly-0))
 174         (t
 175          (let ((entry (assoc initform *initfunctions-for-this-defclass*
 176                              :test #'equal)))
 177            (unless entry
 178              (setq entry (list initform
 179                                (gensym)
 180                                `(function (lambda () ,initform))))
 181              (push entry *initfunctions-for-this-defclass*))
 182            (cadr entry)))))
 183
 184 (defun canonicalize-slot-specification (class-name spec)
 185   (cond ((and (symbolp spec)
 186               (not (keywordp spec))
 187               (not (memq spec '(t nil))))
 188          (push spec *slot-names-for-this-defclass*)
 189          `'(:name ,spec))
 190         ((not (consp spec))
 191          (error "~S is not a legal slot specification." spec))
 192         ((null (cdr spec))
 193          (push (car spec) *slot-names-for-this-defclass*)
 194          `'(:name ,(car spec)))
 195         ((null (cddr spec))
 196          (error "In DEFCLASS ~S, the slot specification ~S is obsolete.~%~
 197                  Convert it to ~S"
 198                 class-name spec (list (car spec) :initform (cadr spec))))
 199         (t
 200          (let* ((name (pop spec))
 201                 (readers ())
 202                 (writers ())
 203                 (initargs ())
 204                 (unsupplied (list nil))
 205                 (initform (getf spec :initform unsupplied)))
 206            (push name *slot-names-for-this-defclass*)
 207            (doplist (key val) spec
 208              (case key
 209                (:accessor (push val readers)
 210                           (push `(setf ,val) writers))
 211                (:reader   (push val readers))
 212                (:writer   (push val writers))
 213                (:initarg  (push val initargs))))
 214            (loop (unless (remf spec :accessor) (return)))
 215            (loop (unless (remf spec :reader)   (return)))
 216            (loop (unless (remf spec :writer)   (return)))
 217            (loop (unless (remf spec :initarg)  (return)))
 218            (setq *writers-for-this-defclass*
 219                  (append writers *writers-for-this-defclass*))
 220            (setq *readers-for-this-defclass*
 221                  (append readers *readers-for-this-defclass*))
 222            (setq spec `(:name     ',name
 223                         :readers  ',readers
 224                         :writers  ',writers
 225                         :initargs ',initargs
 226                         ',spec))
 227            (if (eq initform unsupplied)
 228                `(list* ,@spec)
 229                `(list* :initfunction ,(make-initfunction initform) ,@spec))))))
 230
 231 (defun canonicalize-defclass-option (class-name option)
 232   (declare (ignore class-name))
 233   (case (car option)
 234     (:default-initargs
 235       (let ((canonical ()))
 236         (let (key val (tail (cdr option)))
 237           (loop (when (null tail) (return nil))
 238                 (setq key (pop tail)
 239                       val (pop tail))
 240                 (push ``(,',key ,,(make-initfunction val) ,',val) canonical))
 241           `(:direct-default-initargs (list ,@(nreverse canonical))))))
 242     (:documentation
 243       `(',(car option) ',(cadr option)))
 244     (otherwise
 245      `(',(car option) ',(cdr option)))))
 246 \f
 247 ;;; This is the early definition of LOAD-DEFCLASS. It just collects up
 248 ;;; all the class definitions in a list. Later, in braid1.lisp, these
 249 ;;; are actually defined.
 250
 251 ;;; Each entry in *EARLY-CLASS-DEFINITIONS* is an EARLY-CLASS-DEFINITION.
 252 (defparameter *early-class-definitions* ())
 253
 254 (defun early-class-definition (class-name)
 255   (or (find class-name *early-class-definitions* :key #'ecd-class-name)
 256       (error "~S is not a class in *early-class-definitions*." class-name)))
 257
 258 (defun make-early-class-definition
 259        (name source metaclass
 260         superclass-names canonical-slots other-initargs)
 261   (list 'early-class-definition
 262         name source metaclass
 263         superclass-names canonical-slots other-initargs))
 264
 265 (defun ecd-class-name        (ecd) (nth 1 ecd))
 266 (defun ecd-source            (ecd) (nth 2 ecd))
 267 (defun ecd-metaclass         (ecd) (nth 3 ecd))
 268 (defun ecd-superclass-names  (ecd) (nth 4 ecd))
 269 (defun ecd-canonical-slots   (ecd) (nth 5 ecd))
 270 (defun ecd-other-initargs    (ecd) (nth 6 ecd))
 271
 272 (defvar *early-class-slots* nil)
 273
 274 (defun canonical-slot-name (canonical-slot)
 275   (getf canonical-slot :name))
 276
 277 (defun early-class-slots (class-name)
 278   (cdr (or (assoc class-name *early-class-slots*)
 279            (let ((a (cons class-name
 280                           (mapcar #'canonical-slot-name
 281                                   (early-collect-inheritance class-name)))))
 282              (push a *early-class-slots*)
 283              a))))
 284
 285 (defun early-class-size (class-name)
 286   (length (early-class-slots class-name)))
 287
 288 (defun early-collect-inheritance (class-name)
 289   ;;(declare (values slots cpl default-initargs direct-subclasses))
 290   (let ((cpl (early-collect-cpl class-name)))
 291     (values (early-collect-slots cpl)
 292             cpl
 293             (early-collect-default-initargs cpl)
 294             (let (collect)
 295               (dolist (definition *early-class-definitions*)
 296                 (when (memq class-name (ecd-superclass-names definition))
 297                   (push (ecd-class-name definition) collect)))
 298               (nreverse collect)))))
 299
 300 (defun early-collect-slots (cpl)
 301   (let* ((definitions (mapcar #'early-class-definition cpl))
 302          (super-slots (mapcar #'ecd-canonical-slots definitions))
 303          (slots (apply #'append (reverse super-slots))))
 304     (dolist (s1 slots)
 305       (let ((name1 (canonical-slot-name s1)))
 306         (dolist (s2 (cdr (memq s1 slots)))
 307           (when (eq name1 (canonical-slot-name s2))
 308             (error "More than one early class defines a slot with the~%~
 309                     name ~S. This can't work because the bootstrap~%~
 310                     object system doesn't know how to compute effective~%~
 311                     slots."
 312                    name1)))))
 313     slots))
 314
 315 (defun early-collect-cpl (class-name)
 316   (labels ((walk (c)
 317              (let* ((definition (early-class-definition c))
 318                     (supers (ecd-superclass-names definition)))
 319                (cons c
 320                      (apply #'append (mapcar #'early-collect-cpl supers))))))
 321     (remove-duplicates (walk class-name) :from-end nil :test #'eq)))
 322
 323 (defun early-collect-default-initargs (cpl)
 324   (let ((default-initargs ()))
 325     (dolist (class-name cpl)
 326       (let* ((definition (early-class-definition class-name))
 327              (others (ecd-other-initargs definition)))
 328         (loop (when (null others) (return nil))
 329               (let ((initarg (pop others)))
 330                 (unless (eq initarg :direct-default-initargs)
 331                  (error "~@<The defclass option ~S is not supported by ~
 332                         the bootstrap object system.~:@>"
 333                         initarg)))
 334               (setq default-initargs
 335                     (nconc default-initargs (reverse (pop others)))))))
 336     (reverse default-initargs)))
 337
 338 (defun !bootstrap-slot-index (class-name slot-name)
 339   (or (position slot-name (early-class-slots class-name))
 340       (error "~S not found" slot-name)))
 341
 342 ;;; !BOOTSTRAP-GET-SLOT and !BOOTSTRAP-SET-SLOT are used to access and
 343 ;;; change the values of slots during bootstrapping. During
 344 ;;; bootstrapping, there are only two kinds of objects whose slots we
 345 ;;; need to access, CLASSes and SLOT-DEFINITIONs. The first argument
 346 ;;; to these functions tells whether the object is a CLASS or a
 347 ;;; SLOT-DEFINITION.
 348 ;;;
 349 ;;; Note that the way this works it stores the slot in the same place
 350 ;;; in memory that the full object system will expect to find it
 351 ;;; later. This is critical to the bootstrapping process, the whole
 352 ;;; changeover to the full object system is predicated on this.
 353 ;;;
 354 ;;; One important point is that the layout of standard classes and
 355 ;;; standard slots must be computed the same way in this file as it is
 356 ;;; by the full object system later.
 357 (defmacro !bootstrap-get-slot (type object slot-name)
 358   `(clos-slots-ref (get-slots ,object)
 359                    (!bootstrap-slot-index ,type ,slot-name)))
 360 (defun !bootstrap-set-slot (type object slot-name new-value)
 361   (setf (!bootstrap-get-slot type object slot-name) new-value))
 362
 363 (defun early-class-name (class)
 364   (!bootstrap-get-slot 'class class 'name))
 365
 366 (defun early-class-precedence-list (class)
 367   (!bootstrap-get-slot 'pcl-class class 'class-precedence-list))
 368
 369 (defun early-class-name-of (instance)
 370   (early-class-name (class-of instance)))
 371
 372 (defun early-class-slotds (class)
 373   (!bootstrap-get-slot 'slot-class class 'slots))
 374
 375 (defun early-slot-definition-name (slotd)
 376   (!bootstrap-get-slot 'standard-effective-slot-definition slotd 'name))
 377
 378 (defun early-slot-definition-location (slotd)
 379   (!bootstrap-get-slot 'standard-effective-slot-definition slotd 'location))
 380
 381 (defun early-accessor-method-slot-name (method)
 382   (!bootstrap-get-slot 'standard-accessor-method method 'slot-name))
 383
 384 (unless (fboundp 'class-name-of)
 385   (setf (symbol-function 'class-name-of)
 386         (symbol-function 'early-class-name-of)))
 387 (unintern 'early-class-name-of)
 388
 389 (defun early-class-direct-subclasses (class)
 390   (!bootstrap-get-slot 'class class 'direct-subclasses))
 391
 392 (declaim (notinline load-defclass))
 393 (defun load-defclass (name metaclass supers canonical-slots canonical-options)
 394   (setq supers  (copy-tree supers)
 395         canonical-slots   (copy-tree canonical-slots)
 396         canonical-options (copy-tree canonical-options))
 397   (let ((ecd
 398           (make-early-class-definition name
 399                                        *load-pathname*
 400                                        metaclass
 401                                        supers
 402                                        canonical-slots
 403                                        canonical-options))
 404         (existing
 405           (find name *early-class-definitions* :key #'ecd-class-name)))
 406     (setq *early-class-definitions*
 407           (cons ecd (remove existing *early-class-definitions*)))
 408     ecd))
 409