src/pcl/defclass.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 ;;;; DEFCLASS macro and close personal friends
  27
  28 ;;; ANSI says (Macro DEFCLASS, section 7.7) that DEFCLASS, if it
  29 ;;; "appears as a top level form, the compiler must make the class
  30 ;;; name be recognized as a valid type name in subsequent declarations
  31 ;;; (as for deftype) and be recognized as a valid class name for
  32 ;;; defmethod parameter specializers and for use as the :metaclass
  33 ;;; option of a subsequent defclass."
  34 (defun preinform-compiler-about-class-type (name)
  35   ;; Unless the type system already has an actual type attached to
  36   ;; NAME (in which case (1) writing a placeholder value over that
  37   ;; actual type as a compile-time side-effect would probably be a bad
  38   ;; idea and (2) anyway we don't need to modify it in order to make
  39   ;; NAME be recognized as a valid type name)
  40   (unless (info :type :kind name)
  41     ;; Tell the compiler to expect a class with the given NAME, by
  42     ;; writing a kind of minimal placeholder type information. This
  43     ;; placeholder will be overwritten later when the class is defined.
  44     (setf (info :type :kind name) :forthcoming-defclass-type))
  45   (values))
  46
  47 ;;; state for the current DEFCLASS expansion
  48 (defvar *initfunctions-for-this-defclass*)
  49 (defvar *readers-for-this-defclass*)
  50 (defvar *writers-for-this-defclass*)
  51 (defvar *slot-names-for-this-defclass*)
  52
  53 ;;; Like the DEFMETHOD macro, the expansion of the DEFCLASS macro is
  54 ;;; fixed. DEFCLASS always expands into a call to LOAD-DEFCLASS. Until
  55 ;;; the meta-braid is set up, LOAD-DEFCLASS has a special definition
  56 ;;; which simply collects all class definitions up, when the metabraid
  57 ;;; is initialized it is done from those class definitions.
  58 ;;;
  59 ;;; After the metabraid has been setup, and the protocol for defining
  60 ;;; classes has been defined, the real definition of LOAD-DEFCLASS is
  61 ;;; installed by the file std-class.lisp
  62 (defmacro defclass (&environment env name %direct-superclasses %direct-slots &rest %options)
  63   (let ((supers  (copy-tree %direct-superclasses))
  64         (slots   (copy-tree %direct-slots))
  65         (options (copy-tree %options)))
  66     (let ((metaclass 'standard-class))
  67       (dolist (option options)
  68         (if (not (listp option))
  69           (error "~S is not a legal defclass option." option)
  70           (when (eq (car option) :metaclass)
  71             (unless (legal-class-name-p (cadr option))
  72               (error "The value of the :metaclass option (~S) is not a~%~
  73                       legal class name."
  74                      (cadr option)))
  75             (setq metaclass (cadr option))
  76             (setf options (remove option options))
  77             (return t))))
  78
  79       (let ((*initfunctions-for-this-defclass* ())
  80             (*readers-for-this-defclass* ()) ;Truly a crock, but we got
  81             (*writers-for-this-defclass* ()) ;to have it to live nicely.
  82             (*slot-names-for-this-defclass* ()))
  83         (let ((canonical-slots
  84                 (mapcar (lambda (spec)
  85                           (canonicalize-slot-specification name spec env))
  86                         slots))
  87               (other-initargs
  88                 (mapcar (lambda (option)
  89                           (canonicalize-defclass-option name option))
  90                         options))
  91               ;; DEFSTRUCT-P should be true if the class is defined
  92               ;; with a metaclass STRUCTURE-CLASS, so that a DEFSTRUCT
  93               ;; is compiled for the class.
  94               (defstruct-p (and (eq *boot-state* 'complete)
  95                                 (let ((mclass (find-class metaclass nil)))
  96                                   (and mclass
  97                                        (*subtypep
  98                                         mclass
  99                                         *the-class-structure-class*))))))
 100           (let ((defclass-form
 101                   `(progn
 102                      (let ,(mapcar #'cdr *initfunctions-for-this-defclass*)
 103                        (%compiler-defclass ',name
 104                                            ',*readers-for-this-defclass*
 105                                            ',*writers-for-this-defclass*
 106                                            ',*slot-names-for-this-defclass*)
 107                        (load-defclass ',name
 108                                       ',metaclass
 109                                       ',supers
 110                                       (list ,@canonical-slots)
 111                                       (list ,@(apply #'append
 112                                                      (when defstruct-p
 113                                                        '(:from-defclass-p t))
 114                                                      other-initargs)))))))
 115             (if defstruct-p
 116                 (progn
 117                   ;; FIXME: (YUK!) Why do we do this? Because in order
 118                   ;; to make the defstruct form, we need to know what
 119                   ;; the accessors for the slots are, so we need
 120                   ;; already to have hooked into the CLOS machinery.
 121                   ;;
 122                   ;; There may be a better way to do this: it would
 123                   ;; involve knowing enough about PCL to ask "what
 124                   ;; will my slot names and accessors be"; failing
 125                   ;; this, we currently just evaluate the whole
 126                   ;; kaboodle, and then use CLASS-DIRECT-SLOTS. --
 127                   ;; CSR, 2002-06-07
 128                   (eval defclass-form)
 129                   (let* ((include (or (and supers
 130                                            (fix-super (car supers)))
 131                                       (and (not (eq name 'structure-object))
 132                                            *the-class-structure-object*)))
 133                          (defstruct-form (make-structure-class-defstruct-form
 134                                           name (class-direct-slots (find-class name)) include)))
 135                     `(progn
 136                       (eval-when (:compile-toplevel :load-toplevel :execute)
 137                         ,defstruct-form) ; really compile the defstruct-form
 138                       (eval-when (:compile-toplevel :load-toplevel :execute)
 139                         ,defclass-form))))
 140                 `(progn
 141                    ;; By telling the type system at compile time about
 142                    ;; the existence of a class named NAME, we can avoid
 143                    ;; various bogus warnings about "type isn't defined yet"
 144                    ;; for code elsewhere in the same file which uses
 145                    ;; the name of the type.
 146                    ;;
 147                    ;; We only need to do this at compile time, because
 148                    ;; at load and execute time we write the actual
 149                    ;; full-blown class, so the "a class of this name is
 150                    ;; coming" note we write here would be irrelevant.
 151                    (eval-when (:compile-toplevel)
 152                      (%compiler-defclass ',name
 153                                          ',*readers-for-this-defclass*
 154                                          ',*writers-for-this-defclass*
 155                                          ',*slot-names-for-this-defclass*))
 156                    (eval-when (:load-toplevel :execute)
 157                      ,defclass-form)))))))))
 158
 159 (defun %compiler-defclass (name readers writers slot-names)
 160   (preinform-compiler-about-class-type name)
 161   (proclaim `(ftype (function (t) t)
 162               ,@readers
 163               ,@(mapcar #'slot-reader-name slot-names)
 164               ,@(mapcar #'slot-boundp-name slot-names)))
 165   (proclaim `(ftype (function (t t) t)
 166               ,@writers ,@(mapcar #'slot-writer-name slot-names))))
 167
 168 (defun make-initfunction (initform)
 169   (cond ((or (eq initform t)
 170              (equal initform ''t))
 171          '(function constantly-t))
 172         ((or (eq initform nil)
 173              (equal initform ''nil))
 174          '(function constantly-nil))
 175         ((or (eql initform 0)
 176              (equal initform ''0))
 177          '(function constantly-0))
 178         (t
 179          (let ((entry (assoc initform *initfunctions-for-this-defclass*
 180                              :test #'equal)))
 181            (unless entry
 182              (setq entry (list initform
 183                                (gensym)
 184                                `(function (lambda () ,initform))))
 185              (push entry *initfunctions-for-this-defclass*))
 186            (cadr entry)))))
 187
 188 (defun canonicalize-slot-specification (class-name spec env)
 189   (labels ((slot-name-illegal (reason)
 190              (error 'simple-program-error
 191                     :format-control
 192                     (format nil "~~@<in DEFCLASS ~~S, the slot name in the ~
 193                                  specification ~~S is ~A.~~@:>" reason)
 194                     :format-arguments (list class-name spec)))
 195            (check-slot-name-legality (name)
 196              (cond
 197                ((not (symbolp name))
 198                 (slot-name-illegal "not a symbol"))
 199                ((keywordp name)
 200                 (slot-name-illegal "a keyword"))
 201                ((constantp name env)
 202                 (slot-name-illegal "a constant")))))
 203     (cond ((atom spec)
 204            (check-slot-name-legality spec)
 205            (push spec *slot-names-for-this-defclass*)
 206            `'(:name ,spec))
 207           ((null (cdr spec))
 208            (check-slot-name-legality (car spec))
 209            (push (car spec) *slot-names-for-this-defclass*)
 210          `'(:name ,(car spec)))
 211           ((null (cddr spec))
 212            (error 'simple-program-error
 213                   :format-control
 214                   "~@<in DEFCLASS ~S, the slot specification ~S is invalid; ~
 215                    the probable intended meaning may be achieved by ~
 216                    specifiying ~S instead.~>"
 217                   :format-arguments
 218                   (list class-name spec
 219                         `(,(car spec) :initform ,(cadr spec)))))
 220           (t
 221            (let* ((name (car spec))
 222                   (spec (cdr spec))
 223                   (readers ())
 224                   (writers ())
 225                   (initargs ())
 226                   (unsupplied (list nil))
 227                   (initform (getf spec :initform unsupplied)))
 228              (check-slot-name-legality name)
 229              (push name *slot-names-for-this-defclass*)
 230              (doplist (key val) spec
 231                (case key
 232                  (:accessor (push val readers)
 233                             (push `(setf ,val) writers))
 234                  (:reader   (push val readers))
 235                  (:writer   (push val writers))
 236                  (:initarg  (push val initargs))))
 237              (loop (unless (remf spec :accessor) (return)))
 238              (loop (unless (remf spec :reader)   (return)))
 239              (loop (unless (remf spec :writer)   (return)))
 240              (loop (unless (remf spec :initarg)  (return)))
 241              (setq *writers-for-this-defclass*
 242                    (append writers *writers-for-this-defclass*))
 243              (setq *readers-for-this-defclass*
 244                    (append readers *readers-for-this-defclass*))
 245              (setq spec `(:name     ',name
 246                           :readers  ',readers
 247                           :writers  ',writers
 248                           :initargs ',initargs
 249                           ',spec))
 250              (if (eq initform unsupplied)
 251                  `(list* ,@spec)
 252                  `(list* :initfunction ,(make-initfunction initform)
 253                          ,@spec)))))))
 254
 255 (defun canonicalize-defclass-option (class-name option)
 256   (declare (ignore class-name))
 257   (case (car option)
 258     (:default-initargs
 259       (let ((canonical ()))
 260         (let (key val (tail (cdr option)))
 261           (loop (when (null tail) (return nil))
 262                 (setq key (pop tail)
 263                       val (pop tail))
 264                 (push ``(,',key ,,(make-initfunction val) ,',val) canonical))
 265           `(:direct-default-initargs (list ,@(nreverse canonical))))))
 266     (:documentation
 267       `(',(car option) ',(cadr option)))
 268     (otherwise
 269      `(',(car option) ',(cdr option)))))
 270 \f
 271 ;;; This is the early definition of LOAD-DEFCLASS. It just collects up
 272 ;;; all the class definitions in a list. Later, in braid1.lisp, these
 273 ;;; are actually defined.
 274
 275 ;;; Each entry in *EARLY-CLASS-DEFINITIONS* is an EARLY-CLASS-DEFINITION.
 276 (defparameter *early-class-definitions* ())
 277
 278 (defun early-class-definition (class-name)
 279   (or (find class-name *early-class-definitions* :key #'ecd-class-name)
 280       (error "~S is not a class in *early-class-definitions*." class-name)))
 281
 282 (defun make-early-class-definition
 283        (name source metaclass
 284         superclass-names canonical-slots other-initargs)
 285   (list 'early-class-definition
 286         name source metaclass
 287         superclass-names canonical-slots other-initargs))
 288
 289 (defun ecd-class-name        (ecd) (nth 1 ecd))
 290 (defun ecd-source            (ecd) (nth 2 ecd))
 291 (defun ecd-metaclass         (ecd) (nth 3 ecd))
 292 (defun ecd-superclass-names  (ecd) (nth 4 ecd))
 293 (defun ecd-canonical-slots   (ecd) (nth 5 ecd))
 294 (defun ecd-other-initargs    (ecd) (nth 6 ecd))
 295
 296 (defvar *early-class-slots* nil)
 297
 298 (defun canonical-slot-name (canonical-slot)
 299   (getf canonical-slot :name))
 300
 301 (defun early-class-slots (class-name)
 302   (cdr (or (assoc class-name *early-class-slots*)
 303            (let ((a (cons class-name
 304                           (mapcar #'canonical-slot-name
 305                                   (early-collect-inheritance class-name)))))
 306              (push a *early-class-slots*)
 307              a))))
 308
 309 (defun early-class-size (class-name)
 310   (length (early-class-slots class-name)))
 311
 312 (defun early-collect-inheritance (class-name)
 313   ;;(declare (values slots cpl default-initargs direct-subclasses))
 314   (let ((cpl (early-collect-cpl class-name)))
 315     (values (early-collect-slots cpl)
 316             cpl
 317             (early-collect-default-initargs cpl)
 318             (let (collect)
 319               (dolist (definition *early-class-definitions*)
 320                 (when (memq class-name (ecd-superclass-names definition))
 321                   (push (ecd-class-name definition) collect)))
 322               (nreverse collect)))))
 323
 324 (defun early-collect-slots (cpl)
 325   (let* ((definitions (mapcar #'early-class-definition cpl))
 326          (super-slots (mapcar #'ecd-canonical-slots definitions))
 327          (slots (apply #'append (reverse super-slots))))
 328     (dolist (s1 slots)
 329       (let ((name1 (canonical-slot-name s1)))
 330         (dolist (s2 (cdr (memq s1 slots)))
 331           (when (eq name1 (canonical-slot-name s2))
 332             (error "More than one early class defines a slot with the~%~
 333                     name ~S. This can't work because the bootstrap~%~
 334                     object system doesn't know how to compute effective~%~
 335                     slots."
 336                    name1)))))
 337     slots))
 338
 339 (defun early-collect-cpl (class-name)
 340   (labels ((walk (c)
 341              (let* ((definition (early-class-definition c))
 342                     (supers (ecd-superclass-names definition)))
 343                (cons c
 344                      (apply #'append (mapcar #'early-collect-cpl supers))))))
 345     (remove-duplicates (walk class-name) :from-end nil :test #'eq)))
 346
 347 (defun early-collect-default-initargs (cpl)
 348   (let ((default-initargs ()))
 349     (dolist (class-name cpl)
 350       (let* ((definition (early-class-definition class-name))
 351              (others (ecd-other-initargs definition)))
 352         (loop (when (null others) (return nil))
 353               (let ((initarg (pop others)))
 354                 (unless (eq initarg :direct-default-initargs)
 355                  (error "~@<The defclass option ~S is not supported by ~
 356                         the bootstrap object system.~:@>"
 357                         initarg)))
 358               (setq default-initargs
 359                     (nconc default-initargs (reverse (pop others)))))))
 360     (reverse default-initargs)))
 361
 362 (defun !bootstrap-slot-index (class-name slot-name)
 363   (or (position slot-name (early-class-slots class-name))
 364       (error "~S not found" slot-name)))
 365
 366 ;;; !BOOTSTRAP-GET-SLOT and !BOOTSTRAP-SET-SLOT are used to access and
 367 ;;; change the values of slots during bootstrapping. During
 368 ;;; bootstrapping, there are only two kinds of objects whose slots we
 369 ;;; need to access, CLASSes and SLOT-DEFINITIONs. The first argument
 370 ;;; to these functions tells whether the object is a CLASS or a
 371 ;;; SLOT-DEFINITION.
 372 ;;;
 373 ;;; Note that the way this works it stores the slot in the same place
 374 ;;; in memory that the full object system will expect to find it
 375 ;;; later. This is critical to the bootstrapping process, the whole
 376 ;;; changeover to the full object system is predicated on this.
 377 ;;;
 378 ;;; One important point is that the layout of standard classes and
 379 ;;; standard slots must be computed the same way in this file as it is
 380 ;;; by the full object system later.
 381 (defmacro !bootstrap-get-slot (type object slot-name)
 382   `(clos-slots-ref (get-slots ,object)
 383                    (!bootstrap-slot-index ,type ,slot-name)))
 384 (defun !bootstrap-set-slot (type object slot-name new-value)
 385   (setf (!bootstrap-get-slot type object slot-name) new-value))
 386
 387 (defun early-class-name (class)
 388   (!bootstrap-get-slot 'class class 'name))
 389
 390 (defun early-class-precedence-list (class)
 391   (!bootstrap-get-slot 'pcl-class class 'class-precedence-list))
 392
 393 (defun early-class-name-of (instance)
 394   (early-class-name (class-of instance)))
 395
 396 (defun early-class-slotds (class)
 397   (!bootstrap-get-slot 'slot-class class 'slots))
 398
 399 (defun early-slot-definition-name (slotd)
 400   (!bootstrap-get-slot 'standard-effective-slot-definition slotd 'name))
 401
 402 (defun early-slot-definition-location (slotd)
 403   (!bootstrap-get-slot 'standard-effective-slot-definition slotd 'location))
 404
 405 (defun early-accessor-method-slot-name (method)
 406   (!bootstrap-get-slot 'standard-accessor-method method 'slot-name))
 407
 408 (unless (fboundp 'class-name-of)
 409   (setf (symbol-function 'class-name-of)
 410         (symbol-function 'early-class-name-of)))
 411 (unintern 'early-class-name-of)
 412
 413 (defun early-class-direct-subclasses (class)
 414   (!bootstrap-get-slot 'class class 'direct-subclasses))
 415
 416 (declaim (notinline load-defclass))
 417 (defun load-defclass (name metaclass supers canonical-slots canonical-options)
 418   (setq supers  (copy-tree supers)
 419         canonical-slots   (copy-tree canonical-slots)
 420         canonical-options (copy-tree canonical-options))
 421   (let ((ecd
 422           (make-early-class-definition name
 423                                        *load-pathname*
 424                                        metaclass
 425                                        supers
 426                                        canonical-slots
 427                                        canonical-options))
 428         (existing
 429           (find name *early-class-definitions* :key #'ecd-class-name)))
 430     (setq *early-class-definitions*
 431           (cons ecd (remove existing *early-class-definitions*)))
 432     ecd))
 433