src/pcl/defclass.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26
  27 (defun make-progn (&rest forms)
  28   (let ((progn-form nil))
  29     (labels ((collect-forms (forms)
  30                (unless (null forms)
  31                  (collect-forms (cdr forms))
  32                  (if (and (listp (car forms))
  33                           (eq (caar forms) 'progn))
  34                      (collect-forms (cdar forms))
  35                      (push (car forms) progn-form)))))
  36       (collect-forms forms)
  37       (cons 'progn progn-form))))
  38 \f
  39 ;;; Like the DEFMETHOD macro, the expansion of the DEFCLASS macro is
  40 ;;; fixed. DEFCLASS always expands into a call to LOAD-DEFCLASS. Until
  41 ;;; the meta-braid is set up, LOAD-DEFCLASS has a special definition
  42 ;;; which simply collects all class definitions up, when the metabraid
  43 ;;; is initialized it is done from those class definitions.
  44 ;;;
  45 ;;; After the metabraid has been setup, and the protocol for defining
  46 ;;; classes has been defined, the real definition of LOAD-DEFCLASS is
  47 ;;; installed by the file defclass.lisp
  48 (defmacro defclass (name direct-superclasses direct-slots &rest options)
  49   (expand-defclass name direct-superclasses direct-slots options))
  50
  51 (defun expand-defclass (name supers slots options)
  52   ;; FIXME: We should probably just ensure that the relevant
  53   ;; DEFVAR/DEFPARAMETERs occur before this definition, rather
  54   ;; than locally declaring them SPECIAL.
  55   (declare (special *boot-state* *the-class-structure-class*))
  56   (setq supers  (copy-tree supers)
  57         slots   (copy-tree slots)
  58         options (copy-tree options))
  59   (let ((metaclass 'standard-class))
  60     (dolist (option options)
  61       (if (not (listp option))
  62           (error "~S is not a legal defclass option." option)
  63           (when (eq (car option) ':metaclass)
  64             (unless (legal-class-name-p (cadr option))
  65               (error "The value of the :metaclass option (~S) is not a~%~
  66                       legal class name."
  67                      (cadr option)))
  68             (setq metaclass
  69                   (case (cadr option)
  70                     (cl:standard-class 'standard-class)
  71                     (cl:structure-class 'structure-class)
  72                     (t (cadr option))))
  73             (setf options (remove option options))
  74             (return t))))
  75
  76     (let ((*initfunctions* ())
  77           (*readers* ())                ;Truly a crock, but we got
  78           (*writers* ()))               ;to have it to live nicely.
  79       (declare (special *initfunctions* *readers* *writers*))
  80       (let ((canonical-slots
  81               (mapcar #'(lambda (spec)
  82                           (canonicalize-slot-specification name spec))
  83                       slots))
  84             (other-initargs
  85               (mapcar #'(lambda (option)
  86                           (canonicalize-defclass-option name option))
  87                       options))
  88             (defstruct-p (and (eq *boot-state* 'complete)
  89                               (let ((mclass (find-class metaclass nil)))
  90                                 (and mclass
  91                                      (*subtypep
  92                                       mclass
  93                                       *the-class-structure-class*))))))
  94         (let ((defclass-form
  95                 `(progn
  96                    ,@(mapcar (lambda (x)
  97                                `(declaim (ftype (function (t) t) ,x)))
  98                              *readers*)
  99                    ,@(mapcar (lambda (x)
 100                                `(declaim (ftype (function (t t) t) ,x)))
 101                              *writers*)
 102                    (let ,(mapcar #'cdr *initfunctions*)
 103                      (load-defclass ',name
 104                                     ',metaclass
 105                                     ',supers
 106                                     (list ,@canonical-slots)
 107                                     (list ,@(apply #'append
 108                                                    (when defstruct-p
 109                                                      '(:from-defclass-p t))
 110                                                    other-initargs)))))))
 111           (if defstruct-p
 112               (progn
 113                 (eval defclass-form) ; Define the class now, so that..
 114                 `(progn       ; ..the defstruct can be compiled.
 115                    ,(class-defstruct-form (find-class name))
 116                    ,defclass-form))
 117               (progn
 118                 (when (eq *boot-state* 'complete)
 119                   (inform-type-system-about-std-class name))
 120                 defclass-form)))))))
 121
 122 (defun make-initfunction (initform)
 123   (declare (special *initfunctions*))
 124   (cond ((or (eq initform t)
 125              (equal initform ''t))
 126          '(function constantly-t))
 127         ((or (eq initform nil)
 128              (equal initform ''nil))
 129          '(function constantly-nil))
 130         ((or (eql initform 0)
 131              (equal initform ''0))
 132          '(function constantly-0))
 133         (t
 134          (let ((entry (assoc initform *initfunctions* :test #'equal)))
 135            (unless entry
 136              (setq entry (list initform
 137                                (gensym)
 138                                `(function (lambda () ,initform))))
 139              (push entry *initfunctions*))
 140            (cadr entry)))))
 141
 142 (defun canonicalize-slot-specification (class-name spec)
 143   (declare (special *readers* *writers*))
 144   (cond ((and (symbolp spec)
 145               (not (keywordp spec))
 146               (not (memq spec '(t nil))))
 147          `'(:name ,spec))
 148         ((not (consp spec))
 149          (error "~S is not a legal slot specification." spec))
 150         ((null (cdr spec))
 151          `'(:name ,(car spec)))
 152         ((null (cddr spec))
 153          (error "In DEFCLASS ~S, the slot specification ~S is obsolete.~%~
 154                  Convert it to ~S"
 155                 class-name spec (list (car spec) :initform (cadr spec))))
 156         (t
 157          (let* ((name (pop spec))
 158                 (readers ())
 159                 (writers ())
 160                 (initargs ())
 161                 (unsupplied (list nil))
 162                 (initform (getf spec :initform unsupplied)))
 163            (doplist (key val) spec
 164              (case key
 165                (:accessor (push val readers)
 166                           (push `(setf ,val) writers))
 167                (:reader   (push val readers))
 168                (:writer   (push val writers))
 169                (:initarg  (push val initargs))))
 170            (loop (unless (remf spec :accessor) (return)))
 171            (loop (unless (remf spec :reader)   (return)))
 172            (loop (unless (remf spec :writer)   (return)))
 173            (loop (unless (remf spec :initarg)  (return)))
 174            (setq *writers* (append writers *writers*))
 175            (setq *readers* (append readers *readers*))
 176            (setq spec `(:name     ',name
 177                         :readers  ',readers
 178                         :writers  ',writers
 179                         :initargs ',initargs
 180                         ',spec))
 181            (if (eq initform unsupplied)
 182                `(list* ,@spec)
 183                `(list* :initfunction ,(make-initfunction initform) ,@spec))))))
 184
 185 (defun canonicalize-defclass-option (class-name option)
 186   (declare (ignore class-name))
 187   (case (car option)
 188     (:default-initargs
 189       (let ((canonical ()))
 190         (let (key val (tail (cdr option)))
 191           (loop (when (null tail) (return nil))
 192                 (setq key (pop tail)
 193                       val (pop tail))
 194                 (push ``(,',key ,,(make-initfunction val) ,',val) canonical))
 195           `(':direct-default-initargs (list ,@(nreverse canonical))))))
 196     (:documentation
 197       `(',(car option) ',(cadr option)))
 198     (otherwise
 199      `(',(car option) ',(cdr option)))))
 200 \f
 201 ;;; This is the early definition of load-defclass. It just collects up
 202 ;;; all the class definitions in a list. Later, in the file
 203 ;;; braid1.lisp, these are actually defined.
 204
 205 ;;; Each entry in *EARLY-CLASS-DEFINITIONS* is an EARLY-CLASS-DEFINITION.
 206 (defparameter *early-class-definitions* ())
 207
 208 (defun early-class-definition (class-name)
 209   (or (find class-name *early-class-definitions* :key #'ecd-class-name)
 210       (error "~S is not a class in *early-class-definitions*." class-name)))
 211
 212 (defun make-early-class-definition
 213        (name source metaclass
 214         superclass-names canonical-slots other-initargs)
 215   (list 'early-class-definition
 216         name source metaclass
 217         superclass-names canonical-slots other-initargs))
 218
 219 (defun ecd-class-name        (ecd) (nth 1 ecd))
 220 (defun ecd-source            (ecd) (nth 2 ecd))
 221 (defun ecd-metaclass         (ecd) (nth 3 ecd))
 222 (defun ecd-superclass-names  (ecd) (nth 4 ecd))
 223 (defun ecd-canonical-slots   (ecd) (nth 5 ecd))
 224 (defun ecd-other-initargs    (ecd) (nth 6 ecd))
 225
 226 (defvar *early-class-slots* nil)
 227
 228 (defun canonical-slot-name (canonical-slot)
 229   (getf canonical-slot :name))
 230
 231 (defun early-class-slots (class-name)
 232   (cdr (or (assoc class-name *early-class-slots*)
 233            (let ((a (cons class-name
 234                           (mapcar #'canonical-slot-name
 235                                   (early-collect-inheritance class-name)))))
 236              (push a *early-class-slots*)
 237              a))))
 238
 239 (defun early-class-size (class-name)
 240   (length (early-class-slots class-name)))
 241
 242 (defun early-collect-inheritance (class-name)
 243   ;;(declare (values slots cpl default-initargs direct-subclasses))
 244   (let ((cpl (early-collect-cpl class-name)))
 245     (values (early-collect-slots cpl)
 246             cpl
 247             (early-collect-default-initargs cpl)
 248             (gathering1 (collecting)
 249               (dolist (definition *early-class-definitions*)
 250                 (when (memq class-name (ecd-superclass-names definition))
 251                   (gather1 (ecd-class-name definition))))))))
 252
 253 (defun early-collect-slots (cpl)
 254   (let* ((definitions (mapcar #'early-class-definition cpl))
 255          (super-slots (mapcar #'ecd-canonical-slots definitions))
 256          (slots (apply #'append (reverse super-slots))))
 257     (dolist (s1 slots)
 258       (let ((name1 (canonical-slot-name s1)))
 259         (dolist (s2 (cdr (memq s1 slots)))
 260           (when (eq name1 (canonical-slot-name s2))
 261             (error "More than one early class defines a slot with the~%~
 262                     name ~S. This can't work because the bootstrap~%~
 263                     object system doesn't know how to compute effective~%~
 264                     slots."
 265                    name1)))))
 266     slots))
 267
 268 (defun early-collect-cpl (class-name)
 269   (labels ((walk (c)
 270              (let* ((definition (early-class-definition c))
 271                     (supers (ecd-superclass-names definition)))
 272                (cons c
 273                      (apply #'append (mapcar #'early-collect-cpl supers))))))
 274     (remove-duplicates (walk class-name) :from-end nil :test #'eq)))
 275
 276 (defun early-collect-default-initargs (cpl)
 277   (let ((default-initargs ()))
 278     (dolist (class-name cpl)
 279       (let* ((definition (early-class-definition class-name))
 280              (others (ecd-other-initargs definition)))
 281         (loop (when (null others) (return nil))
 282               (let ((initarg (pop others)))
 283                 (unless (eq initarg :direct-default-initargs)
 284                  (error "~@<The defclass option ~S is not supported by ~
 285                         the bootstrap object system.~:@>"
 286                         initarg)))
 287               (setq default-initargs
 288                     (nconc default-initargs (reverse (pop others)))))))
 289     (reverse default-initargs)))
 290
 291 (defun !bootstrap-slot-index (class-name slot-name)
 292   (or (position slot-name (early-class-slots class-name))
 293       (error "~S not found" slot-name)))
 294
 295 ;;; !BOOTSTRAP-GET-SLOT and !BOOTSTRAP-SET-SLOT are used to access and
 296 ;;; change the values of slots during bootstrapping. During
 297 ;;; bootstrapping, there are only two kinds of objects whose slots we
 298 ;;; need to access, CLASSes and SLOT-DEFINITIONs. The first argument
 299 ;;; to these functions tells whether the object is a CLASS or a
 300 ;;; SLOT-DEFINITION.
 301 ;;;
 302 ;;; Note that the way this works it stores the slot in the same place
 303 ;;; in memory that the full object system will expect to find it
 304 ;;; later. This is critical to the bootstrapping process, the whole
 305 ;;; changeover to the full object system is predicated on this.
 306 ;;;
 307 ;;; One important point is that the layout of standard classes and
 308 ;;; standard slots must be computed the same way in this file as it is
 309 ;;; by the full object system later.
 310 (defmacro !bootstrap-get-slot (type object slot-name)
 311   `(clos-slots-ref (get-slots ,object)
 312                    (!bootstrap-slot-index ,type ,slot-name)))
 313 (defun !bootstrap-set-slot (type object slot-name new-value)
 314   (setf (!bootstrap-get-slot type object slot-name) new-value))
 315
 316 (defun early-class-name (class)
 317   (!bootstrap-get-slot 'class class 'name))
 318
 319 (defun early-class-precedence-list (class)
 320   (!bootstrap-get-slot 'pcl-class class 'class-precedence-list))
 321
 322 (defun early-class-name-of (instance)
 323   (early-class-name (class-of instance)))
 324
 325 (defun early-class-slotds (class)
 326   (!bootstrap-get-slot 'slot-class class 'slots))
 327
 328 (defun early-slot-definition-name (slotd)
 329   (!bootstrap-get-slot 'standard-effective-slot-definition slotd 'name))
 330
 331 (defun early-slot-definition-location (slotd)
 332   (!bootstrap-get-slot 'standard-effective-slot-definition slotd 'location))
 333
 334 (defun early-accessor-method-slot-name (method)
 335   (!bootstrap-get-slot 'standard-accessor-method method 'slot-name))
 336
 337 (unless (fboundp 'class-name-of)
 338   (setf (symbol-function 'class-name-of)
 339         (symbol-function 'early-class-name-of)))
 340 (unintern 'early-class-name-of)
 341
 342 (defun early-class-direct-subclasses (class)
 343   (!bootstrap-get-slot 'class class 'direct-subclasses))
 344
 345 (declaim (notinline load-defclass))
 346 (defun load-defclass (name metaclass supers canonical-slots canonical-options)
 347   (setq supers  (copy-tree supers)
 348         canonical-slots   (copy-tree canonical-slots)
 349         canonical-options (copy-tree canonical-options))
 350   (when (eq metaclass 'standard-class)
 351     (inform-type-system-about-std-class name))
 352   (let ((ecd
 353           (make-early-class-definition name
 354                                        *load-truename*
 355                                        metaclass
 356                                        supers
 357                                        canonical-slots
 358                                        canonical-options))
 359         (existing
 360           (find name *early-class-definitions* :key #'ecd-class-name)))
 361     (setq *early-class-definitions*
 362           (cons ecd (remove existing *early-class-definitions*)))
 363     ecd))
 364