src/pcl/defclass.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 ;;;; DEFCLASS macro and close personal friends
  27
  28 ;;; state for the current DEFCLASS expansion
  29 (defvar *initfunctions-for-this-defclass*)
  30 (defvar *readers-for-this-defclass*)
  31 (defvar *writers-for-this-defclass*)
  32 (defvar *slot-names-for-this-defclass*)
  33
  34 ;;; Like the DEFMETHOD macro, the expansion of the DEFCLASS macro is
  35 ;;; fixed. DEFCLASS always expands into a call to LOAD-DEFCLASS. Until
  36 ;;; the meta-braid is set up, LOAD-DEFCLASS has a special definition
  37 ;;; which simply collects all class definitions up, when the metabraid
  38 ;;; is initialized it is done from those class definitions.
  39 ;;;
  40 ;;; After the metabraid has been setup, and the protocol for defining
  41 ;;; classes has been defined, the real definition of LOAD-DEFCLASS is
  42 ;;; installed by the file std-class.lisp
  43 (defmacro defclass (&environment env name direct-superclasses direct-slots &rest options)
  44   (let (*initfunctions-for-this-defclass*
  45         *readers-for-this-defclass* ;Truly a crock, but we got
  46         *writers-for-this-defclass* ;to have it to live nicely.
  47         *slot-names-for-this-defclass*)
  48     ;; FIXME: It would be nice to collect all errors from the
  49     ;; expansion of a defclass and signal them in a single go.
  50     (multiple-value-bind (metaclass canonical-options)
  51         (canonize-defclass-options name options)
  52     (let ((canonical-slots (canonize-defclass-slots name direct-slots env))
  53           ;; DEFSTRUCT-P should be true if the class is defined
  54           ;; with a metaclass STRUCTURE-CLASS, so that a DEFSTRUCT
  55           ;; is compiled for the class.
  56           (defstruct-p (and (eq *boot-state* 'complete)
  57                             (let ((mclass (find-class metaclass nil)))
  58                               (and mclass
  59                                    (*subtypep
  60                                     mclass
  61                                     *the-class-structure-class*))))))
  62       (let* ((defclass-form
  63               `(let ,(mapcar #'cdr *initfunctions-for-this-defclass*)
  64                  (load-defclass ',name
  65                                 ',metaclass
  66                                 ',direct-superclasses
  67                                 (list ,@canonical-slots)
  68                                 (list ,@(apply #'append
  69                                                (when defstruct-p
  70                                                  '(:from-defclass-p t))
  71                                                 canonical-options))
  72                                 ',*readers-for-this-defclass*
  73                                 ',*writers-for-this-defclass*
  74                                 ',*slot-names-for-this-defclass*))))
  75         (if defstruct-p
  76             (progn
  77               ;; FIXME: (YUK!) Why do we do this? Because in order
  78               ;; to make the defstruct form, we need to know what
  79               ;; the accessors for the slots are, so we need already
  80               ;; to have hooked into the CLOS machinery.
  81               ;;
  82               ;; There may be a better way to do this: it would
  83               ;; involve knowing enough about PCL to ask "what will
  84               ;; my slot names and accessors be"; failing this, we
  85               ;; currently just evaluate the whole kaboodle, and
  86               ;; then use CLASS-DIRECT-SLOTS. -- CSR, 2002-06-07
  87               (eval defclass-form)
  88               (let* ((include (or (and direct-superclasses
  89                                        (fix-super (car direct-superclasses)))
  90                                   (and (not (eq name 'structure-object))
  91                                        *the-class-structure-object*)))
  92                      (defstruct-form (make-structure-class-defstruct-form
  93                                       name (class-direct-slots (find-class name))
  94                                       include)))
  95                 `(progn
  96                    (eval-when (:compile-toplevel :load-toplevel :execute)
  97                      ,defstruct-form) ; really compile the defstruct-form
  98                    (eval-when (:compile-toplevel :load-toplevel :execute)
  99                      ,defclass-form))))
 100             `(progn
 101                ;; By telling the type system at compile time about
 102                ;; the existence of a class named NAME, we can avoid
 103                ;; various bogus warnings about "type isn't defined yet"
 104                ;; for code elsewhere in the same file which uses
 105                ;; the name of the type.
 106                ;;
 107                ;; We only need to do this at compile time, because
 108                ;; at load and execute time we write the actual
 109                ;; full-blown class, so the "a class of this name is
 110                ;; coming" note we write here would be irrelevant.
 111                (eval-when (:compile-toplevel)
 112                  (%compiler-defclass ',name
 113                                      ',*readers-for-this-defclass*
 114                                      ',*writers-for-this-defclass*
 115                                      ',*slot-names-for-this-defclass*))
 116                (eval-when (:load-toplevel :execute)
 117                  ,defclass-form))))))))
 118
 119 (defun canonize-defclass-options (class-name options)
 120   (macrolet ((assert-single (option)
 121                `(when ,option
 122                   (error "Multiple ~A options in DEFCLASS ~S."
 123                          ,(intern (string option) :keyword)
 124                          class-name))))
 125     (let (metaclass
 126           default-initargs
 127           documentation
 128           canonized-options)
 129       (dolist (option options)
 130         (unless (listp option)
 131           (error "~S is not a legal defclass option." option))
 132         (case (first option)
 133           (:metaclass
 134            (assert-single metaclass)
 135            (let ((maybe-metaclass (second option)))
 136              (unless (and maybe-metaclass (legal-class-name-p maybe-metaclass))
 137                (error "~@<The value of the :metaclass option (~S) ~
 138                          is not a legal class name.~:@>"
 139                       maybe-metaclass))
 140              (setf metaclass maybe-metaclass)))
 141           (:default-initargs
 142            (assert-single default-initargs)
 143            (let (initargs arg-names)
 144              (doplist (key val) (cdr option)
 145                (when (member key arg-names)
 146                  (error 'simple-program-error
 147                         :format-control "~@<Duplicate initialization argument ~
 148                                          name ~S in :DEFAULT-INITARGS of ~
 149                                          DEFCLASS ~S.~:>"
 150                         :format-arguments (list key class-name)))
 151                (push key arg-names)
 152                (push ``(,',key ,,(make-initfunction val) ,',val) initargs))
 153              (setf default-initargs t)
 154              (push `(:direct-default-initargs (list ,@(nreverse initargs)))
 155                    canonized-options)))
 156           (:documentation
 157            (assert-single documentation)
 158            (unless (stringp (second option))
 159              (error "~S is not a legal :documentation value" (second option)))
 160            (setf documentation t)
 161            (push `(:documentation ,(second option)) canonized-options))
 162           (otherwise
 163            (push `(',(car option) ',(cdr option)) canonized-options))))
 164       (values (or metaclass 'standard-class) (nreverse canonized-options)))))
 165
 166 (defun canonize-defclass-slots (class-name slots env)
 167   (let (canonized-specs)
 168     (dolist (spec slots)
 169       (when (atom spec)
 170         (setf spec (list spec)))
 171       (when (and (cdr spec) (null (cddr spec)))
 172         (error 'simple-program-error
 173                :format-control "~@<in DEFCLASS ~S, the slot specification ~S ~
 174                                 is invalid; the probable intended meaning may ~
 175                                 be achieved by specifiying ~S instead.~:>"
 176                :format-arguments (list class-name spec
 177                                        `(,(car spec) :initform ,(cadr spec)))))
 178       (let* ((name (car spec))
 179              (plist (cdr spec))
 180              (readers ())
 181              (writers ())
 182              (initargs ())
 183              (others ())
 184              (unsupplied (list nil))
 185              (initform unsupplied))
 186         (check-slot-name-for-defclass name class-name env)
 187         (push name *slot-names-for-this-defclass*)
 188         (flet ((note-reader (x)
 189                  (unless (symbolp x)
 190                    (error 'simple-program-error
 191                           :format-control "Slot reader name ~S for slot ~S in ~
 192                                            DEFCLASS ~S is not a symbol."
 193                           :format-arguments (list x name class-name)))
 194                  (push x readers)
 195                  (push x *readers-for-this-defclass*))
 196                (note-writer (x)
 197                  (push x writers)
 198                  (push x *writers-for-this-defclass*)))
 199           (doplist (key val) plist
 200             (case key
 201               (:accessor (note-reader val) (note-writer `(setf ,val)))
 202               (:reader   (note-reader val))
 203               (:writer   (note-writer val))
 204               (:initarg
 205                (unless (symbolp val)
 206                  (error 'simple-program-error
 207                         :format-control "Slot initarg name ~S for slot ~S in ~
 208                                          DEFCLASS ~S is not a symbol."
 209                         :format-arguments (list val name class-name)))
 210                (push val initargs))
 211               (otherwise
 212                (when (member key '(:initform :allocation :type :documentation))
 213                  (when (eq key :initform)
 214                    (setf initform val))
 215                  (when (get-properties others (list key))
 216                    (error 'simple-program-error
 217                           :format-control "Duplicate slot option ~S for slot ~
 218                                            ~S in DEFCLASS ~S."
 219                           :format-arguments (list key name class-name))))
 220                ;; For non-standard options multiple entries go in a list
 221                (push val (getf others key))))))
 222         ;; Unwrap singleton lists (AMOP 5.4.2)
 223         (do ((head others (cddr head)))
 224             ((null head))
 225           (unless (cdr (second head))
 226             (setf (second head) (car (second head)))))
 227         (let ((canon `(:name ',name :readers ',readers :writers ',writers
 228                              :initargs ',initargs ',others)))
 229           (push (if (eq initform unsupplied)
 230                     `(list* ,@canon)
 231                     `(list* :initfunction ,(make-initfunction initform)
 232                             ,@canon))
 233                 canonized-specs))))
 234     (nreverse canonized-specs)))
 235
 236
 237 (defun check-slot-name-for-defclass (name class-name env)
 238   (flet ((slot-name-illegal (reason)
 239            (error 'simple-program-error
 240                   :format-control
 241                   (format nil "~~@<In DEFCLASS ~~S, the slot name ~~S ~
 242                                is ~A.~~@:>" reason)
 243                   :format-arguments (list class-name name))))
 244     (cond ((not (symbolp name))
 245            (slot-name-illegal "not a symbol"))
 246           ((keywordp name)
 247            (slot-name-illegal "a keyword"))
 248           ((constantp name env)
 249            (slot-name-illegal "a constant"))
 250           ((member name *slot-names-for-this-defclass*)
 251            (error 'simple-program-error
 252                   :format-control "Multiple slots named ~S in DEFCLASS ~S."
 253                   :format-arguments (list name class-name))))))
 254
 255 (defun make-initfunction (initform)
 256   (cond ((or (eq initform t)
 257              (equal initform ''t))
 258          '(function constantly-t))
 259         ((or (eq initform nil)
 260              (equal initform ''nil))
 261          '(function constantly-nil))
 262         ((or (eql initform 0)
 263              (equal initform ''0))
 264          '(function constantly-0))
 265         (t
 266          (let ((entry (assoc initform *initfunctions-for-this-defclass*
 267                              :test #'equal)))
 268            (unless entry
 269              (setq entry (list initform
 270                                (gensym)
 271                                `(function (lambda () ,initform))))
 272              (push entry *initfunctions-for-this-defclass*))
 273            (cadr entry)))))
 274
 275 (defun %compiler-defclass (name readers writers slots)
 276   ;; ANSI says (Macro DEFCLASS, section 7.7) that DEFCLASS, if it
 277   ;; "appears as a top level form, the compiler must make the class
 278   ;; name be recognized as a valid type name in subsequent
 279   ;; declarations (as for deftype) and be recognized as a valid class
 280   ;; name for defmethod parameter specializers and for use as the
 281   ;; :metaclass option of a subsequent defclass."
 282   (preinform-compiler-about-class-type name)
 283   (preinform-compiler-about-accessors readers writers slots))
 284
 285 (defun preinform-compiler-about-class-type (name)
 286   ;; Unless the type system already has an actual type attached to
 287   ;; NAME (in which case (1) writing a placeholder value over that
 288   ;; actual type as a compile-time side-effect would probably be a bad
 289   ;; idea and (2) anyway we don't need to modify it in order to make
 290   ;; NAME be recognized as a valid type name)
 291   (unless (info :type :kind name)
 292     ;; Tell the compiler to expect a class with the given NAME, by
 293     ;; writing a kind of minimal placeholder type information. This
 294     ;; placeholder will be overwritten later when the class is defined.
 295     (setf (info :type :kind name) :forthcoming-defclass-type))
 296   (values))
 297
 298 (defun preinform-compiler-about-accessors (readers writers slots)
 299   (flet ((inform (name type)
 300            ;; FIXME: This matches what PROCLAIM FTYPE does, except
 301            ;; that :WHERE-FROM is :DEFINED, not :DECLARED, and should
 302            ;; probably be factored into a common function -- eg.
 303            ;; (%proclaim-ftype name declared-or-defined).
 304            (when (eq (info :function :where-from name) :assumed)
 305              (proclaim-as-fun-name name)
 306              (note-name-defined name :function)
 307              (setf (info :function :where-from name) :defined
 308                    (info :function :type name) type))))
 309     (let ((rtype (specifier-type '(function (t) t)))
 310           (wtype (specifier-type '(function (t t) t))))
 311       (dolist (reader readers)
 312         (inform reader rtype))
 313       (dolist (writer writers)
 314         (inform writer wtype))
 315       (dolist (slot slots)
 316         (inform (slot-reader-name slot) rtype)
 317         (inform (slot-boundp-name slot) rtype)
 318         (inform (slot-writer-name slot) wtype)))))
 319 \f
 320 ;;; This is the early definition of LOAD-DEFCLASS. It just collects up
 321 ;;; all the class definitions in a list. Later, in braid1.lisp, these
 322 ;;; are actually defined.
 323
 324 ;;; Each entry in *EARLY-CLASS-DEFINITIONS* is an EARLY-CLASS-DEFINITION.
 325 (defparameter *early-class-definitions* ())
 326
 327 (defun early-class-definition (class-name)
 328   (or (find class-name *early-class-definitions* :key #'ecd-class-name)
 329       (error "~S is not a class in *early-class-definitions*." class-name)))
 330
 331 (defun make-early-class-definition
 332        (name source metaclass
 333         superclass-names canonical-slots other-initargs)
 334   (list 'early-class-definition
 335         name source metaclass
 336         superclass-names canonical-slots other-initargs))
 337
 338 (defun ecd-class-name        (ecd) (nth 1 ecd))
 339 (defun ecd-source            (ecd) (nth 2 ecd))
 340 (defun ecd-metaclass         (ecd) (nth 3 ecd))
 341 (defun ecd-superclass-names  (ecd) (nth 4 ecd))
 342 (defun ecd-canonical-slots   (ecd) (nth 5 ecd))
 343 (defun ecd-other-initargs    (ecd) (nth 6 ecd))
 344
 345 (defvar *early-class-slots* nil)
 346
 347 (defun canonical-slot-name (canonical-slot)
 348   (getf canonical-slot :name))
 349
 350 (defun early-class-slots (class-name)
 351   (cdr (or (assoc class-name *early-class-slots*)
 352            (let ((a (cons class-name
 353                           (mapcar #'canonical-slot-name
 354                                   (early-collect-inheritance class-name)))))
 355              (push a *early-class-slots*)
 356              a))))
 357
 358 (defun early-class-size (class-name)
 359   (length (early-class-slots class-name)))
 360
 361 (defun early-collect-inheritance (class-name)
 362   ;;(declare (values slots cpl default-initargs direct-subclasses))
 363   (let ((cpl (early-collect-cpl class-name)))
 364     (values (early-collect-slots cpl)
 365             cpl
 366             (early-collect-default-initargs cpl)
 367             (let (collect)
 368               (dolist (definition *early-class-definitions*)
 369                 (when (memq class-name (ecd-superclass-names definition))
 370                   (push (ecd-class-name definition) collect)))
 371               (nreverse collect)))))
 372
 373 (defun early-collect-slots (cpl)
 374   (let* ((definitions (mapcar #'early-class-definition cpl))
 375          (super-slots (mapcar #'ecd-canonical-slots definitions))
 376          (slots (apply #'append (reverse super-slots))))
 377     (dolist (s1 slots)
 378       (let ((name1 (canonical-slot-name s1)))
 379         (dolist (s2 (cdr (memq s1 slots)))
 380           (when (eq name1 (canonical-slot-name s2))
 381             (error "More than one early class defines a slot with the~%~
 382                     name ~S. This can't work because the bootstrap~%~
 383                     object system doesn't know how to compute effective~%~
 384                     slots."
 385                    name1)))))
 386     slots))
 387
 388 (defun early-collect-cpl (class-name)
 389   (labels ((walk (c)
 390              (let* ((definition (early-class-definition c))
 391                     (supers (ecd-superclass-names definition)))
 392                (cons c
 393                      (apply #'append (mapcar #'early-collect-cpl supers))))))
 394     (remove-duplicates (walk class-name) :from-end nil :test #'eq)))
 395
 396 (defun early-collect-default-initargs (cpl)
 397   (let ((default-initargs ()))
 398     (dolist (class-name cpl)
 399       (let* ((definition (early-class-definition class-name))
 400              (others (ecd-other-initargs definition)))
 401         (loop (when (null others) (return nil))
 402               (let ((initarg (pop others)))
 403                 (unless (eq initarg :direct-default-initargs)
 404                  (error "~@<The defclass option ~S is not supported by ~
 405                         the bootstrap object system.~:@>"
 406                         initarg)))
 407               (setq default-initargs
 408                     (nconc default-initargs (reverse (pop others)))))))
 409     (reverse default-initargs)))
 410
 411 (defun !bootstrap-slot-index (class-name slot-name)
 412   (or (position slot-name (early-class-slots class-name))
 413       (error "~S not found" slot-name)))
 414
 415 ;;; !BOOTSTRAP-GET-SLOT and !BOOTSTRAP-SET-SLOT are used to access and
 416 ;;; change the values of slots during bootstrapping. During
 417 ;;; bootstrapping, there are only two kinds of objects whose slots we
 418 ;;; need to access, CLASSes and SLOT-DEFINITIONs. The first argument
 419 ;;; to these functions tells whether the object is a CLASS or a
 420 ;;; SLOT-DEFINITION.
 421 ;;;
 422 ;;; Note that the way this works it stores the slot in the same place
 423 ;;; in memory that the full object system will expect to find it
 424 ;;; later. This is critical to the bootstrapping process, the whole
 425 ;;; changeover to the full object system is predicated on this.
 426 ;;;
 427 ;;; One important point is that the layout of standard classes and
 428 ;;; standard slots must be computed the same way in this file as it is
 429 ;;; by the full object system later.
 430 (defmacro !bootstrap-get-slot (type object slot-name)
 431   `(clos-slots-ref (get-slots ,object)
 432                    (!bootstrap-slot-index ,type ,slot-name)))
 433 (defun !bootstrap-set-slot (type object slot-name new-value)
 434   (setf (!bootstrap-get-slot type object slot-name) new-value))
 435
 436 (defun early-class-name (class)
 437   (!bootstrap-get-slot 'class class 'name))
 438
 439 (defun early-class-precedence-list (class)
 440   (!bootstrap-get-slot 'pcl-class class 'class-precedence-list))
 441
 442 (defun early-class-name-of (instance)
 443   (early-class-name (class-of instance)))
 444
 445 (defun early-class-slotds (class)
 446   (!bootstrap-get-slot 'slot-class class 'slots))
 447
 448 (defun early-slot-definition-name (slotd)
 449   (!bootstrap-get-slot 'standard-effective-slot-definition slotd 'name))
 450
 451 (defun early-slot-definition-location (slotd)
 452   (!bootstrap-get-slot 'standard-effective-slot-definition slotd 'location))
 453
 454 (defun early-accessor-method-slot-name (method)
 455   (!bootstrap-get-slot 'standard-accessor-method method 'slot-name))
 456
 457 (unless (fboundp 'class-name-of)
 458   (setf (symbol-function 'class-name-of)
 459         (symbol-function 'early-class-name-of)))
 460 (unintern 'early-class-name-of)
 461
 462 (defun early-class-direct-subclasses (class)
 463   (!bootstrap-get-slot 'class class 'direct-subclasses))
 464
 465 (declaim (notinline load-defclass))
 466 (defun load-defclass (name metaclass supers canonical-slots canonical-options
 467                       readers writers slot-names)
 468   (%compiler-defclass name readers writers slot-names)
 469   (setq supers  (copy-tree supers)
 470         canonical-slots   (copy-tree canonical-slots)
 471         canonical-options (copy-tree canonical-options))
 472   (let ((ecd
 473           (make-early-class-definition name
 474                                        *load-pathname*
 475                                        metaclass
 476                                        supers
 477                                        canonical-slots
 478                                        canonical-options))
 479         (existing
 480           (find name *early-class-definitions* :key #'ecd-class-name)))
 481     (setq *early-class-definitions*
 482           (cons ecd (remove existing *early-class-definitions*)))
 483     ecd))